src/pcl/fast-init.lisp

   1 ;;;; This file defines the optimized make-instance functions.
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5
   6 ;;;; This software is derived from software originally released by Xerox
   7 ;;;; Corporation. Copyright and release statements follow. Later modifications
   8 ;;;; to the software are in the public domain and are provided with
   9 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  10 ;;;; information.
  11
  12 ;;;; copyright information from original PCL sources:
  13 ;;;;
  14 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  15 ;;;; All rights reserved.
  16 ;;;;
  17 ;;;; Use and copying of this software and preparation of derivative works based
  18 ;;;; upon this software are permitted. Any distribution of this software or
  19 ;;;; derivative works must comply with all applicable United States export
  20 ;;;; control laws.
  21 ;;;;
  22 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  23 ;;;; warranty about the software, its performance or its conformity to any
  24 ;;;; specification.
  25
  26 (in-package "SB-PCL")
  27 \f
  28 (defvar *compile-make-instance-functions-p* nil)
  29
  30 (defun update-make-instance-function-table (&optional (class *the-class-t*))
  31   (when (symbolp class) (setq class (find-class class)))
  32     (when (eq class *the-class-t*) (setq class *the-class-slot-object*))
  33     (when (memq *the-class-slot-object* (class-precedence-list class))
  34       (map-all-classes #'reset-class-initialize-info class)))
  35
  36 (defun constant-symbol-p (form)
  37   (and (constantp form)
  38        (let ((object (eval form)))
  39          (and (symbolp object)
  40               (symbol-package object)))))
  41
  42 (defvar *make-instance-function-keys* nil)
  43
  44 (defun expand-make-instance-form (form)
  45   (let ((class (cadr form)) (initargs (cddr form))
  46         (keys nil)(allow-other-keys-p nil) key value)
  47     (when (and (constant-symbol-p class)
  48                (let ((initargs-tail initargs))
  49                  (loop (when (null initargs-tail) (return t))
  50                        (unless (constant-symbol-p (car initargs-tail))
  51                          (return nil))
  52                        (setq key (eval (pop initargs-tail)))
  53                        (setq value (pop initargs-tail))
  54                        (when (eq ':allow-other-keys key)
  55                          (setq allow-other-keys-p value))
  56                        (push key keys))))
  57       (let* ((class (eval class))
  58              (keys (nreverse keys))
  59              (key (list class keys allow-other-keys-p))
  60              (sym (make-instance-function-symbol key)))
  61         (push key *make-instance-function-keys*)
  62         (when sym
  63           `(,sym ',class (list ,@initargs)))))))
  64
  65 (defmacro expanding-make-instance-top-level (&rest forms &environment env)
  66   (let* ((*make-instance-function-keys* nil)
  67          (form (macroexpand `(expanding-make-instance ,@forms) env)))
  68     `(progn
  69        ,@(when *make-instance-function-keys*
  70            `((get-make-instance-functions ',*make-instance-function-keys*)))
  71        ,form)))
  72
  73 (defmacro expanding-make-instance (&rest forms &environment env)
  74   `(progn
  75      ,@(mapcar #'(lambda (form)
  76                    (walk-form form env
  77                               #'(lambda (subform context env)
  78                                   (declare (ignore env))
  79                                   (or (and (eq context ':eval)
  80                                            (consp subform)
  81                                            (eq (car subform) 'make-instance)
  82                                            (expand-make-instance-form subform))
  83                                       subform))))
  84                forms)))
  85
  86 (defmacro defconstructor
  87           (name class lambda-list &rest initialization-arguments)
  88   `(expanding-make-instance-top-level
  89     (defun ,name ,lambda-list
  90       (make-instance ',class ,@initialization-arguments))))
  91
  92 (defun get-make-instance-functions (key-list)
  93   (dolist (key key-list)
  94     (let* ((cell (find-class-cell (car key)))
  95            (make-instance-function-keys
  96             (find-class-cell-make-instance-function-keys cell))
  97            (mif-key (cons (cadr key) (caddr key))))
  98       (unless (find mif-key make-instance-function-keys
  99                     :test #'equal)
 100         (push mif-key (find-class-cell-make-instance-function-keys cell))
 101         (let ((class (find-class-cell-class cell)))
 102           (when (and class (not (forward-referenced-class-p class)))
 103             (update-initialize-info-internal
 104              (initialize-info class (car mif-key) nil (cdr mif-key))
 105              'make-instance-function)))))))
 106
 107 (defun make-instance-function-symbol (key)
 108   (let* ((class (car key))
 109          (symbolp (symbolp class)))
 110     (when (or symbolp (classp class))
 111       (let* ((class-name (if (symbolp class) class (class-name class)))
 112              (keys (cadr key))
 113              (allow-other-keys-p (caddr key)))
 114         (when (and (or symbolp
 115                        (and (symbolp class-name)
 116                             (eq class (find-class class-name nil))))
 117                    (symbol-package class-name))
 118           (let ((*package* *pcl-package*)
 119                 (*print-length* nil)
 120                 (*print-level* nil)
 121                 (*print-circle* nil)
 122                 (*print-case* :upcase)
 123                 (*print-pretty* nil))
 124             (intern (format nil
 125                             "MAKE-INSTANCE ~S ~S ~S"
 126                             class-name
 127                             keys
 128                             allow-other-keys-p))))))))
 129
 130 (defun make-instance-1 (class initargs)
 131   (apply #'make-instance class initargs))
 132
 133 (defmacro define-cached-reader (type name trap)
 134   (let ((reader-name (intern (format nil "~A-~A" type name)))
 135         (cached-name (intern (format nil "~A-CACHED-~A" type name))))
 136     `(defmacro ,reader-name (info)
 137        `(let ((value (,',cached-name ,info)))
 138           (if (eq value ':unknown)
 139               (progn
 140                 (,',trap ,info ',',name)
 141                 (,',cached-name ,info))
 142               value)))))
 143
 144 (eval-when (:compile-toplevel :load-toplevel :execute)
 145 (defparameter *initialize-info-cached-slots*
 146   '(valid-p                             ; t or (:invalid key)
 147     ri-valid-p
 148     initargs-form-list
 149     new-keys
 150     default-initargs-function
 151     shared-initialize-t-function
 152     shared-initialize-nil-function
 153     constants
 154     combined-initialize-function ; allocate-instance + shared-initialize
 155     make-instance-function ; nil means use gf
 156     make-instance-function-symbol)))
 157
 158 (defmacro define-initialize-info ()
 159   (let ((cached-slot-names
 160          (mapcar #'(lambda (name)
 161                      (intern (format nil "CACHED-~A" name)))
 162                  *initialize-info-cached-slots*))
 163         (cached-names
 164          (mapcar #'(lambda (name)
 165                      (intern (format nil "~A-CACHED-~A"
 166                                      'initialize-info name)))
 167                  *initialize-info-cached-slots*)))
 168     `(progn
 169        (defstruct initialize-info
 170          key wrapper
 171          ,@(mapcar #'(lambda (name)
 172                        `(,name :unknown))
 173                    cached-slot-names))
 174        (defmacro reset-initialize-info-internal (info)
 175          `(progn
 176             ,@(mapcar #'(lambda (cname)
 177                           `(setf (,cname ,info) ':unknown))
 178                       ',cached-names)))
 179        (defun initialize-info-bound-slots (info)
 180          (let ((slots nil))
 181            ,@(mapcar #'(lambda (name cached-name)
 182                          `(unless (eq ':unknown (,cached-name info))
 183                             (push ',name slots)))
 184                      *initialize-info-cached-slots* cached-names)
 185            slots))
 186       ,@(mapcar #'(lambda (name)
 187                     `(define-cached-reader initialize-info ,name
 188                       update-initialize-info-internal))
 189                 *initialize-info-cached-slots*))))
 190
 191 (define-initialize-info)
 192
 193 (defvar *initialize-info-cache-class* nil)
 194 (defvar *initialize-info-cache-initargs* nil)
 195 (defvar *initialize-info-cache-info* nil)
 196
 197 (defvar *revert-initialize-info-p* nil)
 198
 199 (defun reset-initialize-info (info)
 200   (setf (initialize-info-wrapper info)
 201         (class-wrapper (car (initialize-info-key info))))
 202   (let ((slots-to-revert (if *revert-initialize-info-p*
 203                              (initialize-info-bound-slots info)
 204                              '(make-instance-function))))
 205     (reset-initialize-info-internal info)
 206     (dolist (slot slots-to-revert)
 207       (update-initialize-info-internal info slot))
 208     info))
 209
 210 (defun reset-class-initialize-info (class)
 211   (reset-class-initialize-info-1 (class-initialize-info class)))
 212
 213 (defun reset-class-initialize-info-1 (cell)
 214   (when (consp cell)
 215     (when (car cell)
 216       (reset-initialize-info (car cell)))
 217     (let ((alist (cdr cell)))
 218       (dolist (a alist)
 219         (reset-class-initialize-info-1 (cdr a))))))
 220
 221 (defun initialize-info (class initargs &optional (plist-p t) allow-other-keys-arg)
 222   (let ((info nil))
 223     (if (and (eq *initialize-info-cache-class* class)
 224              (eq *initialize-info-cache-initargs* initargs))
 225         (setq info *initialize-info-cache-info*)
 226         (let ((initargs-tail initargs)
 227               (cell (or (class-initialize-info class)
 228                         (setf (class-initialize-info class) (cons nil nil)))))
 229           (loop (when (null initargs-tail) (return nil))
 230                 (let ((keyword (pop initargs-tail))
 231                       (alist-cell cell))
 232                   (when plist-p
 233                     (if (eq keyword :allow-other-keys)
 234                         (setq allow-other-keys-arg (pop initargs-tail))
 235                         (pop initargs-tail)))
 236                   (loop (let ((alist (cdr alist-cell)))
 237                           (when (null alist)
 238                             (setq cell (cons nil nil))
 239                             (setf (cdr alist-cell) (list (cons keyword cell)))
 240                             (return nil))
 241                           (when (eql keyword (caar alist))
 242                             (setq cell (cdar alist))
 243                             (return nil))
 244                           (setq alist-cell alist)))))
 245           (setq info (or (car cell)
 246                          (setf (car cell) (make-initialize-info))))))
 247     (let ((wrapper (initialize-info-wrapper info)))
 248       (unless (eq wrapper (class-wrapper class))
 249         (unless wrapper
 250           (let* ((initargs-tail initargs)
 251                  (klist-cell (list nil))
 252                  (klist-tail klist-cell))
 253             (loop (when (null initargs-tail) (return nil))
 254                   (let ((key (pop initargs-tail)))
 255                     (setf (cdr klist-tail) (list key)))
 256                   (setf klist-tail (cdr klist-tail))
 257                   (when plist-p (pop initargs-tail)))
 258             (setf (initialize-info-key info)
 259                   (list class (cdr klist-cell) allow-other-keys-arg))))
 260         (reset-initialize-info info)))
 261     (setq *initialize-info-cache-class* class)
 262     (setq *initialize-info-cache-initargs* initargs)
 263     (setq *initialize-info-cache-info* info)
 264     info))
 265
 266 (defun update-initialize-info-internal (info name)
 267   (let* ((key (initialize-info-key info))
 268          (class (car key))
 269          (keys (cadr key))
 270          (allow-other-keys-arg (caddr key)))
 271     (ecase name
 272       ((initargs-form-list new-keys)
 273        (multiple-value-bind (initargs-form-list new-keys)
 274            (make-default-initargs-form-list class keys)
 275          (setf (initialize-info-cached-initargs-form-list info) initargs-form-list)
 276          (setf (initialize-info-cached-new-keys info) new-keys)))
 277       ((default-initargs-function)
 278        (let ((initargs-form-list (initialize-info-initargs-form-list info)))
 279          (setf (initialize-info-cached-default-initargs-function info)
 280                (initialize-instance-simple-function
 281                 'default-initargs-function info
 282                 class initargs-form-list))))
 283       ((valid-p ri-valid-p)
 284        (flet ((compute-valid-p (methods)
 285                 (or (not (null allow-other-keys-arg))
 286                     (multiple-value-bind (legal allow-other-keys)
 287                         (check-initargs-values class methods)
 288                       (or (not (null allow-other-keys))
 289                           (dolist (key keys t)
 290                             (unless (member key legal)
 291                               (return (cons :invalid key)))))))))
 292          (let ((proto (class-prototype class)))
 293            (setf (initialize-info-cached-valid-p info)
 294                  (compute-valid-p
 295                   (list (list* 'allocate-instance class nil)
 296                         (list* 'initialize-instance proto nil)
 297                         (list* 'shared-initialize proto t nil))))
 298            (setf (initialize-info-cached-ri-valid-p info)
 299                  (compute-valid-p
 300                   (list (list* 'reinitialize-instance proto nil)
 301                         (list* 'shared-initialize proto nil nil)))))))
 302       ((shared-initialize-t-function)
 303        (multiple-value-bind (initialize-form-list ignore)
 304            (make-shared-initialize-form-list class keys t nil)
 305          (declare (ignore ignore))
 306          (setf (initialize-info-cached-shared-initialize-t-function info)
 307                (initialize-instance-simple-function
 308                 'shared-initialize-t-function info
 309                 class initialize-form-list))))
 310       ((shared-initialize-nil-function)
 311        (multiple-value-bind (initialize-form-list ignore)
 312            (make-shared-initialize-form-list class keys nil nil)
 313          (declare (ignore ignore))
 314          (setf (initialize-info-cached-shared-initialize-nil-function info)
 315                (initialize-instance-simple-function
 316                 'shared-initialize-nil-function info
 317                 class initialize-form-list))))
 318       ((constants combined-initialize-function)
 319        (let ((initargs-form-list (initialize-info-initargs-form-list info))
 320              (new-keys (initialize-info-new-keys info)))
 321          (multiple-value-bind (initialize-form-list constants)
 322              (make-shared-initialize-form-list class new-keys t t)
 323            (setf (initialize-info-cached-constants info) constants)
 324            (setf (initialize-info-cached-combined-initialize-function info)
 325                  (initialize-instance-simple-function
 326                   'combined-initialize-function info
 327                   class (append initargs-form-list initialize-form-list))))))
 328       ((make-instance-function-symbol)
 329        (setf (initialize-info-cached-make-instance-function-symbol info)
 330              (make-instance-function-symbol key)))
 331       ((make-instance-function)
 332        (let* ((function (get-make-instance-function key))
 333               (symbol (initialize-info-make-instance-function-symbol info)))
 334          (setf (initialize-info-cached-make-instance-function info) function)
 335          (when symbol (setf (gdefinition symbol)
 336                             (or function #'make-instance-1)))))))
 337   info)
 338
 339 (defun get-make-instance-function (key)
 340   (let* ((class (car key))
 341          (keys (cadr key)))
 342     (unless (eq *boot-state* 'complete)
 343       (return-from get-make-instance-function nil))
 344     (when (symbolp class)
 345       (setq class (find-class class)))
 346     (when (classp class)
 347       (unless (class-finalized-p class) (finalize-inheritance class)))
 348     (let* ((initargs (mapcan #'(lambda (key) (list key nil)) keys))
 349            (class-and-initargs (list* class initargs))
 350            (make-instance (gdefinition 'make-instance))
 351            (make-instance-methods
 352             (compute-applicable-methods make-instance class-and-initargs))
 353            (std-mi-meth (find-standard-ii-method make-instance-methods 'class))
 354            (class+initargs (list class initargs))
 355            (default-initargs (gdefinition 'default-initargs))
 356            (default-initargs-methods
 357                (compute-applicable-methods default-initargs class+initargs))
 358            (proto (and (classp class) (class-prototype class)))
 359            (initialize-instance-methods
 360             (when proto
 361               (compute-applicable-methods (gdefinition 'initialize-instance)
 362                                           (list* proto initargs))))
 363            (shared-initialize-methods
 364             (when proto
 365               (compute-applicable-methods (gdefinition 'shared-initialize)
 366                                           (list* proto t initargs)))))
 367       (when (null make-instance-methods)
 368         (return-from get-make-instance-function
 369           #'(lambda (class initargs)
 370               (apply #'no-applicable-method make-instance class initargs))))
 371       (unless (and (null (cdr make-instance-methods))
 372                    (eq (car make-instance-methods) std-mi-meth)
 373                    (null (cdr default-initargs-methods))
 374                    (eq (car (method-specializers (car default-initargs-methods)))
 375                        *the-class-slot-class*)
 376                    (flet ((check-meth (meth)
 377                             (let ((quals (method-qualifiers meth)))
 378                               (if (null quals)
 379                                   (eq (car (method-specializers meth))
 380                                       *the-class-slot-object*)
 381                                   (and (null (cdr quals))
 382                                        (or (eq (car quals) ':before)
 383                                            (eq (car quals) ':after)))))))
 384                      (and (every #'check-meth initialize-instance-methods)
 385                           (every #'check-meth shared-initialize-methods))))
 386         (return-from get-make-instance-function nil))
 387       (get-make-instance-function-internal
 388        class key (default-initargs class initargs)
 389        initialize-instance-methods shared-initialize-methods))))
 390
 391 (defun get-make-instance-function-internal (class key initargs
 392                                                   initialize-instance-methods
 393                                                   shared-initialize-methods)
 394   (let* ((keys (cadr key))
 395          (allow-other-keys-p (caddr key))
 396          (allocate-instance-methods
 397           (compute-applicable-methods (gdefinition 'allocate-instance)
 398                                       (list* class initargs))))
 399     (unless allow-other-keys-p
 400       (unless (check-initargs-1
 401                class initargs
 402                (append allocate-instance-methods
 403                        initialize-instance-methods
 404                        shared-initialize-methods)
 405                t nil)
 406         (return-from get-make-instance-function-internal nil)))
 407     (if (or (cdr allocate-instance-methods)
 408             (some #'complicated-instance-creation-method
 409                   initialize-instance-methods)
 410             (some #'complicated-instance-creation-method
 411                   shared-initialize-methods))
 412         (make-instance-function-complex
 413          key class keys
 414          initialize-instance-methods shared-initialize-methods)
 415         (make-instance-function-simple
 416          key class keys
 417          initialize-instance-methods shared-initialize-methods))))
 418
 419 (defun complicated-instance-creation-method (m)
 420   (let ((qual (method-qualifiers m)))
 421     (if qual
 422         (not (and (null (cdr qual)) (eq (car qual) ':after)))
 423         (let ((specl (car (method-specializers m))))
 424           (or (not (classp specl))
 425               (not (eq 'slot-object (class-name specl))))))))
 426
 427 (defun find-standard-ii-method (methods class-names)
 428   (dolist (m methods)
 429     (when (null (method-qualifiers m))
 430       (let ((specl (car (method-specializers m))))
 431         (when (and (classp specl)
 432                    (if (listp class-names)
 433                        (member (class-name specl) class-names)
 434                        (eq (class-name specl) class-names)))
 435           (return m))))))
 436
 437 (defmacro call-initialize-function (initialize-function instance initargs)
 438   `(let ((.function. ,initialize-function))
 439      (if (and (consp .function.)
 440               (eq (car .function.) 'call-initialize-instance-simple))
 441          (initialize-instance-simple (cadr .function.) (caddr .function.)
 442                                      ,instance ,initargs)
 443          (funcall (the function .function.) ,instance ,initargs))))
 444
 445 (defun make-instance-function-simple (key class keys
 446                                           initialize-instance-methods
 447                                           shared-initialize-methods)
 448   (multiple-value-bind (initialize-function constants)
 449       (get-simple-initialization-function class keys (caddr key))
 450     (let* ((wrapper (class-wrapper class))
 451            (lwrapper (list wrapper))
 452            (allocate-function
 453             (cond ((structure-class-p class)
 454                    #'allocate-structure-instance)
 455                   ((standard-class-p class)
 456                    #'allocate-standard-instance)
 457                   ((funcallable-standard-class-p class)
 458                    #'allocate-funcallable-instance)
 459                   (t
 460                    (error "error in make-instance-function-simple"))))
 461            (std-si-meth (find-standard-ii-method shared-initialize-methods
 462                                                  'slot-object))
 463            (shared-initfns
 464             (nreverse (mapcar #'(lambda (method)
 465                                   (make-effective-method-function
 466                                    #'shared-initialize
 467                                    `(call-method ,method nil)
 468                                    nil lwrapper))
 469                               (remove std-si-meth shared-initialize-methods))))
 470            (std-ii-meth (find-standard-ii-method initialize-instance-methods
 471                                                  'slot-object))
 472            (initialize-initfns
 473             (nreverse (mapcar #'(lambda (method)
 474                                   (make-effective-method-function
 475                                    #'initialize-instance
 476                                    `(call-method ,method nil)
 477                                    nil lwrapper))
 478                               (remove std-ii-meth
 479                                       initialize-instance-methods)))))
 480       #'(lambda (class1 initargs)
 481           (if (not (eq wrapper (class-wrapper class)))
 482               (let* ((info (initialize-info class1 initargs))
 483                      (fn (initialize-info-make-instance-function info)))
 484                 (declare (type function fn))
 485                 (funcall fn class1 initargs))
 486               (let* ((instance (funcall allocate-function wrapper constants))
 487                      (initargs (call-initialize-function initialize-function
 488                                                          instance initargs)))
 489                 (dolist (fn shared-initfns)
 490                   (invoke-effective-method-function fn t instance t initargs))
 491                 (dolist (fn initialize-initfns)
 492                   (invoke-effective-method-function fn t instance initargs))
 493                 instance))))))
 494
 495 (defun make-instance-function-complex (key class keys
 496                                            initialize-instance-methods
 497                                            shared-initialize-methods)
 498   (multiple-value-bind (initargs-function initialize-function)
 499       (get-complex-initialization-functions class keys (caddr key))
 500     (let* ((wrapper (class-wrapper class))
 501            (shared-initialize
 502             (get-secondary-dispatch-function
 503              #'shared-initialize shared-initialize-methods
 504              `((class-eq ,class) t t)
 505              `((,(find-standard-ii-method shared-initialize-methods 'slot-object)
 506                 ,#'(lambda (instance init-type &rest initargs)
 507                      (declare (ignore init-type))
 508                      (call-initialize-function initialize-function
 509                                                instance initargs)
 510                      instance)))
 511              (list wrapper *the-wrapper-of-t* *the-wrapper-of-t*)))
 512            (initialize-instance
 513             (get-secondary-dispatch-function
 514              #'initialize-instance initialize-instance-methods
 515              `((class-eq ,class) t)
 516              `((,(find-standard-ii-method initialize-instance-methods 'slot-object)
 517                 ,#'(lambda (instance &rest initargs)
 518                      (invoke-effective-method-function
 519                       shared-initialize t instance t initargs))))
 520              (list wrapper *the-wrapper-of-t*))))
 521       #'(lambda (class1 initargs)
 522           (if (not (eq wrapper (class-wrapper class)))
 523               (let* ((info (initialize-info class1 initargs))
 524                      (fn (initialize-info-make-instance-function info)))
 525                 (declare (type function fn))
 526                 (funcall fn class1 initargs))
 527               (let* ((initargs (call-initialize-function initargs-function
 528                                                          nil initargs))
 529                      (instance (apply #'allocate-instance class initargs)))
 530                 (invoke-effective-method-function
 531                  initialize-instance t instance initargs)
 532                 instance))))))
 533
 534 (defun get-simple-initialization-function (class keys &optional allow-other-keys-arg)
 535   (let ((info (initialize-info class keys nil allow-other-keys-arg)))
 536     (values (initialize-info-combined-initialize-function info)
 537             (initialize-info-constants info))))
 538
 539 (defun get-complex-initialization-functions (class keys &optional allow-other-keys-arg
 540                                                    separate-p)
 541   (let* ((info (initialize-info class keys nil allow-other-keys-arg))
 542          (default-initargs-function (initialize-info-default-initargs-function info)))
 543     (if separate-p
 544         (values default-initargs-function
 545                 (initialize-info-shared-initialize-t-function info))
 546         (values default-initargs-function
 547                 (initialize-info-shared-initialize-t-function
 548                  (initialize-info class (initialize-info-new-keys info)
 549                                   nil allow-other-keys-arg))))))
 550
 551 (defun add-forms (forms forms-list)
 552   (when forms
 553     (setq forms (copy-list forms))
 554     (if (null (car forms-list))
 555         (setf (car forms-list) forms)
 556         (setf (cddr forms-list) forms))
 557     (setf (cdr forms-list) (last forms)))
 558   (car forms-list))
 559
 560 (defun make-default-initargs-form-list (class keys &optional (separate-p t))
 561   (let ((initargs-form-list (cons nil nil))
 562         (default-initargs (class-default-initargs class))
 563         (nkeys keys)
 564         (slots-alist
 565          (mapcan #'(lambda (slot)
 566                      (mapcar #'(lambda (arg)
 567                                  (cons arg slot))
 568                              (slot-definition-initargs slot)))
 569                  (class-slots class)))
 570         (nslots nil))
 571     (dolist (key nkeys)
 572       (pushnew (cdr (assoc key slots-alist)) nslots))
 573     (dolist (default default-initargs)
 574       (let* ((key (car default))
 575              (slot (cdr (assoc key slots-alist)))
 576              (function (cadr default)))
 577         (unless (member slot nslots)
 578           (add-forms `((funcall ,function) (push-initarg ,key))
 579                      initargs-form-list)
 580           (push key nkeys)
 581           (push slot nslots))))
 582     (when separate-p
 583       (add-forms `((update-initialize-info-cache
 584                     ,class ,(initialize-info class nkeys nil)))
 585                  initargs-form-list))
 586     (add-forms `((finish-pushing-initargs))
 587                initargs-form-list)
 588     (values (car initargs-form-list) nkeys)))
 589
 590 (defun make-shared-initialize-form-list (class keys si-slot-names simple-p)
 591   (let* ((initialize-form-list (cons nil nil))
 592          (type (cond ((structure-class-p class)
 593                       'structure)
 594                      ((standard-class-p class)
 595                       'standard)
 596                      ((funcallable-standard-class-p class)
 597                       'funcallable)
 598                      (t (error "error in make-shared-initialize-form-list"))))
 599          (wrapper (class-wrapper class))
 600          (constants (when simple-p
 601                       (make-list (wrapper-no-of-instance-slots wrapper)
 602                                  ':initial-element +slot-unbound+)))
 603          (slots (class-slots class))
 604          (slot-names (mapcar #'slot-definition-name slots))
 605          (slots-key (mapcar #'(lambda (slot)
 606                                 (let ((index most-positive-fixnum))
 607                                   (dolist (key (slot-definition-initargs slot))
 608                                     (let ((pos (position key keys)))
 609                                       (when pos (setq index (min index pos)))))
 610                                   (cons slot index)))
 611                             slots))
 612          (slots (stable-sort slots-key #'< :key #'cdr)))
 613     (let ((n-popped 0))
 614       (dolist (slot+index slots)
 615         (let* ((slot (car slot+index))
 616                (name (slot-definition-name slot))
 617                (npop (1+ (- (cdr slot+index) n-popped))))
 618           (unless (eql (cdr slot+index) most-positive-fixnum)
 619             (let* ((pv-offset (1+ (position name slot-names))))
 620               (add-forms `(,@(when (plusp npop)
 621                                `((pop-initargs ,(* 2 npop))))
 622                            (instance-set ,pv-offset ,slot))
 623                          initialize-form-list))
 624             (incf n-popped npop)))))
 625     (dolist (slot+index slots)
 626       (let* ((slot (car slot+index))
 627              (name (slot-definition-name slot)))
 628         (when (and (eql (cdr slot+index) most-positive-fixnum)
 629                    (or (eq si-slot-names 't)
 630                        (member name si-slot-names)))
 631           (let* ((initform (slot-definition-initform slot))
 632                  (initfunction (slot-definition-initfunction slot))
 633                  (location (unless (eq type 'structure)
 634                              (slot-definition-location slot)))
 635                  (pv-offset (1+ (position name slot-names)))
 636                  (forms (cond ((null initfunction)
 637                                nil)
 638                               ((constantp initform)
 639                                (let ((value (funcall initfunction)))
 640                                  (if (and simple-p (integerp location))
 641                                      (progn (setf (nth location constants) value)
 642                                             nil)
 643                                      `((const ,value)
 644                                        (instance-set ,pv-offset ,slot)))))
 645                               (t
 646                                `((funcall ,(slot-definition-initfunction slot))
 647                                  (instance-set ,pv-offset ,slot))))))
 648             (add-forms `(,@(unless (or simple-p (null forms))
 649                              `((skip-when-instance-boundp ,pv-offset ,slot
 650                                 ,(length forms))))
 651                          ,@forms)
 652                        initialize-form-list)))))
 653     (values (car initialize-form-list) constants)))
 654
 655 (defvar *class-pv-table-table* (make-hash-table :test 'eq))
 656
 657 (defun get-pv-cell-for-class (class)
 658   (let* ((slot-names (mapcar #'slot-definition-name (class-slots class)))
 659          (slot-name-lists (list (cons nil slot-names)))
 660          (pv-table (gethash class *class-pv-table-table*)))
 661     (unless (and pv-table
 662                  (equal slot-name-lists (pv-table-slot-name-lists pv-table)))
 663       (setq pv-table (intern-pv-table :slot-name-lists slot-name-lists))
 664       (setf (gethash class *class-pv-table-table*) pv-table))
 665     (pv-table-lookup pv-table (class-wrapper class))))
 666
 667 (defvar *initialize-instance-simple-alist* nil)
 668 (defvar *note-iis-entry-p* nil)
 669
 670 (defvar *compiled-initialize-instance-simple-functions*
 671   (make-hash-table :test 'equal))
 672
 673 (defun initialize-instance-simple-function (use info class form-list)
 674   (let* ((pv-cell (get-pv-cell-for-class class))
 675          (key (initialize-info-key info))
 676          (sf-key (list* use (class-name (car key)) (cdr key))))
 677     (if (or *compile-make-instance-functions-p*
 678             (gethash sf-key *compiled-initialize-instance-simple-functions*))
 679         (multiple-value-bind (form args)
 680             (form-list-to-lisp pv-cell form-list)
 681           (let ((entry (assoc form *initialize-instance-simple-alist*
 682                               :test #'equal)))
 683             (setf (gethash sf-key
 684                            *compiled-initialize-instance-simple-functions*)
 685                   t)
 686             (if entry
 687                 (setf (cdddr entry) (union (list sf-key) (cdddr entry)
 688                                            :test #'equal))
 689                 (progn
 690                   (setq entry (list* form nil nil (list sf-key)))
 691                   (setq *initialize-instance-simple-alist*
 692                         (nconc *initialize-instance-simple-alist*
 693                                (list entry)))))
 694             (unless (or *note-iis-entry-p* (cadr entry))
 695               (setf (cadr entry) (compile nil (car entry))))
 696             (if (cadr entry)
 697                 (apply (the function (cadr entry)) args)
 698                 `(call-initialize-instance-simple ,pv-cell ,form-list))))
 699         #||
 700         #'(lambda (instance initargs)
 701             (initialize-instance-simple pv-cell form-list instance initargs))
 702         ||#
 703         `(call-initialize-instance-simple ,pv-cell ,form-list))))
 704
 705 (defun load-precompiled-iis-entry (form function system uses)
 706   (let ((entry (assoc form *initialize-instance-simple-alist*
 707                       :test #'equal)))
 708     (unless entry
 709       (setq entry (list* form nil nil nil))
 710       (setq *initialize-instance-simple-alist*
 711             (nconc *initialize-instance-simple-alist*
 712                    (list entry))))
 713     (setf (cadr entry) function)
 714     (setf (caddr entry) system)
 715     (dolist (use uses)
 716       (setf (gethash use *compiled-initialize-instance-simple-functions*) t))
 717     (setf (cdddr entry) (union uses (cdddr entry)
 718                                :test #'equal))))
 719
 720 (defmacro precompile-iis-functions (&optional system)
 721   `(progn
 722     ,@(gathering1 (collecting)
 723                   (dolist (iis-entry *initialize-instance-simple-alist*)
 724                     (when (or (null (caddr iis-entry))
 725                               (eq (caddr iis-entry) system))
 726                       (when system (setf (caddr iis-entry) system))
 727                       (gather1
 728                        `(load-precompiled-iis-entry
 729                          ',(car iis-entry)
 730                          #',(car iis-entry)
 731                          ',system
 732                          ',(cdddr iis-entry))))))))
 733
 734 (defun compile-iis-functions (after-p)
 735   (let ((*compile-make-instance-functions-p* t)
 736         (*revert-initialize-info-p* t)
 737         (*note-iis-entry-p* (not after-p)))
 738     (declare (special *compile-make-instance-functions-p*))
 739     (when (eq *boot-state* 'complete)
 740       (update-make-instance-function-table))))
 741
 742 ;(const const)
 743 ;(funcall function)
 744 ;(push-initarg const)
 745 ;(pop-supplied count) ; a positive odd number
 746 ;(instance-set pv-offset slotd)
 747 ;(skip-when-instance-boundp pv-offset slotd n)
 748
 749 (defun initialize-instance-simple (pv-cell form-list instance initargs)
 750   (let ((pv (car pv-cell))
 751         (initargs-tail initargs)
 752         (slots (get-slots-or-nil instance))
 753         (class (class-of instance))
 754         value)
 755     (loop (when (null form-list) (return nil))
 756           (let ((form (pop form-list)))
 757             (ecase (car form)
 758               (push-initarg
 759                (push value initargs)
 760                (push (cadr form) initargs))
 761               (const
 762                (setq value (cadr form)))
 763               (funcall
 764                (setq value (funcall (the function (cadr form)))))
 765               (pop-initargs
 766                (setq initargs-tail (nthcdr (1- (cadr form)) initargs-tail))
 767                (setq value (pop initargs-tail)))
 768               (instance-set
 769                (instance-write-internal
 770                 pv slots (cadr form) value
 771                 (setf (slot-value-using-class class instance (caddr form))
 772                       value)))
 773               (skip-when-instance-boundp
 774                (when (instance-boundp-internal
 775                       pv slots (cadr form)
 776                       (slot-boundp-using-class class instance (caddr form)))
 777                  (dotimes-fixnum (i (cadddr form))
 778                    (pop form-list))))
 779               (update-initialize-info-cache
 780                (when (consp initargs)
 781                  (setq initargs (cons (car initargs) (cdr initargs))))
 782                (setq *initialize-info-cache-class* (cadr form))
 783                (setq *initialize-info-cache-initargs* initargs)
 784                (setq *initialize-info-cache-info* (caddr form)))
 785               (finish-pushing-initargs
 786                (setq initargs-tail initargs)))))
 787     initargs))
 788
 789 (defun add-to-cvector (cvector constant)
 790   (or (position constant cvector)
 791       (prog1 (fill-pointer cvector)
 792         (vector-push-extend constant cvector))))
 793
 794 (defvar *inline-iis-instance-locations-p* t)
 795
 796 (defun first-form-to-lisp (forms cvector pv)
 797   (flet ((const (constant)
 798            (cond ((or (numberp constant) (characterp constant))
 799                   constant)
 800                  ((and (symbolp constant) (symbol-package constant))
 801                   `',constant)
 802                  (t
 803                   `(svref cvector ,(add-to-cvector cvector constant))))))
 804     (let ((form (pop (car forms))))
 805       (ecase (car form)
 806         (push-initarg
 807          `((push value initargs)
 808            (push ,(const (cadr form)) initargs)))
 809         (const
 810          `((setq value ,(const (cadr form)))))
 811         (funcall
 812          `((setq value (funcall (the function ,(const (cadr form)))))))
 813         (pop-initargs
 814          `((setq initargs-tail (,@(let ((pop (1- (cadr form))))
 815                                     (case pop
 816                                       (1 `(cdr))
 817                                       (3 `(cdddr))
 818                                       (t `(nthcdr ,pop))))
 819                                 initargs-tail))
 820            (setq value (pop initargs-tail))))
 821         (instance-set
 822          (let* ((pv-offset (cadr form))
 823                 (location (pvref pv pv-offset))
 824                 (default `(setf (slot-value-using-class class instance
 825                                                         ,(const (caddr form)))
 826                                 value)))
 827            (if *inline-iis-instance-locations-p*
 828                (typecase location
 829                  (fixnum `((and slots
 830                                 (setf (clos-slots-ref slots ,(const location))
 831                                       value))))
 832                  (cons `((setf (cdr ,(const location)) value)))
 833                  (t `(,default)))
 834                `((instance-write-internal pv slots ,(const pv-offset) value
 835                   ,default
 836                   ,(typecase location
 837                      (fixnum ':instance)
 838                      (cons ':class)
 839                      (t ':default)))))))
 840         (skip-when-instance-boundp
 841          (let* ((pv-offset (cadr form))
 842                 (location (pvref pv pv-offset))
 843                 (default `(slot-boundp-using-class class instance
 844                            ,(const (caddr form)))))
 845            `((unless ,(if *inline-iis-instance-locations-p*
 846                           (typecase location
 847                             (fixnum `(not (and slots
 848                                                (eq (clos-slots-ref
 849                                                     slots
 850                                                     ,(const location))
 851                                                    +slot-unbound+))))
 852                             (cons `(not (eq (cdr ,(const location))
 853                                             +slot-unbound+)))
 854                             (t default))
 855                           `(instance-boundp-internal
 856                             pv slots ,(const pv-offset)
 857                             ,default
 858                             ,(typecase (pvref pv pv-offset)
 859                                (fixnum ':instance)
 860                                (cons ':class)
 861                                (t ':default))))
 862                ,@(let ((sforms (cons nil nil)))
 863                    (dotimes-fixnum (i (cadddr form) (car sforms))
 864                      (add-forms (first-form-to-lisp forms cvector pv)
 865                                 sforms)))))))
 866         (update-initialize-info-cache
 867          `((when (consp initargs)
 868              (setq initargs (cons (car initargs) (cdr initargs))))
 869            (setq *initialize-info-cache-class* ,(const (cadr form)))
 870            (setq *initialize-info-cache-initargs* initargs)
 871            (setq *initialize-info-cache-info* ,(const (caddr form)))))
 872         (finish-pushing-initargs
 873          `((setq initargs-tail initargs)))))))
 874
 875 (defmacro iis-body (&body forms)
 876   `(let ((initargs-tail initargs)
 877          (slots (get-slots-or-nil instance))
 878          (class (class-of instance))
 879          (pv (car pv-cell))
 880          value)
 881      initargs instance initargs-tail pv cvector slots class value
 882      ,@forms))
 883
 884 (defun form-list-to-lisp (pv-cell form-list)
 885   (let* ((forms (list form-list))
 886          (cvector (make-array (floor (length form-list) 2)
 887                               :fill-pointer 0 :adjustable t))
 888          (pv (car pv-cell))
 889          (body (let ((rforms (cons nil nil)))
 890                  (loop (when (null (car forms)) (return (car rforms)))
 891                        (add-forms (first-form-to-lisp forms cvector pv)
 892                                   rforms))))
 893          (cvector-type `(simple-vector ,(length cvector))))
 894     (values
 895      `(lambda (pv-cell cvector)
 896         (declare (type ,cvector-type cvector))
 897         #'(lambda (instance initargs)
 898             (declare #.*optimize-speed*)
 899             (iis-body ,@body)
 900             initargs))
 901      (list pv-cell (coerce cvector cvector-type)))))
 902 \f
 903 ;;; The effect of this is to cause almost all of the overhead of MAKE-INSTANCE
 904 ;;; to happen at load time (or maybe at precompile time, as explained in a
 905 ;;; previous message) rather than the first time that MAKE-INSTANCE is called
 906 ;;; with a given class-name and sequence of keywords.
 907
 908 ;;; This optimization applies only when the first argument and all the even
 909 ;;; numbered arguments are constants evaluating to interned symbols.
 910
 911 (declaim (ftype (function (t) symbol) get-make-instance-function-symbol))
 912
 913 (define-compiler-macro make-instance (&whole form &rest args)
 914   (declare (ignore args))
 915   (let* ((*make-instance-function-keys* nil)
 916          (expanded-form (expand-make-instance-form form)))
 917     (if expanded-form
 918         `(funcall (name-get-fdefinition
 919                    ;; The symbol is guaranteed to be fbound.
 920                    ;; Is there a way to declare this?
 921                    (load-time-value
 922                     (get-make-instance-function-symbol
 923                      ',(first *make-instance-function-keys*))))
 924                   ,@(cdr expanded-form))
 925         form)))
 926
 927 (defun get-make-instance-function-symbol (key)
 928   (get-make-instance-functions (list key))
 929   (make-instance-function-symbol key))