src/pcl/print-object.lisp

   1 ;;;; some basic PRINT-OBJECT functionality
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5
   6 ;;;; This software is derived from software originally released by Xerox
   7 ;;;; Corporation. Copyright and release statements follow. Later modifications
   8 ;;;; to the software are in the public domain and are provided with
   9 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  10 ;;;; information.
  11
  12 ;;;; Some of the text in this file was originally taken from various files of
  13 ;;;; the PCL system from Xerox Corporation, which carried the following
  14 ;;;; copyright information:
  15 ;;;;
  16 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  17 ;;;; All rights reserved.
  18 ;;;;
  19 ;;;; Use and copying of this software and preparation of derivative works based
  20 ;;;; upon this software are permitted. Any distribution of this software or
  21 ;;;; derivative works must comply with all applicable United States export
  22 ;;;; control laws.
  23 ;;;;
  24 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  25 ;;;; warranty about the software, its performance or its conformity to any
  26 ;;;; specification.
  27
  28 (in-package "SB-PCL")
  29 \f
  30 ;;;; the PRINT-OBJECT generic function
  31
  32 ;;; Blow away the old non-generic function placeholder which was used
  33 ;;; by the printer doing bootstrapping, and immediately replace it
  34 ;;; with some new printing logic, so that the Lisp printer stays
  35 ;;; crippled only for the shortest necessary time.
  36 (/show0 "about to replace placeholder PRINT-OBJECT with DEFGENERIC")
  37 (let (;; (If we don't suppress /SHOW printing while the printer is
  38       ;; crippled here, it becomes really easy to crash the bootstrap
  39       ;; sequence by adding /SHOW statements e.g. to the compiler,
  40       ;; which kinda defeats the purpose of /SHOW being a harmless
  41       ;; tracing-style statement.)
  42       #+sb-show (*/show* nil)
  43       ;; (another workaround for the problem of debugging while the
  44       ;; printer is disabled here)
  45       #+sb-show
  46       (sb-impl::*print-object-is-disabled-p* t))
  47   (fmakunbound 'print-object)
  48   (defgeneric print-object (object stream))
  49   (defmethod print-object ((x t) stream)
  50     (print-unreadable-object (x stream :type t :identity t))))
  51 (/show0 "done replacing placeholder PRINT-OBJECT with DEFGENERIC")
  52 \f
  53 ;;;; a hook called by the printer to take care of dispatching to PRINT-OBJECT
  54 ;;;; for appropriate FUNCALLABLE-INSTANCE objects
  55
  56 ;;; Now that CLOS is working, we can replace our old temporary placeholder code
  57 ;;; for writing funcallable instances with permanent code:
  58 (defun sb-impl::printed-as-funcallable-standard-class (object stream)
  59   (when (funcallable-standard-class-p (class-of object))
  60     (print-object object stream)
  61     t))
  62 \f
  63 ;;;; PRINT-OBJECT methods for objects from PCL classes
  64 ;;;;
  65 ;;;; FIXME: Perhaps these should be moved back alongside the definitions of
  66 ;;;; the classes they print. (Bootstrapping problems could be avoided by
  67 ;;;; using DEF!METHOD to do this.)
  68
  69 (defmethod print-object ((method standard-method) stream)
  70   (print-unreadable-object (method stream :type t :identity t)
  71     (if (slot-boundp method 'generic-function)
  72         (let ((generic-function (method-generic-function method)))
  73           (format stream "~S ~{~S ~}~:S"
  74                   (and generic-function
  75                        (generic-function-name generic-function))
  76                   (method-qualifiers method)
  77                   (unparse-specializers method)))
  78         ;; FIXME: Why do we do CALL-NEXT-METHOD in this method (and
  79         ;; in the PRINT-OBJECT STANDARD-ACCESSOR-METHOD method too)?
  80         (call-next-method))))
  81
  82 (defmethod print-object ((method standard-accessor-method) stream)
  83   (print-unreadable-object (method stream :type t :identity t)
  84     (if (slot-boundp method 'generic-function)
  85         (let ((generic-function (method-generic-function method)))
  86           (format stream "~S, slot:~S, ~:S"
  87                   (and generic-function
  88                        (generic-function-name generic-function))
  89                   (accessor-method-slot-name method)
  90                   (unparse-specializers method)))
  91         (call-next-method))))
  92
  93 (defmethod print-object ((mc standard-method-combination) stream)
  94   (print-unreadable-object (mc stream :type t :identity t)
  95     (format stream
  96             "~S ~S"
  97             (slot-value-or-default mc 'type)
  98             (slot-value-or-default mc 'options))))
  99
 100 (defun named-object-print-function (instance stream
 101                                     &optional (extra nil extra-p))
 102   (print-unreadable-object (instance stream :type t)
 103     (if extra-p
 104         (format stream
 105                 "~S ~:S"
 106                 (slot-value-or-default instance 'name)
 107                 extra)
 108         (format stream
 109                 "~S"
 110                 (slot-value-or-default instance 'name)))))
 111
 112 (defmethod print-object ((class class) stream)
 113   (named-object-print-function class stream))
 114
 115 (defmethod print-object ((slotd slot-definition) stream)
 116   (named-object-print-function slotd stream))
 117
 118 (defmethod print-object ((generic-function generic-function) stream)
 119   (named-object-print-function
 120     generic-function
 121     stream
 122     (if (slot-boundp generic-function 'methods)
 123         (list (length (generic-function-methods generic-function)))
 124         "?")))
 125
 126 (defmethod print-object ((constructor constructor) stream)
 127   (print-unreadable-object (constructor stream :type t :identity t)
 128     (format stream
 129             "~S (~S)"
 130             (slot-value-or-default constructor 'name)
 131             (slot-value-or-default constructor 'code-type))))
 132
 133 (defmethod print-object ((cache cache) stream)
 134   (print-unreadable-object (cache stream :type t :identity t)
 135     (format stream
 136             "~D ~S ~D"
 137             (cache-nkeys cache)
 138             (cache-valuep cache)
 139             (cache-nlines cache))))
 140
 141 (defmethod print-object ((wrapper wrapper) stream)
 142   (print-unreadable-object (wrapper stream :type t :identity t)
 143     (prin1 (wrapper-class wrapper) stream)))
 144
 145 (defmethod print-object ((dfun-info dfun-info) stream)
 146   (declare (type stream stream))
 147   (print-unreadable-object (dfun-info stream :type t :identity t)))