src/pcl/defs.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; (These are left over from the days when PCL was an add-on package
  27 ;;; for a pre-CLOS Common Lisp. They shouldn't happen in a normal
  28 ;;; build, of course, but they might happen if someone is experimenting
  29 ;;; and debugging, and it's probably worth complaining if they do,
  30 ;;; so we've left 'em in.)
  31 (when (eq *boot-state* 'complete)
  32   (error "Trying to load (or compile) PCL in an environment in which it~%~
  33           has already been loaded. This doesn't work, you will have to~%~
  34           get a fresh lisp (reboot) and then load PCL."))
  35 (when *boot-state*
  36   (cerror "Try loading (or compiling) PCL anyways."
  37           "Trying to load (or compile) PCL in an environment in which it~%~
  38            has already been partially loaded. This may not work, you may~%~
  39            need to get a fresh lisp (reboot) and then load PCL."))
  40 \f
  41 #-sb-fluid (declaim (inline gdefinition))
  42 (defun gdefinition (spec)
  43   ;; This is null layer right now, but once FDEFINITION stops bypasssing
  44   ;; fwrappers/encapsulations we can do that here.
  45   (fdefinition spec))
  46
  47 (defun (setf gdefinition) (new-value spec)
  48   ;; This is almost a null layer right now, but once (SETF
  49   ;; FDEFINITION) stops bypasssing fwrappers/encapsulations we can do
  50   ;; that here.
  51   (sb-c::note-name-defined spec :function) ; FIXME: do we need this? Why?
  52   (setf (fdefinition spec) new-value))
  53 \f
  54 ;;;; type specifier hackery
  55
  56 ;;; internal to this file
  57 (defun coerce-to-class (class &optional make-forward-referenced-class-p)
  58   (if (symbolp class)
  59       (or (find-class class (not make-forward-referenced-class-p))
  60           (ensure-class class))
  61       class))
  62
  63 ;;; interface
  64 (defun specializer-from-type (type &aux args)
  65   (when (consp type)
  66     (setq args (cdr type) type (car type)))
  67   (cond ((symbolp type)
  68          (or (and (null args) (find-class type))
  69              (ecase type
  70                (class    (coerce-to-class (car args)))
  71                (prototype (make-instance 'class-prototype-specializer
  72                                          :object (coerce-to-class (car args))))
  73                (class-eq (class-eq-specializer (coerce-to-class (car args))))
  74                (eql      (intern-eql-specializer (car args))))))
  75         ;; FIXME: do we still need this?
  76         ((and (null args) (typep type 'classoid))
  77          (or (classoid-pcl-class type)
  78              (ensure-non-standard-class (classoid-name type))))
  79         ((specializerp type) type)))
  80
  81 ;;; interface
  82 (defun type-from-specializer (specl)
  83   (cond ((eq specl t)
  84          t)
  85         ((consp specl)
  86          (unless (member (car specl) '(class prototype class-eq eql))
  87            (error "~S is not a legal specializer type." specl))
  88          specl)
  89         ((progn
  90            (when (symbolp specl)
  91              ;;maybe (or (find-class specl nil) (ensure-class specl)) instead?
  92              (setq specl (find-class specl)))
  93            (or (not (eq *boot-state* 'complete))
  94                (specializerp specl)))
  95          (specializer-type specl))
  96         (t
  97          (error "~S is neither a type nor a specializer." specl))))
  98
  99 (defun type-class (type)
 100   (declare (special *the-class-t*))
 101   (setq type (type-from-specializer type))
 102   (if (atom type)
 103       (if (eq type t)
 104           *the-class-t*
 105           (error "bad argument to TYPE-CLASS"))
 106       (case (car type)
 107         (eql (class-of (cadr type)))
 108         (prototype (class-of (cadr type))) ;?
 109         (class-eq (cadr type))
 110         (class (cadr type)))))
 111
 112 (defun class-eq-type (class)
 113   (specializer-type (class-eq-specializer class)))
 114
 115 ;;; internal to this file..
 116 ;;;
 117 ;;; These functions are a pale imitation of their namesake. They accept
 118 ;;; class objects or types where they should.
 119 (defun *normalize-type (type)
 120   (cond ((consp type)
 121          (if (member (car type) '(not and or))
 122              `(,(car type) ,@(mapcar #'*normalize-type (cdr type)))
 123              (if (null (cdr type))
 124                  (*normalize-type (car type))
 125                  type)))
 126         ((symbolp type)
 127          (let ((class (find-class type nil)))
 128            (if class
 129                (let ((type (specializer-type class)))
 130                  (if (listp type) type `(,type)))
 131                `(,type))))
 132         ((or (not (eq *boot-state* 'complete))
 133              (specializerp type))
 134          (specializer-type type))
 135         (t
 136          (error "~S is not a type." type))))
 137
 138 ;;; internal to this file...
 139 (defun convert-to-system-type (type)
 140   (case (car type)
 141     ((not and or) `(,(car type) ,@(mapcar #'convert-to-system-type
 142                                           (cdr type))))
 143     ((class class-eq) ; class-eq is impossible to do right
 144      (layout-classoid (class-wrapper (cadr type))))
 145     (eql type)
 146     (t (if (null (cdr type))
 147            (car type)
 148            type))))
 149
 150 ;;; Writing the missing NOT and AND clauses will improve the quality
 151 ;;; of code generated by GENERATE-DISCRIMINATION-NET, but calling
 152 ;;; SUBTYPEP in place of just returning (VALUES NIL NIL) can be very
 153 ;;; slow. *SUBTYPEP is used by PCL itself, and must be fast.
 154 ;;;
 155 ;;; FIXME: SB-KERNEL has fast-and-not-quite-precise type code for use
 156 ;;; in the compiler. Could we share some of it here?
 157 (defun *subtypep (type1 type2)
 158   (if (equal type1 type2)
 159       (values t t)
 160       (if (eq *boot-state* 'early)
 161           (values (eq type1 type2) t)
 162           (let ((*in-precompute-effective-methods-p* t))
 163             (declare (special *in-precompute-effective-methods-p*))
 164             ;; FIXME: *IN-PRECOMPUTE-EFFECTIVE-METHODS-P* is not a
 165             ;; good name. It changes the way
 166             ;; CLASS-APPLICABLE-USING-CLASS-P works.
 167             (setq type1 (*normalize-type type1))
 168             (setq type2 (*normalize-type type2))
 169             (case (car type2)
 170               (not
 171                (values nil nil)) ; XXX We should improve this.
 172               (and
 173                (values nil nil)) ; XXX We should improve this.
 174               ((eql wrapper-eq class-eq class)
 175                (multiple-value-bind (app-p maybe-app-p)
 176                    (specializer-applicable-using-type-p type2 type1)
 177                  (values app-p (or app-p (not maybe-app-p)))))
 178               (t
 179                (subtypep (convert-to-system-type type1)
 180                          (convert-to-system-type type2))))))))
 181 \f
 182 (defvar *built-in-class-symbols* ())
 183 (defvar *built-in-wrapper-symbols* ())
 184
 185 (defun get-built-in-class-symbol (class-name)
 186   (or (cadr (assq class-name *built-in-class-symbols*))
 187       (let ((symbol (make-class-symbol class-name)))
 188         (push (list class-name symbol) *built-in-class-symbols*)
 189         symbol)))
 190
 191 (defun get-built-in-wrapper-symbol (class-name)
 192   (or (cadr (assq class-name *built-in-wrapper-symbols*))
 193       (let ((symbol (make-wrapper-symbol class-name)))
 194         (push (list class-name symbol) *built-in-wrapper-symbols*)
 195         symbol)))
 196 \f
 197 (pushnew '%class *var-declarations*)
 198 (pushnew '%variable-rebinding *var-declarations*)
 199
 200 (defun variable-class (var env)
 201   (caddr (var-declaration 'class var env)))
 202
 203 (defvar *standard-method-combination*)
 204 \f
 205 (defun plist-value (object name)
 206   (getf (object-plist object) name))
 207
 208 (defun (setf plist-value) (new-value object name)
 209   (if new-value
 210       (setf (getf (object-plist object) name) new-value)
 211       (progn
 212         (remf (object-plist object) name)
 213         nil)))
 214 \f
 215 ;;;; built-in classes
 216
 217 ;;; Grovel over SB-KERNEL::*BUILT-IN-CLASSES* in order to set
 218 ;;; SB-PCL:*BUILT-IN-CLASSES*.
 219 (/show "about to set up SB-PCL::*BUILT-IN-CLASSES*")
 220 (defvar *built-in-classes*
 221   (labels ((direct-supers (class)
 222              (/noshow "entering DIRECT-SUPERS" (classoid-name class))
 223              (if (typep class 'built-in-classoid)
 224                  (built-in-classoid-direct-superclasses class)
 225                  (let ((inherits (layout-inherits
 226                                   (classoid-layout class))))
 227                    (/noshow inherits)
 228                    (list (svref inherits (1- (length inherits)))))))
 229            (direct-subs (class)
 230              (/noshow "entering DIRECT-SUBS" (classoid-name class))
 231              (collect ((res))
 232                (let ((subs (classoid-subclasses class)))
 233                  (/noshow subs)
 234                  (when subs
 235                    (dohash (sub v subs)
 236                      (declare (ignore v))
 237                      (/noshow sub)
 238                      (when (member class (direct-supers sub))
 239                        (res sub)))))
 240                (res))))
 241     (mapcar (lambda (kernel-bic-entry)
 242               (/noshow "setting up" kernel-bic-entry)
 243               (let* ((name (car kernel-bic-entry))
 244                      (class (find-classoid name))
 245                      (prototype-form
 246                       (getf (cdr kernel-bic-entry) :prototype-form)))
 247                 (/noshow name class)
 248                 `(,name
 249                   ,(mapcar #'classoid-name (direct-supers class))
 250                   ,(mapcar #'classoid-name (direct-subs class))
 251                   ,(map 'list
 252                         (lambda (x)
 253                           (classoid-name
 254                            (layout-classoid x)))
 255                         (reverse
 256                          (layout-inherits
 257                           (classoid-layout class))))
 258                   ,(if prototype-form
 259                        (eval prototype-form)
 260                        ;; This is the default prototype value which
 261                        ;; was used, without explanation, by the CMU CL
 262                        ;; code we're derived from. Evidently it's safe
 263                        ;; in all relevant cases.
 264                        42))))
 265             (remove-if (lambda (kernel-bic-entry)
 266                          (member (first kernel-bic-entry)
 267                                  ;; I'm not sure why these are removed from
 268                                  ;; the list, but that's what the original
 269                                  ;; CMU CL code did. -- WHN 20000715
 270                                  '(t function stream
 271                                      file-stream string-stream)))
 272                        sb-kernel::*built-in-classes*))))
 273 (/noshow "done setting up SB-PCL::*BUILT-IN-CLASSES*")
 274 \f
 275 ;;;; the classes that define the kernel of the metabraid
 276
 277 (defclass t () ()
 278   (:metaclass built-in-class))
 279
 280 (defclass function (t) ()
 281   (:metaclass built-in-class))
 282
 283 (defclass stream (t) ()
 284   (:metaclass built-in-class))
 285
 286 (defclass file-stream (stream) ()
 287   (:metaclass built-in-class))
 288
 289 (defclass string-stream (stream) ()
 290   (:metaclass built-in-class))
 291
 292 (defclass slot-object (t) ()
 293   (:metaclass slot-class))
 294
 295 (defclass condition (slot-object) ()
 296   (:metaclass condition-class))
 297
 298 (defclass structure-object (slot-object) ()
 299   (:metaclass structure-class))
 300
 301 (defstruct (dead-beef-structure-object
 302             (:constructor |STRUCTURE-OBJECT class constructor|)
 303             (:copier nil)))
 304
 305 (defclass standard-object (slot-object) ())
 306
 307 (defclass funcallable-standard-object (standard-object function)
 308   ()
 309   (:metaclass funcallable-standard-class))
 310
 311 (defclass metaobject (standard-object) ())
 312
 313 (defclass generic-function (dependent-update-mixin
 314                             definition-source-mixin
 315                             metaobject
 316                             funcallable-standard-object)
 317   ((%documentation :initform nil :initarg :documentation)
 318    ;; We need to make a distinction between the methods initially set
 319    ;; up by :METHOD options to DEFGENERIC and the ones set up later by
 320    ;; DEFMETHOD, because ANSI specifies that executing DEFGENERIC on
 321    ;; an already-DEFGENERICed function clears the methods set by the
 322    ;; previous DEFGENERIC, but not methods set by DEFMETHOD. (Making
 323    ;; this distinction seems a little kludgy, but it has the positive
 324    ;; effect of making it so that loading a file a.lisp containing
 325    ;; DEFGENERIC, then loading a second file b.lisp containing
 326    ;; DEFMETHOD, then modifying and reloading a.lisp and/or b.lisp
 327    ;; tends to leave the generic function in a state consistent with
 328    ;; the most-recently-loaded state of a.lisp and b.lisp.)
 329    (initial-methods :initform ()
 330                     :accessor generic-function-initial-methods))
 331   (:metaclass funcallable-standard-class))
 332
 333 (defclass standard-generic-function (generic-function)
 334   ((name
 335     :initform nil
 336     :initarg :name
 337     :reader generic-function-name)
 338    (methods
 339     :initform ()
 340     :accessor generic-function-methods
 341     :type list)
 342    (method-class
 343     :initarg :method-class
 344     :accessor generic-function-method-class)
 345    (%method-combination
 346     :initarg :method-combination
 347     :accessor generic-function-method-combination)
 348    (declarations
 349     ;; KLUDGE: AMOP specifies :DECLARATIONS, while ANSI specifies
 350     ;; :DECLARE.  Allow either (but FIXME: maybe a note or a warning
 351     ;; might be appropriate).
 352     :initarg :declarations
 353     :initarg :declare
 354     :initform ()
 355     :accessor generic-function-declarations)
 356    (arg-info
 357     :initform (make-arg-info)
 358     :reader gf-arg-info)
 359    (dfun-state
 360     :initform ()
 361     :accessor gf-dfun-state))
 362   (:metaclass funcallable-standard-class)
 363   (:default-initargs :method-class *the-class-standard-method*
 364                      :method-combination *standard-method-combination*))
 365
 366 (defclass method (metaobject) ())
 367
 368 (defclass standard-method (definition-source-mixin plist-mixin method)
 369   ((%generic-function
 370     :initform nil
 371     :accessor method-generic-function)
 372    #+nil ; implemented by PLIST
 373    (qualifiers
 374     :initform ()
 375     :initarg  :qualifiers
 376     :reader method-qualifiers)
 377    (specializers
 378     :initform ()
 379     :initarg  :specializers
 380     :reader method-specializers)
 381    (lambda-list
 382     :initform ()
 383     :initarg  :lambda-list
 384     :reader method-lambda-list)
 385    (%function :initform nil :initarg :function)
 386    (fast-function
 387     :initform nil
 388     :initarg :fast-function             ;no writer
 389     :reader method-fast-function)
 390    (%documentation :initform nil :initarg :documentation)))
 391
 392 (defclass accessor-method (standard-method)
 393   ((slot-name :initform nil :initarg :slot-name
 394               :reader accessor-method-slot-name)))
 395
 396 (defclass standard-accessor-method (accessor-method)
 397   ((%slot-definition :initform nil :initarg :slot-definition
 398                      :reader accessor-method-slot-definition)))
 399
 400 (defclass standard-reader-method (standard-accessor-method) ())
 401 (defclass standard-writer-method (standard-accessor-method) ())
 402 ;;; an extension, apparently.
 403 (defclass standard-boundp-method (standard-accessor-method) ())
 404
 405 ;;; for (SLOT-VALUE X 'FOO) / ACCESSOR-SLOT-VALUE optimization, which
 406 ;;; can't be STANDARD-READER-METHOD because there is no associated
 407 ;;; slot definition.
 408 (defclass global-reader-method (accessor-method) ())
 409 (defclass global-writer-method (accessor-method) ())
 410 (defclass global-boundp-method (accessor-method) ())
 411
 412 (defclass method-combination (metaobject)
 413   ((%documentation :initform nil :initarg :documentation)))
 414
 415 (defclass standard-method-combination (definition-source-mixin
 416                                        method-combination)
 417   ((type-name
 418     :reader method-combination-type-name
 419     :initarg :type-name)
 420    (options
 421     :reader method-combination-options
 422     :initarg :options)))
 423
 424 (defclass long-method-combination (standard-method-combination)
 425   ((function
 426     :initarg :function
 427     :reader long-method-combination-function)
 428    (args-lambda-list
 429     :initarg :args-lambda-list
 430     :reader long-method-combination-args-lambda-list)))
 431
 432 (defclass short-method-combination (standard-method-combination)
 433   ((operator
 434     :reader short-combination-operator
 435     :initarg :operator)
 436    (identity-with-one-argument
 437     :reader short-combination-identity-with-one-argument
 438     :initarg :identity-with-one-argument)))
 439
 440 (defclass slot-definition (metaobject)
 441   ((name
 442     :initform nil
 443     :initarg :name
 444     :accessor slot-definition-name)
 445    (initform
 446     :initform nil
 447     :initarg :initform
 448     :accessor slot-definition-initform)
 449    (initfunction
 450     :initform nil
 451     :initarg :initfunction
 452     :accessor slot-definition-initfunction)
 453    (readers
 454     :initform nil
 455     :initarg :readers
 456     :accessor slot-definition-readers)
 457    (writers
 458     :initform nil
 459     :initarg :writers
 460     :accessor slot-definition-writers)
 461    (initargs
 462     :initform nil
 463     :initarg :initargs
 464     :accessor slot-definition-initargs)
 465    (%type :initform t :initarg :type :accessor slot-definition-type)
 466    (%documentation
 467     :initform nil :initarg :documentation
 468     ;; KLUDGE: we need a reader for bootstrapping purposes, in
 469     ;; COMPUTE-EFFECTIVE-SLOT-DEFINITION-INITARGS.
 470     :reader %slot-definition-documentation)
 471    (%class :initform nil :initarg :class :accessor slot-definition-class)))
 472
 473 (defclass standard-slot-definition (slot-definition)
 474   ((allocation
 475     :initform :instance
 476     :initarg :allocation
 477     :accessor slot-definition-allocation)
 478    (allocation-class
 479     :initform nil
 480     :initarg :allocation-class
 481     :accessor slot-definition-allocation-class)))
 482
 483 (defclass condition-slot-definition (slot-definition)
 484   ((allocation
 485     :initform :instance
 486     :initarg :allocation
 487     :accessor slot-definition-allocation)
 488    (allocation-class
 489     :initform nil
 490     :initarg :allocation-class
 491     :accessor slot-definition-allocation-class)))
 492
 493 (defclass structure-slot-definition (slot-definition)
 494   ((defstruct-accessor-symbol
 495      :initform nil
 496      :initarg :defstruct-accessor-symbol
 497      :accessor slot-definition-defstruct-accessor-symbol)
 498    (internal-reader-function
 499      :initform nil
 500      :initarg :internal-reader-function
 501      :accessor slot-definition-internal-reader-function)
 502    (internal-writer-function
 503      :initform nil
 504      :initarg :internal-writer-function
 505      :accessor slot-definition-internal-writer-function)))
 506
 507 (defclass direct-slot-definition (slot-definition)
 508   ())
 509
 510 (defclass effective-slot-definition (slot-definition)
 511   ((reader-function ; (lambda (object) ...)
 512     :accessor slot-definition-reader-function)
 513    (writer-function ; (lambda (new-value object) ...)
 514     :accessor slot-definition-writer-function)
 515    (boundp-function ; (lambda (object) ...)
 516     :accessor slot-definition-boundp-function)
 517    (accessor-flags
 518     :initform 0)))
 519
 520 (defclass standard-direct-slot-definition (standard-slot-definition
 521                                            direct-slot-definition)
 522   ())
 523
 524 (defclass standard-effective-slot-definition (standard-slot-definition
 525                                               effective-slot-definition)
 526   ((location ; nil, a fixnum, a cons: (slot-name . value)
 527     :initform nil
 528     :accessor slot-definition-location)))
 529
 530 (defclass condition-direct-slot-definition (condition-slot-definition
 531                                             direct-slot-definition)
 532   ())
 533
 534 (defclass condition-effective-slot-definition (condition-slot-definition
 535                                                effective-slot-definition)
 536   ())
 537
 538 (defclass structure-direct-slot-definition (structure-slot-definition
 539                                             direct-slot-definition)
 540   ())
 541
 542 (defclass structure-effective-slot-definition (structure-slot-definition
 543                                                effective-slot-definition)
 544   ())
 545
 546 (defclass specializer (metaobject)
 547   ;; KLUDGE: in sbcl-0.9.10.2 this was renamed from TYPE, which was an
 548   ;; external symbol of the CL package and hence potentially collides
 549   ;; with user code.  Renaming this to %TYPE, however, is the coward's
 550   ;; way out, because the objects that PCL puts in this slot aren't
 551   ;; (quite) types: they are closer to kinds of specializer.  However,
 552   ;; the wholesale renaming and disentangling of specializers didn't
 553   ;; appeal.  (See also message <sqd5hrclb2.fsf@cam.ac.uk> and
 554   ;; responses in comp.lang.lisp).  -- CSR, 2006-02-27
 555   ((%type :initform nil :reader specializer-type)))
 556
 557 (defclass specializer-with-object (specializer) ())
 558
 559 (defclass exact-class-specializer (specializer) ())
 560
 561 (defclass class-eq-specializer (exact-class-specializer
 562                                 specializer-with-object)
 563   ((object :initarg :class
 564            :reader specializer-class
 565            :reader specializer-object)))
 566
 567 (defclass class-prototype-specializer (specializer-with-object)
 568   ((object :initarg :class
 569            :reader specializer-class
 570            :reader specializer-object)))
 571
 572 (defclass eql-specializer (exact-class-specializer specializer-with-object)
 573   ((object :initarg :object :reader specializer-object
 574            :reader eql-specializer-object)))
 575
 576 (defvar *eql-specializer-table* (make-hash-table :test 'eql))
 577
 578 (defun intern-eql-specializer (object)
 579   (or (gethash object *eql-specializer-table*)
 580       (setf (gethash object *eql-specializer-table*)
 581             (make-instance 'eql-specializer :object object))))
 582
 583 (defclass class (dependent-update-mixin
 584                  definition-source-mixin
 585                  specializer)
 586   ((name
 587     :initform nil
 588     :initarg :name
 589     :reader class-name)
 590    (class-eq-specializer
 591     :initform nil
 592     :reader class-eq-specializer)
 593    (direct-superclasses
 594     :initform ()
 595     :reader class-direct-superclasses)
 596    ;; Note: The (CLASS-)DIRECT-SUBCLASSES for STRUCTURE-CLASSes and
 597    ;; CONDITION-CLASSes are lazily computed whenever the subclass info
 598    ;; becomes available, i.e. when the PCL class is created.
 599    (direct-subclasses
 600     :initform ()
 601     :reader class-direct-subclasses)
 602    (direct-methods
 603     :initform (cons nil nil))
 604    (%documentation
 605     :initform nil
 606     :initarg :documentation)
 607    (finalized-p
 608     :initform nil
 609     :reader class-finalized-p)))
 610
 611 (def!method make-load-form ((class class) &optional env)
 612   ;; FIXME: should we not instead pass ENV to FIND-CLASS?  Probably
 613   ;; doesn't matter while all our environments are the same...
 614   (declare (ignore env))
 615   (let ((name (class-name class)))
 616     (unless (and name (eq (find-class name nil) class))
 617       (error "~@<Can't use anonymous or undefined class as constant: ~S~:@>"
 618              class))
 619     `(find-class ',name)))
 620
 621 ;;; The class PCL-CLASS is an implementation-specific common
 622 ;;; superclass of all specified subclasses of the class CLASS.
 623 (defclass pcl-class (class)
 624   ((%class-precedence-list
 625     :reader class-precedence-list)
 626    ;; KLUDGE: see note in CPL-OR-NIL
 627    (cpl-available-p
 628     :reader cpl-available-p
 629     :initform nil)
 630    (can-precede-list
 631     :initform ()
 632     :reader class-can-precede-list)
 633    (incompatible-superclass-list
 634     :initform ()
 635     :accessor class-incompatible-superclass-list)
 636    (wrapper
 637     :initform nil
 638     :reader class-wrapper)
 639    (prototype
 640     :initform nil
 641     :reader class-prototype)))
 642
 643 (defclass slot-class (pcl-class)
 644   ((direct-slots
 645     :initform ()
 646     :accessor class-direct-slots)
 647    (slots
 648     :initform ()
 649     :accessor class-slots)))
 650
 651 ;;; The class STD-CLASS is an implementation-specific common
 652 ;;; superclass of the classes STANDARD-CLASS and
 653 ;;; FUNCALLABLE-STANDARD-CLASS.
 654 (defclass std-class (slot-class)
 655   ())
 656
 657 (defclass standard-class (std-class)
 658   ())
 659
 660 (defclass funcallable-standard-class (std-class)
 661   ())
 662
 663 (defclass forward-referenced-class (pcl-class) ())
 664
 665 (defclass built-in-class (pcl-class) ())
 666
 667 (defclass condition-class (slot-class) ())
 668
 669 (defclass structure-class (slot-class)
 670   ((defstruct-form
 671      :initform ()
 672      :accessor class-defstruct-form)
 673    (defstruct-constructor
 674      :initform nil
 675      :accessor class-defstruct-constructor)
 676    (from-defclass-p
 677     :initform nil
 678     :initarg :from-defclass-p)))
 679
 680 (defclass definition-source-mixin (standard-object)
 681   ((source
 682     :initform nil
 683     :reader definition-source
 684     :initarg :definition-source)))
 685
 686 (defclass plist-mixin (standard-object)
 687   ((plist :initform () :accessor object-plist)))
 688
 689 (defclass dependent-update-mixin (plist-mixin) ())
 690
 691 (defparameter *early-class-predicates*
 692   '((specializer specializerp)
 693     (exact-class-specializer exact-class-specializer-p)
 694     (class-eq-specializer class-eq-specializer-p)
 695     (eql-specializer eql-specializer-p)
 696     (class classp)
 697     (slot-class slot-class-p)
 698     (std-class std-class-p)
 699     (standard-class standard-class-p)
 700     (funcallable-standard-class funcallable-standard-class-p)
 701     (condition-class condition-class-p)
 702     (structure-class structure-class-p)
 703     (forward-referenced-class forward-referenced-class-p)
 704     (method method-p)
 705     (standard-method standard-method-p)
 706     (accessor-method accessor-method-p)
 707     (standard-accessor-method standard-accessor-method-p)
 708     (standard-reader-method standard-reader-method-p)
 709     (standard-writer-method standard-writer-method-p)
 710     (standard-boundp-method standard-boundp-method-p)
 711     (global-reader-method global-reader-method-p)
 712     (global-writer-method global-writer-method-p)
 713     (global-boundp-method global-boundp-method-p)
 714     (generic-function generic-function-p)
 715     (standard-generic-function standard-generic-function-p)
 716     (method-combination method-combination-p)
 717     (long-method-combination long-method-combination-p)
 718     (short-method-combination short-method-combination-p)))