src/pcl/methods.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; methods
  27 ;;;
  28 ;;; Methods themselves are simple inanimate objects. Most properties of
  29 ;;; methods are immutable, methods cannot be reinitialized. The following
  30 ;;; properties of methods can be changed:
  31 ;;;   METHOD-GENERIC-FUNCTION
  32 \f
  33 ;;; initialization
  34 ;;;
  35 ;;; Error checking is done in before methods. Because of the simplicity of
  36 ;;; standard method objects the standard primary method can fill the slots.
  37 ;;;
  38 ;;; Methods are not reinitializable.
  39
  40 (define-condition metaobject-initialization-violation
  41     (reference-condition simple-error)
  42   ())
  43
  44 (macrolet ((def (name args control)
  45                `(defmethod ,name ,args
  46                  (declare (ignore initargs))
  47                  (error 'metaobject-initialization-violation
  48                   :format-control ,(format nil "~@<~A~@:>" control)
  49                   :format-arguments (list ',name)
  50                   :references (list '(:amop :initialization method))))))
  51   (def reinitialize-instance ((method method) &rest initargs)
  52     "Method objects cannot be redefined by ~S.")
  53   (def change-class ((method method) new &rest initargs)
  54     "Method objects cannot be redefined by ~S.")
  55   ;; NEW being a subclass of method is dealt with in the general
  56   ;; method of CHANGE-CLASS
  57   (def update-instance-for-redefined-class ((method method) added discarded
  58                                             plist &rest initargs)
  59     "No behaviour specified for ~S on method objects.")
  60   (def update-instance-for-different-class (old (new method) &rest initargs)
  61     "No behaviour specified for ~S on method objects.")
  62   (def update-instance-for-different-class ((old method) new &rest initargs)
  63     "No behaviour specified for ~S on method objects."))
  64
  65 (define-condition invalid-method-initarg (simple-program-error)
  66   ((method :initarg :method :reader invalid-method-initarg-method))
  67   (:report
  68    (lambda (c s)
  69      (format s "~@<In initialization of ~S:~2I~_~?~@:>"
  70              (invalid-method-initarg-method c)
  71              (simple-condition-format-control c)
  72              (simple-condition-format-arguments c)))))
  73
  74 (defun invalid-method-initarg (method format-control &rest args)
  75   (error 'invalid-method-initarg :method method
  76          :format-control format-control :format-arguments args))
  77
  78 (defun check-documentation (method doc)
  79   (unless (or (null doc) (stringp doc))
  80     (invalid-method-initarg method "~@<~S of ~S is neither ~S nor a ~S.~@:>"
  81                             :documentation doc 'null 'string)))
  82 (defun check-lambda-list (method ll)
  83   nil)
  84
  85 (defun check-method-function (method fun)
  86   (unless (functionp fun)
  87     (invalid-method-initarg method "~@<~S of ~S is not a ~S.~@:>"
  88                             :function fun 'function)))
  89
  90 (defun check-qualifiers (method qualifiers)
  91   (flet ((improper-list ()
  92            (invalid-method-initarg method
  93                                    "~@<~S of ~S is an improper list.~@:>"
  94                                    :qualifiers qualifiers)))
  95     (dolist-carefully (q qualifiers improper-list)
  96       (unless (and q (atom q))
  97         (invalid-method-initarg method
  98                                 "~@<~S, in ~S ~S, is not a non-~S atom.~@:>"
  99                                 q :qualifiers qualifiers 'null)))))
 100
 101 (defun check-slot-name (method name)
 102   (unless (symbolp name)
 103     (invalid-method-initarg "~@<~S of ~S is not a ~S.~@:>"
 104                             :slot-name name 'symbol)))
 105
 106 (defun check-specializers (method specializers)
 107   (flet ((improper-list ()
 108            (invalid-method-initarg method
 109                                    "~@<~S of ~S is an improper list.~@:>"
 110                                    :specializers specializers)))
 111     (dolist-carefully (s specializers improper-list)
 112       (unless (specializerp s)
 113         (invalid-method-initarg method
 114                                 "~@<~S, in ~S ~S, is not a ~S.~@:>"
 115                                 s :specializers specializers 'specializer)))
 116     ;; KLUDGE: ANSI says that it's not valid to have methods
 117     ;; specializing on classes which are "not defined", leaving
 118     ;; unclear what the definedness of a class is; AMOP suggests that
 119     ;; forward-referenced-classes, since they have proper names and
 120     ;; all, are at least worthy of some level of definition.  We allow
 121     ;; methods specialized on forward-referenced-classes, but it's
 122     ;; non-portable and potentially dubious, so
 123     (let ((frcs (remove-if-not #'forward-referenced-class-p specializers)))
 124       (unless (null frcs)
 125         (style-warn "~@<Defining a method using ~
 126                      ~V[~;~1{~S~}~;~1{~S and ~S~}~:;~{~#[~;and ~]~S~^, ~}~] ~
 127                      as ~2:*~V[~;a specializer~:;specializers~].~@:>"
 128                     (length frcs) frcs)))))
 129
 130 (defmethod shared-initialize :before
 131     ((method standard-method) slot-names &key
 132      qualifiers lambda-list specializers function documentation)
 133   (declare (ignore slot-names))
 134   ;; FIXME: it's not clear to me (CSR, 2006-08-09) why methods get
 135   ;; this extra paranoia and nothing else does; either everything
 136   ;; should be aggressively checking initargs, or nothing much should.
 137   ;; In either case, it would probably be better to have :type
 138   ;; declarations in slots, which would then give a suitable type
 139   ;; error (if we implement type-checking for slots...) rather than
 140   ;; this hand-crafted thing.
 141   (check-qualifiers method qualifiers)
 142   (check-lambda-list method lambda-list)
 143   (check-specializers method specializers)
 144   (check-method-function method function)
 145   (check-documentation method documentation))
 146
 147 (defmethod shared-initialize :before
 148     ((method standard-accessor-method) slot-names &key
 149      slot-name slot-definition)
 150   (declare (ignore slot-names))
 151   (unless slot-definition
 152     (check-slot-name method slot-name)))
 153
 154 (defmethod shared-initialize :after ((method standard-method) slot-names
 155                                      &rest initargs &key ((method-cell method-cell)))
 156   (declare (ignore slot-names method-cell))
 157   (initialize-method-function initargs method))
 158 \f
 159 (defvar *the-class-generic-function*
 160   (find-class 'generic-function))
 161 (defvar *the-class-standard-generic-function*
 162   (find-class 'standard-generic-function))
 163 \f
 164 (defmethod shared-initialize :before
 165            ((generic-function standard-generic-function)
 166             slot-names
 167             &key (name nil namep)
 168                  (lambda-list () lambda-list-p)
 169                  argument-precedence-order
 170                  declarations
 171                  documentation
 172                  (method-class nil method-class-supplied-p)
 173                  (method-combination nil method-combination-supplied-p))
 174   (declare (ignore slot-names
 175                    declarations argument-precedence-order documentation
 176                    lambda-list lambda-list-p))
 177
 178   (when namep
 179     (set-fun-name generic-function name))
 180
 181   (flet ((initarg-error (initarg value string)
 182            (error "when initializing the generic function ~S:~%~
 183                    The ~S initialization argument was: ~A.~%~
 184                    It must be ~A."
 185                   generic-function initarg value string)))
 186     (cond (method-class-supplied-p
 187            (when (symbolp method-class)
 188              (setq method-class (find-class method-class)))
 189            (unless (and (classp method-class)
 190                         (*subtypep (class-eq-specializer method-class)
 191                                    *the-class-method*))
 192              (initarg-error :method-class
 193                             method-class
 194                             "a subclass of the class METHOD"))
 195            (setf (slot-value generic-function 'method-class) method-class))
 196           ((slot-boundp generic-function 'method-class))
 197           (t
 198            (initarg-error :method-class
 199                           "not supplied"
 200                           "a subclass of the class METHOD")))
 201     (cond (method-combination-supplied-p
 202            (unless (method-combination-p method-combination)
 203              (initarg-error :method-combination
 204                             method-combination
 205                             "a method combination object")))
 206           ((slot-boundp generic-function '%method-combination))
 207           (t
 208            (initarg-error :method-combination
 209                           "not supplied"
 210                           "a method combination object")))))
 211 \f
 212 (defun find-generic-function (name &optional (errorp t))
 213   (let ((fun (and (fboundp name) (fdefinition name))))
 214     (cond
 215       ((and fun (typep fun 'generic-function)) fun)
 216       (errorp (error "No generic function named ~S." name))
 217       (t nil))))
 218
 219 (defun real-add-named-method (generic-function-name qualifiers
 220                               specializers lambda-list &rest other-initargs)
 221   (unless (and (fboundp generic-function-name)
 222                (typep (fdefinition generic-function-name) 'generic-function))
 223     (warn 'implicit-generic-function-warning :name generic-function-name))
 224   (let* ((existing-gf (find-generic-function generic-function-name nil))
 225          (generic-function
 226           (if existing-gf
 227               (ensure-generic-function
 228                generic-function-name
 229                :generic-function-class (class-of existing-gf))
 230               (ensure-generic-function generic-function-name)))
 231          (proto (method-prototype-for-gf generic-function-name)))
 232     ;; FIXME: Destructive modification of &REST list.
 233     (setf (getf (getf other-initargs 'plist) :name)
 234           (make-method-spec generic-function qualifiers specializers))
 235     (let ((new (apply #'make-instance (class-of proto)
 236                       :qualifiers qualifiers :specializers specializers
 237                       :lambda-list lambda-list other-initargs)))
 238       (add-method generic-function new)
 239       new)))
 240
 241 (define-condition find-method-length-mismatch
 242     (reference-condition simple-error)
 243   ()
 244   (:default-initargs :references (list '(:ansi-cl :function find-method))))
 245
 246 (defun real-get-method (generic-function qualifiers specializers
 247                         &optional (errorp t)
 248                         always-check-specializers)
 249   (let ((lspec (length specializers))
 250         (methods (generic-function-methods generic-function)))
 251     (when (or methods always-check-specializers)
 252       (let ((nreq (length (arg-info-metatypes (gf-arg-info
 253                                                generic-function)))))
 254         ;; Since we internally bypass FIND-METHOD by using GET-METHOD
 255         ;; instead we need to to this here or users may get hit by a
 256         ;; failed AVER instead of a sensible error message.
 257         (when (/= lspec nreq)
 258           (error
 259            'find-method-length-mismatch
 260            :format-control
 261            "~@<The generic function ~S takes ~D required argument~:P; ~
 262             was asked to find a method with specializers ~S~@:>"
 263            :format-arguments (list generic-function nreq specializers)))))
 264     (let ((hit
 265            (dolist (method methods)
 266              (let ((mspecializers (method-specializers method)))
 267                (aver (= lspec (length mspecializers)))
 268                (when (and (equal qualifiers (safe-method-qualifiers method))
 269                           (every #'same-specializer-p specializers
 270                                  (method-specializers method)))
 271                  (return method))))))
 272       (cond (hit hit)
 273             ((null errorp) nil)
 274             (t
 275              (error "~@<There is no method on ~S with ~
 276                     ~:[no qualifiers~;~:*qualifiers ~S~] ~
 277                     and specializers ~S.~@:>"
 278                     generic-function qualifiers specializers))))))
 279
 280 (defmethod find-method ((generic-function standard-generic-function)
 281                         qualifiers specializers &optional (errorp t))
 282   ;; ANSI about FIND-METHOD: "The specializers argument contains the
 283   ;; parameter specializers for the method. It must correspond in
 284   ;; length to the number of required arguments of the generic
 285   ;; function, or an error is signaled."
 286   ;;
 287   ;; This error checking is done by REAL-GET-METHOD.
 288   (real-get-method
 289    generic-function qualifiers
 290    ;; ANSI for FIND-METHOD seems to imply that in fact specializers
 291    ;; should always be passed in parsed form instead of being parsed
 292    ;; at this point.  Since there's no ANSI-blessed way of getting an
 293    ;; EQL specializer, that seems unnecessarily painful, so we are
 294    ;; nice to our users.  -- CSR, 2007-06-01
 295    (parse-specializers generic-function specializers) errorp t))
 296 \f
 297 ;;; Compute various information about a generic-function's arglist by looking
 298 ;;; at the argument lists of the methods. The hair for trying not to use
 299 ;;; &REST arguments lives here.
 300 ;;;  The values returned are:
 301 ;;;    number-of-required-arguments
 302 ;;;       the number of required arguments to this generic-function's
 303 ;;;       discriminating function
 304 ;;;    &rest-argument-p
 305 ;;;       whether or not this generic-function's discriminating
 306 ;;;       function takes an &rest argument.
 307 ;;;    specialized-argument-positions
 308 ;;;       a list of the positions of the arguments this generic-function
 309 ;;;       specializes (e.g. for a classical generic-function this is the
 310 ;;;       list: (1)).
 311 (defmethod compute-discriminating-function-arglist-info
 312            ((generic-function standard-generic-function))
 313   ;;(declare (values number-of-required-arguments &rest-argument-p
 314   ;;             specialized-argument-postions))
 315   (let ((number-required nil)
 316         (restp nil)
 317         (specialized-positions ())
 318         (methods (generic-function-methods generic-function)))
 319     (dolist (method methods)
 320       (multiple-value-setq (number-required restp specialized-positions)
 321         (compute-discriminating-function-arglist-info-internal
 322          generic-function method number-required restp specialized-positions)))
 323     (values number-required restp (sort specialized-positions #'<))))
 324
 325 (defun compute-discriminating-function-arglist-info-internal
 326        (generic-function method number-of-requireds restp
 327         specialized-argument-positions)
 328   (declare (ignore generic-function)
 329            (type (or null fixnum) number-of-requireds))
 330   (let ((requireds 0))
 331     (declare (fixnum requireds))
 332     ;; Go through this methods arguments seeing how many are required,
 333     ;; and whether there is an &rest argument.
 334     (dolist (arg (method-lambda-list method))
 335       (cond ((eq arg '&aux) (return))
 336             ((memq arg '(&optional &rest &key))
 337              (return (setq restp t)))
 338             ((memq arg lambda-list-keywords))
 339             (t (incf requireds))))
 340     ;; Now go through this method's type specifiers to see which
 341     ;; argument positions are type specified. Treat T specially
 342     ;; in the usual sort of way. For efficiency don't bother to
 343     ;; keep specialized-argument-positions sorted, rather depend
 344     ;; on our caller to do that.
 345     (let ((pos 0))
 346       (dolist (type-spec (method-specializers method))
 347         (unless (eq type-spec *the-class-t*)
 348           (pushnew pos specialized-argument-positions :test #'eq))
 349         (incf pos)))
 350     ;; Finally merge the values for this method into the values
 351     ;; for the exisiting methods and return them. Note that if
 352     ;; num-of-requireds is NIL it means this is the first method
 353     ;; and we depend on that.
 354     (values (min (or number-of-requireds requireds) requireds)
 355             (or restp
 356                 (and number-of-requireds (/= number-of-requireds requireds)))
 357             specialized-argument-positions)))
 358
 359 (defun make-discriminating-function-arglist (number-required-arguments restp)
 360   (nconc (let ((args nil))
 361            (dotimes (i number-required-arguments)
 362              (push (format-symbol *package* ;; ! is this right?
 363                                   "Discriminating Function Arg ~D"
 364                                   i)
 365                    args))
 366            (nreverse args))
 367          (when restp
 368                `(&rest ,(format-symbol *package*
 369                                        "Discriminating Function &rest Arg")))))
 370 \f
 371 (defmethod generic-function-argument-precedence-order
 372     ((gf standard-generic-function))
 373   (aver (eq **boot-state** 'complete))
 374   (loop with arg-info = (gf-arg-info gf)
 375         with lambda-list = (arg-info-lambda-list arg-info)
 376         for argument-position in (arg-info-precedence arg-info)
 377         collect (nth argument-position lambda-list)))
 378
 379 (defmethod generic-function-lambda-list ((gf generic-function))
 380   (gf-lambda-list gf))
 381
 382 (defmethod gf-fast-method-function-p ((gf standard-generic-function))
 383   (gf-info-fast-mf-p (slot-value gf 'arg-info)))
 384
 385 (defmethod initialize-instance :after ((gf standard-generic-function)
 386                                        &key (lambda-list nil lambda-list-p)
 387                                        argument-precedence-order)
 388   (with-slots (arg-info) gf
 389     (if lambda-list-p
 390         (set-arg-info gf
 391                       :lambda-list lambda-list
 392                       :argument-precedence-order argument-precedence-order)
 393         (set-arg-info gf))
 394     (when (arg-info-valid-p arg-info)
 395       (update-dfun gf))))
 396
 397 (defmethod reinitialize-instance :around
 398     ((gf standard-generic-function) &rest args &key
 399      (lambda-list nil lambda-list-p) (argument-precedence-order nil apo-p))
 400   (let ((old-mc (generic-function-method-combination gf)))
 401     (prog1 (call-next-method)
 402       ;; KLUDGE: EQ is too strong a test.
 403       (unless (eq old-mc (generic-function-method-combination gf))
 404         (flush-effective-method-cache gf))
 405       (cond
 406         ((and lambda-list-p apo-p)
 407          (set-arg-info gf
 408                        :lambda-list lambda-list
 409                        :argument-precedence-order argument-precedence-order))
 410         (lambda-list-p (set-arg-info gf :lambda-list lambda-list))
 411         (t (set-arg-info gf)))
 412       (when (arg-info-valid-p (gf-arg-info gf))
 413         (update-dfun gf))
 414       (map-dependents gf (lambda (dependent)
 415                            (apply #'update-dependent gf dependent args))))))
 416
 417 (declaim (special *lazy-dfun-compute-p*))
 418
 419 (defun set-methods (gf methods)
 420   (setf (generic-function-methods gf) nil)
 421   (loop (when (null methods) (return gf))
 422         (real-add-method gf (pop methods) methods)))
 423
 424 (define-condition new-value-specialization (reference-condition error)
 425   ((%method :initarg :method :reader new-value-specialization-method))
 426   (:report
 427    (lambda (c s)
 428      (format s "~@<Cannot add method ~S to ~S, as it specializes the ~
 429                 new-value argument.~@:>"
 430              (new-value-specialization-method c)
 431              #'(setf slot-value-using-class))))
 432   (:default-initargs :references
 433       (list '(:sbcl :node "Metaobject Protocol")
 434             '(:amop :generic-function (setf slot-value-using-class)))))
 435
 436 (defgeneric values-for-add-method (gf method)
 437   (:method ((gf standard-generic-function) (method standard-method))
 438     ;; KLUDGE: Just a single generic dispatch, and everything else
 439     ;; comes from permutation vectors. Would be nicer to define
 440     ;; REAL-ADD-METHOD with a proper method so that we could efficiently
 441     ;; use SLOT-VALUE there.
 442     ;;
 443     ;; Optimization note: REAL-ADD-METHOD has a lot of O(N) stuff in it (as
 444     ;; does PCL as a whole). It should not be too hard to internally store
 445     ;; many of the things we now keep in lists as either purely functional
 446     ;; O(log N) sets, or --if we don't mind the memory cost-- using
 447     ;; specialized hash-tables: most things are used to answer questions about
 448     ;; set-membership, not ordering.
 449     (values (slot-value gf '%lock)
 450             (slot-value method 'qualifiers)
 451             (slot-value method 'specializers)
 452             (slot-value method 'lambda-list)
 453             (slot-value method '%generic-function)
 454             (slot-value gf 'name))))
 455
 456 (define-condition print-object-stream-specializer (reference-condition simple-warning)
 457   ()
 458   (:default-initargs
 459    :references (list '(:ansi-cl :function print-object))
 460    :format-control "~@<Specializing on the second argument to ~S has ~
 461                     unportable effects, and also interferes with ~
 462                     precomputation of print functions for exceptional ~
 463                     situations.~@:>"
 464    :format-arguments (list 'print-object)))
 465
 466 (defun real-add-method (generic-function method &optional skip-dfun-update-p)
 467   (flet ((similar-lambda-lists-p (old-method new-lambda-list)
 468            (multiple-value-bind (a-nreq a-nopt a-keyp a-restp)
 469                (analyze-lambda-list (method-lambda-list old-method))
 470              (multiple-value-bind (b-nreq b-nopt b-keyp b-restp)
 471                  (analyze-lambda-list new-lambda-list)
 472                (and (= a-nreq b-nreq)
 473                     (= a-nopt b-nopt)
 474                     (eq (or a-keyp a-restp)
 475                         (or b-keyp b-restp)))))))
 476     (multiple-value-bind (lock qualifiers specializers new-lambda-list
 477                           method-gf name)
 478         (values-for-add-method generic-function method)
 479       (when method-gf
 480         (error "~@<The method ~S is already part of the generic ~
 481                 function ~S; it can't be added to another generic ~
 482                 function until it is removed from the first one.~@:>"
 483                method method-gf))
 484       (when (and (eq name 'print-object) (not (eq (second specializers) *the-class-t*)))
 485         (warn 'print-object-stream-specializer))
 486       (handler-case
 487           ;; System lock because interrupts need to be disabled as
 488           ;; well: it would be bad to unwind and leave the gf in an
 489           ;; inconsistent state.
 490           (sb-thread::with-recursive-system-spinlock (lock)
 491             (let ((existing (get-method generic-function
 492                                         qualifiers
 493                                         specializers
 494                                         nil)))
 495
 496               ;; If there is already a method like this one then we must get
 497               ;; rid of it before proceeding.  Note that we call the generic
 498               ;; function REMOVE-METHOD to remove it rather than doing it in
 499               ;; some internal way.
 500               (when (and existing (similar-lambda-lists-p existing new-lambda-list))
 501                 (remove-method generic-function existing))
 502
 503               ;; KLUDGE: We have a special case here, as we disallow
 504               ;; specializations of the NEW-VALUE argument to (SETF
 505               ;; SLOT-VALUE-USING-CLASS).  GET-ACCESSOR-METHOD-FUNCTION is
 506               ;; the optimizing function here: it precomputes the effective
 507               ;; method, assuming that there is no dispatch to be done on
 508               ;; the new-value argument.
 509               (when (and (eq generic-function #'(setf slot-value-using-class))
 510                          (not (eq *the-class-t* (first specializers))))
 511                 (error 'new-value-specialization :method  method))
 512
 513               (setf (method-generic-function method) generic-function)
 514               (pushnew method (generic-function-methods generic-function) :test #'eq)
 515               (dolist (specializer specializers)
 516                 (add-direct-method specializer method))
 517
 518               ;; KLUDGE: SET-ARG-INFO contains the error-detecting logic for
 519               ;; detecting attempts to add methods with incongruent lambda
 520               ;; lists.  However, according to Gerd Moellmann on cmucl-imp,
 521               ;; it also depends on the new method already having been added
 522               ;; to the generic function.  Therefore, we need to remove it
 523               ;; again on error:
 524               (let ((remove-again-p t))
 525                 (unwind-protect
 526                      (progn
 527                        (set-arg-info generic-function :new-method method)
 528                        (setq remove-again-p nil))
 529                   (when remove-again-p
 530                     (remove-method generic-function method))))
 531
 532               ;; KLUDGE II: ANSI saith that it is not an error to add a
 533               ;; method with invalid qualifiers to a generic function of the
 534               ;; wrong kind; it's only an error at generic function
 535               ;; invocation time; I dunno what the rationale was, and it
 536               ;; sucks.  Nevertheless, it's probably a programmer error, so
 537               ;; let's warn anyway. -- CSR, 2003-08-20
 538               (let ((mc (generic-function-method-combination generic-functioN)))
 539                 (cond
 540                   ((eq mc *standard-method-combination*)
 541                    (when (and qualifiers
 542                               (or (cdr qualifiers)
 543                                   (not (memq (car qualifiers)
 544                                              '(:around :before :after)))))
 545                      (warn "~@<Invalid qualifiers for standard method ~
 546                             combination in method ~S:~2I~_~S.~@:>"
 547                            method qualifiers)))
 548                   ((short-method-combination-p mc)
 549                    (let ((mc-name (method-combination-type-name mc)))
 550                      (when (or (null qualifiers)
 551                                (cdr qualifiers)
 552                                (and (neq (car qualifiers) :around)
 553                                     (neq (car qualifiers) mc-name)))
 554                        (warn "~@<Invalid qualifiers for ~S method combination ~
 555                               in method ~S:~2I~_~S.~@:>"
 556                              mc-name method qualifiers))))))
 557
 558               (unless skip-dfun-update-p
 559                 (update-ctors 'add-method
 560                               :generic-function generic-function
 561                               :method method)
 562                 (update-dfun generic-function))
 563               (setf (gf-info-needs-update generic-function) t)
 564               (map-dependents generic-function
 565                               (lambda (dep)
 566                                 (update-dependent generic-function
 567                                                   dep 'add-method method)))))
 568         (serious-condition (c)
 569           (error c)))))
 570   generic-function)
 571
 572 (defun real-remove-method (generic-function method)
 573   (when (eq generic-function (method-generic-function method))
 574     (let ((lock (gf-lock generic-function)))
 575       ;; System lock because interrupts need to be disabled as well:
 576       ;; it would be bad to unwind and leave the gf in an inconsistent
 577       ;; state.
 578       (sb-thread::with-recursive-system-spinlock (lock)
 579         (let* ((specializers (method-specializers method))
 580                (methods (generic-function-methods generic-function))
 581                (new-methods (remove method methods)))
 582           (setf (method-generic-function method) nil
 583                 (generic-function-methods generic-function) new-methods)
 584           (dolist (specializer (method-specializers method))
 585             (remove-direct-method specializer method))
 586           (set-arg-info generic-function)
 587           (update-ctors 'remove-method
 588                         :generic-function generic-function
 589                         :method method)
 590           (update-dfun generic-function)
 591           (setf (gf-info-needs-update generic-function) t)
 592           (map-dependents generic-function
 593                           (lambda (dep)
 594                             (update-dependent generic-function
 595                                               dep 'remove-method method)))))))
 596   generic-function)
 597
 598
 599 ;; Tell INFO about the generic function's methods' keys so that the
 600 ;; compiler doesn't complain that the keys defined for some method are
 601 ;; unrecognized.
 602 (sb-ext:without-package-locks
 603   (defun sb-c::maybe-update-info-for-gf (name)
 604     (let ((gf (if (fboundp name) (fdefinition name))))
 605       (when (and gf (generic-function-p gf) (not (early-gf-p gf))
 606                  (not (eq :declared (info :function :where-from name)))
 607                  (gf-info-needs-update gf))
 608         (let* ((methods (generic-function-methods gf))
 609                (gf-lambda-list (generic-function-lambda-list gf))
 610                (tfun (constantly t))
 611                keysp)
 612           (multiple-value-bind (gf.required gf.optional gf.restp gf.rest
 613                                             gf.keyp gf.keys gf.allowp)
 614               (parse-lambda-list gf-lambda-list)
 615             (declare (ignore gf.rest))
 616             ;; 7.6.4 point 5 probably entails that if any method says
 617             ;; &allow-other-keys then the gf should be construed to
 618             ;; accept any key.
 619             (let ((allowp (or gf.allowp
 620                               (find '&allow-other-keys methods
 621                                     :test #'find
 622                                     :key #'method-lambda-list))))
 623               (setf (info :function :type name)
 624                     (specifier-type
 625                      `(function
 626                        (,@(mapcar tfun gf.required)
 627                           ,@(if gf.optional
 628                                 `(&optional ,@(mapcar tfun gf.optional)))
 629                           ,@(if gf.restp
 630                                 `(&rest t))
 631                           ,@(when gf.keyp
 632                               (let ((all-keys
 633                                      (mapcar
 634                                       (lambda (x)
 635                                         (list x t))
 636                                       (remove-duplicates
 637                                        (nconc
 638                                         (mapcan #'function-keywords methods)
 639                                         (mapcar #'keywordicate gf.keys))))))
 640                                 (when all-keys
 641                                   (setq keysp t)
 642                                   `(&key ,@all-keys))))
 643                           ,@(when (and (not keysp) allowp)
 644                               `(&key))
 645                           ,@(when allowp
 646                               `(&allow-other-keys)))
 647                        *))
 648                     (info :function :where-from name) :defined-method
 649                     (gf-info-needs-update gf) nil))))))
 650     (values)))
 651 \f
 652 (defun compute-applicable-methods-function (generic-function arguments)
 653   (values (compute-applicable-methods-using-types
 654            generic-function
 655            (types-from-args generic-function arguments 'eql))))
 656
 657 (defmethod compute-applicable-methods
 658     ((generic-function generic-function) arguments)
 659   (values (compute-applicable-methods-using-types
 660            generic-function
 661            (types-from-args generic-function arguments 'eql))))
 662
 663 (defmethod compute-applicable-methods-using-classes
 664     ((generic-function generic-function) classes)
 665   (compute-applicable-methods-using-types
 666    generic-function
 667    (types-from-args generic-function classes 'class-eq)))
 668
 669 (defun proclaim-incompatible-superclasses (classes)
 670   (setq classes (mapcar (lambda (class)
 671                           (if (symbolp class)
 672                               (find-class class)
 673                               class))
 674                         classes))
 675   (dolist (class classes)
 676     (dolist (other-class classes)
 677       (unless (eq class other-class)
 678         (pushnew other-class (class-incompatible-superclass-list class) :test #'eq)))))
 679
 680 (defun superclasses-compatible-p (class1 class2)
 681   (let ((cpl1 (cpl-or-nil class1))
 682         (cpl2 (cpl-or-nil class2)))
 683     (dolist (sc1 cpl1 t)
 684       (dolist (ic (class-incompatible-superclass-list sc1))
 685         (when (memq ic cpl2)
 686           (return-from superclasses-compatible-p nil))))))
 687
 688 (mapc
 689  #'proclaim-incompatible-superclasses
 690  '(;; superclass class
 691    (built-in-class std-class structure-class) ; direct subclasses of pcl-class
 692    (standard-class funcallable-standard-class)
 693    ;; superclass metaobject
 694    (class eql-specializer class-eq-specializer method method-combination
 695     generic-function slot-definition)
 696    ;; metaclass built-in-class
 697    (number sequence character           ; direct subclasses of t, but not array
 698     standard-object structure-object)   ;                        or symbol
 699    (number array character symbol       ; direct subclasses of t, but not
 700     standard-object structure-object)   ;                        sequence
 701    (complex float rational)             ; direct subclasses of number
 702    (integer ratio)                      ; direct subclasses of rational
 703    (list vector)                        ; direct subclasses of sequence
 704    (cons null)                          ; direct subclasses of list
 705    (string bit-vector)                  ; direct subclasses of vector
 706    ))
 707 \f
 708 (defmethod same-specializer-p ((specl1 specializer) (specl2 specializer))
 709   (eql specl1 specl2))
 710
 711 (defmethod same-specializer-p ((specl1 class) (specl2 class))
 712   (eq specl1 specl2))
 713
 714 (defmethod specializer-class ((specializer class))
 715   specializer)
 716
 717 (defmethod same-specializer-p ((specl1 class-eq-specializer)
 718                                (specl2 class-eq-specializer))
 719   (eq (specializer-class specl1) (specializer-class specl2)))
 720
 721 (defmethod same-specializer-p ((specl1 eql-specializer)
 722                                (specl2 eql-specializer))
 723   (eq (specializer-object specl1) (specializer-object specl2)))
 724
 725 (defmethod specializer-class ((specializer eql-specializer))
 726   (class-of (slot-value specializer 'object)))
 727
 728 (defun specializer-class-or-nil (specializer)
 729   (and (standard-specializer-p specializer)
 730        (specializer-class specializer)))
 731
 732 (defun error-need-at-least-n-args (function n)
 733   (error 'simple-program-error
 734          :format-control "~@<The function ~2I~_~S ~I~_requires ~
 735                           at least ~W argument~:P.~:>"
 736          :format-arguments (list function n)))
 737
 738 (defun types-from-args (generic-function arguments &optional type-modifier)
 739   (multiple-value-bind (nreq applyp metatypes nkeys arg-info)
 740       (get-generic-fun-info generic-function)
 741     (declare (ignore applyp metatypes nkeys))
 742     (let ((types-rev nil))
 743       (dotimes-fixnum (i nreq)
 744         i
 745         (unless arguments
 746           (error-need-at-least-n-args (generic-function-name generic-function)
 747                                       nreq))
 748         (let ((arg (pop arguments)))
 749           (push (if type-modifier `(,type-modifier ,arg) arg) types-rev)))
 750       (values (nreverse types-rev) arg-info))))
 751
 752 (defun get-wrappers-from-classes (nkeys wrappers classes metatypes)
 753   (let* ((w wrappers) (w-tail w) (mt-tail metatypes))
 754     (dolist (class (if (listp classes) classes (list classes)))
 755       (unless (eq t (car mt-tail))
 756         (let ((c-w (class-wrapper class)))
 757           (unless c-w (return-from get-wrappers-from-classes nil))
 758           (if (eql nkeys 1)
 759               (setq w c-w)
 760               (setf (car w-tail) c-w
 761                     w-tail (cdr w-tail)))))
 762       (setq mt-tail (cdr mt-tail)))
 763     w))
 764
 765 (defun sdfun-for-caching (gf classes)
 766   (let ((types (mapcar #'class-eq-type classes)))
 767     (multiple-value-bind (methods all-applicable-and-sorted-p)
 768         (compute-applicable-methods-using-types gf types)
 769       (let ((generator (get-secondary-dispatch-function1
 770                         gf methods types nil t all-applicable-and-sorted-p)))
 771         (make-callable gf methods generator
 772                        nil (mapcar #'class-wrapper classes))))))
 773
 774 (defun value-for-caching (gf classes)
 775   (let ((methods (compute-applicable-methods-using-types
 776                    gf (mapcar #'class-eq-type classes))))
 777     (method-plist-value (car methods) :constant-value)))
 778
 779 (defun default-secondary-dispatch-function (generic-function)
 780   (lambda (&rest args)
 781     (let ((methods (compute-applicable-methods generic-function args)))
 782       (if methods
 783           (let ((emf (get-effective-method-function generic-function
 784                                                     methods)))
 785             (invoke-emf emf args))
 786           (apply #'no-applicable-method generic-function args)))))
 787
 788 (defun list-eq (x y)
 789   (loop (when (atom x) (return (eq x y)))
 790         (when (atom y) (return nil))
 791         (unless (eq (car x) (car y)) (return nil))
 792         (setq x (cdr x)
 793               y (cdr y))))
 794
 795 (defvar *std-cam-methods* nil)
 796
 797 (defun compute-applicable-methods-emf (generic-function)
 798   (if (eq **boot-state** 'complete)
 799       (let* ((cam (gdefinition 'compute-applicable-methods))
 800              (cam-methods (compute-applicable-methods-using-types
 801                            cam (list `(eql ,generic-function) t))))
 802         (values (get-effective-method-function cam cam-methods)
 803                 (list-eq cam-methods
 804                          (or *std-cam-methods*
 805                              (setq *std-cam-methods*
 806                                    (compute-applicable-methods-using-types
 807                                     cam (list `(eql ,cam) t)))))))
 808       (values #'compute-applicable-methods-function t)))
 809
 810 (defun compute-applicable-methods-emf-std-p (gf)
 811   (gf-info-c-a-m-emf-std-p (gf-arg-info gf)))
 812
 813 (defvar *old-c-a-m-gf-methods* nil)
 814
 815 (defun update-all-c-a-m-gf-info (c-a-m-gf)
 816   (let ((methods (generic-function-methods c-a-m-gf)))
 817     (if (and *old-c-a-m-gf-methods*
 818              (every (lambda (old-method)
 819                       (member old-method methods :test #'eq))
 820                     *old-c-a-m-gf-methods*))
 821         (let ((gfs-to-do nil)
 822               (gf-classes-to-do nil))
 823           (dolist (method methods)
 824             (unless (member method *old-c-a-m-gf-methods* :test #'eq)
 825               (let ((specl (car (method-specializers method))))
 826                 (if (eql-specializer-p specl)
 827                     (pushnew (specializer-object specl) gfs-to-do :test #'eq)
 828                     (pushnew (specializer-class specl) gf-classes-to-do :test #'eq)))))
 829           (map-all-generic-functions
 830            (lambda (gf)
 831              (when (or (member gf gfs-to-do :test #'eq)
 832                        (dolist (class gf-classes-to-do nil)
 833                          (member class
 834                                  (class-precedence-list (class-of gf))
 835                                  :test #'eq)))
 836                (update-c-a-m-gf-info gf)))))
 837         (map-all-generic-functions #'update-c-a-m-gf-info))
 838     (setq *old-c-a-m-gf-methods* methods)))
 839
 840 (defun update-gf-info (gf)
 841   (update-c-a-m-gf-info gf)
 842   (update-gf-simple-accessor-type gf))
 843
 844 (defun update-c-a-m-gf-info (gf)
 845   (unless (early-gf-p gf)
 846     (multiple-value-bind (c-a-m-emf std-p)
 847         (compute-applicable-methods-emf gf)
 848       (let ((arg-info (gf-arg-info gf)))
 849         (setf (gf-info-static-c-a-m-emf arg-info) c-a-m-emf)
 850         (setf (gf-info-c-a-m-emf-std-p arg-info) std-p)))))
 851
 852 (defun update-gf-simple-accessor-type (gf)
 853   (let ((arg-info (gf-arg-info gf)))
 854     (setf (gf-info-simple-accessor-type arg-info)
 855           (let* ((methods (generic-function-methods gf))
 856                  (class (and methods (class-of (car methods))))
 857                  (type
 858                   (and class
 859                        (cond ((or (eq class *the-class-standard-reader-method*)
 860                                   (eq class *the-class-global-reader-method*))
 861                               'reader)
 862                              ((or (eq class *the-class-standard-writer-method*)
 863                                   (eq class *the-class-global-writer-method*))
 864                               'writer)
 865                              ((or (eq class *the-class-standard-boundp-method*)
 866                                   (eq class *the-class-global-boundp-method*))
 867                               'boundp)))))
 868             (when (and (gf-info-c-a-m-emf-std-p arg-info)
 869                        type
 870                        (dolist (method (cdr methods) t)
 871                          (unless (eq class (class-of method)) (return nil)))
 872                        (eq (generic-function-method-combination gf)
 873                            *standard-method-combination*))
 874               type)))))
 875
 876
 877 ;;; CMUCL (Gerd's PCL, 2002-04-25) comment:
 878 ;;;
 879 ;;; Return two values.  First value is a function to be stored in
 880 ;;; effective slot definition SLOTD for reading it with
 881 ;;; SLOT-VALUE-USING-CLASS, setting it with (SETF
 882 ;;; SLOT-VALUE-USING-CLASS) or testing it with
 883 ;;; SLOT-BOUNDP-USING-CLASS.  GF is one of these generic functions,
 884 ;;; TYPE is one of the symbols READER, WRITER, BOUNDP.  CLASS is
 885 ;;; SLOTD's class.
 886 ;;;
 887 ;;; Second value is true if the function returned is one of the
 888 ;;; optimized standard functions for the purpose, which are used
 889 ;;; when only standard methods are applicable.
 890 ;;;
 891 ;;; FIXME: Change all these wacky function names to something sane.
 892 (defun get-accessor-method-function (gf type class slotd)
 893   (let* ((std-method (standard-svuc-method type))
 894          (str-method (structure-svuc-method type))
 895          (types1 `((eql ,class) (class-eq ,class) (eql ,slotd)))
 896          (types (if (eq type 'writer) `(t ,@types1) types1))
 897          (methods (compute-applicable-methods-using-types gf types))
 898          (std-p (null (cdr methods))))
 899     (values
 900      (if std-p
 901          (get-optimized-std-accessor-method-function class slotd type)
 902          (let* ((optimized-std-fun
 903                  (get-optimized-std-slot-value-using-class-method-function
 904                   class slotd type))
 905                 (method-alist
 906                  `((,(car (or (member std-method methods :test #'eq)
 907                               (member str-method methods :test #'eq)
 908                               (bug "error in ~S"
 909                                    'get-accessor-method-function)))
 910                     ,optimized-std-fun)))
 911                 (wrappers
 912                  (let ((wrappers (list (wrapper-of class)
 913                                        (class-wrapper class)
 914                                        (wrapper-of slotd))))
 915                    (if (eq type 'writer)
 916                        (cons (class-wrapper *the-class-t*) wrappers)
 917                        wrappers)))
 918                 (sdfun (get-secondary-dispatch-function
 919                         gf methods types method-alist wrappers)))
 920            (get-accessor-from-svuc-method-function class slotd sdfun type)))
 921      std-p)))
 922
 923 ;;; used by OPTIMIZE-SLOT-VALUE-BY-CLASS-P (vector.lisp)
 924 (defun update-slot-value-gf-info (gf type)
 925   (unless *new-class*
 926     (update-std-or-str-methods gf type))
 927   (when (and (standard-svuc-method type) (structure-svuc-method type))
 928     (flet ((update-accessor-info (class)
 929              (when (class-finalized-p class)
 930                (dolist (slotd (class-slots class))
 931                  (compute-slot-accessor-info slotd type gf)))))
 932       (if *new-class*
 933           (update-accessor-info *new-class*)
 934           (map-all-classes #'update-accessor-info 'slot-object)))))
 935
 936 (defvar *standard-slot-value-using-class-method* nil)
 937 (defvar *standard-setf-slot-value-using-class-method* nil)
 938 (defvar *standard-slot-boundp-using-class-method* nil)
 939 (defvar *condition-slot-value-using-class-method* nil)
 940 (defvar *condition-setf-slot-value-using-class-method* nil)
 941 (defvar *condition-slot-boundp-using-class-method* nil)
 942 (defvar *structure-slot-value-using-class-method* nil)
 943 (defvar *structure-setf-slot-value-using-class-method* nil)
 944 (defvar *structure-slot-boundp-using-class-method* nil)
 945
 946 (defun standard-svuc-method (type)
 947   (case type
 948     (reader *standard-slot-value-using-class-method*)
 949     (writer *standard-setf-slot-value-using-class-method*)
 950     (boundp *standard-slot-boundp-using-class-method*)))
 951
 952 (defun set-standard-svuc-method (type method)
 953   (case type
 954     (reader (setq *standard-slot-value-using-class-method* method))
 955     (writer (setq *standard-setf-slot-value-using-class-method* method))
 956     (boundp (setq *standard-slot-boundp-using-class-method* method))))
 957
 958 (defun condition-svuc-method (type)
 959   (case type
 960     (reader *condition-slot-value-using-class-method*)
 961     (writer *condition-setf-slot-value-using-class-method*)
 962     (boundp *condition-slot-boundp-using-class-method*)))
 963
 964 (defun set-condition-svuc-method (type method)
 965   (case type
 966     (reader (setq *condition-slot-value-using-class-method* method))
 967     (writer (setq *condition-setf-slot-value-using-class-method* method))
 968     (boundp (setq *condition-slot-boundp-using-class-method* method))))
 969
 970 (defun structure-svuc-method (type)
 971   (case type
 972     (reader *structure-slot-value-using-class-method*)
 973     (writer *structure-setf-slot-value-using-class-method*)
 974     (boundp *structure-slot-boundp-using-class-method*)))
 975
 976 (defun set-structure-svuc-method (type method)
 977   (case type
 978     (reader (setq *structure-slot-value-using-class-method* method))
 979     (writer (setq *structure-setf-slot-value-using-class-method* method))
 980     (boundp (setq *structure-slot-boundp-using-class-method* method))))
 981
 982 (defun update-std-or-str-methods (gf type)
 983   (dolist (method (generic-function-methods gf))
 984     (let ((specls (method-specializers method)))
 985       (when (and (or (not (eq type 'writer))
 986                      (eq (pop specls) *the-class-t*))
 987                  (every #'classp specls))
 988         (cond ((and (eq (class-name (car specls)) 'std-class)
 989                     (eq (class-name (cadr specls)) 'standard-object)
 990                     (eq (class-name (caddr specls))
 991                         'standard-effective-slot-definition))
 992                (set-standard-svuc-method type method))
 993               ((and (eq (class-name (car specls)) 'condition-class)
 994                     (eq (class-name (cadr specls)) 'condition)
 995                     (eq (class-name (caddr specls))
 996                         'condition-effective-slot-definition))
 997                (set-condition-svuc-method type method))
 998               ((and (eq (class-name (car specls)) 'structure-class)
 999                     (eq (class-name (cadr specls)) 'structure-object)
1000                     (eq (class-name (caddr specls))
1001                         'structure-effective-slot-definition))
1002                (set-structure-svuc-method type method)))))))
1003
1004 (defun mec-all-classes-internal (spec precompute-p)
1005   (let ((wrapper (class-wrapper (specializer-class spec))))
1006     (unless (or (not wrapper) (invalid-wrapper-p wrapper))
1007       (cons (specializer-class spec)
1008             (and (classp spec)
1009                  precompute-p
1010                  (not (or (eq spec *the-class-t*)
1011                           (eq spec *the-class-slot-object*)
1012                           (eq spec *the-class-standard-object*)
1013                           (eq spec *the-class-structure-object*)))
1014                  (let ((sc (class-direct-subclasses spec)))
1015                    (when sc
1016                      (mapcan (lambda (class)
1017                                (mec-all-classes-internal class precompute-p))
1018                              sc))))))))
1019
1020 (defun mec-all-classes (spec precompute-p)
1021   (let ((classes (mec-all-classes-internal spec precompute-p)))
1022     (if (null (cdr classes))
1023         classes
1024         (let* ((a-classes (cons nil classes))
1025                (tail classes))
1026           (loop (when (null (cdr tail))
1027                   (return (cdr a-classes)))
1028                 (let ((class (cadr tail))
1029                       (ttail (cddr tail)))
1030                   (if (dolist (c ttail nil)
1031                         (when (eq class c) (return t)))
1032                       (setf (cdr tail) (cddr tail))
1033                       (setf tail (cdr tail)))))))))
1034
1035 (defun mec-all-class-lists (spec-list precompute-p)
1036   (if (null spec-list)
1037       (list nil)
1038       (let* ((car-all-classes (mec-all-classes (car spec-list)
1039                                                precompute-p))
1040              (all-class-lists (mec-all-class-lists (cdr spec-list)
1041                                                    precompute-p)))
1042         (mapcan (lambda (list)
1043                   (mapcar (lambda (c) (cons c list)) car-all-classes))
1044                 all-class-lists))))
1045
1046 (defun make-emf-cache (generic-function valuep cache classes-list new-class)
1047   (let* ((arg-info (gf-arg-info generic-function))
1048          (nkeys (arg-info-nkeys arg-info))
1049          (metatypes (arg-info-metatypes arg-info))
1050          (wrappers (unless (eq nkeys 1) (make-list nkeys)))
1051          (precompute-p (gf-precompute-dfun-and-emf-p arg-info)))
1052     (flet ((add-class-list (classes)
1053              (when (or (null new-class) (memq new-class classes))
1054                (let ((%wrappers (get-wrappers-from-classes
1055                                  nkeys wrappers classes metatypes)))
1056                  (when (and %wrappers (not (probe-cache cache %wrappers)))
1057                    (let ((value (cond ((eq valuep t)
1058                                        (sdfun-for-caching generic-function
1059                                                           classes))
1060                                       ((eq valuep :constant-value)
1061                                        (value-for-caching generic-function
1062                                                           classes)))))
1063                      ;; need to get them again, as finalization might
1064                      ;; have happened in between, which would
1065                      ;; invalidate wrappers.
1066                      (let ((wrappers (get-wrappers-from-classes
1067                                       nkeys wrappers classes metatypes)))
1068                        (when (if (atom wrappers)
1069                                  (not (invalid-wrapper-p wrappers))
1070                                  (every (complement #'invalid-wrapper-p)
1071                                         wrappers))
1072                          (setq cache (fill-cache cache wrappers value))))))))))
1073       (if classes-list
1074           (mapc #'add-class-list classes-list)
1075           (dolist (method (generic-function-methods generic-function))
1076             (mapc #'add-class-list
1077                   (mec-all-class-lists (method-specializers method)
1078                                        precompute-p))))
1079       cache)))
1080
1081 (defmacro class-test (arg class)
1082   (cond
1083     ((eq class *the-class-t*) t)
1084     ((eq class *the-class-slot-object*)
1085      `(not (typep (classoid-of ,arg) 'built-in-classoid)))
1086     ((eq class *the-class-standard-object*)
1087      `(or (std-instance-p ,arg) (fsc-instance-p ,arg)))
1088     ((eq class *the-class-funcallable-standard-object*)
1089      `(fsc-instance-p ,arg))
1090     (t
1091      `(typep ,arg ',(class-name class)))))
1092
1093 (defmacro class-eq-test (arg class)
1094   `(eq (class-of ,arg) ',class))
1095
1096 (defmacro eql-test (arg object)
1097   `(eql ,arg ',object))
1098
1099 (defun dnet-methods-p (form)
1100   (and (consp form)
1101        (or (eq (car form) 'methods)
1102            (eq (car form) 'unordered-methods))))
1103
1104 ;;; This is CASE, but without gensyms.
1105 (defmacro scase (arg &rest clauses)
1106   `(let ((.case-arg. ,arg))
1107      (cond ,@(mapcar (lambda (clause)
1108                        (list* (cond ((null (car clause))
1109                                      nil)
1110                                     ((consp (car clause))
1111                                      (if (null (cdar clause))
1112                                          `(eql .case-arg.
1113                                                ',(caar clause))
1114                                          `(member .case-arg.
1115                                                   ',(car clause))))
1116                                     ((member (car clause) '(t otherwise))
1117                                      `t)
1118                                     (t
1119                                      `(eql .case-arg. ',(car clause))))
1120                               nil
1121                               (cdr clause)))
1122                      clauses))))
1123
1124 (defmacro mcase (arg &rest clauses) `(scase ,arg ,@clauses))
1125
1126 (defun generate-discrimination-net (generic-function methods types sorted-p)
1127   (let* ((arg-info (gf-arg-info generic-function))
1128          (c-a-m-emf-std-p (gf-info-c-a-m-emf-std-p arg-info))
1129          (precedence (arg-info-precedence arg-info)))
1130     (generate-discrimination-net-internal
1131      generic-function methods types
1132      (lambda (methods known-types)
1133        (if (or sorted-p
1134                (and c-a-m-emf-std-p
1135                     (block one-order-p
1136                       (let ((sorted-methods nil))
1137                         (map-all-orders
1138                          (copy-list methods) precedence
1139                          (lambda (methods)
1140                            (when sorted-methods (return-from one-order-p nil))
1141                            (setq sorted-methods methods)))
1142                         (setq methods sorted-methods))
1143                       t)))
1144            `(methods ,methods ,known-types)
1145            `(unordered-methods ,methods ,known-types)))
1146      (lambda (position type true-value false-value)
1147        (let ((arg (dfun-arg-symbol position)))
1148          (if (eq (car type) 'eql)
1149              (let* ((false-case-p (and (consp false-value)
1150                                        (or (eq (car false-value) 'scase)
1151                                            (eq (car false-value) 'mcase))
1152                                        (eq arg (cadr false-value))))
1153                     (false-clauses (if false-case-p
1154                                        (cddr false-value)
1155                                        `((t ,false-value))))
1156                     (case-sym (if (and (dnet-methods-p true-value)
1157                                        (if false-case-p
1158                                            (eq (car false-value) 'mcase)
1159                                            (dnet-methods-p false-value)))
1160                                   'mcase
1161                                   'scase))
1162                     (type-sym `(,(cadr type))))
1163                `(,case-sym ,arg
1164                            (,type-sym ,true-value)
1165                            ,@false-clauses))
1166              `(if ,(let ((arg (dfun-arg-symbol position)))
1167                      (case (car type)
1168                        (class    `(class-test    ,arg ,(cadr type)))
1169                        (class-eq `(class-eq-test ,arg ,(cadr type)))))
1170                   ,true-value
1171                   ,false-value))))
1172      #'identity)))
1173
1174 (defun class-from-type (type)
1175   (if (or (atom type) (eq (car type) t))
1176       *the-class-t*
1177       (case (car type)
1178         (and (dolist (type (cdr type) *the-class-t*)
1179                (when (and (consp type) (not (eq (car type) 'not)))
1180                  (return (class-from-type type)))))
1181         (not *the-class-t*)
1182         (eql (class-of (cadr type)))
1183         (class-eq (cadr type))
1184         (class (cadr type)))))
1185
1186 (defun precompute-effective-methods (gf caching-p &optional classes-list-p)
1187   (let* ((arg-info (gf-arg-info gf))
1188          (methods (generic-function-methods gf))
1189          (precedence (arg-info-precedence arg-info))
1190          (*in-precompute-effective-methods-p* t)
1191          (classes-list nil))
1192     (generate-discrimination-net-internal
1193      gf methods nil
1194      (lambda (methods known-types)
1195        (when methods
1196          (when classes-list-p
1197            (push (mapcar #'class-from-type known-types) classes-list))
1198          (let ((no-eql-specls-p (not (methods-contain-eql-specializer-p
1199                                       methods))))
1200            (map-all-orders
1201             methods precedence
1202             (lambda (methods)
1203               (get-secondary-dispatch-function1
1204                gf methods known-types
1205                nil caching-p no-eql-specls-p))))))
1206      (lambda (position type true-value false-value)
1207        (declare (ignore position type true-value false-value))
1208        nil)
1209      (lambda (type)
1210        (if (and (consp type) (eq (car type) 'eql))
1211            `(class-eq ,(class-of (cadr type)))
1212            type)))
1213     classes-list))
1214
1215 ;;; We know that known-type implies neither new-type nor `(not ,new-type).
1216 (defun augment-type (new-type known-type)
1217   (if (or (eq known-type t)
1218           (eq (car new-type) 'eql))
1219       new-type
1220       (let ((so-far (if (and (consp known-type) (eq (car known-type) 'and))
1221                         (cdr known-type)
1222                         (list known-type))))
1223         (unless (eq (car new-type) 'not)
1224           (setq so-far
1225                 (mapcan (lambda (type)
1226                           (unless (*subtypep new-type type)
1227                             (list type)))
1228                         so-far)))
1229         (if (null so-far)
1230             new-type
1231             `(and ,new-type ,@so-far)))))
1232
1233 (defun generate-discrimination-net-internal
1234     (gf methods types methods-function test-fun type-function)
1235   (let* ((arg-info (gf-arg-info gf))
1236          (precedence (arg-info-precedence arg-info))
1237          (nreq (arg-info-number-required arg-info))
1238          (metatypes (arg-info-metatypes arg-info)))
1239     (labels ((do-column (p-tail contenders known-types)
1240                (if p-tail
1241                    (let* ((position (car p-tail))
1242                           (known-type (or (nth position types) t)))
1243                      (if (eq (nth position metatypes) t)
1244                          (do-column (cdr p-tail) contenders
1245                                     (cons (cons position known-type)
1246                                           known-types))
1247                          (do-methods p-tail contenders
1248                                      known-type () known-types)))
1249                    (funcall methods-function contenders
1250                             (let ((k-t (make-list nreq)))
1251                               (dolist (index+type known-types)
1252                                 (setf (nth (car index+type) k-t)
1253                                       (cdr index+type)))
1254                               k-t))))
1255              (do-methods (p-tail contenders known-type winners known-types)
1256                ;; CONTENDERS
1257                ;;   is a (sorted) list of methods that must be discriminated.
1258                ;; KNOWN-TYPE
1259                ;;   is the type of this argument, constructed from tests
1260                ;;   already made.
1261                ;; WINNERS
1262                ;;   is a (sorted) list of methods that are potentially
1263                ;;   applicable after the discrimination has been made.
1264                (if (null contenders)
1265                    (do-column (cdr p-tail)
1266                               winners
1267                               (cons (cons (car p-tail) known-type)
1268                                     known-types))
1269                    (let* ((position (car p-tail))
1270                           (method (car contenders))
1271                           (specl (nth position (method-specializers method)))
1272                           (type (funcall type-function
1273                                          (type-from-specializer specl))))
1274                      (multiple-value-bind (app-p maybe-app-p)
1275                          (specializer-applicable-using-type-p type known-type)
1276                        (flet ((determined-to-be (truth-value)
1277                                 (if truth-value app-p (not maybe-app-p)))
1278                               (do-if (truth &optional implied)
1279                                 (let ((ntype (if truth type `(not ,type))))
1280                                   (do-methods p-tail
1281                                     (cdr contenders)
1282                                     (if implied
1283                                         known-type
1284                                         (augment-type ntype known-type))
1285                                     (if truth
1286                                         (append winners `(,method))
1287                                         winners)
1288                                     known-types))))
1289                          (cond ((determined-to-be nil) (do-if nil t))
1290                                ((determined-to-be t)   (do-if t   t))
1291                                (t (funcall test-fun position type
1292                                            (do-if t) (do-if nil))))))))))
1293       (do-column precedence methods ()))))
1294
1295 (defun compute-secondary-dispatch-function (generic-function net &optional
1296                                             method-alist wrappers)
1297   (function-funcall (compute-secondary-dispatch-function1 generic-function net)
1298                     method-alist wrappers))
1299
1300 (defvar *eq-case-table-limit* 15)
1301 (defvar *case-table-limit* 10)
1302
1303 (defun compute-mcase-parameters (case-list)
1304   (unless (eq t (caar (last case-list)))
1305     (error "The key for the last case arg to mcase was not T"))
1306   (let* ((eq-p (dolist (case case-list t)
1307                  (unless (or (eq (car case) t)
1308                              (symbolp (caar case)))
1309                    (return nil))))
1310          (len (1- (length case-list)))
1311          (type (cond ((= len 1)
1312                       :simple)
1313                      ((<= len
1314                           (if eq-p
1315                               *eq-case-table-limit*
1316                               *case-table-limit*))
1317                       :assoc)
1318                      (t
1319                       :hash-table))))
1320     (list eq-p type)))
1321
1322 (defmacro mlookup (key info default &optional eq-p type)
1323   (unless (or (eq eq-p t) (null eq-p))
1324     (bug "Invalid eq-p argument: ~S" eq-p))
1325   (ecase type
1326     (:simple
1327      `(if (locally
1328             (declare (optimize (inhibit-warnings 3)))
1329             (,(if eq-p 'eq 'eql) ,key (car ,info)))
1330           (cdr ,info)
1331           ,default))
1332     (:assoc
1333      `(dolist (e ,info ,default)
1334         (when (locally
1335                 (declare (optimize (inhibit-warnings 3)))
1336                 (,(if eq-p 'eq 'eql) (car e) ,key))
1337           (return (cdr e)))))
1338     (:hash-table
1339      `(gethash ,key ,info ,default))))
1340
1341 (defun net-test-converter (form)
1342   (if (atom form)
1343       (default-test-converter form)
1344       (case (car form)
1345         ((invoke-effective-method-function invoke-fast-method-call
1346           invoke-effective-narrow-method-function)
1347          '.call.)
1348         (methods
1349          '.methods.)
1350         (unordered-methods
1351          '.umethods.)
1352         (mcase
1353          `(mlookup ,(cadr form)
1354                    nil
1355                    nil
1356                    ,@(compute-mcase-parameters (cddr form))))
1357         (t (default-test-converter form)))))
1358
1359 (defun net-code-converter (form)
1360   (if (atom form)
1361       (default-code-converter form)
1362       (case (car form)
1363         ((methods unordered-methods)
1364          (let ((gensym (gensym)))
1365            (values gensym
1366                    (list gensym))))
1367         (mcase
1368          (let ((mp (compute-mcase-parameters (cddr form)))
1369                (gensym (gensym)) (default (gensym)))
1370            (values `(mlookup ,(cadr form) ,gensym ,default ,@mp)
1371                    (list gensym default))))
1372         (t
1373          (default-code-converter form)))))
1374
1375 (defun net-constant-converter (form generic-function)
1376   (or (let ((c (methods-converter form generic-function)))
1377         (when c (list c)))
1378       (if (atom form)
1379           (default-constant-converter form)
1380           (case (car form)
1381             (mcase
1382              (let* ((mp (compute-mcase-parameters (cddr form)))
1383                     (list (mapcar (lambda (clause)
1384                                     (let ((key (car clause))
1385                                           (meth (cadr clause)))
1386                                       (cons (if (consp key) (car key) key)
1387                                             (methods-converter
1388                                              meth generic-function))))
1389                                   (cddr form)))
1390                     (default (car (last list))))
1391                (list (list* :mcase mp (nbutlast list))
1392                      (cdr default))))
1393             (t
1394              (default-constant-converter form))))))
1395
1396 (defun methods-converter (form generic-function)
1397   (cond ((and (consp form) (eq (car form) 'methods))
1398          (cons '.methods.
1399                (get-effective-method-function1 generic-function (cadr form))))
1400         ((and (consp form) (eq (car form) 'unordered-methods))
1401          (default-secondary-dispatch-function generic-function))))
1402
1403 (defun convert-methods (constant method-alist wrappers)
1404   (if (and (consp constant)
1405            (eq (car constant) '.methods.))
1406       (funcall (cdr constant) method-alist wrappers)
1407       constant))
1408
1409 (defun convert-table (constant method-alist wrappers)
1410   (cond ((and (consp constant)
1411               (eq (car constant) :mcase))
1412          (let ((alist (mapcar (lambda (k+m)
1413                                 (cons (car k+m)
1414                                       (convert-methods (cdr k+m)
1415                                                        method-alist
1416                                                        wrappers)))
1417                               (cddr constant)))
1418                (mp (cadr constant)))
1419            (ecase (cadr mp)
1420              (:simple
1421               (car alist))
1422              (:assoc
1423               alist)
1424              (:hash-table
1425               (let ((table (make-hash-table :test (if (car mp) 'eq 'eql))))
1426                 (dolist (k+m alist)
1427                   (setf (gethash (car k+m) table) (cdr k+m)))
1428                 table)))))))
1429
1430 (defun compute-secondary-dispatch-function1 (generic-function net
1431                                              &optional function-p)
1432   (cond
1433    ((and (eq (car net) 'methods) (not function-p))
1434     (get-effective-method-function1 generic-function (cadr net)))
1435    (t
1436     (let* ((name (generic-function-name generic-function))
1437            (arg-info (gf-arg-info generic-function))
1438            (metatypes (arg-info-metatypes arg-info))
1439            (nargs (length metatypes))
1440            (applyp (arg-info-applyp arg-info))
1441            (fmc-arg-info (cons nargs applyp))
1442            (arglist (if function-p
1443                         (make-dfun-lambda-list nargs applyp)
1444                         (make-fast-method-call-lambda-list nargs applyp))))
1445       (multiple-value-bind (cfunction constants)
1446           (get-fun1 `(lambda
1447                       ,arglist
1448                       ,@(unless function-p
1449                           `((declare (ignore .pv. .next-method-call.))))
1450                       (locally (declare #.*optimize-speed*)
1451                                (let ((emf ,net))
1452                                  ,(make-emf-call nargs applyp 'emf))))
1453                     #'net-test-converter
1454                     #'net-code-converter
1455                     (lambda (form)
1456                       (net-constant-converter form generic-function)))
1457         (lambda (method-alist wrappers)
1458           (let* ((alist (list nil))
1459                  (alist-tail alist))
1460             (dolist (constant constants)
1461               (let* ((a (or (dolist (a alist nil)
1462                               (when (eq (car a) constant)
1463                                 (return a)))
1464                             (cons constant
1465                                   (or (convert-table
1466                                        constant method-alist wrappers)
1467                                       (convert-methods
1468                                        constant method-alist wrappers)))))
1469                      (new (list a)))
1470                 (setf (cdr alist-tail) new)
1471                 (setf alist-tail new)))
1472             (let ((function (apply cfunction (mapcar #'cdr (cdr alist)))))
1473               (if function-p
1474                   function
1475                   (make-fast-method-call
1476                    :function (set-fun-name function `(sdfun-method ,name))
1477                    :arg-info fmc-arg-info))))))))))
1478
1479 (defvar *show-make-unordered-methods-emf-calls* nil)
1480
1481 (defun make-unordered-methods-emf (generic-function methods)
1482   (when *show-make-unordered-methods-emf-calls*
1483     (format t "~&make-unordered-methods-emf ~S~%"
1484             (generic-function-name generic-function)))
1485   (lambda (&rest args)
1486     (let* ((types (types-from-args generic-function args 'eql))
1487            (smethods (sort-applicable-methods generic-function
1488                                               methods
1489                                               types))
1490            (emf (get-effective-method-function generic-function smethods)))
1491       (invoke-emf emf args))))
1492 \f
1493 ;;; The value returned by compute-discriminating-function is a function
1494 ;;; object. It is called a discriminating function because it is called
1495 ;;; when the generic function is called and its role is to discriminate
1496 ;;; on the arguments to the generic function and then call appropriate
1497 ;;; method functions.
1498 ;;;
1499 ;;; A discriminating function can only be called when it is installed as
1500 ;;; the funcallable instance function of the generic function for which
1501 ;;; it was computed.
1502 ;;;
1503 ;;; More precisely, if compute-discriminating-function is called with
1504 ;;; an argument <gf1>, and returns a result <df1>, that result must
1505 ;;; not be passed to apply or funcall directly. Rather, <df1> must be
1506 ;;; stored as the funcallable instance function of the same generic
1507 ;;; function <gf1> (using SET-FUNCALLABLE-INSTANCE-FUNCTION). Then the
1508 ;;; generic function can be passed to funcall or apply.
1509 ;;;
1510 ;;; An important exception is that methods on this generic function are
1511 ;;; permitted to return a function which itself ends up calling the value
1512 ;;; returned by a more specific method. This kind of `encapsulation' of
1513 ;;; discriminating function is critical to many uses of the MOP.
1514 ;;;
1515 ;;; As an example, the following canonical case is legal:
1516 ;;;
1517 ;;;   (defmethod compute-discriminating-function ((gf my-generic-function))
1518 ;;;     (let ((std (call-next-method)))
1519 ;;;       (lambda (arg)
1520 ;;;         (print (list 'call-to-gf gf arg))
1521 ;;;         (funcall std arg))))
1522 ;;;
1523 ;;; Because many discriminating functions would like to use a dynamic
1524 ;;; strategy in which the precise discriminating function changes with
1525 ;;; time it is important to specify how a discriminating function is
1526 ;;; permitted itself to change the funcallable instance function of the
1527 ;;; generic function.
1528 ;;;
1529 ;;; Discriminating functions may set the funcallable instance function
1530 ;;; of the generic function, but the new value must be generated by making
1531 ;;; a call to COMPUTE-DISCRIMINATING-FUNCTION. This is to ensure that any
1532 ;;; more specific methods which may have encapsulated the discriminating
1533 ;;; function will get a chance to encapsulate the new, inner discriminating
1534 ;;; function.
1535 ;;;
1536 ;;; This implies that if a discriminating function wants to modify itself
1537 ;;; it should first store some information in the generic function proper,
1538 ;;; and then call compute-discriminating-function. The appropriate method
1539 ;;; on compute-discriminating-function will see the information stored in
1540 ;;; the generic function and generate a discriminating function accordingly.
1541 ;;;
1542 ;;; The following is an example of a discriminating function which modifies
1543 ;;; itself in accordance with this protocol:
1544 ;;;
1545 ;;;   (defmethod compute-discriminating-function ((gf my-generic-function))
1546 ;;;     (lambda (arg)
1547 ;;;      (cond (<some condition>
1548 ;;;             <store some info in the generic function>
1549 ;;;             (set-funcallable-instance-function
1550 ;;;               gf
1551 ;;;               (compute-discriminating-function gf))
1552 ;;;             (funcall gf arg))
1553 ;;;            (t
1554 ;;;             <call-a-method-of-gf>))))
1555 ;;;
1556 ;;; Whereas this code would not be legal:
1557 ;;;
1558 ;;;   (defmethod compute-discriminating-function ((gf my-generic-function))
1559 ;;;     (lambda (arg)
1560 ;;;      (cond (<some condition>
1561 ;;;             (set-funcallable-instance-function
1562 ;;;               gf
1563 ;;;               (lambda (a) ..))
1564 ;;;             (funcall gf arg))
1565 ;;;            (t
1566 ;;;             <call-a-method-of-gf>))))
1567 ;;;
1568 ;;; NOTE:  All the examples above assume that all instances of the class
1569 ;;;     my-generic-function accept only one argument.
1570
1571 (defun slot-value-using-class-dfun (class object slotd)
1572   (declare (ignore class))
1573   (function-funcall (slot-definition-reader-function slotd) object))
1574
1575 (defun setf-slot-value-using-class-dfun (new-value class object slotd)
1576   (declare (ignore class))
1577   (function-funcall (slot-definition-writer-function slotd) new-value object))
1578
1579 (defun slot-boundp-using-class-dfun (class object slotd)
1580   (declare (ignore class))
1581   (function-funcall (slot-definition-boundp-function slotd) object))
1582
1583 (defun special-case-for-compute-discriminating-function-p (gf)
1584   (or (eq gf #'slot-value-using-class)
1585       (eq gf #'(setf slot-value-using-class))
1586       (eq gf #'slot-boundp-using-class)))
1587
1588 (let (initial-print-object-cache)
1589   (defmethod compute-discriminating-function ((gf standard-generic-function))
1590     (let ((dfun-state (slot-value gf 'dfun-state)))
1591       (when (special-case-for-compute-discriminating-function-p gf)
1592         ;; if we have a special case for
1593         ;; COMPUTE-DISCRIMINATING-FUNCTION, then (at least for the
1594         ;; special cases implemented as of 2006-05-09) any information
1595         ;; in the cache is misplaced.
1596         (aver (null dfun-state)))
1597       (typecase dfun-state
1598         (null
1599          (when (eq gf #'compute-applicable-methods)
1600            (update-all-c-a-m-gf-info gf))
1601          (cond
1602            ((eq gf #'slot-value-using-class)
1603             (update-slot-value-gf-info gf 'reader)
1604             #'slot-value-using-class-dfun)
1605            ((eq gf #'(setf slot-value-using-class))
1606             (update-slot-value-gf-info gf 'writer)
1607             #'setf-slot-value-using-class-dfun)
1608            ((eq gf #'slot-boundp-using-class)
1609             (update-slot-value-gf-info gf 'boundp)
1610             #'slot-boundp-using-class-dfun)
1611            ;; KLUDGE: PRINT-OBJECT is not a special-case in the sense
1612            ;; of having a desperately special discriminating function.
1613            ;; However, it is important that the machinery for printing
1614            ;; conditions for stack and heap exhaustion, and the
1615            ;; restarts offered by the debugger, work without consuming
1616            ;; many extra resources.  This way (testing by name of GF
1617            ;; rather than by identity) was the only way I found to get
1618            ;; this to bootstrap, given that the PRINT-OBJECT generic
1619            ;; function is only set up later, in
1620            ;; SRC;PCL;PRINT-OBJECT.LISP.  -- CSR, 2008-06-09
1621            ((eq (slot-value gf 'name) 'print-object)
1622             (let ((nkeys (nth-value 3 (get-generic-fun-info gf))))
1623               (cond ((/= nkeys 1)
1624                      ;; KLUDGE: someone has defined a method
1625                      ;; specialized on the second argument: punt.
1626                      (setf initial-print-object-cache nil)
1627                      (make-initial-dfun gf))
1628                     (initial-print-object-cache
1629                      (multiple-value-bind (dfun cache info)
1630                          (make-caching-dfun gf (copy-cache initial-print-object-cache))
1631                        (set-dfun gf dfun cache info)))
1632                     ;; the relevant PRINT-OBJECT methods get defined
1633                     ;; late, by delayed DEF!METHOD.  We mustn't cache
1634                     ;; the effective method for our classes earlier
1635                     ;; than the relevant PRINT-OBJECT methods are
1636                     ;; defined...
1637                     ((boundp 'sb-impl::*delayed-def!method-args*)
1638                      (make-initial-dfun gf))
1639                     (t (multiple-value-bind (dfun cache info)
1640                            (make-final-dfun-internal
1641                             gf
1642                             (mapcar (lambda (x) (list (find-class x)))
1643                                     '(sb-kernel::control-stack-exhausted
1644                                       sb-kernel::binding-stack-exhausted
1645                                       sb-kernel::alien-stack-exhausted
1646                                       sb-kernel::heap-exhausted-error
1647                                       restart)))
1648                          (setq initial-print-object-cache cache)
1649                          (set-dfun gf dfun (copy-cache cache) info))))))
1650            ((gf-precompute-dfun-and-emf-p (slot-value gf 'arg-info))
1651             (make-final-dfun gf))
1652            (t
1653             (make-initial-dfun gf))))
1654         (function dfun-state)
1655         (cons (car dfun-state))))))
1656 \f
1657 (defmethod (setf class-name) (new-value class)
1658   (let ((classoid (wrapper-classoid (class-wrapper class))))
1659     (if (and new-value (symbolp new-value))
1660         (setf (classoid-name classoid) new-value)
1661         (setf (classoid-name classoid) nil)))
1662   (reinitialize-instance class :name new-value)
1663   new-value)
1664
1665 (defmethod (setf generic-function-name) (new-value generic-function)
1666   (reinitialize-instance generic-function :name new-value)
1667   new-value)
1668 \f
1669 (defmethod function-keywords ((method standard-method))
1670   (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p
1671                         keywords)
1672       (analyze-lambda-list (if (consp method)
1673                                (early-method-lambda-list method)
1674                                (method-lambda-list method)))
1675     (declare (ignore nreq nopt keysp restp))
1676     (values keywords allow-other-keys-p)))
1677
1678 (defmethod function-keyword-parameters ((method standard-method))
1679   (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p
1680                         keywords keyword-parameters)
1681       (analyze-lambda-list (if (consp method)
1682                                (early-method-lambda-list method)
1683                                (method-lambda-list method)))
1684     (declare (ignore nreq nopt keysp restp keywords))
1685     (values keyword-parameters allow-other-keys-p)))
1686
1687 (defun method-ll->generic-function-ll (ll)
1688   (multiple-value-bind
1689       (nreq nopt keysp restp allow-other-keys-p keywords keyword-parameters)
1690       (analyze-lambda-list ll)
1691     (declare (ignore nreq nopt keysp restp allow-other-keys-p keywords))
1692     (remove-if (lambda (s)
1693                  (or (memq s keyword-parameters)
1694                      (eq s '&allow-other-keys)))
1695                ll)))
1696 \f
1697 ;;; This is based on the rules of method lambda list congruency
1698 ;;; defined in the spec. The lambda list it constructs is the pretty
1699 ;;; union of the lambda lists of the generic function and of all its
1700 ;;; methods.  It doesn't take method applicability into account at all
1701 ;;; yet.
1702
1703 ;;; (Notice that we ignore &AUX variables as they're not part of the
1704 ;;; "public interface" of a function.)
1705
1706 (defmethod generic-function-pretty-arglist
1707            ((generic-function standard-generic-function))
1708   (let ((gf-lambda-list (generic-function-lambda-list generic-function))
1709         (methods (generic-function-methods generic-function)))
1710     (if (null methods)
1711         gf-lambda-list
1712         (multiple-value-bind (gf.required gf.optional gf.rest gf.keys gf.allowp)
1713             (%split-arglist gf-lambda-list)
1714           ;; Possibly extend the keyword parameters of the gf by
1715           ;; additional key parameters of its methods:
1716           (let ((methods.keys nil) (methods.allowp nil))
1717             (dolist (m methods)
1718               (multiple-value-bind (m.keyparams m.allow-other-keys)
1719                   (function-keyword-parameters m)
1720                 (setq methods.keys (union methods.keys m.keyparams :key #'maybe-car))
1721                 (setq methods.allowp (or methods.allowp m.allow-other-keys))))
1722             (let ((arglist '()))
1723               (when (or gf.allowp methods.allowp)
1724                 (push '&allow-other-keys arglist))
1725               (when (or gf.keys methods.keys)
1726                 ;; We make sure that the keys of the gf appear before
1727                 ;; those of its methods, since they're probably more
1728                 ;; generally appliable.
1729                 (setq arglist (nconc (list '&key) gf.keys
1730                                      (nset-difference methods.keys gf.keys)
1731                                      arglist)))
1732               (when gf.rest
1733                 (setq arglist (nconc (list '&rest gf.rest) arglist)))
1734               (when gf.optional
1735                 (setq arglist (nconc (list '&optional) gf.optional arglist)))
1736               (nconc gf.required arglist)))))))
1737
1738 (defun maybe-car (thing)
1739   (if (listp thing)
1740       (car thing)
1741       thing))
1742
1743
1744 (defun %split-arglist (lambda-list)
1745   ;; This function serves to shrink the number of returned values of
1746   ;; PARSE-LAMBDA-LIST to something handier.
1747   (multiple-value-bind (required optional restp rest keyp keys allowp
1748                         auxp aux morep more-context more-count)
1749       (parse-lambda-list lambda-list)
1750     (declare (ignore restp keyp auxp aux morep))
1751     (declare (ignore more-context more-count))
1752     (values required optional rest keys allowp)))