src/pcl/defcombin.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmacro define-method-combination (&whole form &rest args)
  27   (declare (ignore args))
  28   `(progn
  29      (with-single-package-locked-error
  30          (:symbol ',(second form) "defining ~A as a method combination"))
  31      ,(if (and (cddr form)
  32                (listp (caddr form)))
  33           (expand-long-defcombin form)
  34           (expand-short-defcombin form))))
  35 \f
  36 ;;;; standard method combination
  37
  38 ;;; The STANDARD method combination type is implemented directly by
  39 ;;; the class STANDARD-METHOD-COMBINATION. The method on
  40 ;;; COMPUTE-EFFECTIVE-METHOD does standard method combination directly
  41 ;;; and is defined by hand in the file combin.lisp. The method for
  42 ;;; FIND-METHOD-COMBINATION must appear in this file for bootstrapping
  43 ;;; reasons.
  44 (defmethod find-method-combination ((generic-function generic-function)
  45                                     (type (eql 'standard))
  46                                     options)
  47   (when options
  48     (method-combination-error
  49       "The method combination type STANDARD accepts no options."))
  50   *standard-method-combination*)
  51 \f
  52 ;;;; short method combinations
  53 ;;;;
  54 ;;;; Short method combinations all follow the same rule for computing the
  55 ;;;; effective method. So, we just implement that rule once. Each short
  56 ;;;; method combination object just reads the parameters out of the object
  57 ;;;; and runs the same rule.
  58
  59 (defclass short-method-combination (standard-method-combination)
  60   ((operator
  61     :reader short-combination-operator
  62     :initarg :operator)
  63    (identity-with-one-argument
  64     :reader short-combination-identity-with-one-argument
  65     :initarg :identity-with-one-argument))
  66   (:predicate-name short-method-combination-p))
  67
  68 (defun expand-short-defcombin (whole)
  69   (let* ((type (cadr whole))
  70          (documentation
  71            (getf (cddr whole) :documentation ""))
  72          (identity-with-one-arg
  73            (getf (cddr whole) :identity-with-one-argument nil))
  74          (operator
  75            (getf (cddr whole) :operator type)))
  76     `(load-short-defcombin
  77      ',type ',operator ',identity-with-one-arg ',documentation)))
  78
  79 (defun load-short-defcombin (type operator ioa doc)
  80   (let* ((pathname *load-pathname*)
  81          (specializers
  82            (list (find-class 'generic-function)
  83                  (intern-eql-specializer type)
  84                  *the-class-t*))
  85          (old-method
  86            (get-method #'find-method-combination () specializers nil))
  87          (new-method nil))
  88     (setq new-method
  89           (make-instance 'standard-method
  90             :qualifiers ()
  91             :specializers specializers
  92             :lambda-list '(generic-function type options)
  93             :function (lambda (args nms &rest cm-args)
  94                         (declare (ignore nms cm-args))
  95                         (apply
  96                          (lambda (gf type options)
  97                            (declare (ignore gf))
  98                            (short-combine-methods
  99                             type options operator ioa new-method doc))
 100                          args))
 101             :definition-source `((define-method-combination ,type) ,pathname)))
 102     (when old-method
 103       (remove-method #'find-method-combination old-method))
 104     (add-method #'find-method-combination new-method)
 105     (setf (random-documentation type 'method-combination) doc)
 106     type))
 107
 108 (defun short-combine-methods (type options operator ioa method doc)
 109   (cond ((null options) (setq options '(:most-specific-first)))
 110         ((equal options '(:most-specific-first)))
 111         ((equal options '(:most-specific-last)))
 112         (t
 113          (method-combination-error
 114           "Illegal options to a short method combination type.~%~
 115            The method combination type ~S accepts one option which~%~
 116            must be either :MOST-SPECIFIC-FIRST or :MOST-SPECIFIC-LAST."
 117           type)))
 118   (make-instance 'short-method-combination
 119                  :type type
 120                  :options options
 121                  :operator operator
 122                  :identity-with-one-argument ioa
 123                  :definition-source method
 124                  :documentation doc))
 125
 126 (defmethod compute-effective-method ((generic-function generic-function)
 127                                      (combin short-method-combination)
 128                                      applicable-methods)
 129   (let ((type (method-combination-type combin))
 130         (operator (short-combination-operator combin))
 131         (ioa (short-combination-identity-with-one-argument combin))
 132         (order (car (method-combination-options combin)))
 133         (around ())
 134         (primary ()))
 135     (flet ((invalid (gf combin m)
 136              (return-from compute-effective-method
 137                `(%invalid-qualifiers ',gf ',combin ',m))))
 138       (dolist (m applicable-methods)
 139         (let ((qualifiers (method-qualifiers m)))
 140           (cond ((null qualifiers) (invalid generic-function combin m))
 141                 ((cdr qualifiers) (invalid generic-function combin m))
 142                 ((eq (car qualifiers) :around)
 143                  (push m around))
 144                 ((eq (car qualifiers) type)
 145                  (push m primary))
 146                 (t (invalid generic-function combin m))))))
 147     (setq around (nreverse around))
 148     (ecase order
 149       (:most-specific-last) ; nothing to be done, already in correct order
 150       (:most-specific-first
 151        (setq primary (nreverse primary))))
 152     (let ((main-method
 153             (if (and (null (cdr primary))
 154                      (not (null ioa)))
 155                 `(call-method ,(car primary) ())
 156                 `(,operator ,@(mapcar (lambda (m) `(call-method ,m ()))
 157                                       primary)))))
 158       (cond ((null primary)
 159              ;; As of sbcl-0.8.0.80 we don't seem to need to need
 160              ;; to do anything messy like
 161              ;;        `(APPLY (FUNCTION (IF AROUND
 162              ;;                              'NO-PRIMARY-METHOD
 163              ;;                              'NO-APPLICABLE-METHOD)
 164              ;;                           ',GENERIC-FUNCTION
 165              ;;                           .ARGS.)
 166              ;; here because (for reasons I don't understand at the
 167              ;; moment -- WHN) control will never reach here if there
 168              ;; are no applicable methods, but instead end up
 169              ;; in NO-APPLICABLE-METHODS first.
 170              ;;
 171              ;; FIXME: The way that we arrange for .ARGS. to be bound
 172              ;; here seems weird. We rely on EXPAND-EFFECTIVE-METHOD-FUNCTION
 173              ;; recognizing any form whose operator is %NO-PRIMARY-METHOD
 174              ;; as magical, and carefully surrounding it with a
 175              ;; LAMBDA form which binds .ARGS. But...
 176              ;;   1. That seems fragile, because the magicalness of
 177              ;;      %NO-PRIMARY-METHOD forms is scattered around
 178              ;;      the system. So it could easily be broken by
 179              ;;      locally-plausible maintenance changes like,
 180              ;;      e.g., using the APPLY expression above.
 181              ;;   2. That seems buggy w.r.t. to MOPpish tricks in
 182              ;;      user code, e.g.
 183              ;;         (DEFMETHOD COMPUTE-EFFECTIVE-METHOD :AROUND (...)
 184              ;;           `(PROGN ,(CALL-NEXT-METHOD) (INCF *MY-CTR*)))
 185              `(%no-primary-method ',generic-function .args.))
 186             ((null around) main-method)
 187             (t
 188              `(call-method ,(car around)
 189                            (,@(cdr around) (make-method ,main-method))))))))
 190
 191 (defmethod invalid-qualifiers ((gf generic-function)
 192                                (combin short-method-combination)
 193                                method)
 194   (let ((qualifiers (method-qualifiers method))
 195         (type (method-combination-type combin)))
 196     (let ((why (cond
 197                  ((null qualifiers) "has no qualifiers")
 198                  ((cdr qualifiers) "has too many qualifiers")
 199                  (t (aver (and (neq (car qualifiers) type)
 200                                (neq (car qualifiers) :around)))
 201                     "has an invalid qualifier"))))
 202       (invalid-method-error
 203        method
 204        "The method ~S on ~S ~A.~%~
 205         The method combination type ~S was defined with the~%~
 206         short form of DEFINE-METHOD-COMBINATION and so requires~%~
 207         all methods have either the single qualifier ~S or the~%~
 208         single qualifier :AROUND."
 209        method gf why type type))))
 210 \f
 211 ;;;; long method combinations
 212
 213 (defun expand-long-defcombin (form)
 214   (let ((type (cadr form))
 215         (lambda-list (caddr form))
 216         (method-group-specifiers (cadddr form))
 217         (body (cddddr form))
 218         (args-option ())
 219         (gf-var nil))
 220     (when (and (consp (car body)) (eq (caar body) :arguments))
 221       (setq args-option (cdr (pop body))))
 222     (when (and (consp (car body)) (eq (caar body) :generic-function))
 223       (setq gf-var (cadr (pop body))))
 224     (multiple-value-bind (documentation function)
 225         (make-long-method-combination-function
 226           type lambda-list method-group-specifiers args-option gf-var
 227           body)
 228       `(load-long-defcombin ',type ',documentation #',function
 229                             ',args-option))))
 230
 231 (defvar *long-method-combination-functions* (make-hash-table :test 'eq))
 232
 233 (defun load-long-defcombin (type doc function args-lambda-list)
 234   (let* ((specializers
 235            (list (find-class 'generic-function)
 236                  (intern-eql-specializer type)
 237                  *the-class-t*))
 238          (old-method
 239            (get-method #'find-method-combination () specializers nil))
 240          (new-method
 241            (make-instance 'standard-method
 242              :qualifiers ()
 243              :specializers specializers
 244              :lambda-list '(generic-function type options)
 245              :function (lambda (args nms &rest cm-args)
 246                          (declare (ignore nms cm-args))
 247                          (apply
 248                           (lambda (generic-function type options)
 249                             (declare (ignore generic-function))
 250                             (make-instance 'long-method-combination
 251                                            :type type
 252                                            :options options
 253                                            :args-lambda-list args-lambda-list
 254                                            :documentation doc))
 255                           args))
 256              :definition-source `((define-method-combination ,type)
 257                                   ,*load-pathname*))))
 258     (setf (gethash type *long-method-combination-functions*) function)
 259     (when old-method (remove-method #'find-method-combination old-method))
 260     (add-method #'find-method-combination new-method)
 261     (setf (random-documentation type 'method-combination) doc)
 262     type))
 263
 264 (defmethod compute-effective-method ((generic-function generic-function)
 265                                      (combin long-method-combination)
 266                                      applicable-methods)
 267   (funcall (gethash (method-combination-type combin)
 268                     *long-method-combination-functions*)
 269            generic-function
 270            combin
 271            applicable-methods))
 272
 273 (defun make-long-method-combination-function
 274        (type ll method-group-specifiers args-option gf-var body)
 275   (declare (ignore type))
 276   (multiple-value-bind (real-body declarations documentation)
 277       (parse-body body)
 278     (let ((wrapped-body
 279             (wrap-method-group-specifier-bindings method-group-specifiers
 280                                                   declarations
 281                                                   real-body)))
 282       (when gf-var
 283         (push `(,gf-var .generic-function.) (cadr wrapped-body)))
 284
 285       (when args-option
 286         (setq wrapped-body (deal-with-args-option wrapped-body args-option)))
 287
 288       (when ll
 289         (setq wrapped-body
 290               `(apply #'(lambda ,ll ,wrapped-body)
 291                       (method-combination-options .method-combination.))))
 292
 293       (values
 294         documentation
 295         `(lambda (.generic-function. .method-combination. .applicable-methods.)
 296            (declare (ignorable .generic-function.
 297                      .method-combination. .applicable-methods.))
 298            (block .long-method-combination-function. ,wrapped-body))))))
 299
 300 (define-condition long-method-combination-error
 301     (reference-condition simple-error)
 302   ()
 303   (:default-initargs
 304       :references (list '(:ansi-cl :macro define-method-combination))))
 305
 306 ;;; NOTE:
 307 ;;;
 308 ;;; The semantics of long form method combination in the presence of
 309 ;;; multiple methods with the same specializers in the same method
 310 ;;; group are unclear by the spec: a portion of the standard implies
 311 ;;; that an error should be signalled, and another is more lenient.
 312 ;;;
 313 ;;; It is reasonable to allow a single method group of * to bypass all
 314 ;;; rules, as this is explicitly stated in the standard.
 315
 316 (defun group-cond-clause (name tests specializer-cache star-only)
 317   (let ((maybe-error-clause
 318          (if star-only
 319              `(setq ,specializer-cache .specializers.)
 320              `(if (and (equal ,specializer-cache .specializers.)
 321                        (not (null .specializers.)))
 322                   (return-from .long-method-combination-function.
 323                     '(error 'long-method-combination-error
 324                       :format-control "More than one method of type ~S ~
 325                                        with the same specializers."
 326                       :format-arguments (list ',name)))
 327                   (setq ,specializer-cache .specializers.)))))
 328     `((or ,@tests)
 329       ,maybe-error-clause
 330       (push .method. ,name))))
 331
 332 (defun wrap-method-group-specifier-bindings
 333     (method-group-specifiers declarations real-body)
 334   (let (names specializer-caches cond-clauses required-checks order-cleanups)
 335     (let ((nspecifiers (length method-group-specifiers)))
 336       (dolist (method-group-specifier method-group-specifiers)
 337         (multiple-value-bind (name tests description order required)
 338             (parse-method-group-specifier method-group-specifier)
 339           (declare (ignore description))
 340           (let ((specializer-cache (gensym)))
 341             (push name names)
 342             (push specializer-cache specializer-caches)
 343             (push (group-cond-clause name tests specializer-cache
 344                                      (and (eq (cadr method-group-specifier) '*)
 345                                           (= nspecifiers 1)))
 346                   cond-clauses)
 347             (when required
 348               (push `(when (null ,name)
 349                       (return-from .long-method-combination-function.
 350                         '(error 'long-method-combination-error
 351                           :format-control "No ~S methods."
 352                           :format-arguments (list ',name))))
 353                     required-checks))
 354             (loop (unless (and (constantp order)
 355                                (neq order (setq order (eval order))))
 356                     (return t)))
 357             (push (cond ((eq order :most-specific-first)
 358                          `(setq ,name (nreverse ,name)))
 359                         ((eq order :most-specific-last) ())
 360                         (t
 361                          `(ecase ,order
 362                            (:most-specific-first
 363                             (setq ,name (nreverse ,name)))
 364                            (:most-specific-last))))
 365                   order-cleanups))))
 366       `(let (,@(nreverse names) ,@(nreverse specializer-caches))
 367         ,@declarations
 368         (dolist (.method. .applicable-methods.)
 369           (let ((.qualifiers. (method-qualifiers .method.))
 370                 (.specializers. (method-specializers .method.)))
 371             (declare (ignorable .qualifiers. .specializers.))
 372             (cond ,@(nreverse cond-clauses))))
 373         ,@(nreverse required-checks)
 374         ,@(nreverse order-cleanups)
 375         ,@real-body))))
 376
 377 (defun parse-method-group-specifier (method-group-specifier)
 378   ;;(declare (values name tests description order required))
 379   (let* ((name (pop method-group-specifier))
 380          (patterns ())
 381          (tests
 382            (let (collect)
 383              (block collect-tests
 384                (loop
 385                  (if (or (null method-group-specifier)
 386                          (memq (car method-group-specifier)
 387                                '(:description :order :required)))
 388                      (return-from collect-tests t)
 389                      (let ((pattern (pop method-group-specifier)))
 390                        (push pattern patterns)
 391                        (push (parse-qualifier-pattern name pattern)
 392                              collect)))))
 393              (nreverse collect))))
 394     (values name
 395             tests
 396             (getf method-group-specifier :description
 397                   (make-default-method-group-description patterns))
 398             (getf method-group-specifier :order :most-specific-first)
 399             (getf method-group-specifier :required nil))))
 400
 401 (defun parse-qualifier-pattern (name pattern)
 402   (cond ((eq pattern '()) `(null .qualifiers.))
 403         ((eq pattern '*) t)
 404         ((symbolp pattern) `(,pattern .qualifiers.))
 405         ((listp pattern) `(qualifier-check-runtime ',pattern .qualifiers.))
 406         (t (error "In the method group specifier ~S,~%~
 407                    ~S isn't a valid qualifier pattern."
 408                   name pattern))))
 409
 410 (defun qualifier-check-runtime (pattern qualifiers)
 411   (loop (cond ((and (null pattern) (null qualifiers))
 412                (return t))
 413               ((eq pattern '*) (return t))
 414               ((and pattern qualifiers (eq (car pattern) (car qualifiers)))
 415                (pop pattern)
 416                (pop qualifiers))
 417               (t (return nil)))))
 418
 419 (defun make-default-method-group-description (patterns)
 420   (if (cdr patterns)
 421       (format nil
 422               "methods matching one of the patterns: ~{~S, ~} ~S"
 423               (butlast patterns) (car (last patterns)))
 424       (format nil
 425               "methods matching the pattern: ~S"
 426               (car patterns))))
 427
 428 ;;; This baby is a complete mess. I can't believe we put it in this
 429 ;;; way. No doubt this is a large part of what drives MLY crazy.
 430 ;;;
 431 ;;; At runtime (when the effective-method is run), we bind an intercept
 432 ;;; lambda-list to the arguments to the generic function.
 433 ;;;
 434 ;;; At compute-effective-method time, the symbols in the :arguments
 435 ;;; option are bound to the symbols in the intercept lambda list.
 436 ;;;
 437 ;;; FIXME: in here we have not one but two mini-copies of a weird
 438 ;;; hybrid of PARSE-LAMBDA-LIST and PARSE-DEFMACRO-LAMBDA-LIST.
 439 (defun deal-with-args-option (wrapped-body args-lambda-list)
 440   (let ((intercept-rebindings
 441          (let (rebindings)
 442            (dolist (arg args-lambda-list (nreverse rebindings))
 443              (unless (member arg lambda-list-keywords)
 444                (typecase arg
 445                  (symbol (push `(,arg ',arg) rebindings))
 446                  (cons
 447                   (unless (symbolp (car arg))
 448                     (error "invalid lambda-list specifier: ~S." arg))
 449                   (push `(,(car arg) ',(car arg)) rebindings))
 450                  (t (error "invalid lambda-list-specifier: ~S." arg)))))))
 451         (nreq 0)
 452         (nopt 0)
 453         (whole nil))
 454     ;; Count the number of required and optional parameters in
 455     ;; ARGS-LAMBDA-LIST into NREQ and NOPT, and set WHOLE to the
 456     ;; name of a &WHOLE parameter, if any.
 457     (when (member '&whole (rest args-lambda-list))
 458       (error 'simple-program-error
 459              :format-control "~@<The value of the :ARGUMENTS option of ~
 460                 DEFINE-METHOD-COMBINATION is~2I~_~S,~I~_but &WHOLE may ~
 461                 only appear first in the lambda list.~:>"
 462              :format-arguments (list args-lambda-list)))
 463     (loop with state = 'required
 464           for arg in args-lambda-list do
 465             (if (memq arg lambda-list-keywords)
 466                 (setq state arg)
 467                 (case state
 468                   (required (incf nreq))
 469                   (&optional (incf nopt))
 470                   (&whole (setq whole arg state 'required)))))
 471     ;; This assumes that the head of WRAPPED-BODY is a let, and it
 472     ;; injects let-bindings of the form (ARG 'SYM) for all variables
 473     ;; of the argument-lambda-list; SYM is a gensym.
 474     (aver (memq (first wrapped-body) '(let let*)))
 475     (setf (second wrapped-body)
 476           (append intercept-rebindings (second wrapped-body)))
 477     ;; Be sure to fill out the args lambda list so that it can be too
 478     ;; short if it wants to.
 479     (unless (or (memq '&rest args-lambda-list)
 480                 (memq '&allow-other-keys args-lambda-list))
 481       (let ((aux (memq '&aux args-lambda-list)))
 482         (setq args-lambda-list
 483               (append (ldiff args-lambda-list aux)
 484                       (if (memq '&key args-lambda-list)
 485                           '(&allow-other-keys)
 486                           '(&rest .ignore.))
 487                       aux))))
 488     ;; .GENERIC-FUNCTION. is bound to the generic function in the
 489     ;; method combination function, and .GF-ARGS* is bound to the
 490     ;; generic function arguments in effective method functions
 491     ;; created for generic functions having a method combination that
 492     ;; uses :ARGUMENTS.
 493     ;;
 494     ;; The DESTRUCTURING-BIND binds the parameters of the
 495     ;; ARGS-LAMBDA-LIST to actual generic function arguments.  Because
 496     ;; ARGS-LAMBDA-LIST may be shorter or longer than the generic
 497     ;; function's lambda list, which is only known at run time, this
 498     ;; destructuring has to be done on a slighly modified list of
 499     ;; actual arguments, from which values might be stripped or added.
 500     ;;
 501     ;; Using one of the variable names in the body inserts a symbol
 502     ;; into the effective method, and running the effective method
 503     ;; produces the value of actual argument that is bound to the
 504     ;; symbol.
 505     `(let ((inner-result. ,wrapped-body)
 506            (gf-lambda-list (generic-function-lambda-list .generic-function.)))
 507        `(destructuring-bind ,',args-lambda-list
 508             (frob-combined-method-args
 509              .gf-args. ',gf-lambda-list
 510              ,',nreq ,',nopt)
 511           ,,(when (memq '.ignore. args-lambda-list)
 512               ''(declare (ignore .ignore.)))
 513           ;; If there is a &WHOLE in the args-lambda-list, let
 514           ;; it result in the actual arguments of the generic-function
 515           ;; not the frobbed list.
 516           ,,(when whole
 517               ``(setq ,',whole .gf-args.))
 518           ,inner-result.))))
 519
 520 ;;; Partition VALUES into three sections: required, optional, and the
 521 ;;; rest, according to required, optional, and other parameters in
 522 ;;; LAMBDA-LIST.  Make the required and optional sections NREQ and
 523 ;;; NOPT elements long by discarding values or adding NILs.  Value is
 524 ;;; the concatenated list of required and optional sections, and what
 525 ;;; is left as rest from VALUES.
 526 (defun frob-combined-method-args (values lambda-list nreq nopt)
 527   (loop with section = 'required
 528         for arg in lambda-list
 529         if (memq arg lambda-list-keywords) do
 530           (setq section arg)
 531           (unless (eq section '&optional)
 532             (loop-finish))
 533         else if (eq section 'required)
 534           count t into nr
 535           and collect (pop values) into required
 536         else if (eq section '&optional)
 537           count t into no
 538           and collect (pop values) into optional
 539         finally
 540           (flet ((frob (list n m)
 541                    (cond ((> n m) (butlast list (- n m)))
 542                          ((< n m) (nconc list (make-list (- m n))))
 543                          (t list))))
 544             (return (nconc (frob required nr nreq)
 545                            (frob optional no nopt)
 546                            values)))))
 547