src/pcl/defs.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; (These are left over from the days when PCL was an add-on package
  27 ;;; for a pre-CLOS Common Lisp. They shouldn't happen in a normal
  28 ;;; build, of course, but they might happen if someone is experimenting
  29 ;;; and debugging, and it's probably worth complaining if they do,
  30 ;;; so we've left 'em in.)
  31 (when (eq *boot-state* 'complete)
  32   (error "Trying to load (or compile) PCL in an environment in which it~%~
  33           has already been loaded. This doesn't work, you will have to~%~
  34           get a fresh lisp (reboot) and then load PCL."))
  35 (when *boot-state*
  36   (cerror "Try loading (or compiling) PCL anyways."
  37           "Trying to load (or compile) PCL in an environment in which it~%~
  38            has already been partially loaded. This may not work, you may~%~
  39            need to get a fresh lisp (reboot) and then load PCL."))
  40 \f
  41 #-sb-fluid (declaim (inline gdefinition))
  42 (defun gdefinition (spec)
  43   ;; This is null layer right now, but once FDEFINITION stops bypasssing
  44   ;; fwrappers/encapsulations we can do that here.
  45   (fdefinition spec))
  46
  47 (defun (setf gdefinition) (new-value spec)
  48   ;; This is almost a null layer right now, but once (SETF
  49   ;; FDEFINITION) stops bypasssing fwrappers/encapsulations we can do
  50   ;; that here.
  51   (sb-c::note-name-defined spec :function) ; FIXME: do we need this? Why?
  52   (setf (fdefinition spec) new-value))
  53 \f
  54 ;;;; type specifier hackery
  55
  56 ;;; internal to this file
  57 (defun coerce-to-class (class &optional make-forward-referenced-class-p)
  58   (if (symbolp class)
  59       (or (find-class class (not make-forward-referenced-class-p))
  60           (ensure-class class))
  61       class))
  62
  63 ;;; interface
  64 (defun specializer-from-type (type &aux args)
  65   (when (consp type)
  66     (setq args (cdr type) type (car type)))
  67   (cond ((symbolp type)
  68          (or (and (null args) (find-class type))
  69              (ecase type
  70                (class    (coerce-to-class (car args)))
  71                (prototype (make-instance 'class-prototype-specializer
  72                                          :object (coerce-to-class (car args))))
  73                (class-eq (class-eq-specializer (coerce-to-class (car args))))
  74                (eql      (intern-eql-specializer (car args))))))
  75         ;; FIXME: do we still need this?
  76         ((and (null args) (typep type 'classoid))
  77          (or (classoid-pcl-class type)
  78              (ensure-non-standard-class (classoid-name type))))
  79         ((specializerp type) type)))
  80
  81 ;;; interface
  82 (defun type-from-specializer (specl)
  83   (cond ((eq specl t)
  84          t)
  85         ((consp specl)
  86          (unless (member (car specl) '(class prototype class-eq eql))
  87            (error "~S is not a legal specializer type." specl))
  88          specl)
  89         ((progn
  90            (when (symbolp specl)
  91              ;;maybe (or (find-class specl nil) (ensure-class specl)) instead?
  92              (setq specl (find-class specl)))
  93            (or (not (eq *boot-state* 'complete))
  94                (specializerp specl)))
  95          (specializer-type specl))
  96         (t
  97          (error "~S is neither a type nor a specializer." specl))))
  98
  99 (defun type-class (type)
 100   (declare (special *the-class-t*))
 101   (setq type (type-from-specializer type))
 102   (if (atom type)
 103       (if (eq type t)
 104           *the-class-t*
 105           (error "bad argument to TYPE-CLASS"))
 106       (case (car type)
 107         (eql (class-of (cadr type)))
 108         (prototype (class-of (cadr type))) ;?
 109         (class-eq (cadr type))
 110         (class (cadr type)))))
 111
 112 (defun class-eq-type (class)
 113   (specializer-type (class-eq-specializer class)))
 114
 115 ;;; internal to this file..
 116 ;;;
 117 ;;; These functions are a pale imitation of their namesake. They accept
 118 ;;; class objects or types where they should.
 119 (defun *normalize-type (type)
 120   (cond ((consp type)
 121          (if (member (car type) '(not and or))
 122              `(,(car type) ,@(mapcar #'*normalize-type (cdr type)))
 123              (if (null (cdr type))
 124                  (*normalize-type (car type))
 125                  type)))
 126         ((symbolp type)
 127          (let ((class (find-class type nil)))
 128            (if class
 129                (let ((type (specializer-type class)))
 130                  (if (listp type) type `(,type)))
 131                `(,type))))
 132         ((or (not (eq *boot-state* 'complete))
 133              (specializerp type))
 134          (specializer-type type))
 135         (t
 136          (error "~S is not a type." type))))
 137
 138 ;;; internal to this file...
 139 (defun convert-to-system-type (type)
 140   (case (car type)
 141     ((not and or) `(,(car type) ,@(mapcar #'convert-to-system-type
 142                                           (cdr type))))
 143     ((class class-eq) ; class-eq is impossible to do right
 144      (layout-classoid (class-wrapper (cadr type))))
 145     (eql type)
 146     (t (if (null (cdr type))
 147            (car type)
 148            type))))
 149
 150 ;;; Writing the missing NOT and AND clauses will improve the quality
 151 ;;; of code generated by GENERATE-DISCRIMINATION-NET, but calling
 152 ;;; SUBTYPEP in place of just returning (VALUES NIL NIL) can be very
 153 ;;; slow. *SUBTYPEP is used by PCL itself, and must be fast.
 154 ;;;
 155 ;;; FIXME: SB-KERNEL has fast-and-not-quite-precise type code for use
 156 ;;; in the compiler. Could we share some of it here?
 157 (defun *subtypep (type1 type2)
 158   (if (equal type1 type2)
 159       (values t t)
 160       (if (eq *boot-state* 'early)
 161           (values (eq type1 type2) t)
 162           (let ((*in-precompute-effective-methods-p* t))
 163             (declare (special *in-precompute-effective-methods-p*))
 164             ;; FIXME: *IN-PRECOMPUTE-EFFECTIVE-METHODS-P* is not a
 165             ;; good name. It changes the way
 166             ;; CLASS-APPLICABLE-USING-CLASS-P works.
 167             (setq type1 (*normalize-type type1))
 168             (setq type2 (*normalize-type type2))
 169             (case (car type2)
 170               (not
 171                (values nil nil)) ; XXX We should improve this.
 172               (and
 173                (values nil nil)) ; XXX We should improve this.
 174               ((eql wrapper-eq class-eq class)
 175                (multiple-value-bind (app-p maybe-app-p)
 176                    (specializer-applicable-using-type-p type2 type1)
 177                  (values app-p (or app-p (not maybe-app-p)))))
 178               (t
 179                (subtypep (convert-to-system-type type1)
 180                          (convert-to-system-type type2))))))))
 181 \f
 182 (defvar *built-in-class-symbols* ())
 183 (defvar *built-in-wrapper-symbols* ())
 184
 185 (defun get-built-in-class-symbol (class-name)
 186   (or (cadr (assq class-name *built-in-class-symbols*))
 187       (let ((symbol (make-class-symbol class-name)))
 188         (push (list class-name symbol) *built-in-class-symbols*)
 189         symbol)))
 190
 191 (defun get-built-in-wrapper-symbol (class-name)
 192   (or (cadr (assq class-name *built-in-wrapper-symbols*))
 193       (let ((symbol (make-wrapper-symbol class-name)))
 194         (push (list class-name symbol) *built-in-wrapper-symbols*)
 195         symbol)))
 196 \f
 197 (pushnew '%class *var-declarations*)
 198 (pushnew '%variable-rebinding *var-declarations*)
 199
 200 (defun variable-class (var env)
 201   (caddr (var-declaration 'class var env)))
 202
 203 (defvar *standard-method-combination*)
 204 \f
 205 (defun plist-value (object name)
 206   (getf (object-plist object) name))
 207
 208 (defun (setf plist-value) (new-value object name)
 209   (if new-value
 210       (setf (getf (object-plist object) name) new-value)
 211       (progn
 212         (remf (object-plist object) name)
 213         nil)))
 214 \f
 215 ;;;; built-in classes
 216
 217 ;;; Grovel over SB-KERNEL::*BUILT-IN-CLASSES* in order to set
 218 ;;; SB-PCL:*BUILT-IN-CLASSES*.
 219 (/show "about to set up SB-PCL::*BUILT-IN-CLASSES*")
 220 (defvar *built-in-classes*
 221   (labels ((direct-supers (class)
 222              (/noshow "entering DIRECT-SUPERS" (classoid-name class))
 223              (if (typep class 'built-in-classoid)
 224                  (built-in-classoid-direct-superclasses class)
 225                  (let ((inherits (layout-inherits
 226                                   (classoid-layout class))))
 227                    (/noshow inherits)
 228                    (list (svref inherits (1- (length inherits)))))))
 229            (direct-subs (class)
 230              (/noshow "entering DIRECT-SUBS" (classoid-name class))
 231              (collect ((res))
 232                (let ((subs (classoid-subclasses class)))
 233                  (/noshow subs)
 234                  (when subs
 235                    (dohash (sub v subs)
 236                      (declare (ignore v))
 237                      (/noshow sub)
 238                      (when (member class (direct-supers sub))
 239                        (res sub)))))
 240                (res))))
 241     (mapcar (lambda (kernel-bic-entry)
 242               (/noshow "setting up" kernel-bic-entry)
 243               (let* ((name (car kernel-bic-entry))
 244                      (class (find-classoid name))
 245                      (prototype-form
 246                       (getf (cdr kernel-bic-entry) :prototype-form)))
 247                 (/noshow name class)
 248                 `(,name
 249                   ,(mapcar #'classoid-name (direct-supers class))
 250                   ,(mapcar #'classoid-name (direct-subs class))
 251                   ,(map 'list
 252                         (lambda (x)
 253                           (classoid-name
 254                            (layout-classoid x)))
 255                         (reverse
 256                          (layout-inherits
 257                           (classoid-layout class))))
 258                   ,(if prototype-form
 259                        (eval prototype-form)
 260                        ;; This is the default prototype value which
 261                        ;; was used, without explanation, by the CMU CL
 262                        ;; code we're derived from. Evidently it's safe
 263                        ;; in all relevant cases.
 264                        42))))
 265             (remove-if (lambda (kernel-bic-entry)
 266                          (member (first kernel-bic-entry)
 267                                  ;; I'm not sure why these are removed from
 268                                  ;; the list, but that's what the original
 269                                  ;; CMU CL code did. -- WHN 20000715
 270                                  '(t function stream
 271                                      file-stream string-stream)))
 272                        sb-kernel::*built-in-classes*))))
 273 (/noshow "done setting up SB-PCL::*BUILT-IN-CLASSES*")
 274 \f
 275 ;;;; the classes that define the kernel of the metabraid
 276
 277 (defclass t () ()
 278   (:metaclass built-in-class))
 279
 280 (defclass function (t) ()
 281   (:metaclass built-in-class))
 282
 283 (defclass stream (t) ()
 284   (:metaclass built-in-class))
 285
 286 (defclass file-stream (stream) ()
 287   (:metaclass built-in-class))
 288
 289 (defclass string-stream (stream) ()
 290   (:metaclass built-in-class))
 291
 292 (defclass slot-object (t) ()
 293   (:metaclass slot-class))
 294
 295 (defclass condition (slot-object) ()
 296   (:metaclass condition-class))
 297
 298 (defclass structure-object (slot-object) ()
 299   (:metaclass structure-class))
 300
 301 (defstruct (dead-beef-structure-object
 302             (:constructor |STRUCTURE-OBJECT class constructor|)
 303             (:copier nil)))
 304
 305 (defclass standard-object (slot-object) ())
 306
 307 (defclass funcallable-standard-object (function standard-object)
 308   ()
 309   (:metaclass funcallable-standard-class))
 310
 311 (defclass metaobject (standard-object) ())
 312
 313 (defclass generic-function (dependent-update-mixin
 314                             definition-source-mixin
 315                             metaobject
 316                             funcallable-standard-object)
 317   ((%documentation :initform nil :initarg :documentation)
 318    ;; We need to make a distinction between the methods initially set
 319    ;; up by :METHOD options to DEFGENERIC and the ones set up later by
 320    ;; DEFMETHOD, because ANSI specifies that executing DEFGENERIC on
 321    ;; an already-DEFGENERICed function clears the methods set by the
 322    ;; previous DEFGENERIC, but not methods set by DEFMETHOD. (Making
 323    ;; this distinction seems a little kludgy, but it has the positive
 324    ;; effect of making it so that loading a file a.lisp containing
 325    ;; DEFGENERIC, then loading a second file b.lisp containing
 326    ;; DEFMETHOD, then modifying and reloading a.lisp and/or b.lisp
 327    ;; tends to leave the generic function in a state consistent with
 328    ;; the most-recently-loaded state of a.lisp and b.lisp.)
 329    (initial-methods :initform ()
 330                     :accessor generic-function-initial-methods))
 331   (:metaclass funcallable-standard-class))
 332
 333 (defclass standard-generic-function (generic-function)
 334   ((name
 335     :initform nil
 336     :initarg :name
 337     :reader generic-function-name)
 338    (methods
 339     :initform ()
 340     :accessor generic-function-methods
 341     :type list)
 342    (method-class
 343     :initarg :method-class
 344     :accessor generic-function-method-class)
 345    (%method-combination
 346     :initarg :method-combination
 347     :accessor generic-function-method-combination)
 348    (declarations
 349     ;; KLUDGE: AMOP specifies :DECLARATIONS, while ANSI specifies
 350     ;; :DECLARE.  Allow either (but FIXME: maybe a note or a warning
 351     ;; might be appropriate).
 352     :initarg :declarations
 353     :initarg :declare
 354     :initform ()
 355     :accessor generic-function-declarations)
 356    (arg-info
 357     :initform (make-arg-info)
 358     :reader gf-arg-info)
 359    (dfun-state
 360     :initform ()
 361     :accessor gf-dfun-state))
 362   (:metaclass funcallable-standard-class)
 363   (:default-initargs :method-class *the-class-standard-method*
 364                      :method-combination *standard-method-combination*))
 365
 366 (defclass method (metaobject) ())
 367
 368 (defclass standard-method (plist-mixin definition-source-mixin method)
 369   ((%generic-function
 370     :initform nil
 371     :accessor method-generic-function)
 372    (qualifiers
 373     :initform ()
 374     :initarg  :qualifiers
 375     :reader method-qualifiers)
 376    (specializers
 377     :initform ()
 378     :initarg  :specializers
 379     :reader method-specializers)
 380    (lambda-list
 381     :initform ()
 382     :initarg  :lambda-list
 383     :reader method-lambda-list)
 384    (%function :initform nil :initarg :function :reader method-function)
 385    (%documentation :initform nil :initarg :documentation)))
 386
 387 (defclass accessor-method (standard-method)
 388   ((slot-name :initform nil :initarg :slot-name
 389               :reader accessor-method-slot-name)))
 390
 391 (defclass standard-accessor-method (accessor-method)
 392   ((%slot-definition :initform nil :initarg :slot-definition
 393                      :reader accessor-method-slot-definition)))
 394
 395 (defclass standard-reader-method (standard-accessor-method) ())
 396 (defclass standard-writer-method (standard-accessor-method) ())
 397 ;;; an extension, apparently.
 398 (defclass standard-boundp-method (standard-accessor-method) ())
 399
 400 ;;; for (SLOT-VALUE X 'FOO) / ACCESSOR-SLOT-VALUE optimization, which
 401 ;;; can't be STANDARD-READER-METHOD because there is no associated
 402 ;;; slot definition.
 403 (defclass global-reader-method (accessor-method) ())
 404 (defclass global-writer-method (accessor-method) ())
 405 (defclass global-boundp-method (accessor-method) ())
 406
 407 (defclass method-combination (metaobject)
 408   ((%documentation :initform nil :initarg :documentation)))
 409
 410 (defclass standard-method-combination (definition-source-mixin
 411                                        method-combination)
 412   ((type-name
 413     :reader method-combination-type-name
 414     :initarg :type-name)
 415    (options
 416     :reader method-combination-options
 417     :initarg :options)))
 418
 419 (defclass long-method-combination (standard-method-combination)
 420   ((function
 421     :initarg :function
 422     :reader long-method-combination-function)
 423    (args-lambda-list
 424     :initarg :args-lambda-list
 425     :reader long-method-combination-args-lambda-list)))
 426
 427 (defclass short-method-combination (standard-method-combination)
 428   ((operator
 429     :reader short-combination-operator
 430     :initarg :operator)
 431    (identity-with-one-argument
 432     :reader short-combination-identity-with-one-argument
 433     :initarg :identity-with-one-argument)))
 434
 435 (defclass slot-definition (metaobject)
 436   ((name
 437     :initform nil
 438     :initarg :name
 439     :accessor slot-definition-name)
 440    (initform
 441     :initform nil
 442     :initarg :initform
 443     :accessor slot-definition-initform)
 444    (initfunction
 445     :initform nil
 446     :initarg :initfunction
 447     :accessor slot-definition-initfunction)
 448    (readers
 449     :initform nil
 450     :initarg :readers
 451     :accessor slot-definition-readers)
 452    (writers
 453     :initform nil
 454     :initarg :writers
 455     :accessor slot-definition-writers)
 456    (initargs
 457     :initform nil
 458     :initarg :initargs
 459     :accessor slot-definition-initargs)
 460    (%type :initform t :initarg :type :accessor slot-definition-type)
 461    (%type-check-function :initform nil
 462                          :initarg type-check-function
 463                          :accessor slot-definition-type-check-function)
 464    (%documentation
 465     :initform nil :initarg :documentation
 466     ;; KLUDGE: we need a reader for bootstrapping purposes, in
 467     ;; COMPUTE-EFFECTIVE-SLOT-DEFINITION-INITARGS.
 468     :reader %slot-definition-documentation)
 469    (%class :initform nil :initarg :class :accessor slot-definition-class)))
 470
 471 (defclass standard-slot-definition (slot-definition)
 472   ((allocation
 473     :initform :instance
 474     :initarg :allocation
 475     :accessor slot-definition-allocation)
 476    (allocation-class
 477     :initform nil
 478     :initarg :allocation-class
 479     :accessor slot-definition-allocation-class)))
 480
 481 (defclass condition-slot-definition (slot-definition)
 482   ((allocation
 483     :initform :instance
 484     :initarg :allocation
 485     :accessor slot-definition-allocation)
 486    (allocation-class
 487     :initform nil
 488     :initarg :allocation-class
 489     :accessor slot-definition-allocation-class)))
 490
 491 (defclass structure-slot-definition (slot-definition)
 492   ((defstruct-accessor-symbol
 493      :initform nil
 494      :initarg :defstruct-accessor-symbol
 495      :accessor slot-definition-defstruct-accessor-symbol)
 496    (internal-reader-function
 497      :initform nil
 498      :initarg :internal-reader-function
 499      :accessor slot-definition-internal-reader-function)
 500    (internal-writer-function
 501      :initform nil
 502      :initarg :internal-writer-function
 503      :accessor slot-definition-internal-writer-function)))
 504
 505 (defclass direct-slot-definition (slot-definition)
 506   ())
 507
 508 (defclass effective-slot-definition (slot-definition)
 509   ((reader-function ; (lambda (object) ...)
 510     :accessor slot-definition-reader-function)
 511    (writer-function ; (lambda (new-value object) ...)
 512     :accessor slot-definition-writer-function)
 513    (boundp-function ; (lambda (object) ...)
 514     :accessor slot-definition-boundp-function)
 515    (accessor-flags
 516     :initform 0)))
 517
 518 (defclass standard-direct-slot-definition (standard-slot-definition
 519                                            direct-slot-definition)
 520   ())
 521
 522 (defclass standard-effective-slot-definition (standard-slot-definition
 523                                               effective-slot-definition)
 524   ((location ; nil, a fixnum, a cons: (slot-name . value)
 525     :initform nil
 526     :accessor slot-definition-location)))
 527
 528 (defclass condition-direct-slot-definition (condition-slot-definition
 529                                             direct-slot-definition)
 530   ())
 531
 532 (defclass condition-effective-slot-definition (condition-slot-definition
 533                                                effective-slot-definition)
 534   ())
 535
 536 (defclass structure-direct-slot-definition (structure-slot-definition
 537                                             direct-slot-definition)
 538   ())
 539
 540 (defclass structure-effective-slot-definition (structure-slot-definition
 541                                                effective-slot-definition)
 542   ())
 543
 544 (defclass specializer (metaobject)
 545   ;; KLUDGE: in sbcl-0.9.10.2 this was renamed from TYPE, which was an
 546   ;; external symbol of the CL package and hence potentially collides
 547   ;; with user code.  Renaming this to %TYPE, however, is the coward's
 548   ;; way out, because the objects that PCL puts in this slot aren't
 549   ;; (quite) types: they are closer to kinds of specializer.  However,
 550   ;; the wholesale renaming and disentangling of specializers didn't
 551   ;; appeal.  (See also message <sqd5hrclb2.fsf@cam.ac.uk> and
 552   ;; responses in comp.lang.lisp).  -- CSR, 2006-02-27
 553   ((%type :initform nil :reader specializer-type)))
 554
 555 (defclass specializer-with-object (specializer) ())
 556
 557 (defclass exact-class-specializer (specializer) ())
 558
 559 (defclass class-eq-specializer (exact-class-specializer
 560                                 specializer-with-object)
 561   ((object :initarg :class
 562            :reader specializer-class
 563            :reader specializer-object)))
 564
 565 (defclass class-prototype-specializer (specializer-with-object)
 566   ((object :initarg :class
 567            :reader specializer-class
 568            :reader specializer-object)))
 569
 570 (defclass eql-specializer (exact-class-specializer specializer-with-object)
 571   ((object :initarg :object :reader specializer-object
 572            :reader eql-specializer-object)))
 573
 574 (defvar *eql-specializer-table* (make-hash-table :test 'eql))
 575
 576 (defun intern-eql-specializer (object)
 577   (or (gethash object *eql-specializer-table*)
 578       (setf (gethash object *eql-specializer-table*)
 579             (make-instance 'eql-specializer :object object))))
 580
 581 (defclass class (dependent-update-mixin
 582                  definition-source-mixin
 583                  specializer)
 584   ((name
 585     :initform nil
 586     :initarg :name
 587     :reader class-name)
 588    (class-eq-specializer
 589     :initform nil
 590     :reader class-eq-specializer)
 591    (direct-superclasses
 592     :initform ()
 593     :reader class-direct-superclasses)
 594    ;; Note: The (CLASS-)DIRECT-SUBCLASSES for STRUCTURE-CLASSes and
 595    ;; CONDITION-CLASSes are lazily computed whenever the subclass info
 596    ;; becomes available, i.e. when the PCL class is created.
 597    (direct-subclasses
 598     :initform ()
 599     :reader class-direct-subclasses)
 600    (direct-methods
 601     :initform (cons nil nil))
 602    (%documentation
 603     :initform nil
 604     :initarg :documentation)
 605    ;; True if the class definition was compiled with a (SAFETY 3)
 606    ;; optimization policy.
 607    (safe-p
 608     :initform nil
 609     :initarg safe-p
 610     :accessor safe-p)
 611    (finalized-p
 612     :initform nil
 613     :reader class-finalized-p)))
 614
 615 (def!method make-load-form ((class class) &optional env)
 616   ;; FIXME: should we not instead pass ENV to FIND-CLASS?  Probably
 617   ;; doesn't matter while all our environments are the same...
 618   (declare (ignore env))
 619   (let ((name (class-name class)))
 620     (unless (and name (eq (find-class name nil) class))
 621       (error "~@<Can't use anonymous or undefined class as constant: ~S~:@>"
 622              class))
 623     `(find-class ',name)))
 624
 625 ;;; The class PCL-CLASS is an implementation-specific common
 626 ;;; superclass of all specified subclasses of the class CLASS.
 627 (defclass pcl-class (class)
 628   ((%class-precedence-list
 629     :reader class-precedence-list)
 630    ;; KLUDGE: see note in CPL-OR-NIL
 631    (cpl-available-p
 632     :reader cpl-available-p
 633     :initform nil)
 634    (can-precede-list
 635     :initform ()
 636     :reader class-can-precede-list)
 637    (incompatible-superclass-list
 638     :initform ()
 639     :accessor class-incompatible-superclass-list)
 640    (wrapper
 641     :initform nil
 642     :reader class-wrapper)
 643    (prototype
 644     :initform nil
 645     :reader class-prototype)))
 646
 647 (defclass slot-class (pcl-class)
 648   ((direct-slots
 649     :initform ()
 650     :accessor class-direct-slots)
 651    (slots
 652     :initform ()
 653     :accessor class-slots)))
 654
 655 ;;; The class STD-CLASS is an implementation-specific common
 656 ;;; superclass of the classes STANDARD-CLASS and
 657 ;;; FUNCALLABLE-STANDARD-CLASS.
 658 (defclass std-class (slot-class)
 659   ())
 660
 661 (defclass standard-class (std-class)
 662   ())
 663
 664 (defclass funcallable-standard-class (std-class)
 665   ())
 666
 667 (defclass forward-referenced-class (pcl-class) ())
 668
 669 (defclass built-in-class (pcl-class) ())
 670
 671 (defclass condition-class (slot-class) ())
 672
 673 (defclass structure-class (slot-class)
 674   ((defstruct-form
 675      :initform ()
 676      :accessor class-defstruct-form)
 677    (defstruct-constructor
 678      :initform nil
 679      :accessor class-defstruct-constructor)
 680    (from-defclass-p
 681     :initform nil
 682     :initarg :from-defclass-p)))
 683
 684 (defclass definition-source-mixin (standard-object)
 685   ((source
 686     :initform nil
 687     :reader definition-source
 688     :initarg :definition-source)))
 689
 690 (defclass plist-mixin (standard-object)
 691   ((plist :initform () :accessor object-plist :initarg plist)))
 692
 693 (defclass dependent-update-mixin (plist-mixin) ())
 694
 695 (defparameter *early-class-predicates*
 696   '((specializer specializerp)
 697     (exact-class-specializer exact-class-specializer-p)
 698     (class-eq-specializer class-eq-specializer-p)
 699     (eql-specializer eql-specializer-p)
 700     (class classp)
 701     (slot-class slot-class-p)
 702     (std-class std-class-p)
 703     (standard-class standard-class-p)
 704     (funcallable-standard-class funcallable-standard-class-p)
 705     (condition-class condition-class-p)
 706     (structure-class structure-class-p)
 707     (forward-referenced-class forward-referenced-class-p)
 708     (method method-p)
 709     (standard-method standard-method-p)
 710     (accessor-method accessor-method-p)
 711     (standard-accessor-method standard-accessor-method-p)
 712     (standard-reader-method standard-reader-method-p)
 713     (standard-writer-method standard-writer-method-p)
 714     (standard-boundp-method standard-boundp-method-p)
 715     (global-reader-method global-reader-method-p)
 716     (global-writer-method global-writer-method-p)
 717     (global-boundp-method global-boundp-method-p)
 718     (generic-function generic-function-p)
 719     (standard-generic-function standard-generic-function-p)
 720     (method-combination method-combination-p)
 721     (long-method-combination long-method-combination-p)
 722     (short-method-combination short-method-combination-p)))