src/pcl/defs.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; (These are left over from the days when PCL was an add-on package
  27 ;;; for a pre-CLOS Common Lisp. They shouldn't happen in a normal
  28 ;;; build, of course, but they might happen if someone is experimenting
  29 ;;; and debugging, and it's probably worth complaining if they do,
  30 ;;; so we've left 'em in.)
  31 (when (eq **boot-state** 'complete)
  32   (error "Trying to load (or compile) PCL in an environment in which it~%~
  33           has already been loaded. This doesn't work, you will have to~%~
  34           get a fresh lisp (reboot) and then load PCL."))
  35 (when **boot-state**
  36   (cerror "Try loading (or compiling) PCL anyways."
  37           "Trying to load (or compile) PCL in an environment in which it~%~
  38            has already been partially loaded. This may not work, you may~%~
  39            need to get a fresh lisp (reboot) and then load PCL."))
  40 \f
  41 #-sb-fluid (declaim (inline gdefinition))
  42 (defun gdefinition (spec)
  43   ;; This is null layer right now, but once FDEFINITION stops bypasssing
  44   ;; fwrappers/encapsulations we can do that here.
  45   (fdefinition spec))
  46
  47 (defun (setf gdefinition) (new-value spec)
  48   ;; This is almost a null layer right now, but once (SETF
  49   ;; FDEFINITION) stops bypasssing fwrappers/encapsulations we can do
  50   ;; that here.
  51   (sb-c::note-name-defined spec :function) ; FIXME: do we need this? Why?
  52   (setf (fdefinition spec) new-value))
  53 \f
  54 ;;;; type specifier hackery
  55
  56 ;;; internal to this file
  57 (defun coerce-to-class (class &optional make-forward-referenced-class-p)
  58   (if (symbolp class)
  59       (or (find-class class (not make-forward-referenced-class-p))
  60           (ensure-class class))
  61       class))
  62
  63 ;;; interface
  64 (defun specializer-from-type (type &aux args)
  65   (when (symbolp type)
  66     (return-from specializer-from-type (find-class type)))
  67   (when (consp type)
  68     (setq args (cdr type) type (car type)))
  69   (cond ((symbolp type)
  70          (or (ecase type
  71                (class    (coerce-to-class (car args)))
  72                (prototype (make-instance 'class-prototype-specializer
  73                                          :object (coerce-to-class (car args))))
  74                (class-eq (class-eq-specializer (coerce-to-class (car args))))
  75                (eql      (intern-eql-specializer (car args))))))
  76         ;; FIXME: do we still need this?
  77         ((and (null args) (typep type 'classoid))
  78          (or (classoid-pcl-class type)
  79              (ensure-non-standard-class (classoid-name type) type)))
  80         ((specializerp type) type)))
  81
  82 ;;; interface
  83 (defun type-from-specializer (specl)
  84   (cond ((eq specl t)
  85          t)
  86         ((consp specl)
  87          (unless (member (car specl) '(class prototype class-eq eql))
  88            (error "~S is not a legal specializer type." specl))
  89          specl)
  90         ((progn
  91            (when (symbolp specl)
  92              ;;maybe (or (find-class specl nil) (ensure-class specl)) instead?
  93              (setq specl (find-class specl)))
  94            (or (not (eq **boot-state** 'complete))
  95                (specializerp specl)))
  96          (specializer-type specl))
  97         (t
  98          (error "~S is neither a type nor a specializer." specl))))
  99
 100 (defun type-class (type)
 101   (declare (special *the-class-t*))
 102   (setq type (type-from-specializer type))
 103   (if (atom type)
 104       (if (eq type t)
 105           *the-class-t*
 106           (error "bad argument to TYPE-CLASS"))
 107       (case (car type)
 108         (eql (class-of (cadr type)))
 109         (prototype (class-of (cadr type))) ;?
 110         (class-eq (cadr type))
 111         (class (cadr type)))))
 112
 113 (defun class-eq-type (class)
 114   (specializer-type (class-eq-specializer class)))
 115
 116 ;;; internal to this file..
 117 ;;;
 118 ;;; These functions are a pale imitation of their namesake. They accept
 119 ;;; class objects or types where they should.
 120 (defun *normalize-type (type)
 121   (cond ((consp type)
 122          (if (member (car type) '(not and or))
 123              `(,(car type) ,@(mapcar #'*normalize-type (cdr type)))
 124              (if (null (cdr type))
 125                  (*normalize-type (car type))
 126                  type)))
 127         ((symbolp type)
 128          (let ((class (find-class type nil)))
 129            (if class
 130                (let ((type (specializer-type class)))
 131                  (if (listp type) type `(,type)))
 132                `(,type))))
 133         ((or (not (eq **boot-state** 'complete))
 134              (specializerp type))
 135          (specializer-type type))
 136         (t
 137          (error "~S is not a type." type))))
 138
 139 ;;; internal to this file...
 140 (defun convert-to-system-type (type)
 141   (case (car type)
 142     ((not and or) `(,(car type) ,@(mapcar #'convert-to-system-type
 143                                           (cdr type))))
 144     ((class class-eq) ; class-eq is impossible to do right
 145      (layout-classoid (class-wrapper (cadr type))))
 146     (eql type)
 147     (t (if (null (cdr type))
 148            (car type)
 149            type))))
 150
 151 ;;; Writing the missing NOT and AND clauses will improve the quality
 152 ;;; of code generated by GENERATE-DISCRIMINATION-NET, but calling
 153 ;;; SUBTYPEP in place of just returning (VALUES NIL NIL) can be very
 154 ;;; slow. *SUBTYPEP is used by PCL itself, and must be fast.
 155 ;;;
 156 ;;; FIXME: SB-KERNEL has fast-and-not-quite-precise type code for use
 157 ;;; in the compiler. Could we share some of it here?
 158 (defvar *in-*subtypep* nil)
 159
 160 (defun *subtypep (type1 type2)
 161   (if (equal type1 type2)
 162       (values t t)
 163       (if (eq **boot-state** 'early)
 164           (values (eq type1 type2) t)
 165           (let ((*in-*subtypep* t))
 166             (setq type1 (*normalize-type type1))
 167             (setq type2 (*normalize-type type2))
 168             (case (car type2)
 169               (not
 170                (values nil nil)) ; XXX We should improve this.
 171               (and
 172                (values nil nil)) ; XXX We should improve this.
 173               ((eql wrapper-eq class-eq class)
 174                (multiple-value-bind (app-p maybe-app-p)
 175                    (specializer-applicable-using-type-p type2 type1)
 176                  (values app-p (or app-p (not maybe-app-p)))))
 177               (t
 178                (subtypep (convert-to-system-type type1)
 179                          (convert-to-system-type type2))))))))
 180 \f
 181 (defvar *built-in-class-symbols* ())
 182 (defvar *built-in-wrapper-symbols* ())
 183
 184 (defun get-built-in-class-symbol (class-name)
 185   (or (cadr (assq class-name *built-in-class-symbols*))
 186       (let ((symbol (make-class-symbol class-name)))
 187         (push (list class-name symbol) *built-in-class-symbols*)
 188         symbol)))
 189
 190 (defun get-built-in-wrapper-symbol (class-name)
 191   (or (cadr (assq class-name *built-in-wrapper-symbols*))
 192       (let ((symbol (make-wrapper-symbol class-name)))
 193         (push (list class-name symbol) *built-in-wrapper-symbols*)
 194         symbol)))
 195 \f
 196 (defvar *standard-method-combination*)
 197 \f
 198 (defun plist-value (object name)
 199   (getf (object-plist object) name))
 200
 201 (defun (setf plist-value) (new-value object name)
 202   (if new-value
 203       (setf (getf (object-plist object) name) new-value)
 204       (progn
 205         (remf (object-plist object) name)
 206         nil)))
 207 \f
 208 ;;;; built-in classes
 209
 210 ;;; Grovel over SB-KERNEL::*BUILT-IN-CLASSES* in order to set
 211 ;;; SB-PCL:*BUILT-IN-CLASSES*.
 212 (/show "about to set up SB-PCL::*BUILT-IN-CLASSES*")
 213 (defvar *built-in-classes*
 214   (labels ((direct-supers (class)
 215              (/noshow "entering DIRECT-SUPERS" (classoid-name class))
 216              (if (typep class 'built-in-classoid)
 217                  (built-in-classoid-direct-superclasses class)
 218                  (let ((inherits (layout-inherits
 219                                   (classoid-layout class))))
 220                    (/noshow inherits)
 221                    (list (svref inherits (1- (length inherits)))))))
 222            (direct-subs (class)
 223              (/noshow "entering DIRECT-SUBS" (classoid-name class))
 224              (collect ((res))
 225                (let ((subs (classoid-subclasses class)))
 226                  (/noshow subs)
 227                  (when subs
 228                    (dohash ((sub v) subs)
 229                      (declare (ignore v))
 230                      (/noshow sub)
 231                      (when (member class (direct-supers sub) :test #'eq)
 232                        (res sub)))))
 233                (res))))
 234     (mapcar (lambda (kernel-bic-entry)
 235               (/noshow "setting up" kernel-bic-entry)
 236               (let* ((name (car kernel-bic-entry))
 237                      (class (find-classoid name))
 238                      (prototype-form
 239                       (getf (cdr kernel-bic-entry) :prototype-form)))
 240                 (/noshow name class)
 241                 `(,name
 242                   ,(mapcar #'classoid-name (direct-supers class))
 243                   ,(mapcar #'classoid-name (direct-subs class))
 244                   ,(map 'list
 245                         (lambda (x)
 246                           (classoid-name
 247                            (layout-classoid x)))
 248                         (reverse
 249                          (layout-inherits
 250                           (classoid-layout class))))
 251                   ,(if prototype-form
 252                        (eval prototype-form)
 253                        ;; This is the default prototype value which
 254                        ;; was used, without explanation, by the CMU CL
 255                        ;; code we're derived from. Evidently it's safe
 256                        ;; in all relevant cases.
 257                        42))))
 258             (remove-if (lambda (kernel-bic-entry)
 259                          (member (first kernel-bic-entry)
 260                                  ;; I'm not sure why these are removed from
 261                                  ;; the list, but that's what the original
 262                                  ;; CMU CL code did. -- WHN 20000715
 263                                  '(t function stream
 264                                      file-stream string-stream)))
 265                        sb-kernel::*built-in-classes*))))
 266 (/noshow "done setting up SB-PCL::*BUILT-IN-CLASSES*")
 267 \f
 268 ;;;; the classes that define the kernel of the metabraid
 269
 270 (defclass t () ()
 271   (:metaclass built-in-class))
 272
 273 (defclass function (t) ()
 274   (:metaclass built-in-class))
 275
 276 (defclass stream (t) ()
 277   (:metaclass built-in-class))
 278
 279 (defclass file-stream (stream) ()
 280   (:metaclass built-in-class))
 281
 282 (defclass string-stream (stream) ()
 283   (:metaclass built-in-class))
 284
 285 (defclass slot-object (t) ()
 286   (:metaclass slot-class))
 287
 288 (defclass condition (slot-object) ()
 289   (:metaclass condition-class))
 290
 291 (defclass structure-object (slot-object) ()
 292   (:metaclass structure-class))
 293
 294 (defstruct (dead-beef-structure-object
 295             (:constructor |STRUCTURE-OBJECT class constructor|)
 296             (:copier nil)))
 297
 298 (defclass standard-object (slot-object) ())
 299
 300 (defclass funcallable-standard-object (function standard-object)
 301   ()
 302   (:metaclass funcallable-standard-class))
 303
 304 (defclass metaobject (standard-object) ())
 305
 306 (defclass generic-function (dependent-update-mixin
 307                             definition-source-mixin
 308                             metaobject
 309                             funcallable-standard-object)
 310   ((%documentation
 311     :initform nil
 312     :initarg :documentation)
 313    ;; We need to make a distinction between the methods initially set
 314    ;; up by :METHOD options to DEFGENERIC and the ones set up later by
 315    ;; DEFMETHOD, because ANSI specifies that executing DEFGENERIC on
 316    ;; an already-DEFGENERICed function clears the methods set by the
 317    ;; previous DEFGENERIC, but not methods set by DEFMETHOD. (Making
 318    ;; this distinction seems a little kludgy, but it has the positive
 319    ;; effect of making it so that loading a file a.lisp containing
 320    ;; DEFGENERIC, then loading a second file b.lisp containing
 321    ;; DEFMETHOD, then modifying and reloading a.lisp and/or b.lisp
 322    ;; tends to leave the generic function in a state consistent with
 323    ;; the most-recently-loaded state of a.lisp and b.lisp.)
 324    (initial-methods
 325     :initform ()
 326     :accessor generic-function-initial-methods))
 327   (:metaclass funcallable-standard-class))
 328
 329 (defclass standard-generic-function (generic-function)
 330   ((name
 331     :initform nil
 332     :initarg :name
 333     :reader generic-function-name)
 334    (methods
 335     :initform ()
 336     :accessor generic-function-methods
 337     :type list)
 338    (method-class
 339     :initarg :method-class
 340     :accessor generic-function-method-class)
 341    (%method-combination
 342     :initarg :method-combination
 343     :accessor generic-function-method-combination)
 344    (declarations
 345     ;; KLUDGE: AMOP specifies :DECLARATIONS, while ANSI specifies
 346     ;; :DECLARE.  Allow either (but FIXME: maybe a note or a warning
 347     ;; might be appropriate).
 348     :initarg :declarations
 349     :initarg :declare
 350     :initform ()
 351     :accessor generic-function-declarations)
 352    (arg-info
 353     :initform (make-arg-info)
 354     :reader gf-arg-info)
 355    (dfun-state
 356     :initform ()
 357     :accessor gf-dfun-state)
 358    ;; Used to make DFUN-STATE & FIN-FUNCTION updates atomic.
 359    (%lock
 360     :initform (sb-thread::make-spinlock :name "GF lock")
 361     :reader gf-lock)
 362    ;; Set to true by ADD-METHOD, REMOVE-METHOD; to false by
 363    ;; MAYBE-UPDATE-INFO-FOR-GF.
 364    (info-needs-update
 365     :initform nil
 366     :accessor gf-info-needs-update))
 367   (:metaclass funcallable-standard-class)
 368   (:default-initargs :method-class *the-class-standard-method*
 369                      :method-combination *standard-method-combination*))
 370
 371 (defclass method (metaobject) ())
 372
 373 (defclass standard-method (plist-mixin definition-source-mixin method)
 374   ((%generic-function :initform nil :accessor method-generic-function)
 375    (qualifiers :initform () :initarg :qualifiers :reader method-qualifiers)
 376    (specializers :initform () :initarg :specializers
 377                  :reader method-specializers)
 378    (lambda-list :initform () :initarg :lambda-list :reader method-lambda-list)
 379    (%function :initform nil :initarg :function :reader method-function)
 380    (%documentation :initform nil :initarg :documentation)))
 381
 382 (defclass accessor-method (standard-method)
 383   ((slot-name :initform nil :initarg :slot-name
 384               :reader accessor-method-slot-name)))
 385
 386 (defclass standard-accessor-method (accessor-method)
 387   ((%slot-definition :initform nil :initarg :slot-definition
 388                      :reader accessor-method-slot-definition)))
 389
 390 (defclass standard-reader-method (standard-accessor-method) ())
 391 (defclass standard-writer-method (standard-accessor-method) ())
 392 ;;; an extension, apparently.
 393 (defclass standard-boundp-method (standard-accessor-method) ())
 394
 395 ;;; for (SLOT-VALUE X 'FOO) / ACCESSOR-SLOT-VALUE optimization, which
 396 ;;; can't be STANDARD-READER-METHOD because there is no associated
 397 ;;; slot definition.
 398 (defclass global-reader-method (accessor-method) ())
 399 (defclass global-writer-method (accessor-method) ())
 400 (defclass global-boundp-method (accessor-method) ())
 401
 402 (defclass method-combination (metaobject)
 403   ((%documentation :initform nil :initarg :documentation)))
 404
 405 (defclass standard-method-combination (definition-source-mixin
 406                                        method-combination)
 407   ((type-name
 408     :reader method-combination-type-name
 409     :initarg :type-name)
 410    (options
 411     :reader method-combination-options
 412     :initarg :options)))
 413
 414 (defclass long-method-combination (standard-method-combination)
 415   ((function
 416     :initarg :function
 417     :reader long-method-combination-function)
 418    (args-lambda-list
 419     :initarg :args-lambda-list
 420     :reader long-method-combination-args-lambda-list)))
 421
 422 (defclass short-method-combination (standard-method-combination)
 423   ((operator
 424     :reader short-combination-operator
 425     :initarg :operator)
 426    (identity-with-one-argument
 427     :reader short-combination-identity-with-one-argument
 428     :initarg :identity-with-one-argument)))
 429
 430 (defclass slot-definition (metaobject)
 431   ((name
 432     :initform nil
 433     :initarg :name
 434     :accessor slot-definition-name)
 435    (initform
 436     :initform nil
 437     :initarg :initform
 438     :accessor slot-definition-initform)
 439    (initfunction
 440     :initform nil
 441     :initarg :initfunction
 442     :accessor slot-definition-initfunction)
 443    (readers
 444     :initform nil
 445     :initarg :readers
 446     :accessor slot-definition-readers)
 447    (writers
 448     :initform nil
 449     :initarg :writers
 450     :accessor slot-definition-writers)
 451    (initargs
 452     :initform nil
 453     :initarg :initargs
 454     :accessor slot-definition-initargs)
 455    (%type :initform t :initarg :type :accessor slot-definition-type)
 456    (%documentation
 457     :initform nil :initarg :documentation
 458     ;; KLUDGE: we need a reader for bootstrapping purposes, in
 459     ;; COMPUTE-EFFECTIVE-SLOT-DEFINITION-INITARGS.
 460     :reader %slot-definition-documentation)
 461    (%class :initform nil :initarg :class :accessor slot-definition-class)))
 462
 463 (defclass standard-slot-definition (slot-definition)
 464   ((allocation
 465     :initform :instance
 466     :initarg :allocation
 467     :accessor slot-definition-allocation)
 468    (allocation-class
 469     :initform nil
 470     :initarg :allocation-class
 471     :accessor slot-definition-allocation-class)))
 472
 473 (defclass condition-slot-definition (slot-definition)
 474   ((allocation
 475     :initform :instance
 476     :initarg :allocation
 477     :accessor slot-definition-allocation)
 478    (allocation-class
 479     :initform nil
 480     :initarg :allocation-class
 481     :accessor slot-definition-allocation-class)))
 482
 483 (defclass structure-slot-definition (slot-definition)
 484   ((defstruct-accessor-symbol
 485      :initform nil
 486      :initarg :defstruct-accessor-symbol
 487      :accessor slot-definition-defstruct-accessor-symbol)
 488    (internal-reader-function
 489      :initform nil
 490      :initarg :internal-reader-function
 491      :accessor slot-definition-internal-reader-function)
 492    (internal-writer-function
 493      :initform nil
 494      :initarg :internal-writer-function
 495      :accessor slot-definition-internal-writer-function)))
 496
 497 (defclass direct-slot-definition (slot-definition)
 498   ())
 499
 500 (defclass effective-slot-definition (slot-definition)
 501   ((accessor-flags
 502     :initform 0)
 503    (info
 504     :accessor slot-definition-info)))
 505
 506 ;;; We use a structure here, because fast slot-accesses to this information
 507 ;;; are critical to making SLOT-VALUE-USING-CLASS &co fast: places that need
 508 ;;; these functions can access the SLOT-INFO directly, avoiding the overhead
 509 ;;; of accessing a standard-instance.
 510 (defstruct (slot-info (:constructor make-slot-info
 511                                     (&key slotd
 512                                           typecheck
 513                                           (type t)
 514                                           (reader
 515                                            (uninitialized-accessor-function :reader slotd))
 516                                           (writer
 517                                            (uninitialized-accessor-function :writer slotd))
 518                                           (boundp
 519                                            (uninitialized-accessor-function :boundp slotd)))))
 520   (typecheck nil :type (or null function))
 521   (reader (missing-arg) :type function)
 522   (writer (missing-arg) :type function)
 523   (boundp (missing-arg) :type function))
 524
 525 (defclass standard-direct-slot-definition (standard-slot-definition
 526                                            direct-slot-definition)
 527   ())
 528
 529 (defclass standard-effective-slot-definition (standard-slot-definition
 530                                               effective-slot-definition)
 531   ((location ; nil, a fixnum, a cons: (slot-name . value)
 532     :initform nil
 533     :accessor slot-definition-location)))
 534
 535 (defclass condition-direct-slot-definition (condition-slot-definition
 536                                             direct-slot-definition)
 537   ())
 538
 539 (defclass condition-effective-slot-definition (condition-slot-definition
 540                                                effective-slot-definition)
 541   ())
 542
 543 (defclass structure-direct-slot-definition (structure-slot-definition
 544                                             direct-slot-definition)
 545   ())
 546
 547 (defclass structure-effective-slot-definition (structure-slot-definition
 548                                                effective-slot-definition)
 549   ())
 550
 551 (defclass specializer (metaobject)
 552   ;; KLUDGE: in sbcl-0.9.10.2 this was renamed from TYPE, which was an
 553   ;; external symbol of the CL package and hence potentially collides
 554   ;; with user code.  Renaming this to %TYPE, however, is the coward's
 555   ;; way out, because the objects that PCL puts in this slot aren't
 556   ;; (quite) types: they are closer to kinds of specializer.  However,
 557   ;; the wholesale renaming and disentangling of specializers didn't
 558   ;; appeal.  (See also message <sqd5hrclb2.fsf@cam.ac.uk> and
 559   ;; responses in comp.lang.lisp).  -- CSR, 2006-02-27
 560   ((%type :initform nil :reader specializer-type)))
 561
 562 ;;; STANDARD in this name doesn't mean "blessed by a standard" but
 563 ;;; "comes as standard with PCL"; that is, it includes CLASS-EQ
 564 ;;; and vestiges of PROTOTYPE specializers
 565 (defclass standard-specializer (specializer) ())
 566
 567 (defclass specializer-with-object (specializer) ())
 568
 569 (defclass exact-class-specializer (specializer) ())
 570
 571 (defclass class-eq-specializer (standard-specializer
 572                                 exact-class-specializer
 573                                 specializer-with-object)
 574   ((object :initarg :class
 575            :reader specializer-class
 576            :reader specializer-object)))
 577
 578 (defclass class-prototype-specializer (standard-specializer specializer-with-object)
 579   ((object :initarg :class
 580            :reader specializer-class
 581            :reader specializer-object)))
 582
 583 (defclass eql-specializer (standard-specializer exact-class-specializer specializer-with-object)
 584   ((object :initarg :object :reader specializer-object
 585            :reader eql-specializer-object)))
 586
 587 (defvar *eql-specializer-table* (make-hash-table :test 'eql))
 588
 589 (defvar *eql-specializer-table-lock*
 590   (sb-thread::make-spinlock :name "EQL-specializer table lock"))
 591
 592 (defun intern-eql-specializer (object)
 593   ;; Need to lock, so that two threads don't get non-EQ specializers
 594   ;; for an EQL object.
 595   (sb-thread::with-spinlock (*eql-specializer-table-lock*)
 596     (or (gethash object *eql-specializer-table*)
 597         (setf (gethash object *eql-specializer-table*)
 598               (make-instance 'eql-specializer :object object)))))
 599
 600 (defclass class (dependent-update-mixin
 601                  definition-source-mixin
 602                  standard-specializer)
 603   ((name
 604     :initform nil
 605     :initarg :name
 606     :reader class-name)
 607    (class-eq-specializer
 608     :initform nil
 609     :reader class-eq-specializer)
 610    (direct-superclasses
 611     :initform ()
 612     :reader class-direct-superclasses)
 613    ;; Note: The (CLASS-)DIRECT-SUBCLASSES for STRUCTURE-CLASSes and
 614    ;; CONDITION-CLASSes are lazily computed whenever the subclass info
 615    ;; becomes available, i.e. when the PCL class is created.
 616    (direct-subclasses
 617     :initform ()
 618     :reader class-direct-subclasses)
 619    (direct-methods
 620     :initform (cons nil nil))
 621    (%documentation
 622     :initform nil
 623     :initarg :documentation)
 624    ;; True if the class definition was compiled with a (SAFETY 3)
 625    ;; optimization policy.
 626    (safe-p
 627     :initform nil
 628     :initarg safe-p
 629     :accessor safe-p)
 630    (finalized-p
 631     :initform nil
 632     :reader class-finalized-p)))
 633
 634 (def!method make-load-form ((class class) &optional env)
 635   ;; FIXME: should we not instead pass ENV to FIND-CLASS?  Probably
 636   ;; doesn't matter while all our environments are the same...
 637   (declare (ignore env))
 638   (let ((name (class-name class)))
 639     (unless (and name (eq (find-class name nil) class))
 640       (error "~@<Can't use anonymous or undefined class as constant: ~S~:@>"
 641              class))
 642     `(find-class ',name)))
 643
 644 ;;; The class PCL-CLASS is an implementation-specific common
 645 ;;; superclass of all specified subclasses of the class CLASS.
 646 (defclass pcl-class (class)
 647   ((%class-precedence-list
 648     :reader class-precedence-list)
 649    ;; KLUDGE: see note in CPL-OR-NIL
 650    (cpl-available-p
 651     :reader cpl-available-p
 652     :initform nil)
 653    (can-precede-list
 654     :initform ()
 655     :reader class-can-precede-list)
 656    (incompatible-superclass-list
 657     :initform ()
 658     :accessor class-incompatible-superclass-list)
 659    (wrapper
 660     :initform nil
 661     :reader class-wrapper)
 662    (prototype
 663     :initform nil
 664     :reader class-prototype)))
 665
 666 (defclass slot-class (pcl-class)
 667   ((direct-slots
 668     :initform ()
 669     :reader class-direct-slots)
 670    (slots
 671     :initform ()
 672     :reader class-slots)))
 673
 674 ;;; The class STD-CLASS is an implementation-specific common
 675 ;;; superclass of the classes STANDARD-CLASS and
 676 ;;; FUNCALLABLE-STANDARD-CLASS.
 677 (defclass std-class (slot-class)
 678   ())
 679
 680 (defclass standard-class (std-class)
 681   ()
 682   (:default-initargs
 683    :direct-superclasses (list *the-class-standard-object*)))
 684
 685 (defclass funcallable-standard-class (std-class)
 686   ()
 687   (:default-initargs
 688    :direct-superclasses (list *the-class-funcallable-standard-object*)))
 689
 690 (defclass forward-referenced-class (pcl-class) ())
 691
 692 (defclass built-in-class (pcl-class) ())
 693
 694 (defclass condition-class (slot-class) ())
 695
 696 (defclass structure-class (slot-class)
 697   ((defstruct-form :initform () :accessor class-defstruct-form)
 698    (defstruct-constructor :initform nil :accessor class-defstruct-constructor)
 699    (from-defclass-p :initform nil :initarg :from-defclass-p)))
 700
 701 (defclass definition-source-mixin (standard-object)
 702   ((source
 703     :initform nil
 704     :reader definition-source
 705     :initarg :definition-source)))
 706
 707 (defclass plist-mixin (standard-object)
 708   ((plist :initform () :accessor object-plist :initarg plist)))
 709
 710 (defclass dependent-update-mixin (plist-mixin) ())
 711
 712 (defparameter *early-class-predicates*
 713   '((specializer specializerp)
 714     (standard-specializer standard-specializer-p)
 715     (exact-class-specializer exact-class-specializer-p)
 716     (class-eq-specializer class-eq-specializer-p)
 717     (eql-specializer eql-specializer-p)
 718     (class classp)
 719     (slot-class slot-class-p)
 720     (std-class std-class-p)
 721     (standard-class standard-class-p)
 722     (funcallable-standard-class funcallable-standard-class-p)
 723     (condition-class condition-class-p)
 724     (structure-class structure-class-p)
 725     (forward-referenced-class forward-referenced-class-p)
 726     (method method-p)
 727     (standard-method standard-method-p)
 728     (accessor-method accessor-method-p)
 729     (standard-accessor-method standard-accessor-method-p)
 730     (standard-reader-method standard-reader-method-p)
 731     (standard-writer-method standard-writer-method-p)
 732     (standard-boundp-method standard-boundp-method-p)
 733     (global-reader-method global-reader-method-p)
 734     (global-writer-method global-writer-method-p)
 735     (global-boundp-method global-boundp-method-p)
 736     (generic-function generic-function-p)
 737     (standard-generic-function standard-generic-function-p)
 738     (method-combination method-combination-p)
 739     (long-method-combination long-method-combination-p)
 740     (short-method-combination short-method-combination-p)))