src/pcl/macros.lisp

   1 ;;;; macros, global variable definitions, and other miscellaneous support stuff
   2 ;;;; used by the rest of the PCL subsystem
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6
   7 ;;;; This software is derived from software originally released by Xerox
   8 ;;;; Corporation. Copyright and release statements follow. Later modifications
   9 ;;;; to the software are in the public domain and are provided with
  10 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  11 ;;;; information.
  12
  13 ;;;; copyright information from original PCL sources:
  14 ;;;;
  15 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  16 ;;;; All rights reserved.
  17 ;;;;
  18 ;;;; Use and copying of this software and preparation of derivative works based
  19 ;;;; upon this software are permitted. Any distribution of this software or
  20 ;;;; derivative works must comply with all applicable United States export
  21 ;;;; control laws.
  22 ;;;;
  23 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  24 ;;;; warranty about the software, its performance or its conformity to any
  25 ;;;; specification.
  26
  27 (in-package "SB-PCL")
  28 \f
  29 (/show "starting pcl/macros.lisp")
  30
  31 (declaim (declaration
  32           ;; As of sbcl-0.7.0.6, SBCL actively uses this declaration
  33           ;; to propagate information needed to set up nice debug
  34           ;; names (as seen e.g. in BACKTRACE) for method functions.
  35           %method-name
  36           ;; These nonstandard declarations seem to be used privately
  37           ;; within PCL itself to pass information around, so we can't
  38           ;; just delete them.
  39           %class
  40           %method-lambda-list
  41           ;; This declaration may also be used within PCL to pass
  42           ;; information around, I'm not sure. -- WHN 2000-12-30
  43           %variable-rebinding))
  44
  45 (/show "done with DECLAIM DECLARATION")
  46
  47 (defun get-declaration (name declarations &optional default)
  48   (dolist (d declarations default)
  49     (dolist (form (cdr d))
  50       (when (and (consp form) (eq (car form) name))
  51         (return-from get-declaration (cdr form))))))
  52
  53 (/show "pcl/macros.lisp 85")
  54
  55 (defmacro doplist ((key val) plist &body body)
  56   `(let ((.plist-tail. ,plist) ,key ,val)
  57      (loop (when (null .plist-tail.) (return nil))
  58            (setq ,key (pop .plist-tail.))
  59            (when (null .plist-tail.)
  60              (error "malformed plist, odd number of elements"))
  61            (setq ,val (pop .plist-tail.))
  62            (progn ,@body))))
  63
  64 (/show "pcl/macros.lisp 101")
  65
  66 (defmacro dolist-carefully ((var list improper-list-handler) &body body)
  67   `(let ((,var nil)
  68          (.dolist-carefully. ,list))
  69      (loop (when (null .dolist-carefully.) (return nil))
  70            (if (consp .dolist-carefully.)
  71                (progn
  72                  (setq ,var (pop .dolist-carefully.))
  73                  ,@body)
  74                (,improper-list-handler)))))
  75 \f
  76 ;;;; FIND-CLASS
  77 ;;;;
  78 ;;;; This is documented in the CLOS specification. FIXME: Except that
  79 ;;;; SBCL deviates from the spec by having CL:FIND-CLASS distinct from
  80 ;;;; PCL:FIND-CLASS, alas.
  81
  82 (/show "pcl/macros.lisp 119")
  83
  84 (defvar *find-class* (make-hash-table :test 'eq))
  85
  86 (defmacro find-class-cell-class (cell)
  87   `(car ,cell))
  88
  89 (defmacro find-class-cell-predicate (cell)
  90   `(cadr ,cell))
  91
  92 (defmacro find-class-cell-make-instance-function-keys (cell)
  93   `(cddr ,cell))
  94
  95 (defmacro make-find-class-cell (class-name)
  96   (declare (ignore class-name))
  97   '(list* nil #'constantly-nil nil))
  98
  99 (defun find-class-cell (symbol &optional dont-create-p)
 100   (or (gethash symbol *find-class*)
 101       (unless dont-create-p
 102         (unless (legal-class-name-p symbol)
 103           (error "~S is not a legal class name." symbol))
 104         (setf (gethash symbol *find-class*) (make-find-class-cell symbol)))))
 105
 106 (/show "pcl/macros.lisp 157")
 107
 108 (defvar *create-classes-from-internal-structure-definitions-p* t)
 109
 110 (defun find-class-from-cell (symbol cell &optional (errorp t))
 111   (or (find-class-cell-class cell)
 112       (and *create-classes-from-internal-structure-definitions-p*
 113            (structure-type-p symbol)
 114            (find-structure-class symbol))
 115       (cond ((null errorp) nil)
 116             ((legal-class-name-p symbol)
 117              (error "There is no class named ~S." symbol))
 118             (t
 119              (error "~S is not a legal class name." symbol)))))
 120
 121 (defun find-class-predicate-from-cell (symbol cell &optional (errorp t))
 122   (unless (find-class-cell-class cell)
 123     (find-class-from-cell symbol cell errorp))
 124   (find-class-cell-predicate cell))
 125
 126 (defun legal-class-name-p (x)
 127   (and (symbolp x)
 128        (not (keywordp x))))
 129
 130 (defun find-class (symbol &optional (errorp t) environment)
 131   (declare (ignore environment))
 132   (find-class-from-cell symbol
 133                         (find-class-cell symbol errorp)
 134                         errorp))
 135
 136 (defun find-class-predicate (symbol &optional (errorp t) environment)
 137   (declare (ignore environment))
 138   (find-class-predicate-from-cell symbol
 139                                   (find-class-cell symbol errorp)
 140                                   errorp))
 141 \f
 142 ;;; This DEFVAR was originally in defs.lisp, now moved here.
 143 ;;;
 144 ;;; Possible values are NIL, EARLY, BRAID, or COMPLETE.
 145 ;;;
 146 ;;; KLUDGE: This should probably become
 147 ;;;   (DECLAIM (TYPE (MEMBER NIL :EARLY :BRAID :COMPLETE) *BOOT-STATE*))
 148 (defvar *boot-state* nil)
 149
 150 (/show "pcl/macros.lisp 187")
 151
 152 ;;; Note that in SBCL as in CMU CL,
 153 ;;;   COMMON-LISP:FIND-CLASS /= SB-PCL:FIND-CLASS.
 154 ;;; (Yes, this is a KLUDGE!)
 155 (define-compiler-macro find-class (&whole form
 156                                    symbol &optional (errorp t) environment)
 157   (declare (ignore environment))
 158   (if (and (constantp symbol)
 159            (legal-class-name-p (eval symbol))
 160            (constantp errorp)
 161            (member *boot-state* '(braid complete)))
 162       (let ((symbol (eval symbol))
 163             (errorp (not (null (eval errorp))))
 164             (class-cell (make-symbol "CLASS-CELL")))
 165         `(let ((,class-cell (load-time-value (find-class-cell ',symbol))))
 166            (or (find-class-cell-class ,class-cell)
 167                ,(if errorp
 168                     `(find-class-from-cell ',symbol ,class-cell t)
 169                     `(and (sb-kernel:class-cell-class
 170                            ',(sb-kernel:find-class-cell symbol))
 171                           (find-class-from-cell ',symbol ,class-cell nil))))))
 172       form))
 173
 174 (defun (setf find-class) (new-value symbol)
 175   (if (legal-class-name-p symbol)
 176       (let ((cell (find-class-cell symbol)))
 177         (setf (find-class-cell-class cell) new-value)
 178         (when (or (eq *boot-state* 'complete)
 179                   (eq *boot-state* 'braid))
 180           (when (and new-value (class-wrapper new-value))
 181             (setf (find-class-cell-predicate cell)
 182                   (fdefinition (class-predicate-name new-value))))
 183           (when (and new-value (not (forward-referenced-class-p new-value)))
 184
 185             (dolist (keys+aok (find-class-cell-make-instance-function-keys
 186                                cell))
 187               (update-initialize-info-internal
 188                (initialize-info new-value (car keys+aok) nil (cdr keys+aok))
 189                'make-instance-function))))
 190         new-value)
 191       (error "~S is not a legal class name." symbol)))
 192
 193 (/show "pcl/macros.lisp 230")
 194
 195 (defun (setf find-class-predicate)
 196        (new-value symbol)
 197   (if (legal-class-name-p symbol)
 198     (setf (find-class-cell-predicate (find-class-cell symbol)) new-value)
 199     (error "~S is not a legal class name." symbol)))
 200
 201 (defun find-wrapper (symbol)
 202   (class-wrapper (find-class symbol)))
 203
 204 (/show "pcl/macros.lisp 241")
 205
 206 (defmacro function-funcall (form &rest args)
 207   `(funcall (the function ,form) ,@args))
 208
 209 (defmacro function-apply (form &rest args)
 210   `(apply (the function ,form) ,@args))
 211
 212 (/show "pcl/macros.lisp 249")
 213 \f
 214 (defun get-setf-fun-name (name)
 215   `(setf ,name))
 216
 217 (defsetf slot-value set-slot-value)
 218 \f
 219 (/show "finished with pcl/macros.lisp")