src/pcl/defs.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; (These are left over from the days when PCL was an add-on package
  27 ;;; for a pre-CLOS Common Lisp. They shouldn't happen in a normal
  28 ;;; build, of course, but they might happen if someone is experimenting
  29 ;;; and debugging, and it's probably worth complaining if they do,
  30 ;;; so we've left 'em in.)
  31 (when (eq *boot-state* 'complete)
  32   (error "Trying to load (or compile) PCL in an environment in which it~%~
  33           has already been loaded. This doesn't work, you will have to~%~
  34           get a fresh lisp (reboot) and then load PCL."))
  35 (when *boot-state*
  36   (cerror "Try loading (or compiling) PCL anyways."
  37           "Trying to load (or compile) PCL in an environment in which it~%~
  38            has already been partially loaded. This may not work, you may~%~
  39            need to get a fresh lisp (reboot) and then load PCL."))
  40 \f
  41 ;;; comments from CMU CL version of PCL:
  42 ;;;     This is like fdefinition on the Lispm. If Common Lisp had
  43 ;;;   something like function specs I wouldn't need this. On the other
  44 ;;;   hand, I don't like the way this really works so maybe function
  45 ;;;   specs aren't really right either?
  46 ;;;     I also don't understand the real implications of a Lisp-1 on this
  47 ;;;   sort of thing. Certainly some of the lossage in all of this is
  48 ;;;   because these SPECs name global definitions.
  49 ;;;     Note that this implementation is set up so that an implementation
  50 ;;;   which has a 'real' function spec mechanism can use that instead
  51 ;;;   and in that way get rid of setf generic function names.
  52 (defmacro parse-gspec (spec
  53                        (non-setf-var . non-setf-case))
  54   `(let ((,non-setf-var ,spec)) ,@non-setf-case))
  55
  56 ;;; If symbol names a function which is traced, return the untraced
  57 ;;; definition. This lets us get at the generic function object even
  58 ;;; when it is traced.
  59 (defun unencapsulated-fdefinition (symbol)
  60   (fdefinition symbol))
  61
  62 ;;; If symbol names a function which is traced, redefine the `real'
  63 ;;; definition without affecting the trace.
  64 (defun fdefine-carefully (name new-definition)
  65   (progn
  66     (sb-c::note-name-defined name :function)
  67     new-definition)
  68   (setf (fdefinition name) new-definition))
  69
  70 (defun gboundp (spec)
  71   (parse-gspec spec
  72     (name (fboundp name))))
  73
  74 (defun gmakunbound (spec)
  75   (parse-gspec spec
  76     (name (fmakunbound name))))
  77
  78 (defun gdefinition (spec)
  79   (parse-gspec spec
  80     (name (unencapsulated-fdefinition name))))
  81
  82 (defun (setf gdefinition) (new-value spec)
  83   (parse-gspec spec
  84     (name (fdefine-carefully name new-value))))
  85 \f
  86 (declaim (special *the-class-t*
  87                   *the-class-vector* *the-class-symbol*
  88                   *the-class-string* *the-class-sequence*
  89                   *the-class-rational* *the-class-ratio*
  90                   *the-class-number* *the-class-null* *the-class-list*
  91                   *the-class-integer* *the-class-float* *the-class-cons*
  92                   *the-class-complex* *the-class-character*
  93                   *the-class-bit-vector* *the-class-array*
  94                   *the-class-stream*
  95
  96                   *the-class-slot-object*
  97                   *the-class-structure-object*
  98                   *the-class-std-object*
  99                   *the-class-standard-object*
 100                   *the-class-funcallable-standard-object*
 101                   *the-class-class*
 102                   *the-class-generic-function*
 103                   *the-class-built-in-class*
 104                   *the-class-slot-class*
 105                   *the-class-structure-class*
 106                   *the-class-std-class*
 107                   *the-class-standard-class*
 108                   *the-class-funcallable-standard-class*
 109                   *the-class-method*
 110                   *the-class-standard-method*
 111                   *the-class-standard-reader-method*
 112                   *the-class-standard-writer-method*
 113                   *the-class-standard-boundp-method*
 114                   *the-class-standard-generic-function*
 115                   *the-class-standard-effective-slot-definition*
 116
 117                   *the-eslotd-standard-class-slots*
 118                   *the-eslotd-funcallable-standard-class-slots*))
 119
 120 (declaim (special *the-wrapper-of-t*
 121                   *the-wrapper-of-vector* *the-wrapper-of-symbol*
 122                   *the-wrapper-of-string* *the-wrapper-of-sequence*
 123                   *the-wrapper-of-rational* *the-wrapper-of-ratio*
 124                   *the-wrapper-of-number* *the-wrapper-of-null*
 125                   *the-wrapper-of-list* *the-wrapper-of-integer*
 126                   *the-wrapper-of-float* *the-wrapper-of-cons*
 127                   *the-wrapper-of-complex* *the-wrapper-of-character*
 128                   *the-wrapper-of-bit-vector* *the-wrapper-of-array*))
 129 \f
 130 ;;;; type specifier hackery
 131
 132 ;;; internal to this file
 133 (defun coerce-to-class (class &optional make-forward-referenced-class-p)
 134   (if (symbolp class)
 135       (or (find-class class (not make-forward-referenced-class-p))
 136           (ensure-class class))
 137       class))
 138
 139 ;;; interface
 140 (defun specializer-from-type (type &aux args)
 141   (when (consp type)
 142     (setq args (cdr type) type (car type)))
 143   (cond ((symbolp type)
 144          (or (and (null args) (find-class type))
 145              (ecase type
 146                (class    (coerce-to-class (car args)))
 147                (prototype (make-instance 'class-prototype-specializer
 148                                          :object (coerce-to-class (car args))))
 149                (class-eq (class-eq-specializer (coerce-to-class (car args))))
 150                (eql      (intern-eql-specializer (car args))))))
 151         ;; FIXME: do we still need this?
 152         ((and (null args) (typep type 'classoid))
 153          (or (classoid-pcl-class type)
 154              (ensure-non-standard-class (classoid-name type))))
 155         ((specializerp type) type)))
 156
 157 ;;; interface
 158 (defun type-from-specializer (specl)
 159   (cond ((eq specl t)
 160          t)
 161         ((consp specl)
 162          (unless (member (car specl) '(class prototype class-eq eql))
 163            (error "~S is not a legal specializer type." specl))
 164          specl)
 165         ((progn
 166            (when (symbolp specl)
 167              ;;maybe (or (find-class specl nil) (ensure-class specl)) instead?
 168              (setq specl (find-class specl)))
 169            (or (not (eq *boot-state* 'complete))
 170                (specializerp specl)))
 171          (specializer-type specl))
 172         (t
 173          (error "~S is neither a type nor a specializer." specl))))
 174
 175 (defun type-class (type)
 176   (declare (special *the-class-t*))
 177   (setq type (type-from-specializer type))
 178   (if (atom type)
 179       (if (eq type t)
 180           *the-class-t*
 181           (error "bad argument to TYPE-CLASS"))
 182       (case (car type)
 183         (eql (class-of (cadr type)))
 184         (prototype (class-of (cadr type))) ;?
 185         (class-eq (cadr type))
 186         (class (cadr type)))))
 187
 188 (defun class-eq-type (class)
 189   (specializer-type (class-eq-specializer class)))
 190
 191 ;;; internal to this file..
 192 ;;;
 193 ;;; These functions are a pale imitation of their namesake. They accept
 194 ;;; class objects or types where they should.
 195 (defun *normalize-type (type)
 196   (cond ((consp type)
 197          (if (member (car type) '(not and or))
 198              `(,(car type) ,@(mapcar #'*normalize-type (cdr type)))
 199              (if (null (cdr type))
 200                  (*normalize-type (car type))
 201                  type)))
 202         ((symbolp type)
 203          (let ((class (find-class type nil)))
 204            (if class
 205                (let ((type (specializer-type class)))
 206                  (if (listp type) type `(,type)))
 207                `(,type))))
 208         ((or (not (eq *boot-state* 'complete))
 209              (specializerp type))
 210          (specializer-type type))
 211         (t
 212          (error "~S is not a type." type))))
 213
 214 ;;; internal to this file...
 215 (defun convert-to-system-type (type)
 216   (case (car type)
 217     ((not and or) `(,(car type) ,@(mapcar #'convert-to-system-type
 218                                           (cdr type))))
 219     ((class class-eq) ; class-eq is impossible to do right
 220      (layout-classoid (class-wrapper (cadr type))))
 221     (eql type)
 222     (t (if (null (cdr type))
 223            (car type)
 224            type))))
 225
 226 ;;; Writing the missing NOT and AND clauses will improve the quality
 227 ;;; of code generated by GENERATE-DISCRIMINATION-NET, but calling
 228 ;;; SUBTYPEP in place of just returning (VALUES NIL NIL) can be very
 229 ;;; slow. *SUBTYPEP is used by PCL itself, and must be fast.
 230 ;;;
 231 ;;; FIXME: SB-KERNEL has fast-and-not-quite-precise type code for use
 232 ;;; in the compiler. Could we share some of it here?
 233 (defun *subtypep (type1 type2)
 234   (if (equal type1 type2)
 235       (values t t)
 236       (if (eq *boot-state* 'early)
 237           (values (eq type1 type2) t)
 238           (let ((*in-precompute-effective-methods-p* t))
 239             (declare (special *in-precompute-effective-methods-p*))
 240             ;; FIXME: *IN-PRECOMPUTE-EFFECTIVE-METHODS-P* is not a
 241             ;; good name. It changes the way
 242             ;; CLASS-APPLICABLE-USING-CLASS-P works.
 243             (setq type1 (*normalize-type type1))
 244             (setq type2 (*normalize-type type2))
 245             (case (car type2)
 246               (not
 247                (values nil nil)) ; XXX We should improve this.
 248               (and
 249                (values nil nil)) ; XXX We should improve this.
 250               ((eql wrapper-eq class-eq class)
 251                (multiple-value-bind (app-p maybe-app-p)
 252                    (specializer-applicable-using-type-p type2 type1)
 253                  (values app-p (or app-p (not maybe-app-p)))))
 254               (t
 255                (subtypep (convert-to-system-type type1)
 256                          (convert-to-system-type type2))))))))
 257 \f
 258 (defvar *built-in-class-symbols* ())
 259 (defvar *built-in-wrapper-symbols* ())
 260
 261 (defun get-built-in-class-symbol (class-name)
 262   (or (cadr (assq class-name *built-in-class-symbols*))
 263       (let ((symbol (intern (format nil
 264                                     "*THE-CLASS-~A*"
 265                                     (symbol-name class-name))
 266                             *pcl-package*)))
 267         (push (list class-name symbol) *built-in-class-symbols*)
 268         symbol)))
 269
 270 (defun get-built-in-wrapper-symbol (class-name)
 271   (or (cadr (assq class-name *built-in-wrapper-symbols*))
 272       (let ((symbol (intern (format nil
 273                                     "*THE-WRAPPER-OF-~A*"
 274                                     (symbol-name class-name))
 275                             *pcl-package*)))
 276         (push (list class-name symbol) *built-in-wrapper-symbols*)
 277         symbol)))
 278 \f
 279 (pushnew '%class *var-declarations*)
 280 (pushnew '%variable-rebinding *var-declarations*)
 281
 282 (defun variable-class (var env)
 283   (caddr (var-declaration 'class var env)))
 284
 285 (defvar *name->class->slotd-table* (make-hash-table))
 286
 287 (defvar *standard-method-combination*)
 288 \f
 289 (defun make-class-predicate-name (name)
 290   (list 'class-predicate name))
 291
 292 (defun plist-value (object name)
 293   (getf (object-plist object) name))
 294
 295 (defun (setf plist-value) (new-value object name)
 296   (if new-value
 297       (setf (getf (object-plist object) name) new-value)
 298       (progn
 299         (remf (object-plist object) name)
 300         nil)))
 301 \f
 302 ;;;; built-in classes
 303
 304 ;;; FIXME: This was the portable PCL way of setting up
 305 ;;; *BUILT-IN-CLASSES*, but in SBCL (as in CMU CL) it's almost
 306 ;;; entirely wasted motion, since it's immediately overwritten by a
 307 ;;; result mostly derived from SB-KERNEL::*BUILT-IN-CLASSES*. However,
 308 ;;; we can't just delete it, since the fifth element from each entry
 309 ;;; (a prototype of the class) is still in the final result. It would
 310 ;;; be nice to clean this up so that the other, never-used stuff is
 311 ;;; gone, perhaps finding a tidier way to represent examples of each
 312 ;;; class, too.
 313 ;;;
 314 ;;; FIXME: This can probably be blown away after bootstrapping.
 315 ;;; And SB-KERNEL::*BUILT-IN-CLASSES*, too..
 316 #|
 317 (defvar *built-in-classes*
 318   ;; name       supers     subs              cdr of cpl
 319   ;; prototype
 320   '(;(t  ()      (number sequence array character symbol) ())
 321     (number     (t)     (complex float rational) (t))
 322     (complex    (number)   ()                  (number t)
 323      #c(1 1))
 324     (float      (number)   ()                  (number t)
 325      1.0)
 326     (rational   (number)   (integer ratio)        (number t))
 327     (integer    (rational) ()                  (rational number t)
 328      1)
 329     (ratio      (rational) ()                  (rational number t)
 330      1/2)
 331
 332     (sequence   (t)     (list vector)       (t))
 333     (list       (sequence) (cons null)        (sequence t))
 334     (cons       (list)     ()                  (list sequence t)
 335      (nil))
 336
 337     (array      (t)     (vector)                 (t)
 338      #2A((nil)))
 339     (vector     (array
 340                  sequence) (string bit-vector)      (array sequence t)
 341      #())
 342     (string     (vector)   ()                  (vector array sequence t)
 343      "")
 344     (bit-vector (vector)   ()                  (vector array sequence t)
 345      #*1)
 346     (character  (t)     ()                     (t)
 347      #\c)
 348
 349     (symbol     (t)     (null)             (t)
 350      symbol)
 351     (null       (symbol
 352                  list)     ()                  (symbol list sequence t)
 353      nil)))
 354 |#
 355
 356 ;;; Grovel over SB-KERNEL::*BUILT-IN-CLASSES* in order to set
 357 ;;; SB-PCL:*BUILT-IN-CLASSES*.
 358 (/show "about to set up SB-PCL::*BUILT-IN-CLASSES*")
 359 (defvar *built-in-classes*
 360   (labels ((direct-supers (class)
 361              (/noshow "entering DIRECT-SUPERS" (classoid-name class))
 362              (if (typep class 'built-in-classoid)
 363                  (built-in-classoid-direct-superclasses class)
 364                  (let ((inherits (layout-inherits
 365                                   (classoid-layout class))))
 366                    (/noshow inherits)
 367                    (list (svref inherits (1- (length inherits)))))))
 368            (direct-subs (class)
 369              (/noshow "entering DIRECT-SUBS" (classoid-name class))
 370              (collect ((res))
 371                (let ((subs (classoid-subclasses class)))
 372                  (/noshow subs)
 373                  (when subs
 374                    (dohash (sub v subs)
 375                      (declare (ignore v))
 376                      (/noshow sub)
 377                      (when (member class (direct-supers sub))
 378                        (res sub)))))
 379                (res)))
 380            (prototype (class-name)
 381              (let ((assoc (assoc class-name
 382                                  '((complex    . #c(1 1))
 383                                    (float      . 1.0)
 384                                    (integer    . 1)
 385                                    (ratio      . 1/2)
 386                                    (sequence   . nil)
 387                                    (list       . nil)
 388                                    (cons       . (nil))
 389                                    (array      . #2a((nil)))
 390                                    (vector     . #())
 391                                    (string     . "")
 392                                    (bit-vector . #*1)
 393                                    (character  . #\c)
 394                                    (symbol     . symbol)
 395                                    (null       . nil)))))
 396                (if assoc
 397                    (cdr assoc)
 398                    ;; This is the default prototype value which was
 399                    ;; used, without explanation, by the CMU CL code
 400                    ;; we're derived from. Evidently it's safe in all
 401                    ;; relevant cases.
 402                    42))))
 403     (mapcar (lambda (kernel-bic-entry)
 404               (/noshow "setting up" kernel-bic-entry)
 405               (let* ((name (car kernel-bic-entry))
 406                      (class (find-classoid name)))
 407                 (/noshow name class)
 408                 `(,name
 409                   ,(mapcar #'classoid-name (direct-supers class))
 410                   ,(mapcar #'classoid-name (direct-subs class))
 411                   ,(map 'list
 412                         (lambda (x)
 413                           (classoid-name
 414                            (layout-classoid x)))
 415                         (reverse
 416                          (layout-inherits
 417                           (classoid-layout class))))
 418                   ,(prototype name))))
 419             (remove-if (lambda (kernel-bic-entry)
 420                          (member (first kernel-bic-entry)
 421                                  ;; I'm not sure why these are removed from
 422                                  ;; the list, but that's what the original
 423                                  ;; CMU CL code did. -- WHN 20000715
 424                                  '(t instance
 425                                      funcallable-instance
 426                                      function stream)))
 427                        sb-kernel::*built-in-classes*))))
 428 (/noshow "done setting up SB-PCL::*BUILT-IN-CLASSES*")
 429 \f
 430 ;;;; the classes that define the kernel of the metabraid
 431
 432 (defclass t () ()
 433   (:metaclass built-in-class))
 434
 435 (defclass instance (t) ()
 436   (:metaclass built-in-class))
 437
 438 (defclass function (t) ()
 439   (:metaclass built-in-class))
 440
 441 (defclass funcallable-instance (function) ()
 442   (:metaclass built-in-class))
 443
 444 (defclass stream (instance) ()
 445   (:metaclass built-in-class))
 446
 447 (defclass slot-object (t) ()
 448   (:metaclass slot-class))
 449
 450 (defclass structure-object (slot-object instance) ()
 451   (:metaclass structure-class))
 452
 453 (defstruct (dead-beef-structure-object
 454             (:constructor |STRUCTURE-OBJECT class constructor|)
 455             (:copier nil)))
 456
 457 (defclass std-object (slot-object) ()
 458   (:metaclass std-class))
 459
 460 (defclass standard-object (std-object instance) ())
 461
 462 (defclass funcallable-standard-object (std-object funcallable-instance)
 463   ()
 464   (:metaclass funcallable-standard-class))
 465
 466 (defclass specializer (standard-object)
 467   ((type
 468     :initform nil
 469     :reader specializer-type)))
 470
 471 (defclass definition-source-mixin (std-object)
 472   ((source
 473     :initform *load-pathname*
 474     :reader definition-source
 475     :initarg :definition-source))
 476   (:metaclass std-class))
 477
 478 (defclass plist-mixin (std-object)
 479   ((plist
 480     :initform ()
 481     :accessor object-plist))
 482   (:metaclass std-class))
 483
 484 (defclass documentation-mixin (plist-mixin)
 485   ()
 486   (:metaclass std-class))
 487
 488 (defclass dependent-update-mixin (plist-mixin)
 489   ()
 490   (:metaclass std-class))
 491
 492 ;;; The class CLASS is a specified basic class. It is the common
 493 ;;; superclass of any kind of class. That is, any class that can be a
 494 ;;; metaclass must have the class CLASS in its class precedence list.
 495 (defclass class (documentation-mixin
 496                  dependent-update-mixin
 497                  definition-source-mixin
 498                  specializer)
 499   ((name
 500     :initform nil
 501     :initarg  :name
 502     :accessor class-name)
 503    (class-eq-specializer
 504     :initform nil
 505     :reader class-eq-specializer)
 506    (direct-superclasses
 507     :initform ()
 508     :reader class-direct-superclasses)
 509    ;; Note: The (CLASS-)DIRECT-SUBCLASSES for STRUCTURE-CLASSes and
 510    ;; CONDITION-CLASSes are lazily computed whenever the subclass info
 511    ;; becomes available, i.e. when the PCL class is created.
 512    (direct-subclasses
 513     :initform ()
 514     :reader class-direct-subclasses)
 515    (direct-methods
 516     :initform (cons nil nil))
 517    (predicate-name
 518     :initform nil
 519     :reader class-predicate-name)))
 520
 521 ;;; The class PCL-CLASS is an implementation-specific common
 522 ;;; superclass of all specified subclasses of the class CLASS.
 523 (defclass pcl-class (class)
 524   ((class-precedence-list
 525     :reader class-precedence-list)
 526    (can-precede-list
 527     :initform ()
 528     :reader class-can-precede-list)
 529    (incompatible-superclass-list
 530     :initform ()
 531     :accessor class-incompatible-superclass-list)
 532    (wrapper
 533     :initform nil
 534     :reader class-wrapper)
 535    (prototype
 536     :initform nil
 537     :reader class-prototype)))
 538
 539 (defclass slot-class (pcl-class)
 540   ((direct-slots
 541     :initform ()
 542     :accessor class-direct-slots)
 543    (slots
 544     :initform ()
 545     :accessor class-slots)
 546    (initialize-info
 547     :initform nil
 548     :accessor class-initialize-info)))
 549
 550 ;;; The class STD-CLASS is an implementation-specific common
 551 ;;; superclass of the classes STANDARD-CLASS and
 552 ;;; FUNCALLABLE-STANDARD-CLASS.
 553 (defclass std-class (slot-class)
 554   ())
 555
 556 (defclass standard-class (std-class)
 557   ())
 558
 559 (defclass funcallable-standard-class (std-class)
 560   ())
 561
 562 (defclass forward-referenced-class (pcl-class) ())
 563
 564 (defclass built-in-class (pcl-class) ())
 565
 566 (defclass condition-class (pcl-class) ())
 567
 568 (defclass structure-class (slot-class)
 569   ((defstruct-form
 570      :initform ()
 571      :accessor class-defstruct-form)
 572    (defstruct-constructor
 573      :initform nil
 574      :accessor class-defstruct-constructor)
 575    (from-defclass-p
 576     :initform nil
 577     :initarg :from-defclass-p)))
 578
 579 (defclass specializer-with-object (specializer) ())
 580
 581 (defclass exact-class-specializer (specializer) ())
 582
 583 (defclass class-eq-specializer (exact-class-specializer
 584                                 specializer-with-object)
 585   ((object :initarg :class
 586            :reader specializer-class
 587            :reader specializer-object)))
 588
 589 (defclass class-prototype-specializer (specializer-with-object)
 590   ((object :initarg :class
 591            :reader specializer-class
 592            :reader specializer-object)))
 593
 594 (defclass eql-specializer (exact-class-specializer specializer-with-object)
 595   ((object :initarg :object :reader specializer-object
 596            :reader eql-specializer-object)))
 597
 598 (defvar *eql-specializer-table* (make-hash-table :test 'eql))
 599
 600 (defun intern-eql-specializer (object)
 601   (or (gethash object *eql-specializer-table*)
 602       (setf (gethash object *eql-specializer-table*)
 603             (make-instance 'eql-specializer :object object))))
 604 \f
 605 ;;;; slot definitions
 606
 607 (defclass slot-definition (standard-object)
 608   ((name
 609     :initform nil
 610     :initarg :name
 611     :accessor slot-definition-name)
 612    (initform
 613     :initform nil
 614     :initarg :initform
 615     :accessor slot-definition-initform)
 616    (initfunction
 617     :initform nil
 618     :initarg :initfunction
 619     :accessor slot-definition-initfunction)
 620    (readers
 621     :initform nil
 622     :initarg :readers
 623     :accessor slot-definition-readers)
 624    (writers
 625     :initform nil
 626     :initarg :writers
 627     :accessor slot-definition-writers)
 628    (initargs
 629     :initform nil
 630     :initarg :initargs
 631     :accessor slot-definition-initargs)
 632    (type
 633     :initform t
 634     :initarg :type
 635     :accessor slot-definition-type)
 636    (documentation
 637     :initform ""
 638     :initarg :documentation)
 639    (class
 640     :initform nil
 641     :initarg :class
 642     :accessor slot-definition-class)))
 643
 644 (defclass standard-slot-definition (slot-definition)
 645   ((allocation
 646     :initform :instance
 647     :initarg :allocation
 648     :accessor slot-definition-allocation)
 649    (allocation-class
 650     :initform nil
 651     :initarg :allocation-class
 652     :accessor slot-definition-allocation-class)))
 653
 654 (defclass structure-slot-definition (slot-definition)
 655   ((defstruct-accessor-symbol
 656      :initform nil
 657      :initarg :defstruct-accessor-symbol
 658      :accessor slot-definition-defstruct-accessor-symbol)
 659    (internal-reader-function
 660      :initform nil
 661      :initarg :internal-reader-function
 662      :accessor slot-definition-internal-reader-function)
 663    (internal-writer-function
 664      :initform nil
 665      :initarg :internal-writer-function
 666      :accessor slot-definition-internal-writer-function)))
 667
 668 (defclass direct-slot-definition (slot-definition)
 669   ())
 670
 671 (defclass effective-slot-definition (slot-definition)
 672   ((reader-function ; (lambda (object) ...)
 673     :accessor slot-definition-reader-function)
 674    (writer-function ; (lambda (new-value object) ...)
 675     :accessor slot-definition-writer-function)
 676    (boundp-function ; (lambda (object) ...)
 677     :accessor slot-definition-boundp-function)
 678    (accessor-flags
 679     :initform 0)))
 680
 681 (defclass standard-direct-slot-definition (standard-slot-definition
 682                                            direct-slot-definition)
 683   ())
 684
 685 (defclass standard-effective-slot-definition (standard-slot-definition
 686                                               effective-slot-definition)
 687   ((location ; nil, a fixnum, a cons: (slot-name . value)
 688     :initform nil
 689     :accessor slot-definition-location)))
 690
 691 (defclass structure-direct-slot-definition (structure-slot-definition
 692                                             direct-slot-definition)
 693   ())
 694
 695 (defclass structure-effective-slot-definition (structure-slot-definition
 696                                                effective-slot-definition)
 697   ())
 698
 699 (defclass method (standard-object) ())
 700
 701 (defclass standard-method (definition-source-mixin plist-mixin method)
 702   ((generic-function
 703     :initform nil
 704     :accessor method-generic-function)
 705 ;;;     (qualifiers
 706 ;;;     :initform ()
 707 ;;;     :initarg  :qualifiers
 708 ;;;     :reader method-qualifiers)
 709    (specializers
 710     :initform ()
 711     :initarg  :specializers
 712     :reader method-specializers)
 713    (lambda-list
 714     :initform ()
 715     :initarg  :lambda-list
 716     :reader method-lambda-list)
 717    (function
 718     :initform nil
 719     :initarg :function)                 ;no writer
 720    (fast-function
 721     :initform nil
 722     :initarg :fast-function             ;no writer
 723     :reader method-fast-function)
 724 ;;;     (documentation
 725 ;;;     :initform nil
 726 ;;;     :initarg  :documentation
 727 ;;;     :reader method-documentation)
 728   ))
 729
 730 (defclass standard-accessor-method (standard-method)
 731   ((slot-name :initform nil
 732               :initarg :slot-name
 733               :reader accessor-method-slot-name)
 734    (slot-definition :initform nil
 735                     :initarg :slot-definition
 736                     :reader accessor-method-slot-definition)))
 737
 738 (defclass standard-reader-method (standard-accessor-method) ())
 739
 740 (defclass standard-writer-method (standard-accessor-method) ())
 741
 742 (defclass standard-boundp-method (standard-accessor-method) ())
 743
 744 (defclass generic-function (dependent-update-mixin
 745                             definition-source-mixin
 746                             documentation-mixin
 747                             funcallable-standard-object)
 748   (;; We need to make a distinction between the methods initially set
 749    ;; up by :METHOD options to DEFGENERIC and the ones set up later by
 750    ;; DEFMETHOD, because ANSI's specifies that executing DEFGENERIC on
 751    ;; an already-DEFGENERICed function clears the methods set by the
 752    ;; previous DEFGENERIC, but not methods set by DEFMETHOD. (Making
 753    ;; this distinction seems a little kludgy, but it has the positive
 754    ;; effect of making it so that loading a file a.lisp containing
 755    ;; DEFGENERIC, then loading a second file b.lisp containing
 756    ;; DEFMETHOD, then modifying and reloading a.lisp and/or b.lisp
 757    ;; tends to leave the generic function in a state consistent with
 758    ;; the most-recently-loaded state of a.lisp and b.lisp.)
 759    (initial-methods
 760     :initform ()
 761     :accessor generic-function-initial-methods))
 762   (:metaclass funcallable-standard-class))
 763
 764 (defclass standard-generic-function (generic-function)
 765   ((name
 766     :initform nil
 767     :initarg :name
 768     :accessor generic-function-name)
 769    (methods
 770     :initform ()
 771     :accessor generic-function-methods
 772     :type list)
 773    (method-class
 774     :initarg :method-class
 775     :accessor generic-function-method-class)
 776    (method-combination
 777     :initarg :method-combination
 778     :accessor generic-function-method-combination)
 779    (declarations
 780     :initarg :declarations
 781     :initform ()
 782     :accessor generic-function-declarations)
 783    (arg-info
 784     :initform (make-arg-info)
 785     :reader gf-arg-info)
 786    (dfun-state
 787     :initform ()
 788     :accessor gf-dfun-state))
 789   (:metaclass funcallable-standard-class)
 790   (:default-initargs :method-class *the-class-standard-method*
 791                      :method-combination *standard-method-combination*))
 792
 793 (defclass method-combination (standard-object) ())
 794
 795 (defclass standard-method-combination (definition-source-mixin
 796                                         method-combination)
 797   ((type
 798     :reader method-combination-type
 799     :initarg :type)
 800    (documentation
 801     :reader method-combination-documentation
 802     :initarg :documentation)
 803    (options
 804     :reader method-combination-options
 805     :initarg :options)))
 806
 807 (defclass long-method-combination (standard-method-combination)
 808   ((function
 809     :initarg :function
 810     :reader long-method-combination-function)
 811    (args-lambda-list
 812     :initarg :args-lambda-list
 813     :reader long-method-combination-args-lambda-list)))
 814
 815 (defparameter *early-class-predicates*
 816   '((specializer specializerp)
 817     (exact-class-specializer exact-class-specializer-p)
 818     (class-eq-specializer class-eq-specializer-p)
 819     (eql-specializer eql-specializer-p)
 820     (class classp)
 821     (slot-class slot-class-p)
 822     (std-class std-class-p)
 823     (standard-class standard-class-p)
 824     (funcallable-standard-class funcallable-standard-class-p)
 825     (structure-class structure-class-p)
 826     (forward-referenced-class forward-referenced-class-p)
 827     (method method-p)
 828     (standard-method standard-method-p)
 829     (standard-accessor-method standard-accessor-method-p)
 830     (standard-reader-method standard-reader-method-p)
 831     (standard-writer-method standard-writer-method-p)
 832     (standard-boundp-method standard-boundp-method-p)
 833     (generic-function generic-function-p)
 834     (standard-generic-function standard-generic-function-p)
 835     (method-combination method-combination-p)
 836     (long-method-combination long-method-combination-p)))
 837