src/pcl/defs.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; (These are left over from the days when PCL was an add-on package
  27 ;;; for a pre-CLOS Common Lisp. They shouldn't happen in a normal
  28 ;;; build, of course, but they might happen if someone is experimenting
  29 ;;; and debugging, and it's probably worth complaining if they do,
  30 ;;; so we've left 'em in.)
  31 (when (eq *boot-state* 'complete)
  32   (error "Trying to load (or compile) PCL in an environment in which it~%~
  33           has already been loaded. This doesn't work, you will have to~%~
  34           get a fresh lisp (reboot) and then load PCL."))
  35 (when *boot-state*
  36   (cerror "Try loading (or compiling) PCL anyways."
  37           "Trying to load (or compile) PCL in an environment in which it~%~
  38            has already been partially loaded. This may not work, you may~%~
  39            need to get a fresh lisp (reboot) and then load PCL."))
  40 \f
  41 ;;; comments from CMU CL version of PCL:
  42 ;;;     This is like fdefinition on the Lispm. If Common Lisp had
  43 ;;;   something like function specs I wouldn't need this. On the other
  44 ;;;   hand, I don't like the way this really works so maybe function
  45 ;;;   specs aren't really right either?
  46 ;;;     I also don't understand the real implications of a Lisp-1 on this
  47 ;;;   sort of thing. Certainly some of the lossage in all of this is
  48 ;;;   because these SPECs name global definitions.
  49 ;;;     Note that this implementation is set up so that an implementation
  50 ;;;   which has a 'real' function spec mechanism can use that instead
  51 ;;;   and in that way get rid of setf generic function names.
  52 (defmacro parse-gspec (spec
  53                        (non-setf-var . non-setf-case))
  54   `(let ((,non-setf-var ,spec)) ,@non-setf-case))
  55
  56 ;;; If symbol names a function which is traced, return the untraced
  57 ;;; definition. This lets us get at the generic function object even
  58 ;;; when it is traced.
  59 (defun unencapsulated-fdefinition (symbol)
  60   (fdefinition symbol))
  61
  62 ;;; If symbol names a function which is traced, redefine the `real'
  63 ;;; definition without affecting the trace.
  64 (defun fdefine-carefully (name new-definition)
  65   (progn
  66     (sb-c::note-name-defined name :function)
  67     new-definition)
  68   (setf (fdefinition name) new-definition))
  69
  70 (defun gboundp (spec)
  71   (parse-gspec spec
  72     (name (fboundp name))))
  73
  74 (defun gmakunbound (spec)
  75   (parse-gspec spec
  76     (name (fmakunbound name))))
  77
  78 (defun gdefinition (spec)
  79   (parse-gspec spec
  80     (name (unencapsulated-fdefinition name))))
  81
  82 (defun (setf gdefinition) (new-value spec)
  83   (parse-gspec spec
  84     (name (fdefine-carefully name new-value))))
  85 \f
  86 ;;;; type specifier hackery
  87
  88 ;;; internal to this file
  89 (defun coerce-to-class (class &optional make-forward-referenced-class-p)
  90   (if (symbolp class)
  91       (or (find-class class (not make-forward-referenced-class-p))
  92           (ensure-class class))
  93       class))
  94
  95 ;;; interface
  96 (defun specializer-from-type (type &aux args)
  97   (when (consp type)
  98     (setq args (cdr type) type (car type)))
  99   (cond ((symbolp type)
 100          (or (and (null args) (find-class type))
 101              (ecase type
 102                (class    (coerce-to-class (car args)))
 103                (prototype (make-instance 'class-prototype-specializer
 104                                          :object (coerce-to-class (car args))))
 105                (class-eq (class-eq-specializer (coerce-to-class (car args))))
 106                (eql      (intern-eql-specializer (car args))))))
 107         ;; FIXME: do we still need this?
 108         ((and (null args) (typep type 'classoid))
 109          (or (classoid-pcl-class type)
 110              (ensure-non-standard-class (classoid-name type))))
 111         ((specializerp type) type)))
 112
 113 ;;; interface
 114 (defun type-from-specializer (specl)
 115   (cond ((eq specl t)
 116          t)
 117         ((consp specl)
 118          (unless (member (car specl) '(class prototype class-eq eql))
 119            (error "~S is not a legal specializer type." specl))
 120          specl)
 121         ((progn
 122            (when (symbolp specl)
 123              ;;maybe (or (find-class specl nil) (ensure-class specl)) instead?
 124              (setq specl (find-class specl)))
 125            (or (not (eq *boot-state* 'complete))
 126                (specializerp specl)))
 127          (specializer-type specl))
 128         (t
 129          (error "~S is neither a type nor a specializer." specl))))
 130
 131 (defun type-class (type)
 132   (declare (special *the-class-t*))
 133   (setq type (type-from-specializer type))
 134   (if (atom type)
 135       (if (eq type t)
 136           *the-class-t*
 137           (error "bad argument to TYPE-CLASS"))
 138       (case (car type)
 139         (eql (class-of (cadr type)))
 140         (prototype (class-of (cadr type))) ;?
 141         (class-eq (cadr type))
 142         (class (cadr type)))))
 143
 144 (defun class-eq-type (class)
 145   (specializer-type (class-eq-specializer class)))
 146
 147 ;;; internal to this file..
 148 ;;;
 149 ;;; These functions are a pale imitation of their namesake. They accept
 150 ;;; class objects or types where they should.
 151 (defun *normalize-type (type)
 152   (cond ((consp type)
 153          (if (member (car type) '(not and or))
 154              `(,(car type) ,@(mapcar #'*normalize-type (cdr type)))
 155              (if (null (cdr type))
 156                  (*normalize-type (car type))
 157                  type)))
 158         ((symbolp type)
 159          (let ((class (find-class type nil)))
 160            (if class
 161                (let ((type (specializer-type class)))
 162                  (if (listp type) type `(,type)))
 163                `(,type))))
 164         ((or (not (eq *boot-state* 'complete))
 165              (specializerp type))
 166          (specializer-type type))
 167         (t
 168          (error "~S is not a type." type))))
 169
 170 ;;; internal to this file...
 171 (defun convert-to-system-type (type)
 172   (case (car type)
 173     ((not and or) `(,(car type) ,@(mapcar #'convert-to-system-type
 174                                           (cdr type))))
 175     ((class class-eq) ; class-eq is impossible to do right
 176      (layout-classoid (class-wrapper (cadr type))))
 177     (eql type)
 178     (t (if (null (cdr type))
 179            (car type)
 180            type))))
 181
 182 ;;; Writing the missing NOT and AND clauses will improve the quality
 183 ;;; of code generated by GENERATE-DISCRIMINATION-NET, but calling
 184 ;;; SUBTYPEP in place of just returning (VALUES NIL NIL) can be very
 185 ;;; slow. *SUBTYPEP is used by PCL itself, and must be fast.
 186 ;;;
 187 ;;; FIXME: SB-KERNEL has fast-and-not-quite-precise type code for use
 188 ;;; in the compiler. Could we share some of it here?
 189 (defun *subtypep (type1 type2)
 190   (if (equal type1 type2)
 191       (values t t)
 192       (if (eq *boot-state* 'early)
 193           (values (eq type1 type2) t)
 194           (let ((*in-precompute-effective-methods-p* t))
 195             (declare (special *in-precompute-effective-methods-p*))
 196             ;; FIXME: *IN-PRECOMPUTE-EFFECTIVE-METHODS-P* is not a
 197             ;; good name. It changes the way
 198             ;; CLASS-APPLICABLE-USING-CLASS-P works.
 199             (setq type1 (*normalize-type type1))
 200             (setq type2 (*normalize-type type2))
 201             (case (car type2)
 202               (not
 203                (values nil nil)) ; XXX We should improve this.
 204               (and
 205                (values nil nil)) ; XXX We should improve this.
 206               ((eql wrapper-eq class-eq class)
 207                (multiple-value-bind (app-p maybe-app-p)
 208                    (specializer-applicable-using-type-p type2 type1)
 209                  (values app-p (or app-p (not maybe-app-p)))))
 210               (t
 211                (subtypep (convert-to-system-type type1)
 212                          (convert-to-system-type type2))))))))
 213 \f
 214 (defvar *built-in-class-symbols* ())
 215 (defvar *built-in-wrapper-symbols* ())
 216
 217 (defun get-built-in-class-symbol (class-name)
 218   (or (cadr (assq class-name *built-in-class-symbols*))
 219       (let ((symbol (make-class-symbol class-name)))
 220         (push (list class-name symbol) *built-in-class-symbols*)
 221         symbol)))
 222
 223 (defun get-built-in-wrapper-symbol (class-name)
 224   (or (cadr (assq class-name *built-in-wrapper-symbols*))
 225       (let ((symbol (make-wrapper-symbol class-name)))
 226         (push (list class-name symbol) *built-in-wrapper-symbols*)
 227         symbol)))
 228 \f
 229 (pushnew '%class *var-declarations*)
 230 (pushnew '%variable-rebinding *var-declarations*)
 231
 232 (defun variable-class (var env)
 233   (caddr (var-declaration 'class var env)))
 234
 235 (defvar *name->class->slotd-table* (make-hash-table))
 236
 237 (defvar *standard-method-combination*)
 238 \f
 239 (defun make-class-predicate-name (name)
 240   (list 'class-predicate name))
 241
 242 (defun plist-value (object name)
 243   (getf (object-plist object) name))
 244
 245 (defun (setf plist-value) (new-value object name)
 246   (if new-value
 247       (setf (getf (object-plist object) name) new-value)
 248       (progn
 249         (remf (object-plist object) name)
 250         nil)))
 251 \f
 252 ;;;; built-in classes
 253
 254 ;;; Grovel over SB-KERNEL::*BUILT-IN-CLASSES* in order to set
 255 ;;; SB-PCL:*BUILT-IN-CLASSES*.
 256 (/show "about to set up SB-PCL::*BUILT-IN-CLASSES*")
 257 (defvar *built-in-classes*
 258   (labels ((direct-supers (class)
 259              (/noshow "entering DIRECT-SUPERS" (classoid-name class))
 260              (if (typep class 'built-in-classoid)
 261                  (built-in-classoid-direct-superclasses class)
 262                  (let ((inherits (layout-inherits
 263                                   (classoid-layout class))))
 264                    (/noshow inherits)
 265                    (list (svref inherits (1- (length inherits)))))))
 266            (direct-subs (class)
 267              (/noshow "entering DIRECT-SUBS" (classoid-name class))
 268              (collect ((res))
 269                (let ((subs (classoid-subclasses class)))
 270                  (/noshow subs)
 271                  (when subs
 272                    (dohash (sub v subs)
 273                      (declare (ignore v))
 274                      (/noshow sub)
 275                      (when (member class (direct-supers sub))
 276                        (res sub)))))
 277                (res))))
 278     (mapcar (lambda (kernel-bic-entry)
 279               (/noshow "setting up" kernel-bic-entry)
 280               (let* ((name (car kernel-bic-entry))
 281                      (class (find-classoid name))
 282                      (prototype-form
 283                       (getf (cdr kernel-bic-entry) :prototype-form)))
 284                 (/noshow name class)
 285                 `(,name
 286                   ,(mapcar #'classoid-name (direct-supers class))
 287                   ,(mapcar #'classoid-name (direct-subs class))
 288                   ,(map 'list
 289                         (lambda (x)
 290                           (classoid-name
 291                            (layout-classoid x)))
 292                         (reverse
 293                          (layout-inherits
 294                           (classoid-layout class))))
 295                   ,(if prototype-form
 296                        (eval prototype-form)
 297                        ;; This is the default prototype value which
 298                        ;; was used, without explanation, by the CMU CL
 299                        ;; code we're derived from. Evidently it's safe
 300                        ;; in all relevant cases.
 301                        42))))
 302             (remove-if (lambda (kernel-bic-entry)
 303                          (member (first kernel-bic-entry)
 304                                  ;; I'm not sure why these are removed from
 305                                  ;; the list, but that's what the original
 306                                  ;; CMU CL code did. -- WHN 20000715
 307                                  '(t instance
 308                                      funcallable-instance
 309                                      function stream)))
 310                        sb-kernel::*built-in-classes*))))
 311 (/noshow "done setting up SB-PCL::*BUILT-IN-CLASSES*")
 312 \f
 313 ;;;; the classes that define the kernel of the metabraid
 314
 315 (defclass t () ()
 316   (:metaclass built-in-class))
 317
 318 (defclass instance (t) ()
 319   (:metaclass built-in-class))
 320
 321 (defclass function (t) ()
 322   (:metaclass built-in-class))
 323
 324 (defclass funcallable-instance (function) ()
 325   (:metaclass built-in-class))
 326
 327 (defclass stream (instance) ()
 328   (:metaclass built-in-class))
 329
 330 (defclass slot-object (t) ()
 331   (:metaclass slot-class))
 332
 333 (defclass condition (slot-object instance) ()
 334   (:metaclass condition-class))
 335
 336 (defclass structure-object (slot-object instance) ()
 337   (:metaclass structure-class))
 338
 339 (defstruct (dead-beef-structure-object
 340             (:constructor |STRUCTURE-OBJECT class constructor|)
 341             (:copier nil)))
 342
 343 (defclass std-object (slot-object) ()
 344   (:metaclass std-class))
 345
 346 (defclass standard-object (std-object instance) ())
 347
 348 (defclass funcallable-standard-object (std-object funcallable-instance)
 349   ()
 350   (:metaclass funcallable-standard-class))
 351
 352 (defclass specializer (standard-object)
 353   ((type
 354     :initform nil
 355     :reader specializer-type)))
 356
 357 (defclass definition-source-mixin (std-object)
 358   ((source
 359     :initform *load-pathname*
 360     :reader definition-source
 361     :initarg :definition-source))
 362   (:metaclass std-class))
 363
 364 (defclass plist-mixin (std-object)
 365   ((plist
 366     :initform ()
 367     :accessor object-plist))
 368   (:metaclass std-class))
 369
 370 (defclass dependent-update-mixin (plist-mixin)
 371   ()
 372   (:metaclass std-class))
 373
 374 ;;; The class CLASS is a specified basic class. It is the common
 375 ;;; superclass of any kind of class. That is, any class that can be a
 376 ;;; metaclass must have the class CLASS in its class precedence list.
 377 (defclass class (dependent-update-mixin
 378                  definition-source-mixin
 379                  specializer)
 380   ((name
 381     :initform nil
 382     :initarg  :name
 383     :accessor class-name)
 384    (class-eq-specializer
 385     :initform nil
 386     :reader class-eq-specializer)
 387    (direct-superclasses
 388     :initform ()
 389     :reader class-direct-superclasses)
 390    ;; Note: The (CLASS-)DIRECT-SUBCLASSES for STRUCTURE-CLASSes and
 391    ;; CONDITION-CLASSes are lazily computed whenever the subclass info
 392    ;; becomes available, i.e. when the PCL class is created.
 393    (direct-subclasses
 394     :initform ()
 395     :reader class-direct-subclasses)
 396    (direct-methods
 397     :initform (cons nil nil))
 398    (predicate-name
 399     :initform nil
 400     :reader class-predicate-name)
 401    (documentation
 402     :initform nil
 403     :initarg :documentation)
 404    (finalized-p
 405     :initform nil
 406     :reader class-finalized-p)))
 407
 408 (def!method make-load-form ((class class) &optional env)
 409   ;; FIXME: should we not instead pass ENV to FIND-CLASS?  Probably
 410   ;; doesn't matter while all our environments are the same...
 411   (declare (ignore env))
 412   (let ((name (class-name class)))
 413     (unless (and name (eq (find-class name nil) class))
 414       (error "~@<Can't use anonymous or undefined class as constant: ~S~:@>"
 415              class))
 416     `(find-class ',name)))
 417
 418 ;;; The class PCL-CLASS is an implementation-specific common
 419 ;;; superclass of all specified subclasses of the class CLASS.
 420 (defclass pcl-class (class)
 421   ((class-precedence-list
 422     :reader class-precedence-list)
 423    ;; KLUDGE: see note in CPL-OR-NIL
 424    (cpl-available-p
 425     :reader cpl-available-p
 426     :initform nil)
 427    (can-precede-list
 428     :initform ()
 429     :reader class-can-precede-list)
 430    (incompatible-superclass-list
 431     :initform ()
 432     :accessor class-incompatible-superclass-list)
 433    (wrapper
 434     :initform nil
 435     :reader class-wrapper)
 436    (prototype
 437     :initform nil
 438     :reader class-prototype)))
 439
 440 (defclass slot-class (pcl-class)
 441   ((direct-slots
 442     :initform ()
 443     :accessor class-direct-slots)
 444    (slots
 445     :initform ()
 446     :accessor class-slots)))
 447
 448 ;;; The class STD-CLASS is an implementation-specific common
 449 ;;; superclass of the classes STANDARD-CLASS and
 450 ;;; FUNCALLABLE-STANDARD-CLASS.
 451 (defclass std-class (slot-class)
 452   ())
 453
 454 (defclass standard-class (std-class)
 455   ())
 456
 457 (defclass funcallable-standard-class (std-class)
 458   ())
 459
 460 (defclass forward-referenced-class (pcl-class) ())
 461
 462 (defclass built-in-class (pcl-class) ())
 463
 464 (defclass condition-class (slot-class) ())
 465
 466 (defclass structure-class (slot-class)
 467   ((defstruct-form
 468      :initform ()
 469      :accessor class-defstruct-form)
 470    (defstruct-constructor
 471      :initform nil
 472      :accessor class-defstruct-constructor)
 473    (from-defclass-p
 474     :initform nil
 475     :initarg :from-defclass-p)))
 476
 477 (defclass specializer-with-object (specializer) ())
 478
 479 (defclass exact-class-specializer (specializer) ())
 480
 481 (defclass class-eq-specializer (exact-class-specializer
 482                                 specializer-with-object)
 483   ((object :initarg :class
 484            :reader specializer-class
 485            :reader specializer-object)))
 486
 487 (defclass class-prototype-specializer (specializer-with-object)
 488   ((object :initarg :class
 489            :reader specializer-class
 490            :reader specializer-object)))
 491
 492 (defclass eql-specializer (exact-class-specializer specializer-with-object)
 493   ((object :initarg :object :reader specializer-object
 494            :reader eql-specializer-object)))
 495
 496 (defvar *eql-specializer-table* (make-hash-table :test 'eql))
 497
 498 (defun intern-eql-specializer (object)
 499   (or (gethash object *eql-specializer-table*)
 500       (setf (gethash object *eql-specializer-table*)
 501             (make-instance 'eql-specializer :object object))))
 502 \f
 503 ;;;; slot definitions
 504
 505 (defclass slot-definition (standard-object)
 506   ((name
 507     :initform nil
 508     :initarg :name
 509     :accessor slot-definition-name)
 510    (initform
 511     :initform nil
 512     :initarg :initform
 513     :accessor slot-definition-initform)
 514    (initfunction
 515     :initform nil
 516     :initarg :initfunction
 517     :accessor slot-definition-initfunction)
 518    (readers
 519     :initform nil
 520     :initarg :readers
 521     :accessor slot-definition-readers)
 522    (writers
 523     :initform nil
 524     :initarg :writers
 525     :accessor slot-definition-writers)
 526    (initargs
 527     :initform nil
 528     :initarg :initargs
 529     :accessor slot-definition-initargs)
 530    (type
 531     :initform t
 532     :initarg :type
 533     :accessor slot-definition-type)
 534    (documentation
 535     :initform nil
 536     :initarg :documentation)
 537    (class
 538     :initform nil
 539     :initarg :class
 540     :accessor slot-definition-class)))
 541
 542 (defclass standard-slot-definition (slot-definition)
 543   ((allocation
 544     :initform :instance
 545     :initarg :allocation
 546     :accessor slot-definition-allocation)
 547    (allocation-class
 548     :initform nil
 549     :initarg :allocation-class
 550     :accessor slot-definition-allocation-class)))
 551
 552 (defclass condition-slot-definition (slot-definition)
 553   ((allocation
 554     :initform :instance
 555     :initarg :allocation
 556     :accessor slot-definition-allocation)
 557    (allocation-class
 558     :initform nil
 559     :initarg :allocation-class
 560     :accessor slot-definition-allocation-class)))
 561
 562 (defclass structure-slot-definition (slot-definition)
 563   ((defstruct-accessor-symbol
 564      :initform nil
 565      :initarg :defstruct-accessor-symbol
 566      :accessor slot-definition-defstruct-accessor-symbol)
 567    (internal-reader-function
 568      :initform nil
 569      :initarg :internal-reader-function
 570      :accessor slot-definition-internal-reader-function)
 571    (internal-writer-function
 572      :initform nil
 573      :initarg :internal-writer-function
 574      :accessor slot-definition-internal-writer-function)))
 575
 576 (defclass direct-slot-definition (slot-definition)
 577   ())
 578
 579 (defclass effective-slot-definition (slot-definition)
 580   ((reader-function ; (lambda (object) ...)
 581     :accessor slot-definition-reader-function)
 582    (writer-function ; (lambda (new-value object) ...)
 583     :accessor slot-definition-writer-function)
 584    (boundp-function ; (lambda (object) ...)
 585     :accessor slot-definition-boundp-function)
 586    (accessor-flags
 587     :initform 0)))
 588
 589 (defclass standard-direct-slot-definition (standard-slot-definition
 590                                            direct-slot-definition)
 591   ())
 592
 593 (defclass standard-effective-slot-definition (standard-slot-definition
 594                                               effective-slot-definition)
 595   ((location ; nil, a fixnum, a cons: (slot-name . value)
 596     :initform nil
 597     :accessor slot-definition-location)))
 598
 599 (defclass condition-direct-slot-definition (condition-slot-definition
 600                                             direct-slot-definition)
 601   ())
 602
 603 (defclass condition-effective-slot-definition (condition-slot-definition
 604                                                effective-slot-definition)
 605   ())
 606
 607 (defclass structure-direct-slot-definition (structure-slot-definition
 608                                             direct-slot-definition)
 609   ())
 610
 611 (defclass structure-effective-slot-definition (structure-slot-definition
 612                                                effective-slot-definition)
 613   ())
 614
 615 (defclass method (standard-object) ())
 616
 617 (defclass standard-method (definition-source-mixin plist-mixin method)
 618   ((generic-function
 619     :initform nil
 620     :accessor method-generic-function)
 621 ;;;     (qualifiers
 622 ;;;     :initform ()
 623 ;;;     :initarg  :qualifiers
 624 ;;;     :reader method-qualifiers)
 625    (specializers
 626     :initform ()
 627     :initarg  :specializers
 628     :reader method-specializers)
 629    (lambda-list
 630     :initform ()
 631     :initarg  :lambda-list
 632     :reader method-lambda-list)
 633    (function
 634     :initform nil
 635     :initarg :function)                 ;no writer
 636    (fast-function
 637     :initform nil
 638     :initarg :fast-function             ;no writer
 639     :reader method-fast-function)
 640    (documentation
 641     :initform nil
 642     :initarg :documentation)))
 643
 644 (defclass standard-accessor-method (standard-method)
 645   ((slot-name :initform nil
 646               :initarg :slot-name
 647               :reader accessor-method-slot-name)
 648    (slot-definition :initform nil
 649                     :initarg :slot-definition
 650                     :reader accessor-method-slot-definition)))
 651
 652 (defclass standard-reader-method (standard-accessor-method) ())
 653
 654 (defclass standard-writer-method (standard-accessor-method) ())
 655
 656 (defclass standard-boundp-method (standard-accessor-method) ())
 657
 658 (defclass generic-function (dependent-update-mixin
 659                             definition-source-mixin
 660                             funcallable-standard-object)
 661   ((documentation
 662     :initform nil
 663     :initarg :documentation)
 664    ;; We need to make a distinction between the methods initially set
 665    ;; up by :METHOD options to DEFGENERIC and the ones set up later by
 666    ;; DEFMETHOD, because ANSI specifies that executing DEFGENERIC on
 667    ;; an already-DEFGENERICed function clears the methods set by the
 668    ;; previous DEFGENERIC, but not methods set by DEFMETHOD. (Making
 669    ;; this distinction seems a little kludgy, but it has the positive
 670    ;; effect of making it so that loading a file a.lisp containing
 671    ;; DEFGENERIC, then loading a second file b.lisp containing
 672    ;; DEFMETHOD, then modifying and reloading a.lisp and/or b.lisp
 673    ;; tends to leave the generic function in a state consistent with
 674    ;; the most-recently-loaded state of a.lisp and b.lisp.)
 675    (initial-methods
 676     :initform ()
 677     :accessor generic-function-initial-methods))
 678   (:metaclass funcallable-standard-class))
 679
 680 (defclass standard-generic-function (generic-function)
 681   ((name
 682     :initform nil
 683     :initarg :name
 684     :accessor generic-function-name)
 685    (methods
 686     :initform ()
 687     :accessor generic-function-methods
 688     :type list)
 689    (method-class
 690     :initarg :method-class
 691     :accessor generic-function-method-class)
 692    (method-combination
 693     :initarg :method-combination
 694     :accessor generic-function-method-combination)
 695    (declarations
 696     :initarg :declarations
 697     :initform ()
 698     :accessor generic-function-declarations)
 699    (arg-info
 700     :initform (make-arg-info)
 701     :reader gf-arg-info)
 702    (dfun-state
 703     :initform ()
 704     :accessor gf-dfun-state))
 705   (:metaclass funcallable-standard-class)
 706   (:default-initargs :method-class *the-class-standard-method*
 707                      :method-combination *standard-method-combination*))
 708
 709 (defclass method-combination (standard-object)
 710   ((documentation
 711     :reader method-combination-documentation
 712     :initform nil
 713     :initarg :documentation)))
 714
 715 (defclass standard-method-combination (definition-source-mixin
 716                                        method-combination)
 717   ((type
 718     :reader method-combination-type
 719     :initarg :type)
 720    (options
 721     :reader method-combination-options
 722     :initarg :options)))
 723
 724 (defclass long-method-combination (standard-method-combination)
 725   ((function
 726     :initarg :function
 727     :reader long-method-combination-function)
 728    (args-lambda-list
 729     :initarg :args-lambda-list
 730     :reader long-method-combination-args-lambda-list)))
 731
 732 (defparameter *early-class-predicates*
 733   '((specializer specializerp)
 734     (exact-class-specializer exact-class-specializer-p)
 735     (class-eq-specializer class-eq-specializer-p)
 736     (eql-specializer eql-specializer-p)
 737     (class classp)
 738     (slot-class slot-class-p)
 739     (std-class std-class-p)
 740     (standard-class standard-class-p)
 741     (funcallable-standard-class funcallable-standard-class-p)
 742     (condition-class condition-class-p)
 743     (structure-class structure-class-p)
 744     (forward-referenced-class forward-referenced-class-p)
 745     (method method-p)
 746     (standard-method standard-method-p)
 747     (standard-accessor-method standard-accessor-method-p)
 748     (standard-reader-method standard-reader-method-p)
 749     (standard-writer-method standard-writer-method-p)
 750     (standard-boundp-method standard-boundp-method-p)
 751     (generic-function generic-function-p)
 752     (standard-generic-function standard-generic-function-p)
 753     (method-combination method-combination-p)
 754     (long-method-combination long-method-combination-p)))
 755