src/pcl/defs.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; (These are left over from the days when PCL was an add-on package
  27 ;;; for a pre-CLOS Common Lisp. They shouldn't happen in a normal
  28 ;;; build, of course, but they might happen if someone is experimenting
  29 ;;; and debugging, and it's probably worth complaining if they do,
  30 ;;; so we've left 'em in.)
  31 (when (eq *boot-state* 'complete)
  32   (error "Trying to load (or compile) PCL in an environment in which it~%~
  33           has already been loaded. This doesn't work, you will have to~%~
  34           get a fresh lisp (reboot) and then load PCL."))
  35 (when *boot-state*
  36   (cerror "Try loading (or compiling) PCL anyways."
  37           "Trying to load (or compile) PCL in an environment in which it~%~
  38            has already been partially loaded. This may not work, you may~%~
  39            need to get a fresh lisp (reboot) and then load PCL."))
  40 \f
  41 ;;; comments from CMU CL version of PCL:
  42 ;;;     This is like fdefinition on the Lispm. If Common Lisp had
  43 ;;;   something like function specs I wouldn't need this. On the other
  44 ;;;   hand, I don't like the way this really works so maybe function
  45 ;;;   specs aren't really right either?
  46 ;;;     I also don't understand the real implications of a Lisp-1 on this
  47 ;;;   sort of thing. Certainly some of the lossage in all of this is
  48 ;;;   because these SPECs name global definitions.
  49 ;;;     Note that this implementation is set up so that an implementation
  50 ;;;   which has a 'real' function spec mechanism can use that instead
  51 ;;;   and in that way get rid of setf generic function names.
  52 (defmacro parse-gspec (spec
  53                        (non-setf-var . non-setf-case))
  54   `(let ((,non-setf-var ,spec)) ,@non-setf-case))
  55
  56 ;;; If symbol names a function which is traced, return the untraced
  57 ;;; definition. This lets us get at the generic function object even
  58 ;;; when it is traced.
  59 (defun unencapsulated-fdefinition (symbol)
  60   (fdefinition symbol))
  61
  62 ;;; If symbol names a function which is traced, redefine the `real'
  63 ;;; definition without affecting the trace.
  64 (defun fdefine-carefully (name new-definition)
  65   (progn
  66     (sb-c::note-name-defined name :function)
  67     new-definition)
  68   (setf (fdefinition name) new-definition))
  69
  70 (defun gboundp (spec)
  71   (parse-gspec spec
  72     (name (fboundp name))))
  73
  74 (defun gmakunbound (spec)
  75   (parse-gspec spec
  76     (name (fmakunbound name))))
  77
  78 (defun gdefinition (spec)
  79   (parse-gspec spec
  80     (name (unencapsulated-fdefinition name))))
  81
  82 (defun (setf gdefinition) (new-value spec)
  83   (parse-gspec spec
  84     (name (fdefine-carefully name new-value))))
  85 \f
  86 ;;;; type specifier hackery
  87
  88 ;;; internal to this file
  89 (defun coerce-to-class (class &optional make-forward-referenced-class-p)
  90   (if (symbolp class)
  91       (or (find-class class (not make-forward-referenced-class-p))
  92           (ensure-class class))
  93       class))
  94
  95 ;;; interface
  96 (defun specializer-from-type (type &aux args)
  97   (when (consp type)
  98     (setq args (cdr type) type (car type)))
  99   (cond ((symbolp type)
 100          (or (and (null args) (find-class type))
 101              (ecase type
 102                (class    (coerce-to-class (car args)))
 103                (prototype (make-instance 'class-prototype-specializer
 104                                          :object (coerce-to-class (car args))))
 105                (class-eq (class-eq-specializer (coerce-to-class (car args))))
 106                (eql      (intern-eql-specializer (car args))))))
 107         ;; FIXME: do we still need this?
 108         ((and (null args) (typep type 'classoid))
 109          (or (classoid-pcl-class type)
 110              (ensure-non-standard-class (classoid-name type))))
 111         ((specializerp type) type)))
 112
 113 ;;; interface
 114 (defun type-from-specializer (specl)
 115   (cond ((eq specl t)
 116          t)
 117         ((consp specl)
 118          (unless (member (car specl) '(class prototype class-eq eql))
 119            (error "~S is not a legal specializer type." specl))
 120          specl)
 121         ((progn
 122            (when (symbolp specl)
 123              ;;maybe (or (find-class specl nil) (ensure-class specl)) instead?
 124              (setq specl (find-class specl)))
 125            (or (not (eq *boot-state* 'complete))
 126                (specializerp specl)))
 127          (specializer-type specl))
 128         (t
 129          (error "~S is neither a type nor a specializer." specl))))
 130
 131 (defun type-class (type)
 132   (declare (special *the-class-t*))
 133   (setq type (type-from-specializer type))
 134   (if (atom type)
 135       (if (eq type t)
 136           *the-class-t*
 137           (error "bad argument to TYPE-CLASS"))
 138       (case (car type)
 139         (eql (class-of (cadr type)))
 140         (prototype (class-of (cadr type))) ;?
 141         (class-eq (cadr type))
 142         (class (cadr type)))))
 143
 144 (defun class-eq-type (class)
 145   (specializer-type (class-eq-specializer class)))
 146
 147 ;;; internal to this file..
 148 ;;;
 149 ;;; These functions are a pale imitation of their namesake. They accept
 150 ;;; class objects or types where they should.
 151 (defun *normalize-type (type)
 152   (cond ((consp type)
 153          (if (member (car type) '(not and or))
 154              `(,(car type) ,@(mapcar #'*normalize-type (cdr type)))
 155              (if (null (cdr type))
 156                  (*normalize-type (car type))
 157                  type)))
 158         ((symbolp type)
 159          (let ((class (find-class type nil)))
 160            (if class
 161                (let ((type (specializer-type class)))
 162                  (if (listp type) type `(,type)))
 163                `(,type))))
 164         ((or (not (eq *boot-state* 'complete))
 165              (specializerp type))
 166          (specializer-type type))
 167         (t
 168          (error "~S is not a type." type))))
 169
 170 ;;; internal to this file...
 171 (defun convert-to-system-type (type)
 172   (case (car type)
 173     ((not and or) `(,(car type) ,@(mapcar #'convert-to-system-type
 174                                           (cdr type))))
 175     ((class class-eq) ; class-eq is impossible to do right
 176      (layout-classoid (class-wrapper (cadr type))))
 177     (eql type)
 178     (t (if (null (cdr type))
 179            (car type)
 180            type))))
 181
 182 ;;; Writing the missing NOT and AND clauses will improve the quality
 183 ;;; of code generated by GENERATE-DISCRIMINATION-NET, but calling
 184 ;;; SUBTYPEP in place of just returning (VALUES NIL NIL) can be very
 185 ;;; slow. *SUBTYPEP is used by PCL itself, and must be fast.
 186 ;;;
 187 ;;; FIXME: SB-KERNEL has fast-and-not-quite-precise type code for use
 188 ;;; in the compiler. Could we share some of it here?
 189 (defun *subtypep (type1 type2)
 190   (if (equal type1 type2)
 191       (values t t)
 192       (if (eq *boot-state* 'early)
 193           (values (eq type1 type2) t)
 194           (let ((*in-precompute-effective-methods-p* t))
 195             (declare (special *in-precompute-effective-methods-p*))
 196             ;; FIXME: *IN-PRECOMPUTE-EFFECTIVE-METHODS-P* is not a
 197             ;; good name. It changes the way
 198             ;; CLASS-APPLICABLE-USING-CLASS-P works.
 199             (setq type1 (*normalize-type type1))
 200             (setq type2 (*normalize-type type2))
 201             (case (car type2)
 202               (not
 203                (values nil nil)) ; XXX We should improve this.
 204               (and
 205                (values nil nil)) ; XXX We should improve this.
 206               ((eql wrapper-eq class-eq class)
 207                (multiple-value-bind (app-p maybe-app-p)
 208                    (specializer-applicable-using-type-p type2 type1)
 209                  (values app-p (or app-p (not maybe-app-p)))))
 210               (t
 211                (subtypep (convert-to-system-type type1)
 212                          (convert-to-system-type type2))))))))
 213 \f
 214 (defvar *built-in-class-symbols* ())
 215 (defvar *built-in-wrapper-symbols* ())
 216
 217 (defun get-built-in-class-symbol (class-name)
 218   (or (cadr (assq class-name *built-in-class-symbols*))
 219       (let ((symbol (make-class-symbol class-name)))
 220         (push (list class-name symbol) *built-in-class-symbols*)
 221         symbol)))
 222
 223 (defun get-built-in-wrapper-symbol (class-name)
 224   (or (cadr (assq class-name *built-in-wrapper-symbols*))
 225       (let ((symbol (make-wrapper-symbol class-name)))
 226         (push (list class-name symbol) *built-in-wrapper-symbols*)
 227         symbol)))
 228 \f
 229 (pushnew '%class *var-declarations*)
 230 (pushnew '%variable-rebinding *var-declarations*)
 231
 232 (defun variable-class (var env)
 233   (caddr (var-declaration 'class var env)))
 234
 235 (defvar *name->class->slotd-table* (make-hash-table))
 236
 237 (defvar *standard-method-combination*)
 238 \f
 239 (defun make-class-predicate-name (name)
 240   (list 'class-predicate name))
 241
 242 (defun plist-value (object name)
 243   (getf (object-plist object) name))
 244
 245 (defun (setf plist-value) (new-value object name)
 246   (if new-value
 247       (setf (getf (object-plist object) name) new-value)
 248       (progn
 249         (remf (object-plist object) name)
 250         nil)))
 251 \f
 252 ;;;; built-in classes
 253
 254 ;;; Grovel over SB-KERNEL::*BUILT-IN-CLASSES* in order to set
 255 ;;; SB-PCL:*BUILT-IN-CLASSES*.
 256 (/show "about to set up SB-PCL::*BUILT-IN-CLASSES*")
 257 (defvar *built-in-classes*
 258   (labels ((direct-supers (class)
 259              (/noshow "entering DIRECT-SUPERS" (classoid-name class))
 260              (if (typep class 'built-in-classoid)
 261                  (built-in-classoid-direct-superclasses class)
 262                  (let ((inherits (layout-inherits
 263                                   (classoid-layout class))))
 264                    (/noshow inherits)
 265                    (list (svref inherits (1- (length inherits)))))))
 266            (direct-subs (class)
 267              (/noshow "entering DIRECT-SUBS" (classoid-name class))
 268              (collect ((res))
 269                (let ((subs (classoid-subclasses class)))
 270                  (/noshow subs)
 271                  (when subs
 272                    (dohash (sub v subs)
 273                      (declare (ignore v))
 274                      (/noshow sub)
 275                      (when (member class (direct-supers sub))
 276                        (res sub)))))
 277                (res))))
 278     (mapcar (lambda (kernel-bic-entry)
 279               (/noshow "setting up" kernel-bic-entry)
 280               (let* ((name (car kernel-bic-entry))
 281                      (class (find-classoid name))
 282                      (prototype-form
 283                       (getf (cdr kernel-bic-entry) :prototype-form)))
 284                 (/noshow name class)
 285                 `(,name
 286                   ,(mapcar #'classoid-name (direct-supers class))
 287                   ,(mapcar #'classoid-name (direct-subs class))
 288                   ,(map 'list
 289                         (lambda (x)
 290                           (classoid-name
 291                            (layout-classoid x)))
 292                         (reverse
 293                          (layout-inherits
 294                           (classoid-layout class))))
 295                   ,(if prototype-form
 296                        (eval prototype-form)
 297                        ;; This is the default prototype value which
 298                        ;; was used, without explanation, by the CMU CL
 299                        ;; code we're derived from. Evidently it's safe
 300                        ;; in all relevant cases.
 301                        42))))
 302             (remove-if (lambda (kernel-bic-entry)
 303                          (member (first kernel-bic-entry)
 304                                  ;; I'm not sure why these are removed from
 305                                  ;; the list, but that's what the original
 306                                  ;; CMU CL code did. -- WHN 20000715
 307                                  '(t function stream
 308                                      file-stream string-stream)))
 309                        sb-kernel::*built-in-classes*))))
 310 (/noshow "done setting up SB-PCL::*BUILT-IN-CLASSES*")
 311 \f
 312 ;;;; the classes that define the kernel of the metabraid
 313
 314 (defclass t () ()
 315   (:metaclass built-in-class))
 316
 317 (defclass function (t) ()
 318   (:metaclass built-in-class))
 319
 320 (defclass stream (t) ()
 321   (:metaclass built-in-class))
 322
 323 (defclass file-stream (stream) ()
 324   (:metaclass built-in-class))
 325
 326 (defclass string-stream (stream) ()
 327   (:metaclass built-in-class))
 328
 329 (defclass slot-object (t) ()
 330   (:metaclass slot-class))
 331
 332 (defclass condition (slot-object) ()
 333   (:metaclass condition-class))
 334
 335 (defclass structure-object (slot-object) ()
 336   (:metaclass structure-class))
 337
 338 (defstruct (dead-beef-structure-object
 339             (:constructor |STRUCTURE-OBJECT class constructor|)
 340             (:copier nil)))
 341
 342 (defclass std-object (slot-object) ()
 343   (:metaclass std-class))
 344
 345 (defclass standard-object (std-object) ())
 346
 347 (defclass funcallable-standard-object (standard-object function)
 348   ()
 349   (:metaclass funcallable-standard-class))
 350
 351 (defclass specializer (standard-object)
 352   ((type
 353     :initform nil
 354     :reader specializer-type)))
 355
 356 (defclass definition-source-mixin (std-object)
 357   ((source
 358     :initform *load-pathname*
 359     :reader definition-source
 360     :initarg :definition-source))
 361   (:metaclass std-class))
 362
 363 (defclass plist-mixin (std-object)
 364   ((plist
 365     :initform ()
 366     :accessor object-plist))
 367   (:metaclass std-class))
 368
 369 (defclass dependent-update-mixin (plist-mixin)
 370   ()
 371   (:metaclass std-class))
 372
 373 ;;; The class CLASS is a specified basic class. It is the common
 374 ;;; superclass of any kind of class. That is, any class that can be a
 375 ;;; metaclass must have the class CLASS in its class precedence list.
 376 (defclass class (dependent-update-mixin
 377                  definition-source-mixin
 378                  specializer)
 379   ((name
 380     :initform nil
 381     :initarg  :name
 382     :accessor class-name)
 383    (class-eq-specializer
 384     :initform nil
 385     :reader class-eq-specializer)
 386    (direct-superclasses
 387     :initform ()
 388     :reader class-direct-superclasses)
 389    ;; Note: The (CLASS-)DIRECT-SUBCLASSES for STRUCTURE-CLASSes and
 390    ;; CONDITION-CLASSes are lazily computed whenever the subclass info
 391    ;; becomes available, i.e. when the PCL class is created.
 392    (direct-subclasses
 393     :initform ()
 394     :reader class-direct-subclasses)
 395    (direct-methods
 396     :initform (cons nil nil))
 397    (predicate-name
 398     :initform nil
 399     :reader class-predicate-name)
 400    (documentation
 401     :initform nil
 402     :initarg :documentation)
 403    (finalized-p
 404     :initform nil
 405     :reader class-finalized-p)))
 406
 407 (def!method make-load-form ((class class) &optional env)
 408   ;; FIXME: should we not instead pass ENV to FIND-CLASS?  Probably
 409   ;; doesn't matter while all our environments are the same...
 410   (declare (ignore env))
 411   (let ((name (class-name class)))
 412     (unless (and name (eq (find-class name nil) class))
 413       (error "~@<Can't use anonymous or undefined class as constant: ~S~:@>"
 414              class))
 415     `(find-class ',name)))
 416
 417 ;;; The class PCL-CLASS is an implementation-specific common
 418 ;;; superclass of all specified subclasses of the class CLASS.
 419 (defclass pcl-class (class)
 420   ((class-precedence-list
 421     :reader class-precedence-list)
 422    ;; KLUDGE: see note in CPL-OR-NIL
 423    (cpl-available-p
 424     :reader cpl-available-p
 425     :initform nil)
 426    (can-precede-list
 427     :initform ()
 428     :reader class-can-precede-list)
 429    (incompatible-superclass-list
 430     :initform ()
 431     :accessor class-incompatible-superclass-list)
 432    (wrapper
 433     :initform nil
 434     :reader class-wrapper)
 435    (prototype
 436     :initform nil
 437     :reader class-prototype)))
 438
 439 (defclass slot-class (pcl-class)
 440   ((direct-slots
 441     :initform ()
 442     :accessor class-direct-slots)
 443    (slots
 444     :initform ()
 445     :accessor class-slots)))
 446
 447 ;;; The class STD-CLASS is an implementation-specific common
 448 ;;; superclass of the classes STANDARD-CLASS and
 449 ;;; FUNCALLABLE-STANDARD-CLASS.
 450 (defclass std-class (slot-class)
 451   ())
 452
 453 (defclass standard-class (std-class)
 454   ())
 455
 456 (defclass funcallable-standard-class (std-class)
 457   ())
 458
 459 (defclass forward-referenced-class (pcl-class) ())
 460
 461 (defclass built-in-class (pcl-class) ())
 462
 463 (defclass condition-class (slot-class) ())
 464
 465 (defclass structure-class (slot-class)
 466   ((defstruct-form
 467      :initform ()
 468      :accessor class-defstruct-form)
 469    (defstruct-constructor
 470      :initform nil
 471      :accessor class-defstruct-constructor)
 472    (from-defclass-p
 473     :initform nil
 474     :initarg :from-defclass-p)))
 475
 476 (defclass specializer-with-object (specializer) ())
 477
 478 (defclass exact-class-specializer (specializer) ())
 479
 480 (defclass class-eq-specializer (exact-class-specializer
 481                                 specializer-with-object)
 482   ((object :initarg :class
 483            :reader specializer-class
 484            :reader specializer-object)))
 485
 486 (defclass class-prototype-specializer (specializer-with-object)
 487   ((object :initarg :class
 488            :reader specializer-class
 489            :reader specializer-object)))
 490
 491 (defclass eql-specializer (exact-class-specializer specializer-with-object)
 492   ((object :initarg :object :reader specializer-object
 493            :reader eql-specializer-object)))
 494
 495 (defvar *eql-specializer-table* (make-hash-table :test 'eql))
 496
 497 (defun intern-eql-specializer (object)
 498   (or (gethash object *eql-specializer-table*)
 499       (setf (gethash object *eql-specializer-table*)
 500             (make-instance 'eql-specializer :object object))))
 501 \f
 502 ;;;; slot definitions
 503
 504 (defclass slot-definition (standard-object)
 505   ((name
 506     :initform nil
 507     :initarg :name
 508     :accessor slot-definition-name)
 509    (initform
 510     :initform nil
 511     :initarg :initform
 512     :accessor slot-definition-initform)
 513    (initfunction
 514     :initform nil
 515     :initarg :initfunction
 516     :accessor slot-definition-initfunction)
 517    (readers
 518     :initform nil
 519     :initarg :readers
 520     :accessor slot-definition-readers)
 521    (writers
 522     :initform nil
 523     :initarg :writers
 524     :accessor slot-definition-writers)
 525    (initargs
 526     :initform nil
 527     :initarg :initargs
 528     :accessor slot-definition-initargs)
 529    (type
 530     :initform t
 531     :initarg :type
 532     :accessor slot-definition-type)
 533    (documentation
 534     :initform nil
 535     :initarg :documentation)
 536    (class
 537     :initform nil
 538     :initarg :class
 539     :accessor slot-definition-class)))
 540
 541 (defclass standard-slot-definition (slot-definition)
 542   ((allocation
 543     :initform :instance
 544     :initarg :allocation
 545     :accessor slot-definition-allocation)
 546    (allocation-class
 547     :initform nil
 548     :initarg :allocation-class
 549     :accessor slot-definition-allocation-class)))
 550
 551 (defclass condition-slot-definition (slot-definition)
 552   ((allocation
 553     :initform :instance
 554     :initarg :allocation
 555     :accessor slot-definition-allocation)
 556    (allocation-class
 557     :initform nil
 558     :initarg :allocation-class
 559     :accessor slot-definition-allocation-class)))
 560
 561 (defclass structure-slot-definition (slot-definition)
 562   ((defstruct-accessor-symbol
 563      :initform nil
 564      :initarg :defstruct-accessor-symbol
 565      :accessor slot-definition-defstruct-accessor-symbol)
 566    (internal-reader-function
 567      :initform nil
 568      :initarg :internal-reader-function
 569      :accessor slot-definition-internal-reader-function)
 570    (internal-writer-function
 571      :initform nil
 572      :initarg :internal-writer-function
 573      :accessor slot-definition-internal-writer-function)))
 574
 575 (defclass direct-slot-definition (slot-definition)
 576   ())
 577
 578 (defclass effective-slot-definition (slot-definition)
 579   ((reader-function ; (lambda (object) ...)
 580     :accessor slot-definition-reader-function)
 581    (writer-function ; (lambda (new-value object) ...)
 582     :accessor slot-definition-writer-function)
 583    (boundp-function ; (lambda (object) ...)
 584     :accessor slot-definition-boundp-function)
 585    (accessor-flags
 586     :initform 0)))
 587
 588 (defclass standard-direct-slot-definition (standard-slot-definition
 589                                            direct-slot-definition)
 590   ())
 591
 592 (defclass standard-effective-slot-definition (standard-slot-definition
 593                                               effective-slot-definition)
 594   ((location ; nil, a fixnum, a cons: (slot-name . value)
 595     :initform nil
 596     :accessor slot-definition-location)))
 597
 598 (defclass condition-direct-slot-definition (condition-slot-definition
 599                                             direct-slot-definition)
 600   ())
 601
 602 (defclass condition-effective-slot-definition (condition-slot-definition
 603                                                effective-slot-definition)
 604   ())
 605
 606 (defclass structure-direct-slot-definition (structure-slot-definition
 607                                             direct-slot-definition)
 608   ())
 609
 610 (defclass structure-effective-slot-definition (structure-slot-definition
 611                                                effective-slot-definition)
 612   ())
 613
 614 (defclass method (standard-object) ())
 615
 616 (defclass standard-method (definition-source-mixin plist-mixin method)
 617   ((generic-function
 618     :initform nil
 619     :accessor method-generic-function)
 620 ;;;     (qualifiers
 621 ;;;     :initform ()
 622 ;;;     :initarg  :qualifiers
 623 ;;;     :reader method-qualifiers)
 624    (specializers
 625     :initform ()
 626     :initarg  :specializers
 627     :reader method-specializers)
 628    (lambda-list
 629     :initform ()
 630     :initarg  :lambda-list
 631     :reader method-lambda-list)
 632    (function
 633     :initform nil
 634     :initarg :function)                 ;no writer
 635    (fast-function
 636     :initform nil
 637     :initarg :fast-function             ;no writer
 638     :reader method-fast-function)
 639    (documentation
 640     :initform nil
 641     :initarg :documentation)))
 642
 643 (defclass standard-accessor-method (standard-method)
 644   ((slot-name :initform nil
 645               :initarg :slot-name
 646               :reader accessor-method-slot-name)
 647    (slot-definition :initform nil
 648                     :initarg :slot-definition
 649                     :reader accessor-method-slot-definition)))
 650
 651 (defclass standard-reader-method (standard-accessor-method) ())
 652
 653 (defclass standard-writer-method (standard-accessor-method) ())
 654
 655 (defclass standard-boundp-method (standard-accessor-method) ())
 656
 657 (defclass generic-function (dependent-update-mixin
 658                             definition-source-mixin
 659                             funcallable-standard-object)
 660   ((documentation
 661     :initform nil
 662     :initarg :documentation)
 663    ;; We need to make a distinction between the methods initially set
 664    ;; up by :METHOD options to DEFGENERIC and the ones set up later by
 665    ;; DEFMETHOD, because ANSI specifies that executing DEFGENERIC on
 666    ;; an already-DEFGENERICed function clears the methods set by the
 667    ;; previous DEFGENERIC, but not methods set by DEFMETHOD. (Making
 668    ;; this distinction seems a little kludgy, but it has the positive
 669    ;; effect of making it so that loading a file a.lisp containing
 670    ;; DEFGENERIC, then loading a second file b.lisp containing
 671    ;; DEFMETHOD, then modifying and reloading a.lisp and/or b.lisp
 672    ;; tends to leave the generic function in a state consistent with
 673    ;; the most-recently-loaded state of a.lisp and b.lisp.)
 674    (initial-methods
 675     :initform ()
 676     :accessor generic-function-initial-methods))
 677   (:metaclass funcallable-standard-class))
 678
 679 (defclass standard-generic-function (generic-function)
 680   ((name
 681     :initform nil
 682     :initarg :name
 683     :accessor generic-function-name)
 684    (methods
 685     :initform ()
 686     :accessor generic-function-methods
 687     :type list)
 688    (method-class
 689     :initarg :method-class
 690     :accessor generic-function-method-class)
 691    (method-combination
 692     :initarg :method-combination
 693     :accessor generic-function-method-combination)
 694    (declarations
 695     ;; KLUDGE: AMOP specifies :DECLARATIONS, while ANSI specifies
 696     ;; :DECLARE.  Allow either (but FIXME: maybe a note or a warning
 697     ;; might be appropriate).
 698     :initarg :declarations
 699     :initarg :declare
 700     :initform ()
 701     :accessor generic-function-declarations)
 702    (arg-info
 703     :initform (make-arg-info)
 704     :reader gf-arg-info)
 705    (dfun-state
 706     :initform ()
 707     :accessor gf-dfun-state))
 708   (:metaclass funcallable-standard-class)
 709   (:default-initargs :method-class *the-class-standard-method*
 710                      :method-combination *standard-method-combination*))
 711
 712 (defclass method-combination (standard-object)
 713   ((documentation
 714     :reader method-combination-documentation
 715     :initform nil
 716     :initarg :documentation)))
 717
 718 (defclass standard-method-combination (definition-source-mixin
 719                                        method-combination)
 720   ((type
 721     :reader method-combination-type
 722     :initarg :type)
 723    (options
 724     :reader method-combination-options
 725     :initarg :options)))
 726
 727 (defclass long-method-combination (standard-method-combination)
 728   ((function
 729     :initarg :function
 730     :reader long-method-combination-function)
 731    (args-lambda-list
 732     :initarg :args-lambda-list
 733     :reader long-method-combination-args-lambda-list)))
 734
 735 (defparameter *early-class-predicates*
 736   '((specializer specializerp)
 737     (exact-class-specializer exact-class-specializer-p)
 738     (class-eq-specializer class-eq-specializer-p)
 739     (eql-specializer eql-specializer-p)
 740     (class classp)
 741     (slot-class slot-class-p)
 742     (std-class std-class-p)
 743     (standard-class standard-class-p)
 744     (funcallable-standard-class funcallable-standard-class-p)
 745     (condition-class condition-class-p)
 746     (structure-class structure-class-p)
 747     (forward-referenced-class forward-referenced-class-p)
 748     (method method-p)
 749     (standard-method standard-method-p)
 750     (standard-accessor-method standard-accessor-method-p)
 751     (standard-reader-method standard-reader-method-p)
 752     (standard-writer-method standard-writer-method-p)
 753     (standard-boundp-method standard-boundp-method-p)
 754     (generic-function generic-function-p)
 755     (standard-generic-function standard-generic-function-p)
 756     (method-combination method-combination-p)
 757     (long-method-combination long-method-combination-p)))
 758