src/pcl/dfun.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 #|
  27
  28 This implementation of method lookup was redone in early August of 89.
  29
  30 It has the following properties:
  31
  32  - Its modularity makes it easy to modify the actual caching algorithm.
  33    The caching algorithm is almost completely separated into the files
  34    cache.lisp and dlap.lisp. This file just contains the various uses
  35    of it. There will be more tuning as we get more results from Luis'
  36    measurements of caching behavior.
  37
  38  - The metacircularity issues have been dealt with properly. All of
  39    PCL now grounds out properly. Moreover, it is now possible to have
  40    metaobject classes which are themselves not instances of standard
  41    metaobject classes.
  42
  43 ** Modularity of the code **
  44
  45 The actual caching algorithm is isolated in a modest number of functions.
  46 The code which generates cache lookup code is all found in cache.lisp and
  47 dlap.lisp. Certain non-wrapper-caching special cases are in this file.
  48
  49 ** Handling the metacircularity **
  50
  51 In CLOS, method lookup is the potential source of infinite metacircular
  52 regress. The metaobject protocol specification gives us wide flexibility
  53 in how to address this problem. PCL uses a technique which handles the
  54 problem not only for the metacircular language described in Chapter 3, but
  55 also for the PCL protocol which includes additional generic functions
  56 which control more aspects of the CLOS implementation.
  57
  58 The source of the metacircular regress can be seen in a number of ways.
  59 One is that the specified method lookup protocol must, as part of doing
  60 the method lookup (or at least the cache miss case), itself call generic
  61 functions. It is easy to see that if the method lookup for a generic
  62 function ends up calling that same generic function there can be trouble.
  63
  64 Fortunately, there is an easy solution at hand. The solution is based on
  65 the restriction that portable code cannot change the class of a specified
  66 metaobject. This restriction implies that for specified generic functions,
  67 the method lookup protocol they follow is fixed.
  68
  69 More precisely, for such specified generic functions, most generic functions
  70 that are called during their own method lookup will not run portable methods.
  71 This allows the implementation to usurp the actual generic function call in
  72 this case. In short, method lookup of a standard generic function, in the
  73 case where the only applicable methods are themselves standard doesn't
  74 have to do any method lookup to implement itself.
  75
  76 And so, we are saved.
  77
  78 Except see also BREAK-VICIOUS-METACIRCLE.  -- CSR, 2003-05-28
  79
  80 |#
  81 \f
  82 ;;; an alist in which each entry is of the form
  83 ;;;   (<generator> . (<subentry> ...)).
  84 ;;; Each subentry is of the form
  85 ;;;   (<args> <constructor> <system>).
  86 (defvar *dfun-constructors* ())
  87
  88 ;;; If this is NIL, then the whole mechanism for caching dfun constructors is
  89 ;;; turned off. The only time that makes sense is when debugging LAP code.
  90 (defvar *enable-dfun-constructor-caching* t)
  91
  92 (defun show-dfun-constructors ()
  93   (format t "~&DFUN constructor caching is ~A."
  94           (if *enable-dfun-constructor-caching*
  95               "enabled" "disabled"))
  96   (dolist (generator-entry *dfun-constructors*)
  97     (dolist (args-entry (cdr generator-entry))
  98       (format t "~&~S ~S"
  99               (cons (car generator-entry) (caar args-entry))
 100               (caddr args-entry)))))
 101
 102 (defvar *raise-metatypes-to-class-p* t)
 103
 104 (defun get-dfun-constructor (generator &rest args)
 105   (when (and *raise-metatypes-to-class-p*
 106              (member generator '(emit-checking emit-caching
 107                                  emit-in-checking-cache-p emit-constant-value)))
 108     (setq args (cons (mapcar (lambda (mt)
 109                                (if (eq mt t)
 110                                    mt
 111                                    'class))
 112                              (car args))
 113                      (cdr args))))
 114   (let* ((generator-entry (assq generator *dfun-constructors*))
 115          (args-entry (assoc args (cdr generator-entry) :test #'equal)))
 116     (if (null *enable-dfun-constructor-caching*)
 117         (apply (fdefinition generator) args)
 118         (or (cadr args-entry)
 119             (multiple-value-bind (new not-best-p)
 120                 (apply (symbol-function generator) args)
 121               (let ((entry (list (copy-list args) new (unless not-best-p 'pcl)
 122                                  not-best-p)))
 123                 (if generator-entry
 124                     (push entry (cdr generator-entry))
 125                     (push (list generator entry)
 126                           *dfun-constructors*)))
 127               (values new not-best-p))))))
 128
 129 (defun load-precompiled-dfun-constructor (generator args system constructor)
 130   (let* ((generator-entry (assq generator *dfun-constructors*))
 131          (args-entry (assoc args (cdr generator-entry) :test #'equal)))
 132     (if args-entry
 133         (when (fourth args-entry)
 134           (let* ((dfun-type (case generator
 135                               (emit-checking 'checking)
 136                               (emit-caching 'caching)
 137                               (emit-constant-value 'constant-value)
 138                               (emit-default-only 'default-method-only)))
 139                  (metatypes (car args))
 140                  (gfs (when dfun-type (gfs-of-type dfun-type))))
 141             (dolist (gf gfs)
 142               (when (and (equal metatypes
 143                                 (arg-info-metatypes (gf-arg-info gf)))
 144                          (let ((gf-name (generic-function-name gf)))
 145                            (and (not (eq gf-name 'slot-value-using-class))
 146                                 (not (equal gf-name
 147                                             '(setf slot-value-using-class)))
 148                                 (not (eq gf-name 'slot-boundp-using-class)))))
 149                 (update-dfun gf)))
 150             (setf (second args-entry) constructor)
 151             (setf (third args-entry) system)
 152             (setf (fourth args-entry) nil)))
 153         (let ((entry (list args constructor system nil)))
 154           (if generator-entry
 155               (push entry (cdr generator-entry))
 156               (push (list generator entry) *dfun-constructors*))))))
 157
 158 (defmacro precompile-dfun-constructors (&optional system)
 159   (let ((*precompiling-lap* t))
 160     `(progn
 161        ,@(let (collect)
 162            (dolist (generator-entry *dfun-constructors*)
 163              (dolist (args-entry (cdr generator-entry))
 164                (when (or (null (caddr args-entry))
 165                          (eq (caddr args-entry) system))
 166                  (when system (setf (caddr args-entry) system))
 167                  (push `(load-precompiled-dfun-constructor
 168                          ',(car generator-entry)
 169                          ',(car args-entry)
 170                          ',system
 171                          ,(apply (fdefinition (car generator-entry))
 172                                  (car args-entry)))
 173                        collect))))
 174            (nreverse collect)))))
 175 \f
 176 ;;; Standardized class slot access: when trying to break vicious
 177 ;;; metacircles, we need a way to get at the values of slots of some
 178 ;;; standard classes without going through the whole meta machinery,
 179 ;;; because that would likely enter the vicious circle again.  The
 180 ;;; following are helper functions that short-circuit the generic
 181 ;;; lookup machinery.
 182
 183 (defvar *standard-classes*
 184   '(standard-method standard-generic-function standard-class
 185     standard-effective-slot-definition))
 186
 187 (defvar *standard-slot-locations* (make-hash-table :test 'equal))
 188
 189 (defun compute-standard-slot-locations ()
 190   (clrhash *standard-slot-locations*)
 191   (dolist (class-name *standard-classes*)
 192     (let ((class (find-class class-name)))
 193       (dolist (slot (class-slots class))
 194         (setf (gethash (cons class (slot-definition-name slot))
 195                        *standard-slot-locations*)
 196               (slot-definition-location slot))))))
 197
 198 ;;; FIXME: harmonize the names between COMPUTE-STANDARD-SLOT-LOCATIONS
 199 ;;; and MAYBE-UPDATE-STANDARD-CLASS-LOCATIONS.
 200 (defun maybe-update-standard-class-locations (class)
 201   (when (and (eq *boot-state* 'complete)
 202              (memq (class-name class) *standard-classes*))
 203     (compute-standard-slot-locations)))
 204
 205 (defun standard-slot-value (object slot-name class)
 206   (let ((location (gethash (cons class slot-name) *standard-slot-locations*)))
 207     (if location
 208         (let ((value (if (funcallable-instance-p object)
 209                          (funcallable-standard-instance-access object location)
 210                          (standard-instance-access object location))))
 211           (when (eq +slot-unbound+ value)
 212             (error "~@<slot ~s of class ~s is unbound in object ~s~@:>"
 213                    slot-name class object))
 214           value)
 215         (error "~@<cannot get standard value of slot ~s of class ~s ~
 216                 in object ~s~@:>"
 217                slot-name class object))))
 218
 219 (defun standard-slot-value/gf (gf slot-name)
 220   (standard-slot-value gf slot-name *the-class-standard-generic-function*))
 221
 222 (defun standard-slot-value/method (method slot-name)
 223   (standard-slot-value method slot-name *the-class-standard-method*))
 224
 225 (defun standard-slot-value/eslotd (slotd slot-name)
 226   (standard-slot-value slotd slot-name
 227                        *the-class-standard-effective-slot-definition*))
 228
 229 (defun standard-slot-value/class (class slot-name)
 230   (standard-slot-value class slot-name *the-class-standard-class*))
 231 \f
 232 ;;; When all the methods of a generic function are automatically
 233 ;;; generated reader or writer methods a number of special
 234 ;;; optimizations are possible. These are important because of the
 235 ;;; large number of generic functions of this type.
 236 ;;;
 237 ;;; There are a number of cases:
 238 ;;;
 239 ;;;   ONE-CLASS-ACCESSOR
 240 ;;;     In this case, the accessor generic function has only been
 241 ;;;     called with one class of argument. There is no cache vector,
 242 ;;;     the wrapper of the one class, and the slot index are stored
 243 ;;;     directly as closure variables of the discriminating function.
 244 ;;;     This case can convert to either of the next kind.
 245 ;;;
 246 ;;;   TWO-CLASS-ACCESSOR
 247 ;;;     Like above, but two classes. This is common enough to do
 248 ;;;     specially. There is no cache vector. The two classes are
 249 ;;;     stored a separate closure variables.
 250 ;;;
 251 ;;;   ONE-INDEX-ACCESSOR
 252 ;;;     In this case, the accessor generic function has seen more than
 253 ;;;     one class of argument, but the index of the slot is the same
 254 ;;;     for all the classes that have been seen. A cache vector is
 255 ;;;     used to store the wrappers that have been seen, the slot index
 256 ;;;     is stored directly as a closure variable of the discriminating
 257 ;;;     function. This case can convert to the next kind.
 258 ;;;
 259 ;;;   N-N-ACCESSOR
 260 ;;;     This is the most general case. In this case, the accessor
 261 ;;;     generic function has seen more than one class of argument and
 262 ;;;     more than one slot index. A cache vector stores the wrappers
 263 ;;;     and corresponding slot indexes. Because each cache line is
 264 ;;;     more than one element long, a cache lock count is used.
 265 (defstruct (dfun-info (:constructor nil)
 266                       (:copier nil))
 267   (cache nil))
 268
 269 (defstruct (no-methods (:constructor no-methods-dfun-info ())
 270                        (:include dfun-info)
 271                        (:copier nil)))
 272
 273 (defstruct (initial (:constructor initial-dfun-info ())
 274                     (:include dfun-info)
 275                     (:copier nil)))
 276
 277 (defstruct (initial-dispatch (:constructor initial-dispatch-dfun-info ())
 278                              (:include dfun-info)
 279                              (:copier nil)))
 280
 281 (defstruct (dispatch (:constructor dispatch-dfun-info ())
 282                      (:include dfun-info)
 283                      (:copier nil)))
 284
 285 (defstruct (default-method-only (:constructor default-method-only-dfun-info ())
 286                                 (:include dfun-info)
 287                                 (:copier nil)))
 288
 289 ;without caching:
 290 ;  dispatch one-class two-class default-method-only
 291
 292 ;with caching:
 293 ;  one-index n-n checking caching
 294
 295 ;accessor:
 296 ;  one-class two-class one-index n-n
 297 (defstruct (accessor-dfun-info (:constructor nil)
 298                                (:include dfun-info)
 299                                (:copier nil))
 300   accessor-type) ; (member reader writer)
 301
 302 (defmacro dfun-info-accessor-type (di)
 303   `(accessor-dfun-info-accessor-type ,di))
 304
 305 (defstruct (one-index-dfun-info (:constructor nil)
 306                                 (:include accessor-dfun-info)
 307                                 (:copier nil))
 308   index)
 309
 310 (defmacro dfun-info-index (di)
 311   `(one-index-dfun-info-index ,di))
 312
 313 (defstruct (n-n (:constructor n-n-dfun-info (accessor-type cache))
 314                 (:include accessor-dfun-info)
 315                 (:copier nil)))
 316
 317 (defstruct (one-class (:constructor one-class-dfun-info
 318                                     (accessor-type index wrapper0))
 319                       (:include one-index-dfun-info)
 320                       (:copier nil))
 321   wrapper0)
 322
 323 (defmacro dfun-info-wrapper0 (di)
 324   `(one-class-wrapper0 ,di))
 325
 326 (defstruct (two-class (:constructor two-class-dfun-info
 327                                     (accessor-type index wrapper0 wrapper1))
 328                       (:include one-class)
 329                       (:copier nil))
 330   wrapper1)
 331
 332 (defmacro dfun-info-wrapper1 (di)
 333   `(two-class-wrapper1 ,di))
 334
 335 (defstruct (one-index (:constructor one-index-dfun-info
 336                                     (accessor-type index cache))
 337                       (:include one-index-dfun-info)
 338                       (:copier nil)))
 339
 340 (defstruct (checking (:constructor checking-dfun-info (function cache))
 341                      (:include dfun-info)
 342                      (:copier nil))
 343   function)
 344
 345 (defmacro dfun-info-function (di)
 346   `(checking-function ,di))
 347
 348 (defstruct (caching (:constructor caching-dfun-info (cache))
 349                     (:include dfun-info)
 350                     (:copier nil)))
 351
 352 (defstruct (constant-value (:constructor constant-value-dfun-info (cache))
 353                            (:include dfun-info)
 354                            (:copier nil)))
 355
 356 (defmacro dfun-update (generic-function function &rest args)
 357   `(multiple-value-bind (dfun cache info)
 358        (funcall ,function ,generic-function ,@args)
 359      (update-dfun ,generic-function dfun cache info)))
 360
 361 (defun accessor-miss-function (gf dfun-info)
 362   (ecase (dfun-info-accessor-type dfun-info)
 363     ((reader boundp)
 364      (lambda (arg)
 365        (accessor-miss gf nil arg dfun-info)))
 366     (writer
 367      (lambda (new arg)
 368        (accessor-miss gf new arg dfun-info)))))
 369
 370 #-sb-fluid (declaim (sb-ext:freeze-type dfun-info))
 371 \f
 372 (defun make-one-class-accessor-dfun (gf type wrapper index)
 373   (let ((emit (ecase type
 374                 (reader 'emit-one-class-reader)
 375                 (boundp 'emit-one-class-boundp)
 376                 (writer 'emit-one-class-writer)))
 377         (dfun-info (one-class-dfun-info type index wrapper)))
 378     (values
 379      (funcall (get-dfun-constructor emit (consp index))
 380               wrapper index
 381               (accessor-miss-function gf dfun-info))
 382      nil
 383      dfun-info)))
 384
 385 (defun make-two-class-accessor-dfun (gf type w0 w1 index)
 386   (let ((emit (ecase type
 387                 (reader 'emit-two-class-reader)
 388                 (boundp 'emit-two-class-boundp)
 389                 (writer 'emit-two-class-writer)))
 390         (dfun-info (two-class-dfun-info type index w0 w1)))
 391     (values
 392      (funcall (get-dfun-constructor emit (consp index))
 393               w0 w1 index
 394               (accessor-miss-function gf dfun-info))
 395      nil
 396      dfun-info)))
 397
 398 ;;; std accessors same index dfun
 399 (defun make-one-index-accessor-dfun (gf type index &optional cache)
 400   (let* ((emit (ecase type
 401                  (reader 'emit-one-index-readers)
 402                  (boundp 'emit-one-index-boundps)
 403                  (writer 'emit-one-index-writers)))
 404          (cache (or cache (get-cache 1 nil #'one-index-limit-fn 4)))
 405          (dfun-info (one-index-dfun-info type index cache)))
 406     (declare (type cache cache))
 407     (values
 408      (funcall (get-dfun-constructor emit (consp index))
 409               cache
 410               index
 411               (accessor-miss-function gf dfun-info))
 412      cache
 413      dfun-info)))
 414
 415 (defun make-final-one-index-accessor-dfun (gf type index table)
 416   (let ((cache (fill-dfun-cache table nil 1 #'one-index-limit-fn)))
 417     (make-one-index-accessor-dfun gf type index cache)))
 418
 419 (defun one-index-limit-fn (nlines)
 420   (default-limit-fn nlines))
 421
 422 (defun make-n-n-accessor-dfun (gf type &optional cache)
 423   (let* ((emit (ecase type
 424                  (reader 'emit-n-n-readers)
 425                  (boundp 'emit-n-n-boundps)
 426                  (writer 'emit-n-n-writers)))
 427          (cache (or cache (get-cache 1 t #'n-n-accessors-limit-fn 2)))
 428          (dfun-info (n-n-dfun-info type cache)))
 429     (declare (type cache cache))
 430     (values
 431      (funcall (get-dfun-constructor emit)
 432               cache
 433               (accessor-miss-function gf dfun-info))
 434      cache
 435      dfun-info)))
 436
 437 (defun make-final-n-n-accessor-dfun (gf type table)
 438   (let ((cache (fill-dfun-cache table t 1 #'n-n-accessors-limit-fn)))
 439     (make-n-n-accessor-dfun gf type cache)))
 440
 441 (defun n-n-accessors-limit-fn (nlines)
 442   (default-limit-fn nlines))
 443
 444 (defun make-checking-dfun (generic-function function &optional cache)
 445   (unless cache
 446     (when (use-caching-dfun-p generic-function)
 447       (return-from make-checking-dfun (make-caching-dfun generic-function)))
 448     (when (use-dispatch-dfun-p generic-function)
 449       (return-from make-checking-dfun (make-dispatch-dfun generic-function))))
 450   (multiple-value-bind (nreq applyp metatypes nkeys)
 451       (get-generic-fun-info generic-function)
 452     (declare (ignore nreq))
 453     (if (every (lambda (mt) (eq mt t)) metatypes)
 454         (let ((dfun-info (default-method-only-dfun-info)))
 455           (values
 456            (funcall (get-dfun-constructor 'emit-default-only metatypes applyp)
 457                     function)
 458            nil
 459            dfun-info))
 460         (let* ((cache (or cache (get-cache nkeys nil #'checking-limit-fn 2)))
 461                (dfun-info (checking-dfun-info function cache)))
 462           (values
 463            (funcall (get-dfun-constructor 'emit-checking metatypes applyp)
 464                     cache
 465                     function
 466                     (lambda (&rest args)
 467                       (checking-miss generic-function args dfun-info)))
 468            cache
 469            dfun-info)))))
 470
 471 (defun make-final-checking-dfun (generic-function function
 472                                                   classes-list new-class)
 473   (let ((metatypes (arg-info-metatypes (gf-arg-info generic-function))))
 474     (if (every (lambda (mt) (eq mt t)) metatypes)
 475         (values (lambda (&rest args)
 476                   (invoke-emf function args))
 477                 nil (default-method-only-dfun-info))
 478         (let ((cache (make-final-ordinary-dfun-internal
 479                       generic-function nil #'checking-limit-fn
 480                       classes-list new-class)))
 481           (make-checking-dfun generic-function function cache)))))
 482
 483 (defun use-default-method-only-dfun-p (generic-function)
 484   (multiple-value-bind (nreq applyp metatypes nkeys)
 485       (get-generic-fun-info generic-function)
 486     (declare (ignore nreq applyp nkeys))
 487     (every (lambda (mt) (eq mt t)) metatypes)))
 488
 489 (defun use-caching-dfun-p (generic-function)
 490   (some (lambda (method)
 491           (let ((fmf (if (listp method)
 492                          (third method)
 493                          (method-fast-function method))))
 494             (method-function-get fmf :slot-name-lists)))
 495         ;; KLUDGE: As of sbcl-0.6.4, it's very important for
 496         ;; efficiency to know the type of the sequence argument to
 497         ;; quantifiers (SOME/NOTANY/etc.) at compile time, but
 498         ;; the compiler isn't smart enough to understand the :TYPE
 499         ;; slot option for DEFCLASS, so we just tell
 500         ;; it the type by hand here.
 501         (the list
 502              (if (early-gf-p generic-function)
 503                  (early-gf-methods generic-function)
 504                  (generic-function-methods generic-function)))))
 505
 506 (defun checking-limit-fn (nlines)
 507   (default-limit-fn nlines))
 508 \f
 509 (defun make-caching-dfun (generic-function &optional cache)
 510   (unless cache
 511     (when (use-constant-value-dfun-p generic-function)
 512       (return-from make-caching-dfun
 513         (make-constant-value-dfun generic-function)))
 514     (when (use-dispatch-dfun-p generic-function)
 515       (return-from make-caching-dfun
 516         (make-dispatch-dfun generic-function))))
 517   (multiple-value-bind (nreq applyp metatypes nkeys)
 518       (get-generic-fun-info generic-function)
 519     (declare (ignore nreq))
 520     (let* ((cache (or cache (get-cache nkeys t #'caching-limit-fn 2)))
 521            (dfun-info (caching-dfun-info cache)))
 522       (values
 523        (funcall (get-dfun-constructor 'emit-caching metatypes applyp)
 524                 cache
 525                 (lambda (&rest args)
 526                   (caching-miss generic-function args dfun-info)))
 527        cache
 528        dfun-info))))
 529
 530 (defun make-final-caching-dfun (generic-function classes-list new-class)
 531   (let ((cache (make-final-ordinary-dfun-internal
 532                 generic-function t #'caching-limit-fn
 533                 classes-list new-class)))
 534     (make-caching-dfun generic-function cache)))
 535
 536 (defun caching-limit-fn (nlines)
 537   (default-limit-fn nlines))
 538
 539 (defun insure-caching-dfun (gf)
 540   (multiple-value-bind (nreq applyp metatypes nkeys)
 541       (get-generic-fun-info gf)
 542     (declare (ignore nreq nkeys))
 543     (when (and metatypes
 544                (not (null (car metatypes)))
 545                (dolist (mt metatypes nil)
 546                  (unless (eq mt t) (return t))))
 547       (get-dfun-constructor 'emit-caching metatypes applyp))))
 548
 549 (defun use-constant-value-dfun-p (gf &optional boolean-values-p)
 550   (multiple-value-bind (nreq applyp metatypes nkeys)
 551       (get-generic-fun-info gf)
 552     (declare (ignore nreq metatypes nkeys))
 553     (let* ((early-p (early-gf-p gf))
 554            (methods (if early-p
 555                         (early-gf-methods gf)
 556                         (generic-function-methods gf)))
 557            (default '(unknown)))
 558       (and (null applyp)
 559            (or (not (eq *boot-state* 'complete))
 560                ;; If COMPUTE-APPLICABLE-METHODS is specialized, we
 561                ;; can't use this, of course, because we can't tell
 562                ;; which methods will be considered applicable.
 563                ;;
 564                ;; Also, don't use this dfun method if the generic
 565                ;; function has a non-standard method combination,
 566                ;; because if it has, it's not sure that method
 567                ;; functions are used directly as effective methods,
 568                ;; which CONSTANT-VALUE-MISS depends on.  The
 569                ;; pre-defined method combinations like LIST are
 570                ;; examples of that.
 571                (and (compute-applicable-methods-emf-std-p gf)
 572                     (eq (generic-function-method-combination gf)
 573                         *standard-method-combination*)))
 574            ;; Check that no method is eql-specialized, and that all
 575            ;; methods return a constant value.  If BOOLEAN-VALUES-P,
 576            ;; check that all return T or NIL.  Also, check that no
 577            ;; method has qualifiers, to make sure that emfs are really
 578            ;; method functions; see above.
 579            (dolist (method methods t)
 580              (when (eq *boot-state* 'complete)
 581                (when (or (some #'eql-specializer-p
 582                                (method-specializers method))
 583                          (method-qualifiers method))
 584                  (return nil)))
 585              (let ((value (method-function-get
 586                            (if early-p
 587                                (or (third method) (second method))
 588                                (or (method-fast-function method)
 589                                    (method-function method)))
 590                            :constant-value default)))
 591                (when (or (eq value default)
 592                          (and boolean-values-p
 593                               (not (member value '(t nil)))))
 594                  (return nil))))))))
 595
 596 (defun make-constant-value-dfun (generic-function &optional cache)
 597   (multiple-value-bind (nreq applyp metatypes nkeys)
 598       (get-generic-fun-info generic-function)
 599     (declare (ignore nreq applyp))
 600     (let* ((cache (or cache (get-cache nkeys t #'caching-limit-fn 2)))
 601            (dfun-info (constant-value-dfun-info cache)))
 602       (values
 603        (funcall (get-dfun-constructor 'emit-constant-value metatypes)
 604                 cache
 605                 (lambda (&rest args)
 606                   (constant-value-miss generic-function args dfun-info)))
 607        cache
 608        dfun-info))))
 609
 610 (defun make-final-constant-value-dfun (generic-function classes-list new-class)
 611   (let ((cache (make-final-ordinary-dfun-internal
 612                 generic-function :constant-value #'caching-limit-fn
 613                 classes-list new-class)))
 614     (make-constant-value-dfun generic-function cache)))
 615
 616 (defun use-dispatch-dfun-p (gf &optional (caching-p (use-caching-dfun-p gf)))
 617   (when (eq *boot-state* 'complete)
 618     (unless caching-p
 619       ;; This should return T when almost all dispatching is by
 620       ;; eql specializers or built-in classes. In other words,
 621       ;; return NIL if we might ever need to do more than
 622       ;; one (non built-in) typep.
 623       ;; Otherwise, it is probably at least as fast to use
 624       ;; a caching dfun first, possibly followed by secondary dispatching.
 625
 626       #||;;; Original found in cmu 17f -- S L O W
 627       (< (dispatch-dfun-cost gf) (caching-dfun-cost gf))
 628       ||#
 629       ;; This uses improved dispatch-dfun-cost below
 630       (let ((cdc  (caching-dfun-cost gf))) ; fast
 631         (> cdc (dispatch-dfun-cost gf cdc))))))
 632
 633 (defparameter *non-built-in-typep-cost* 1)
 634 (defparameter *structure-typep-cost* 1)
 635 (defparameter *built-in-typep-cost* 0)
 636
 637 ;;; According to comments in the original CMU CL version of PCL,
 638 ;;; the cost LIMIT is important to cut off exponential growth for
 639 ;;; large numbers of gf methods and argument lists.
 640 (defun dispatch-dfun-cost (gf &optional limit)
 641   (generate-discrimination-net-internal
 642    gf (generic-function-methods gf) nil
 643    (lambda (methods known-types)
 644      (declare (ignore methods known-types))
 645      0)
 646    (lambda (position type true-value false-value)
 647      (declare (ignore position))
 648      (let* ((type-test-cost
 649              (if (eq 'class (car type))
 650                  (let* ((metaclass (class-of (cadr type)))
 651                         (mcpl (class-precedence-list metaclass)))
 652                    (cond ((memq *the-class-built-in-class* mcpl)
 653                           *built-in-typep-cost*)
 654                          ((memq *the-class-structure-class* mcpl)
 655                           *structure-typep-cost*)
 656                          (t
 657                           *non-built-in-typep-cost*)))
 658                  0))
 659             (max-cost-so-far
 660              (+ (max true-value false-value) type-test-cost)))
 661        (when (and limit (<= limit max-cost-so-far))
 662          (return-from dispatch-dfun-cost max-cost-so-far))
 663        max-cost-so-far))
 664    #'identity))
 665
 666 (defparameter *cache-lookup-cost* 1)
 667 (defparameter *wrapper-of-cost* 0)
 668 (defparameter *secondary-dfun-call-cost* 1)
 669
 670 (defun caching-dfun-cost (gf)
 671   (let* ((arg-info (gf-arg-info gf))
 672          (nreq (length (arg-info-metatypes arg-info))))
 673     (+ *cache-lookup-cost*
 674        (* *wrapper-of-cost* nreq)
 675        (if (methods-contain-eql-specializer-p
 676             (generic-function-methods gf))
 677            *secondary-dfun-call-cost*
 678            0))))
 679
 680 (setq *non-built-in-typep-cost* 100)
 681 (setq *structure-typep-cost* 15)
 682 (setq *built-in-typep-cost* 5)
 683 (setq *cache-lookup-cost* 30)
 684 (setq *wrapper-of-cost* 15)
 685 (setq *secondary-dfun-call-cost* 30)
 686
 687 (defun make-dispatch-dfun (gf)
 688   (values (get-dispatch-function gf) nil (dispatch-dfun-info)))
 689
 690 (defun get-dispatch-function (gf)
 691   (let ((methods (generic-function-methods gf)))
 692     (function-funcall (get-secondary-dispatch-function1 gf methods nil nil nil
 693                                                         nil nil t)
 694                       nil nil)))
 695
 696 (defun make-final-dispatch-dfun (gf)
 697   (make-dispatch-dfun gf))
 698
 699 (defun update-dispatch-dfuns ()
 700   (dolist (gf (gfs-of-type '(dispatch initial-dispatch)))
 701     (dfun-update gf #'make-dispatch-dfun)))
 702
 703 (defun fill-dfun-cache (table valuep nkeys limit-fn &optional cache)
 704   (let ((cache (or cache (get-cache nkeys valuep limit-fn
 705                                     (+ (hash-table-count table) 3)))))
 706     (maphash (lambda (classes value)
 707                (setq cache (fill-cache cache
 708                                        (class-wrapper classes)
 709                                        value)))
 710              table)
 711     cache))
 712
 713 (defun make-final-ordinary-dfun-internal (generic-function valuep limit-fn
 714                                                            classes-list new-class)
 715   (let* ((arg-info (gf-arg-info generic-function))
 716          (nkeys (arg-info-nkeys arg-info))
 717          (new-class (and new-class
 718                          (equal (type-of (gf-dfun-info generic-function))
 719                                 (cond ((eq valuep t) 'caching)
 720                                       ((eq valuep :constant-value) 'constant-value)
 721                                       ((null valuep) 'checking)))
 722                          new-class))
 723          (cache (if new-class
 724                     (copy-cache (gf-dfun-cache generic-function))
 725                     (get-cache nkeys (not (null valuep)) limit-fn 4))))
 726       (make-emf-cache generic-function valuep cache classes-list new-class)))
 727 \f
 728 (defvar *dfun-miss-gfs-on-stack* ())
 729
 730 (defmacro dfun-miss ((gf args wrappers invalidp nemf
 731                       &optional type index caching-p applicable)
 732                      &body body)
 733   (unless applicable (setq applicable (gensym)))
 734   `(multiple-value-bind (,nemf ,applicable ,wrappers ,invalidp
 735                          ,@(when type `(,type ,index)))
 736        (cache-miss-values ,gf ,args ',(cond (caching-p 'caching)
 737                                             (type 'accessor)
 738                                             (t 'checking)))
 739     (when (and ,applicable (not (memq ,gf *dfun-miss-gfs-on-stack*)))
 740       (let ((*dfun-miss-gfs-on-stack* (cons ,gf *dfun-miss-gfs-on-stack*)))
 741         ,@body))
 742     ;; Create a FAST-INSTANCE-BOUNDP structure instance for a cached
 743     ;; SLOT-BOUNDP so that INVOKE-EMF does the right thing, that is,
 744     ;; does not signal a SLOT-UNBOUND error for a boundp test.
 745     ,@(if type
 746           ;; FIXME: could the NEMF not be a CONS (for :CLASS-allocated
 747           ;; slots?)
 748           `((if (and (eq ,type 'boundp) (integerp ,nemf))
 749                 (invoke-emf (make-fast-instance-boundp :index ,nemf) ,args)
 750                 (invoke-emf ,nemf ,args)))
 751           `((invoke-emf ,nemf ,args)))))
 752
 753 ;;; The dynamically adaptive method lookup algorithm is implemented is
 754 ;;; implemented as a kind of state machine. The kinds of
 755 ;;; discriminating function is the state, the various kinds of reasons
 756 ;;; for a cache miss are the state transitions.
 757 ;;;
 758 ;;; The code which implements the transitions is all in the miss
 759 ;;; handlers for each kind of dfun. Those appear here.
 760 ;;;
 761 ;;; Note that within the states that cache, there are dfun updates
 762 ;;; which simply select a new cache or cache field. Those are not
 763 ;;; considered as state transitions.
 764 (defvar *lazy-dfun-compute-p* t)
 765 (defvar *early-p* nil)
 766 (defvar *max-emf-precomputation-methods* 10)
 767
 768 (defun finalize-specializers (gf)
 769   (let ((methods (generic-function-methods gf)))
 770     (when (<= (length methods) *max-emf-precomputation-methods*)
 771       (let ((all-finalized t))
 772         (dolist (method methods all-finalized)
 773           (dolist (specializer (method-specializers method))
 774             (when (and (classp specializer)
 775                        (not (class-finalized-p specializer)))
 776               (if (class-has-a-forward-referenced-superclass-p specializer)
 777                   (setq all-finalized nil)
 778                   (finalize-inheritance specializer)))))))))
 779
 780 (defun make-initial-dfun (gf)
 781   (let ((initial-dfun
 782          #'(instance-lambda (&rest args)
 783              (initial-dfun gf args))))
 784     (multiple-value-bind (dfun cache info)
 785         (cond
 786           ((and (eq *boot-state* 'complete)
 787                 (not (finalize-specializers gf)))
 788            (values initial-dfun nil (initial-dfun-info)))
 789           ((and (eq *boot-state* 'complete)
 790                 (compute-applicable-methods-emf-std-p gf))
 791            (let* ((caching-p (use-caching-dfun-p gf))
 792                   ;; KLUDGE: the only effect of this (when
 793                   ;; *LAZY-DFUN-COMPUTE-P* is true, as it usually is)
 794                   ;; is to signal an error when we try to add methods
 795                   ;; with the wrong qualifiers to a generic function.
 796                   (classes-list (precompute-effective-methods
 797                                  gf caching-p
 798                                  (not *lazy-dfun-compute-p*))))
 799              (if *lazy-dfun-compute-p*
 800                  (cond ((use-dispatch-dfun-p gf caching-p)
 801                         (values initial-dfun
 802                                 nil
 803                                 (initial-dispatch-dfun-info)))
 804                        (caching-p
 805                         (insure-caching-dfun gf)
 806                         (values initial-dfun nil (initial-dfun-info)))
 807                        (t
 808                         (values initial-dfun nil (initial-dfun-info))))
 809                  (make-final-dfun-internal gf classes-list))))
 810           (t
 811            (let ((arg-info (if (early-gf-p gf)
 812                                (early-gf-arg-info gf)
 813                                (gf-arg-info gf)))
 814                  (type nil))
 815              (if (and (gf-precompute-dfun-and-emf-p arg-info)
 816                       (setq type (final-accessor-dfun-type gf)))
 817                  (if *early-p*
 818                      (values (make-early-accessor gf type) nil nil)
 819                      (make-final-accessor-dfun gf type))
 820                  (values initial-dfun nil (initial-dfun-info))))))
 821       (set-dfun gf dfun cache info))))
 822
 823 (defun make-early-accessor (gf type)
 824   (let* ((methods (early-gf-methods gf))
 825          (slot-name (early-method-standard-accessor-slot-name (car methods))))
 826     (ecase type
 827       (reader #'(instance-lambda (instance)
 828                   (let* ((class (class-of instance))
 829                          (class-name (!bootstrap-get-slot 'class class 'name)))
 830                     (!bootstrap-get-slot class-name instance slot-name))))
 831       (boundp #'(instance-lambda (instance)
 832                   (let* ((class (class-of instance))
 833                          (class-name (!bootstrap-get-slot 'class class 'name)))
 834                     (not (eq +slot-unbound+
 835                              (!bootstrap-get-slot class-name
 836                                                   instance slot-name))))))
 837       (writer #'(instance-lambda (new-value instance)
 838                   (let* ((class (class-of instance))
 839                          (class-name (!bootstrap-get-slot 'class class 'name)))
 840                     (!bootstrap-set-slot class-name instance slot-name new-value)))))))
 841
 842 (defun initial-dfun (gf args)
 843   (dfun-miss (gf args wrappers invalidp nemf ntype nindex)
 844     (cond (invalidp)
 845           ((and ntype nindex)
 846            (dfun-update
 847             gf #'make-one-class-accessor-dfun ntype wrappers nindex))
 848           ((use-caching-dfun-p gf)
 849            (dfun-update gf #'make-caching-dfun))
 850           (t
 851            (dfun-update
 852             gf #'make-checking-dfun
 853             ;; nemf is suitable only for caching, have to do this:
 854             (cache-miss-values gf args 'checking))))))
 855
 856 (defun make-final-dfun (gf &optional classes-list)
 857   (multiple-value-bind (dfun cache info)
 858       (make-final-dfun-internal gf classes-list)
 859     (set-dfun gf dfun cache info)))
 860
 861 (defvar *new-class* nil)
 862
 863 (defvar *free-hash-tables* (mapcar #'list '(eq equal eql)))
 864
 865 (defmacro with-hash-table ((table test) &body forms)
 866   `(let* ((.free. (assoc ',test *free-hash-tables*))
 867           (,table (if (cdr .free.)
 868                       (pop (cdr .free.))
 869                       (make-hash-table :test ',test))))
 870      (multiple-value-prog1
 871          (progn ,@forms)
 872        (clrhash ,table)
 873        (push ,table (cdr .free.)))))
 874
 875 (defmacro with-eq-hash-table ((table) &body forms)
 876   `(with-hash-table (,table eq) ,@forms))
 877
 878 (defun final-accessor-dfun-type (gf)
 879   (let ((methods (if (early-gf-p gf)
 880                      (early-gf-methods gf)
 881                      (generic-function-methods gf))))
 882     (cond ((every (lambda (method)
 883                     (if (consp method)
 884                         (eq *the-class-standard-reader-method*
 885                             (early-method-class method))
 886                         (standard-reader-method-p method)))
 887                   methods)
 888            'reader)
 889           ((every (lambda (method)
 890                     (if (consp method)
 891                         (eq *the-class-standard-boundp-method*
 892                             (early-method-class method))
 893                         (standard-boundp-method-p method)))
 894                   methods)
 895            'boundp)
 896           ((every (lambda (method)
 897                     (if (consp method)
 898                         (eq *the-class-standard-writer-method*
 899                             (early-method-class method))
 900                         (standard-writer-method-p method)))
 901                   methods)
 902            'writer))))
 903
 904 (defun make-final-accessor-dfun (gf type &optional classes-list new-class)
 905   (with-eq-hash-table (table)
 906     (multiple-value-bind (table all-index first second size no-class-slots-p)
 907         (make-accessor-table gf type table)
 908       (if table
 909           (cond ((= size 1)
 910                  (let ((w (class-wrapper first)))
 911                    (make-one-class-accessor-dfun gf type w all-index)))
 912                 ((and (= size 2) (or (integerp all-index) (consp all-index)))
 913                  (let ((w0 (class-wrapper first))
 914                        (w1 (class-wrapper second)))
 915                    (make-two-class-accessor-dfun gf type w0 w1 all-index)))
 916                 ((or (integerp all-index) (consp all-index))
 917                  (make-final-one-index-accessor-dfun
 918                   gf type all-index table))
 919                 (no-class-slots-p
 920                  (make-final-n-n-accessor-dfun gf type table))
 921                 (t
 922                  (make-final-caching-dfun gf classes-list new-class)))
 923           (make-final-caching-dfun gf classes-list new-class)))))
 924
 925 (defun make-final-dfun-internal (gf &optional classes-list)
 926   (let ((methods (generic-function-methods gf)) type
 927         (new-class *new-class*) (*new-class* nil)
 928         specls all-same-p)
 929     (cond ((null methods)
 930            (values
 931             #'(instance-lambda (&rest args)
 932                 (apply #'no-applicable-method gf args))
 933             nil
 934             (no-methods-dfun-info)))
 935           ((setq type (final-accessor-dfun-type gf))
 936            (make-final-accessor-dfun gf type classes-list new-class))
 937           ((and (not (and (every (lambda (specl) (eq specl *the-class-t*))
 938                                  (setq specls
 939                                        (method-specializers (car methods))))
 940                           (setq all-same-p
 941                                 (every (lambda (method)
 942                                          (and (equal specls
 943                                                      (method-specializers
 944                                                       method))))
 945                                        methods))))
 946                 (use-constant-value-dfun-p gf))
 947            (make-final-constant-value-dfun gf classes-list new-class))
 948           ((use-dispatch-dfun-p gf)
 949            (make-final-dispatch-dfun gf))
 950           ((and all-same-p (not (use-caching-dfun-p gf)))
 951            (let ((emf (get-secondary-dispatch-function gf methods nil)))
 952              (make-final-checking-dfun gf emf classes-list new-class)))
 953           (t
 954            (make-final-caching-dfun gf classes-list new-class)))))
 955
 956 (defun accessor-miss (gf new object dfun-info)
 957   (let* ((ostate (type-of dfun-info))
 958          (otype (dfun-info-accessor-type dfun-info))
 959          oindex ow0 ow1 cache
 960          (args (ecase otype
 961                  ;; The congruence rules ensure that this is safe
 962                  ;; despite not knowing the new type yet.
 963                  ((reader boundp) (list object))
 964                  (writer (list new object)))))
 965     (dfun-miss (gf args wrappers invalidp nemf ntype nindex)
 966
 967       ;; The following lexical functions change the state of the
 968       ;; dfun to that which is their name. They accept arguments
 969       ;; which are the parameters of the new state, and get other
 970       ;; information from the lexical variables bound above.
 971       (flet ((two-class (index w0 w1)
 972                (when (zerop (random 2)) (psetf w0 w1 w1 w0))
 973                (dfun-update gf
 974                             #'make-two-class-accessor-dfun
 975                             ntype
 976                             w0
 977                             w1
 978                             index))
 979              (one-index (index &optional cache)
 980                (dfun-update gf
 981                             #'make-one-index-accessor-dfun
 982                             ntype
 983                             index
 984                             cache))
 985              (n-n (&optional cache)
 986                (if (consp nindex)
 987                    (dfun-update gf #'make-checking-dfun nemf)
 988                    (dfun-update gf #'make-n-n-accessor-dfun ntype cache)))
 989              (caching () ; because cached accessor emfs are much faster
 990                          ; for accessors
 991                (dfun-update gf #'make-caching-dfun))
 992              (do-fill (update-fn)
 993                (let ((ncache (fill-cache cache wrappers nindex)))
 994                  (unless (eq ncache cache)
 995                    (funcall update-fn ncache)))))
 996
 997         (cond ((null ntype)
 998                (caching))
 999               ((or invalidp
1000                    (null nindex)))
1001               ((not (pcl-instance-p object))
1002                (caching))
1003               ((or (neq ntype otype) (listp wrappers))
1004                (caching))
1005               (t
1006                (ecase ostate
1007                  (one-class
1008                   (setq oindex (dfun-info-index dfun-info))
1009                   (setq ow0 (dfun-info-wrapper0 dfun-info))
1010                   (unless (eq ow0 wrappers)
1011                     (if (eql nindex oindex)
1012                         (two-class nindex ow0 wrappers)
1013                         (n-n))))
1014                  (two-class
1015                   (setq oindex (dfun-info-index dfun-info))
1016                   (setq ow0 (dfun-info-wrapper0 dfun-info))
1017                   (setq ow1 (dfun-info-wrapper1 dfun-info))
1018                   (unless (or (eq ow0 wrappers) (eq ow1 wrappers))
1019                     (if (eql nindex oindex)
1020                         (one-index nindex)
1021                         (n-n))))
1022                  (one-index
1023                   (setq oindex (dfun-info-index dfun-info))
1024                   (setq cache (dfun-info-cache dfun-info))
1025                   (if (eql nindex oindex)
1026                       (do-fill (lambda (ncache)
1027                                  (one-index nindex ncache)))
1028                       (n-n)))
1029                  (n-n
1030                   (setq cache (dfun-info-cache dfun-info))
1031                   (if (consp nindex)
1032                       (caching)
1033                       (do-fill #'n-n))))))))))
1034
1035 (defun checking-miss (generic-function args dfun-info)
1036   (let ((oemf (dfun-info-function dfun-info))
1037         (cache (dfun-info-cache dfun-info)))
1038     (dfun-miss (generic-function args wrappers invalidp nemf)
1039       (cond (invalidp)
1040             ((eq oemf nemf)
1041              (let ((ncache (fill-cache cache wrappers nil)))
1042                (unless (eq ncache cache)
1043                  (dfun-update generic-function #'make-checking-dfun
1044                               nemf ncache))))
1045             (t
1046              (dfun-update generic-function #'make-caching-dfun))))))
1047
1048 (defun caching-miss (generic-function args dfun-info)
1049   (let ((ocache (dfun-info-cache dfun-info)))
1050     (dfun-miss (generic-function args wrappers invalidp emf nil nil t)
1051       (cond (invalidp)
1052             (t
1053              (let ((ncache (fill-cache ocache wrappers emf)))
1054                (unless (eq ncache ocache)
1055                  (dfun-update generic-function
1056                               #'make-caching-dfun ncache))))))))
1057
1058 (defun constant-value-miss (generic-function args dfun-info)
1059   (let ((ocache (dfun-info-cache dfun-info)))
1060     (dfun-miss (generic-function args wrappers invalidp emf nil nil t)
1061       (unless invalidp
1062         (let* ((function
1063                 (typecase emf
1064                   (fast-method-call (fast-method-call-function emf))
1065                   (method-call (method-call-function emf))))
1066                (value (let ((val (method-function-get
1067                                   function :constant-value '.not-found.)))
1068                         (aver (not (eq val '.not-found.)))
1069                         val))
1070                (ncache (fill-cache ocache wrappers value)))
1071           (unless (eq ncache ocache)
1072             (dfun-update generic-function
1073                          #'make-constant-value-dfun ncache)))))))
1074 \f
1075 ;;; Given a generic function and a set of arguments to that generic
1076 ;;; function, return a mess of values.
1077 ;;;
1078 ;;;  <function>   The compiled effective method function for this set of
1079 ;;;            arguments.
1080 ;;;
1081 ;;;  <applicable> Sorted list of applicable methods.
1082 ;;;
1083 ;;;  <wrappers>   Is a single wrapper if the generic function has only
1084 ;;;            one key, that is arg-info-nkeys of the arg-info is 1.
1085 ;;;            Otherwise a list of the wrappers of the specialized
1086 ;;;            arguments to the generic function.
1087 ;;;
1088 ;;;            Note that all these wrappers are valid. This function
1089 ;;;            does invalid wrapper traps when it finds an invalid
1090 ;;;            wrapper and then returns the new, valid wrapper.
1091 ;;;
1092 ;;;  <invalidp>   True if any of the specialized arguments had an invalid
1093 ;;;            wrapper, false otherwise.
1094 ;;;
1095 ;;;  <type>       READER or WRITER when the only method that would be run
1096 ;;;            is a standard reader or writer method. To be specific,
1097 ;;;            the value is READER when the method combination is eq to
1098 ;;;            *standard-method-combination*; there are no applicable
1099 ;;;            :before, :after or :around methods; and the most specific
1100 ;;;            primary method is a standard reader method.
1101 ;;;
1102 ;;;  <index>      If <type> is READER or WRITER, and the slot accessed is
1103 ;;;            an :instance slot, this is the index number of that slot
1104 ;;;            in the object argument.
1105 (defvar *cache-miss-values-stack* ())
1106
1107 (defun cache-miss-values (gf args state)
1108   (multiple-value-bind (nreq applyp metatypes nkeys arg-info)
1109       (get-generic-fun-info gf)
1110     (declare (ignore nreq applyp nkeys))
1111     (with-dfun-wrappers (args metatypes)
1112       (dfun-wrappers invalid-wrapper-p wrappers classes types)
1113       (error-need-at-least-n-args gf (length metatypes))
1114       (multiple-value-bind (emf methods accessor-type index)
1115           (cache-miss-values-internal
1116            gf arg-info wrappers classes types state)
1117         (values emf methods
1118                 dfun-wrappers
1119                 invalid-wrapper-p
1120                 accessor-type index)))))
1121
1122 (defun cache-miss-values-internal (gf arg-info wrappers classes types state)
1123   (if (and classes (equal classes (cdr (assq gf *cache-miss-values-stack*))))
1124       (break-vicious-metacircle gf classes arg-info)
1125       (let ((*cache-miss-values-stack*
1126              (acons gf classes *cache-miss-values-stack*))
1127             (cam-std-p (or (null arg-info)
1128                            (gf-info-c-a-m-emf-std-p arg-info))))
1129         (multiple-value-bind (methods all-applicable-and-sorted-p)
1130             (if cam-std-p
1131                 (compute-applicable-methods-using-types gf types)
1132                 (compute-applicable-methods-using-classes gf classes))
1133
1134   (let* ((for-accessor-p (eq state 'accessor))
1135          (for-cache-p (or (eq state 'caching) (eq state 'accessor)))
1136          (emf (if (or cam-std-p all-applicable-and-sorted-p)
1137                   (function-funcall (get-secondary-dispatch-function1
1138                                      gf methods types nil (and for-cache-p
1139                                                                wrappers)
1140                                      all-applicable-and-sorted-p)
1141                                     nil (and for-cache-p wrappers))
1142                   (default-secondary-dispatch-function gf))))
1143     (multiple-value-bind (index accessor-type)
1144         (and for-accessor-p all-applicable-and-sorted-p methods
1145              (accessor-values gf arg-info classes methods))
1146       (values (if (integerp index) index emf)
1147               methods accessor-type index)))))))
1148
1149 ;;; Try to break a vicious circle while computing a cache miss.
1150 ;;; GF is the generic function, CLASSES are the classes of actual
1151 ;;; arguments, and ARG-INFO is the generic functions' arg-info.
1152 ;;;
1153 ;;; A vicious circle can be entered when the computation of the cache
1154 ;;; miss values itself depends on the values being computed.  For
1155 ;;; instance, adding a method which is an instance of a subclass of
1156 ;;; STANDARD-METHOD leads to cache misses for slot accessors of
1157 ;;; STANDARD-METHOD like METHOD-SPECIALIZERS, and METHOD-SPECIALIZERS
1158 ;;; is itself used while we compute cache miss values.
1159 (defun break-vicious-metacircle (gf classes arg-info)
1160   (when (typep gf 'standard-generic-function)
1161     (multiple-value-bind (class slotd accessor-type)
1162         (accesses-standard-class-slot-p gf)
1163       (when class
1164         (let ((method (find-standard-class-accessor-method
1165                        gf class accessor-type))
1166               (index (standard-slot-value/eslotd slotd 'location))
1167               (type (gf-info-simple-accessor-type arg-info)))
1168           (when (and method
1169                      (subtypep (ecase accessor-type
1170                                  ((reader) (car classes))
1171                                  ((writer) (cadr classes)))
1172                                class))
1173             (return-from break-vicious-metacircle
1174               (values index (list method) type index)))))))
1175   (error "~@<vicious metacircle:  The computation of an ~
1176           effective method of ~s for arguments of types ~s uses ~
1177           the effective method being computed.~@:>"
1178          gf classes))
1179
1180 ;;; Return (CLASS SLOTD ACCESSOR-TYPE) if some method of generic
1181 ;;; function GF accesses a slot of some class in *STANDARD-CLASSES*.
1182 ;;; CLASS is the class accessed, SLOTD is the effective slot definition
1183 ;;; object of the slot accessed, and ACCESSOR-TYPE is one of the symbols
1184 ;;; READER or WRITER describing the slot access.
1185 (defun accesses-standard-class-slot-p (gf)
1186   (flet ((standard-class-slot-access (gf class)
1187            (loop with gf-name = (standard-slot-value/gf gf 'name)
1188                  for slotd in (standard-slot-value/class class 'slots)
1189                  ;; FIXME: where does BOUNDP fit in here?  Is it
1190                  ;; relevant?
1191                  as readers = (standard-slot-value/eslotd slotd 'readers)
1192                  as writers = (standard-slot-value/eslotd slotd 'writers)
1193                  if (member gf-name readers :test #'equal)
1194                    return (values slotd 'reader)
1195                  else if (member gf-name writers :test #'equal)
1196                    return (values slotd 'writer))))
1197     (dolist (class-name *standard-classes*)
1198       (let ((class (find-class class-name)))
1199         (multiple-value-bind (slotd accessor-type)
1200             (standard-class-slot-access gf class)
1201           (when slotd
1202             (return (values class slotd accessor-type))))))))
1203
1204 ;;; Find a slot reader/writer method among the methods of generic
1205 ;;; function GF which reads/writes instances of class CLASS.
1206 ;;; TYPE is one of the symbols READER or WRITER.
1207 (defun find-standard-class-accessor-method (gf class type)
1208   (dolist (method (standard-slot-value/gf gf 'methods))
1209     (let ((specializers (standard-slot-value/method method 'specializers))
1210           (qualifiers (plist-value method 'qualifiers)))
1211       (when (and (null qualifiers)
1212                  (eq (ecase type
1213                        (reader (car specializers))
1214                        (writer (cadr specializers)))
1215                      class))
1216         (return method)))))
1217
1218 (defun accessor-values (gf arg-info classes methods)
1219   (declare (ignore gf))
1220   (let* ((accessor-type (gf-info-simple-accessor-type arg-info))
1221          (accessor-class (case accessor-type
1222                            ((reader boundp) (car classes))
1223                            (writer (cadr classes)))))
1224     (accessor-values-internal accessor-type accessor-class methods)))
1225
1226 (defun accessor-values1 (gf accessor-type accessor-class)
1227   (let* ((type `(class-eq ,accessor-class))
1228          (types (ecase accessor-type
1229                   ((reader boundp) `(,type))
1230                   (writer `(t ,type))))
1231          (methods (compute-applicable-methods-using-types gf types)))
1232     (accessor-values-internal accessor-type accessor-class methods)))
1233
1234 (defun accessor-values-internal (accessor-type accessor-class methods)
1235   (dolist (meth methods)
1236     (when (if (consp meth)
1237               (early-method-qualifiers meth)
1238               (method-qualifiers meth))
1239       (return-from accessor-values-internal (values nil nil))))
1240   (let* ((meth (car methods))
1241          (early-p (not (eq *boot-state* 'complete)))
1242          (slot-name (when accessor-class
1243                       (if (consp meth)
1244                           (and (early-method-standard-accessor-p meth)
1245                                (early-method-standard-accessor-slot-name meth))
1246                           (and (member *the-class-std-object*
1247                                        (if early-p
1248                                            (early-class-precedence-list
1249                                             accessor-class)
1250                                            (class-precedence-list
1251                                             accessor-class)))
1252                                (if early-p
1253                                    (not (eq *the-class-standard-method*
1254                                             (early-method-class meth)))
1255                                    (standard-accessor-method-p meth))
1256                                (if early-p
1257                                    (early-accessor-method-slot-name meth)
1258                                    (accessor-method-slot-name meth))))))
1259          (slotd (and accessor-class
1260                      (if early-p
1261                          (dolist (slot (early-class-slotds accessor-class) nil)
1262                            (when (eql slot-name
1263                                       (early-slot-definition-name slot))
1264                              (return slot)))
1265                          (find-slot-definition accessor-class slot-name)))))
1266     (when (and slotd
1267                (or early-p
1268                    (slot-accessor-std-p slotd accessor-type)))
1269       (values (if early-p
1270                   (early-slot-definition-location slotd)
1271                   (slot-definition-location slotd))
1272               accessor-type))))
1273
1274 (defun make-accessor-table (gf type &optional table)
1275   (unless table (setq table (make-hash-table :test 'eq)))
1276   (let ((methods (if (early-gf-p gf)
1277                      (early-gf-methods gf)
1278                      (generic-function-methods gf)))
1279         (all-index nil)
1280         (no-class-slots-p t)
1281         (early-p (not (eq *boot-state* 'complete)))
1282         first second (size 0))
1283     (declare (fixnum size))
1284     ;; class -> {(specl slotd)}
1285     (dolist (method methods)
1286       (let* ((specializers (if (consp method)
1287                                (early-method-specializers method t)
1288                                (method-specializers method)))
1289              (specl (ecase type
1290                       ((reader boundp) (car specializers))
1291                       (writer (cadr specializers))))
1292              (specl-cpl (if early-p
1293                             (early-class-precedence-list specl)
1294                             (and (class-finalized-p specl)
1295                                  (class-precedence-list specl))))
1296              (so-p (member *the-class-std-object* specl-cpl))
1297              (slot-name (if (consp method)
1298                             (and (early-method-standard-accessor-p method)
1299                                  (early-method-standard-accessor-slot-name
1300                                   method))
1301                             (accessor-method-slot-name method))))
1302         (when (or (null specl-cpl)
1303                   (member *the-class-structure-object* specl-cpl))
1304           (return-from make-accessor-table nil))
1305         (maphash (lambda (class slotd)
1306                    (let ((cpl (if early-p
1307                                   (early-class-precedence-list class)
1308                                   (class-precedence-list class))))
1309                      (when (memq specl cpl)
1310                        (unless (and (or so-p
1311                                         (member *the-class-std-object* cpl))
1312                                     (or early-p
1313                                         (slot-accessor-std-p slotd type)))
1314                          (return-from make-accessor-table nil))
1315                        (push (cons specl slotd) (gethash class table)))))
1316                  (gethash slot-name *name->class->slotd-table*))))
1317     (maphash (lambda (class specl+slotd-list)
1318                (dolist (sclass (if early-p
1319                                    (early-class-precedence-list class)
1320                                    (class-precedence-list class))
1321                                (error "This can't happen."))
1322                  (let ((a (assq sclass specl+slotd-list)))
1323                    (when a
1324                      (let* ((slotd (cdr a))
1325                             (index (if early-p
1326                                        (early-slot-definition-location slotd)
1327                                        (slot-definition-location slotd))))
1328                        (unless index (return-from make-accessor-table nil))
1329                        (setf (gethash class table) index)
1330                        (when (consp index) (setq no-class-slots-p nil))
1331                        (setq all-index (if (or (null all-index)
1332                                                (eql all-index index))
1333                                            index t))
1334                        (incf size)
1335                        (cond ((= size 1) (setq first class))
1336                              ((= size 2) (setq second class)))
1337                        (return nil))))))
1338              table)
1339     (values table all-index first second size no-class-slots-p)))
1340
1341 (defun compute-applicable-methods-using-types (generic-function types)
1342   (let ((definite-p t) (possibly-applicable-methods nil))
1343     (dolist (method (if (early-gf-p generic-function)
1344                         (early-gf-methods generic-function)
1345                         (generic-function-methods generic-function)))
1346       (let ((specls (if (consp method)
1347                         (early-method-specializers method t)
1348                         (method-specializers method)))
1349             (types types)
1350             (possibly-applicable-p t) (applicable-p t))
1351         (dolist (specl specls)
1352           (multiple-value-bind (specl-applicable-p specl-possibly-applicable-p)
1353               (specializer-applicable-using-type-p specl (pop types))
1354             (unless specl-applicable-p
1355               (setq applicable-p nil))
1356             (unless specl-possibly-applicable-p
1357               (setq possibly-applicable-p nil)
1358               (return nil))))
1359         (when possibly-applicable-p
1360           (unless applicable-p (setq definite-p nil))
1361           (push method possibly-applicable-methods))))
1362     (let ((precedence (arg-info-precedence (if (early-gf-p generic-function)
1363                                                (early-gf-arg-info
1364                                                 generic-function)
1365                                                (gf-arg-info
1366                                                 generic-function)))))
1367       (values (sort-applicable-methods precedence
1368                                        (nreverse possibly-applicable-methods)
1369                                        types)
1370               definite-p))))
1371
1372 (defun sort-applicable-methods (precedence methods types)
1373   (sort-methods methods
1374                 precedence
1375                 (lambda (class1 class2 index)
1376                   (let* ((class (type-class (nth index types)))
1377                          (cpl (if (eq *boot-state* 'complete)
1378                                   (class-precedence-list class)
1379                                   (early-class-precedence-list class))))
1380                     (if (memq class2 (memq class1 cpl))
1381                         class1 class2)))))
1382
1383 (defun sort-methods (methods precedence compare-classes-function)
1384   (flet ((sorter (method1 method2)
1385            (dolist (index precedence)
1386              (let* ((specl1 (nth index (if (listp method1)
1387                                            (early-method-specializers method1
1388                                                                       t)
1389                                            (method-specializers method1))))
1390                     (specl2 (nth index (if (listp method2)
1391                                            (early-method-specializers method2
1392                                                                       t)
1393                                            (method-specializers method2))))
1394                     (order (order-specializers
1395                              specl1 specl2 index compare-classes-function)))
1396                (when order
1397                  (return-from sorter (eq order specl1)))))))
1398     (stable-sort methods #'sorter)))
1399
1400 (defun order-specializers (specl1 specl2 index compare-classes-function)
1401   (let ((type1 (if (eq *boot-state* 'complete)
1402                    (specializer-type specl1)
1403                    (!bootstrap-get-slot 'specializer specl1 'type)))
1404         (type2 (if (eq *boot-state* 'complete)
1405                    (specializer-type specl2)
1406                    (!bootstrap-get-slot 'specializer specl2 'type))))
1407     (cond ((eq specl1 specl2)
1408            nil)
1409           ((atom type1)
1410            specl2)
1411           ((atom type2)
1412            specl1)
1413           (t
1414            (case (car type1)
1415              (class    (case (car type2)
1416                          (class (funcall compare-classes-function
1417                                          specl1 specl2 index))
1418                          (t specl2)))
1419              (prototype (case (car type2)
1420                          (class (funcall compare-classes-function
1421                                          specl1 specl2 index))
1422                          (t specl2)))
1423              (class-eq (case (car type2)
1424                          (eql specl2)
1425                          (class-eq nil)
1426                          (class type1)))
1427              (eql      (case (car type2)
1428                          (eql nil)
1429                          (t specl1))))))))
1430
1431 (defun map-all-orders (methods precedence function)
1432   (let ((choices nil))
1433     (flet ((compare-classes-function (class1 class2 index)
1434              (declare (ignore index))
1435              (let ((choice nil))
1436                (dolist (c choices nil)
1437                  (when (or (and (eq (first c) class1)
1438                                 (eq (second c) class2))
1439                            (and (eq (first c) class2)
1440                                 (eq (second c) class1)))
1441                    (return (setq choice c))))
1442                (unless choice
1443                  (setq choice
1444                        (if (class-might-precede-p class1 class2)
1445                            (if (class-might-precede-p class2 class1)
1446                                (list class1 class2 nil t)
1447                                (list class1 class2 t))
1448                            (if (class-might-precede-p class2 class1)
1449                                (list class2 class1 t)
1450                                (let ((name1 (class-name class1))
1451                                      (name2 (class-name class2)))
1452                                  (if (and name1
1453                                           name2
1454                                           (symbolp name1)
1455                                           (symbolp name2)
1456                                           (string< (symbol-name name1)
1457                                                    (symbol-name name2)))
1458                                      (list class1 class2 t)
1459                                      (list class2 class1 t))))))
1460                  (push choice choices))
1461                (car choice))))
1462       (loop (funcall function
1463                      (sort-methods methods
1464                                    precedence
1465                                    #'compare-classes-function))
1466             (unless (dolist (c choices nil)
1467                       (unless (third c)
1468                         (rotatef (car c) (cadr c))
1469                         (return (setf (third c) t))))
1470               (return nil))))))
1471
1472 (defvar *in-precompute-effective-methods-p* nil)
1473
1474 ;used only in map-all-orders
1475 (defun class-might-precede-p (class1 class2)
1476   (if (not *in-precompute-effective-methods-p*)
1477       (not (member class1 (cdr (class-precedence-list class2))))
1478       (class-can-precede-p class1 class2)))
1479
1480 (defun compute-precedence (lambda-list nreq argument-precedence-order)
1481   (if (null argument-precedence-order)
1482       (let ((list nil))
1483         (dotimes-fixnum (i nreq list) (push (- (1- nreq) i) list)))
1484       (mapcar (lambda (x) (position x lambda-list))
1485               argument-precedence-order)))
1486
1487 (defun cpl-or-nil (class)
1488   (if (eq *boot-state* 'complete)
1489       (when (class-finalized-p class)
1490         (class-precedence-list class))
1491       (early-class-precedence-list class)))
1492
1493 (defun saut-and (specl type)
1494   (let ((applicable nil)
1495         (possibly-applicable t))
1496     (dolist (type (cdr type))
1497       (multiple-value-bind (appl poss-appl)
1498           (specializer-applicable-using-type-p specl type)
1499         (when appl (return (setq applicable t)))
1500         (unless poss-appl (return (setq possibly-applicable nil)))))
1501     (values applicable possibly-applicable)))
1502
1503 (defun saut-not (specl type)
1504   (let ((ntype (cadr type)))
1505     (values nil
1506             (case (car ntype)
1507               (class      (saut-not-class specl ntype))
1508               (class-eq   (saut-not-class-eq specl ntype))
1509               (prototype  (saut-not-prototype specl ntype))
1510               (eql      (saut-not-eql specl ntype))
1511               (t (error "~S cannot handle the second argument ~S"
1512                         'specializer-applicable-using-type-p type))))))
1513
1514 (defun saut-not-class (specl ntype)
1515   (let* ((class (type-class specl))
1516          (cpl (cpl-or-nil class)))
1517     (not (memq (cadr ntype) cpl))))
1518
1519 (defun saut-not-prototype (specl ntype)
1520   (let* ((class (case (car specl)
1521                   (eql       (class-of (cadr specl)))
1522                   (class-eq  (cadr specl))
1523                   (prototype (cadr specl))
1524                   (class     (cadr specl))))
1525          (cpl (cpl-or-nil class)))
1526     (not (memq (cadr ntype) cpl))))
1527
1528 (defun saut-not-class-eq (specl ntype)
1529   (let ((class (case (car specl)
1530                  (eql      (class-of (cadr specl)))
1531                  (class-eq (cadr specl)))))
1532     (not (eq class (cadr ntype)))))
1533
1534 (defun saut-not-eql (specl ntype)
1535   (case (car specl)
1536     (eql (not (eql (cadr specl) (cadr ntype))))
1537     (t   t)))
1538
1539 (defun class-applicable-using-class-p (specl type)
1540   (let ((pred (memq specl (cpl-or-nil type))))
1541     (values pred
1542             (or pred
1543                 (if (not *in-precompute-effective-methods-p*)
1544                     ;; classes might get common subclass
1545                     (superclasses-compatible-p specl type)
1546                     ;; worry only about existing classes
1547                     (classes-have-common-subclass-p specl type))))))
1548
1549 (defun classes-have-common-subclass-p (class1 class2)
1550   (or (eq class1 class2)
1551       (let ((class1-subs (class-direct-subclasses class1)))
1552         (or (memq class2 class1-subs)
1553             (dolist (class1-sub class1-subs nil)
1554               (when (classes-have-common-subclass-p class1-sub class2)
1555                 (return t)))))))
1556
1557 (defun saut-class (specl type)
1558   (case (car specl)
1559     (class (class-applicable-using-class-p (cadr specl) (cadr type)))
1560     (t     (values nil (let ((class (type-class specl)))
1561                          (memq (cadr type)
1562                                (cpl-or-nil class)))))))
1563
1564 (defun saut-class-eq (specl type)
1565   (if (eq (car specl) 'eql)
1566       (values nil (eq (class-of (cadr specl)) (cadr type)))
1567       (let ((pred (case (car specl)
1568                     (class-eq
1569                      (eq (cadr specl) (cadr type)))
1570                     (class
1571                      (or (eq (cadr specl) (cadr type))
1572                          (memq (cadr specl) (cpl-or-nil (cadr type))))))))
1573         (values pred pred))))
1574
1575 (defun saut-prototype (specl type)
1576   (declare (ignore specl type))
1577   (values nil nil)) ; XXX original PCL comment: fix this someday
1578
1579 (defun saut-eql (specl type)
1580   (let ((pred (case (car specl)
1581                 (eql    (eql (cadr specl) (cadr type)))
1582                 (class-eq   (eq (cadr specl) (class-of (cadr type))))
1583                 (class      (memq (cadr specl)
1584                                   (let ((class (class-of (cadr type))))
1585                                     (cpl-or-nil class)))))))
1586     (values pred pred)))
1587
1588 (defun specializer-applicable-using-type-p (specl type)
1589   (setq specl (type-from-specializer specl))
1590   (when (eq specl t)
1591     (return-from specializer-applicable-using-type-p (values t t)))
1592   ;; This is used by C-A-M-U-T and GENERATE-DISCRIMINATION-NET-INTERNAL,
1593   ;; and has only what they need.
1594   (if (or (atom type) (eq (car type) t))
1595       (values nil t)
1596       (case (car type)
1597         (and    (saut-and specl type))
1598         (not    (saut-not specl type))
1599         (class      (saut-class specl type))
1600         (prototype  (saut-prototype specl type))
1601         (class-eq   (saut-class-eq specl type))
1602         (eql    (saut-eql specl type))
1603         (t        (error "~S cannot handle the second argument ~S."
1604                            'specializer-applicable-using-type-p
1605                            type)))))
1606
1607 (defun map-all-classes (function &optional (root t))
1608   (let ((braid-p (or (eq *boot-state* 'braid)
1609                      (eq *boot-state* 'complete))))
1610     (labels ((do-class (class)
1611                (mapc #'do-class
1612                      (if braid-p
1613                          (class-direct-subclasses class)
1614                          (early-class-direct-subclasses class)))
1615                (funcall function class)))
1616       (do-class (if (symbolp root)
1617                     (find-class root)
1618                     root)))))
1619 \f
1620 ;;; NOTE: We are assuming a restriction on user code that the method
1621 ;;;       combination must not change once it is connected to the
1622 ;;;       generic function.
1623 ;;;
1624 ;;;       This has to be legal, because otherwise any kind of method
1625 ;;;       lookup caching couldn't work. See this by saying that this
1626 ;;;       cache, is just a backing cache for the fast cache. If that
1627 ;;;       cache is legal, this one must be too.
1628 ;;;
1629 ;;; Don't clear this table!
1630 (defvar *effective-method-table* (make-hash-table :test 'eq))
1631
1632 (defun get-secondary-dispatch-function (gf methods types &optional
1633                                                          method-alist wrappers)
1634   (function-funcall (get-secondary-dispatch-function1
1635                      gf methods types
1636                      (not (null method-alist))
1637                      (not (null wrappers))
1638                      (not (methods-contain-eql-specializer-p methods)))
1639                     method-alist wrappers))
1640
1641 (defun get-secondary-dispatch-function1 (gf methods types method-alist-p
1642                                             wrappers-p
1643                                             &optional
1644                                             all-applicable-p
1645                                             (all-sorted-p t)
1646                                             function-p)
1647   (if (null methods)
1648       (if function-p
1649           (lambda (method-alist wrappers)
1650             (declare (ignore method-alist wrappers))
1651             #'(instance-lambda (&rest args)
1652                 (apply #'no-applicable-method gf args)))
1653           (lambda (method-alist wrappers)
1654             (declare (ignore method-alist wrappers))
1655             (lambda (&rest args)
1656               (apply #'no-applicable-method gf args))))
1657       (let* ((key (car methods))
1658              (ht-value (or (gethash key *effective-method-table*)
1659                            (setf (gethash key *effective-method-table*)
1660                                  (cons nil nil)))))
1661         (if (and (null (cdr methods)) all-applicable-p ; the most common case
1662                  (null method-alist-p) wrappers-p (not function-p))
1663             (or (car ht-value)
1664                 (setf (car ht-value)
1665                       (get-secondary-dispatch-function2
1666                        gf methods types method-alist-p wrappers-p
1667                        all-applicable-p all-sorted-p function-p)))
1668             (let ((akey (list methods
1669                               (if all-applicable-p 'all-applicable types)
1670                               method-alist-p wrappers-p function-p)))
1671               (or (cdr (assoc akey (cdr ht-value) :test #'equal))
1672                   (let ((value (get-secondary-dispatch-function2
1673                                 gf methods types method-alist-p wrappers-p
1674                                 all-applicable-p all-sorted-p function-p)))
1675                     (push (cons akey value) (cdr ht-value))
1676                     value)))))))
1677
1678 (defun get-secondary-dispatch-function2 (gf methods types method-alist-p
1679                                             wrappers-p all-applicable-p
1680                                             all-sorted-p function-p)
1681   (if (and all-applicable-p all-sorted-p (not function-p))
1682       (if (eq *boot-state* 'complete)
1683           (let* ((combin (generic-function-method-combination gf))
1684                  (effective (compute-effective-method gf combin methods)))
1685             (make-effective-method-function1 gf effective method-alist-p
1686                                              wrappers-p))
1687           (let ((effective (standard-compute-effective-method gf nil methods)))
1688             (make-effective-method-function1 gf effective method-alist-p
1689                                              wrappers-p)))
1690       (let ((net (generate-discrimination-net
1691                   gf methods types all-sorted-p)))
1692         (compute-secondary-dispatch-function1 gf net function-p))))
1693
1694 (defun get-effective-method-function (gf methods
1695                                          &optional method-alist wrappers)
1696   (function-funcall (get-secondary-dispatch-function1 gf methods nil
1697                                                       (not (null method-alist))
1698                                                       (not (null wrappers))
1699                                                       t)
1700                     method-alist wrappers))
1701
1702 (defun get-effective-method-function1 (gf methods &optional (sorted-p t))
1703   (get-secondary-dispatch-function1 gf methods nil nil nil t sorted-p))
1704
1705 (defun methods-contain-eql-specializer-p (methods)
1706   (and (eq *boot-state* 'complete)
1707        (dolist (method methods nil)
1708          (when (dolist (spec (method-specializers method) nil)
1709                  (when (eql-specializer-p spec) (return t)))
1710            (return t)))))
1711 \f
1712 (defun update-dfun (generic-function &optional dfun cache info)
1713   (let* ((early-p (early-gf-p generic-function))
1714          (gf-name (if early-p
1715                       (!early-gf-name generic-function)
1716                       (generic-function-name generic-function))))
1717     (set-dfun generic-function dfun cache info)
1718     (let ((dfun (if early-p
1719                     (or dfun (make-initial-dfun generic-function))
1720                     (compute-discriminating-function generic-function))))
1721       (set-funcallable-instance-function generic-function dfun)
1722       (set-fun-name generic-function gf-name)
1723       dfun)))
1724 \f
1725 (defvar *dfun-count* nil)
1726 (defvar *dfun-list* nil)
1727 (defvar *minimum-cache-size-to-list*)
1728
1729 ;;; These functions aren't used in SBCL, or documented anywhere that
1730 ;;; I'm aware of, but they look like they might be useful for
1731 ;;; debugging or performance tweaking or something, so I've just
1732 ;;; commented them out instead of deleting them. -- WHN 2001-03-28
1733 #|
1734 (defun list-dfun (gf)
1735   (let* ((sym (type-of (gf-dfun-info gf)))
1736          (a (assq sym *dfun-list*)))
1737     (unless a
1738       (push (setq a (list sym)) *dfun-list*))
1739     (push (generic-function-name gf) (cdr a))))
1740
1741 (defun list-all-dfuns ()
1742   (setq *dfun-list* nil)
1743   (map-all-generic-functions #'list-dfun)
1744   *dfun-list*)
1745
1746 (defun list-large-cache (gf)
1747   (let* ((sym (type-of (gf-dfun-info gf)))
1748          (cache (gf-dfun-cache gf)))
1749     (when cache
1750       (let ((size (cache-size cache)))
1751         (when (>= size *minimum-cache-size-to-list*)
1752           (let ((a (assoc size *dfun-list*)))
1753             (unless a
1754               (push (setq a (list size)) *dfun-list*))
1755             (push (let ((name (generic-function-name gf)))
1756                     (if (eq sym 'caching) name (list name sym)))
1757                   (cdr a))))))))
1758
1759 (defun list-large-caches (&optional (*minimum-cache-size-to-list* 130))
1760   (setq *dfun-list* nil)
1761   (map-all-generic-functions #'list-large-cache)
1762   (setq *dfun-list* (sort *dfun-list* #'< :key #'car))
1763   (mapc #'print *dfun-list*)
1764   (values))
1765
1766 (defun count-dfun (gf)
1767   (let* ((sym (type-of (gf-dfun-info gf)))
1768          (cache (gf-dfun-cache gf))
1769          (a (assq sym *dfun-count*)))
1770     (unless a
1771       (push (setq a (list sym 0 nil)) *dfun-count*))
1772     (incf (cadr a))
1773     (when cache
1774       (let* ((size (cache-size cache))
1775              (b (assoc size (third a))))
1776         (unless b
1777           (push (setq b (cons size 0)) (third a)))
1778         (incf (cdr b))))))
1779
1780 (defun count-all-dfuns ()
1781   (setq *dfun-count* (mapcar (lambda (type) (list type 0 nil))
1782                              '(ONE-CLASS TWO-CLASS DEFAULT-METHOD-ONLY
1783                                ONE-INDEX N-N CHECKING CACHING
1784                                DISPATCH)))
1785   (map-all-generic-functions #'count-dfun)
1786   (mapc (lambda (type+count+sizes)
1787           (setf (third type+count+sizes)
1788                 (sort (third type+count+sizes) #'< :key #'car)))
1789         *dfun-count*)
1790   (mapc (lambda (type+count+sizes)
1791           (format t "~&There are ~W dfuns of type ~S."
1792                   (cadr type+count+sizes) (car type+count+sizes))
1793           (format t "~%   ~S~%" (caddr type+count+sizes)))
1794         *dfun-count*)
1795   (values))
1796 |#
1797
1798 (defun gfs-of-type (type)
1799   (unless (consp type) (setq type (list type)))
1800   (let ((gf-list nil))
1801     (map-all-generic-functions (lambda (gf)
1802                                  (when (memq (type-of (gf-dfun-info gf))
1803                                              type)
1804                                    (push gf gf-list))))
1805     gf-list))