src/pcl/init.lisp

   1 ;;;; This file defines the initialization and related protocols.
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5
   6 ;;;; This software is derived from software originally released by Xerox
   7 ;;;; Corporation. Copyright and release statements follow. Later modifications
   8 ;;;; to the software are in the public domain and are provided with
   9 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  10 ;;;; information.
  11
  12 ;;;; copyright information from original PCL sources:
  13 ;;;;
  14 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  15 ;;;; All rights reserved.
  16 ;;;;
  17 ;;;; Use and copying of this software and preparation of derivative works based
  18 ;;;; upon this software are permitted. Any distribution of this software or
  19 ;;;; derivative works must comply with all applicable United States export
  20 ;;;; control laws.
  21 ;;;;
  22 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  23 ;;;; warranty about the software, its performance or its conformity to any
  24 ;;;; specification.
  25
  26 (in-package "SB-PCL")
  27 \f
  28 (defmethod make-instance ((class symbol) &rest initargs)
  29   (apply #'make-instance (find-class class) initargs))
  30
  31 (defmethod make-instance ((class class) &rest initargs)
  32   (unless (class-finalized-p class) (finalize-inheritance class))
  33   (let ((class-default-initargs (class-default-initargs class)))
  34     (when class-default-initargs
  35       (setf initargs (default-initargs class initargs class-default-initargs)))
  36     (when initargs
  37       (when (and (eq *boot-state* 'complete)
  38                  (not (getf initargs :allow-other-keys)))
  39         (let ((class-proto (class-prototype class)))
  40           (check-initargs-1
  41            class initargs
  42            (append (compute-applicable-methods
  43                     #'allocate-instance (list class))
  44                    (compute-applicable-methods
  45                     #'initialize-instance (list class-proto))
  46                    (compute-applicable-methods
  47                     #'shared-initialize (list class-proto t)))))))
  48     (let ((instance (apply #'allocate-instance class initargs)))
  49       (apply #'initialize-instance instance initargs)
  50       instance)))
  51
  52 (defmethod default-initargs ((class slot-class)
  53                              supplied-initargs
  54                              class-default-initargs)
  55   (loop for (key nil fun) in class-default-initargs
  56         when (eq (getf supplied-initargs key '.not-there.) '.not-there.)
  57           append (list key (funcall fun)) into default-initargs
  58         finally
  59           (return (append supplied-initargs default-initargs))))
  60
  61 (defmethod initialize-instance ((instance slot-object) &rest initargs)
  62   (apply #'shared-initialize instance t initargs))
  63
  64 (defmethod reinitialize-instance ((instance slot-object) &rest initargs)
  65   ;; the ctor machinery allows us to track when memoization of
  66   ;; validity of initargs should be cleared.
  67   (check-ri-initargs instance initargs)
  68   (apply #'shared-initialize instance nil initargs)
  69   instance)
  70
  71 (defmethod update-instance-for-different-class
  72     ((previous standard-object) (current standard-object) &rest initargs)
  73   ;; First we must compute the newly added slots. The spec defines
  74   ;; newly added slots as "those local slots for which no slot of
  75   ;; the same name exists in the previous class."
  76   (let ((added-slots '())
  77         (current-slotds (class-slots (class-of current)))
  78         (previous-slot-names (mapcar #'slot-definition-name
  79                                      (class-slots (class-of previous)))))
  80     (dolist (slotd current-slotds)
  81       (if (and (not (memq (slot-definition-name slotd) previous-slot-names))
  82                (eq (slot-definition-allocation slotd) :instance))
  83           (push (slot-definition-name slotd) added-slots)))
  84     (check-initargs-1
  85      (class-of current) initargs
  86      (list (list* 'update-instance-for-different-class previous current initargs)
  87            (list* 'shared-initialize current added-slots initargs)))
  88     (apply #'shared-initialize current added-slots initargs)))
  89
  90 (defmethod update-instance-for-redefined-class
  91     ((instance standard-object) added-slots discarded-slots property-list
  92      &rest initargs)
  93   (check-initargs-1
  94    (class-of instance) initargs
  95    (list (list* 'update-instance-for-redefined-class
  96                 instance added-slots discarded-slots property-list initargs)
  97          (list* 'shared-initialize instance added-slots initargs)))
  98   (apply #'shared-initialize instance added-slots initargs))
  99
 100 (defmethod shared-initialize ((instance slot-object) slot-names &rest initargs)
 101   (flet ((initialize-slot-from-initarg (class instance slotd)
 102            (let ((slot-initargs (slot-definition-initargs slotd)))
 103              (doplist (initarg value) initargs
 104                (when (memq initarg slot-initargs)
 105                  (setf (slot-value-using-class class instance slotd)
 106                        value)
 107                  (return t)))))
 108          (initialize-slot-from-initfunction (class instance slotd)
 109            ;; CLHS: If a before method stores something in a slot,
 110            ;; that slot won't be initialized from its :INITFORM, if any.
 111            (let ((initfun (slot-definition-initfunction slotd)))
 112              (if (typep instance 'structure-object)
 113                  ;; We don't have a consistent unbound marker for structure
 114                  ;; object slots, and structure object redefinition is not
 115                  ;; really supported anyways -- so unconditionally
 116                  ;; initializing the slot should be fine.
 117                  (when initfun
 118                    (setf (slot-value-using-class class instance slotd)
 119                          (funcall initfun)))
 120                  (unless (or (not initfun)
 121                              (slot-boundp-using-class class instance slotd))
 122                    (setf (slot-value-using-class class instance slotd)
 123                          (funcall initfun)))))))
 124     (let* ((class (class-of instance))
 125            (initfn-slotds
 126             (loop for slotd in (class-slots class)
 127                   unless (initialize-slot-from-initarg class instance slotd)
 128                   collect slotd)))
 129       (dolist (slotd initfn-slotds)
 130         (when (or (eq t slot-names)
 131                   (memq (slot-definition-name slotd) slot-names))
 132           (initialize-slot-from-initfunction class instance slotd))))
 133     instance))
 134 \f
 135 ;;; If initargs are valid return nil, otherwise signal an error.
 136 (defun check-initargs-1 (class initargs call-list
 137                          &optional (plist-p t) (error-p t))
 138   (multiple-value-bind (legal allow-other-keys)
 139       (check-initargs-values class call-list)
 140     (unless allow-other-keys
 141       (if plist-p
 142           (check-initargs-2-plist initargs class legal error-p)
 143           (check-initargs-2-list initargs class legal error-p)))))
 144
 145 (defun check-initargs-values (class call-list)
 146   (let ((methods (mapcan (lambda (call)
 147                            (if (consp call)
 148                                (copy-list (compute-applicable-methods
 149                                            (gdefinition (car call))
 150                                            (cdr call)))
 151                                (list call)))
 152                          call-list))
 153         (legal (apply #'append (mapcar #'slot-definition-initargs
 154                                        (class-slots class)))))
 155     ;; Add to the set of slot-filling initargs the set of
 156     ;; initargs that are accepted by the methods. If at
 157     ;; any point we come across &allow-other-keys, we can
 158     ;; just quit.
 159     (dolist (method methods)
 160       (multiple-value-bind (nreq nopt keysp restp allow-other-keys keys)
 161           (analyze-lambda-list (if (consp method)
 162                                    (early-method-lambda-list method)
 163                                    (method-lambda-list method)))
 164         (declare (ignore nreq nopt keysp restp))
 165         (when allow-other-keys
 166           (return-from check-initargs-values (values nil t)))
 167         (setq legal (append keys legal))))
 168     (values legal nil)))
 169
 170 (define-condition initarg-error (reference-condition program-error)
 171   ((class :reader initarg-error-class :initarg :class)
 172    (initargs :reader initarg-error-initargs :initarg :initargs))
 173   (:default-initargs :references (list '(:ansi-cl :section (7 1 2))))
 174   (:report (lambda (condition stream)
 175              (format stream "~@<Invalid initialization argument~P: ~2I~_~
 176                              ~<~{~S~^, ~} ~@:>~I~_in call for class ~S.~:>"
 177                      (length (initarg-error-initargs condition))
 178                      (list (initarg-error-initargs condition))
 179                      (initarg-error-class condition)))))
 180
 181 (defun check-initargs-2-plist (initargs class legal &optional (error-p t))
 182   (let ((invalid-keys ()))
 183     (unless (getf initargs :allow-other-keys)
 184       ;; Now check the supplied-initarg-names and the default initargs
 185       ;; against the total set that we know are legal.
 186       (doplist (key val) initargs
 187         (unless (or (memq key legal)
 188                     ;; :ALLOW-OTHER-KEYS NIL gets here
 189                     (eq key :allow-other-keys))
 190           (push key invalid-keys)))
 191       (when (and invalid-keys error-p)
 192         (error 'initarg-error :class class :initargs invalid-keys)))
 193     invalid-keys))
 194
 195 (defun check-initargs-2-list (initkeys class legal &optional (error-p t))
 196   (let ((invalid-keys ()))
 197     (unless (memq :allow-other-keys initkeys)
 198       ;; Now check the supplied-initarg-names and the default initargs
 199       ;; against the total set that we know are legal.
 200       (dolist (key initkeys)
 201         (unless (memq key legal)
 202           (push key invalid-keys)))
 203       (when (and invalid-keys error-p)
 204         (error 'initarg-error :class class :initargs invalid-keys)))
 205     invalid-keys))
 206