src/pcl/dfun.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 #|
  27
  28 This implementation of method lookup was redone in early August of 89.
  29
  30 It has the following properties:
  31
  32  - Its modularity makes it easy to modify the actual caching algorithm.
  33    The caching algorithm is almost completely separated into the files
  34    cache.lisp and dlap.lisp. This file just contains the various uses
  35    of it. There will be more tuning as we get more results from Luis'
  36    measurements of caching behavior.
  37
  38  - The metacircularity issues have been dealt with properly. All of
  39    PCL now grounds out properly. Moreover, it is now possible to have
  40    metaobject classes which are themselves not instances of standard
  41    metaobject classes.
  42
  43 ** Modularity of the code **
  44
  45 The actual caching algorithm is isolated in a modest number of functions.
  46 The code which generates cache lookup code is all found in cache.lisp and
  47 dlap.lisp. Certain non-wrapper-caching special cases are in this file.
  48
  49 ** Handling the metacircularity **
  50
  51 In CLOS, method lookup is the potential source of infinite metacircular
  52 regress. The metaobject protocol specification gives us wide flexibility
  53 in how to address this problem. PCL uses a technique which handles the
  54 problem not only for the metacircular language described in Chapter 3, but
  55 also for the PCL protocol which includes additional generic functions
  56 which control more aspects of the CLOS implementation.
  57
  58 The source of the metacircular regress can be seen in a number of ways.
  59 One is that the specified method lookup protocol must, as part of doing
  60 the method lookup (or at least the cache miss case), itself call generic
  61 functions. It is easy to see that if the method lookup for a generic
  62 function ends up calling that same generic function there can be trouble.
  63
  64 Fortunately, there is an easy solution at hand. The solution is based on
  65 the restriction that portable code cannot change the class of a specified
  66 metaobject. This restriction implies that for specified generic functions,
  67 the method lookup protocol they follow is fixed.
  68
  69 More precisely, for such specified generic functions, most generic functions
  70 that are called during their own method lookup will not run portable methods.
  71 This allows the implementation to usurp the actual generic function call in
  72 this case. In short, method lookup of a standard generic function, in the
  73 case where the only applicable methods are themselves standard doesn't
  74 have to do any method lookup to implement itself.
  75
  76 And so, we are saved.
  77
  78 Except see also BREAK-VICIOUS-METACIRCLE.  -- CSR, 2003-05-28
  79
  80 |#
  81 \f
  82 ;;; an alist in which each entry is of the form
  83 ;;;   (<generator> . (<subentry> ...)).
  84 ;;; Each subentry is of the form
  85 ;;;   (<args> <constructor> <system>).
  86 (defvar *dfun-constructors* ())
  87
  88 ;;; If this is NIL, then the whole mechanism for caching dfun constructors is
  89 ;;; turned off. The only time that makes sense is when debugging LAP code.
  90 (defvar *enable-dfun-constructor-caching* t)
  91
  92 (defun show-dfun-constructors ()
  93   (format t "~&DFUN constructor caching is ~A."
  94           (if *enable-dfun-constructor-caching*
  95               "enabled" "disabled"))
  96   (dolist (generator-entry *dfun-constructors*)
  97     (dolist (args-entry (cdr generator-entry))
  98       (format t "~&~S ~S"
  99               (cons (car generator-entry) (caar args-entry))
 100               (caddr args-entry)))))
 101
 102 (defvar *raise-metatypes-to-class-p* t)
 103
 104 (defun get-dfun-constructor (generator &rest args)
 105   (when (and *raise-metatypes-to-class-p*
 106              (member generator '(emit-checking emit-caching
 107                                  emit-in-checking-cache-p emit-constant-value)))
 108     (setq args (cons (mapcar (lambda (mt)
 109                                (if (eq mt t)
 110                                    mt
 111                                    'class))
 112                              (car args))
 113                      (cdr args))))
 114   (let* ((generator-entry (assq generator *dfun-constructors*))
 115          (args-entry (assoc args (cdr generator-entry) :test #'equal)))
 116     (if (null *enable-dfun-constructor-caching*)
 117         (apply (fdefinition generator) args)
 118         (or (cadr args-entry)
 119             (multiple-value-bind (new not-best-p)
 120                 (apply (symbol-function generator) args)
 121               (let ((entry (list (copy-list args) new (unless not-best-p 'pcl)
 122                                  not-best-p)))
 123                 (if generator-entry
 124                     (push entry (cdr generator-entry))
 125                     (push (list generator entry)
 126                           *dfun-constructors*)))
 127               (values new not-best-p))))))
 128
 129 (defun load-precompiled-dfun-constructor (generator args system constructor)
 130   (let* ((generator-entry (assq generator *dfun-constructors*))
 131          (args-entry (assoc args (cdr generator-entry) :test #'equal)))
 132     (if args-entry
 133         (when (fourth args-entry)
 134           (let* ((dfun-type (case generator
 135                               (emit-checking 'checking)
 136                               (emit-caching 'caching)
 137                               (emit-constant-value 'constant-value)
 138                               (emit-default-only 'default-method-only)))
 139                  (metatypes (car args))
 140                  (gfs (when dfun-type (gfs-of-type dfun-type))))
 141             (dolist (gf gfs)
 142               (when (and (equal metatypes
 143                                 (arg-info-metatypes (gf-arg-info gf)))
 144                          (let ((gf-name (generic-function-name gf)))
 145                            (and (not (eq gf-name 'slot-value-using-class))
 146                                 (not (equal gf-name
 147                                             '(setf slot-value-using-class)))
 148                                 (not (eq gf-name 'slot-boundp-using-class)))))
 149                 (update-dfun gf)))
 150             (setf (second args-entry) constructor)
 151             (setf (third args-entry) system)
 152             (setf (fourth args-entry) nil)))
 153         (let ((entry (list args constructor system nil)))
 154           (if generator-entry
 155               (push entry (cdr generator-entry))
 156               (push (list generator entry) *dfun-constructors*))))))
 157
 158 (defmacro precompile-dfun-constructors (&optional system)
 159   (let ((*precompiling-lap* t))
 160     `(progn
 161        ,@(let (collect)
 162            (dolist (generator-entry *dfun-constructors*)
 163              (dolist (args-entry (cdr generator-entry))
 164                (when (or (null (caddr args-entry))
 165                          (eq (caddr args-entry) system))
 166                  (when system (setf (caddr args-entry) system))
 167                  (push `(load-precompiled-dfun-constructor
 168                          ',(car generator-entry)
 169                          ',(car args-entry)
 170                          ',system
 171                          ,(apply (fdefinition (car generator-entry))
 172                                  (car args-entry)))
 173                        collect))))
 174            (nreverse collect)))))
 175 \f
 176 ;;; Standardized class slot access: when trying to break vicious
 177 ;;; metacircles, we need a way to get at the values of slots of some
 178 ;;; standard classes without going through the whole meta machinery,
 179 ;;; because that would likely enter the vicious circle again.  The
 180 ;;; following are helper functions that short-circuit the generic
 181 ;;; lookup machinery.
 182
 183 (defvar *standard-classes*
 184   '(standard-method standard-generic-function standard-class
 185     standard-effective-slot-definition))
 186
 187 (defvar *standard-slot-locations* (make-hash-table :test 'equal))
 188
 189 (defun compute-standard-slot-locations ()
 190   (clrhash *standard-slot-locations*)
 191   (dolist (class-name *standard-classes*)
 192     (let ((class (find-class class-name)))
 193       (dolist (slot (class-slots class))
 194         (setf (gethash (cons class (slot-definition-name slot))
 195                        *standard-slot-locations*)
 196               (slot-definition-location slot))))))
 197
 198 ;;; FIXME: harmonize the names between COMPUTE-STANDARD-SLOT-LOCATIONS
 199 ;;; and MAYBE-UPDATE-STANDARD-CLASS-LOCATIONS.
 200 (defun maybe-update-standard-class-locations (class)
 201   (when (and (eq *boot-state* 'complete)
 202              (memq (class-name class) *standard-classes*))
 203     (compute-standard-slot-locations)))
 204
 205 (defun standard-slot-value (object slot-name class)
 206   (let ((location (gethash (cons class slot-name) *standard-slot-locations*)))
 207     (if location
 208         (let ((value (if (funcallable-instance-p object)
 209                          (funcallable-standard-instance-access object location)
 210                          (standard-instance-access object location))))
 211           (when (eq +slot-unbound+ value)
 212             (error "~@<slot ~s of class ~s is unbound in object ~s~@:>"
 213                    slot-name class object))
 214           value)
 215         (error "~@<cannot get standard value of slot ~s of class ~s ~
 216                 in object ~s~@:>"
 217                slot-name class object))))
 218
 219 (defun standard-slot-value/gf (gf slot-name)
 220   (standard-slot-value gf slot-name *the-class-standard-generic-function*))
 221
 222 (defun standard-slot-value/method (method slot-name)
 223   (standard-slot-value method slot-name *the-class-standard-method*))
 224
 225 (defun standard-slot-value/eslotd (slotd slot-name)
 226   (standard-slot-value slotd slot-name
 227                        *the-class-standard-effective-slot-definition*))
 228
 229 (defun standard-slot-value/class (class slot-name)
 230   (standard-slot-value class slot-name *the-class-standard-class*))
 231 \f
 232 ;;; When all the methods of a generic function are automatically
 233 ;;; generated reader or writer methods a number of special
 234 ;;; optimizations are possible. These are important because of the
 235 ;;; large number of generic functions of this type.
 236 ;;;
 237 ;;; There are a number of cases:
 238 ;;;
 239 ;;;   ONE-CLASS-ACCESSOR
 240 ;;;     In this case, the accessor generic function has only been
 241 ;;;     called with one class of argument. There is no cache vector,
 242 ;;;     the wrapper of the one class, and the slot index are stored
 243 ;;;     directly as closure variables of the discriminating function.
 244 ;;;     This case can convert to either of the next kind.
 245 ;;;
 246 ;;;   TWO-CLASS-ACCESSOR
 247 ;;;     Like above, but two classes. This is common enough to do
 248 ;;;     specially. There is no cache vector. The two classes are
 249 ;;;     stored a separate closure variables.
 250 ;;;
 251 ;;;   ONE-INDEX-ACCESSOR
 252 ;;;     In this case, the accessor generic function has seen more than
 253 ;;;     one class of argument, but the index of the slot is the same
 254 ;;;     for all the classes that have been seen. A cache vector is
 255 ;;;     used to store the wrappers that have been seen, the slot index
 256 ;;;     is stored directly as a closure variable of the discriminating
 257 ;;;     function. This case can convert to the next kind.
 258 ;;;
 259 ;;;   N-N-ACCESSOR
 260 ;;;     This is the most general case. In this case, the accessor
 261 ;;;     generic function has seen more than one class of argument and
 262 ;;;     more than one slot index. A cache vector stores the wrappers
 263 ;;;     and corresponding slot indexes. Because each cache line is
 264 ;;;     more than one element long, a cache lock count is used.
 265 (defstruct (dfun-info (:constructor nil)
 266                       (:copier nil))
 267   (cache nil))
 268
 269 (defstruct (no-methods (:constructor no-methods-dfun-info ())
 270                        (:include dfun-info)
 271                        (:copier nil)))
 272
 273 (defstruct (initial (:constructor initial-dfun-info ())
 274                     (:include dfun-info)
 275                     (:copier nil)))
 276
 277 (defstruct (initial-dispatch (:constructor initial-dispatch-dfun-info ())
 278                              (:include dfun-info)
 279                              (:copier nil)))
 280
 281 (defstruct (dispatch (:constructor dispatch-dfun-info ())
 282                      (:include dfun-info)
 283                      (:copier nil)))
 284
 285 (defstruct (default-method-only (:constructor default-method-only-dfun-info ())
 286                                 (:include dfun-info)
 287                                 (:copier nil)))
 288
 289 ;without caching:
 290 ;  dispatch one-class two-class default-method-only
 291
 292 ;with caching:
 293 ;  one-index n-n checking caching
 294
 295 ;accessor:
 296 ;  one-class two-class one-index n-n
 297 (defstruct (accessor-dfun-info (:constructor nil)
 298                                (:include dfun-info)
 299                                (:copier nil))
 300   accessor-type) ; (member reader writer)
 301
 302 (defmacro dfun-info-accessor-type (di)
 303   `(accessor-dfun-info-accessor-type ,di))
 304
 305 (defstruct (one-index-dfun-info (:constructor nil)
 306                                 (:include accessor-dfun-info)
 307                                 (:copier nil))
 308   index)
 309
 310 (defmacro dfun-info-index (di)
 311   `(one-index-dfun-info-index ,di))
 312
 313 (defstruct (n-n (:constructor n-n-dfun-info (accessor-type cache))
 314                 (:include accessor-dfun-info)
 315                 (:copier nil)))
 316
 317 (defstruct (one-class (:constructor one-class-dfun-info
 318                                     (accessor-type index wrapper0))
 319                       (:include one-index-dfun-info)
 320                       (:copier nil))
 321   wrapper0)
 322
 323 (defmacro dfun-info-wrapper0 (di)
 324   `(one-class-wrapper0 ,di))
 325
 326 (defstruct (two-class (:constructor two-class-dfun-info
 327                                     (accessor-type index wrapper0 wrapper1))
 328                       (:include one-class)
 329                       (:copier nil))
 330   wrapper1)
 331
 332 (defmacro dfun-info-wrapper1 (di)
 333   `(two-class-wrapper1 ,di))
 334
 335 (defstruct (one-index (:constructor one-index-dfun-info
 336                                     (accessor-type index cache))
 337                       (:include one-index-dfun-info)
 338                       (:copier nil)))
 339
 340 (defstruct (checking (:constructor checking-dfun-info (function cache))
 341                      (:include dfun-info)
 342                      (:copier nil))
 343   function)
 344
 345 (defmacro dfun-info-function (di)
 346   `(checking-function ,di))
 347
 348 (defstruct (caching (:constructor caching-dfun-info (cache))
 349                     (:include dfun-info)
 350                     (:copier nil)))
 351
 352 (defstruct (constant-value (:constructor constant-value-dfun-info (cache))
 353                            (:include dfun-info)
 354                            (:copier nil)))
 355
 356 (defmacro dfun-update (generic-function function &rest args)
 357   `(multiple-value-bind (dfun cache info)
 358        (funcall ,function ,generic-function ,@args)
 359      (update-dfun ,generic-function dfun cache info)))
 360
 361 (defun accessor-miss-function (gf dfun-info)
 362   (ecase (dfun-info-accessor-type dfun-info)
 363     ((reader boundp)
 364      (lambda (arg)
 365        (accessor-miss gf nil arg dfun-info)))
 366     (writer
 367      (lambda (new arg)
 368        (accessor-miss gf new arg dfun-info)))))
 369
 370 #-sb-fluid (declaim (sb-ext:freeze-type dfun-info))
 371 \f
 372 (defun make-one-class-accessor-dfun (gf type wrapper index)
 373   (let ((emit (ecase type
 374                 (reader 'emit-one-class-reader)
 375                 (boundp 'emit-one-class-boundp)
 376                 (writer 'emit-one-class-writer)))
 377         (dfun-info (one-class-dfun-info type index wrapper)))
 378     (values
 379      (funcall (get-dfun-constructor emit (consp index))
 380               wrapper index
 381               (accessor-miss-function gf dfun-info))
 382      nil
 383      dfun-info)))
 384
 385 (defun make-two-class-accessor-dfun (gf type w0 w1 index)
 386   (let ((emit (ecase type
 387                 (reader 'emit-two-class-reader)
 388                 (boundp 'emit-two-class-boundp)
 389                 (writer 'emit-two-class-writer)))
 390         (dfun-info (two-class-dfun-info type index w0 w1)))
 391     (values
 392      (funcall (get-dfun-constructor emit (consp index))
 393               w0 w1 index
 394               (accessor-miss-function gf dfun-info))
 395      nil
 396      dfun-info)))
 397
 398 ;;; std accessors same index dfun
 399 (defun make-one-index-accessor-dfun (gf type index &optional cache)
 400   (let* ((emit (ecase type
 401                  (reader 'emit-one-index-readers)
 402                  (boundp 'emit-one-index-boundps)
 403                  (writer 'emit-one-index-writers)))
 404          (cache (or cache (get-cache 1 nil #'one-index-limit-fn 4)))
 405          (dfun-info (one-index-dfun-info type index cache)))
 406     (declare (type cache cache))
 407     (values
 408      (funcall (get-dfun-constructor emit (consp index))
 409               cache
 410               index
 411               (accessor-miss-function gf dfun-info))
 412      cache
 413      dfun-info)))
 414
 415 (defun make-final-one-index-accessor-dfun (gf type index table)
 416   (let ((cache (fill-dfun-cache table nil 1 #'one-index-limit-fn)))
 417     (make-one-index-accessor-dfun gf type index cache)))
 418
 419 (defun one-index-limit-fn (nlines)
 420   (default-limit-fn nlines))
 421
 422 (defun make-n-n-accessor-dfun (gf type &optional cache)
 423   (let* ((emit (ecase type
 424                  (reader 'emit-n-n-readers)
 425                  (boundp 'emit-n-n-boundps)
 426                  (writer 'emit-n-n-writers)))
 427          (cache (or cache (get-cache 1 t #'n-n-accessors-limit-fn 2)))
 428          (dfun-info (n-n-dfun-info type cache)))
 429     (declare (type cache cache))
 430     (values
 431      (funcall (get-dfun-constructor emit)
 432               cache
 433               (accessor-miss-function gf dfun-info))
 434      cache
 435      dfun-info)))
 436
 437 (defun make-final-n-n-accessor-dfun (gf type table)
 438   (let ((cache (fill-dfun-cache table t 1 #'n-n-accessors-limit-fn)))
 439     (make-n-n-accessor-dfun gf type cache)))
 440
 441 (defun n-n-accessors-limit-fn (nlines)
 442   (default-limit-fn nlines))
 443
 444 (defun make-checking-dfun (generic-function function &optional cache)
 445   (unless cache
 446     (when (use-caching-dfun-p generic-function)
 447       (return-from make-checking-dfun (make-caching-dfun generic-function)))
 448     (when (use-dispatch-dfun-p generic-function)
 449       (return-from make-checking-dfun (make-dispatch-dfun generic-function))))
 450   (multiple-value-bind (nreq applyp metatypes nkeys)
 451       (get-generic-fun-info generic-function)
 452     (declare (ignore nreq))
 453     (if (every (lambda (mt) (eq mt t)) metatypes)
 454         (let ((dfun-info (default-method-only-dfun-info)))
 455           (values
 456            (funcall (get-dfun-constructor 'emit-default-only metatypes applyp)
 457                     function)
 458            nil
 459            dfun-info))
 460         (let* ((cache (or cache (get-cache nkeys nil #'checking-limit-fn 2)))
 461                (dfun-info (checking-dfun-info function cache)))
 462           (values
 463            (funcall (get-dfun-constructor 'emit-checking metatypes applyp)
 464                     cache
 465                     function
 466                     (lambda (&rest args)
 467                       (checking-miss generic-function args dfun-info)))
 468            cache
 469            dfun-info)))))
 470
 471 (defun make-final-checking-dfun (generic-function function
 472                                                   classes-list new-class)
 473   (let ((metatypes (arg-info-metatypes (gf-arg-info generic-function))))
 474     (if (every (lambda (mt) (eq mt t)) metatypes)
 475         (values (lambda (&rest args)
 476                   (invoke-emf function args))
 477                 nil (default-method-only-dfun-info))
 478         (let ((cache (make-final-ordinary-dfun-internal
 479                       generic-function nil #'checking-limit-fn
 480                       classes-list new-class)))
 481           (make-checking-dfun generic-function function cache)))))
 482
 483 (defun use-default-method-only-dfun-p (generic-function)
 484   (multiple-value-bind (nreq applyp metatypes nkeys)
 485       (get-generic-fun-info generic-function)
 486     (declare (ignore nreq applyp nkeys))
 487     (every (lambda (mt) (eq mt t)) metatypes)))
 488
 489 (defun use-caching-dfun-p (generic-function)
 490   (some (lambda (method)
 491           (let ((fmf (if (listp method)
 492                          (third method)
 493                          (method-fast-function method))))
 494             (method-function-get fmf :slot-name-lists)))
 495         ;; KLUDGE: As of sbcl-0.6.4, it's very important for
 496         ;; efficiency to know the type of the sequence argument to
 497         ;; quantifiers (SOME/NOTANY/etc.) at compile time, but
 498         ;; the compiler isn't smart enough to understand the :TYPE
 499         ;; slot option for DEFCLASS, so we just tell
 500         ;; it the type by hand here.
 501         (the list
 502              (if (early-gf-p generic-function)
 503                  (early-gf-methods generic-function)
 504                  (generic-function-methods generic-function)))))
 505
 506 (defun checking-limit-fn (nlines)
 507   (default-limit-fn nlines))
 508 \f
 509 (defun make-caching-dfun (generic-function &optional cache)
 510   (unless cache
 511     (when (use-constant-value-dfun-p generic-function)
 512       (return-from make-caching-dfun
 513         (make-constant-value-dfun generic-function)))
 514     (when (use-dispatch-dfun-p generic-function)
 515       (return-from make-caching-dfun
 516         (make-dispatch-dfun generic-function))))
 517   (multiple-value-bind (nreq applyp metatypes nkeys)
 518       (get-generic-fun-info generic-function)
 519     (declare (ignore nreq))
 520     (let* ((cache (or cache (get-cache nkeys t #'caching-limit-fn 2)))
 521            (dfun-info (caching-dfun-info cache)))
 522       (values
 523        (funcall (get-dfun-constructor 'emit-caching metatypes applyp)
 524                 cache
 525                 (lambda (&rest args)
 526                   (caching-miss generic-function args dfun-info)))
 527        cache
 528        dfun-info))))
 529
 530 (defun make-final-caching-dfun (generic-function classes-list new-class)
 531   (let ((cache (make-final-ordinary-dfun-internal
 532                 generic-function t #'caching-limit-fn
 533                 classes-list new-class)))
 534     (make-caching-dfun generic-function cache)))
 535
 536 (defun caching-limit-fn (nlines)
 537   (default-limit-fn nlines))
 538
 539 (defun insure-caching-dfun (gf)
 540   (multiple-value-bind (nreq applyp metatypes nkeys)
 541       (get-generic-fun-info gf)
 542     (declare (ignore nreq nkeys))
 543     (when (and metatypes
 544                (not (null (car metatypes)))
 545                (dolist (mt metatypes nil)
 546                  (unless (eq mt t) (return t))))
 547       (get-dfun-constructor 'emit-caching metatypes applyp))))
 548
 549 (defun use-constant-value-dfun-p (gf &optional boolean-values-p)
 550   (multiple-value-bind (nreq applyp metatypes nkeys)
 551       (get-generic-fun-info gf)
 552     (declare (ignore nreq metatypes nkeys))
 553     (let* ((early-p (early-gf-p gf))
 554            (methods (if early-p
 555                         (early-gf-methods gf)
 556                         (generic-function-methods gf)))
 557            (default '(unknown)))
 558       (and (null applyp)
 559            (or (not (eq *boot-state* 'complete))
 560                ;; If COMPUTE-APPLICABLE-METHODS is specialized, we
 561                ;; can't use this, of course, because we can't tell
 562                ;; which methods will be considered applicable.
 563                ;;
 564                ;; Also, don't use this dfun method if the generic
 565                ;; function has a non-standard method combination,
 566                ;; because if it has, it's not sure that method
 567                ;; functions are used directly as effective methods,
 568                ;; which CONSTANT-VALUE-MISS depends on.  The
 569                ;; pre-defined method combinations like LIST are
 570                ;; examples of that.
 571                (and (compute-applicable-methods-emf-std-p gf)
 572                     (eq (generic-function-method-combination gf)
 573                         *standard-method-combination*)))
 574            ;; Check that no method is eql-specialized, and that all
 575            ;; methods return a constant value.  If BOOLEAN-VALUES-P,
 576            ;; check that all return T or NIL.  Also, check that no
 577            ;; method has qualifiers, to make sure that emfs are really
 578            ;; method functions; see above.
 579            (dolist (method methods t)
 580              (when (eq *boot-state* 'complete)
 581                (when (or (some #'eql-specializer-p
 582                                (method-specializers method))
 583                          (method-qualifiers method))
 584                  (return nil)))
 585              (let ((value (method-function-get
 586                            (if early-p
 587                                (or (third method) (second method))
 588                                (or (method-fast-function method)
 589                                    (method-function method)))
 590                            :constant-value default)))
 591                (when (or (eq value default)
 592                          (and boolean-values-p
 593                               (not (member value '(t nil)))))
 594                  (return nil))))))))
 595
 596 (defun make-constant-value-dfun (generic-function &optional cache)
 597   (multiple-value-bind (nreq applyp metatypes nkeys)
 598       (get-generic-fun-info generic-function)
 599     (declare (ignore nreq applyp))
 600     (let* ((cache (or cache (get-cache nkeys t #'caching-limit-fn 2)))
 601            (dfun-info (constant-value-dfun-info cache)))
 602       (values
 603        (funcall (get-dfun-constructor 'emit-constant-value metatypes)
 604                 cache
 605                 (lambda (&rest args)
 606                   (constant-value-miss generic-function args dfun-info)))
 607        cache
 608        dfun-info))))
 609
 610 (defun make-final-constant-value-dfun (generic-function classes-list new-class)
 611   (let ((cache (make-final-ordinary-dfun-internal
 612                 generic-function :constant-value #'caching-limit-fn
 613                 classes-list new-class)))
 614     (make-constant-value-dfun generic-function cache)))
 615
 616 (defun use-dispatch-dfun-p (gf &optional (caching-p (use-caching-dfun-p gf)))
 617   (when (eq *boot-state* 'complete)
 618     (unless (or caching-p (gf-requires-emf-keyword-checks gf))
 619       ;; This should return T when almost all dispatching is by
 620       ;; eql specializers or built-in classes. In other words,
 621       ;; return NIL if we might ever need to do more than
 622       ;; one (non built-in) typep.
 623       ;; Otherwise, it is probably at least as fast to use
 624       ;; a caching dfun first, possibly followed by secondary dispatching.
 625
 626       #||;;; Original found in cmu 17f -- S L O W
 627       (< (dispatch-dfun-cost gf) (caching-dfun-cost gf))
 628       ||#
 629       ;; This uses improved dispatch-dfun-cost below
 630       (let ((cdc  (caching-dfun-cost gf))) ; fast
 631         (> cdc (dispatch-dfun-cost gf cdc))))))
 632
 633 (defparameter *non-built-in-typep-cost* 1)
 634 (defparameter *structure-typep-cost* 1)
 635 (defparameter *built-in-typep-cost* 0)
 636
 637 ;;; According to comments in the original CMU CL version of PCL,
 638 ;;; the cost LIMIT is important to cut off exponential growth for
 639 ;;; large numbers of gf methods and argument lists.
 640 (defun dispatch-dfun-cost (gf &optional limit)
 641   (generate-discrimination-net-internal
 642    gf (generic-function-methods gf) nil
 643    (lambda (methods known-types)
 644      (declare (ignore methods known-types))
 645      0)
 646    (lambda (position type true-value false-value)
 647      (declare (ignore position))
 648      (let* ((type-test-cost
 649              (if (eq 'class (car type))
 650                  (let* ((metaclass (class-of (cadr type)))
 651                         (mcpl (class-precedence-list metaclass)))
 652                    (cond ((memq *the-class-built-in-class* mcpl)
 653                           *built-in-typep-cost*)
 654                          ((memq *the-class-structure-class* mcpl)
 655                           *structure-typep-cost*)
 656                          (t
 657                           *non-built-in-typep-cost*)))
 658                  0))
 659             (max-cost-so-far
 660              (+ (max true-value false-value) type-test-cost)))
 661        (when (and limit (<= limit max-cost-so-far))
 662          (return-from dispatch-dfun-cost max-cost-so-far))
 663        max-cost-so-far))
 664    #'identity))
 665
 666 (defparameter *cache-lookup-cost* 1)
 667 (defparameter *wrapper-of-cost* 0)
 668 (defparameter *secondary-dfun-call-cost* 1)
 669
 670 (defun caching-dfun-cost (gf)
 671   (let* ((arg-info (gf-arg-info gf))
 672          (nreq (length (arg-info-metatypes arg-info))))
 673     (+ *cache-lookup-cost*
 674        (* *wrapper-of-cost* nreq)
 675        (if (methods-contain-eql-specializer-p
 676             (generic-function-methods gf))
 677            *secondary-dfun-call-cost*
 678            0))))
 679
 680 (setq *non-built-in-typep-cost* 100)
 681 (setq *structure-typep-cost* 15)
 682 (setq *built-in-typep-cost* 5)
 683 (setq *cache-lookup-cost* 30)
 684 (setq *wrapper-of-cost* 15)
 685 (setq *secondary-dfun-call-cost* 30)
 686
 687 (declaim (inline make-callable))
 688 (defun make-callable (gf methods generator method-alist wrappers)
 689   (let* ((*applicable-methods* methods)
 690          (callable (function-funcall generator method-alist wrappers)))
 691     callable))
 692
 693 (defun make-dispatch-dfun (gf)
 694   (values (get-dispatch-function gf) nil (dispatch-dfun-info)))
 695
 696 (defun get-dispatch-function (gf)
 697   (let* ((methods (generic-function-methods gf))
 698          (generator (get-secondary-dispatch-function1
 699                      gf methods nil nil nil nil nil t)))
 700     (make-callable gf methods generator nil nil)))
 701
 702 (defun make-final-dispatch-dfun (gf)
 703   (make-dispatch-dfun gf))
 704
 705 (defun update-dispatch-dfuns ()
 706   (dolist (gf (gfs-of-type '(dispatch initial-dispatch)))
 707     (dfun-update gf #'make-dispatch-dfun)))
 708
 709 (defun fill-dfun-cache (table valuep nkeys limit-fn &optional cache)
 710   (let ((cache (or cache (get-cache nkeys valuep limit-fn
 711                                     (+ (hash-table-count table) 3)))))
 712     (maphash (lambda (classes value)
 713                (setq cache (fill-cache cache
 714                                        (class-wrapper classes)
 715                                        value)))
 716              table)
 717     cache))
 718
 719 (defun make-final-ordinary-dfun-internal (generic-function valuep limit-fn
 720                                                            classes-list new-class)
 721   (let* ((arg-info (gf-arg-info generic-function))
 722          (nkeys (arg-info-nkeys arg-info))
 723          (new-class (and new-class
 724                          (equal (type-of (gf-dfun-info generic-function))
 725                                 (cond ((eq valuep t) 'caching)
 726                                       ((eq valuep :constant-value) 'constant-value)
 727                                       ((null valuep) 'checking)))
 728                          new-class))
 729          (cache (if new-class
 730                     (copy-cache (gf-dfun-cache generic-function))
 731                     (get-cache nkeys (not (null valuep)) limit-fn 4))))
 732       (make-emf-cache generic-function valuep cache classes-list new-class)))
 733 \f
 734 (defvar *dfun-miss-gfs-on-stack* ())
 735
 736 (defmacro dfun-miss ((gf args wrappers invalidp nemf
 737                       &optional type index caching-p applicable)
 738                      &body body)
 739   (unless applicable (setq applicable (gensym)))
 740   `(multiple-value-bind (,nemf ,applicable ,wrappers ,invalidp
 741                          ,@(when type `(,type ,index)))
 742        (cache-miss-values ,gf ,args ',(cond (caching-p 'caching)
 743                                             (type 'accessor)
 744                                             (t 'checking)))
 745     (when (and ,applicable (not (memq ,gf *dfun-miss-gfs-on-stack*)))
 746       (let ((*dfun-miss-gfs-on-stack* (cons ,gf *dfun-miss-gfs-on-stack*)))
 747         ,@body))
 748     ;; Create a FAST-INSTANCE-BOUNDP structure instance for a cached
 749     ;; SLOT-BOUNDP so that INVOKE-EMF does the right thing, that is,
 750     ;; does not signal a SLOT-UNBOUND error for a boundp test.
 751     ,@(if type
 752           ;; FIXME: could the NEMF not be a CONS (for :CLASS-allocated
 753           ;; slots?)
 754           `((if (and (eq ,type 'boundp) (integerp ,nemf))
 755                 (invoke-emf (make-fast-instance-boundp :index ,nemf) ,args)
 756                 (invoke-emf ,nemf ,args)))
 757           `((invoke-emf ,nemf ,args)))))
 758
 759 ;;; The dynamically adaptive method lookup algorithm is implemented is
 760 ;;; implemented as a kind of state machine. The kinds of
 761 ;;; discriminating function is the state, the various kinds of reasons
 762 ;;; for a cache miss are the state transitions.
 763 ;;;
 764 ;;; The code which implements the transitions is all in the miss
 765 ;;; handlers for each kind of dfun. Those appear here.
 766 ;;;
 767 ;;; Note that within the states that cache, there are dfun updates
 768 ;;; which simply select a new cache or cache field. Those are not
 769 ;;; considered as state transitions.
 770 (defvar *lazy-dfun-compute-p* t)
 771 (defvar *early-p* nil)
 772
 773 (declaim (type (or null unsigned-byte) *max-emf-precomputation-methods*))
 774 (defvar *max-emf-precomputation-methods* nil)
 775
 776 (defun finalize-specializers (gf)
 777   (let ((methods (generic-function-methods gf)))
 778     (when (or (null *max-emf-precomputation-methods*)
 779               (<= (length methods) *max-emf-precomputation-methods*))
 780       (let ((all-finalized t))
 781         (dolist (method methods all-finalized)
 782           (dolist (specializer (method-specializers method))
 783             (when (and (classp specializer)
 784                        (not (class-finalized-p specializer)))
 785               (if (class-has-a-forward-referenced-superclass-p specializer)
 786                   (setq all-finalized nil)
 787                   (finalize-inheritance specializer)))))))))
 788
 789 (defun make-initial-dfun (gf)
 790   (let ((initial-dfun
 791          #'(instance-lambda (&rest args)
 792              (initial-dfun gf args))))
 793     (multiple-value-bind (dfun cache info)
 794         (cond
 795           ((and (eq *boot-state* 'complete)
 796                 (not (finalize-specializers gf)))
 797            (values initial-dfun nil (initial-dfun-info)))
 798           ((and (eq *boot-state* 'complete)
 799                 (compute-applicable-methods-emf-std-p gf))
 800            (let* ((caching-p (use-caching-dfun-p gf))
 801                   ;; KLUDGE: the only effect of this (when
 802                   ;; *LAZY-DFUN-COMPUTE-P* is true, as it usually is)
 803                   ;; is to signal an error when we try to add methods
 804                   ;; with the wrong qualifiers to a generic function.
 805                   (classes-list (precompute-effective-methods
 806                                  gf caching-p
 807                                  (not *lazy-dfun-compute-p*))))
 808              (if *lazy-dfun-compute-p*
 809                  (cond ((use-dispatch-dfun-p gf caching-p)
 810                         (values initial-dfun
 811                                 nil
 812                                 (initial-dispatch-dfun-info)))
 813                        (caching-p
 814                         (insure-caching-dfun gf)
 815                         (values initial-dfun nil (initial-dfun-info)))
 816                        (t
 817                         (values initial-dfun nil (initial-dfun-info))))
 818                  (make-final-dfun-internal gf classes-list))))
 819           (t
 820            (let ((arg-info (if (early-gf-p gf)
 821                                (early-gf-arg-info gf)
 822                                (gf-arg-info gf)))
 823                  (type nil))
 824              (if (and (gf-precompute-dfun-and-emf-p arg-info)
 825                       (setq type (final-accessor-dfun-type gf)))
 826                  (if *early-p*
 827                      (values (make-early-accessor gf type) nil nil)
 828                      (make-final-accessor-dfun gf type))
 829                  (values initial-dfun nil (initial-dfun-info))))))
 830       (set-dfun gf dfun cache info))))
 831
 832 (defun make-early-accessor (gf type)
 833   (let* ((methods (early-gf-methods gf))
 834          (slot-name (early-method-standard-accessor-slot-name (car methods))))
 835     (ecase type
 836       (reader #'(instance-lambda (instance)
 837                   (let* ((class (class-of instance))
 838                          (class-name (!bootstrap-get-slot 'class class 'name)))
 839                     (!bootstrap-get-slot class-name instance slot-name))))
 840       (boundp #'(instance-lambda (instance)
 841                   (let* ((class (class-of instance))
 842                          (class-name (!bootstrap-get-slot 'class class 'name)))
 843                     (not (eq +slot-unbound+
 844                              (!bootstrap-get-slot class-name
 845                                                   instance slot-name))))))
 846       (writer #'(instance-lambda (new-value instance)
 847                   (let* ((class (class-of instance))
 848                          (class-name (!bootstrap-get-slot 'class class 'name)))
 849                     (!bootstrap-set-slot class-name instance slot-name new-value)))))))
 850
 851 (defun initial-dfun (gf args)
 852   (dfun-miss (gf args wrappers invalidp nemf ntype nindex)
 853     (cond (invalidp)
 854           ((and ntype nindex)
 855            (dfun-update
 856             gf #'make-one-class-accessor-dfun ntype wrappers nindex))
 857           ((use-caching-dfun-p gf)
 858            (dfun-update gf #'make-caching-dfun))
 859           (t
 860            (dfun-update
 861             gf #'make-checking-dfun
 862             ;; nemf is suitable only for caching, have to do this:
 863             (cache-miss-values gf args 'checking))))))
 864
 865 (defun make-final-dfun (gf &optional classes-list)
 866   (multiple-value-bind (dfun cache info)
 867       (make-final-dfun-internal gf classes-list)
 868     (set-dfun gf dfun cache info)))
 869
 870 (defvar *new-class* nil)
 871
 872 (defvar *free-hash-tables* (mapcar #'list '(eq equal eql)))
 873
 874 (defmacro with-hash-table ((table test) &body forms)
 875   `(let* ((.free. (assoc ',test *free-hash-tables*))
 876           (,table (if (cdr .free.)
 877                       (pop (cdr .free.))
 878                       (make-hash-table :test ',test))))
 879      (multiple-value-prog1
 880          (progn ,@forms)
 881        (clrhash ,table)
 882        (push ,table (cdr .free.)))))
 883
 884 (defmacro with-eq-hash-table ((table) &body forms)
 885   `(with-hash-table (,table eq) ,@forms))
 886
 887 (defun final-accessor-dfun-type (gf)
 888   (let ((methods (if (early-gf-p gf)
 889                      (early-gf-methods gf)
 890                      (generic-function-methods gf))))
 891     (cond ((every (lambda (method)
 892                     (if (consp method)
 893                         (eq *the-class-standard-reader-method*
 894                             (early-method-class method))
 895                         (standard-reader-method-p method)))
 896                   methods)
 897            'reader)
 898           ((every (lambda (method)
 899                     (if (consp method)
 900                         (eq *the-class-standard-boundp-method*
 901                             (early-method-class method))
 902                         (standard-boundp-method-p method)))
 903                   methods)
 904            'boundp)
 905           ((every (lambda (method)
 906                     (if (consp method)
 907                         (eq *the-class-standard-writer-method*
 908                             (early-method-class method))
 909                         (standard-writer-method-p method)))
 910                   methods)
 911            'writer))))
 912
 913 (defun make-final-accessor-dfun (gf type &optional classes-list new-class)
 914   (with-eq-hash-table (table)
 915     (multiple-value-bind (table all-index first second size no-class-slots-p)
 916         (make-accessor-table gf type table)
 917       (if table
 918           (cond ((= size 1)
 919                  (let ((w (class-wrapper first)))
 920                    (make-one-class-accessor-dfun gf type w all-index)))
 921                 ((and (= size 2) (or (integerp all-index) (consp all-index)))
 922                  (let ((w0 (class-wrapper first))
 923                        (w1 (class-wrapper second)))
 924                    (make-two-class-accessor-dfun gf type w0 w1 all-index)))
 925                 ((or (integerp all-index) (consp all-index))
 926                  (make-final-one-index-accessor-dfun
 927                   gf type all-index table))
 928                 (no-class-slots-p
 929                  (make-final-n-n-accessor-dfun gf type table))
 930                 (t
 931                  (make-final-caching-dfun gf classes-list new-class)))
 932           (make-final-caching-dfun gf classes-list new-class)))))
 933
 934 (defun make-final-dfun-internal (gf &optional classes-list)
 935   (let ((methods (generic-function-methods gf)) type
 936         (new-class *new-class*) (*new-class* nil)
 937         specls all-same-p)
 938     (cond ((null methods)
 939            (values
 940             #'(instance-lambda (&rest args)
 941                 (apply #'no-applicable-method gf args))
 942             nil
 943             (no-methods-dfun-info)))
 944           ((setq type (final-accessor-dfun-type gf))
 945            (make-final-accessor-dfun gf type classes-list new-class))
 946           ((and (not (and (every (lambda (specl) (eq specl *the-class-t*))
 947                                  (setq specls
 948                                        (method-specializers (car methods))))
 949                           (setq all-same-p
 950                                 (every (lambda (method)
 951                                          (and (equal specls
 952                                                      (method-specializers
 953                                                       method))))
 954                                        methods))))
 955                 (use-constant-value-dfun-p gf))
 956            (make-final-constant-value-dfun gf classes-list new-class))
 957           ((use-dispatch-dfun-p gf)
 958            (make-final-dispatch-dfun gf))
 959           ((and all-same-p (not (use-caching-dfun-p gf)))
 960            (let ((emf (get-secondary-dispatch-function gf methods nil)))
 961              (make-final-checking-dfun gf emf classes-list new-class)))
 962           (t
 963            (make-final-caching-dfun gf classes-list new-class)))))
 964
 965 (defun accessor-miss (gf new object dfun-info)
 966   (let* ((ostate (type-of dfun-info))
 967          (otype (dfun-info-accessor-type dfun-info))
 968          oindex ow0 ow1 cache
 969          (args (ecase otype
 970                  ;; The congruence rules ensure that this is safe
 971                  ;; despite not knowing the new type yet.
 972                  ((reader boundp) (list object))
 973                  (writer (list new object)))))
 974     (dfun-miss (gf args wrappers invalidp nemf ntype nindex)
 975
 976       ;; The following lexical functions change the state of the
 977       ;; dfun to that which is their name. They accept arguments
 978       ;; which are the parameters of the new state, and get other
 979       ;; information from the lexical variables bound above.
 980       (flet ((two-class (index w0 w1)
 981                (when (zerop (random 2)) (psetf w0 w1 w1 w0))
 982                (dfun-update gf
 983                             #'make-two-class-accessor-dfun
 984                             ntype
 985                             w0
 986                             w1
 987                             index))
 988              (one-index (index &optional cache)
 989                (dfun-update gf
 990                             #'make-one-index-accessor-dfun
 991                             ntype
 992                             index
 993                             cache))
 994              (n-n (&optional cache)
 995                (if (consp nindex)
 996                    (dfun-update gf #'make-checking-dfun nemf)
 997                    (dfun-update gf #'make-n-n-accessor-dfun ntype cache)))
 998              (caching () ; because cached accessor emfs are much faster
 999                          ; for accessors
1000                (dfun-update gf #'make-caching-dfun))
1001              (do-fill (update-fn)
1002                (let ((ncache (fill-cache cache wrappers nindex)))
1003                  (unless (eq ncache cache)
1004                    (funcall update-fn ncache)))))
1005
1006         (cond ((null ntype)
1007                (caching))
1008               ((or invalidp
1009                    (null nindex)))
1010               ((not (pcl-instance-p object))
1011                (caching))
1012               ((or (neq ntype otype) (listp wrappers))
1013                (caching))
1014               (t
1015                (ecase ostate
1016                  (one-class
1017                   (setq oindex (dfun-info-index dfun-info))
1018                   (setq ow0 (dfun-info-wrapper0 dfun-info))
1019                   (unless (eq ow0 wrappers)
1020                     (if (eql nindex oindex)
1021                         (two-class nindex ow0 wrappers)
1022                         (n-n))))
1023                  (two-class
1024                   (setq oindex (dfun-info-index dfun-info))
1025                   (setq ow0 (dfun-info-wrapper0 dfun-info))
1026                   (setq ow1 (dfun-info-wrapper1 dfun-info))
1027                   (unless (or (eq ow0 wrappers) (eq ow1 wrappers))
1028                     (if (eql nindex oindex)
1029                         (one-index nindex)
1030                         (n-n))))
1031                  (one-index
1032                   (setq oindex (dfun-info-index dfun-info))
1033                   (setq cache (dfun-info-cache dfun-info))
1034                   (if (eql nindex oindex)
1035                       (do-fill (lambda (ncache)
1036                                  (one-index nindex ncache)))
1037                       (n-n)))
1038                  (n-n
1039                   (setq cache (dfun-info-cache dfun-info))
1040                   (if (consp nindex)
1041                       (caching)
1042                       (do-fill #'n-n))))))))))
1043
1044 (defun checking-miss (generic-function args dfun-info)
1045   (let ((oemf (dfun-info-function dfun-info))
1046         (cache (dfun-info-cache dfun-info)))
1047     (dfun-miss (generic-function args wrappers invalidp nemf)
1048       (cond (invalidp)
1049             ((eq oemf nemf)
1050              (let ((ncache (fill-cache cache wrappers nil)))
1051                (unless (eq ncache cache)
1052                  (dfun-update generic-function #'make-checking-dfun
1053                               nemf ncache))))
1054             (t
1055              (dfun-update generic-function #'make-caching-dfun))))))
1056
1057 (defun caching-miss (generic-function args dfun-info)
1058   (let ((ocache (dfun-info-cache dfun-info)))
1059     (dfun-miss (generic-function args wrappers invalidp emf nil nil t)
1060       (cond (invalidp)
1061             (t
1062              (let ((ncache (fill-cache ocache wrappers emf)))
1063                (unless (eq ncache ocache)
1064                  (dfun-update generic-function
1065                               #'make-caching-dfun ncache))))))))
1066
1067 (defun constant-value-miss (generic-function args dfun-info)
1068   (let ((ocache (dfun-info-cache dfun-info)))
1069     (dfun-miss (generic-function args wrappers invalidp emf nil nil t)
1070       (unless invalidp
1071         (let* ((function
1072                 (typecase emf
1073                   (fast-method-call (fast-method-call-function emf))
1074                   (method-call (method-call-function emf))))
1075                (value (let ((val (method-function-get
1076                                   function :constant-value '.not-found.)))
1077                         (aver (not (eq val '.not-found.)))
1078                         val))
1079                (ncache (fill-cache ocache wrappers value)))
1080           (unless (eq ncache ocache)
1081             (dfun-update generic-function
1082                          #'make-constant-value-dfun ncache)))))))
1083 \f
1084 ;;; Given a generic function and a set of arguments to that generic
1085 ;;; function, return a mess of values.
1086 ;;;
1087 ;;;  <function>   The compiled effective method function for this set of
1088 ;;;            arguments.
1089 ;;;
1090 ;;;  <applicable> Sorted list of applicable methods.
1091 ;;;
1092 ;;;  <wrappers>   Is a single wrapper if the generic function has only
1093 ;;;            one key, that is arg-info-nkeys of the arg-info is 1.
1094 ;;;            Otherwise a list of the wrappers of the specialized
1095 ;;;            arguments to the generic function.
1096 ;;;
1097 ;;;            Note that all these wrappers are valid. This function
1098 ;;;            does invalid wrapper traps when it finds an invalid
1099 ;;;            wrapper and then returns the new, valid wrapper.
1100 ;;;
1101 ;;;  <invalidp>   True if any of the specialized arguments had an invalid
1102 ;;;            wrapper, false otherwise.
1103 ;;;
1104 ;;;  <type>       READER or WRITER when the only method that would be run
1105 ;;;            is a standard reader or writer method. To be specific,
1106 ;;;            the value is READER when the method combination is eq to
1107 ;;;            *standard-method-combination*; there are no applicable
1108 ;;;            :before, :after or :around methods; and the most specific
1109 ;;;            primary method is a standard reader method.
1110 ;;;
1111 ;;;  <index>      If <type> is READER or WRITER, and the slot accessed is
1112 ;;;            an :instance slot, this is the index number of that slot
1113 ;;;            in the object argument.
1114 (defvar *cache-miss-values-stack* ())
1115
1116 (defun cache-miss-values (gf args state)
1117   (multiple-value-bind (nreq applyp metatypes nkeys arg-info)
1118       (get-generic-fun-info gf)
1119     (declare (ignore nreq applyp nkeys))
1120     (with-dfun-wrappers (args metatypes)
1121       (dfun-wrappers invalid-wrapper-p wrappers classes types)
1122       (error-need-at-least-n-args gf (length metatypes))
1123       (multiple-value-bind (emf methods accessor-type index)
1124           (cache-miss-values-internal
1125            gf arg-info wrappers classes types state)
1126         (values emf methods
1127                 dfun-wrappers
1128                 invalid-wrapper-p
1129                 accessor-type index)))))
1130
1131 (defun cache-miss-values-internal (gf arg-info wrappers classes types state)
1132   (if (and classes (equal classes (cdr (assq gf *cache-miss-values-stack*))))
1133       (break-vicious-metacircle gf classes arg-info)
1134       (let ((*cache-miss-values-stack*
1135              (acons gf classes *cache-miss-values-stack*))
1136             (cam-std-p (or (null arg-info)
1137                            (gf-info-c-a-m-emf-std-p arg-info))))
1138         (multiple-value-bind (methods all-applicable-and-sorted-p)
1139             (if cam-std-p
1140                 (compute-applicable-methods-using-types gf types)
1141                 (compute-applicable-methods-using-classes gf classes))
1142
1143   (let* ((for-accessor-p (eq state 'accessor))
1144          (for-cache-p (or (eq state 'caching) (eq state 'accessor)))
1145          (emf (if (or cam-std-p all-applicable-and-sorted-p)
1146                   (let ((generator
1147                          (get-secondary-dispatch-function1
1148                           gf methods types nil (and for-cache-p wrappers)
1149                           all-applicable-and-sorted-p)))
1150                     (make-callable gf methods generator
1151                                    nil (and for-cache-p wrappers)))
1152                   (default-secondary-dispatch-function gf))))
1153     (multiple-value-bind (index accessor-type)
1154         (and for-accessor-p all-applicable-and-sorted-p methods
1155              (accessor-values gf arg-info classes methods))
1156       (values (if (integerp index) index emf)
1157               methods accessor-type index)))))))
1158
1159 ;;; Try to break a vicious circle while computing a cache miss.
1160 ;;; GF is the generic function, CLASSES are the classes of actual
1161 ;;; arguments, and ARG-INFO is the generic functions' arg-info.
1162 ;;;
1163 ;;; A vicious circle can be entered when the computation of the cache
1164 ;;; miss values itself depends on the values being computed.  For
1165 ;;; instance, adding a method which is an instance of a subclass of
1166 ;;; STANDARD-METHOD leads to cache misses for slot accessors of
1167 ;;; STANDARD-METHOD like METHOD-SPECIALIZERS, and METHOD-SPECIALIZERS
1168 ;;; is itself used while we compute cache miss values.
1169 (defun break-vicious-metacircle (gf classes arg-info)
1170   (when (typep gf 'standard-generic-function)
1171     (multiple-value-bind (class slotd accessor-type)
1172         (accesses-standard-class-slot-p gf)
1173       (when class
1174         (let ((method (find-standard-class-accessor-method
1175                        gf class accessor-type))
1176               (index (standard-slot-value/eslotd slotd 'location))
1177               (type (gf-info-simple-accessor-type arg-info)))
1178           (when (and method
1179                      (subtypep (ecase accessor-type
1180                                  ((reader) (car classes))
1181                                  ((writer) (cadr classes)))
1182                                class))
1183             (return-from break-vicious-metacircle
1184               (values index (list method) type index)))))))
1185   (error "~@<vicious metacircle:  The computation of an ~
1186           effective method of ~s for arguments of types ~s uses ~
1187           the effective method being computed.~@:>"
1188          gf classes))
1189
1190 ;;; Return (CLASS SLOTD ACCESSOR-TYPE) if some method of generic
1191 ;;; function GF accesses a slot of some class in *STANDARD-CLASSES*.
1192 ;;; CLASS is the class accessed, SLOTD is the effective slot definition
1193 ;;; object of the slot accessed, and ACCESSOR-TYPE is one of the symbols
1194 ;;; READER or WRITER describing the slot access.
1195 (defun accesses-standard-class-slot-p (gf)
1196   (flet ((standard-class-slot-access (gf class)
1197            (loop with gf-name = (standard-slot-value/gf gf 'name)
1198                  for slotd in (standard-slot-value/class class 'slots)
1199                  ;; FIXME: where does BOUNDP fit in here?  Is it
1200                  ;; relevant?
1201                  as readers = (standard-slot-value/eslotd slotd 'readers)
1202                  as writers = (standard-slot-value/eslotd slotd 'writers)
1203                  if (member gf-name readers :test #'equal)
1204                    return (values slotd 'reader)
1205                  else if (member gf-name writers :test #'equal)
1206                    return (values slotd 'writer))))
1207     (dolist (class-name *standard-classes*)
1208       (let ((class (find-class class-name)))
1209         (multiple-value-bind (slotd accessor-type)
1210             (standard-class-slot-access gf class)
1211           (when slotd
1212             (return (values class slotd accessor-type))))))))
1213
1214 ;;; Find a slot reader/writer method among the methods of generic
1215 ;;; function GF which reads/writes instances of class CLASS.
1216 ;;; TYPE is one of the symbols READER or WRITER.
1217 (defun find-standard-class-accessor-method (gf class type)
1218   (dolist (method (standard-slot-value/gf gf 'methods))
1219     (let ((specializers (standard-slot-value/method method 'specializers))
1220           (qualifiers (plist-value method 'qualifiers)))
1221       (when (and (null qualifiers)
1222                  (eq (ecase type
1223                        (reader (car specializers))
1224                        (writer (cadr specializers)))
1225                      class))
1226         (return method)))))
1227
1228 (defun accessor-values (gf arg-info classes methods)
1229   (declare (ignore gf))
1230   (let* ((accessor-type (gf-info-simple-accessor-type arg-info))
1231          (accessor-class (case accessor-type
1232                            ((reader boundp) (car classes))
1233                            (writer (cadr classes)))))
1234     (accessor-values-internal accessor-type accessor-class methods)))
1235
1236 (defun accessor-values1 (gf accessor-type accessor-class)
1237   (let* ((type `(class-eq ,accessor-class))
1238          (types (ecase accessor-type
1239                   ((reader boundp) `(,type))
1240                   (writer `(t ,type))))
1241          (methods (compute-applicable-methods-using-types gf types)))
1242     (accessor-values-internal accessor-type accessor-class methods)))
1243
1244 (defun accessor-values-internal (accessor-type accessor-class methods)
1245   (dolist (meth methods)
1246     (when (if (consp meth)
1247               (early-method-qualifiers meth)
1248               (method-qualifiers meth))
1249       (return-from accessor-values-internal (values nil nil))))
1250   (let* ((meth (car methods))
1251          (early-p (not (eq *boot-state* 'complete)))
1252          (slot-name (when accessor-class
1253                       (if (consp meth)
1254                           (and (early-method-standard-accessor-p meth)
1255                                (early-method-standard-accessor-slot-name meth))
1256                           (and (member *the-class-std-object*
1257                                        (if early-p
1258                                            (early-class-precedence-list
1259                                             accessor-class)
1260                                            (class-precedence-list
1261                                             accessor-class)))
1262                                (if early-p
1263                                    (not (eq *the-class-standard-method*
1264                                             (early-method-class meth)))
1265                                    (standard-accessor-method-p meth))
1266                                (if early-p
1267                                    (early-accessor-method-slot-name meth)
1268                                    (accessor-method-slot-name meth))))))
1269          (slotd (and accessor-class
1270                      (if early-p
1271                          (dolist (slot (early-class-slotds accessor-class) nil)
1272                            (when (eql slot-name
1273                                       (early-slot-definition-name slot))
1274                              (return slot)))
1275                          (find-slot-definition accessor-class slot-name)))))
1276     (when (and slotd
1277                (or early-p
1278                    (slot-accessor-std-p slotd accessor-type)))
1279       (values (if early-p
1280                   (early-slot-definition-location slotd)
1281                   (slot-definition-location slotd))
1282               accessor-type))))
1283
1284 (defun make-accessor-table (gf type &optional table)
1285   (unless table (setq table (make-hash-table :test 'eq)))
1286   (let ((methods (if (early-gf-p gf)
1287                      (early-gf-methods gf)
1288                      (generic-function-methods gf)))
1289         (all-index nil)
1290         (no-class-slots-p t)
1291         (early-p (not (eq *boot-state* 'complete)))
1292         first second (size 0))
1293     (declare (fixnum size))
1294     ;; class -> {(specl slotd)}
1295     (dolist (method methods)
1296       (let* ((specializers (if (consp method)
1297                                (early-method-specializers method t)
1298                                (method-specializers method)))
1299              (specl (ecase type
1300                       ((reader boundp) (car specializers))
1301                       (writer (cadr specializers))))
1302              (specl-cpl (if early-p
1303                             (early-class-precedence-list specl)
1304                             (and (class-finalized-p specl)
1305                                  (class-precedence-list specl))))
1306              (so-p (member *the-class-std-object* specl-cpl))
1307              (slot-name (if (consp method)
1308                             (and (early-method-standard-accessor-p method)
1309                                  (early-method-standard-accessor-slot-name
1310                                   method))
1311                             (accessor-method-slot-name method))))
1312         (when (or (null specl-cpl)
1313                   (member *the-class-structure-object* specl-cpl))
1314           (return-from make-accessor-table nil))
1315         (maphash (lambda (class slotd)
1316                    (let ((cpl (if early-p
1317                                   (early-class-precedence-list class)
1318                                   (class-precedence-list class))))
1319                      (when (memq specl cpl)
1320                        (unless (and (or so-p
1321                                         (member *the-class-std-object* cpl))
1322                                     (or early-p
1323                                         (slot-accessor-std-p slotd type)))
1324                          (return-from make-accessor-table nil))
1325                        (push (cons specl slotd) (gethash class table)))))
1326                  (gethash slot-name *name->class->slotd-table*))))
1327     (maphash (lambda (class specl+slotd-list)
1328                (dolist (sclass (if early-p
1329                                    (early-class-precedence-list class)
1330                                    (class-precedence-list class))
1331                                (error "This can't happen."))
1332                  (let ((a (assq sclass specl+slotd-list)))
1333                    (when a
1334                      (let* ((slotd (cdr a))
1335                             (index (if early-p
1336                                        (early-slot-definition-location slotd)
1337                                        (slot-definition-location slotd))))
1338                        (unless index (return-from make-accessor-table nil))
1339                        (setf (gethash class table) index)
1340                        (when (consp index) (setq no-class-slots-p nil))
1341                        (setq all-index (if (or (null all-index)
1342                                                (eql all-index index))
1343                                            index t))
1344                        (incf size)
1345                        (cond ((= size 1) (setq first class))
1346                              ((= size 2) (setq second class)))
1347                        (return nil))))))
1348              table)
1349     (values table all-index first second size no-class-slots-p)))
1350
1351 (defun compute-applicable-methods-using-types (generic-function types)
1352   (let ((definite-p t) (possibly-applicable-methods nil))
1353     (dolist (method (if (early-gf-p generic-function)
1354                         (early-gf-methods generic-function)
1355                         (generic-function-methods generic-function)))
1356       (let ((specls (if (consp method)
1357                         (early-method-specializers method t)
1358                         (method-specializers method)))
1359             (types types)
1360             (possibly-applicable-p t) (applicable-p t))
1361         (dolist (specl specls)
1362           (multiple-value-bind (specl-applicable-p specl-possibly-applicable-p)
1363               (specializer-applicable-using-type-p specl (pop types))
1364             (unless specl-applicable-p
1365               (setq applicable-p nil))
1366             (unless specl-possibly-applicable-p
1367               (setq possibly-applicable-p nil)
1368               (return nil))))
1369         (when possibly-applicable-p
1370           (unless applicable-p (setq definite-p nil))
1371           (push method possibly-applicable-methods))))
1372     (let ((precedence (arg-info-precedence (if (early-gf-p generic-function)
1373                                                (early-gf-arg-info
1374                                                 generic-function)
1375                                                (gf-arg-info
1376                                                 generic-function)))))
1377       (values (sort-applicable-methods precedence
1378                                        (nreverse possibly-applicable-methods)
1379                                        types)
1380               definite-p))))
1381
1382 (defun sort-applicable-methods (precedence methods types)
1383   (sort-methods methods
1384                 precedence
1385                 (lambda (class1 class2 index)
1386                   (let* ((class (type-class (nth index types)))
1387                          (cpl (if (eq *boot-state* 'complete)
1388                                   (class-precedence-list class)
1389                                   (early-class-precedence-list class))))
1390                     (if (memq class2 (memq class1 cpl))
1391                         class1 class2)))))
1392
1393 (defun sort-methods (methods precedence compare-classes-function)
1394   (flet ((sorter (method1 method2)
1395            (dolist (index precedence)
1396              (let* ((specl1 (nth index (if (listp method1)
1397                                            (early-method-specializers method1
1398                                                                       t)
1399                                            (method-specializers method1))))
1400                     (specl2 (nth index (if (listp method2)
1401                                            (early-method-specializers method2
1402                                                                       t)
1403                                            (method-specializers method2))))
1404                     (order (order-specializers
1405                              specl1 specl2 index compare-classes-function)))
1406                (when order
1407                  (return-from sorter (eq order specl1)))))))
1408     (stable-sort methods #'sorter)))
1409
1410 (defun order-specializers (specl1 specl2 index compare-classes-function)
1411   (let ((type1 (if (eq *boot-state* 'complete)
1412                    (specializer-type specl1)
1413                    (!bootstrap-get-slot 'specializer specl1 'type)))
1414         (type2 (if (eq *boot-state* 'complete)
1415                    (specializer-type specl2)
1416                    (!bootstrap-get-slot 'specializer specl2 'type))))
1417     (cond ((eq specl1 specl2)
1418            nil)
1419           ((atom type1)
1420            specl2)
1421           ((atom type2)
1422            specl1)
1423           (t
1424            (case (car type1)
1425              (class    (case (car type2)
1426                          (class (funcall compare-classes-function
1427                                          specl1 specl2 index))
1428                          (t specl2)))
1429              (prototype (case (car type2)
1430                          (class (funcall compare-classes-function
1431                                          specl1 specl2 index))
1432                          (t specl2)))
1433              (class-eq (case (car type2)
1434                          (eql specl2)
1435                          (class-eq nil)
1436                          (class type1)))
1437              (eql      (case (car type2)
1438                          (eql nil)
1439                          (t specl1))))))))
1440
1441 (defun map-all-orders (methods precedence function)
1442   (let ((choices nil))
1443     (flet ((compare-classes-function (class1 class2 index)
1444              (declare (ignore index))
1445              (let ((choice nil))
1446                (dolist (c choices nil)
1447                  (when (or (and (eq (first c) class1)
1448                                 (eq (second c) class2))
1449                            (and (eq (first c) class2)
1450                                 (eq (second c) class1)))
1451                    (return (setq choice c))))
1452                (unless choice
1453                  (setq choice
1454                        (if (class-might-precede-p class1 class2)
1455                            (if (class-might-precede-p class2 class1)
1456                                (list class1 class2 nil t)
1457                                (list class1 class2 t))
1458                            (if (class-might-precede-p class2 class1)
1459                                (list class2 class1 t)
1460                                (let ((name1 (class-name class1))
1461                                      (name2 (class-name class2)))
1462                                  (if (and name1
1463                                           name2
1464                                           (symbolp name1)
1465                                           (symbolp name2)
1466                                           (string< (symbol-name name1)
1467                                                    (symbol-name name2)))
1468                                      (list class1 class2 t)
1469                                      (list class2 class1 t))))))
1470                  (push choice choices))
1471                (car choice))))
1472       (loop (funcall function
1473                      (sort-methods methods
1474                                    precedence
1475                                    #'compare-classes-function))
1476             (unless (dolist (c choices nil)
1477                       (unless (third c)
1478                         (rotatef (car c) (cadr c))
1479                         (return (setf (third c) t))))
1480               (return nil))))))
1481
1482 ;;; CMUCL comment: used only in map-all-orders
1483 (defun class-might-precede-p (class1 class2)
1484   (if (not *in-precompute-effective-methods-p*)
1485       (not (member class1 (cdr (class-precedence-list class2))))
1486       (class-can-precede-p class1 class2)))
1487
1488 (defun compute-precedence (lambda-list nreq argument-precedence-order)
1489   (if (null argument-precedence-order)
1490       (let ((list nil))
1491         (dotimes-fixnum (i nreq list) (push (- (1- nreq) i) list)))
1492       (mapcar (lambda (x) (position x lambda-list))
1493               argument-precedence-order)))
1494
1495 (defun cpl-or-nil (class)
1496   (if (eq *boot-state* 'complete)
1497       (when (class-finalized-p class)
1498         (class-precedence-list class))
1499       (early-class-precedence-list class)))
1500
1501 (defun saut-and (specl type)
1502   (let ((applicable nil)
1503         (possibly-applicable t))
1504     (dolist (type (cdr type))
1505       (multiple-value-bind (appl poss-appl)
1506           (specializer-applicable-using-type-p specl type)
1507         (when appl (return (setq applicable t)))
1508         (unless poss-appl (return (setq possibly-applicable nil)))))
1509     (values applicable possibly-applicable)))
1510
1511 (defun saut-not (specl type)
1512   (let ((ntype (cadr type)))
1513     (values nil
1514             (case (car ntype)
1515               (class      (saut-not-class specl ntype))
1516               (class-eq   (saut-not-class-eq specl ntype))
1517               (prototype  (saut-not-prototype specl ntype))
1518               (eql      (saut-not-eql specl ntype))
1519               (t (error "~S cannot handle the second argument ~S"
1520                         'specializer-applicable-using-type-p type))))))
1521
1522 (defun saut-not-class (specl ntype)
1523   (let* ((class (type-class specl))
1524          (cpl (cpl-or-nil class)))
1525     (not (memq (cadr ntype) cpl))))
1526
1527 (defun saut-not-prototype (specl ntype)
1528   (let* ((class (case (car specl)
1529                   (eql       (class-of (cadr specl)))
1530                   (class-eq  (cadr specl))
1531                   (prototype (cadr specl))
1532                   (class     (cadr specl))))
1533          (cpl (cpl-or-nil class)))
1534     (not (memq (cadr ntype) cpl))))
1535
1536 (defun saut-not-class-eq (specl ntype)
1537   (let ((class (case (car specl)
1538                  (eql      (class-of (cadr specl)))
1539                  (class-eq (cadr specl)))))
1540     (not (eq class (cadr ntype)))))
1541
1542 (defun saut-not-eql (specl ntype)
1543   (case (car specl)
1544     (eql (not (eql (cadr specl) (cadr ntype))))
1545     (t   t)))
1546
1547 (defun class-applicable-using-class-p (specl type)
1548   (let ((pred (memq specl (cpl-or-nil type))))
1549     (values pred
1550             (or pred
1551                 (if (not *in-precompute-effective-methods-p*)
1552                     ;; classes might get common subclass
1553                     (superclasses-compatible-p specl type)
1554                     ;; worry only about existing classes
1555                     (classes-have-common-subclass-p specl type))))))
1556
1557 (defun classes-have-common-subclass-p (class1 class2)
1558   (or (eq class1 class2)
1559       (let ((class1-subs (class-direct-subclasses class1)))
1560         (or (memq class2 class1-subs)
1561             (dolist (class1-sub class1-subs nil)
1562               (when (classes-have-common-subclass-p class1-sub class2)
1563                 (return t)))))))
1564
1565 (defun saut-class (specl type)
1566   (case (car specl)
1567     (class (class-applicable-using-class-p (cadr specl) (cadr type)))
1568     (t     (values nil (let ((class (type-class specl)))
1569                          (memq (cadr type)
1570                                (cpl-or-nil class)))))))
1571
1572 (defun saut-class-eq (specl type)
1573   (if (eq (car specl) 'eql)
1574       (values nil (eq (class-of (cadr specl)) (cadr type)))
1575       (let ((pred (case (car specl)
1576                     (class-eq
1577                      (eq (cadr specl) (cadr type)))
1578                     (class
1579                      (or (eq (cadr specl) (cadr type))
1580                          (memq (cadr specl) (cpl-or-nil (cadr type))))))))
1581         (values pred pred))))
1582
1583 (defun saut-prototype (specl type)
1584   (declare (ignore specl type))
1585   (values nil nil)) ; XXX original PCL comment: fix this someday
1586
1587 (defun saut-eql (specl type)
1588   (let ((pred (case (car specl)
1589                 (eql    (eql (cadr specl) (cadr type)))
1590                 (class-eq   (eq (cadr specl) (class-of (cadr type))))
1591                 (class      (memq (cadr specl)
1592                                   (let ((class (class-of (cadr type))))
1593                                     (cpl-or-nil class)))))))
1594     (values pred pred)))
1595
1596 (defun specializer-applicable-using-type-p (specl type)
1597   (setq specl (type-from-specializer specl))
1598   (when (eq specl t)
1599     (return-from specializer-applicable-using-type-p (values t t)))
1600   ;; This is used by C-A-M-U-T and GENERATE-DISCRIMINATION-NET-INTERNAL,
1601   ;; and has only what they need.
1602   (if (or (atom type) (eq (car type) t))
1603       (values nil t)
1604       (case (car type)
1605         (and    (saut-and specl type))
1606         (not    (saut-not specl type))
1607         (class      (saut-class specl type))
1608         (prototype  (saut-prototype specl type))
1609         (class-eq   (saut-class-eq specl type))
1610         (eql    (saut-eql specl type))
1611         (t        (error "~S cannot handle the second argument ~S."
1612                            'specializer-applicable-using-type-p
1613                            type)))))
1614
1615 (defun map-all-classes (function &optional (root t))
1616   (let ((braid-p (or (eq *boot-state* 'braid)
1617                      (eq *boot-state* 'complete))))
1618     (labels ((do-class (class)
1619                (mapc #'do-class
1620                      (if braid-p
1621                          (class-direct-subclasses class)
1622                          (early-class-direct-subclasses class)))
1623                (funcall function class)))
1624       (do-class (if (symbolp root)
1625                     (find-class root)
1626                     root)))))
1627 \f
1628 (defvar *effective-method-cache* (make-hash-table :test 'eq))
1629
1630 (defun flush-effective-method-cache (generic-function)
1631   (dolist (method (generic-function-methods generic-function))
1632     (remhash method *effective-method-cache*)))
1633
1634 (defun get-secondary-dispatch-function (gf methods types
1635                                         &optional method-alist wrappers)
1636   (let ((generator
1637          (get-secondary-dispatch-function1
1638           gf methods types (not (null method-alist)) (not (null wrappers))
1639           (not (methods-contain-eql-specializer-p methods)))))
1640     (make-callable gf methods generator method-alist wrappers)))
1641
1642 (defun get-secondary-dispatch-function1 (gf methods types method-alist-p
1643                                             wrappers-p
1644                                             &optional
1645                                             all-applicable-p
1646                                             (all-sorted-p t)
1647                                             function-p)
1648   (if (null methods)
1649       (if function-p
1650           (lambda (method-alist wrappers)
1651             (declare (ignore method-alist wrappers))
1652             #'(instance-lambda (&rest args)
1653                 (apply #'no-applicable-method gf args)))
1654           (lambda (method-alist wrappers)
1655             (declare (ignore method-alist wrappers))
1656             (lambda (&rest args)
1657               (apply #'no-applicable-method gf args))))
1658       (let* ((key (car methods))
1659              (ht-value (or (gethash key *effective-method-cache*)
1660                            (setf (gethash key *effective-method-cache*)
1661                                  (cons nil nil)))))
1662         (if (and (null (cdr methods)) all-applicable-p ; the most common case
1663                  (null method-alist-p) wrappers-p (not function-p))
1664             (or (car ht-value)
1665                 (setf (car ht-value)
1666                       (get-secondary-dispatch-function2
1667                        gf methods types method-alist-p wrappers-p
1668                        all-applicable-p all-sorted-p function-p)))
1669             (let ((akey (list methods
1670                               (if all-applicable-p 'all-applicable types)
1671                               method-alist-p wrappers-p function-p)))
1672               (or (cdr (assoc akey (cdr ht-value) :test #'equal))
1673                   (let ((value (get-secondary-dispatch-function2
1674                                 gf methods types method-alist-p wrappers-p
1675                                 all-applicable-p all-sorted-p function-p)))
1676                     (push (cons akey value) (cdr ht-value))
1677                     value)))))))
1678
1679 (defun get-secondary-dispatch-function2 (gf methods types method-alist-p
1680                                             wrappers-p all-applicable-p
1681                                             all-sorted-p function-p)
1682   (if (and all-applicable-p all-sorted-p (not function-p))
1683       (if (eq *boot-state* 'complete)
1684           (let* ((combin (generic-function-method-combination gf))
1685                  (effective (compute-effective-method gf combin methods)))
1686             (make-effective-method-function1 gf effective method-alist-p
1687                                              wrappers-p))
1688           (let ((effective (standard-compute-effective-method gf nil methods)))
1689             (make-effective-method-function1 gf effective method-alist-p
1690                                              wrappers-p)))
1691       (let ((net (generate-discrimination-net
1692                   gf methods types all-sorted-p)))
1693         (compute-secondary-dispatch-function1 gf net function-p))))
1694
1695 (defun get-effective-method-function (gf methods
1696                                          &optional method-alist wrappers)
1697   (let ((generator
1698          (get-secondary-dispatch-function1
1699           gf methods nil (not (null method-alist)) (not (null wrappers)) t)))
1700     (make-callable gf methods generator method-alist wrappers)))
1701
1702 (defun get-effective-method-function1 (gf methods &optional (sorted-p t))
1703   (get-secondary-dispatch-function1 gf methods nil nil nil t sorted-p))
1704
1705 (defun methods-contain-eql-specializer-p (methods)
1706   (and (eq *boot-state* 'complete)
1707        (dolist (method methods nil)
1708          (when (dolist (spec (method-specializers method) nil)
1709                  (when (eql-specializer-p spec) (return t)))
1710            (return t)))))
1711 \f
1712 (defun update-dfun (generic-function &optional dfun cache info)
1713   (let* ((early-p (early-gf-p generic-function))
1714          (gf-name (if early-p
1715                       (!early-gf-name generic-function)
1716                       (generic-function-name generic-function))))
1717     (set-dfun generic-function dfun cache info)
1718     (let ((dfun (if early-p
1719                     (or dfun (make-initial-dfun generic-function))
1720                     (compute-discriminating-function generic-function))))
1721       (set-funcallable-instance-function generic-function dfun)
1722       (set-fun-name generic-function gf-name)
1723       dfun)))
1724 \f
1725 (defvar *dfun-count* nil)
1726 (defvar *dfun-list* nil)
1727 (defvar *minimum-cache-size-to-list*)
1728
1729 ;;; These functions aren't used in SBCL, or documented anywhere that
1730 ;;; I'm aware of, but they look like they might be useful for
1731 ;;; debugging or performance tweaking or something, so I've just
1732 ;;; commented them out instead of deleting them. -- WHN 2001-03-28
1733 #|
1734 (defun list-dfun (gf)
1735   (let* ((sym (type-of (gf-dfun-info gf)))
1736          (a (assq sym *dfun-list*)))
1737     (unless a
1738       (push (setq a (list sym)) *dfun-list*))
1739     (push (generic-function-name gf) (cdr a))))
1740
1741 (defun list-all-dfuns ()
1742   (setq *dfun-list* nil)
1743   (map-all-generic-functions #'list-dfun)
1744   *dfun-list*)
1745
1746 (defun list-large-cache (gf)
1747   (let* ((sym (type-of (gf-dfun-info gf)))
1748          (cache (gf-dfun-cache gf)))
1749     (when cache
1750       (let ((size (cache-size cache)))
1751         (when (>= size *minimum-cache-size-to-list*)
1752           (let ((a (assoc size *dfun-list*)))
1753             (unless a
1754               (push (setq a (list size)) *dfun-list*))
1755             (push (let ((name (generic-function-name gf)))
1756                     (if (eq sym 'caching) name (list name sym)))
1757                   (cdr a))))))))
1758
1759 (defun list-large-caches (&optional (*minimum-cache-size-to-list* 130))
1760   (setq *dfun-list* nil)
1761   (map-all-generic-functions #'list-large-cache)
1762   (setq *dfun-list* (sort *dfun-list* #'< :key #'car))
1763   (mapc #'print *dfun-list*)
1764   (values))
1765
1766 (defun count-dfun (gf)
1767   (let* ((sym (type-of (gf-dfun-info gf)))
1768          (cache (gf-dfun-cache gf))
1769          (a (assq sym *dfun-count*)))
1770     (unless a
1771       (push (setq a (list sym 0 nil)) *dfun-count*))
1772     (incf (cadr a))
1773     (when cache
1774       (let* ((size (cache-size cache))
1775              (b (assoc size (third a))))
1776         (unless b
1777           (push (setq b (cons size 0)) (third a)))
1778         (incf (cdr b))))))
1779
1780 (defun count-all-dfuns ()
1781   (setq *dfun-count* (mapcar (lambda (type) (list type 0 nil))
1782                              '(ONE-CLASS TWO-CLASS DEFAULT-METHOD-ONLY
1783                                ONE-INDEX N-N CHECKING CACHING
1784                                DISPATCH)))
1785   (map-all-generic-functions #'count-dfun)
1786   (mapc (lambda (type+count+sizes)
1787           (setf (third type+count+sizes)
1788                 (sort (third type+count+sizes) #'< :key #'car)))
1789         *dfun-count*)
1790   (mapc (lambda (type+count+sizes)
1791           (format t "~&There are ~W dfuns of type ~S."
1792                   (cadr type+count+sizes) (car type+count+sizes))
1793           (format t "~%   ~S~%" (caddr type+count+sizes)))
1794         *dfun-count*)
1795   (values))
1796 |#
1797
1798 (defun gfs-of-type (type)
1799   (unless (consp type) (setq type (list type)))
1800   (let ((gf-list nil))
1801     (map-all-generic-functions (lambda (gf)
1802                                  (when (memq (type-of (gf-dfun-info gf))
1803                                              type)
1804                                    (push gf gf-list))))
1805     gf-list))