src/pcl/macros.lisp

   1 ;;;; macros, global variable definitions, and other miscellaneous support stuff
   2 ;;;; used by the rest of the PCL subsystem
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6
   7 ;;;; This software is derived from software originally released by Xerox
   8 ;;;; Corporation. Copyright and release statements follow. Later modifications
   9 ;;;; to the software are in the public domain and are provided with
  10 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  11 ;;;; information.
  12
  13 ;;;; copyright information from original PCL sources:
  14 ;;;;
  15 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  16 ;;;; All rights reserved.
  17 ;;;;
  18 ;;;; Use and copying of this software and preparation of derivative works based
  19 ;;;; upon this software are permitted. Any distribution of this software or
  20 ;;;; derivative works must comply with all applicable United States export
  21 ;;;; control laws.
  22 ;;;;
  23 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  24 ;;;; warranty about the software, its performance or its conformity to any
  25 ;;;; specification.
  26
  27 (in-package "SB-PCL")
  28 \f
  29 (/show "starting pcl/macros.lisp")
  30
  31 (declaim (declaration
  32           ;; As of sbcl-0.7.0.6, SBCL actively uses this declaration
  33           ;; to propagate information needed to set up nice debug
  34           ;; names (as seen e.g. in BACKTRACE) for method functions.
  35           %method-name
  36           ;; These nonstandard declarations seem to be used privately
  37           ;; within PCL itself to pass information around, so we can't
  38           ;; just delete them.
  39           %class
  40           %method-lambda-list
  41           ;; This declaration may also be used within PCL to pass
  42           ;; information around, I'm not sure. -- WHN 2000-12-30
  43           %variable-rebinding))
  44
  45 (/show "done with DECLAIM DECLARATION")
  46
  47 (defun get-declaration (name declarations &optional default)
  48   (dolist (d declarations default)
  49     (dolist (form (cdr d))
  50       (when (and (consp form) (eq (car form) name))
  51         (return-from get-declaration (cdr form))))))
  52
  53 (/show "pcl/macros.lisp 85")
  54
  55 (defmacro doplist ((key val) plist &body body)
  56   `(let ((.plist-tail. ,plist) ,key ,val)
  57      (loop (when (null .plist-tail.) (return nil))
  58            (setq ,key (pop .plist-tail.))
  59            (when (null .plist-tail.)
  60              (error "malformed plist, odd number of elements"))
  61            (setq ,val (pop .plist-tail.))
  62            (progn ,@body))))
  63
  64 (/show "pcl/macros.lisp 101")
  65
  66 (defmacro dolist-carefully ((var list improper-list-handler) &body body)
  67   `(let ((,var nil)
  68          (.dolist-carefully. ,list))
  69      (loop (when (null .dolist-carefully.) (return nil))
  70            (if (consp .dolist-carefully.)
  71                (progn
  72                  (setq ,var (pop .dolist-carefully.))
  73                  ,@body)
  74                (,improper-list-handler)))))
  75 \f
  76 ;;;; FIND-CLASS
  77 ;;;;
  78 ;;;; This is documented in the CLOS specification.
  79
  80 (/show "pcl/macros.lisp 119")
  81
  82 (defvar *find-class* (make-hash-table :test 'eq))
  83
  84 (defmacro find-class-cell-class (cell)
  85   `(car ,cell))
  86
  87 (defmacro find-class-cell-predicate (cell)
  88   `(cadr ,cell))
  89
  90 (defmacro make-find-class-cell (class-name)
  91   (declare (ignore class-name))
  92   '(list* nil #'constantly-nil nil))
  93
  94 (defun find-class-cell (symbol &optional dont-create-p)
  95   (or (gethash symbol *find-class*)
  96       (unless dont-create-p
  97         (unless (legal-class-name-p symbol)
  98           (error "~S is not a legal class name." symbol))
  99         (setf (gethash symbol *find-class*) (make-find-class-cell symbol)))))
 100
 101 (/show "pcl/macros.lisp 157")
 102
 103 (defvar *create-classes-from-internal-structure-definitions-p* t)
 104
 105 (defun find-class-from-cell (symbol cell &optional (errorp t))
 106   (or (find-class-cell-class cell)
 107       (and *create-classes-from-internal-structure-definitions-p*
 108            (or (structure-type-p symbol) (condition-type-p symbol))
 109            (ensure-non-standard-class symbol))
 110       (cond ((null errorp) nil)
 111             ((legal-class-name-p symbol)
 112              (error "There is no class named ~S." symbol))
 113             (t
 114              (error "~S is not a legal class name." symbol)))))
 115
 116 (defun legal-class-name-p (x)
 117   (symbolp x))
 118
 119 (defun find-class (symbol &optional (errorp t) environment)
 120   (declare (ignore environment))
 121   (find-class-from-cell symbol
 122                         (find-class-cell symbol errorp)
 123                         errorp))
 124
 125 \f
 126 ;;; This DEFVAR was originally in defs.lisp, now moved here.
 127 ;;;
 128 ;;; Possible values are NIL, EARLY, BRAID, or COMPLETE.
 129 ;;;
 130 ;;; KLUDGE: This should probably become
 131 ;;;   (DECLAIM (TYPE (MEMBER NIL :EARLY :BRAID :COMPLETE) *BOOT-STATE*))
 132 (defvar *boot-state* nil)
 133
 134 (/show "pcl/macros.lisp 187")
 135
 136 (define-compiler-macro find-class (&whole form
 137                                    symbol &optional (errorp t) environment)
 138   (declare (ignore environment))
 139   (if (and (constantp symbol)
 140            (legal-class-name-p (setf symbol (constant-form-value symbol)))
 141            (constantp errorp)
 142            (member *boot-state* '(braid complete)))
 143       (let ((errorp (not (null (constant-form-value errorp))))
 144             (class-cell (make-symbol "CLASS-CELL")))
 145         `(let ((,class-cell (load-time-value (find-class-cell ',symbol))))
 146            (or (find-class-cell-class ,class-cell)
 147                ,(if errorp
 148                     `(find-class-from-cell ',symbol ,class-cell t)
 149                     `(and (classoid-cell-classoid
 150                            ',(find-classoid-cell symbol))
 151                           (find-class-from-cell ',symbol ,class-cell nil))))))
 152       form))
 153
 154 (defun (setf find-class) (new-value name &optional errorp environment)
 155   (declare (ignore errorp environment))
 156   (cond ((legal-class-name-p name)
 157          (with-single-package-locked-error
 158              (:symbol name "using ~A as the class-name argument in ~
 159                            (SETF FIND-CLASS)"))
 160          (let* ((cell (find-class-cell name))
 161                 (class (find-class-cell-class cell)))
 162            (setf (find-class-cell-class cell) new-value)
 163            (when (eq *boot-state* 'complete)
 164              (if (null new-value)
 165                  (progn
 166                    (setf (find-classoid name) new-value)
 167                    (when class
 168                      ;; KLUDGE: This horror comes about essentially
 169                      ;; because we use the proper name of a classoid
 170                      ;; to do TYPEP, which needs to be available
 171                      ;; early, and also to determine whether TYPE-OF
 172                      ;; should return the name or the class (using
 173                      ;; CLASSOID-PROPER-NAME).  So if we are removing
 174                      ;; proper nameness, arrange for
 175                      ;; CLASSOID-PROPER-NAME to do the right thing
 176                      ;; too.  (This is almost certainly not the right
 177                      ;; solution; instead, CLASSOID-NAME and
 178                      ;; FIND-CLASSOID should be direct parallels to
 179                      ;; CLASS-NAME and FIND-CLASS, and TYPEP on
 180                      ;; not-yet-final classes should be compileable.
 181                      (let ((classoid (layout-classoid (slot-value class 'wrapper))))
 182                        (setf (classoid-name classoid) nil))))
 183
 184                  (let ((classoid (layout-classoid (slot-value new-value 'wrapper))))
 185                    (setf (find-classoid name) classoid)
 186                    (set-class-type-translation new-value classoid))))
 187            (when (or (eq *boot-state* 'complete)
 188                      (eq *boot-state* 'braid))
 189              (update-ctors 'setf-find-class :class new-value :name name))
 190            new-value))
 191         (t
 192          (error "~S is not a legal class name." name))))
 193
 194 (/show "pcl/macros.lisp 241")
 195
 196 (defmacro function-funcall (form &rest args)
 197   `(funcall (the function ,form) ,@args))
 198
 199 (defmacro function-apply (form &rest args)
 200   `(apply (the function ,form) ,@args))
 201
 202 (/show "pcl/macros.lisp 249")
 203 \f
 204 (defun get-setf-fun-name (name)
 205   `(setf ,name))
 206
 207 (defsetf slot-value set-slot-value)
 208 \f
 209 (/show "finished with pcl/macros.lisp")