src/pcl/methods.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26
  27 ;;; methods
  28 ;;;
  29 ;;; Methods themselves are simple inanimate objects. Most properties of
  30 ;;; methods are immutable, methods cannot be reinitialized. The following
  31 ;;; properties of methods can be changed:
  32 ;;;   METHOD-GENERIC-FUNCTION
  33 ;;;   METHOD-FUNCTION       ??
  34
  35 (defmethod method-function ((method standard-method))
  36   (or (slot-value method 'function)
  37       (let ((fmf (slot-value method 'fast-function)))
  38         (unless fmf ; The :BEFORE SHARED-INITIALIZE method prevents this.
  39           (error "~S doesn't seem to have a METHOD-FUNCTION." method))
  40         (setf (slot-value method 'function)
  41               (method-function-from-fast-function fmf)))))
  42
  43 (defmethod accessor-method-class ((method standard-accessor-method))
  44   (car (slot-value method 'specializers)))
  45
  46 (defmethod accessor-method-class ((method standard-writer-method))
  47   (cadr (slot-value method 'specializers)))
  48
  49 ;;; initialization
  50 ;;;
  51 ;;; Error checking is done in before methods. Because of the simplicity of
  52 ;;; standard method objects the standard primary method can fill the slots.
  53 ;;;
  54 ;;; Methods are not reinitializable.
  55
  56 (defmethod reinitialize-instance ((method standard-method) &rest initargs)
  57   (declare (ignore initargs))
  58   (error "An attempt was made to reinitialize the method ~S.~%~
  59           Method objects cannot be reinitialized."
  60          method))
  61
  62 (defmethod legal-documentation-p ((object standard-method) x)
  63   (if (or (null x) (stringp x))
  64       t
  65       "a string or NULL"))
  66
  67 (defmethod legal-lambda-list-p ((object standard-method) x)
  68   (declare (ignore x))
  69   t)
  70
  71 (defmethod legal-method-function-p ((object standard-method) x)
  72   (if (functionp x)
  73       t
  74       "a function"))
  75
  76 (defmethod legal-qualifiers-p ((object standard-method) x)
  77   (flet ((improper-list ()
  78            (return-from legal-qualifiers-p "Is not a proper list.")))
  79     (dolist-carefully (q x improper-list)
  80       (let ((ok (legal-qualifier-p object q)))
  81         (unless (eq ok t)
  82           (return-from legal-qualifiers-p
  83             (format nil "Contains ~S which ~A" q ok)))))
  84     t))
  85
  86 (defmethod legal-qualifier-p ((object standard-method) x)
  87   (if (and x (atom x))
  88       t
  89       "is not a non-null atom"))
  90
  91 (defmethod legal-slot-name-p ((object standard-method) x)
  92   (cond ((not (symbolp x)) "is not a symbol")
  93         (t t)))
  94
  95 (defmethod legal-specializers-p ((object standard-method) x)
  96   (flet ((improper-list ()
  97            (return-from legal-specializers-p "Is not a proper list.")))
  98     (dolist-carefully (s x improper-list)
  99       (let ((ok (legal-specializer-p object s)))
 100         (unless (eq ok t)
 101           (return-from legal-specializers-p
 102             (format nil "Contains ~S which ~A" s ok)))))
 103     t))
 104
 105 (defvar *allow-experimental-specializers-p* nil)
 106
 107 (defmethod legal-specializer-p ((object standard-method) x)
 108   (if (if *allow-experimental-specializers-p*
 109           (specializerp x)
 110           (or (classp x)
 111               (eql-specializer-p x)))
 112       t
 113       "is neither a class object nor an EQL specializer"))
 114
 115 (defmethod shared-initialize :before ((method standard-method)
 116                                       slot-names
 117                                       &key qualifiers
 118                                            lambda-list
 119                                            specializers
 120                                            function
 121                                            fast-function
 122                                            documentation)
 123   (declare (ignore slot-names))
 124   (flet ((lose (initarg value string)
 125            (error "when initializing the method ~S:~%~
 126                    The ~S initialization argument was: ~S.~%~
 127                    which ~A."
 128                   method initarg value string)))
 129     (let ((check-qualifiers    (legal-qualifiers-p method qualifiers))
 130           (check-lambda-list   (legal-lambda-list-p method lambda-list))
 131           (check-specializers  (legal-specializers-p method specializers))
 132           (check-fun (legal-method-function-p method
 133                                               (or function
 134                                                   fast-function)))
 135           (check-documentation (legal-documentation-p method documentation)))
 136       (unless (eq check-qualifiers t)
 137         (lose :qualifiers qualifiers check-qualifiers))
 138       (unless (eq check-lambda-list t)
 139         (lose :lambda-list lambda-list check-lambda-list))
 140       (unless (eq check-specializers t)
 141         (lose :specializers specializers check-specializers))
 142       (unless (eq check-fun t)
 143         (lose :function function check-fun))
 144       (unless (eq check-documentation t)
 145         (lose :documentation documentation check-documentation)))))
 146
 147 (defmethod shared-initialize :before ((method standard-accessor-method)
 148                                       slot-names
 149                                       &key slot-name slot-definition)
 150   (declare (ignore slot-names))
 151   (unless slot-definition
 152     (let ((legalp (legal-slot-name-p method slot-name)))
 153       ;; FIXME: nasty convention; should be renamed to ILLEGAL-SLOT-NAME-P and
 154       ;; ILLEGALP, and the convention redone to be less twisty
 155       (unless (eq legalp t)
 156         (error "The value of the :SLOT-NAME initarg ~A." legalp)))))
 157
 158 (defmethod shared-initialize :after ((method standard-method) slot-names
 159                                      &rest initargs
 160                                      &key qualifiers method-spec plist)
 161   (declare (ignore slot-names method-spec plist))
 162   (initialize-method-function initargs nil method)
 163   (setf (plist-value method 'qualifiers) qualifiers)
 164   #+ignore
 165   (setf (slot-value method 'closure-generator)
 166         (method-function-closure-generator (slot-value method 'function))))
 167
 168 (defmethod shared-initialize :after ((method standard-accessor-method)
 169                                      slot-names
 170                                      &key)
 171   (declare (ignore slot-names))
 172   (with-slots (slot-name slot-definition)
 173     method
 174     (unless slot-definition
 175       (let ((class (accessor-method-class method)))
 176         (when (slot-class-p class)
 177           (setq slot-definition (find slot-name (class-direct-slots class)
 178                                       :key #'slot-definition-name)))))
 179     (when (and slot-definition (null slot-name))
 180       (setq slot-name (slot-definition-name slot-definition)))))
 181
 182 (defmethod method-qualifiers ((method standard-method))
 183   (plist-value method 'qualifiers))
 184 \f
 185 (defvar *the-class-generic-function*
 186   (find-class 'generic-function))
 187 (defvar *the-class-standard-generic-function*
 188   (find-class 'standard-generic-function))
 189 \f
 190 (defmethod shared-initialize :before
 191            ((generic-function standard-generic-function)
 192             slot-names
 193             &key (name nil namep)
 194                  (lambda-list () lambda-list-p)
 195                  argument-precedence-order
 196                  declarations
 197                  documentation
 198                  (method-class nil method-class-supplied-p)
 199                  (method-combination nil method-combination-supplied-p))
 200   (declare (ignore slot-names
 201                    declarations argument-precedence-order documentation
 202                    lambda-list lambda-list-p))
 203
 204   (when namep
 205     (set-fun-name generic-function name))
 206
 207   (flet ((initarg-error (initarg value string)
 208            (error "when initializing the generic function ~S:~%~
 209                    The ~S initialization argument was: ~A.~%~
 210                    It must be ~A."
 211                   generic-function initarg value string)))
 212     (cond (method-class-supplied-p
 213            (when (symbolp method-class)
 214              (setq method-class (find-class method-class)))
 215            (unless (and (classp method-class)
 216                         (*subtypep (class-eq-specializer method-class)
 217                                    *the-class-method*))
 218              (initarg-error :method-class
 219                             method-class
 220                             "a subclass of the class METHOD"))
 221            (setf (slot-value generic-function 'method-class) method-class))
 222           ((slot-boundp generic-function 'method-class))
 223           (t
 224            (initarg-error :method-class
 225                           "not supplied"
 226                           "a subclass of the class METHOD")))
 227     (cond (method-combination-supplied-p
 228            (unless (method-combination-p method-combination)
 229              (initarg-error :method-combination
 230                             method-combination
 231                             "a method combination object")))
 232           ((slot-boundp generic-function 'method-combination))
 233           (t
 234            (initarg-error :method-combination
 235                           "not supplied"
 236                           "a method combination object")))))
 237
 238 #||
 239 (defmethod reinitialize-instance ((generic-function standard-generic-function)
 240                                   &rest initargs
 241                                   &key name
 242                                        lambda-list
 243                                        argument-precedence-order
 244                                        declarations
 245                                        documentation
 246                                        method-class
 247                                        method-combination)
 248   (declare (ignore documentation declarations argument-precedence-order
 249                    lambda-list name method-class method-combination))
 250   (macrolet ((add-initarg (check name slot-name)
 251                `(unless ,check
 252                   (push (slot-value generic-function ,slot-name) initargs)
 253                   (push ,name initargs))))
 254 ;   (add-initarg name :name 'name)
 255 ;   (add-initarg lambda-list :lambda-list 'lambda-list)
 256 ;   (add-initarg argument-precedence-order
 257 ;                :argument-precedence-order
 258 ;                'argument-precedence-order)
 259 ;   (add-initarg declarations :declarations 'declarations)
 260 ;   (add-initarg documentation :documentation 'documentation)
 261 ;   (add-initarg method-class :method-class 'method-class)
 262 ;   (add-initarg method-combination :method-combination 'method-combination)
 263     (apply #'call-next-method generic-function initargs)))
 264 ||#
 265 \f
 266 ;;; These two are scheduled for demolition.
 267 (defun real-add-named-method (generic-function-name
 268                               qualifiers
 269                               specializers
 270                               lambda-list
 271                               &rest other-initargs)
 272   (unless (and (fboundp generic-function-name)
 273                (typep (fdefinition generic-function-name) 'generic-function))
 274     (style-warn "implicitly creating new generic function ~S"
 275                 generic-function-name))
 276   ;; XXX What about changing the class of the generic function if
 277   ;; there is one? Whose job is that, anyway? Do we need something
 278   ;; kind of like CLASS-FOR-REDEFINITION?
 279   (let* ((generic-function
 280            (ensure-generic-function generic-function-name))
 281          (specs (parse-specializers specializers))
 282          (proto (method-prototype-for-gf generic-function-name))
 283          (new (apply #'make-instance (class-of proto)
 284                                      :qualifiers qualifiers
 285                                      :specializers specs
 286                                      :lambda-list lambda-list
 287                                      other-initargs)))
 288     (add-method generic-function new)
 289     new))
 290
 291 (define-condition find-method-length-mismatch
 292     (reference-condition simple-error)
 293   ()
 294   (:default-initargs :references (list '(:ansi-cl :function find-method))))
 295
 296 (defun real-get-method (generic-function qualifiers specializers
 297                         &optional (errorp t)
 298                         always-check-specializers)
 299   (let ((lspec (length specializers))
 300         (methods (generic-function-methods generic-function)))
 301     (when (or methods always-check-specializers)
 302       (let ((nreq (length (arg-info-metatypes (gf-arg-info
 303                                                generic-function)))))
 304         ;; Since we internally bypass FIND-METHOD by using GET-METHOD
 305         ;; instead we need to to this here or users may get hit by a
 306         ;; failed AVER instead of a sensible error message.
 307         (when (/= lspec nreq)
 308           (error
 309            'find-method-length-mismatch
 310            :format-control
 311            "~@<The generic function ~S takes ~D required argument~:P; ~
 312             was asked to find a method with specializers ~S~@:>"
 313            :format-arguments (list generic-function nreq specializers)))))
 314     (let ((hit
 315            (dolist (method methods)
 316              (let ((mspecializers (method-specializers method)))
 317                (aver (= lspec (length mspecializers)))
 318                (when (and (equal qualifiers (method-qualifiers method))
 319                           (every #'same-specializer-p specializers
 320                                  (method-specializers method)))
 321                  (return method))))))
 322       (cond (hit hit)
 323             ((null errorp) nil)
 324             (t
 325              (error "~@<There is no method on ~S with ~
 326                     ~:[no qualifiers~;~:*qualifiers ~S~] ~
 327                     and specializers ~S.~@:>"
 328                     generic-function qualifiers specializers))))))
 329
 330 (defmethod find-method ((generic-function standard-generic-function)
 331                         qualifiers specializers &optional (errorp t))
 332   ;; ANSI about FIND-METHOD: "The specializers argument contains the
 333   ;; parameter specializers for the method. It must correspond in
 334   ;; length to the number of required arguments of the generic
 335   ;; function, or an error is signaled."
 336   ;;
 337   ;; This error checking is done by REAL-GET-METHOD.
 338   (real-get-method generic-function
 339                    qualifiers
 340                    (parse-specializers specializers)
 341                    errorp
 342                    t))
 343 \f
 344 ;;; Compute various information about a generic-function's arglist by looking
 345 ;;; at the argument lists of the methods. The hair for trying not to use
 346 ;;; &REST arguments lives here.
 347 ;;;  The values returned are:
 348 ;;;    number-of-required-arguments
 349 ;;;       the number of required arguments to this generic-function's
 350 ;;;       discriminating function
 351 ;;;    &rest-argument-p
 352 ;;;       whether or not this generic-function's discriminating
 353 ;;;       function takes an &rest argument.
 354 ;;;    specialized-argument-positions
 355 ;;;       a list of the positions of the arguments this generic-function
 356 ;;;       specializes (e.g. for a classical generic-function this is the
 357 ;;;       list: (1)).
 358 (defmethod compute-discriminating-function-arglist-info
 359            ((generic-function standard-generic-function))
 360   ;;(declare (values number-of-required-arguments &rest-argument-p
 361   ;;             specialized-argument-postions))
 362   (let ((number-required nil)
 363         (restp nil)
 364         (specialized-positions ())
 365         (methods (generic-function-methods generic-function)))
 366     (dolist (method methods)
 367       (multiple-value-setq (number-required restp specialized-positions)
 368         (compute-discriminating-function-arglist-info-internal
 369          generic-function method number-required restp specialized-positions)))
 370     (values number-required restp (sort specialized-positions #'<))))
 371
 372 (defun compute-discriminating-function-arglist-info-internal
 373        (generic-function method number-of-requireds restp
 374         specialized-argument-positions)
 375   (declare (ignore generic-function)
 376            (type (or null fixnum) number-of-requireds))
 377   (let ((requireds 0))
 378     (declare (fixnum requireds))
 379     ;; Go through this methods arguments seeing how many are required,
 380     ;; and whether there is an &rest argument.
 381     (dolist (arg (method-lambda-list method))
 382       (cond ((eq arg '&aux) (return))
 383             ((memq arg '(&optional &rest &key))
 384              (return (setq restp t)))
 385             ((memq arg lambda-list-keywords))
 386             (t (incf requireds))))
 387     ;; Now go through this method's type specifiers to see which
 388     ;; argument positions are type specified. Treat T specially
 389     ;; in the usual sort of way. For efficiency don't bother to
 390     ;; keep specialized-argument-positions sorted, rather depend
 391     ;; on our caller to do that.
 392     (let ((pos 0))
 393       (dolist (type-spec (method-specializers method))
 394         (unless (eq type-spec *the-class-t*)
 395           (pushnew pos specialized-argument-positions))
 396         (incf pos)))
 397     ;; Finally merge the values for this method into the values
 398     ;; for the exisiting methods and return them. Note that if
 399     ;; num-of-requireds is NIL it means this is the first method
 400     ;; and we depend on that.
 401     (values (min (or number-of-requireds requireds) requireds)
 402             (or restp
 403                 (and number-of-requireds (/= number-of-requireds requireds)))
 404             specialized-argument-positions)))
 405
 406 (defun make-discriminating-function-arglist (number-required-arguments restp)
 407   (nconc (let ((args nil))
 408            (dotimes (i number-required-arguments)
 409              (push (format-symbol *package* ;; ! is this right?
 410                                   "Discriminating Function Arg ~D"
 411                                   i)
 412                    args))
 413            (nreverse args))
 414          (when restp
 415                `(&rest ,(format-symbol *package*
 416                                        "Discriminating Function &rest Arg")))))
 417 \f
 418 (defmethod generic-function-argument-precedence-order
 419     ((gf standard-generic-function))
 420   (aver (eq *boot-state* 'complete))
 421   (loop with arg-info = (gf-arg-info gf)
 422         with lambda-list = (arg-info-lambda-list arg-info)
 423         for argument-position in (arg-info-precedence arg-info)
 424         collect (nth argument-position lambda-list)))
 425
 426 (defmethod generic-function-lambda-list ((gf generic-function))
 427   (gf-lambda-list gf))
 428
 429 (defmethod gf-fast-method-function-p ((gf standard-generic-function))
 430   (gf-info-fast-mf-p (slot-value gf 'arg-info)))
 431
 432 (defmethod initialize-instance :after ((gf standard-generic-function)
 433                                        &key (lambda-list nil lambda-list-p)
 434                                        argument-precedence-order)
 435   (with-slots (arg-info) gf
 436     (if lambda-list-p
 437         (set-arg-info gf
 438                       :lambda-list lambda-list
 439                       :argument-precedence-order argument-precedence-order)
 440         (set-arg-info gf))
 441     (when (arg-info-valid-p arg-info)
 442       (update-dfun gf))))
 443
 444 (defmethod reinitialize-instance :around
 445     ((gf standard-generic-function) &rest args &key
 446      (lambda-list nil lambda-list-p) (argument-precedence-order nil apo-p))
 447   (let ((old-mc (generic-function-method-combination gf)))
 448     (prog1 (call-next-method)
 449       ;; KLUDGE: EQ is too strong a test.
 450       (unless (eq old-mc (generic-function-method-combination gf))
 451         (flush-effective-method-cache gf))
 452       (cond
 453         ((and lambda-list-p apo-p)
 454          (set-arg-info gf
 455                        :lambda-list lambda-list
 456                        :argument-precedence-order argument-precedence-order))
 457         (lambda-list-p (set-arg-info gf :lambda-list lambda-list))
 458         (t (set-arg-info gf)))
 459       (when (and (arg-info-valid-p (gf-arg-info gf))
 460                  (not (null args))
 461                  (or lambda-list-p (cddr args)))
 462         (update-dfun gf)))))
 463
 464 (declaim (special *lazy-dfun-compute-p*))
 465
 466 (defun set-methods (gf methods)
 467   (setf (generic-function-methods gf) nil)
 468   (loop (when (null methods) (return gf))
 469         (real-add-method gf (pop methods) methods)))
 470
 471 (defun real-add-method (generic-function method &optional skip-dfun-update-p)
 472   (when (method-generic-function method)
 473     (error "~@<The method ~S is already part of the generic ~
 474             function ~S; it can't be added to another generic ~
 475             function until it is removed from the first one.~@:>"
 476            method (method-generic-function method)))
 477   (flet ((similar-lambda-lists-p (method-a method-b)
 478            (multiple-value-bind (a-nreq a-nopt a-keyp a-restp)
 479                (analyze-lambda-list (method-lambda-list method-a))
 480              (multiple-value-bind (b-nreq b-nopt b-keyp b-restp)
 481                  (analyze-lambda-list (method-lambda-list method-b))
 482                (and (= a-nreq b-nreq)
 483                     (= a-nopt b-nopt)
 484                     (eq (or a-keyp a-restp)
 485                         (or b-keyp b-restp)))))))
 486       (let* ((name (generic-function-name generic-function))
 487              (qualifiers (method-qualifiers method))
 488              (specializers (method-specializers method))
 489              (existing (get-method generic-function
 490                                    qualifiers
 491                                    specializers
 492                                    nil)))
 493
 494         ;; If there is already a method like this one then we must get
 495         ;; rid of it before proceeding.  Note that we call the generic
 496         ;; function REMOVE-METHOD to remove it rather than doing it in
 497         ;; some internal way.
 498         (when (and existing (similar-lambda-lists-p existing method))
 499           (remove-method generic-function existing))
 500
 501         (setf (method-generic-function method) generic-function)
 502         (pushnew method (generic-function-methods generic-function))
 503         (dolist (specializer specializers)
 504           (add-direct-method specializer method))
 505
 506         ;; KLUDGE: SET-ARG-INFO contains the error-detecting logic for
 507         ;; detecting attempts to add methods with incongruent lambda
 508         ;; lists.  However, according to Gerd Moellmann on cmucl-imp,
 509         ;; it also depends on the new method already having been added
 510         ;; to the generic function.  Therefore, we need to remove it
 511         ;; again on error:
 512         (let ((remove-again-p t))
 513           (unwind-protect
 514                (progn
 515                  (set-arg-info generic-function :new-method method)
 516                  (setq remove-again-p nil))
 517             (when remove-again-p
 518               (remove-method generic-function method))))
 519
 520         ;; KLUDGE II: ANSI saith that it is not an error to add a
 521         ;; method with invalid qualifiers to a generic function of the
 522         ;; wrong kind; it's only an error at generic function
 523         ;; invocation time; I dunno what the rationale was, and it
 524         ;; sucks.  Nevertheless, it's probably a programmer error, so
 525         ;; let's warn anyway. -- CSR, 2003-08-20
 526         (let ((mc (generic-function-method-combination generic-functioN)))
 527           (cond
 528             ((eq mc *standard-method-combination*)
 529              (when (and qualifiers
 530                         (or (cdr qualifiers)
 531                             (not (memq (car qualifiers)
 532                                        '(:around :before :after)))))
 533                (warn "~@<Invalid qualifiers for standard method combination ~
 534                       in method ~S:~2I~_~S.~@:>"
 535                      method qualifiers)))
 536             ((short-method-combination-p mc)
 537              (let ((mc-name (method-combination-type mc)))
 538                (when (or (null qualifiers)
 539                          (cdr qualifiers)
 540                          (and (neq (car qualifiers) :around)
 541                               (neq (car qualifiers) mc-name)))
 542                  (warn "~@<Invalid qualifiers for ~S method combination ~
 543                         in method ~S:~2I~_~S.~@:>"
 544                        mc-name method qualifiers))))))
 545
 546         (unless skip-dfun-update-p
 547           (update-ctors 'add-method
 548                         :generic-function generic-function
 549                         :method method)
 550           (update-dfun generic-function))
 551         generic-function)))
 552
 553 (defun real-remove-method (generic-function method)
 554   (when  (eq generic-function (method-generic-function method))
 555     (let* ((name (generic-function-name generic-function))
 556            (specializers (method-specializers method))
 557            (methods (generic-function-methods generic-function))
 558            (new-methods (remove method methods)))
 559       (setf (method-generic-function method) nil)
 560       (setf (generic-function-methods generic-function) new-methods)
 561       (dolist (specializer (method-specializers method))
 562         (remove-direct-method specializer method))
 563       (set-arg-info generic-function)
 564       (update-ctors 'remove-method
 565                     :generic-function generic-function
 566                     :method method)
 567       (update-dfun generic-function)))
 568   generic-function)
 569 \f
 570 (defun compute-applicable-methods-function (generic-function arguments)
 571   (values (compute-applicable-methods-using-types
 572            generic-function
 573            (types-from-args generic-function arguments 'eql))))
 574
 575 (defmethod compute-applicable-methods
 576     ((generic-function generic-function) arguments)
 577   (values (compute-applicable-methods-using-types
 578            generic-function
 579            (types-from-args generic-function arguments 'eql))))
 580
 581 (defmethod compute-applicable-methods-using-classes
 582     ((generic-function generic-function) classes)
 583   (compute-applicable-methods-using-types
 584    generic-function
 585    (types-from-args generic-function classes 'class-eq)))
 586
 587 (defun proclaim-incompatible-superclasses (classes)
 588   (setq classes (mapcar (lambda (class)
 589                           (if (symbolp class)
 590                               (find-class class)
 591                               class))
 592                         classes))
 593   (dolist (class classes)
 594     (dolist (other-class classes)
 595       (unless (eq class other-class)
 596         (pushnew other-class (class-incompatible-superclass-list class))))))
 597
 598 (defun superclasses-compatible-p (class1 class2)
 599   (let ((cpl1 (cpl-or-nil class1))
 600         (cpl2 (cpl-or-nil class2)))
 601     (dolist (sc1 cpl1 t)
 602       (dolist (ic (class-incompatible-superclass-list sc1))
 603         (when (memq ic cpl2)
 604           (return-from superclasses-compatible-p nil))))))
 605
 606 (mapc
 607  #'proclaim-incompatible-superclasses
 608  '(;; superclass class
 609    (built-in-class std-class structure-class) ; direct subclasses of pcl-class
 610    (standard-class funcallable-standard-class)
 611    ;; superclass metaobject
 612    (class eql-specializer class-eq-specializer method method-combination
 613     generic-function slot-definition)
 614    ;; metaclass built-in-class
 615    (number sequence character           ; direct subclasses of t, but not array
 616     standard-object structure-object)   ;                        or symbol
 617    (number array character symbol       ; direct subclasses of t, but not
 618     standard-object structure-object)   ;                        sequence
 619    (complex float rational)             ; direct subclasses of number
 620    (integer ratio)                      ; direct subclasses of rational
 621    (list vector)                        ; direct subclasses of sequence
 622    (cons null)                          ; direct subclasses of list
 623    (string bit-vector)                  ; direct subclasses of vector
 624    ))
 625 \f
 626 (defmethod same-specializer-p ((specl1 specializer) (specl2 specializer))
 627   nil)
 628
 629 (defmethod same-specializer-p ((specl1 class) (specl2 class))
 630   (eq specl1 specl2))
 631
 632 (defmethod specializer-class ((specializer class))
 633   specializer)
 634
 635 (defmethod same-specializer-p ((specl1 class-eq-specializer)
 636                                (specl2 class-eq-specializer))
 637   (eq (specializer-class specl1) (specializer-class specl2)))
 638
 639 (defmethod same-specializer-p ((specl1 eql-specializer)
 640                                (specl2 eql-specializer))
 641   (eq (specializer-object specl1) (specializer-object specl2)))
 642
 643 (defmethod specializer-class ((specializer eql-specializer))
 644   (class-of (slot-value specializer 'object)))
 645
 646 (defvar *in-gf-arg-info-p* nil)
 647 (setf (gdefinition 'arg-info-reader)
 648       (let ((mf (initialize-method-function
 649                  (make-internal-reader-method-function
 650                   'standard-generic-function 'arg-info)
 651                  t)))
 652         (lambda (&rest args) (funcall mf args nil))))
 653
 654
 655 (defun error-need-at-least-n-args (function n)
 656   (error 'simple-program-error
 657          :format-control "~@<The function ~2I~_~S ~I~_requires ~
 658                           at least ~W argument~:P.~:>"
 659          :format-arguments (list function n)))
 660
 661 (defun types-from-args (generic-function arguments &optional type-modifier)
 662   (multiple-value-bind (nreq applyp metatypes nkeys arg-info)
 663       (get-generic-fun-info generic-function)
 664     (declare (ignore applyp metatypes nkeys))
 665     (let ((types-rev nil))
 666       (dotimes-fixnum (i nreq)
 667         i
 668         (unless arguments
 669           (error-need-at-least-n-args (generic-function-name generic-function)
 670                                       nreq))
 671         (let ((arg (pop arguments)))
 672           (push (if type-modifier `(,type-modifier ,arg) arg) types-rev)))
 673       (values (nreverse types-rev) arg-info))))
 674
 675 (defun get-wrappers-from-classes (nkeys wrappers classes metatypes)
 676   (let* ((w wrappers) (w-tail w) (mt-tail metatypes))
 677     (dolist (class (if (listp classes) classes (list classes)))
 678       (unless (eq t (car mt-tail))
 679         (let ((c-w (class-wrapper class)))
 680           (unless c-w (return-from get-wrappers-from-classes nil))
 681           (if (eql nkeys 1)
 682               (setq w c-w)
 683               (setf (car w-tail) c-w
 684                     w-tail (cdr w-tail)))))
 685       (setq mt-tail (cdr mt-tail)))
 686     w))
 687
 688 (defun sdfun-for-caching (gf classes)
 689   (let ((types (mapcar #'class-eq-type classes)))
 690     (multiple-value-bind (methods all-applicable-and-sorted-p)
 691         (compute-applicable-methods-using-types gf types)
 692       (let ((generator (get-secondary-dispatch-function1
 693                         gf methods types nil t all-applicable-and-sorted-p)))
 694         (make-callable gf methods generator
 695                        nil (mapcar #'class-wrapper classes))))))
 696
 697 (defun value-for-caching (gf classes)
 698   (let ((methods (compute-applicable-methods-using-types
 699                    gf (mapcar #'class-eq-type classes))))
 700     (method-function-get (or (method-fast-function (car methods))
 701                              (method-function (car methods)))
 702                          :constant-value)))
 703
 704 (defun default-secondary-dispatch-function (generic-function)
 705   (lambda (&rest args)
 706     (let ((methods (compute-applicable-methods generic-function args)))
 707       (if methods
 708           (let ((emf (get-effective-method-function generic-function
 709                                                     methods)))
 710             (invoke-emf emf args))
 711           (apply #'no-applicable-method generic-function args)))))
 712
 713 (defun list-eq (x y)
 714   (loop (when (atom x) (return (eq x y)))
 715         (when (atom y) (return nil))
 716         (unless (eq (car x) (car y)) (return nil))
 717         (setq x (cdr x)
 718               y (cdr y))))
 719
 720 (defvar *std-cam-methods* nil)
 721
 722 (defun compute-applicable-methods-emf (generic-function)
 723   (if (eq *boot-state* 'complete)
 724       (let* ((cam (gdefinition 'compute-applicable-methods))
 725              (cam-methods (compute-applicable-methods-using-types
 726                            cam (list `(eql ,generic-function) t))))
 727         (values (get-effective-method-function cam cam-methods)
 728                 (list-eq cam-methods
 729                          (or *std-cam-methods*
 730                              (setq *std-cam-methods*
 731                                    (compute-applicable-methods-using-types
 732                                     cam (list `(eql ,cam) t)))))))
 733       (values #'compute-applicable-methods-function t)))
 734
 735 (defun compute-applicable-methods-emf-std-p (gf)
 736   (gf-info-c-a-m-emf-std-p (gf-arg-info gf)))
 737
 738 (defvar *old-c-a-m-gf-methods* nil)
 739
 740 (defun update-all-c-a-m-gf-info (c-a-m-gf)
 741   (let ((methods (generic-function-methods c-a-m-gf)))
 742     (if (and *old-c-a-m-gf-methods*
 743              (every (lambda (old-method)
 744                       (member old-method methods))
 745                     *old-c-a-m-gf-methods*))
 746         (let ((gfs-to-do nil)
 747               (gf-classes-to-do nil))
 748           (dolist (method methods)
 749             (unless (member method *old-c-a-m-gf-methods*)
 750               (let ((specl (car (method-specializers method))))
 751                 (if (eql-specializer-p specl)
 752                     (pushnew (specializer-object specl) gfs-to-do)
 753                     (pushnew (specializer-class specl) gf-classes-to-do)))))
 754           (map-all-generic-functions
 755            (lambda (gf)
 756              (when (or (member gf gfs-to-do)
 757                        (dolist (class gf-classes-to-do nil)
 758                          (member class
 759                                  (class-precedence-list (class-of gf)))))
 760                (update-c-a-m-gf-info gf)))))
 761         (map-all-generic-functions #'update-c-a-m-gf-info))
 762     (setq *old-c-a-m-gf-methods* methods)))
 763
 764 (defun update-gf-info (gf)
 765   (update-c-a-m-gf-info gf)
 766   (update-gf-simple-accessor-type gf))
 767
 768 (defun update-c-a-m-gf-info (gf)
 769   (unless (early-gf-p gf)
 770     (multiple-value-bind (c-a-m-emf std-p)
 771         (compute-applicable-methods-emf gf)
 772       (let ((arg-info (gf-arg-info gf)))
 773         (setf (gf-info-static-c-a-m-emf arg-info) c-a-m-emf)
 774         (setf (gf-info-c-a-m-emf-std-p arg-info) std-p)))))
 775
 776 (defun update-gf-simple-accessor-type (gf)
 777   (let ((arg-info (gf-arg-info gf)))
 778     (setf (gf-info-simple-accessor-type arg-info)
 779           (let* ((methods (generic-function-methods gf))
 780                  (class (and methods (class-of (car methods))))
 781                  (type (and class
 782                             (cond ((eq class
 783                                        *the-class-standard-reader-method*)
 784                                    'reader)
 785                                   ((eq class
 786                                        *the-class-standard-writer-method*)
 787                                    'writer)
 788                                   ((eq class
 789                                        *the-class-standard-boundp-method*)
 790                                    'boundp)))))
 791             (when (and (gf-info-c-a-m-emf-std-p arg-info)
 792                        type
 793                        (dolist (method (cdr methods) t)
 794                          (unless (eq class (class-of method)) (return nil)))
 795                        (eq (generic-function-method-combination gf)
 796                            *standard-method-combination*))
 797               type)))))
 798
 799
 800 ;;; CMUCL (Gerd's PCL, 2002-04-25) comment:
 801 ;;;
 802 ;;; Return two values.  First value is a function to be stored in
 803 ;;; effective slot definition SLOTD for reading it with
 804 ;;; SLOT-VALUE-USING-CLASS, setting it with (SETF
 805 ;;; SLOT-VALUE-USING-CLASS) or testing it with
 806 ;;; SLOT-BOUNDP-USING-CLASS.  GF is one of these generic functions,
 807 ;;; TYPE is one of the symbols READER, WRITER, BOUNDP.  CLASS is
 808 ;;; SLOTD's class.
 809 ;;;
 810 ;;; Second value is true if the function returned is one of the
 811 ;;; optimized standard functions for the purpose, which are used
 812 ;;; when only standard methods are applicable.
 813 ;;;
 814 ;;; FIXME: Change all these wacky function names to something sane.
 815 (defun get-accessor-method-function (gf type class slotd)
 816   (let* ((std-method (standard-svuc-method type))
 817          (str-method (structure-svuc-method type))
 818          (types1 `((eql ,class) (class-eq ,class) (eql ,slotd)))
 819          (types (if (eq type 'writer) `(t ,@types1) types1))
 820          (methods (compute-applicable-methods-using-types gf types))
 821          (std-p (null (cdr methods))))
 822     (values
 823      (if std-p
 824          (get-optimized-std-accessor-method-function class slotd type)
 825          (let* ((optimized-std-fun
 826                  (get-optimized-std-slot-value-using-class-method-function
 827                   class slotd type))
 828                 (method-alist
 829                  `((,(car (or (member std-method methods)
 830                               (member str-method methods)
 831                               (bug "error in ~S"
 832                                    'get-accessor-method-function)))
 833                     ,optimized-std-fun)))
 834                 (wrappers
 835                  (let ((wrappers (list (wrapper-of class)
 836                                        (class-wrapper class)
 837                                        (wrapper-of slotd))))
 838                    (if (eq type 'writer)
 839                        (cons (class-wrapper *the-class-t*) wrappers)
 840                        wrappers)))
 841                 (sdfun (get-secondary-dispatch-function
 842                         gf methods types method-alist wrappers)))
 843            (get-accessor-from-svuc-method-function class slotd sdfun type)))
 844      std-p)))
 845
 846 ;;; used by OPTIMIZE-SLOT-VALUE-BY-CLASS-P (vector.lisp)
 847 (defun update-slot-value-gf-info (gf type)
 848   (unless *new-class*
 849     (update-std-or-str-methods gf type))
 850   (when (and (standard-svuc-method type) (structure-svuc-method type))
 851     (flet ((update-class (class)
 852              (when (class-finalized-p class)
 853                (dolist (slotd (class-slots class))
 854                  (compute-slot-accessor-info slotd type gf)))))
 855       (if *new-class*
 856           (update-class *new-class*)
 857           (map-all-classes #'update-class 'slot-object)))))
 858
 859 (defvar *standard-slot-value-using-class-method* nil)
 860 (defvar *standard-setf-slot-value-using-class-method* nil)
 861 (defvar *standard-slot-boundp-using-class-method* nil)
 862 (defvar *condition-slot-value-using-class-method* nil)
 863 (defvar *condition-setf-slot-value-using-class-method* nil)
 864 (defvar *condition-slot-boundp-using-class-method* nil)
 865 (defvar *structure-slot-value-using-class-method* nil)
 866 (defvar *structure-setf-slot-value-using-class-method* nil)
 867 (defvar *structure-slot-boundp-using-class-method* nil)
 868
 869 (defun standard-svuc-method (type)
 870   (case type
 871     (reader *standard-slot-value-using-class-method*)
 872     (writer *standard-setf-slot-value-using-class-method*)
 873     (boundp *standard-slot-boundp-using-class-method*)))
 874
 875 (defun set-standard-svuc-method (type method)
 876   (case type
 877     (reader (setq *standard-slot-value-using-class-method* method))
 878     (writer (setq *standard-setf-slot-value-using-class-method* method))
 879     (boundp (setq *standard-slot-boundp-using-class-method* method))))
 880
 881 (defun condition-svuc-method (type)
 882   (case type
 883     (reader *condition-slot-value-using-class-method*)
 884     (writer *condition-setf-slot-value-using-class-method*)
 885     (boundp *condition-slot-boundp-using-class-method*)))
 886
 887 (defun set-condition-svuc-method (type method)
 888   (case type
 889     (reader (setq *condition-slot-value-using-class-method* method))
 890     (writer (setq *condition-setf-slot-value-using-class-method* method))
 891     (boundp (setq *condition-slot-boundp-using-class-method* method))))
 892
 893 (defun structure-svuc-method (type)
 894   (case type
 895     (reader *structure-slot-value-using-class-method*)
 896     (writer *structure-setf-slot-value-using-class-method*)
 897     (boundp *structure-slot-boundp-using-class-method*)))
 898
 899 (defun set-structure-svuc-method (type method)
 900   (case type
 901     (reader (setq *structure-slot-value-using-class-method* method))
 902     (writer (setq *structure-setf-slot-value-using-class-method* method))
 903     (boundp (setq *structure-slot-boundp-using-class-method* method))))
 904
 905 (defun update-std-or-str-methods (gf type)
 906   (dolist (method (generic-function-methods gf))
 907     (let ((specls (method-specializers method)))
 908       (when (and (or (not (eq type 'writer))
 909                      (eq (pop specls) *the-class-t*))
 910                  (every #'classp specls))
 911         (cond ((and (eq (class-name (car specls)) 'std-class)
 912                     (eq (class-name (cadr specls)) 'standard-object)
 913                     (eq (class-name (caddr specls))
 914                         'standard-effective-slot-definition))
 915                (set-standard-svuc-method type method))
 916               ((and (eq (class-name (car specls)) 'condition-class)
 917                     (eq (class-name (cadr specls)) 'condition)
 918                     (eq (class-name (caddr specls))
 919                         'condition-effective-slot-definition))
 920                (set-condition-svuc-method type method))
 921               ((and (eq (class-name (car specls)) 'structure-class)
 922                     (eq (class-name (cadr specls)) 'structure-object)
 923                     (eq (class-name (caddr specls))
 924                         'structure-effective-slot-definition))
 925                (set-structure-svuc-method type method)))))))
 926
 927 (defun mec-all-classes-internal (spec precompute-p)
 928   (cons (specializer-class spec)
 929         (and (classp spec)
 930              precompute-p
 931              (not (or (eq spec *the-class-t*)
 932                       (eq spec *the-class-slot-object*)
 933                       (eq spec *the-class-standard-object*)
 934                       (eq spec *the-class-structure-object*)))
 935              (let ((sc (class-direct-subclasses spec)))
 936                (when sc
 937                  (mapcan (lambda (class)
 938                            (mec-all-classes-internal class precompute-p))
 939                          sc))))))
 940
 941 (defun mec-all-classes (spec precompute-p)
 942   (let ((classes (mec-all-classes-internal spec precompute-p)))
 943     (if (null (cdr classes))
 944         classes
 945         (let* ((a-classes (cons nil classes))
 946                (tail classes))
 947           (loop (when (null (cdr tail))
 948                   (return (cdr a-classes)))
 949                 (let ((class (cadr tail))
 950                       (ttail (cddr tail)))
 951                   (if (dolist (c ttail nil)
 952                         (when (eq class c) (return t)))
 953                       (setf (cdr tail) (cddr tail))
 954                       (setf tail (cdr tail)))))))))
 955
 956 (defun mec-all-class-lists (spec-list precompute-p)
 957   (if (null spec-list)
 958       (list nil)
 959       (let* ((car-all-classes (mec-all-classes (car spec-list)
 960                                                precompute-p))
 961              (all-class-lists (mec-all-class-lists (cdr spec-list)
 962                                                    precompute-p)))
 963         (mapcan (lambda (list)
 964                   (mapcar (lambda (c) (cons c list)) car-all-classes))
 965                 all-class-lists))))
 966
 967 (defun make-emf-cache (generic-function valuep cache classes-list new-class)
 968   (let* ((arg-info (gf-arg-info generic-function))
 969          (nkeys (arg-info-nkeys arg-info))
 970          (metatypes (arg-info-metatypes arg-info))
 971          (wrappers (unless (eq nkeys 1) (make-list nkeys)))
 972          (precompute-p (gf-precompute-dfun-and-emf-p arg-info))
 973          (default '(default)))
 974     (flet ((add-class-list (classes)
 975              (when (or (null new-class) (memq new-class classes))
 976                (let ((wrappers (get-wrappers-from-classes
 977                                 nkeys wrappers classes metatypes)))
 978                  (when (and wrappers
 979                             (eq default (probe-cache cache wrappers default)))
 980                    (let ((value (cond ((eq valuep t)
 981                                        (sdfun-for-caching generic-function
 982                                                           classes))
 983                                       ((eq valuep :constant-value)
 984                                        (value-for-caching generic-function
 985                                                           classes)))))
 986                      (setq cache (fill-cache cache wrappers value))))))))
 987       (if classes-list
 988           (mapc #'add-class-list classes-list)
 989           (dolist (method (generic-function-methods generic-function))
 990             (mapc #'add-class-list
 991                   (mec-all-class-lists (method-specializers method)
 992                                        precompute-p))))
 993       cache)))
 994
 995 (defmacro class-test (arg class)
 996   (cond
 997     ((eq class *the-class-t*) t)
 998     ((eq class *the-class-slot-object*)
 999      `(not (typep (classoid-of ,arg) 'built-in-classoid)))
1000     ((eq class *the-class-standard-object*)
1001      `(or (std-instance-p ,arg) (fsc-instance-p ,arg)))
1002     ((eq class *the-class-funcallable-standard-object*)
1003      `(fsc-instance-p ,arg))
1004     (t
1005      `(typep ,arg ',(class-name class)))))
1006
1007 (defmacro class-eq-test (arg class)
1008   `(eq (class-of ,arg) ',class))
1009
1010 (defmacro eql-test (arg object)
1011   `(eql ,arg ',object))
1012
1013 (defun dnet-methods-p (form)
1014   (and (consp form)
1015        (or (eq (car form) 'methods)
1016            (eq (car form) 'unordered-methods))))
1017
1018 ;;; This is CASE, but without gensyms.
1019 (defmacro scase (arg &rest clauses)
1020   `(let ((.case-arg. ,arg))
1021      (cond ,@(mapcar (lambda (clause)
1022                        (list* (cond ((null (car clause))
1023                                      nil)
1024                                     ((consp (car clause))
1025                                      (if (null (cdar clause))
1026                                          `(eql .case-arg.
1027                                                ',(caar clause))
1028                                          `(member .case-arg.
1029                                                   ',(car clause))))
1030                                     ((member (car clause) '(t otherwise))
1031                                      `t)
1032                                     (t
1033                                      `(eql .case-arg. ',(car clause))))
1034                               nil
1035                               (cdr clause)))
1036                      clauses))))
1037
1038 (defmacro mcase (arg &rest clauses) `(scase ,arg ,@clauses))
1039
1040 (defun generate-discrimination-net (generic-function methods types sorted-p)
1041   (let* ((arg-info (gf-arg-info generic-function))
1042          (c-a-m-emf-std-p (gf-info-c-a-m-emf-std-p arg-info))
1043          (precedence (arg-info-precedence arg-info)))
1044     (generate-discrimination-net-internal
1045      generic-function methods types
1046      (lambda (methods known-types)
1047        (if (or sorted-p
1048                (and c-a-m-emf-std-p
1049                     (block one-order-p
1050                       (let ((sorted-methods nil))
1051                         (map-all-orders
1052                          (copy-list methods) precedence
1053                          (lambda (methods)
1054                            (when sorted-methods (return-from one-order-p nil))
1055                            (setq sorted-methods methods)))
1056                         (setq methods sorted-methods))
1057                       t)))
1058            `(methods ,methods ,known-types)
1059            `(unordered-methods ,methods ,known-types)))
1060      (lambda (position type true-value false-value)
1061        (let ((arg (dfun-arg-symbol position)))
1062          (if (eq (car type) 'eql)
1063              (let* ((false-case-p (and (consp false-value)
1064                                        (or (eq (car false-value) 'scase)
1065                                            (eq (car false-value) 'mcase))
1066                                        (eq arg (cadr false-value))))
1067                     (false-clauses (if false-case-p
1068                                        (cddr false-value)
1069                                        `((t ,false-value))))
1070                     (case-sym (if (and (dnet-methods-p true-value)
1071                                        (if false-case-p
1072                                            (eq (car false-value) 'mcase)
1073                                            (dnet-methods-p false-value)))
1074                                   'mcase
1075                                   'scase))
1076                     (type-sym `(,(cadr type))))
1077                `(,case-sym ,arg
1078                            (,type-sym ,true-value)
1079                            ,@false-clauses))
1080              `(if ,(let ((arg (dfun-arg-symbol position)))
1081                      (case (car type)
1082                        (class    `(class-test    ,arg ,(cadr type)))
1083                        (class-eq `(class-eq-test ,arg ,(cadr type)))))
1084                   ,true-value
1085                   ,false-value))))
1086      #'identity)))
1087
1088 (defun class-from-type (type)
1089   (if (or (atom type) (eq (car type) t))
1090       *the-class-t*
1091       (case (car type)
1092         (and (dolist (type (cdr type) *the-class-t*)
1093                (when (and (consp type) (not (eq (car type) 'not)))
1094                  (return (class-from-type type)))))
1095         (not *the-class-t*)
1096         (eql (class-of (cadr type)))
1097         (class-eq (cadr type))
1098         (class (cadr type)))))
1099
1100 (defun precompute-effective-methods (gf caching-p &optional classes-list-p)
1101   (let* ((arg-info (gf-arg-info gf))
1102          (methods (generic-function-methods gf))
1103          (precedence (arg-info-precedence arg-info))
1104          (*in-precompute-effective-methods-p* t)
1105          (classes-list nil))
1106     (generate-discrimination-net-internal
1107      gf methods nil
1108      (lambda (methods known-types)
1109        (when methods
1110          (when classes-list-p
1111            (push (mapcar #'class-from-type known-types) classes-list))
1112          (let ((no-eql-specls-p (not (methods-contain-eql-specializer-p
1113                                       methods))))
1114            (map-all-orders
1115             methods precedence
1116             (lambda (methods)
1117               (get-secondary-dispatch-function1
1118                gf methods known-types
1119                nil caching-p no-eql-specls-p))))))
1120      (lambda (position type true-value false-value)
1121        (declare (ignore position type true-value false-value))
1122        nil)
1123      (lambda (type)
1124        (if (and (consp type) (eq (car type) 'eql))
1125            `(class-eq ,(class-of (cadr type)))
1126            type)))
1127     classes-list))
1128
1129 ;;; We know that known-type implies neither new-type nor `(not ,new-type).
1130 (defun augment-type (new-type known-type)
1131   (if (or (eq known-type t)
1132           (eq (car new-type) 'eql))
1133       new-type
1134       (let ((so-far (if (and (consp known-type) (eq (car known-type) 'and))
1135                         (cdr known-type)
1136                         (list known-type))))
1137         (unless (eq (car new-type) 'not)
1138           (setq so-far
1139                 (mapcan (lambda (type)
1140                           (unless (*subtypep new-type type)
1141                             (list type)))
1142                         so-far)))
1143         (if (null so-far)
1144             new-type
1145             `(and ,new-type ,@so-far)))))
1146
1147 (defun generate-discrimination-net-internal
1148     (gf methods types methods-function test-fun type-function)
1149   (let* ((arg-info (gf-arg-info gf))
1150          (precedence (arg-info-precedence arg-info))
1151          (nreq (arg-info-number-required arg-info))
1152          (metatypes (arg-info-metatypes arg-info)))
1153     (labels ((do-column (p-tail contenders known-types)
1154                (if p-tail
1155                    (let* ((position (car p-tail))
1156                           (known-type (or (nth position types) t)))
1157                      (if (eq (nth position metatypes) t)
1158                          (do-column (cdr p-tail) contenders
1159                                     (cons (cons position known-type)
1160                                           known-types))
1161                          (do-methods p-tail contenders
1162                                      known-type () known-types)))
1163                    (funcall methods-function contenders
1164                             (let ((k-t (make-list nreq)))
1165                               (dolist (index+type known-types)
1166                                 (setf (nth (car index+type) k-t)
1167                                       (cdr index+type)))
1168                               k-t))))
1169              (do-methods (p-tail contenders known-type winners known-types)
1170                ;; CONTENDERS
1171                ;;   is a (sorted) list of methods that must be discriminated.
1172                ;; KNOWN-TYPE
1173                ;;   is the type of this argument, constructed from tests
1174                ;;   already made.
1175                ;; WINNERS
1176                ;;   is a (sorted) list of methods that are potentially
1177                ;;   applicable after the discrimination has been made.
1178                (if (null contenders)
1179                    (do-column (cdr p-tail)
1180                               winners
1181                               (cons (cons (car p-tail) known-type)
1182                                     known-types))
1183                    (let* ((position (car p-tail))
1184                           (method (car contenders))
1185                           (specl (nth position (method-specializers method)))
1186                           (type (funcall type-function
1187                                          (type-from-specializer specl))))
1188                      (multiple-value-bind (app-p maybe-app-p)
1189                          (specializer-applicable-using-type-p type known-type)
1190                        (flet ((determined-to-be (truth-value)
1191                                 (if truth-value app-p (not maybe-app-p)))
1192                               (do-if (truth &optional implied)
1193                                 (let ((ntype (if truth type `(not ,type))))
1194                                   (do-methods p-tail
1195                                     (cdr contenders)
1196                                     (if implied
1197                                         known-type
1198                                         (augment-type ntype known-type))
1199                                     (if truth
1200                                         (append winners `(,method))
1201                                         winners)
1202                                     known-types))))
1203                          (cond ((determined-to-be nil) (do-if nil t))
1204                                ((determined-to-be t)   (do-if t   t))
1205                                (t (funcall test-fun position type
1206                                            (do-if t) (do-if nil))))))))))
1207       (do-column precedence methods ()))))
1208
1209 (defun compute-secondary-dispatch-function (generic-function net &optional
1210                                             method-alist wrappers)
1211   (function-funcall (compute-secondary-dispatch-function1 generic-function net)
1212                     method-alist wrappers))
1213
1214 (defvar *eq-case-table-limit* 15)
1215 (defvar *case-table-limit* 10)
1216
1217 (defun compute-mcase-parameters (case-list)
1218   (unless (eq t (caar (last case-list)))
1219     (error "The key for the last case arg to mcase was not T"))
1220   (let* ((eq-p (dolist (case case-list t)
1221                  (unless (or (eq (car case) t)
1222                              (symbolp (caar case)))
1223                    (return nil))))
1224          (len (1- (length case-list)))
1225          (type (cond ((= len 1)
1226                       :simple)
1227                      ((<= len
1228                           (if eq-p
1229                               *eq-case-table-limit*
1230                               *case-table-limit*))
1231                       :assoc)
1232                      (t
1233                       :hash-table))))
1234     (list eq-p type)))
1235
1236 (defmacro mlookup (key info default &optional eq-p type)
1237   (unless (or (eq eq-p t) (null eq-p))
1238     (bug "Invalid eq-p argument: ~S" eq-p))
1239   (ecase type
1240     (:simple
1241      `(if (locally
1242             (declare (optimize (inhibit-warnings 3)))
1243             (,(if eq-p 'eq 'eql) ,key (car ,info)))
1244           (cdr ,info)
1245           ,default))
1246     (:assoc
1247      `(dolist (e ,info ,default)
1248         (when (locally
1249                 (declare (optimize (inhibit-warnings 3)))
1250                 (,(if eq-p 'eq 'eql) (car e) ,key))
1251           (return (cdr e)))))
1252     (:hash-table
1253      `(gethash ,key ,info ,default))))
1254
1255 (defun net-test-converter (form)
1256   (if (atom form)
1257       (default-test-converter form)
1258       (case (car form)
1259         ((invoke-effective-method-function invoke-fast-method-call)
1260          '.call.)
1261         (methods
1262          '.methods.)
1263         (unordered-methods
1264          '.umethods.)
1265         (mcase
1266          `(mlookup ,(cadr form)
1267                    nil
1268                    nil
1269                    ,@(compute-mcase-parameters (cddr form))))
1270         (t (default-test-converter form)))))
1271
1272 (defun net-code-converter (form)
1273   (if (atom form)
1274       (default-code-converter form)
1275       (case (car form)
1276         ((methods unordered-methods)
1277          (let ((gensym (gensym)))
1278            (values gensym
1279                    (list gensym))))
1280         (mcase
1281          (let ((mp (compute-mcase-parameters (cddr form)))
1282                (gensym (gensym)) (default (gensym)))
1283            (values `(mlookup ,(cadr form) ,gensym ,default ,@mp)
1284                    (list gensym default))))
1285         (t
1286          (default-code-converter form)))))
1287
1288 (defun net-constant-converter (form generic-function)
1289   (or (let ((c (methods-converter form generic-function)))
1290         (when c (list c)))
1291       (if (atom form)
1292           (default-constant-converter form)
1293           (case (car form)
1294             (mcase
1295              (let* ((mp (compute-mcase-parameters (cddr form)))
1296                     (list (mapcar (lambda (clause)
1297                                     (let ((key (car clause))
1298                                           (meth (cadr clause)))
1299                                       (cons (if (consp key) (car key) key)
1300                                             (methods-converter
1301                                              meth generic-function))))
1302                                   (cddr form)))
1303                     (default (car (last list))))
1304                (list (list* :mcase mp (nbutlast list))
1305                      (cdr default))))
1306             (t
1307              (default-constant-converter form))))))
1308
1309 (defun methods-converter (form generic-function)
1310   (cond ((and (consp form) (eq (car form) 'methods))
1311          (cons '.methods.
1312                (get-effective-method-function1 generic-function (cadr form))))
1313         ((and (consp form) (eq (car form) 'unordered-methods))
1314          (default-secondary-dispatch-function generic-function))))
1315
1316 (defun convert-methods (constant method-alist wrappers)
1317   (if (and (consp constant)
1318            (eq (car constant) '.methods.))
1319       (funcall (cdr constant) method-alist wrappers)
1320       constant))
1321
1322 (defun convert-table (constant method-alist wrappers)
1323   (cond ((and (consp constant)
1324               (eq (car constant) :mcase))
1325          (let ((alist (mapcar (lambda (k+m)
1326                                 (cons (car k+m)
1327                                       (convert-methods (cdr k+m)
1328                                                        method-alist
1329                                                        wrappers)))
1330                               (cddr constant)))
1331                (mp (cadr constant)))
1332            (ecase (cadr mp)
1333              (:simple
1334               (car alist))
1335              (:assoc
1336               alist)
1337              (:hash-table
1338               (let ((table (make-hash-table :test (if (car mp) 'eq 'eql))))
1339                 (dolist (k+m alist)
1340                   (setf (gethash (car k+m) table) (cdr k+m)))
1341                 table)))))))
1342
1343 (defun compute-secondary-dispatch-function1 (generic-function net
1344                                              &optional function-p)
1345   (cond
1346    ((and (eq (car net) 'methods) (not function-p))
1347     (get-effective-method-function1 generic-function (cadr net)))
1348    (t
1349     (let* ((name (generic-function-name generic-function))
1350            (arg-info (gf-arg-info generic-function))
1351            (metatypes (arg-info-metatypes arg-info))
1352            (applyp (arg-info-applyp arg-info))
1353            (fmc-arg-info (cons (length metatypes) applyp))
1354            (arglist (if function-p
1355                         (make-dfun-lambda-list metatypes applyp)
1356                         (make-fast-method-call-lambda-list metatypes applyp))))
1357       (multiple-value-bind (cfunction constants)
1358           (get-fun1 `(lambda
1359                       ,arglist
1360                       ,@(unless function-p
1361                           `((declare (ignore .pv-cell.
1362                                              .next-method-call.))))
1363                       (locally (declare #.*optimize-speed*)
1364                                (let ((emf ,net))
1365                                  ,(make-emf-call metatypes applyp 'emf))))
1366                     #'net-test-converter
1367                     #'net-code-converter
1368                     (lambda (form)
1369                       (net-constant-converter form generic-function)))
1370         (lambda (method-alist wrappers)
1371           (let* ((alist (list nil))
1372                  (alist-tail alist))
1373             (dolist (constant constants)
1374               (let* ((a (or (dolist (a alist nil)
1375                               (when (eq (car a) constant)
1376                                 (return a)))
1377                             (cons constant
1378                                   (or (convert-table
1379                                        constant method-alist wrappers)
1380                                       (convert-methods
1381                                        constant method-alist wrappers)))))
1382                      (new (list a)))
1383                 (setf (cdr alist-tail) new)
1384                 (setf alist-tail new)))
1385             (let ((function (apply cfunction (mapcar #'cdr (cdr alist)))))
1386               (if function-p
1387                   function
1388                   (make-fast-method-call
1389                    :function (set-fun-name function `(sdfun-method ,name))
1390                    :arg-info fmc-arg-info))))))))))
1391
1392 (defvar *show-make-unordered-methods-emf-calls* nil)
1393
1394 (defun make-unordered-methods-emf (generic-function methods)
1395   (when *show-make-unordered-methods-emf-calls*
1396     (format t "~&make-unordered-methods-emf ~S~%"
1397             (generic-function-name generic-function)))
1398   (lambda (&rest args)
1399     (let* ((types (types-from-args generic-function args 'eql))
1400            (smethods (sort-applicable-methods generic-function
1401                                               methods
1402                                               types))
1403            (emf (get-effective-method-function generic-function smethods)))
1404       (invoke-emf emf args))))
1405 \f
1406 ;;; The value returned by compute-discriminating-function is a function
1407 ;;; object. It is called a discriminating function because it is called
1408 ;;; when the generic function is called and its role is to discriminate
1409 ;;; on the arguments to the generic function and then call appropriate
1410 ;;; method functions.
1411 ;;;
1412 ;;; A discriminating function can only be called when it is installed as
1413 ;;; the funcallable instance function of the generic function for which
1414 ;;; it was computed.
1415 ;;;
1416 ;;; More precisely, if compute-discriminating-function is called with
1417 ;;; an argument <gf1>, and returns a result <df1>, that result must
1418 ;;; not be passed to apply or funcall directly. Rather, <df1> must be
1419 ;;; stored as the funcallable instance function of the same generic
1420 ;;; function <gf1> (using SET-FUNCALLABLE-INSTANCE-FUNCTION). Then the
1421 ;;; generic function can be passed to funcall or apply.
1422 ;;;
1423 ;;; An important exception is that methods on this generic function are
1424 ;;; permitted to return a function which itself ends up calling the value
1425 ;;; returned by a more specific method. This kind of `encapsulation' of
1426 ;;; discriminating function is critical to many uses of the MOP.
1427 ;;;
1428 ;;; As an example, the following canonical case is legal:
1429 ;;;
1430 ;;;   (defmethod compute-discriminating-function ((gf my-generic-function))
1431 ;;;     (let ((std (call-next-method)))
1432 ;;;       (lambda (arg)
1433 ;;;         (print (list 'call-to-gf gf arg))
1434 ;;;         (funcall std arg))))
1435 ;;;
1436 ;;; Because many discriminating functions would like to use a dynamic
1437 ;;; strategy in which the precise discriminating function changes with
1438 ;;; time it is important to specify how a discriminating function is
1439 ;;; permitted itself to change the funcallable instance function of the
1440 ;;; generic function.
1441 ;;;
1442 ;;; Discriminating functions may set the funcallable instance function
1443 ;;; of the generic function, but the new value must be generated by making
1444 ;;; a call to COMPUTE-DISCRIMINATING-FUNCTION. This is to ensure that any
1445 ;;; more specific methods which may have encapsulated the discriminating
1446 ;;; function will get a chance to encapsulate the new, inner discriminating
1447 ;;; function.
1448 ;;;
1449 ;;; This implies that if a discriminating function wants to modify itself
1450 ;;; it should first store some information in the generic function proper,
1451 ;;; and then call compute-discriminating-function. The appropriate method
1452 ;;; on compute-discriminating-function will see the information stored in
1453 ;;; the generic function and generate a discriminating function accordingly.
1454 ;;;
1455 ;;; The following is an example of a discriminating function which modifies
1456 ;;; itself in accordance with this protocol:
1457 ;;;
1458 ;;;   (defmethod compute-discriminating-function ((gf my-generic-function))
1459 ;;;     (lambda (arg)
1460 ;;;      (cond (<some condition>
1461 ;;;             <store some info in the generic function>
1462 ;;;             (set-funcallable-instance-function
1463 ;;;               gf
1464 ;;;               (compute-discriminating-function gf))
1465 ;;;             (funcall gf arg))
1466 ;;;            (t
1467 ;;;             <call-a-method-of-gf>))))
1468 ;;;
1469 ;;; Whereas this code would not be legal:
1470 ;;;
1471 ;;;   (defmethod compute-discriminating-function ((gf my-generic-function))
1472 ;;;     (lambda (arg)
1473 ;;;      (cond (<some condition>
1474 ;;;             (set-funcallable-instance-function
1475 ;;;               gf
1476 ;;;               (lambda (a) ..))
1477 ;;;             (funcall gf arg))
1478 ;;;            (t
1479 ;;;             <call-a-method-of-gf>))))
1480 ;;;
1481 ;;; NOTE:  All the examples above assume that all instances of the class
1482 ;;;     my-generic-function accept only one argument.
1483
1484 (defun slot-value-using-class-dfun (class object slotd)
1485   (declare (ignore class))
1486   (function-funcall (slot-definition-reader-function slotd) object))
1487
1488 (defun setf-slot-value-using-class-dfun (new-value class object slotd)
1489   (declare (ignore class))
1490   (function-funcall (slot-definition-writer-function slotd) new-value object))
1491
1492 (defun slot-boundp-using-class-dfun (class object slotd)
1493   (declare (ignore class))
1494   (function-funcall (slot-definition-boundp-function slotd) object))
1495
1496 (defmethod compute-discriminating-function ((gf standard-generic-function))
1497   (with-slots (dfun-state arg-info) gf
1498     (typecase dfun-state
1499       (null (let ((name (generic-function-name gf)))
1500               (when (eq name 'compute-applicable-methods)
1501                 (update-all-c-a-m-gf-info gf))
1502               (cond ((eq name 'slot-value-using-class)
1503                      (update-slot-value-gf-info gf 'reader)
1504                      #'slot-value-using-class-dfun)
1505                     ((equal name '(setf slot-value-using-class))
1506                      (update-slot-value-gf-info gf 'writer)
1507                      #'setf-slot-value-using-class-dfun)
1508                     ((eq name 'slot-boundp-using-class)
1509                      (update-slot-value-gf-info gf 'boundp)
1510                      #'slot-boundp-using-class-dfun)
1511                     ((gf-precompute-dfun-and-emf-p arg-info)
1512                      (make-final-dfun gf))
1513                     (t
1514                      (make-initial-dfun gf)))))
1515       (function dfun-state)
1516       (cons (car dfun-state)))))
1517
1518 (defmethod update-gf-dfun ((class std-class) gf)
1519   (let ((*new-class* class)
1520         #|| (name (generic-function-name gf)) ||#
1521         (arg-info (gf-arg-info gf)))
1522     (cond #||
1523           ((eq name 'slot-value-using-class)
1524            (update-slot-value-gf-info gf 'reader))
1525           ((equal name '(setf slot-value-using-class))
1526            (update-slot-value-gf-info gf 'writer))
1527           ((eq name 'slot-boundp-using-class)
1528            (update-slot-value-gf-info gf 'boundp))
1529           ||#
1530           ((gf-precompute-dfun-and-emf-p arg-info)
1531            (multiple-value-bind (dfun cache info)
1532                (make-final-dfun-internal gf)
1533              (set-dfun gf dfun cache info) ; lest the cache be freed twice
1534              (update-dfun gf dfun cache info))))))
1535 \f
1536 (defmethod (setf class-name) :before (new-value (class class))
1537   (let ((classoid (find-classoid (class-name class))))
1538     (setf (classoid-name classoid) new-value)))
1539 \f
1540 (defmethod function-keywords ((method standard-method))
1541   (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1542       (analyze-lambda-list (if (consp method)
1543                                (early-method-lambda-list method)
1544                                (method-lambda-list method)))
1545     (declare (ignore nreq nopt keysp restp))
1546     (values keywords allow-other-keys-p)))
1547
1548 (defun method-ll->generic-function-ll (ll)
1549   (multiple-value-bind
1550       (nreq nopt keysp restp allow-other-keys-p keywords keyword-parameters)
1551       (analyze-lambda-list ll)
1552     (declare (ignore nreq nopt keysp restp allow-other-keys-p keywords))
1553     (remove-if (lambda (s)
1554                  (or (memq s keyword-parameters)
1555                      (eq s '&allow-other-keys)))
1556                ll)))
1557 \f
1558 ;;; This is based on the rules of method lambda list congruency defined in
1559 ;;; the spec. The lambda list it constructs is the pretty union of the
1560 ;;; lambda lists of all the methods. It doesn't take method applicability
1561 ;;; into account at all yet.
1562 (defmethod generic-function-pretty-arglist
1563            ((generic-function standard-generic-function))
1564   (let ((methods (generic-function-methods generic-function)))
1565     (if methods
1566       (let ((arglist ()))
1567         ;; arglist is constructed from the GF's methods - maybe with
1568         ;; keys and rest stuff added
1569         (multiple-value-bind (required optional rest key allow-other-keys)
1570             (method-pretty-arglist (car methods))
1571           (dolist (m (cdr methods))
1572             (multiple-value-bind (method-key-keywords
1573                                   method-allow-other-keys
1574                                   method-key)
1575                 (function-keywords m)
1576               ;; we've modified function-keywords to return what we want as
1577               ;;  the third value, no other change here.
1578               (declare (ignore method-key-keywords))
1579               (setq key (union key method-key))
1580               (setq allow-other-keys (or allow-other-keys
1581                                          method-allow-other-keys))))
1582           (when allow-other-keys
1583             (setq arglist '(&allow-other-keys)))
1584           (when key
1585             (setq arglist (nconc (list '&key) key arglist)))
1586           (when rest
1587             (setq arglist (nconc (list '&rest rest) arglist)))
1588           (when optional
1589             (setq arglist (nconc (list '&optional) optional arglist)))
1590           (nconc required arglist)))
1591       ;; otherwise we take the lambda-list from the GF directly, with no
1592       ;; other 'keys' added ...
1593       (let ((lambda-list (generic-function-lambda-list generic-function)))
1594         lambda-list))))
1595
1596 (defmethod method-pretty-arglist ((method standard-method))
1597   (let ((required ())
1598         (optional ())
1599         (rest nil)
1600         (key ())
1601         (allow-other-keys nil)
1602         (state 'required)
1603         (arglist (method-lambda-list method)))
1604     (dolist (arg arglist)
1605       (cond ((eq arg '&optional)         (setq state 'optional))
1606             ((eq arg '&rest)             (setq state 'rest))
1607             ((eq arg '&key)              (setq state 'key))
1608             ((eq arg '&allow-other-keys) (setq allow-other-keys t))
1609             ((memq arg lambda-list-keywords))
1610             (t
1611              (ecase state
1612                (required (push arg required))
1613                (optional (push arg optional))
1614                (key      (push arg key))
1615                (rest     (setq rest arg))))))
1616     (values (nreverse required)
1617             (nreverse optional)
1618             rest
1619             (nreverse key)
1620             allow-other-keys)))
1621