src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd '%class)))
  76     (dolist (type '(reader writer boundp))
  77       (let* ((gf-name (ecase type
  78                               (reader 'slot-value-using-class)
  79                               (writer '(setf slot-value-using-class))
  80                               (boundp 'slot-boundp-using-class)))
  81              (gf (gdefinition gf-name)))
  82         (compute-slot-accessor-info slotd type gf)))))
  83
  84 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
  85 ;;;
  86 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
  87 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
  88 ;;; writing/testing effective slot SLOTD.
  89 ;;;
  90 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
  91 ;;; GF.  Store the effective method in the effective slot definition
  92 ;;; object itself; these GFs have special dispatch functions calling
  93 ;;; effective methods directly retrieved from effective slot
  94 ;;; definition objects, as an optimization.
  95 ;;;
  96 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
  97 ;;; or some such.
  98 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  99                                        type gf)
 100   (let* ((name (slot-value slotd 'name))
 101          (class (slot-value slotd '%class))
 102          (old-slotd (when (class-finalized-p class)
 103                       (find-slot-definition class name)))
 104          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
 105     (multiple-value-bind (function std-p)
 106         (if (eq *boot-state* 'complete)
 107             (get-accessor-method-function gf type class slotd)
 108             (get-optimized-std-accessor-method-function class slotd type))
 109       (setf (slot-accessor-std-p slotd type) std-p)
 110       (setf (slot-accessor-function slotd type) function))))
 111
 112 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 113   :instance)
 114 \f
 115 ;;;; various class accessors that are a little more complicated than can be
 116 ;;;; done with automatically generated reader methods
 117
 118 (defmethod class-prototype :before (class)
 119   (unless (class-finalized-p class)
 120     (error "~@<~S is not finalized.~:@>" class)))
 121
 122 ;;; KLUDGE: For some reason factoring the common body into a function
 123 ;;; breaks PCL bootstrapping, so just generate it with a macrolet for
 124 ;;; all.
 125 (macrolet ((def (class)
 126              `(defmethod class-prototype ((class ,class))
 127                 (with-slots (prototype) class
 128                   (or prototype
 129                       (setf prototype (allocate-instance class)))))))
 130   (def std-class)
 131   (def condition-class)
 132   (def structure-class))
 133
 134 (defmethod class-direct-default-initargs ((class slot-class))
 135   (plist-value class 'direct-default-initargs))
 136
 137 (defmethod class-default-initargs ((class slot-class))
 138   (plist-value class 'default-initargs))
 139
 140 (defmethod class-slot-cells ((class std-class))
 141   (plist-value class 'class-slot-cells))
 142 (defmethod (setf class-slot-cells) (new-value (class std-class))
 143   (setf (plist-value class 'class-slot-cells) new-value))
 144 \f
 145 ;;;; class accessors that are even a little bit more complicated than those
 146 ;;;; above. These have a protocol for updating them, we must implement that
 147 ;;;; protocol.
 148
 149 ;;; Maintaining the direct subclasses backpointers. The update methods are
 150 ;;; here, the values are read by an automatically generated reader method.
 151 (defmethod add-direct-subclass ((class class) (subclass class))
 152   (with-slots (direct-subclasses) class
 153     (pushnew subclass direct-subclasses :test #'eq)
 154     subclass))
 155 (defmethod remove-direct-subclass ((class class) (subclass class))
 156   (with-slots (direct-subclasses) class
 157     (setq direct-subclasses (remove subclass direct-subclasses))
 158     subclass))
 159
 160 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 161 ;;;
 162 ;;; There are four generic functions involved, each has one method for the
 163 ;;; class case and another method for the damned EQL specializers. All of
 164 ;;; these are specified methods and appear in their specified place in the
 165 ;;; class graph.
 166 ;;;
 167 ;;;   ADD-DIRECT-METHOD
 168 ;;;   REMOVE-DIRECT-METHOD
 169 ;;;   SPECIALIZER-DIRECT-METHODS
 170 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 171 ;;;
 172 ;;; In each case, we maintain one value which is a cons. The car is the list
 173 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 174 ;;; computed lazily.
 175
 176 ;;; This needs to be used recursively, in case a non-trivial user
 177 ;;; defined ADD/REMOVE-DIRECT-METHOD method ends up calling another
 178 ;;; function using the same lock.
 179 (defvar *specializer-lock* (sb-thread::make-spinlock :name "Specializer lock"))
 180
 181 (defmethod add-direct-method :around ((specializer specializer) method)
 182   ;; All the actions done under this lock are done in an order
 183   ;; that is safe to unwind at any point.
 184   (sb-thread::with-recursive-spinlock (*specializer-lock*)
 185     (call-next-method)))
 186
 187 (defmethod remove-direct-method :around ((specializer specializer) method)
 188   ;; All the actions done under this lock are done in an order
 189   ;; that is safe to unwind at any point.
 190   (sb-thread::with-recursive-spinlock (*specializer-lock*)
 191     (call-next-method)))
 192
 193 (defmethod add-direct-method ((specializer class) (method method))
 194   (let ((cell (slot-value specializer 'direct-methods)))
 195     ;; We need to first smash the CDR, because a parallel read may
 196     ;; be in progress, and because if an interrupt catches us we
 197     ;; need to have a consistent state.
 198     (setf (cdr cell) ()
 199           (car cell) (adjoin method (car cell) :test #'eq)))
 200   method)
 201
 202 (defmethod remove-direct-method ((specializer class) (method method))
 203   (let ((cell (slot-value specializer 'direct-methods)))
 204     ;; We need to first smash the CDR, because a parallel read may
 205     ;; be in progress, and because if an interrupt catches us we
 206     ;; need to have a consistent state.
 207     (setf (cdr cell) ()
 208           (car cell) (remove method (car cell))))
 209   method)
 210
 211 (defmethod specializer-direct-methods ((specializer class))
 212   (with-slots (direct-methods) specializer
 213     (car direct-methods)))
 214
 215 (defmethod specializer-direct-generic-functions ((specializer class))
 216   (let ((cell (slot-value specializer 'direct-methods)))
 217     ;; If an ADD/REMOVE-METHOD is in progress, no matter: either
 218     ;; we behave as if we got just first or just after -- it's just
 219     ;; for update that we need to lock.
 220     (or (cdr cell)
 221         (sb-thread::with-spinlock (*specializer-lock*)
 222           (setf (cdr cell)
 223                 (let (collect)
 224                   (dolist (m (car cell))
 225                     ;; the old PCL code used COLLECTING-ONCE which used
 226                     ;; #'EQ to check for newness
 227                     (pushnew (method-generic-function m) collect :test #'eq))
 228                   (nreverse collect)))))))
 229 \f
 230 ;;; This hash table is used to store the direct methods and direct generic
 231 ;;; functions of EQL specializers. Each value in the table is the cons.
 232 ;;;
 233 ;;; These tables are shared between threads, so they need to be synchronized.
 234 (defvar *eql-specializer-methods* (make-hash-table :test 'eql :synchronized t))
 235 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq :synchronized t))
 236
 237 (defmethod specializer-method-table ((specializer eql-specializer))
 238   *eql-specializer-methods*)
 239
 240 (defmethod specializer-method-table ((specializer class-eq-specializer))
 241   *class-eq-specializer-methods*)
 242
 243 (defmethod add-direct-method ((specializer specializer-with-object)
 244                               (method method))
 245   (let* ((object (specializer-object specializer))
 246          (table (specializer-method-table specializer))
 247          (entry (gethash object table)))
 248     (unless entry
 249       (setf entry
 250             (setf (gethash object table) (cons nil nil))))
 251     ;; We need to first smash the CDR, because a parallel read may
 252     ;; be in progress, and because if an interrupt catches us we
 253     ;; need to have a consistent state.
 254     (setf (cdr entry) ()
 255           (car entry) (adjoin method (car entry) :test #'eq))
 256     method))
 257
 258 (defmethod remove-direct-method ((specializer specializer-with-object)
 259                                  (method method))
 260   (let* ((object (specializer-object specializer))
 261          (entry (gethash object (specializer-method-table specializer))))
 262     (when entry
 263       ;; We need to first smash the CDR, because a parallel read may
 264       ;; be in progress, and because if an interrupt catches us we
 265       ;; need to have a consistent state.
 266       (setf (cdr entry) ()
 267             (car entry) (remove method (car entry))))
 268     method))
 269
 270 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 271   (car (gethash (specializer-object specializer)
 272                 (specializer-method-table specializer))))
 273
 274 (defmethod specializer-direct-generic-functions ((specializer
 275                                                   specializer-with-object))
 276   (let* ((object (specializer-object specializer))
 277          (entry (gethash object (specializer-method-table specializer))))
 278     (when entry
 279       (or (cdr entry)
 280           (sb-thread::with-spinlock (*specializer-lock*)
 281             (setf (cdr entry)
 282                   (let (collect)
 283                     (dolist (m (car entry))
 284                       (pushnew (method-generic-function m) collect :test #'eq))
 285                     (nreverse collect))))))))
 286
 287 (defun map-specializers (function)
 288   (map-all-classes (lambda (class)
 289                      (funcall function (class-eq-specializer class))
 290                      (funcall function class)))
 291   (maphash (lambda (object methods)
 292              (declare (ignore methods))
 293              (intern-eql-specializer object))
 294            *eql-specializer-methods*)
 295   (maphash (lambda (object specl)
 296              (declare (ignore object))
 297              (funcall function specl))
 298            *eql-specializer-table*)
 299   nil)
 300
 301 (defun map-all-generic-functions (function)
 302   (let ((all-generic-functions (make-hash-table :test 'eq)))
 303     (map-specializers (lambda (specl)
 304                         (dolist (gf (specializer-direct-generic-functions
 305                                      specl))
 306                           (unless (gethash gf all-generic-functions)
 307                             (setf (gethash gf all-generic-functions) t)
 308                             (funcall function gf))))))
 309   nil)
 310
 311 (defmethod shared-initialize :after ((specl class-eq-specializer)
 312                                      slot-names
 313                                      &key)
 314   (declare (ignore slot-names))
 315   (setf (slot-value specl '%type) `(class-eq ,(specializer-class specl))))
 316
 317 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 318   (declare (ignore slot-names))
 319   (setf (slot-value specl '%type)
 320         `(eql ,(specializer-object specl)))
 321   (setf (info :type :translator specl)
 322         (constantly (make-member-type :members (list (specializer-object specl))))))
 323
 324 (defun real-load-defclass (name metaclass-name supers slots other
 325                            readers writers slot-names source-location safe-p)
 326   (with-single-package-locked-error (:symbol name "defining ~S as a class")
 327     (%compiler-defclass name readers writers slot-names)
 328     (let ((res (apply #'ensure-class name :metaclass metaclass-name
 329                       :direct-superclasses supers
 330                       :direct-slots slots
 331                       :definition-source source-location
 332                       'safe-p safe-p
 333                       other)))
 334       res)))
 335
 336 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 337
 338 (defun ensure-class (name &rest args)
 339   (apply #'ensure-class-using-class
 340          (let ((class (find-class name nil)))
 341            (when (and class (eq name (class-name class)))
 342              ;; NAME is the proper name of CLASS, so redefine it
 343              class))
 344          name
 345          args))
 346
 347 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 348   (multiple-value-bind (meta initargs)
 349       (frob-ensure-class-args args)
 350     (setf class (apply #'make-instance meta :name name initargs))
 351     (without-package-locks
 352       (setf (find-class name) class))
 353     (set-class-type-translation class name)
 354     class))
 355
 356 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 357   (multiple-value-bind (meta initargs)
 358       (frob-ensure-class-args args)
 359     (unless (eq (class-of class) meta)
 360       (apply #'change-class class meta initargs))
 361     (apply #'reinitialize-instance class initargs)
 362     (without-package-locks
 363       (setf (find-class name) class))
 364     (set-class-type-translation class name)
 365     class))
 366
 367 (defun frob-ensure-class-args (args)
 368   (let (metaclass metaclassp reversed-plist)
 369     (flet ((frob-superclass (s)
 370              (cond
 371                ((classp s) s)
 372                ((legal-class-name-p s)
 373                 (or (find-class s nil)
 374                     (ensure-class s :metaclass 'forward-referenced-class)))
 375                (t (error "Not a class or a legal class name: ~S." s)))))
 376       (doplist (key val) args
 377         (cond ((eq key :metaclass)
 378                (unless metaclassp
 379                  (setf metaclass val metaclassp key)))
 380               (t
 381                (when (eq key :direct-superclasses)
 382                  (setf val (mapcar #'frob-superclass val)))
 383                (setf reversed-plist (list* val key reversed-plist)))))
 384       (values (cond (metaclassp
 385                      (if (classp metaclass)
 386                          metaclass
 387                          (find-class metaclass)))
 388                     (t *the-class-standard-class*))
 389               (nreverse reversed-plist)))))
 390 \f
 391 (defmethod shared-initialize :after
 392     ((class std-class) slot-names &key
 393      (direct-superclasses nil direct-superclasses-p)
 394      (direct-slots nil direct-slots-p)
 395      (direct-default-initargs nil direct-default-initargs-p)
 396      definition-source)
 397   (cond (direct-superclasses-p
 398          (setq direct-superclasses
 399                (or direct-superclasses
 400                    (list (if (funcallable-standard-class-p class)
 401                              *the-class-funcallable-standard-object*
 402                              *the-class-standard-object*))))
 403          (dolist (superclass direct-superclasses)
 404            (unless (validate-superclass class superclass)
 405              (error "~@<The class ~S was specified as a ~
 406                      super-class of the class ~S, ~
 407                      but the meta-classes ~S and ~S are incompatible.  ~
 408                      Define a method for ~S to avoid this error.~@:>"
 409                      superclass class (class-of superclass) (class-of class)
 410                      'validate-superclass)))
 411          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 412         (t
 413          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 414   (setq direct-slots
 415         (if direct-slots-p
 416             (setf (slot-value class 'direct-slots)
 417                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 418                           direct-slots))
 419             (slot-value class 'direct-slots)))
 420   (if direct-default-initargs-p
 421       (setf (plist-value class 'direct-default-initargs)
 422             direct-default-initargs)
 423       (setq direct-default-initargs
 424             (plist-value class 'direct-default-initargs)))
 425   (setf (plist-value class 'class-slot-cells)
 426         (let ((old-class-slot-cells (plist-value class 'class-slot-cells))
 427               (collect '()))
 428           (dolist (dslotd direct-slots)
 429             (when (eq :class (slot-definition-allocation dslotd))
 430               ;; see CLHS 4.3.6
 431               (let* ((name (slot-definition-name dslotd))
 432                      (old (assoc name old-class-slot-cells)))
 433                 (if (or (not old)
 434                         (eq t slot-names)
 435                         (member name slot-names :test #'eq))
 436                     (let* ((initfunction (slot-definition-initfunction dslotd))
 437                            (value (if initfunction
 438                                       (funcall initfunction)
 439                                       +slot-unbound+)))
 440                       (push (cons name value) collect))
 441                     (push old collect)))))
 442           (nreverse collect)))
 443   (add-direct-subclasses class direct-superclasses)
 444   (if (class-finalized-p class)
 445       ;; required by AMOP, "Reinitialization of Class Metaobjects"
 446       (finalize-inheritance class)
 447       (update-class class nil))
 448   (add-slot-accessors class direct-slots definition-source)
 449   (make-preliminary-layout class))
 450
 451 (defmethod shared-initialize :after ((class forward-referenced-class)
 452                                      slot-names &key &allow-other-keys)
 453   (declare (ignore slot-names))
 454   (make-preliminary-layout class))
 455
 456 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 457
 458 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 459 ;;; make it known to the type system.
 460 (defun make-preliminary-layout (class)
 461   (flet ((compute-preliminary-cpl (root)
 462            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 463              (compute-class-precedence-list root))))
 464     (without-package-locks
 465      (unless (class-finalized-p class)
 466        (let ((name (class-name class)))
 467          ;; KLUDGE: This is fairly horrible.  We need to make a
 468          ;; full-fledged CLASSOID here, not just tell the compiler that
 469          ;; some class is forthcoming, because there are legitimate
 470          ;; questions one can ask of the type system, implemented in
 471          ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 472          (let ((layout (make-wrapper 0 class)))
 473            (setf (slot-value class 'wrapper) layout)
 474            (let ((cpl (compute-preliminary-cpl class)))
 475              (setf (layout-inherits layout)
 476                    (order-layout-inherits
 477                     (map 'simple-vector #'class-wrapper
 478                          (reverse (rest cpl))))))
 479            (register-layout layout :invalidate t)
 480            (set-class-type-translation class (layout-classoid layout)))))
 481      (mapc #'make-preliminary-layout (class-direct-subclasses class)))))
 482
 483
 484 (defmethod shared-initialize :before ((class class) slot-names &key name)
 485   (declare (ignore slot-names name))
 486   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 487   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 488   (setf (slot-value class '%type) `(class ,class))
 489   (setf (slot-value class 'class-eq-specializer)
 490         (make-instance 'class-eq-specializer :class class)))
 491
 492 (defmethod reinitialize-instance :before ((class slot-class) &key direct-superclasses)
 493   (dolist (old-super (set-difference (class-direct-superclasses class) direct-superclasses))
 494     (remove-direct-subclass old-super class))
 495   (remove-slot-accessors    class (class-direct-slots class)))
 496
 497 (defmethod reinitialize-instance :after ((class slot-class)
 498                                          &rest initargs
 499                                          &key)
 500   (map-dependents class
 501                   (lambda (dependent)
 502                     (apply #'update-dependent class dependent initargs))))
 503
 504 (defmethod reinitialize-instance :after ((class condition-class) &key)
 505   (let* ((name (class-name class))
 506          (classoid (find-classoid name))
 507          (slots (condition-classoid-slots classoid)))
 508     ;; to balance the REMOVE-SLOT-ACCESSORS call in
 509     ;; REINITIALIZE-INSTANCE :BEFORE (SLOT-CLASS).
 510     (dolist (slot slots)
 511       (let ((slot-name (condition-slot-name slot)))
 512         (dolist (reader (condition-slot-readers slot))
 513           ;; FIXME: see comment in SHARED-INITIALIZE :AFTER
 514           ;; (CONDITION-CLASS T), below.  -- CSR, 2005-11-18
 515           (sb-kernel::install-condition-slot-reader reader name slot-name))
 516         (dolist (writer (condition-slot-writers slot))
 517           (sb-kernel::install-condition-slot-writer writer name slot-name))))))
 518
 519 (defmethod shared-initialize :after ((class condition-class) slot-names
 520                                      &key direct-slots direct-superclasses)
 521   (declare (ignore slot-names))
 522   (let ((classoid (find-classoid (class-name class))))
 523     (with-slots (wrapper %class-precedence-list cpl-available-p
 524                          prototype (direct-supers direct-superclasses))
 525         class
 526       (setf (slot-value class 'direct-slots)
 527             (mapcar (lambda (pl) (make-direct-slotd class pl))
 528                     direct-slots))
 529       (setf (slot-value class 'finalized-p) t)
 530       (setf (classoid-pcl-class classoid) class)
 531       (setq direct-supers direct-superclasses)
 532       (setq wrapper (classoid-layout classoid))
 533       (setq %class-precedence-list (compute-class-precedence-list class))
 534       (setq cpl-available-p t)
 535       (add-direct-subclasses class direct-superclasses)
 536       (let ((slots (compute-slots class)))
 537         (setf (slot-value class 'slots) slots)
 538         (setf (layout-slot-table wrapper) (make-slot-table class slots)))))
 539   ;; Comment from Gerd's PCL, 2003-05-15:
 540   ;;
 541   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 542   ;; override condition accessors with generic functions.  We do this
 543   ;; differently.
 544   ;;
 545   ;; ??? What does the above comment mean and why is it a good idea?
 546   ;; CMUCL (which still as of 2005-11-18 uses this code and has this
 547   ;; comment) loses slot information in its condition classes:
 548   ;; DIRECT-SLOTS is always NIL.  We have the right information, so we
 549   ;; remove slot accessors but never put them back.  I've added a
 550   ;; REINITIALIZE-INSTANCE :AFTER (CONDITION-CLASS) method, but what
 551   ;; was meant to happen?  -- CSR, 2005-11-18
 552   )
 553
 554 (defmethod direct-slot-definition-class ((class condition-class)
 555                                          &rest initargs)
 556   (declare (ignore initargs))
 557   (find-class 'condition-direct-slot-definition))
 558
 559 (defmethod effective-slot-definition-class ((class condition-class)
 560                                             &rest initargs)
 561   (declare (ignore initargs))
 562   (find-class 'condition-effective-slot-definition))
 563
 564 (defmethod finalize-inheritance ((class condition-class))
 565   (aver (slot-value class 'finalized-p))
 566   nil)
 567
 568 (defmethod compute-effective-slot-definition
 569     ((class condition-class) slot-name dslotds)
 570   (let ((slotd (call-next-method)))
 571     (setf (slot-definition-reader-function slotd)
 572           (lambda (x)
 573             (handler-case (condition-reader-function x slot-name)
 574               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 575               ;; is unbound; maybe it should be a CELL-ERROR of some
 576               ;; sort?
 577               (error () (values (slot-unbound class x slot-name))))))
 578     (setf (slot-definition-writer-function slotd)
 579           (lambda (v x)
 580             (condition-writer-function x v slot-name)))
 581     (setf (slot-definition-boundp-function slotd)
 582           (lambda (x)
 583             (multiple-value-bind (v c)
 584                 (ignore-errors (condition-reader-function x slot-name))
 585               (declare (ignore v))
 586               (null c))))
 587     slotd))
 588
 589 (defmethod compute-slots ((class condition-class))
 590   (mapcan (lambda (superclass)
 591             (mapcar (lambda (dslotd)
 592                       (compute-effective-slot-definition
 593                        class (slot-definition-name dslotd) (list dslotd)))
 594                     (class-direct-slots superclass)))
 595           (reverse (slot-value class '%class-precedence-list))))
 596
 597 (defmethod compute-slots :around ((class condition-class))
 598   (let ((eslotds (call-next-method)))
 599     (mapc #'initialize-internal-slot-functions eslotds)
 600     eslotds))
 601
 602 (defmethod shared-initialize :after
 603     ((slotd structure-slot-definition) slot-names &key
 604      (allocation :instance) allocation-class)
 605   (declare (ignore slot-names allocation-class))
 606   (unless (eq allocation :instance)
 607     (error "Structure slots must have :INSTANCE allocation.")))
 608
 609 (defun make-structure-class-defstruct-form (name direct-slots include)
 610   (let* ((conc-name (format-symbol *package* "~S structure class " name))
 611          (constructor (format-symbol *package* "~Aconstructor" conc-name))
 612          (defstruct `(defstruct (,name
 613                                  ,@(when include
 614                                          `((:include ,(class-name include))))
 615                                  (:predicate nil)
 616                                  (:conc-name ,conc-name)
 617                                  (:constructor ,constructor ())
 618                                  (:copier nil))
 619                       ,@(mapcar (lambda (slot)
 620                                   `(,(slot-definition-name slot)
 621                                     +slot-unbound+))
 622                                 direct-slots)))
 623          (reader-names (mapcar (lambda (slotd)
 624                                  (list 'slot-accessor name
 625                                        (slot-definition-name slotd)
 626                                        'reader))
 627                                direct-slots))
 628          (writer-names (mapcar (lambda (slotd)
 629                                  (list 'slot-accessor name
 630                                        (slot-definition-name slotd)
 631                                        'writer))
 632                                direct-slots))
 633          (readers-init
 634            (mapcar (lambda (slotd reader-name)
 635                      (let ((accessor
 636                              (slot-definition-defstruct-accessor-symbol
 637                               slotd)))
 638                        `(defun ,reader-name (obj)
 639                          (declare (type ,name obj))
 640                          (,accessor obj))))
 641                    direct-slots reader-names))
 642          (writers-init
 643            (mapcar (lambda (slotd writer-name)
 644                      (let ((accessor
 645                              (slot-definition-defstruct-accessor-symbol
 646                               slotd)))
 647                        `(defun ,writer-name (nv obj)
 648                          (declare (type ,name obj))
 649                          (setf (,accessor obj) nv))))
 650                    direct-slots writer-names))
 651          (defstruct-form
 652              `(progn
 653                ,defstruct
 654                ,@readers-init ,@writers-init
 655                (cons nil nil))))
 656     (values defstruct-form constructor reader-names writer-names)))
 657
 658 (defun make-defstruct-allocation-function (class)
 659   ;; FIXME: Why don't we go class->layout->info == dd
 660   (let ((dd (find-defstruct-description (class-name class))))
 661     (%make-structure-instance-allocator dd nil)))
 662
 663 (defmethod shared-initialize :after
 664     ((class structure-class) slot-names &key
 665      (direct-superclasses nil direct-superclasses-p)
 666      (direct-slots nil direct-slots-p)
 667      direct-default-initargs
 668      definition-source)
 669   (declare (ignore slot-names direct-default-initargs))
 670   (if direct-superclasses-p
 671       (setf (slot-value class 'direct-superclasses)
 672             (or direct-superclasses
 673                 (setq direct-superclasses
 674                       (and (not (eq (class-name class) 'structure-object))
 675                            (list *the-class-structure-object*)))))
 676       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 677   (let* ((name (class-name class))
 678          (from-defclass-p (slot-value class 'from-defclass-p))
 679          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 680     (if direct-slots-p
 681         (setf (slot-value class 'direct-slots)
 682               (setq direct-slots
 683                     (mapcar (lambda (pl)
 684                               (when defstruct-p
 685                                 (let* ((slot-name (getf pl :name))
 686                                        (accessor
 687                                         (format-symbol *package*
 688                                                        "~S structure class ~A"
 689                                                        name slot-name)))
 690                                   (setq pl (list* :defstruct-accessor-symbol
 691                                                   accessor pl))))
 692                               (make-direct-slotd class pl))
 693                             direct-slots)))
 694         (setq direct-slots (slot-value class 'direct-slots)))
 695     (if defstruct-p
 696         (let ((include (car (slot-value class 'direct-superclasses))))
 697           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 698               (make-structure-class-defstruct-form name direct-slots include)
 699             (unless (structure-type-p name) (eval defstruct-form))
 700             (mapc (lambda (dslotd reader-name writer-name)
 701                     (let* ((reader (gdefinition reader-name))
 702                            (writer (when (fboundp writer-name)
 703                                      (gdefinition writer-name))))
 704                       (setf (slot-value dslotd 'internal-reader-function)
 705                             reader)
 706                       (setf (slot-value dslotd 'internal-writer-function)
 707                             writer)))
 708                   direct-slots reader-names writer-names)
 709             (setf (slot-value class 'defstruct-form) defstruct-form)
 710             (setf (slot-value class 'defstruct-constructor) constructor)))
 711         (setf (slot-value class 'defstruct-constructor)
 712               (make-defstruct-allocation-function class)))
 713     (add-direct-subclasses class direct-superclasses)
 714     (setf (slot-value class '%class-precedence-list)
 715           (compute-class-precedence-list class))
 716     (setf (slot-value class 'cpl-available-p) t)
 717     (let ((slots (compute-slots class)))
 718       (setf (slot-value class 'slots) slots)
 719       (let* ((lclass (find-classoid (class-name class)))
 720              (layout (classoid-layout lclass)))
 721         (setf (classoid-pcl-class lclass) class)
 722         (setf (slot-value class 'wrapper) layout)
 723         (setf (layout-slot-table layout) (make-slot-table class slots))))
 724     (setf (slot-value class 'finalized-p) t)
 725     (add-slot-accessors class direct-slots definition-source)))
 726
 727 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 728   (declare (ignore initargs))
 729   (find-class 'structure-direct-slot-definition))
 730
 731 (defmethod finalize-inheritance ((class structure-class))
 732   nil) ; always finalized
 733 \f
 734 (defun add-slot-accessors (class dslotds &optional source-location)
 735   (fix-slot-accessors class dslotds 'add source-location))
 736
 737 (defun remove-slot-accessors (class dslotds)
 738   (fix-slot-accessors class dslotds 'remove))
 739
 740 (defun fix-slot-accessors (class dslotds add/remove &optional source-location)
 741   (flet ((fix (gfspec name r/w doc)
 742            (let ((gf (cond ((eq add/remove 'add)
 743                             (or (find-generic-function gfspec nil)
 744                                 (ensure-generic-function
 745                                  gfspec :lambda-list (case r/w
 746                                                        (r '(object))
 747                                                        (w '(new-value object))))))
 748                            (t
 749                             (find-generic-function gfspec nil)))))
 750              (when gf
 751                (case r/w
 752                  (r (if (eq add/remove 'add)
 753                         (add-reader-method class gf name doc source-location)
 754                         (remove-reader-method class gf)))
 755                  (w (if (eq add/remove 'add)
 756                         (add-writer-method class gf name doc source-location)
 757                         (remove-writer-method class gf))))))))
 758     (dolist (dslotd dslotds)
 759       (let ((slot-name (slot-definition-name dslotd))
 760             (slot-doc (%slot-definition-documentation dslotd)))
 761         (dolist (r (slot-definition-readers dslotd))
 762           (fix r slot-name 'r slot-doc))
 763         (dolist (w (slot-definition-writers dslotd))
 764           (fix w slot-name 'w slot-doc))))))
 765 \f
 766 (defun add-direct-subclasses (class supers)
 767   (dolist (super supers)
 768     (unless (memq class (class-direct-subclasses class))
 769       (add-direct-subclass super class))))
 770
 771 (defmethod finalize-inheritance ((class std-class))
 772   (update-class class t))
 773
 774 (defmethod finalize-inheritance ((class forward-referenced-class))
 775   ;; FIXME: should we not be thinking a bit about what kinds of error
 776   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 777   ;; possibly a forward-referenced-class-error, though that's
 778   ;; difficult given e.g. class precedence list calculations...
 779   (error
 780    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 781        ~2I~_~S~:>"
 782    class))
 783
 784 \f
 785 (defun class-has-a-forward-referenced-superclass-p (class)
 786   (or (forward-referenced-class-p class)
 787       (some #'class-has-a-forward-referenced-superclass-p
 788             (class-direct-superclasses class))))
 789
 790 ;;; This is called by :after shared-initialize whenever a class is initialized
 791 ;;; or reinitialized. The class may or may not be finalized.
 792 (defun update-class (class finalizep)
 793   (without-package-locks
 794     (when (or finalizep (class-finalized-p class))
 795       (update-cpl class (compute-class-precedence-list class))
 796       ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 797       ;; class.
 798       (update-slots class (compute-slots class))
 799       (update-gfs-of-class class)
 800       (update-initargs class (compute-default-initargs class))
 801       (update-ctors 'finalize-inheritance :class class))
 802     (dolist (sub (class-direct-subclasses class))
 803       (update-class sub nil))))
 804
 805 (define-condition cpl-protocol-violation (reference-condition error)
 806   ((class :initarg :class :reader cpl-protocol-violation-class)
 807    (cpl :initarg :cpl :reader cpl-protocol-violation-cpl))
 808   (:default-initargs :references (list '(:sbcl :node "Metaobject Protocol")))
 809   (:report
 810    (lambda (c s)
 811      (format s "~@<Protocol violation: the ~S class ~S ~
 812                 ~:[has~;does not have~] the class ~S in its ~
 813                 class precedence list: ~S.~@:>"
 814              (class-name (class-of (cpl-protocol-violation-class c)))
 815              (cpl-protocol-violation-class c)
 816              (eq (class-of (cpl-protocol-violation-class c))
 817                  *the-class-funcallable-standard-class*)
 818              (find-class 'function)
 819              (cpl-protocol-violation-cpl c)))))
 820
 821 (defun update-cpl (class cpl)
 822   (when (eq (class-of class) *the-class-standard-class*)
 823     (when (find (find-class 'function) cpl)
 824       (error 'cpl-protocol-violation :class class :cpl cpl)))
 825   (when (eq (class-of class) *the-class-funcallable-standard-class*)
 826     (unless (find (find-class 'function) cpl)
 827       (error 'cpl-protocol-violation :class class :cpl cpl)))
 828   (if (class-finalized-p class)
 829       (unless (and (equal (class-precedence-list class) cpl)
 830                    (dolist (c cpl t)
 831                      (when (position :class (class-direct-slots c)
 832                                      :key #'slot-definition-allocation)
 833                        (return nil))))
 834         ;; comment from the old CMU CL sources:
 835         ;;   Need to have the cpl setup before update-lisp-class-layout
 836         ;;   is called on CMU CL.
 837         (setf (slot-value class '%class-precedence-list) cpl)
 838         (setf (slot-value class 'cpl-available-p) t)
 839         (force-cache-flushes class))
 840       (progn
 841         (setf (slot-value class '%class-precedence-list) cpl)
 842         (setf (slot-value class 'cpl-available-p) t)))
 843   (update-class-can-precede-p cpl))
 844
 845 (defun update-class-can-precede-p (cpl)
 846   (when cpl
 847     (let ((first (car cpl)))
 848       (dolist (c (cdr cpl))
 849         (pushnew c (slot-value first 'can-precede-list) :test #'eq)))
 850     (update-class-can-precede-p (cdr cpl))))
 851
 852 (defun class-can-precede-p (class1 class2)
 853   (member class2 (class-can-precede-list class1) :test #'eq))
 854
 855 (defun update-slots (class eslotds)
 856   (let ((instance-slots ())
 857         (class-slots    ()))
 858     (dolist (eslotd eslotds)
 859       (let ((alloc (slot-definition-allocation eslotd)))
 860         (case alloc
 861           (:instance (push eslotd instance-slots))
 862           (:class (push eslotd class-slots)))))
 863
 864     ;; If there is a change in the shape of the instances then the
 865     ;; old class is now obsolete.
 866     (let* ((nlayout (mapcar #'slot-definition-name
 867                             (sort instance-slots #'<
 868                                   :key #'slot-definition-location)))
 869            (nslots (length nlayout))
 870            (nwrapper-class-slots (compute-class-slots class-slots))
 871            (owrapper (when (class-finalized-p class)
 872                        (class-wrapper class)))
 873            (olayout (when owrapper
 874                       (wrapper-instance-slots-layout owrapper)))
 875            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 876            (nwrapper
 877             (cond ((null owrapper)
 878                    (make-wrapper nslots class))
 879                   ((and (equal nlayout olayout)
 880                         (not
 881                          (loop for o in owrapper-class-slots
 882                                for n in nwrapper-class-slots
 883                                do (unless (eq (car o) (car n)) (return t)))))
 884                    owrapper)
 885                   (t
 886                    ;; This will initialize the new wrapper to have the
 887                    ;; same state as the old wrapper. We will then have
 888                    ;; to change that. This may seem like wasted work
 889                    ;; (and it is), but the spec requires that we call
 890                    ;; MAKE-INSTANCES-OBSOLETE.
 891                    (make-instances-obsolete class)
 892                    (class-wrapper class)))))
 893
 894       (update-lisp-class-layout class nwrapper)
 895       (setf (slot-value class 'slots) eslotds
 896             (wrapper-slot-table nwrapper) (make-slot-table class eslotds)
 897             (wrapper-instance-slots-layout nwrapper) nlayout
 898             (wrapper-class-slots nwrapper) nwrapper-class-slots
 899             (wrapper-length nwrapper) nslots
 900             (slot-value class 'wrapper) nwrapper)
 901       (do* ((slots (slot-value class 'slots) (cdr slots))
 902             (dupes nil))
 903            ((null slots)
 904             (when dupes
 905               (style-warn
 906                "~@<slot names with the same SYMBOL-NAME but ~
 907                   different SYMBOL-PACKAGE (possible package problem) ~
 908                   for class ~S:~4I~@:_~<~@{~S~^~:@_~}~:>~@:>"
 909                class dupes)))
 910         (let* ((slot (car slots))
 911                (oslots (remove (slot-definition-name slot) (cdr slots)
 912                                :test #'string/=
 913                                :key #'slot-definition-name)))
 914           (when oslots
 915             (pushnew (cons (slot-definition-name slot)
 916                            (mapcar #'slot-definition-name oslots))
 917                      dupes
 918                      :test #'string= :key #'car))))
 919       (setf (slot-value class 'finalized-p) t)
 920       (unless (eq owrapper nwrapper)
 921         (maybe-update-standard-class-locations class)))))
 922
 923 (defun compute-class-slots (eslotds)
 924   (let (collect)
 925     (dolist (eslotd eslotds (nreverse collect))
 926       (let ((cell (assoc (slot-definition-name eslotd)
 927                          (class-slot-cells
 928                           (slot-definition-allocation-class eslotd)))))
 929         (aver cell)
 930         (push cell collect)))))
 931
 932 (defun update-gfs-of-class (class)
 933   (when (and (class-finalized-p class)
 934              (let ((cpl (class-precedence-list class)))
 935                (or (member *the-class-slot-class* cpl :test #'eq)
 936                    (member *the-class-standard-effective-slot-definition*
 937                            cpl :test #'eq))))
 938     (let ((gf-table (make-hash-table :test 'eq)))
 939       (labels ((collect-gfs (class)
 940                  (dolist (gf (specializer-direct-generic-functions class))
 941                    (setf (gethash gf gf-table) t))
 942                  (mapc #'collect-gfs (class-direct-superclasses class))))
 943         (collect-gfs class)
 944         (maphash (lambda (gf ignore)
 945                    (declare (ignore ignore))
 946                    (update-gf-dfun class gf))
 947                  gf-table)))))
 948
 949 (defun update-initargs (class inits)
 950   (setf (plist-value class 'default-initargs) inits))
 951 \f
 952 (defmethod compute-default-initargs ((class slot-class))
 953   (let ((initargs (loop for c in (class-precedence-list class)
 954                         append (class-direct-default-initargs c))))
 955     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
 956 \f
 957 ;;;; protocols for constructing direct and effective slot definitions
 958
 959 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
 960   (declare (ignore initargs))
 961   (find-class 'standard-direct-slot-definition))
 962
 963 (defun make-direct-slotd (class initargs)
 964   (apply #'make-instance
 965          (apply #'direct-slot-definition-class class initargs)
 966          :class class
 967          initargs))
 968
 969 ;;; I (CSR) am not sure, but I believe that the particular order of
 970 ;;; slots is quite important: it is ideal to attempt to have a
 971 ;;; constant slot location for the same notional slots as much as
 972 ;;; possible, so that clever discriminating functions (ONE-INDEX et
 973 ;;; al.) have a chance of working.  The below at least walks through
 974 ;;; the slots predictably, but maybe it would be good to compute some
 975 ;;; kind of optimal slot layout by looking at locations of slots in
 976 ;;; superclasses?
 977 (defun std-compute-slots (class)
 978   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 979   ;; for each different slot name we find in our superclasses. Each
 980   ;; call receives the class and a list of the dslotds with that name.
 981   ;; The list is in most-specific-first order.
 982   (let ((name-dslotds-alist ()))
 983     (dolist (c (reverse (class-precedence-list class)))
 984       (dolist (slot (class-direct-slots c))
 985         (let* ((name (slot-definition-name slot))
 986                (entry (assq name name-dslotds-alist)))
 987           (if entry
 988               (push slot (cdr entry))
 989               (push (list name slot) name-dslotds-alist)))))
 990     (mapcar (lambda (direct)
 991               (compute-effective-slot-definition class
 992                                                  (car direct)
 993                                                  (cdr direct)))
 994             (nreverse name-dslotds-alist))))
 995
 996 (defmethod compute-slots ((class standard-class))
 997   (std-compute-slots class))
 998 (defmethod compute-slots ((class funcallable-standard-class))
 999   (std-compute-slots class))
1000
1001 (defun std-compute-slots-around (class eslotds)
1002   (let ((location -1))
1003     (dolist (eslotd eslotds eslotds)
1004       (setf (slot-definition-location eslotd)
1005             (case (slot-definition-allocation eslotd)
1006               (:instance
1007                (incf location))
1008               (:class
1009                (let* ((name (slot-definition-name eslotd))
1010                       (from-class
1011                        (or
1012                         (slot-definition-allocation-class eslotd)
1013                         ;; we get here if the user adds an extra slot
1014                         ;; himself...
1015                         (setf (slot-definition-allocation-class eslotd)
1016                               class)))
1017                       ;; which raises the question of what we should
1018                       ;; do if we find that said user has added a slot
1019                       ;; with the same name as another slot...
1020                       (cell (or (assq name (class-slot-cells from-class))
1021                                 (let ((c (cons name +slot-unbound+)))
1022                                   (push c (class-slot-cells from-class))
1023                                   c))))
1024                  (aver (consp cell))
1025                  (if (eq +slot-unbound+ (cdr cell))
1026                      ;; We may have inherited an initfunction
1027                      (let ((initfun (slot-definition-initfunction eslotd)))
1028                        (if initfun
1029                            (rplacd cell (funcall initfun))
1030                            cell))
1031                      cell)))))
1032       (unless (slot-definition-class eslotd)
1033         (setf (slot-definition-class eslotd) class))
1034       (initialize-internal-slot-functions eslotd))))
1035
1036 (defmethod compute-slots :around ((class standard-class))
1037   (let ((eslotds (call-next-method)))
1038     (std-compute-slots-around class eslotds)))
1039 (defmethod compute-slots :around ((class funcallable-standard-class))
1040   (let ((eslotds (call-next-method)))
1041     (std-compute-slots-around class eslotds)))
1042
1043 (defmethod compute-slots ((class structure-class))
1044   (mapcan (lambda (superclass)
1045             (mapcar (lambda (dslotd)
1046                       (compute-effective-slot-definition
1047                        class
1048                        (slot-definition-name dslotd)
1049                        (list dslotd)))
1050                     (class-direct-slots superclass)))
1051           (reverse (slot-value class '%class-precedence-list))))
1052
1053 (defmethod compute-slots :around ((class structure-class))
1054   (let ((eslotds (call-next-method)))
1055     (mapc #'initialize-internal-slot-functions eslotds)
1056     eslotds))
1057
1058 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1059   (declare (ignore name))
1060   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1061          (class (apply #'effective-slot-definition-class class initargs)))
1062     (apply #'make-instance class initargs)))
1063
1064 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1065   (declare (ignore initargs))
1066   (find-class 'standard-effective-slot-definition))
1067
1068 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1069   (declare (ignore initargs))
1070   (find-class 'structure-effective-slot-definition))
1071
1072 (defmethod compute-effective-slot-definition-initargs
1073     ((class slot-class) direct-slotds)
1074   (let* ((name nil)
1075          (initfunction nil)
1076          (initform nil)
1077          (initargs nil)
1078          (allocation nil)
1079          (allocation-class nil)
1080          (type t)
1081          (type-check-function nil)
1082          (documentation nil)
1083          (documentationp nil)
1084          (namep  nil)
1085          (initp  nil)
1086          (allocp nil))
1087
1088     (dolist (slotd direct-slotds)
1089       (when slotd
1090         (unless namep
1091           (setq name (slot-definition-name slotd)
1092                 namep t))
1093         (unless initp
1094           (when (slot-definition-initfunction slotd)
1095             (setq initform (slot-definition-initform slotd)
1096                   initfunction (slot-definition-initfunction slotd)
1097                   initp t)))
1098         (unless documentationp
1099           (when (%slot-definition-documentation slotd)
1100             (setq documentation (%slot-definition-documentation slotd)
1101                   documentationp t)))
1102         (unless allocp
1103           (setq allocation (slot-definition-allocation slotd)
1104                 allocation-class (slot-definition-class slotd)
1105                 allocp t))
1106         (setq initargs (append (slot-definition-initargs slotd) initargs))
1107         (let ((fun (slot-definition-type-check-function slotd)))
1108           (when fun
1109             (setf type-check-function
1110                   (if type-check-function
1111                       (let ((old-function type-check-function))
1112                         (lambda (value)
1113                           (funcall old-function value)
1114                           (funcall fun value)))
1115                       fun))))
1116         (let ((slotd-type (slot-definition-type slotd)))
1117           (setq type (cond
1118                        ((eq type t) slotd-type)
1119                        ;; This pairwise type intersection is perhaps a
1120                        ;; little inefficient and inelegant, but it's
1121                        ;; unlikely to lie on the critical path.  Shout
1122                        ;; if I'm wrong.  -- CSR, 2005-11-24
1123                        (t (type-specifier
1124                            (specifier-type `(and ,type ,slotd-type)))))))))
1125     (list :name name
1126           :initform initform
1127           :initfunction initfunction
1128           :initargs initargs
1129           :allocation allocation
1130           :allocation-class allocation-class
1131           :type type
1132           'type-check-function type-check-function
1133           :class class
1134           :documentation documentation)))
1135
1136 (defmethod compute-effective-slot-definition-initargs :around
1137     ((class structure-class) direct-slotds)
1138   (let ((slotd (car direct-slotds)))
1139     (list* :defstruct-accessor-symbol
1140            (slot-definition-defstruct-accessor-symbol slotd)
1141            :internal-reader-function
1142            (slot-definition-internal-reader-function slotd)
1143            :internal-writer-function
1144            (slot-definition-internal-writer-function slotd)
1145            (call-next-method))))
1146 \f
1147 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1148 ;;;       to make the method object. They have to use make-a-method which
1149 ;;;       is a specially bootstrapped mechanism for making standard methods.
1150 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1151   (declare (ignore direct-slot initargs))
1152   (find-class 'standard-reader-method))
1153
1154 (defmethod add-reader-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1155   (add-method generic-function
1156               (make-a-method 'standard-reader-method
1157                              ()
1158                              (list (or (class-name class) 'object))
1159                              (list class)
1160                              (make-reader-method-function class slot-name)
1161                              (or slot-documentation "automatically generated reader method")
1162                              :slot-name slot-name
1163                              :object-class class
1164                              :method-class-function #'reader-method-class
1165                              :definition-source source-location)))
1166
1167 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1168   (declare (ignore direct-slot initargs))
1169   (find-class 'standard-writer-method))
1170
1171 (defmethod add-writer-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1172   (add-method generic-function
1173               (make-a-method 'standard-writer-method
1174                              ()
1175                              (list 'new-value (or (class-name class) 'object))
1176                              (list *the-class-t* class)
1177                              (make-writer-method-function class slot-name)
1178                              (or slot-documentation "automatically generated writer method")
1179                              :slot-name slot-name
1180                              :object-class class
1181                              :method-class-function #'writer-method-class
1182                              :definition-source source-location)))
1183
1184 (defmethod add-boundp-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1185   (add-method generic-function
1186               (make-a-method (constantly (find-class 'standard-boundp-method))
1187                              class
1188                              ()
1189                              (list (or (class-name class) 'object))
1190                              (list class)
1191                              (make-boundp-method-function class slot-name)
1192                              (or slot-documentation "automatically generated boundp method")
1193                              :slot-name slot-name
1194                              :definition-source source-location)))
1195
1196 (defmethod remove-reader-method ((class slot-class) generic-function)
1197   (let ((method (get-method generic-function () (list class) nil)))
1198     (when method (remove-method generic-function method))))
1199
1200 (defmethod remove-writer-method ((class slot-class) generic-function)
1201   (let ((method
1202           (get-method generic-function () (list *the-class-t* class) nil)))
1203     (when method (remove-method generic-function method))))
1204
1205 (defmethod remove-boundp-method ((class slot-class) generic-function)
1206   (let ((method (get-method generic-function () (list class) nil)))
1207     (when method (remove-method generic-function method))))
1208 \f
1209 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITER-METHOD-FUNCTION
1210 ;;; function are NOT part of the standard protocol. They are however
1211 ;;; useful; PCL makes use of them internally and documents them for
1212 ;;; PCL users.  (FIXME: but SBCL certainly doesn't)
1213 ;;;
1214 ;;; *** This needs work to make type testing by the writer functions which
1215 ;;; *** do type testing faster. The idea would be to have one constructor
1216 ;;; *** for each possible type test.
1217 ;;;
1218 ;;; *** There is a subtle bug here which is going to have to be fixed.
1219 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1220 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1221 ;;; *** defined for this metaclass a chance to run.
1222
1223 (defmethod make-reader-method-function ((class slot-class) slot-name)
1224   (make-std-reader-method-function class slot-name))
1225
1226 (defmethod make-writer-method-function ((class slot-class) slot-name)
1227   (make-std-writer-method-function class slot-name))
1228
1229 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1230   (make-std-boundp-method-function class slot-name))
1231 \f
1232 (defmethod compatible-meta-class-change-p (class proto-new-class)
1233   (eq (class-of class) (class-of proto-new-class)))
1234
1235 (defmethod validate-superclass ((class class) (superclass class))
1236   (or (eq superclass *the-class-t*)
1237       (eq (class-of class) (class-of superclass))
1238       (and (eq (class-of superclass) *the-class-standard-class*)
1239            (eq (class-of class) *the-class-funcallable-standard-class*))
1240       (and (eq (class-of superclass) *the-class-funcallable-standard-class*)
1241            (eq (class-of class) *the-class-standard-class*))))
1242 \f
1243 ;;; What this does depends on which of the four possible values of
1244 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1245 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1246 ;;; nothing to do, as the new wrapper has already been created.  If
1247 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1248 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1249 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1250 ;;;
1251 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1252 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1253 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1254 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1255 ;;; obsolete the wrapper.
1256 ;;;
1257 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1258 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1259 ;;;                    :UNINITIALIZED)))
1260 ;;;
1261 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1262 (defun force-cache-flushes (class)
1263   (let* ((owrapper (class-wrapper class)))
1264     ;; We only need to do something if the wrapper is still valid. If
1265     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1266     ;; both of those will already be doing what we want. In
1267     ;; particular, we must be sure we never change an OBSOLETE into a
1268     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1269     (when (or (not (invalid-wrapper-p owrapper))
1270               ;; KLUDGE: despite the observations above, this remains
1271               ;; a violation of locality or what might be considered
1272               ;; good style.  There has to be a better way!  -- CSR,
1273               ;; 2002-10-29
1274               (eq (layout-invalid owrapper) t))
1275       (let ((nwrapper (make-wrapper (layout-length owrapper)
1276                                     class)))
1277         (setf (wrapper-instance-slots-layout nwrapper)
1278               (wrapper-instance-slots-layout owrapper))
1279         (setf (wrapper-class-slots nwrapper)
1280               (wrapper-class-slots owrapper))
1281         (setf (wrapper-slot-table nwrapper)
1282               (wrapper-slot-table owrapper))
1283         (with-pcl-lock
1284           (update-lisp-class-layout class nwrapper)
1285           (setf (slot-value class 'wrapper) nwrapper)
1286           ;; Use :OBSOLETE instead of :FLUSH if any superclass has
1287           ;; been obsoleted.
1288           (if (find-if (lambda (x)
1289                          (and (consp x) (eq :obsolete (car x))))
1290                        (layout-inherits owrapper)
1291                        :key #'layout-invalid)
1292               (invalidate-wrapper owrapper :obsolete nwrapper)
1293               (invalidate-wrapper owrapper :flush nwrapper)))))))
1294
1295 (defun flush-cache-trap (owrapper nwrapper instance)
1296   (declare (ignore owrapper))
1297   (set-wrapper instance nwrapper))
1298 \f
1299 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1300 ;;; the next access to the instance (as defined in 88-002R) to trap
1301 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1302 (defmethod make-instances-obsolete ((class std-class))
1303   (let* ((owrapper (class-wrapper class))
1304          (nwrapper (make-wrapper (layout-length owrapper)
1305                                  class)))
1306     (unless (class-finalized-p class)
1307       (if (class-has-a-forward-referenced-superclass-p class)
1308           (return-from make-instances-obsolete class)
1309           (update-cpl class (compute-class-precedence-list class))))
1310     (setf (wrapper-instance-slots-layout nwrapper)
1311           (wrapper-instance-slots-layout owrapper))
1312     (setf (wrapper-class-slots nwrapper)
1313           (wrapper-class-slots owrapper))
1314     (setf (wrapper-slot-table nwrapper)
1315           (wrapper-slot-table owrapper))
1316     (with-pcl-lock
1317         (update-lisp-class-layout class nwrapper)
1318       (setf (slot-value class 'wrapper) nwrapper)
1319       (invalidate-wrapper owrapper :obsolete nwrapper)
1320       class)))
1321
1322 (defmethod make-instances-obsolete ((class symbol))
1323   (make-instances-obsolete (find-class class))
1324   ;; ANSI wants the class name when called with a symbol.
1325   class)
1326
1327 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1328 ;;; see an obsolete instance. The times when it is called are:
1329 ;;;   - when the instance is involved in method lookup
1330 ;;;   - when attempting to access a slot of an instance
1331 ;;;
1332 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1333 ;;; instance access macros.
1334 ;;;
1335 ;;; Of course these times when it is called are an internal
1336 ;;; implementation detail of PCL and are not part of the documented
1337 ;;; description of when the obsolete instance update happens. The
1338 ;;; documented description is as it appears in 88-002R.
1339 ;;;
1340 ;;; This has to return the new wrapper, so it counts on all the
1341 ;;; methods on obsolete-instance-trap-internal to return the new
1342 ;;; wrapper. It also does a little internal error checking to make
1343 ;;; sure that the traps are only happening when they should, and that
1344 ;;; the trap methods are computing appropriate new wrappers.
1345
1346 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1347 ;;; after a structure is redefined. In most cases,
1348 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1349 ;;; so it must signal an error. The hard part of this is that the
1350 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1351 ;;; called again, so in that case, we have to return some reasonable
1352 ;;; wrapper, instead.
1353
1354 (defvar *in-obsolete-instance-trap* nil)
1355 (defvar *the-wrapper-of-structure-object*
1356   (class-wrapper (find-class 'structure-object)))
1357
1358 (define-condition obsolete-structure (error)
1359   ((datum :reader obsolete-structure-datum :initarg :datum))
1360   (:report
1361    (lambda (condition stream)
1362      ;; Don't try to print the structure, since it probably won't work.
1363      (format stream
1364              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1365              (type-of (obsolete-structure-datum condition))))))
1366
1367 (defun obsolete-instance-trap (owrapper nwrapper instance)
1368   (if (not (layout-for-std-class-p owrapper))
1369       (if *in-obsolete-instance-trap*
1370           *the-wrapper-of-structure-object*
1371            (let ((*in-obsolete-instance-trap* t))
1372              (error 'obsolete-structure :datum instance)))
1373       (let* ((class (wrapper-class* nwrapper))
1374              (copy (allocate-instance class)) ;??? allocate-instance ???
1375              (olayout (wrapper-instance-slots-layout owrapper))
1376              (nlayout (wrapper-instance-slots-layout nwrapper))
1377              (oslots (get-slots instance))
1378              (nslots (get-slots copy))
1379              (oclass-slots (wrapper-class-slots owrapper))
1380              (added ())
1381              (discarded ())
1382              (plist ()))
1383
1384         ;; local  --> local     transfer value
1385         ;; local  --> shared    discard value, discard slot
1386         ;; local  -->  --       discard slot
1387         ;; shared --> local     transfer value
1388         ;; shared --> shared    -- (cf SHARED-INITIALIZE :AFTER STD-CLASS)
1389         ;; shared -->  --       discard value
1390         ;;  --    --> local     add slot
1391         ;;  --    --> shared    --
1392
1393         ;; Go through all the old local slots.
1394         (let ((opos 0))
1395           (dolist (name olayout)
1396             (let ((npos (posq name nlayout)))
1397               (if npos
1398                   (setf (clos-slots-ref nslots npos)
1399                         (clos-slots-ref oslots opos))
1400                   (progn
1401                     (push name discarded)
1402                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1403                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1404             (incf opos)))
1405
1406         ;; Go through all the old shared slots.
1407         (dolist (oclass-slot-and-val oclass-slots)
1408           (let ((name (car oclass-slot-and-val))
1409                 (val (cdr oclass-slot-and-val)))
1410             (let ((npos (posq name nlayout)))
1411               (when npos
1412                 (setf (clos-slots-ref nslots npos) val)))))
1413
1414         ;; Go through all the new local slots to compute the added slots.
1415         (dolist (nlocal nlayout)
1416           (unless (or (memq nlocal olayout)
1417                       (assq nlocal oclass-slots))
1418             (push nlocal added)))
1419
1420         (swap-wrappers-and-slots instance copy)
1421
1422         (update-instance-for-redefined-class instance
1423                                              added
1424                                              discarded
1425                                              plist)
1426         nwrapper)))
1427 \f
1428 (defun change-class-internal (instance new-class initargs)
1429   (let* ((old-class (class-of instance))
1430          (copy (allocate-instance new-class))
1431          (new-wrapper (get-wrapper copy))
1432          (old-wrapper (class-wrapper old-class))
1433          (old-layout (wrapper-instance-slots-layout old-wrapper))
1434          (new-layout (wrapper-instance-slots-layout new-wrapper))
1435          (old-slots (get-slots instance))
1436          (new-slots (get-slots copy))
1437          (old-class-slots (wrapper-class-slots old-wrapper)))
1438
1439     ;; "The values of local slots specified by both the class CTO and
1440     ;; CFROM are retained. If such a local slot was unbound, it
1441     ;; remains unbound."
1442     (let ((new-position 0))
1443       (dolist (new-slot new-layout)
1444         (let ((old-position (posq new-slot old-layout)))
1445           (when old-position
1446             (setf (clos-slots-ref new-slots new-position)
1447                   (clos-slots-ref old-slots old-position))))
1448         (incf new-position)))
1449
1450     ;; "The values of slots specified as shared in the class CFROM and
1451     ;; as local in the class CTO are retained."
1452     (dolist (slot-and-val old-class-slots)
1453       (let ((position (posq (car slot-and-val) new-layout)))
1454         (when position
1455           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1456
1457     ;; Make the copy point to the old instance's storage, and make the
1458     ;; old instance point to the new storage.
1459     (swap-wrappers-and-slots instance copy)
1460
1461     (apply #'update-instance-for-different-class copy instance initargs)
1462     instance))
1463
1464 (defmethod change-class ((instance standard-object) (new-class standard-class)
1465                          &rest initargs)
1466   (unless (class-finalized-p new-class)
1467     (finalize-inheritance new-class))
1468   (let ((cpl (class-precedence-list new-class)))
1469     (dolist (class cpl)
1470       (macrolet
1471           ((frob (class-name)
1472              `(when (eq class (find-class ',class-name))
1473                (error 'metaobject-initialization-violation
1474                 :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1475                 :format-arguments (list 'change-class ',class-name)
1476                 :references (list '(:amop :initialization ,class-name))))))
1477         (frob class)
1478         (frob generic-function)
1479         (frob method)
1480         (frob slot-definition))))
1481   (change-class-internal instance new-class initargs))
1482
1483 (defmethod change-class ((instance forward-referenced-class)
1484                          (new-class standard-class) &rest initargs)
1485   (let ((cpl (class-precedence-list new-class)))
1486     (dolist (class cpl
1487              (error 'metaobject-initialization-violation
1488                     :format-control
1489                     "~@<Cannot ~S ~S objects into non-~S objects.~@:>"
1490                     :format-arguments
1491                     (list 'change-class 'forward-referenced-class 'class)
1492                     :references
1493                     (list '(:amop :generic-function ensure-class-using-class)
1494                           '(:amop :initialization class))))
1495       (when (eq class (find-class 'class))
1496         (return nil))))
1497   (change-class-internal instance new-class initargs))
1498
1499 (defmethod change-class ((instance funcallable-standard-object)
1500                          (new-class funcallable-standard-class)
1501                          &rest initargs)
1502   (let ((cpl (class-precedence-list new-class)))
1503     (dolist (class cpl)
1504       (macrolet
1505           ((frob (class-name)
1506              `(when (eq class (find-class ',class-name))
1507                (error 'metaobject-initialization-violation
1508                 :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1509                 :format-arguments (list 'change-class ',class-name)
1510                 :references (list '(:amop :initialization ,class-name))))))
1511         (frob class)
1512         (frob generic-function)
1513         (frob method)
1514         (frob slot-definition))))
1515   (change-class-internal instance new-class initargs))
1516
1517 (defmethod change-class ((instance standard-object)
1518                          (new-class funcallable-standard-class)
1519                          &rest initargs)
1520   (declare (ignore initargs))
1521   (error "You can't change the class of ~S to ~S~@
1522           because it isn't already an instance with metaclass ~S."
1523          instance new-class 'standard-class))
1524
1525 (defmethod change-class ((instance funcallable-standard-object)
1526                          (new-class standard-class)
1527                          &rest initargs)
1528   (declare (ignore initargs))
1529   (error "You can't change the class of ~S to ~S~@
1530           because it isn't already an instance with metaclass ~S."
1531          instance new-class 'funcallable-standard-class))
1532
1533 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1534   (apply #'change-class instance (find-class new-class-name) initargs))
1535 \f
1536 ;;;; The metaclass BUILT-IN-CLASS
1537 ;;;;
1538 ;;;; This metaclass is something of a weird creature. By this point, all
1539 ;;;; instances of it which will exist have been created, and no instance
1540 ;;;; is ever created by calling MAKE-INSTANCE.
1541 ;;;;
1542 ;;;; But, there are other parts of the protocol we must follow and those
1543 ;;;; definitions appear here.
1544
1545 (macrolet ((def (name args control)
1546                `(defmethod ,name ,args
1547                  (declare (ignore initargs))
1548                  (error 'metaobject-initialization-violation
1549                   :format-control ,(format nil "~@<~A~@:>" control)
1550                   :format-arguments (list ',name)
1551                   :references (list '(:amop :initialization "Class"))))))
1552   (def initialize-instance ((class built-in-class) &rest initargs)
1553     "Cannot ~S an instance of BUILT-IN-CLASS.")
1554   (def reinitialize-instance ((class built-in-class) &rest initargs)
1555     "Cannot ~S an instance of BUILT-IN-CLASS."))
1556
1557 (macrolet ((def (name)
1558                `(defmethod ,name ((class built-in-class)) nil)))
1559   (def class-direct-slots)
1560   (def class-slots)
1561   (def class-direct-default-initargs)
1562   (def class-default-initargs))
1563
1564 (defmethod validate-superclass ((c class) (s built-in-class))
1565   (or (eq s *the-class-t*) (eq s *the-class-stream*)
1566       ;; FIXME: bad things happen if someone tries to mix in both
1567       ;; FILE-STREAM and STRING-STREAM (as they have the same
1568       ;; layout-depthoid).  Is there any way we can provide a useful
1569       ;; error message?  -- CSR, 2005-05-03
1570       (eq s *the-class-file-stream*) (eq s *the-class-string-stream*)
1571       ;; This probably shouldn't be mixed in with certain other
1572       ;; classes, too, but it seems to work both with STANDARD-OBJECT
1573       ;; and FUNCALLABLE-STANDARD-OBJECT
1574       (eq s *the-class-sequence*)))
1575 \f
1576 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1577 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1578 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1579 (macrolet ((def (method)
1580              `(defmethod ,method ((class forward-referenced-class))
1581                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1582                        ',method class))))
1583   (def class-default-initargs)
1584   (def class-precedence-list)
1585   (def class-slots))
1586
1587 (defmethod validate-superclass ((c slot-class)
1588                                 (f forward-referenced-class))
1589   t)
1590 \f
1591 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1592   (pushnew dependent (plist-value metaobject 'dependents) :test #'eq))
1593
1594 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1595   (setf (plist-value metaobject 'dependents)
1596         (delete dependent (plist-value metaobject 'dependents))))
1597
1598 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1599   (dolist (dependent (plist-value metaobject 'dependents))
1600     (funcall function dependent)))
1601