src/pcl/macros.lisp

   1 ;;;; macros, global variable definitions, and other miscellaneous support stuff
   2 ;;;; used by the rest of the PCL subsystem
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6
   7 ;;;; This software is derived from software originally released by Xerox
   8 ;;;; Corporation. Copyright and release statements follow. Later modifications
   9 ;;;; to the software are in the public domain and are provided with
  10 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  11 ;;;; information.
  12
  13 ;;;; copyright information from original PCL sources:
  14 ;;;;
  15 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  16 ;;;; All rights reserved.
  17 ;;;;
  18 ;;;; Use and copying of this software and preparation of derivative works based
  19 ;;;; upon this software are permitted. Any distribution of this software or
  20 ;;;; derivative works must comply with all applicable United States export
  21 ;;;; control laws.
  22 ;;;;
  23 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  24 ;;;; warranty about the software, its performance or its conformity to any
  25 ;;;; specification.
  26
  27 (in-package "SB-PCL")
  28 \f
  29 (/show "starting pcl/macros.lisp")
  30
  31 (declaim (declaration
  32           ;; These nonstandard declarations seem to be used privately
  33           ;; within PCL itself to pass information around, so we can't
  34           ;; just delete them.
  35           %class
  36           ;; This declaration may also be used within PCL to pass
  37           ;; information around, I'm not sure. -- WHN 2000-12-30
  38           %variable-rebinding))
  39
  40 (/show "done with DECLAIM DECLARATION")
  41
  42 (defun get-declaration (name declarations &optional default)
  43   (dolist (d declarations default)
  44     (dolist (form (cdr d))
  45       (when (and (consp form) (eq (car form) name))
  46         (return-from get-declaration (cdr form))))))
  47
  48 (/show "pcl/macros.lisp 85")
  49
  50 (/show "pcl/macros.lisp 101")
  51
  52 (defmacro dolist-carefully ((var list improper-list-handler) &body body)
  53   `(let ((,var nil)
  54          (.dolist-carefully. ,list))
  55      (loop (when (null .dolist-carefully.) (return nil))
  56            (if (consp .dolist-carefully.)
  57                (progn
  58                  (setq ,var (pop .dolist-carefully.))
  59                  ,@body)
  60                (,improper-list-handler)))))
  61 \f
  62 ;;;; FIND-CLASS
  63 ;;;;
  64 ;;;; This is documented in the CLOS specification.
  65
  66 (/show "pcl/macros.lisp 119")
  67
  68 (declaim (inline legal-class-name-p))
  69 (defun legal-class-name-p (x)
  70   (symbolp x))
  71
  72 (defvar *create-classes-from-internal-structure-definitions-p* t)
  73
  74 (defun find-class-from-cell (symbol cell &optional (errorp t))
  75   (or (when cell
  76         (or (classoid-cell-pcl-class cell)
  77             (when *create-classes-from-internal-structure-definitions-p*
  78               (let ((classoid (classoid-cell-classoid cell)))
  79                 (when (and classoid
  80                            (or (condition-classoid-p classoid)
  81                                (defstruct-classoid-p classoid)))
  82                   (ensure-non-standard-class symbol classoid))))))
  83       (cond ((null errorp) nil)
  84             ((legal-class-name-p symbol)
  85              (error "There is no class named ~
  86                      ~/sb-impl::print-symbol-with-prefix/." symbol))
  87             (t
  88              (error "~S is not a legal class name." symbol)))))
  89
  90 (defun find-class (symbol &optional (errorp t) environment)
  91   (declare (ignore environment))
  92   (find-class-from-cell symbol
  93                         (find-classoid-cell symbol)
  94                         errorp))
  95
  96 \f
  97 ;;; This DEFVAR was originally in defs.lisp, now moved here.
  98 ;;;
  99 ;;; Possible values are NIL, EARLY, BRAID, or COMPLETE.
 100 (declaim (type (member nil early braid complete) **boot-state**))
 101 (defglobal **boot-state** nil)
 102
 103 (/show "pcl/macros.lisp 187")
 104
 105 (define-compiler-macro find-class (&whole form
 106                                    symbol &optional (errorp t) environment)
 107   (declare (ignore environment))
 108   (if (and (constantp symbol)
 109            (legal-class-name-p (setf symbol (constant-form-value symbol)))
 110            (constantp errorp)
 111            (member **boot-state** '(braid complete)))
 112       (let ((errorp (not (null (constant-form-value errorp))))
 113             (cell (make-symbol "CLASSOID-CELL")))
 114         `(let ((,cell (load-time-value (find-classoid-cell ',symbol :create t))))
 115            (or (classoid-cell-pcl-class ,cell)
 116                ,(if errorp
 117                     `(find-class-from-cell ',symbol ,cell t)
 118                     `(when (classoid-cell-classoid ,cell)
 119                        (find-class-from-cell ',symbol ,cell nil))))))
 120       form))
 121
 122 (declaim (inline class-classoid))
 123 (defun class-classoid (class)
 124   (layout-classoid (class-wrapper class)))
 125
 126 (defun (setf find-class) (new-value name &optional errorp environment)
 127   (declare (ignore errorp environment))
 128   (cond ((legal-class-name-p name)
 129          (with-single-package-locked-error
 130              (:symbol name "Using ~A as the class-name argument in ~
 131                            (SETF FIND-CLASS)"))
 132          (with-world-lock ()
 133            (let ((cell (find-classoid-cell name :create new-value)))
 134              (cond (new-value
 135                     (setf (classoid-cell-pcl-class cell) new-value)
 136                     (when (eq **boot-state** 'complete)
 137                       (let ((classoid (class-classoid new-value)))
 138                         (setf (find-classoid name) classoid)
 139                         (%set-class-type-translation new-value classoid))))
 140                    (cell
 141                     (%clear-classoid name cell)))
 142              (when (or (eq **boot-state** 'complete)
 143                        (eq **boot-state** 'braid))
 144                (update-ctors 'setf-find-class :class new-value :name name))
 145              new-value)))
 146         (t
 147          (error "~S is not a legal class name." name))))
 148
 149 (/show "pcl/macros.lisp 241")
 150
 151 (defmacro function-funcall (form &rest args)
 152   `(funcall (the function ,form) ,@args))
 153
 154 (defmacro function-apply (form &rest args)
 155   `(apply (the function ,form) ,@args))
 156
 157 (/show "pcl/macros.lisp 249")
 158 \f
 159 (defun get-setf-fun-name (name)
 160   `(setf ,name))
 161
 162 (defsetf slot-value set-slot-value)
 163 \f
 164 (/show "finished with pcl/macros.lisp")