src/pcl/defclass.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defun make-progn (&rest forms)
  27   (let ((progn-form nil))
  28     (labels ((collect-forms (forms)
  29                (unless (null forms)
  30                  (collect-forms (cdr forms))
  31                  (if (and (listp (car forms))
  32                           (eq (caar forms) 'progn))
  33                      (collect-forms (cdar forms))
  34                      (push (car forms) progn-form)))))
  35       (collect-forms forms)
  36       (cons 'progn progn-form))))
  37 \f
  38 ;;; Like the DEFMETHOD macro, the expansion of the DEFCLASS macro is
  39 ;;; fixed. DEFCLASS always expands into a call to LOAD-DEFCLASS. Until
  40 ;;; the meta-braid is set up, LOAD-DEFCLASS has a special definition
  41 ;;; which simply collects all class definitions up, when the metabraid
  42 ;;; is initialized it is done from those class definitions.
  43 ;;;
  44 ;;; After the metabraid has been setup, and the protocol for defining
  45 ;;; classes has been defined, the real definition of LOAD-DEFCLASS is
  46 ;;; installed by the file std-class.lisp
  47 (defmacro defclass (name %direct-superclasses %direct-slots &rest %options)
  48   (let ((supers  (copy-tree %direct-superclasses))
  49         (slots   (copy-tree %direct-slots))
  50         (options (copy-tree %options)))
  51     (let ((metaclass 'standard-class))
  52       (dolist (option options)
  53         (if (not (listp option))
  54           (error "~S is not a legal defclass option." option)
  55           (when (eq (car option) :metaclass)
  56             (unless (legal-class-name-p (cadr option))
  57               (error "The value of the :metaclass option (~S) is not a~%~
  58                       legal class name."
  59                      (cadr option)))
  60             (setq metaclass
  61                     (case (cadr option)
  62                       (cl:standard-class 'standard-class)
  63                       (cl:structure-class 'structure-class)
  64                       (t (cadr option))))
  65             (setf options (remove option options))
  66             (return t))))
  67
  68       (let ((*initfunctions* ())
  69             (*readers* ())              ;Truly a crock, but we got
  70             (*writers* ()))             ;to have it to live nicely.
  71         (declare (special *initfunctions* *readers* *writers*))
  72         (let ((canonical-slots
  73                 (mapcar (lambda (spec)
  74                           (canonicalize-slot-specification name spec))
  75                         slots))
  76               (other-initargs
  77                 (mapcar (lambda (option)
  78                           (canonicalize-defclass-option name option))
  79                         options))
  80               ;; DEFSTRUCT-P should be true, if the class is defined with a
  81               ;; metaclass STRUCTURE-CLASS, such that a DEFSTRUCT is compiled
  82               ;; for the class.
  83               (defstruct-p (and (eq *boot-state* 'complete)
  84                                 (let ((mclass (find-class metaclass nil)))
  85                                   (and mclass
  86                                        (*subtypep
  87                                         mclass
  88                                         *the-class-structure-class*))))))
  89           (let ((defclass-form
  90                     `(progn
  91                       ,@(mapcar (lambda (x)
  92                                   `(declaim (ftype (function (t) t) ,x)))
  93                                 *readers*)
  94                       ,@(mapcar (lambda (x)
  95                                   `(declaim (ftype (function (t t) t) ,x)))
  96                                 *writers*)
  97                       (let ,(mapcar #'cdr *initfunctions*)
  98                         (load-defclass ',name
  99                                        ',metaclass
 100                                        ',supers
 101                                        (list ,@canonical-slots)
 102                                        (list ,@(apply #'append
 103                                                       (when defstruct-p
 104                                                         '(:from-defclass-p t))
 105                                                       other-initargs)))))))
 106             (if defstruct-p
 107               (let* ((include (or (and supers
 108                                        (fix-super (car supers)))
 109                                   (and (not (eq name 'structure-object))
 110                                        *the-class-structure-object*)))
 111                      (defstruct-form (make-structure-class-defstruct-form
 112                                       name slots include)))
 113                 `(progn
 114                   (eval-when (:compile-toplevel :load-toplevel :execute)
 115                     ,defstruct-form) ; really compile the defstruct-form
 116                   (eval-when (:compile-toplevel :load-toplevel :execute)
 117                     ,defclass-form)))
 118               `(progn
 119                 ;; By telling the type system at compile time about
 120                 ;; the existence of a class named NAME, we can avoid
 121                 ;; various bogus warnings about "type isn't defined yet".
 122                 ,(when (and
 123                          ;; But it's not so important to get rid of
 124                          ;; "not defined yet" warnings during
 125                          ;; bootstrapping, and machinery like
 126                          ;; INFORM-TYPE-SYSTEM-ABOUT-STD-CLASS
 127                          ;; mightn't be defined yet. So punt then.
 128                          (eq *boot-state* 'complete)
 129                          ;; And although we know enough about
 130                          ;; STANDARD-CLASS, and ANSI imposes enough
 131                          ;; restrictions on the user overloading its
 132                          ;; methods, that (1) we can shortcut the
 133                          ;; method dispatch and do an ordinary
 134                          ;; function call, and (2) be sure we're getting
 135                          ;; it right even when we do it at compile
 136                          ;; time; we don't in general know how to do
 137                          ;; that for other classes. So punt then too.
 138                          (eq metaclass 'standard-class))
 139                        `(eval-when (:compile-toplevel)
 140                          ;; we only need :COMPILE-TOPLEVEL here, because this
 141                          ;; should happen in the compile-time environment
 142                          ;; only.
 143                          ;; Later, INFORM-TYPE-SYSTEM-ABOUT-STD-CLASS is
 144                          ;; called by way of LOAD-DEFCLASS (calling
 145                          ;; ENSURE-CLASS-USING-CLASS) to establish the 'real'
 146                          ;; type predicate.
 147                          (inform-type-system-about-std-class ',name)))
 148                 ,defclass-form))))))))
 149
 150 (defun make-initfunction (initform)
 151   (declare (special *initfunctions*))
 152   (cond ((or (eq initform t)
 153              (equal initform ''t))
 154          '(function constantly-t))
 155         ((or (eq initform nil)
 156              (equal initform ''nil))
 157          '(function constantly-nil))
 158         ((or (eql initform 0)
 159              (equal initform ''0))
 160          '(function constantly-0))
 161         (t
 162          (let ((entry (assoc initform *initfunctions* :test #'equal)))
 163            (unless entry
 164              (setq entry (list initform
 165                                (gensym)
 166                                `(function (lambda () ,initform))))
 167              (push entry *initfunctions*))
 168            (cadr entry)))))
 169
 170 (defun canonicalize-slot-specification (class-name spec)
 171   (declare (special *readers* *writers*))
 172   (cond ((and (symbolp spec)
 173               (not (keywordp spec))
 174               (not (memq spec '(t nil))))
 175          `'(:name ,spec))
 176         ((not (consp spec))
 177          (error "~S is not a legal slot specification." spec))
 178         ((null (cdr spec))
 179          `'(:name ,(car spec)))
 180         ((null (cddr spec))
 181          (error "In DEFCLASS ~S, the slot specification ~S is obsolete.~%~
 182                  Convert it to ~S"
 183                 class-name spec (list (car spec) :initform (cadr spec))))
 184         (t
 185          (let* ((name (pop spec))
 186                 (readers ())
 187                 (writers ())
 188                 (initargs ())
 189                 (unsupplied (list nil))
 190                 (initform (getf spec :initform unsupplied)))
 191            (doplist (key val) spec
 192              (case key
 193                (:accessor (push val readers)
 194                           (push `(setf ,val) writers))
 195                (:reader   (push val readers))
 196                (:writer   (push val writers))
 197                (:initarg  (push val initargs))))
 198            (loop (unless (remf spec :accessor) (return)))
 199            (loop (unless (remf spec :reader)   (return)))
 200            (loop (unless (remf spec :writer)   (return)))
 201            (loop (unless (remf spec :initarg)  (return)))
 202            (setq *writers* (append writers *writers*))
 203            (setq *readers* (append readers *readers*))
 204            (setq spec `(:name     ',name
 205                         :readers  ',readers
 206                         :writers  ',writers
 207                         :initargs ',initargs
 208                         ',spec))
 209            (if (eq initform unsupplied)
 210                `(list* ,@spec)
 211                `(list* :initfunction ,(make-initfunction initform) ,@spec))))))
 212
 213 (defun canonicalize-defclass-option (class-name option)
 214   (declare (ignore class-name))
 215   (case (car option)
 216     (:default-initargs
 217       (let ((canonical ()))
 218         (let (key val (tail (cdr option)))
 219           (loop (when (null tail) (return nil))
 220                 (setq key (pop tail)
 221                       val (pop tail))
 222                 (push ``(,',key ,,(make-initfunction val) ,',val) canonical))
 223           `(:direct-default-initargs (list ,@(nreverse canonical))))))
 224     (:documentation
 225       `(',(car option) ',(cadr option)))
 226     (otherwise
 227      `(',(car option) ',(cdr option)))))
 228 \f
 229 ;;; This is the early definition of load-defclass. It just collects up
 230 ;;; all the class definitions in a list. Later, in the file
 231 ;;; braid1.lisp, these are actually defined.
 232
 233 ;;; Each entry in *EARLY-CLASS-DEFINITIONS* is an EARLY-CLASS-DEFINITION.
 234 (defparameter *early-class-definitions* ())
 235
 236 (defun early-class-definition (class-name)
 237   (or (find class-name *early-class-definitions* :key #'ecd-class-name)
 238       (error "~S is not a class in *early-class-definitions*." class-name)))
 239
 240 (defun make-early-class-definition
 241        (name source metaclass
 242         superclass-names canonical-slots other-initargs)
 243   (list 'early-class-definition
 244         name source metaclass
 245         superclass-names canonical-slots other-initargs))
 246
 247 (defun ecd-class-name        (ecd) (nth 1 ecd))
 248 (defun ecd-source            (ecd) (nth 2 ecd))
 249 (defun ecd-metaclass         (ecd) (nth 3 ecd))
 250 (defun ecd-superclass-names  (ecd) (nth 4 ecd))
 251 (defun ecd-canonical-slots   (ecd) (nth 5 ecd))
 252 (defun ecd-other-initargs    (ecd) (nth 6 ecd))
 253
 254 (defvar *early-class-slots* nil)
 255
 256 (defun canonical-slot-name (canonical-slot)
 257   (getf canonical-slot :name))
 258
 259 (defun early-class-slots (class-name)
 260   (cdr (or (assoc class-name *early-class-slots*)
 261            (let ((a (cons class-name
 262                           (mapcar #'canonical-slot-name
 263                                   (early-collect-inheritance class-name)))))
 264              (push a *early-class-slots*)
 265              a))))
 266
 267 (defun early-class-size (class-name)
 268   (length (early-class-slots class-name)))
 269
 270 (defun early-collect-inheritance (class-name)
 271   ;;(declare (values slots cpl default-initargs direct-subclasses))
 272   (let ((cpl (early-collect-cpl class-name)))
 273     (values (early-collect-slots cpl)
 274             cpl
 275             (early-collect-default-initargs cpl)
 276             (let (collect)
 277               (dolist (definition *early-class-definitions*)
 278                 (when (memq class-name (ecd-superclass-names definition))
 279                   (push (ecd-class-name definition) collect)))
 280               (nreverse collect)))))
 281
 282 (defun early-collect-slots (cpl)
 283   (let* ((definitions (mapcar #'early-class-definition cpl))
 284          (super-slots (mapcar #'ecd-canonical-slots definitions))
 285          (slots (apply #'append (reverse super-slots))))
 286     (dolist (s1 slots)
 287       (let ((name1 (canonical-slot-name s1)))
 288         (dolist (s2 (cdr (memq s1 slots)))
 289           (when (eq name1 (canonical-slot-name s2))
 290             (error "More than one early class defines a slot with the~%~
 291                     name ~S. This can't work because the bootstrap~%~
 292                     object system doesn't know how to compute effective~%~
 293                     slots."
 294                    name1)))))
 295     slots))
 296
 297 (defun early-collect-cpl (class-name)
 298   (labels ((walk (c)
 299              (let* ((definition (early-class-definition c))
 300                     (supers (ecd-superclass-names definition)))
 301                (cons c
 302                      (apply #'append (mapcar #'early-collect-cpl supers))))))
 303     (remove-duplicates (walk class-name) :from-end nil :test #'eq)))
 304
 305 (defun early-collect-default-initargs (cpl)
 306   (let ((default-initargs ()))
 307     (dolist (class-name cpl)
 308       (let* ((definition (early-class-definition class-name))
 309              (others (ecd-other-initargs definition)))
 310         (loop (when (null others) (return nil))
 311               (let ((initarg (pop others)))
 312                 (unless (eq initarg :direct-default-initargs)
 313                  (error "~@<The defclass option ~S is not supported by ~
 314                         the bootstrap object system.~:@>"
 315                         initarg)))
 316               (setq default-initargs
 317                     (nconc default-initargs (reverse (pop others)))))))
 318     (reverse default-initargs)))
 319
 320 (defun !bootstrap-slot-index (class-name slot-name)
 321   (or (position slot-name (early-class-slots class-name))
 322       (error "~S not found" slot-name)))
 323
 324 ;;; !BOOTSTRAP-GET-SLOT and !BOOTSTRAP-SET-SLOT are used to access and
 325 ;;; change the values of slots during bootstrapping. During
 326 ;;; bootstrapping, there are only two kinds of objects whose slots we
 327 ;;; need to access, CLASSes and SLOT-DEFINITIONs. The first argument
 328 ;;; to these functions tells whether the object is a CLASS or a
 329 ;;; SLOT-DEFINITION.
 330 ;;;
 331 ;;; Note that the way this works it stores the slot in the same place
 332 ;;; in memory that the full object system will expect to find it
 333 ;;; later. This is critical to the bootstrapping process, the whole
 334 ;;; changeover to the full object system is predicated on this.
 335 ;;;
 336 ;;; One important point is that the layout of standard classes and
 337 ;;; standard slots must be computed the same way in this file as it is
 338 ;;; by the full object system later.
 339 (defmacro !bootstrap-get-slot (type object slot-name)
 340   `(clos-slots-ref (get-slots ,object)
 341                    (!bootstrap-slot-index ,type ,slot-name)))
 342 (defun !bootstrap-set-slot (type object slot-name new-value)
 343   (setf (!bootstrap-get-slot type object slot-name) new-value))
 344
 345 (defun early-class-name (class)
 346   (!bootstrap-get-slot 'class class 'name))
 347
 348 (defun early-class-precedence-list (class)
 349   (!bootstrap-get-slot 'pcl-class class 'class-precedence-list))
 350
 351 (defun early-class-name-of (instance)
 352   (early-class-name (class-of instance)))
 353
 354 (defun early-class-slotds (class)
 355   (!bootstrap-get-slot 'slot-class class 'slots))
 356
 357 (defun early-slot-definition-name (slotd)
 358   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'name))
 359
 360 (defun early-slot-definition-location (slotd)
 361   (!bootstrap-get-slot 'standard-effective-slot-definition slotd 'location))
 362
 363 (defun early-accessor-method-slot-name (method)
 364   (!bootstrap-get-slot 'standard-accessor-method method 'slot-name))
 365
 366 (unless (fboundp 'class-name-of)
 367   (setf (symbol-function 'class-name-of)
 368         (symbol-function 'early-class-name-of)))
 369 (unintern 'early-class-name-of)
 370
 371 (defun early-class-direct-subclasses (class)
 372   (!bootstrap-get-slot 'class class 'direct-subclasses))
 373
 374 (declaim (notinline load-defclass))
 375 (defun load-defclass (name metaclass supers canonical-slots canonical-options)
 376   (setq supers  (copy-tree supers)
 377         canonical-slots   (copy-tree canonical-slots)
 378         canonical-options (copy-tree canonical-options))
 379   (when (eq metaclass 'standard-class)
 380     (inform-type-system-about-std-class name))
 381   (let ((ecd
 382           (make-early-class-definition name
 383                                        *load-truename*
 384                                        metaclass
 385                                        supers
 386                                        canonical-slots
 387                                        canonical-options))
 388         (existing
 389           (find name *early-class-definitions* :key #'ecd-class-name)))
 390     (setq *early-class-definitions*
 391           (cons ecd (remove existing *early-class-definitions*)))
 392     ecd))
 393