src/pcl/defs.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; (These are left over from the days when PCL was an add-on package
  27 ;;; for a pre-CLOS Common Lisp. They shouldn't happen in a normal
  28 ;;; build, of course, but they might happen if someone is experimenting
  29 ;;; and debugging, and it's probably worth complaining if they do,
  30 ;;; so we've left 'em in.)
  31 (when (eq *boot-state* 'complete)
  32   (error "Trying to load (or compile) PCL in an environment in which it~%~
  33           has already been loaded. This doesn't work, you will have to~%~
  34           get a fresh lisp (reboot) and then load PCL."))
  35 (when *boot-state*
  36   (cerror "Try loading (or compiling) PCL anyways."
  37           "Trying to load (or compile) PCL in an environment in which it~%~
  38            has already been partially loaded. This may not work, you may~%~
  39            need to get a fresh lisp (reboot) and then load PCL."))
  40 \f
  41 ;;; comments from CMU CL version of PCL:
  42 ;;;     This is like fdefinition on the Lispm. If Common Lisp had
  43 ;;;   something like function specs I wouldn't need this. On the other
  44 ;;;   hand, I don't like the way this really works so maybe function
  45 ;;;   specs aren't really right either?
  46 ;;;     I also don't understand the real implications of a Lisp-1 on this
  47 ;;;   sort of thing. Certainly some of the lossage in all of this is
  48 ;;;   because these SPECs name global definitions.
  49 ;;;     Note that this implementation is set up so that an implementation
  50 ;;;   which has a 'real' function spec mechanism can use that instead
  51 ;;;   and in that way get rid of setf generic function names.
  52 (defmacro parse-gspec (spec
  53                        (non-setf-var . non-setf-case))
  54   `(let ((,non-setf-var ,spec)) ,@non-setf-case))
  55
  56 ;;; If symbol names a function which is traced, return the untraced
  57 ;;; definition. This lets us get at the generic function object even
  58 ;;; when it is traced.
  59 (defun unencapsulated-fdefinition (symbol)
  60   (fdefinition symbol))
  61
  62 ;;; If symbol names a function which is traced, redefine the `real'
  63 ;;; definition without affecting the trace.
  64 (defun fdefine-carefully (name new-definition)
  65   (progn
  66     (sb-c::note-name-defined name :function)
  67     new-definition)
  68   (setf (fdefinition name) new-definition))
  69
  70 (defun gboundp (spec)
  71   (parse-gspec spec
  72     (name (fboundp name))))
  73
  74 (defun gmakunbound (spec)
  75   (parse-gspec spec
  76     (name (fmakunbound name))))
  77
  78 (defun gdefinition (spec)
  79   (parse-gspec spec
  80     (name (unencapsulated-fdefinition name))))
  81
  82 (defun (setf gdefinition) (new-value spec)
  83   (parse-gspec spec
  84     (name (fdefine-carefully name new-value))))
  85 \f
  86 ;;;; type specifier hackery
  87
  88 ;;; internal to this file
  89 (defun coerce-to-class (class &optional make-forward-referenced-class-p)
  90   (if (symbolp class)
  91       (or (find-class class (not make-forward-referenced-class-p))
  92           (ensure-class class))
  93       class))
  94
  95 ;;; interface
  96 (defun specializer-from-type (type &aux args)
  97   (when (consp type)
  98     (setq args (cdr type) type (car type)))
  99   (cond ((symbolp type)
 100          (or (and (null args) (find-class type))
 101              (ecase type
 102                (class    (coerce-to-class (car args)))
 103                (prototype (make-instance 'class-prototype-specializer
 104                                          :object (coerce-to-class (car args))))
 105                (class-eq (class-eq-specializer (coerce-to-class (car args))))
 106                (eql      (intern-eql-specializer (car args))))))
 107         ;; FIXME: do we still need this?
 108         ((and (null args) (typep type 'classoid))
 109          (or (classoid-pcl-class type)
 110              (ensure-non-standard-class (classoid-name type))))
 111         ((specializerp type) type)))
 112
 113 ;;; interface
 114 (defun type-from-specializer (specl)
 115   (cond ((eq specl t)
 116          t)
 117         ((consp specl)
 118          (unless (member (car specl) '(class prototype class-eq eql))
 119            (error "~S is not a legal specializer type." specl))
 120          specl)
 121         ((progn
 122            (when (symbolp specl)
 123              ;;maybe (or (find-class specl nil) (ensure-class specl)) instead?
 124              (setq specl (find-class specl)))
 125            (or (not (eq *boot-state* 'complete))
 126                (specializerp specl)))
 127          (specializer-type specl))
 128         (t
 129          (error "~S is neither a type nor a specializer." specl))))
 130
 131 (defun type-class (type)
 132   (declare (special *the-class-t*))
 133   (setq type (type-from-specializer type))
 134   (if (atom type)
 135       (if (eq type t)
 136           *the-class-t*
 137           (error "bad argument to TYPE-CLASS"))
 138       (case (car type)
 139         (eql (class-of (cadr type)))
 140         (prototype (class-of (cadr type))) ;?
 141         (class-eq (cadr type))
 142         (class (cadr type)))))
 143
 144 (defun class-eq-type (class)
 145   (specializer-type (class-eq-specializer class)))
 146
 147 ;;; internal to this file..
 148 ;;;
 149 ;;; These functions are a pale imitation of their namesake. They accept
 150 ;;; class objects or types where they should.
 151 (defun *normalize-type (type)
 152   (cond ((consp type)
 153          (if (member (car type) '(not and or))
 154              `(,(car type) ,@(mapcar #'*normalize-type (cdr type)))
 155              (if (null (cdr type))
 156                  (*normalize-type (car type))
 157                  type)))
 158         ((symbolp type)
 159          (let ((class (find-class type nil)))
 160            (if class
 161                (let ((type (specializer-type class)))
 162                  (if (listp type) type `(,type)))
 163                `(,type))))
 164         ((or (not (eq *boot-state* 'complete))
 165              (specializerp type))
 166          (specializer-type type))
 167         (t
 168          (error "~S is not a type." type))))
 169
 170 ;;; internal to this file...
 171 (defun convert-to-system-type (type)
 172   (case (car type)
 173     ((not and or) `(,(car type) ,@(mapcar #'convert-to-system-type
 174                                           (cdr type))))
 175     ((class class-eq) ; class-eq is impossible to do right
 176      (layout-classoid (class-wrapper (cadr type))))
 177     (eql type)
 178     (t (if (null (cdr type))
 179            (car type)
 180            type))))
 181
 182 ;;; Writing the missing NOT and AND clauses will improve the quality
 183 ;;; of code generated by GENERATE-DISCRIMINATION-NET, but calling
 184 ;;; SUBTYPEP in place of just returning (VALUES NIL NIL) can be very
 185 ;;; slow. *SUBTYPEP is used by PCL itself, and must be fast.
 186 ;;;
 187 ;;; FIXME: SB-KERNEL has fast-and-not-quite-precise type code for use
 188 ;;; in the compiler. Could we share some of it here?
 189 (defun *subtypep (type1 type2)
 190   (if (equal type1 type2)
 191       (values t t)
 192       (if (eq *boot-state* 'early)
 193           (values (eq type1 type2) t)
 194           (let ((*in-precompute-effective-methods-p* t))
 195             (declare (special *in-precompute-effective-methods-p*))
 196             ;; FIXME: *IN-PRECOMPUTE-EFFECTIVE-METHODS-P* is not a
 197             ;; good name. It changes the way
 198             ;; CLASS-APPLICABLE-USING-CLASS-P works.
 199             (setq type1 (*normalize-type type1))
 200             (setq type2 (*normalize-type type2))
 201             (case (car type2)
 202               (not
 203                (values nil nil)) ; XXX We should improve this.
 204               (and
 205                (values nil nil)) ; XXX We should improve this.
 206               ((eql wrapper-eq class-eq class)
 207                (multiple-value-bind (app-p maybe-app-p)
 208                    (specializer-applicable-using-type-p type2 type1)
 209                  (values app-p (or app-p (not maybe-app-p)))))
 210               (t
 211                (subtypep (convert-to-system-type type1)
 212                          (convert-to-system-type type2))))))))
 213 \f
 214 (defvar *built-in-class-symbols* ())
 215 (defvar *built-in-wrapper-symbols* ())
 216
 217 (defun get-built-in-class-symbol (class-name)
 218   (or (cadr (assq class-name *built-in-class-symbols*))
 219       (let ((symbol (make-class-symbol class-name)))
 220         (push (list class-name symbol) *built-in-class-symbols*)
 221         symbol)))
 222
 223 (defun get-built-in-wrapper-symbol (class-name)
 224   (or (cadr (assq class-name *built-in-wrapper-symbols*))
 225       (let ((symbol (make-wrapper-symbol class-name)))
 226         (push (list class-name symbol) *built-in-wrapper-symbols*)
 227         symbol)))
 228 \f
 229 (pushnew '%class *var-declarations*)
 230 (pushnew '%variable-rebinding *var-declarations*)
 231
 232 (defun variable-class (var env)
 233   (caddr (var-declaration 'class var env)))
 234
 235 (defvar *name->class->slotd-table* (make-hash-table))
 236
 237 (defvar *standard-method-combination*)
 238 \f
 239 (defun make-class-predicate-name (name)
 240   (list 'class-predicate name))
 241
 242 (defun plist-value (object name)
 243   (getf (object-plist object) name))
 244
 245 (defun (setf plist-value) (new-value object name)
 246   (if new-value
 247       (setf (getf (object-plist object) name) new-value)
 248       (progn
 249         (remf (object-plist object) name)
 250         nil)))
 251 \f
 252 ;;;; built-in classes
 253
 254 ;;; Grovel over SB-KERNEL::*BUILT-IN-CLASSES* in order to set
 255 ;;; SB-PCL:*BUILT-IN-CLASSES*.
 256 (/show "about to set up SB-PCL::*BUILT-IN-CLASSES*")
 257 (defvar *built-in-classes*
 258   (labels ((direct-supers (class)
 259              (/noshow "entering DIRECT-SUPERS" (classoid-name class))
 260              (if (typep class 'built-in-classoid)
 261                  (built-in-classoid-direct-superclasses class)
 262                  (let ((inherits (layout-inherits
 263                                   (classoid-layout class))))
 264                    (/noshow inherits)
 265                    (list (svref inherits (1- (length inherits)))))))
 266            (direct-subs (class)
 267              (/noshow "entering DIRECT-SUBS" (classoid-name class))
 268              (collect ((res))
 269                (let ((subs (classoid-subclasses class)))
 270                  (/noshow subs)
 271                  (when subs
 272                    (dohash (sub v subs)
 273                      (declare (ignore v))
 274                      (/noshow sub)
 275                      (when (member class (direct-supers sub))
 276                        (res sub)))))
 277                (res))))
 278     (mapcar (lambda (kernel-bic-entry)
 279               (/noshow "setting up" kernel-bic-entry)
 280               (let* ((name (car kernel-bic-entry))
 281                      (class (find-classoid name))
 282                      (prototype-form
 283                       (getf (cdr kernel-bic-entry) :prototype-form)))
 284                 (/noshow name class)
 285                 `(,name
 286                   ,(mapcar #'classoid-name (direct-supers class))
 287                   ,(mapcar #'classoid-name (direct-subs class))
 288                   ,(map 'list
 289                         (lambda (x)
 290                           (classoid-name
 291                            (layout-classoid x)))
 292                         (reverse
 293                          (layout-inherits
 294                           (classoid-layout class))))
 295                   ,(if prototype-form
 296                        (eval prototype-form)
 297                        ;; This is the default prototype value which
 298                        ;; was used, without explanation, by the CMU CL
 299                        ;; code we're derived from. Evidently it's safe
 300                        ;; in all relevant cases.
 301                        42))))
 302             (remove-if (lambda (kernel-bic-entry)
 303                          (member (first kernel-bic-entry)
 304                                  ;; I'm not sure why these are removed from
 305                                  ;; the list, but that's what the original
 306                                  ;; CMU CL code did. -- WHN 20000715
 307                                  '(t function stream
 308                                      file-stream string-stream)))
 309                        sb-kernel::*built-in-classes*))))
 310 (/noshow "done setting up SB-PCL::*BUILT-IN-CLASSES*")
 311 \f
 312 ;;;; the classes that define the kernel of the metabraid
 313
 314 (defclass t () ()
 315   (:metaclass built-in-class))
 316
 317 (defclass function (t) ()
 318   (:metaclass built-in-class))
 319
 320 (defclass stream (t) ()
 321   (:metaclass built-in-class))
 322
 323 (defclass file-stream (stream) ()
 324   (:metaclass built-in-class))
 325
 326 (defclass string-stream (stream) ()
 327   (:metaclass built-in-class))
 328
 329 (defclass slot-object (t) ()
 330   (:metaclass slot-class))
 331
 332 (defclass condition (slot-object) ()
 333   (:metaclass condition-class))
 334
 335 (defclass structure-object (slot-object) ()
 336   (:metaclass structure-class))
 337
 338 (defstruct (dead-beef-structure-object
 339             (:constructor |STRUCTURE-OBJECT class constructor|)
 340             (:copier nil)))
 341
 342 (defclass standard-object (slot-object) ())
 343
 344 (defclass funcallable-standard-object (standard-object function)
 345   ()
 346   (:metaclass funcallable-standard-class))
 347
 348 (defclass metaobject (standard-object) ())
 349
 350 (defclass generic-function (dependent-update-mixin
 351                             definition-source-mixin
 352                             metaobject
 353                             funcallable-standard-object)
 354   ((documentation
 355     :initform nil
 356     :initarg :documentation)
 357    ;; We need to make a distinction between the methods initially set
 358    ;; up by :METHOD options to DEFGENERIC and the ones set up later by
 359    ;; DEFMETHOD, because ANSI specifies that executing DEFGENERIC on
 360    ;; an already-DEFGENERICed function clears the methods set by the
 361    ;; previous DEFGENERIC, but not methods set by DEFMETHOD. (Making
 362    ;; this distinction seems a little kludgy, but it has the positive
 363    ;; effect of making it so that loading a file a.lisp containing
 364    ;; DEFGENERIC, then loading a second file b.lisp containing
 365    ;; DEFMETHOD, then modifying and reloading a.lisp and/or b.lisp
 366    ;; tends to leave the generic function in a state consistent with
 367    ;; the most-recently-loaded state of a.lisp and b.lisp.)
 368    (initial-methods
 369     :initform ()
 370     :accessor generic-function-initial-methods))
 371   (:metaclass funcallable-standard-class))
 372
 373 (defclass standard-generic-function (generic-function)
 374   ((name
 375     :initform nil
 376     :initarg :name
 377     :accessor generic-function-name)
 378    (methods
 379     :initform ()
 380     :accessor generic-function-methods
 381     :type list)
 382    (method-class
 383     :initarg :method-class
 384     :accessor generic-function-method-class)
 385    (method-combination
 386     :initarg :method-combination
 387     :accessor generic-function-method-combination)
 388    (declarations
 389     ;; KLUDGE: AMOP specifies :DECLARATIONS, while ANSI specifies
 390     ;; :DECLARE.  Allow either (but FIXME: maybe a note or a warning
 391     ;; might be appropriate).
 392     :initarg :declarations
 393     :initarg :declare
 394     :initform ()
 395     :accessor generic-function-declarations)
 396    (arg-info
 397     :initform (make-arg-info)
 398     :reader gf-arg-info)
 399    (dfun-state
 400     :initform ()
 401     :accessor gf-dfun-state))
 402   (:metaclass funcallable-standard-class)
 403   (:default-initargs :method-class *the-class-standard-method*
 404                      :method-combination *standard-method-combination*))
 405
 406 (defclass method (metaobject) ())
 407
 408 (defclass standard-method (definition-source-mixin plist-mixin method)
 409   ((generic-function
 410     :initform nil
 411     :accessor method-generic-function)
 412 ;;;     (qualifiers
 413 ;;;     :initform ()
 414 ;;;     :initarg  :qualifiers
 415 ;;;     :reader method-qualifiers)
 416    (specializers
 417     :initform ()
 418     :initarg  :specializers
 419     :reader method-specializers)
 420    (lambda-list
 421     :initform ()
 422     :initarg  :lambda-list
 423     :reader method-lambda-list)
 424    (function
 425     :initform nil
 426     :initarg :function)                 ;no writer
 427    (fast-function
 428     :initform nil
 429     :initarg :fast-function             ;no writer
 430     :reader method-fast-function)
 431    (documentation
 432     :initform nil
 433     :initarg :documentation)))
 434
 435 (defclass standard-accessor-method (standard-method)
 436   ((slot-name :initform nil
 437               :initarg :slot-name
 438               :reader accessor-method-slot-name)
 439    (slot-definition :initform nil
 440                     :initarg :slot-definition
 441                     :reader accessor-method-slot-definition)))
 442
 443 (defclass standard-reader-method (standard-accessor-method) ())
 444 (defclass standard-writer-method (standard-accessor-method) ())
 445 ;;; an extension, apparently.
 446 (defclass standard-boundp-method (standard-accessor-method) ())
 447
 448 (defclass method-combination (metaobject)
 449   ((documentation
 450     :reader method-combination-documentation
 451     :initform nil
 452     :initarg :documentation)))
 453
 454 (defclass standard-method-combination (definition-source-mixin
 455                                        method-combination)
 456   ((type
 457     :reader method-combination-type
 458     :initarg :type)
 459    (options
 460     :reader method-combination-options
 461     :initarg :options)))
 462
 463 (defclass long-method-combination (standard-method-combination)
 464   ((function
 465     :initarg :function
 466     :reader long-method-combination-function)
 467    (args-lambda-list
 468     :initarg :args-lambda-list
 469     :reader long-method-combination-args-lambda-list)))
 470
 471 (defclass slot-definition (metaobject)
 472   ((name
 473     :initform nil
 474     :initarg :name
 475     :accessor slot-definition-name)
 476    (initform
 477     :initform nil
 478     :initarg :initform
 479     :accessor slot-definition-initform)
 480    (initfunction
 481     :initform nil
 482     :initarg :initfunction
 483     :accessor slot-definition-initfunction)
 484    (readers
 485     :initform nil
 486     :initarg :readers
 487     :accessor slot-definition-readers)
 488    (writers
 489     :initform nil
 490     :initarg :writers
 491     :accessor slot-definition-writers)
 492    (initargs
 493     :initform nil
 494     :initarg :initargs
 495     :accessor slot-definition-initargs)
 496    (type
 497     :initform t
 498     :initarg :type
 499     :accessor slot-definition-type)
 500    (documentation
 501     :initform nil
 502     :initarg :documentation)
 503    (class
 504     :initform nil
 505     :initarg :class
 506     :accessor slot-definition-class)))
 507
 508 (defclass standard-slot-definition (slot-definition)
 509   ((allocation
 510     :initform :instance
 511     :initarg :allocation
 512     :accessor slot-definition-allocation)
 513    (allocation-class
 514     :initform nil
 515     :initarg :allocation-class
 516     :accessor slot-definition-allocation-class)))
 517
 518 (defclass condition-slot-definition (slot-definition)
 519   ((allocation
 520     :initform :instance
 521     :initarg :allocation
 522     :accessor slot-definition-allocation)
 523    (allocation-class
 524     :initform nil
 525     :initarg :allocation-class
 526     :accessor slot-definition-allocation-class)))
 527
 528 (defclass structure-slot-definition (slot-definition)
 529   ((defstruct-accessor-symbol
 530      :initform nil
 531      :initarg :defstruct-accessor-symbol
 532      :accessor slot-definition-defstruct-accessor-symbol)
 533    (internal-reader-function
 534      :initform nil
 535      :initarg :internal-reader-function
 536      :accessor slot-definition-internal-reader-function)
 537    (internal-writer-function
 538      :initform nil
 539      :initarg :internal-writer-function
 540      :accessor slot-definition-internal-writer-function)))
 541
 542 (defclass direct-slot-definition (slot-definition)
 543   ())
 544
 545 (defclass effective-slot-definition (slot-definition)
 546   ((reader-function ; (lambda (object) ...)
 547     :accessor slot-definition-reader-function)
 548    (writer-function ; (lambda (new-value object) ...)
 549     :accessor slot-definition-writer-function)
 550    (boundp-function ; (lambda (object) ...)
 551     :accessor slot-definition-boundp-function)
 552    (accessor-flags
 553     :initform 0)))
 554
 555 (defclass standard-direct-slot-definition (standard-slot-definition
 556                                            direct-slot-definition)
 557   ())
 558
 559 (defclass standard-effective-slot-definition (standard-slot-definition
 560                                               effective-slot-definition)
 561   ((location ; nil, a fixnum, a cons: (slot-name . value)
 562     :initform nil
 563     :accessor slot-definition-location)))
 564
 565 (defclass condition-direct-slot-definition (condition-slot-definition
 566                                             direct-slot-definition)
 567   ())
 568
 569 (defclass condition-effective-slot-definition (condition-slot-definition
 570                                                effective-slot-definition)
 571   ())
 572
 573 (defclass structure-direct-slot-definition (structure-slot-definition
 574                                             direct-slot-definition)
 575   ())
 576
 577 (defclass structure-effective-slot-definition (structure-slot-definition
 578                                                effective-slot-definition)
 579   ())
 580
 581 (defclass specializer (metaobject)
 582   ((type :initform nil :reader specializer-type)))
 583
 584 (defclass specializer-with-object (specializer) ())
 585
 586 (defclass exact-class-specializer (specializer) ())
 587
 588 (defclass class-eq-specializer (exact-class-specializer
 589                                 specializer-with-object)
 590   ((object :initarg :class
 591            :reader specializer-class
 592            :reader specializer-object)))
 593
 594 (defclass class-prototype-specializer (specializer-with-object)
 595   ((object :initarg :class
 596            :reader specializer-class
 597            :reader specializer-object)))
 598
 599 (defclass eql-specializer (exact-class-specializer specializer-with-object)
 600   ((object :initarg :object :reader specializer-object
 601            :reader eql-specializer-object)))
 602
 603 (defvar *eql-specializer-table* (make-hash-table :test 'eql))
 604
 605 (defun intern-eql-specializer (object)
 606   (or (gethash object *eql-specializer-table*)
 607       (setf (gethash object *eql-specializer-table*)
 608             (make-instance 'eql-specializer :object object))))
 609
 610 (defclass class (dependent-update-mixin
 611                  definition-source-mixin
 612                  specializer)
 613   ((name
 614     :initform nil
 615     :initarg  :name
 616     :accessor class-name)
 617    (class-eq-specializer
 618     :initform nil
 619     :reader class-eq-specializer)
 620    (direct-superclasses
 621     :initform ()
 622     :reader class-direct-superclasses)
 623    ;; Note: The (CLASS-)DIRECT-SUBCLASSES for STRUCTURE-CLASSes and
 624    ;; CONDITION-CLASSes are lazily computed whenever the subclass info
 625    ;; becomes available, i.e. when the PCL class is created.
 626    (direct-subclasses
 627     :initform ()
 628     :reader class-direct-subclasses)
 629    (direct-methods
 630     :initform (cons nil nil))
 631    (predicate-name
 632     :initform nil
 633     :reader class-predicate-name)
 634    (documentation
 635     :initform nil
 636     :initarg :documentation)
 637    (finalized-p
 638     :initform nil
 639     :reader class-finalized-p)))
 640
 641 (def!method make-load-form ((class class) &optional env)
 642   ;; FIXME: should we not instead pass ENV to FIND-CLASS?  Probably
 643   ;; doesn't matter while all our environments are the same...
 644   (declare (ignore env))
 645   (let ((name (class-name class)))
 646     (unless (and name (eq (find-class name nil) class))
 647       (error "~@<Can't use anonymous or undefined class as constant: ~S~:@>"
 648              class))
 649     `(find-class ',name)))
 650
 651 ;;; The class PCL-CLASS is an implementation-specific common
 652 ;;; superclass of all specified subclasses of the class CLASS.
 653 (defclass pcl-class (class)
 654   ((class-precedence-list
 655     :reader class-precedence-list)
 656    ;; KLUDGE: see note in CPL-OR-NIL
 657    (cpl-available-p
 658     :reader cpl-available-p
 659     :initform nil)
 660    (can-precede-list
 661     :initform ()
 662     :reader class-can-precede-list)
 663    (incompatible-superclass-list
 664     :initform ()
 665     :accessor class-incompatible-superclass-list)
 666    (wrapper
 667     :initform nil
 668     :reader class-wrapper)
 669    (prototype
 670     :initform nil
 671     :reader class-prototype)))
 672
 673 (defclass slot-class (pcl-class)
 674   ((direct-slots
 675     :initform ()
 676     :accessor class-direct-slots)
 677    (slots
 678     :initform ()
 679     :accessor class-slots)))
 680
 681 ;;; The class STD-CLASS is an implementation-specific common
 682 ;;; superclass of the classes STANDARD-CLASS and
 683 ;;; FUNCALLABLE-STANDARD-CLASS.
 684 (defclass std-class (slot-class)
 685   ())
 686
 687 (defclass standard-class (std-class)
 688   ())
 689
 690 (defclass funcallable-standard-class (std-class)
 691   ())
 692
 693 (defclass forward-referenced-class (pcl-class) ())
 694
 695 (defclass built-in-class (pcl-class) ())
 696
 697 (defclass condition-class (slot-class) ())
 698
 699 (defclass structure-class (slot-class)
 700   ((defstruct-form
 701      :initform ()
 702      :accessor class-defstruct-form)
 703    (defstruct-constructor
 704      :initform nil
 705      :accessor class-defstruct-constructor)
 706    (from-defclass-p
 707     :initform nil
 708     :initarg :from-defclass-p)))
 709
 710 (defclass definition-source-mixin (standard-object)
 711   ((source :initform *load-pathname* :reader definition-source
 712            :initarg :definition-source)))
 713
 714 (defclass plist-mixin (standard-object)
 715   ((plist :initform () :accessor object-plist)))
 716
 717 (defclass dependent-update-mixin (plist-mixin) ())
 718
 719 (defparameter *early-class-predicates*
 720   '((specializer specializerp)
 721     (exact-class-specializer exact-class-specializer-p)
 722     (class-eq-specializer class-eq-specializer-p)
 723     (eql-specializer eql-specializer-p)
 724     (class classp)
 725     (slot-class slot-class-p)
 726     (std-class std-class-p)
 727     (standard-class standard-class-p)
 728     (funcallable-standard-class funcallable-standard-class-p)
 729     (condition-class condition-class-p)
 730     (structure-class structure-class-p)
 731     (forward-referenced-class forward-referenced-class-p)
 732     (method method-p)
 733     (standard-method standard-method-p)
 734     (standard-accessor-method standard-accessor-method-p)
 735     (standard-reader-method standard-reader-method-p)
 736     (standard-writer-method standard-writer-method-p)
 737     (standard-boundp-method standard-boundp-method-p)
 738     (generic-function generic-function-p)
 739     (standard-generic-function standard-generic-function-p)
 740     (method-combination method-combination-p)
 741     (long-method-combination long-method-combination-p)))
 742