src/pcl/slots.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;;; ANSI CL condition for unbound slots
  27
  28 (define-condition unbound-slot (cell-error)
  29   ((instance :reader unbound-slot-instance :initarg :instance)
  30    (slot :reader unbound-slot-slot :initarg :slot))
  31   (:report (lambda(condition stream)
  32              (format stream "The slot ~S is unbound in the object ~S."
  33                      (unbound-slot-slot condition)
  34                      (unbound-slot-instance condition)))))
  35
  36 (defmethod wrapper-fetcher ((class standard-class))
  37   'std-instance-wrapper)
  38
  39 (defmethod slots-fetcher ((class standard-class))
  40   'std-instance-slots)
  41
  42 (defmethod raw-instance-allocator ((class standard-class))
  43   'allocate-standard-instance)
  44
  45 ;;; These four functions work on std-instances and fsc-instances. These are
  46 ;;; instances for which it is possible to change the wrapper and the slots.
  47 ;;;
  48 ;;; For these kinds of instances, most specified methods from the instance
  49 ;;; structure protocol are promoted to the implementation-specific class
  50 ;;; std-class. Many of these methods call these four functions.
  51
  52 (defun set-wrapper (inst new)
  53   (cond ((std-instance-p inst)
  54          (setf (std-instance-wrapper inst) new))
  55         ((fsc-instance-p inst)
  56          (setf (fsc-instance-wrapper inst) new))
  57         (t
  58          (error "unrecognized instance type"))))
  59
  60 (defun swap-wrappers-and-slots (i1 i2)
  61   (sb-sys:without-interrupts
  62    (cond ((std-instance-p i1)
  63           (let ((w1 (std-instance-wrapper i1))
  64                 (s1 (std-instance-slots i1)))
  65             (setf (std-instance-wrapper i1) (std-instance-wrapper i2))
  66             (setf (std-instance-slots i1) (std-instance-slots i2))
  67             (setf (std-instance-wrapper i2) w1)
  68             (setf (std-instance-slots i2) s1)))
  69          ((fsc-instance-p i1)
  70           (let ((w1 (fsc-instance-wrapper i1))
  71                 (s1 (fsc-instance-slots i1)))
  72             (setf (fsc-instance-wrapper i1) (fsc-instance-wrapper i2))
  73             (setf (fsc-instance-slots i1) (fsc-instance-slots i2))
  74             (setf (fsc-instance-wrapper i2) w1)
  75             (setf (fsc-instance-slots i2) s1)))
  76          (t
  77           (error "unrecognized instance type")))))
  78 \f
  79 (defun get-class-slot-value-1 (object wrapper slot-name)
  80   (let ((entry (assoc slot-name (wrapper-class-slots wrapper))))
  81     (if (null entry)
  82         (slot-missing (wrapper-class wrapper) object slot-name 'slot-value)
  83         (if (eq (cdr entry) +slot-unbound+)
  84             (slot-unbound (wrapper-class wrapper) object slot-name)
  85             (cdr entry)))))
  86
  87 (defun set-class-slot-value-1 (new-value object wrapper slot-name)
  88   (let ((entry (assoc slot-name (wrapper-class-slots wrapper))))
  89     (if (null entry)
  90         (slot-missing (wrapper-class wrapper)
  91                       object
  92                       slot-name
  93                       'setf
  94                       new-value)
  95         (setf (cdr entry) new-value))))
  96
  97 (defmethod class-slot-value ((class std-class) slot-name)
  98   (let ((wrapper (class-wrapper class))
  99         (prototype (class-prototype class)))
 100     (get-class-slot-value-1 prototype wrapper slot-name)))
 101
 102 (defmethod (setf class-slot-value) (nv (class std-class) slot-name)
 103   (let ((wrapper (class-wrapper class))
 104         (prototype (class-prototype class)))
 105     (set-class-slot-value-1 nv prototype wrapper slot-name)))
 106 \f
 107 (defun find-slot-definition (class slot-name)
 108   (dolist (slot (class-slots class) nil)
 109     (when (eql slot-name (slot-definition-name slot))
 110       (return slot))))
 111
 112 (defun slot-value (object slot-name)
 113   (let* ((class (class-of object))
 114          (slot-definition (find-slot-definition class slot-name)))
 115     (if (null slot-definition)
 116         (slot-missing class object slot-name 'slot-value)
 117         (slot-value-using-class class object slot-definition))))
 118
 119 (setf (gdefinition 'slot-value-normal) #'slot-value)
 120
 121 (define-compiler-macro slot-value (object-form slot-name-form)
 122   (if (and (constantp slot-name-form)
 123            (let ((slot-name (eval slot-name-form)))
 124              (and (symbolp slot-name) (symbol-package slot-name))))
 125       `(accessor-slot-value ,object-form ,slot-name-form)
 126       `(slot-value-normal ,object-form ,slot-name-form)))
 127
 128 (defun set-slot-value (object slot-name new-value)
 129   (let* ((class (class-of object))
 130          (slot-definition (find-slot-definition class slot-name)))
 131     (if (null slot-definition)
 132         (slot-missing class object slot-name 'setf new-value)
 133         (setf (slot-value-using-class class object slot-definition)
 134               new-value))))
 135
 136 (setf (gdefinition 'set-slot-value-normal) #'set-slot-value)
 137
 138 (define-compiler-macro set-slot-value (object-form
 139                                        slot-name-form
 140                                        new-value-form)
 141   (if (and (constantp slot-name-form)
 142            (let ((slot-name (eval slot-name-form)))
 143              (and (symbolp slot-name) (symbol-package slot-name))))
 144       `(accessor-set-slot-value ,object-form ,slot-name-form ,new-value-form)
 145       `(set-slot-value-normal ,object-form ,slot-name-form ,new-value-form)))
 146
 147 (defconstant +optimize-slot-boundp+ nil)
 148
 149 (defun slot-boundp (object slot-name)
 150   (let* ((class (class-of object))
 151          (slot-definition (find-slot-definition class slot-name)))
 152     (if (null slot-definition)
 153         (slot-missing class object slot-name 'slot-boundp)
 154         (slot-boundp-using-class class object slot-definition))))
 155
 156 (setf (gdefinition 'slot-boundp-normal) #'slot-boundp)
 157
 158 (define-compiler-macro slot-boundp (object-form slot-name-form)
 159   (if (and (constantp slot-name-form)
 160            (let ((slot-name (eval slot-name-form)))
 161              (and (symbolp slot-name) (symbol-package slot-name))))
 162       `(accessor-slot-boundp ,object-form ,slot-name-form)
 163       `(slot-boundp-normal ,object-form ,slot-name-form)))
 164
 165 (defun slot-makunbound (object slot-name)
 166   (let* ((class (class-of object))
 167          (slot-definition (find-slot-definition class slot-name)))
 168     (if (null slot-definition)
 169         (slot-missing class object slot-name 'slot-makunbound)
 170         (slot-makunbound-using-class class object slot-definition))))
 171
 172 (defun slot-exists-p (object slot-name)
 173   (let ((class (class-of object)))
 174     (not (null (find-slot-definition class slot-name)))))
 175
 176 ;;; This isn't documented, but is used within PCL in a number of print
 177 ;;; object methods. (See NAMED-OBJECT-PRINT-FUNCTION.)
 178 (defun slot-value-or-default (object slot-name &optional (default "unbound"))
 179   (if (slot-boundp object slot-name)
 180       (slot-value object slot-name)
 181       default))
 182 \f
 183 (defun standard-instance-access (instance location)
 184   (instance-ref (std-instance-slots instance) location))
 185
 186 (defun funcallable-standard-instance-access (instance location)
 187   (instance-ref (fsc-instance-slots instance) location))
 188
 189 (defmethod slot-value-using-class ((class std-class)
 190                                    (object std-object)
 191                                    (slotd standard-effective-slot-definition))
 192   (let* ((location (slot-definition-location slotd))
 193          (value (typecase location
 194                   (fixnum
 195                    (cond ((std-instance-p object)
 196                           ;; FIXME: EQ T (WRAPPER-STATE ..) is better done
 197                           ;; through INVALID-WRAPPER-P (here and below).
 198                           (unless (eq t (wrapper-state (std-instance-wrapper
 199                                                         object)))
 200                             (check-wrapper-validity object))
 201                           (instance-ref (std-instance-slots object) location))
 202                          ((fsc-instance-p object)
 203                           (unless (eq t (wrapper-state (fsc-instance-wrapper
 204                                                         object)))
 205                             (check-wrapper-validity object))
 206                           (instance-ref (fsc-instance-slots object) location))
 207                          (t (error "unrecognized instance type"))))
 208                   (cons
 209                    (cdr location))
 210                   (t
 211                    (error "~@<The slot ~S has neither :INSTANCE nor :CLASS ~
 212                            allocation, so it can't be read by the default ~
 213                            ~S method.~@:>"
 214                           slotd 'slot-value-using-class)))))
 215     (if (eq value +slot-unbound+)
 216         (slot-unbound class object (slot-definition-name slotd))
 217         value)))
 218
 219 (defmethod (setf slot-value-using-class)
 220            (new-value (class std-class)
 221                       (object std-object)
 222                       (slotd standard-effective-slot-definition))
 223   (let ((location (slot-definition-location slotd)))
 224     (typecase location
 225       (fixnum
 226        (cond ((std-instance-p object)
 227               (unless (eq t (wrapper-state (std-instance-wrapper object)))
 228                 (check-wrapper-validity object))
 229                (setf (instance-ref (std-instance-slots object) location)
 230                        new-value))
 231              ((fsc-instance-p object)
 232               (unless (eq t (wrapper-state (fsc-instance-wrapper object)))
 233                 (check-wrapper-validity object))
 234                (setf (instance-ref (fsc-instance-slots object) location)
 235                        new-value))
 236              (t (error "unrecognized instance type"))))
 237       (cons
 238        (setf (cdr location) new-value))
 239       (t
 240        (error "~@<The slot ~S has neither :INSTANCE nor :CLASS allocation, ~
 241                    so it can't be written by the default ~S method.~:@>"
 242               slotd '(setf slot-value-using-class))))))
 243
 244 (defmethod slot-boundp-using-class
 245            ((class std-class)
 246             (object std-object)
 247             (slotd standard-effective-slot-definition))
 248   (let* ((location (slot-definition-location slotd))
 249          (value (typecase location
 250                   (fixnum
 251                    (cond ((std-instance-p object)
 252                           (unless (eq t (wrapper-state (std-instance-wrapper
 253                                                         object)))
 254                             (check-wrapper-validity object))
 255                           (instance-ref (std-instance-slots object) location))
 256                          ((fsc-instance-p object)
 257                           (unless (eq t (wrapper-state (fsc-instance-wrapper
 258                                                         object)))
 259                             (check-wrapper-validity object))
 260                           (instance-ref (fsc-instance-slots object) location))
 261                          (t (error "unrecognized instance type"))))
 262                   (cons
 263                    (cdr location))
 264                   (t
 265                    (error "~@<The slot ~S has neither :INSTANCE nor :CLASS ~
 266                            allocation, so it can't be read by the default ~S ~
 267                            method.~@:>"
 268                           slotd 'slot-boundp-using-class)))))
 269     (not (eq value +slot-unbound+))))
 270
 271 (defmethod slot-makunbound-using-class
 272            ((class std-class)
 273             (object std-object)
 274             (slotd standard-effective-slot-definition))
 275   (let ((location (slot-definition-location slotd)))
 276     (typecase location
 277       (fixnum
 278        (cond ((std-instance-p object)
 279               (unless (eq t (wrapper-state (std-instance-wrapper object)))
 280                 (check-wrapper-validity object))
 281                (setf (instance-ref (std-instance-slots object) location)
 282                        +slot-unbound+))
 283              ((fsc-instance-p object)
 284               (unless (eq t (wrapper-state (fsc-instance-wrapper object)))
 285                 (check-wrapper-validity object))
 286                (setf (instance-ref (fsc-instance-slots object) location)
 287                        +slot-unbound+))
 288              (t (error "unrecognized instance type"))))
 289       (cons
 290        (setf (cdr location) +slot-unbound+))
 291       (t
 292        (error "~@<The slot ~S has neither :INSTANCE nor :CLASS allocation, ~
 293                so it can't be written by the default ~S method.~@:>"
 294               slotd 'slot-makunbound-using-class))))
 295   nil)
 296
 297 (defmethod slot-value-using-class
 298     ((class structure-class)
 299      (object structure-object)
 300      (slotd structure-effective-slot-definition))
 301   (let* ((function (slot-definition-internal-reader-function slotd))
 302          (value (funcall function object)))
 303     (declare (type function function))
 304     (if (eq value +slot-unbound+)
 305         (slot-unbound class object (slot-definition-name slotd))
 306         value)))
 307
 308 (defmethod (setf slot-value-using-class)
 309     (new-value (class structure-class)
 310                (object structure-object)
 311                (slotd structure-effective-slot-definition))
 312   (let ((function (slot-definition-internal-writer-function slotd)))
 313     (declare (type function function))
 314     (funcall function new-value object)))
 315
 316 (defmethod slot-boundp-using-class
 317            ((class structure-class)
 318             (object structure-object)
 319             (slotd structure-effective-slot-definition))
 320   t)
 321
 322 (defmethod slot-makunbound-using-class
 323            ((class structure-class)
 324             (object structure-object)
 325             (slotd structure-effective-slot-definition))
 326   (error "Structure slots can't be unbound."))
 327 \f
 328 (defmethod slot-missing
 329            ((class t) instance slot-name operation &optional new-value)
 330   (error "~@<When attempting to ~A, the slot ~S is missing from the ~
 331           object ~S.~@:>"
 332          (ecase operation
 333            (slot-value "read the slot's value (slot-value)")
 334            (setf (format nil
 335                          "set the slot's value to ~S (SETF of SLOT-VALUE)"
 336                          new-value))
 337            (slot-boundp "test to see whether slot is bound (SLOT-BOUNDP)")
 338            (slot-makunbound "make the slot unbound (SLOT-MAKUNBOUND)"))
 339          slot-name
 340          instance))
 341
 342 (defmethod slot-unbound ((class t) instance slot-name)
 343   (error 'unbound-slot :slot slot-name :instance instance))
 344
 345 (defun slot-unbound-internal (instance position)
 346   (slot-unbound (class-of instance) instance
 347                 (etypecase position
 348                   (fixnum
 349                    (nth position
 350                         (wrapper-instance-slots-layout (wrapper-of instance))))
 351                   (cons
 352                    (car position)))))
 353 \f
 354 (defmethod allocate-instance ((class standard-class) &rest initargs)
 355   (declare (ignore initargs))
 356   (unless (class-finalized-p class) (finalize-inheritance class))
 357   (allocate-standard-instance (class-wrapper class)))
 358
 359 (defmethod allocate-instance ((class structure-class) &rest initargs)
 360   (declare (ignore initargs))
 361   (let ((constructor (class-defstruct-constructor class)))
 362     (if constructor
 363         (funcall constructor)
 364         (error "can't allocate an instance of class ~S" (class-name class)))))