src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd '%class)))
  76     (let ((table (or (gethash name *name->class->slotd-table*)
  77                      (setf (gethash name *name->class->slotd-table*)
  78                            (make-hash-table :test 'eq :size 5)))))
  79       (setf (gethash class table) slotd))
  80     (dolist (type '(reader writer boundp))
  81       (let* ((gf-name (ecase type
  82                               (reader 'slot-value-using-class)
  83                               (writer '(setf slot-value-using-class))
  84                               (boundp 'slot-boundp-using-class)))
  85              (gf (gdefinition gf-name)))
  86         (compute-slot-accessor-info slotd type gf)))))
  87
  88 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
  89 ;;;
  90 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
  91 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
  92 ;;; writing/testing effective slot SLOTD.
  93 ;;;
  94 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
  95 ;;; GF.  Store the effective method in the effective slot definition
  96 ;;; object itself; these GFs have special dispatch functions calling
  97 ;;; effective methods directly retrieved from effective slot
  98 ;;; definition objects, as an optimization.
  99 ;;;
 100 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
 101 ;;; or some such.
 102 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
 103                                        type gf)
 104   (let* ((name (slot-value slotd 'name))
 105          (class (slot-value slotd '%class))
 106          (old-slotd (find-slot-definition class name))
 107          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
 108     (multiple-value-bind (function std-p)
 109         (if (eq *boot-state* 'complete)
 110             (get-accessor-method-function gf type class slotd)
 111             (get-optimized-std-accessor-method-function class slotd type))
 112       (setf (slot-accessor-std-p slotd type) std-p)
 113       (setf (slot-accessor-function slotd type) function))
 114     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 115       (push (cons class name) *pv-table-cache-update-info*))))
 116
 117 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 118   :instance)
 119 \f
 120 ;;;; various class accessors that are a little more complicated than can be
 121 ;;;; done with automatically generated reader methods
 122
 123 (defmethod class-prototype :before (class)
 124   (unless (class-finalized-p class)
 125     (error "~@<~S is not finalized.~:@>" class)))
 126
 127 ;;; KLUDGE: For some reason factoring the common body into a function
 128 ;;; breaks PCL bootstrapping, so just generate it with a macrolet for
 129 ;;; all.
 130 (macrolet ((def (class)
 131              `(defmethod class-prototype ((class ,class))
 132                 (with-slots (prototype) class
 133                   (or prototype
 134                       (setf prototype (allocate-instance class)))))))
 135   (def std-class)
 136   (def condition-class)
 137   (def structure-class))
 138
 139 (defmethod class-direct-default-initargs ((class slot-class))
 140   (plist-value class 'direct-default-initargs))
 141
 142 (defmethod class-default-initargs ((class slot-class))
 143   (plist-value class 'default-initargs))
 144
 145 (defmethod class-slot-cells ((class std-class))
 146   (plist-value class 'class-slot-cells))
 147 (defmethod (setf class-slot-cells) (new-value (class std-class))
 148   (setf (plist-value class 'class-slot-cells) new-value))
 149 \f
 150 ;;;; class accessors that are even a little bit more complicated than those
 151 ;;;; above. These have a protocol for updating them, we must implement that
 152 ;;;; protocol.
 153
 154 ;;; Maintaining the direct subclasses backpointers. The update methods are
 155 ;;; here, the values are read by an automatically generated reader method.
 156 (defmethod add-direct-subclass ((class class) (subclass class))
 157   (with-slots (direct-subclasses) class
 158     (pushnew subclass direct-subclasses)
 159     subclass))
 160 (defmethod remove-direct-subclass ((class class) (subclass class))
 161   (with-slots (direct-subclasses) class
 162     (setq direct-subclasses (remove subclass direct-subclasses))
 163     subclass))
 164
 165 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 166 ;;;
 167 ;;; There are four generic functions involved, each has one method for the
 168 ;;; class case and another method for the damned EQL specializers. All of
 169 ;;; these are specified methods and appear in their specified place in the
 170 ;;; class graph.
 171 ;;;
 172 ;;;   ADD-DIRECT-METHOD
 173 ;;;   REMOVE-DIRECT-METHOD
 174 ;;;   SPECIALIZER-DIRECT-METHODS
 175 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 176 ;;;
 177 ;;; In each case, we maintain one value which is a cons. The car is the list
 178 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 179 ;;; computed lazily.
 180 (defmethod add-direct-method ((specializer class) (method method))
 181   (with-slots (direct-methods) specializer
 182     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 183           (cdr direct-methods) ()))
 184   method)
 185 (defmethod remove-direct-method ((specializer class) (method method))
 186   (with-slots (direct-methods) specializer
 187     (setf (car direct-methods) (remove method (car direct-methods))
 188           (cdr direct-methods) ()))
 189   method)
 190
 191 (defmethod specializer-direct-methods ((specializer class))
 192   (with-slots (direct-methods) specializer
 193     (car direct-methods)))
 194
 195 (defmethod specializer-direct-generic-functions ((specializer class))
 196   (with-slots (direct-methods) specializer
 197     (or (cdr direct-methods)
 198         (setf (cdr direct-methods)
 199               (let (collect)
 200                 (dolist (m (car direct-methods))
 201                   ;; the old PCL code used COLLECTING-ONCE which used
 202                   ;; #'EQ to check for newness
 203                   (pushnew (method-generic-function m) collect :test #'eq))
 204                 (nreverse collect))))))
 205 \f
 206 ;;; This hash table is used to store the direct methods and direct generic
 207 ;;; functions of EQL specializers. Each value in the table is the cons.
 208 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 209 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 210
 211 (defmethod specializer-method-table ((specializer eql-specializer))
 212   *eql-specializer-methods*)
 213
 214 (defmethod specializer-method-table ((specializer class-eq-specializer))
 215   *class-eq-specializer-methods*)
 216
 217 (defmethod add-direct-method ((specializer specializer-with-object)
 218                               (method method))
 219   (let* ((object (specializer-object specializer))
 220          (table (specializer-method-table specializer))
 221          (entry (gethash object table)))
 222     (unless entry
 223       (setq entry
 224             (setf (gethash object table)
 225                   (cons nil nil))))
 226     (setf (car entry) (adjoin method (car entry))
 227           (cdr entry) ())
 228     method))
 229
 230 (defmethod remove-direct-method ((specializer specializer-with-object)
 231                                  (method method))
 232   (let* ((object (specializer-object specializer))
 233          (entry (gethash object (specializer-method-table specializer))))
 234     (when entry
 235       (setf (car entry) (remove method (car entry))
 236             (cdr entry) ()))
 237     method))
 238
 239 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 240   (car (gethash (specializer-object specializer)
 241                 (specializer-method-table specializer))))
 242
 243 (defmethod specializer-direct-generic-functions ((specializer
 244                                                   specializer-with-object))
 245   (let* ((object (specializer-object specializer))
 246          (entry (gethash object (specializer-method-table specializer))))
 247     (when entry
 248       (or (cdr entry)
 249           (setf (cdr entry)
 250                 (let (collect)
 251                   (dolist (m (car entry))
 252                     (pushnew (method-generic-function m) collect :test #'eq))
 253                   (nreverse collect)))))))
 254
 255 (defun map-specializers (function)
 256   (map-all-classes (lambda (class)
 257                      (funcall function (class-eq-specializer class))
 258                      (funcall function class)))
 259   (maphash (lambda (object methods)
 260              (declare (ignore methods))
 261              (intern-eql-specializer object))
 262            *eql-specializer-methods*)
 263   (maphash (lambda (object specl)
 264              (declare (ignore object))
 265              (funcall function specl))
 266            *eql-specializer-table*)
 267   nil)
 268
 269 (defun map-all-generic-functions (function)
 270   (let ((all-generic-functions (make-hash-table :test 'eq)))
 271     (map-specializers (lambda (specl)
 272                         (dolist (gf (specializer-direct-generic-functions
 273                                      specl))
 274                           (unless (gethash gf all-generic-functions)
 275                             (setf (gethash gf all-generic-functions) t)
 276                             (funcall function gf))))))
 277   nil)
 278
 279 (defmethod shared-initialize :after ((specl class-eq-specializer)
 280                                      slot-names
 281                                      &key)
 282   (declare (ignore slot-names))
 283   (setf (slot-value specl '%type) `(class-eq ,(specializer-class specl))))
 284
 285 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 286   (declare (ignore slot-names))
 287   (setf (slot-value specl '%type)
 288         `(eql ,(specializer-object specl)))
 289   (setf (info :type :translator specl)
 290         (constantly (make-member-type :members (list (specializer-object specl))))))
 291
 292 (defun real-load-defclass (name metaclass-name supers slots other
 293                            readers writers slot-names source-location)
 294   (with-single-package-locked-error (:symbol name "defining ~S as a class")
 295     (%compiler-defclass name readers writers slot-names)
 296     (let ((res (apply #'ensure-class name :metaclass metaclass-name
 297                       :direct-superclasses supers
 298                       :direct-slots slots
 299                       :definition-source source-location
 300                       other)))
 301       res)))
 302
 303 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 304
 305 (defun ensure-class (name &rest args)
 306   (apply #'ensure-class-using-class
 307          (let ((class (find-class name nil)))
 308            (when (and class (eq name (class-name class)))
 309              ;; NAME is the proper name of CLASS, so redefine it
 310              class))
 311          name
 312          args))
 313
 314 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 315   (multiple-value-bind (meta initargs)
 316       (ensure-class-values class args)
 317     (set-class-type-translation (class-prototype meta) name)
 318     (setf class (apply #'make-instance meta :name name initargs))
 319     (without-package-locks
 320       (setf (find-class name) class))
 321     (set-class-type-translation class name)
 322     class))
 323
 324 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 325   (multiple-value-bind (meta initargs)
 326       (ensure-class-values class args)
 327     (unless (eq (class-of class) meta)
 328       (apply #'change-class class meta initargs))
 329     (apply #'reinitialize-instance class initargs)
 330     (without-package-locks
 331       (setf (find-class name) class))
 332     (set-class-type-translation class name)
 333     class))
 334
 335 (defun fix-super (s)
 336   (cond ((classp s) s)
 337         ((not (legal-class-name-p s))
 338          (error "~S is not a class or a legal class name." s))
 339         (t
 340          (or (find-class s nil)
 341              (make-instance 'forward-referenced-class
 342                             :name s)))))
 343
 344 (defun ensure-class-values (class initargs)
 345   (let (metaclass metaclassp reversed-plist)
 346     (doplist (key val) initargs
 347       (cond ((eq key :metaclass)
 348              (setf metaclass val
 349                    metaclassp key))
 350             (t
 351              (when (eq key :direct-superclasses)
 352                (setf val (mapcar #'fix-super val)))
 353              (setf reversed-plist (list* val key reversed-plist)))))
 354     (values (cond (metaclassp
 355                    (if (classp metaclass)
 356                        metaclass
 357                        (find-class metaclass)))
 358                   ((or (null class) (forward-referenced-class-p class))
 359                    *the-class-standard-class*)
 360                   (t
 361                    (class-of class)))
 362             (nreverse reversed-plist))))
 363
 364 \f
 365 (defmethod shared-initialize :after
 366     ((class std-class) slot-names &key
 367      (direct-superclasses nil direct-superclasses-p)
 368      (direct-slots nil direct-slots-p)
 369      (direct-default-initargs nil direct-default-initargs-p))
 370   (cond (direct-superclasses-p
 371          (setq direct-superclasses
 372                (or direct-superclasses
 373                    (list (if (funcallable-standard-class-p class)
 374                              *the-class-funcallable-standard-object*
 375                              *the-class-standard-object*))))
 376          (dolist (superclass direct-superclasses)
 377            (unless (validate-superclass class superclass)
 378              (error "~@<The class ~S was specified as a ~
 379                      super-class of the class ~S, ~
 380                      but the meta-classes ~S and ~S are incompatible.  ~
 381                      Define a method for ~S to avoid this error.~@:>"
 382                      superclass class (class-of superclass) (class-of class)
 383                      'validate-superclass)))
 384          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 385         (t
 386          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 387   (setq direct-slots
 388         (if direct-slots-p
 389             (setf (slot-value class 'direct-slots)
 390                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 391                           direct-slots))
 392             (slot-value class 'direct-slots)))
 393   (if direct-default-initargs-p
 394       (setf (plist-value class 'direct-default-initargs)
 395             direct-default-initargs)
 396       (setq direct-default-initargs
 397             (plist-value class 'direct-default-initargs)))
 398   (setf (plist-value class 'class-slot-cells)
 399         (let ((old-class-slot-cells (plist-value class 'class-slot-cells))
 400               (collect '()))
 401           (dolist (dslotd direct-slots)
 402             (when (eq :class (slot-definition-allocation dslotd))
 403               ;; see CLHS 4.3.6
 404               (let* ((name (slot-definition-name dslotd))
 405                      (old (assoc name old-class-slot-cells)))
 406                 (if (or (not old)
 407                         (eq t slot-names)
 408                         (member name slot-names))
 409                     (let* ((initfunction (slot-definition-initfunction dslotd))
 410                            (value (if initfunction
 411                                       (funcall initfunction)
 412                                       +slot-unbound+)))
 413                       (push (cons name value) collect))
 414                     (push old collect)))))
 415           (nreverse collect)))
 416   (add-direct-subclasses class direct-superclasses)
 417   (update-class class nil)
 418   (do* ((slots (slot-value class 'slots) (cdr slots))
 419         (dupes nil))
 420        ((null slots) (when dupes
 421                        (style-warn
 422                         ;; FIXME: the indentation request ("~4I")
 423                         ;; below appears not to do anything.  Finding
 424                         ;; out why would be nice.  -- CSR, 2003-04-24
 425                         "~@<slot names with the same SYMBOL-NAME but ~
 426                          different SYMBOL-PACKAGE (possible package problem) ~
 427                          for class ~S:~@:_~4I~<~@{~S~^~:@_~}~:>~@:>"
 428                         class
 429                         dupes)))
 430     (let* ((slot (car slots))
 431            (oslots (remove (slot-definition-name slot) (cdr slots)
 432                            :test #'string/= :key #'slot-definition-name)))
 433       (when oslots
 434         (pushnew (cons (slot-definition-name slot)
 435                        (mapcar #'slot-definition-name oslots))
 436                  dupes
 437                  :test #'string= :key #'car))))
 438   (add-slot-accessors class direct-slots)
 439   (make-preliminary-layout class))
 440
 441 (defmethod shared-initialize :after ((class forward-referenced-class)
 442                                      slot-names &key &allow-other-keys)
 443   (declare (ignore slot-names))
 444   (make-preliminary-layout class))
 445
 446 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 447
 448 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 449 ;;; make it known to the type system.
 450 (defun make-preliminary-layout (class)
 451   (flet ((compute-preliminary-cpl (root)
 452            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 453              (compute-class-precedence-list root))))
 454     (without-package-locks
 455      (unless (class-finalized-p class)
 456        (let ((name (class-name class)))
 457          (setf (find-class name) class)
 458          ;; KLUDGE: This is fairly horrible.  We need to make a
 459          ;; full-fledged CLASSOID here, not just tell the compiler that
 460          ;; some class is forthcoming, because there are legitimate
 461          ;; questions one can ask of the type system, implemented in
 462          ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 463          (when (and (eq *boot-state* 'complete)
 464                     (null (find-classoid name nil)))
 465            (setf (find-classoid name)
 466                  (make-standard-classoid :name name)))
 467          (set-class-type-translation class name)
 468          (let ((layout (make-wrapper 0 class))
 469                (classoid (find-classoid name)))
 470            (setf (layout-classoid layout) classoid)
 471            (setf (classoid-pcl-class classoid) class)
 472            (setf (slot-value class 'wrapper) layout)
 473            (let ((cpl (compute-preliminary-cpl class)))
 474              (setf (layout-inherits layout)
 475                    (order-layout-inherits
 476                     (map 'simple-vector #'class-wrapper
 477                          (reverse (rest cpl))))))
 478            (register-layout layout :invalidate t)
 479            (setf (classoid-layout classoid) layout)
 480            (mapc #'make-preliminary-layout (class-direct-subclasses class))))))))
 481
 482
 483 (defmethod shared-initialize :before ((class class) slot-names &key name)
 484   (declare (ignore slot-names name))
 485   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 486   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 487   (setf (slot-value class '%type) `(class ,class))
 488   (setf (slot-value class 'class-eq-specializer)
 489         (make-instance 'class-eq-specializer :class class)))
 490
 491 (defmethod reinitialize-instance :before ((class slot-class) &key direct-superclasses)
 492   (dolist (old-super (set-difference (class-direct-superclasses class) direct-superclasses))
 493     (remove-direct-subclass old-super class))
 494   (remove-slot-accessors    class (class-direct-slots class)))
 495
 496 (defmethod reinitialize-instance :after ((class slot-class)
 497                                          &rest initargs
 498                                          &key)
 499   (map-dependents class
 500                   (lambda (dependent)
 501                     (apply #'update-dependent class dependent initargs))))
 502
 503 (defmethod reinitialize-instance :after ((class condition-class) &key)
 504   (let* ((name (class-name class))
 505          (classoid (find-classoid name))
 506          (slots (condition-classoid-slots classoid)))
 507     ;; to balance the REMOVE-SLOT-ACCESSORS call in
 508     ;; REINITIALIZE-INSTANCE :BEFORE (SLOT-CLASS).
 509     (dolist (slot slots)
 510       (let ((slot-name (condition-slot-name slot)))
 511         (dolist (reader (condition-slot-readers slot))
 512           ;; FIXME: see comment in SHARED-INITIALIZE :AFTER
 513           ;; (CONDITION-CLASS T), below.  -- CSR, 2005-11-18
 514           (sb-kernel::install-condition-slot-reader reader name slot-name))
 515         (dolist (writer (condition-slot-writers slot))
 516           (sb-kernel::install-condition-slot-writer writer name slot-name))))))
 517
 518 (defmethod shared-initialize :after ((class condition-class) slot-names
 519                                      &key direct-slots direct-superclasses)
 520   (declare (ignore slot-names))
 521   (let ((classoid (find-classoid (class-name class))))
 522     (with-slots (wrapper %class-precedence-list cpl-available-p
 523                          prototype (direct-supers direct-superclasses))
 524         class
 525       (setf (slot-value class 'direct-slots)
 526             (mapcar (lambda (pl) (make-direct-slotd class pl))
 527                     direct-slots))
 528       (setf (slot-value class 'finalized-p) t)
 529       (setf (classoid-pcl-class classoid) class)
 530       (setq direct-supers direct-superclasses)
 531       (setq wrapper (classoid-layout classoid))
 532       (setq %class-precedence-list (compute-class-precedence-list class))
 533       (setq cpl-available-p t)
 534       (add-direct-subclasses class direct-superclasses)
 535       (setf (slot-value class 'slots) (compute-slots class))))
 536   ;; Comment from Gerd's PCL, 2003-05-15:
 537   ;;
 538   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 539   ;; override condition accessors with generic functions.  We do this
 540   ;; differently.
 541   ;;
 542   ;; ??? What does the above comment mean and why is it a good idea?
 543   ;; CMUCL (which still as of 2005-11-18 uses this code and has this
 544   ;; comment) loses slot information in its condition classes:
 545   ;; DIRECT-SLOTS is always NIL.  We have the right information, so we
 546   ;; remove slot accessors but never put them back.  I've added a
 547   ;; REINITIALIZE-INSTANCE :AFTER (CONDITION-CLASS) method, but what
 548   ;; was meant to happen?  -- CSR, 2005-11-18
 549   (update-pv-table-cache-info class))
 550
 551 (defmethod direct-slot-definition-class ((class condition-class)
 552                                          &rest initargs)
 553   (declare (ignore initargs))
 554   (find-class 'condition-direct-slot-definition))
 555
 556 (defmethod effective-slot-definition-class ((class condition-class)
 557                                             &rest initargs)
 558   (declare (ignore initargs))
 559   (find-class 'condition-effective-slot-definition))
 560
 561 (defmethod finalize-inheritance ((class condition-class))
 562   (aver (slot-value class 'finalized-p))
 563   nil)
 564
 565 (defmethod compute-effective-slot-definition
 566     ((class condition-class) slot-name dslotds)
 567   (let ((slotd (call-next-method)))
 568     (setf (slot-definition-reader-function slotd)
 569           (lambda (x)
 570             (handler-case (condition-reader-function x slot-name)
 571               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 572               ;; is unbound; maybe it should be a CELL-ERROR of some
 573               ;; sort?
 574               (error () (values (slot-unbound class x slot-name))))))
 575     (setf (slot-definition-writer-function slotd)
 576           (lambda (v x)
 577             (condition-writer-function x v slot-name)))
 578     (setf (slot-definition-boundp-function slotd)
 579           (lambda (x)
 580             (multiple-value-bind (v c)
 581                 (ignore-errors (condition-reader-function x slot-name))
 582               (declare (ignore v))
 583               (null c))))
 584     slotd))
 585
 586 (defmethod compute-slots ((class condition-class))
 587   (mapcan (lambda (superclass)
 588             (mapcar (lambda (dslotd)
 589                       (compute-effective-slot-definition
 590                        class (slot-definition-name dslotd) (list dslotd)))
 591                     (class-direct-slots superclass)))
 592           (reverse (slot-value class '%class-precedence-list))))
 593
 594 (defmethod compute-slots :around ((class condition-class))
 595   (let ((eslotds (call-next-method)))
 596     (mapc #'initialize-internal-slot-functions eslotds)
 597     eslotds))
 598
 599 (defmethod shared-initialize :after
 600     ((slotd structure-slot-definition) slot-names &key
 601      (allocation :instance) allocation-class)
 602   (declare (ignore slot-names allocation-class))
 603   (unless (eq allocation :instance)
 604     (error "Structure slots must have :INSTANCE allocation.")))
 605
 606 (defun make-structure-class-defstruct-form (name direct-slots include)
 607   (let* ((conc-name (format-symbol *package* "~S structure class " name))
 608          (constructor (format-symbol *package* "~Aconstructor" conc-name))
 609          (defstruct `(defstruct (,name
 610                                  ,@(when include
 611                                          `((:include ,(class-name include))))
 612                                  (:predicate nil)
 613                                  (:conc-name ,conc-name)
 614                                  (:constructor ,constructor ())
 615                                  (:copier nil))
 616                       ,@(mapcar (lambda (slot)
 617                                   `(,(slot-definition-name slot)
 618                                     +slot-unbound+))
 619                                 direct-slots)))
 620          (reader-names (mapcar (lambda (slotd)
 621                                  (list 'slot-accessor name
 622                                        (slot-definition-name slotd)
 623                                        'reader))
 624                                direct-slots))
 625          (writer-names (mapcar (lambda (slotd)
 626                                  (list 'slot-accessor name
 627                                        (slot-definition-name slotd)
 628                                        'writer))
 629                                direct-slots))
 630          (readers-init
 631            (mapcar (lambda (slotd reader-name)
 632                      (let ((accessor
 633                              (slot-definition-defstruct-accessor-symbol
 634                               slotd)))
 635                        `(defun ,reader-name (obj)
 636                          (declare (type ,name obj))
 637                          (,accessor obj))))
 638                    direct-slots reader-names))
 639          (writers-init
 640            (mapcar (lambda (slotd writer-name)
 641                      (let ((accessor
 642                              (slot-definition-defstruct-accessor-symbol
 643                               slotd)))
 644                        `(defun ,writer-name (nv obj)
 645                          (declare (type ,name obj))
 646                          (setf (,accessor obj) nv))))
 647                    direct-slots writer-names))
 648          (defstruct-form
 649              `(progn
 650                ,defstruct
 651                ,@readers-init ,@writers-init
 652                (cons nil nil))))
 653     (values defstruct-form constructor reader-names writer-names)))
 654
 655 (defun make-defstruct-allocation-function (class)
 656   (let ((dd (get-structure-dd (class-name class))))
 657     (lambda ()
 658       (sb-kernel::%make-instance-with-layout
 659        (sb-kernel::compiler-layout-or-lose (dd-name dd))))))
 660
 661 (defmethod shared-initialize :after
 662     ((class structure-class) slot-names &key
 663      (direct-superclasses nil direct-superclasses-p)
 664      (direct-slots nil direct-slots-p)
 665      direct-default-initargs)
 666   (declare (ignore slot-names direct-default-initargs))
 667   (if direct-superclasses-p
 668       (setf (slot-value class 'direct-superclasses)
 669             (or direct-superclasses
 670                 (setq direct-superclasses
 671                       (and (not (eq (class-name class) 'structure-object))
 672                            (list *the-class-structure-object*)))))
 673       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 674   (let* ((name (class-name class))
 675          (from-defclass-p (slot-value class 'from-defclass-p))
 676          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 677     (if direct-slots-p
 678         (setf (slot-value class 'direct-slots)
 679               (setq direct-slots
 680                     (mapcar (lambda (pl)
 681                               (when defstruct-p
 682                                 (let* ((slot-name (getf pl :name))
 683                                        (accessor
 684                                         (format-symbol *package*
 685                                                        "~S structure class ~A"
 686                                                        name slot-name)))
 687                                   (setq pl (list* :defstruct-accessor-symbol
 688                                                   accessor pl))))
 689                               (make-direct-slotd class pl))
 690                             direct-slots)))
 691         (setq direct-slots (slot-value class 'direct-slots)))
 692     (if defstruct-p
 693         (let ((include (car (slot-value class 'direct-superclasses))))
 694           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 695               (make-structure-class-defstruct-form name direct-slots include)
 696             (unless (structure-type-p name) (eval defstruct-form))
 697             (mapc (lambda (dslotd reader-name writer-name)
 698                     (let* ((reader (gdefinition reader-name))
 699                            (writer (when (fboundp writer-name)
 700                                      (gdefinition writer-name))))
 701                       (setf (slot-value dslotd 'internal-reader-function)
 702                             reader)
 703                       (setf (slot-value dslotd 'internal-writer-function)
 704                             writer)))
 705                   direct-slots reader-names writer-names)
 706             (setf (slot-value class 'defstruct-form) defstruct-form)
 707             (setf (slot-value class 'defstruct-constructor) constructor)))
 708         (setf (slot-value class 'defstruct-constructor)
 709               (make-defstruct-allocation-function class)))
 710     (add-direct-subclasses class direct-superclasses)
 711     (setf (slot-value class '%class-precedence-list)
 712           (compute-class-precedence-list class))
 713     (setf (slot-value class 'cpl-available-p) t)
 714     (setf (slot-value class 'slots) (compute-slots class))
 715     (let ((lclass (find-classoid (class-name class))))
 716       (setf (classoid-pcl-class lclass) class)
 717       (setf (slot-value class 'wrapper) (classoid-layout lclass)))
 718     (setf (slot-value class 'finalized-p) t)
 719     (update-pv-table-cache-info class)
 720     (add-slot-accessors class direct-slots)))
 721
 722 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 723   (declare (ignore initargs))
 724   (find-class 'structure-direct-slot-definition))
 725
 726 (defmethod finalize-inheritance ((class structure-class))
 727   nil) ; always finalized
 728 \f
 729 (defun add-slot-accessors (class dslotds)
 730   (fix-slot-accessors class dslotds 'add))
 731
 732 (defun remove-slot-accessors (class dslotds)
 733   (fix-slot-accessors class dslotds 'remove))
 734
 735 (defun fix-slot-accessors (class dslotds add/remove)
 736   (flet ((fix (gfspec name r/w)
 737            (let ((gf (cond ((eq add/remove 'add)
 738                             (if (fboundp gfspec)
 739                                 (without-package-locks
 740                                   (ensure-generic-function gfspec))
 741                                 (ensure-generic-function
 742                                  gfspec :lambda-list (case r/w
 743                                                        (r '(object))
 744                                                        (w '(new-value object))))))
 745                            ((generic-function-p (and (fboundp gfspec)
 746                                                      (fdefinition gfspec)))
 747                             (without-package-locks
 748                               (ensure-generic-function gfspec))))))
 749              (when gf
 750                (case r/w
 751                  (r (if (eq add/remove 'add)
 752                         (add-reader-method class gf name)
 753                         (remove-reader-method class gf)))
 754                  (w (if (eq add/remove 'add)
 755                         (add-writer-method class gf name)
 756                         (remove-writer-method class gf))))))))
 757     (dolist (dslotd dslotds)
 758       (let ((slot-name (slot-definition-name dslotd)))
 759         (dolist (r (slot-definition-readers dslotd))
 760           (fix r slot-name 'r))
 761         (dolist (w (slot-definition-writers dslotd))
 762           (fix w slot-name 'w))))))
 763 \f
 764 (defun add-direct-subclasses (class supers)
 765   (dolist (super supers)
 766     (unless (memq class (class-direct-subclasses class))
 767       (add-direct-subclass super class))))
 768
 769 (defmethod finalize-inheritance ((class std-class))
 770   (update-class class t))
 771
 772 (defmethod finalize-inheritance ((class forward-referenced-class))
 773   ;; FIXME: should we not be thinking a bit about what kinds of error
 774   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 775   ;; possibly a forward-referenced-class-error, though that's
 776   ;; difficult given e.g. class precedence list calculations...
 777   (error
 778    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 779        ~2I~_~S~:>"
 780    class))
 781
 782 \f
 783 (defun class-has-a-forward-referenced-superclass-p (class)
 784   (or (forward-referenced-class-p class)
 785       (some #'class-has-a-forward-referenced-superclass-p
 786             (class-direct-superclasses class))))
 787
 788 ;;; This is called by :after shared-initialize whenever a class is initialized
 789 ;;; or reinitialized. The class may or may not be finalized.
 790 (defun update-class (class finalizep)
 791   ;; Comment from Gerd Moellmann:
 792   ;;
 793   ;; Note that we can't simply delay the finalization when CLASS has
 794   ;; no forward referenced superclasses because that causes bootstrap
 795   ;; problems.
 796   (without-package-locks
 797    (when (and (not finalizep)
 798               (not (class-finalized-p class))
 799               (not (class-has-a-forward-referenced-superclass-p class)))
 800      (finalize-inheritance class)
 801      (return-from update-class))
 802    (when (or finalizep (class-finalized-p class)
 803              (not (class-has-a-forward-referenced-superclass-p class)))
 804      (setf (find-class (class-name class)) class)
 805      (update-cpl class (compute-class-precedence-list class))
 806      ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 807      ;; class.  The hoops above are to ensure that FINALIZE-INHERITANCE
 808      ;; is called at finalization, so that MOP programmers can hook
 809      ;; into the system as described in "Class Finalization Protocol"
 810      ;; (section 5.5.2 of AMOP).
 811      (update-slots class (compute-slots class))
 812      (update-gfs-of-class class)
 813      (update-initargs class (compute-default-initargs class))
 814      (update-ctors 'finalize-inheritance :class class))
 815    (dolist (sub (class-direct-subclasses class))
 816      (update-class sub nil))))
 817
 818 (define-condition cpl-protocol-violation (reference-condition error)
 819   ((class :initarg :class :reader cpl-protocol-violation-class)
 820    (cpl :initarg :cpl :reader cpl-protocol-violation-cpl))
 821   (:default-initargs :references (list '(:sbcl :node "Metaobject Protocol")))
 822   (:report
 823    (lambda (c s)
 824      (format s "~@<Protocol violation: the ~S class ~S ~
 825                 ~:[has~;does not have~] the class ~S in its ~
 826                 class precedence list: ~S.~@:>"
 827              (class-name (class-of (cpl-protocol-violation-class c)))
 828              (cpl-protocol-violation-class c)
 829              (eq (class-of (cpl-protocol-violation-class c))
 830                  *the-class-funcallable-standard-class*)
 831              (find-class 'function)
 832              (cpl-protocol-violation-cpl c)))))
 833
 834 (defun update-cpl (class cpl)
 835   (when (eq (class-of class) *the-class-standard-class*)
 836     (when (find (find-class 'function) cpl)
 837       (error 'cpl-protocol-violation :class class :cpl cpl)))
 838   (when (eq (class-of class) *the-class-funcallable-standard-class*)
 839     (unless (find (find-class 'function) cpl)
 840       (error 'cpl-protocol-violation :class class :cpl cpl)))
 841   (if (class-finalized-p class)
 842       (unless (and (equal (class-precedence-list class) cpl)
 843                    (dolist (c cpl t)
 844                      (when (position :class (class-direct-slots c)
 845                                      :key #'slot-definition-allocation)
 846                        (return nil))))
 847         ;; comment from the old CMU CL sources:
 848         ;;   Need to have the cpl setup before update-lisp-class-layout
 849         ;;   is called on CMU CL.
 850         (setf (slot-value class '%class-precedence-list) cpl)
 851         (setf (slot-value class 'cpl-available-p) t)
 852         (force-cache-flushes class))
 853       (progn
 854         (setf (slot-value class '%class-precedence-list) cpl)
 855         (setf (slot-value class 'cpl-available-p) t)))
 856   (update-class-can-precede-p cpl))
 857
 858 (defun update-class-can-precede-p (cpl)
 859   (when cpl
 860     (let ((first (car cpl)))
 861       (dolist (c (cdr cpl))
 862         (pushnew c (slot-value first 'can-precede-list))))
 863     (update-class-can-precede-p (cdr cpl))))
 864
 865 (defun class-can-precede-p (class1 class2)
 866   (member class2 (class-can-precede-list class1)))
 867
 868 (defun update-slots (class eslotds)
 869   (let ((instance-slots ())
 870         (class-slots    ()))
 871     (dolist (eslotd eslotds)
 872       (let ((alloc (slot-definition-allocation eslotd)))
 873         (case alloc
 874           (:instance (push eslotd instance-slots))
 875           (:class (push eslotd class-slots)))))
 876
 877     ;; If there is a change in the shape of the instances then the
 878     ;; old class is now obsolete.
 879     (let* ((nlayout (mapcar #'slot-definition-name
 880                             (sort instance-slots #'<
 881                                   :key #'slot-definition-location)))
 882            (nslots (length nlayout))
 883            (nwrapper-class-slots (compute-class-slots class-slots))
 884            (owrapper (when (class-finalized-p class)
 885                        (class-wrapper class)))
 886            (olayout (when owrapper
 887                       (wrapper-instance-slots-layout owrapper)))
 888            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 889            (nwrapper
 890             (cond ((null owrapper)
 891                    (make-wrapper nslots class))
 892                   ((and (equal nlayout olayout)
 893                         (not
 894                          (loop for o in owrapper-class-slots
 895                                for n in nwrapper-class-slots
 896                                do (unless (eq (car o) (car n)) (return t)))))
 897                    owrapper)
 898                   (t
 899                    ;; This will initialize the new wrapper to have the
 900                    ;; same state as the old wrapper. We will then have
 901                    ;; to change that. This may seem like wasted work
 902                    ;; (and it is), but the spec requires that we call
 903                    ;; MAKE-INSTANCES-OBSOLETE.
 904                    (make-instances-obsolete class)
 905                    (class-wrapper class)))))
 906
 907       (with-slots (wrapper slots) class
 908         (update-lisp-class-layout class nwrapper)
 909         (setf slots eslotds
 910               (wrapper-instance-slots-layout nwrapper) nlayout
 911               (wrapper-class-slots nwrapper) nwrapper-class-slots
 912               (wrapper-no-of-instance-slots nwrapper) nslots
 913               wrapper nwrapper))
 914       (setf (slot-value class 'finalized-p) t)
 915       (unless (eq owrapper nwrapper)
 916         (update-pv-table-cache-info class)
 917         (maybe-update-standard-class-locations class)))))
 918
 919 (defun compute-class-slots (eslotds)
 920   (let (collect)
 921     (dolist (eslotd eslotds)
 922       (push (assoc (slot-definition-name eslotd)
 923                    (class-slot-cells (slot-definition-class eslotd)))
 924             collect))
 925     (nreverse collect)))
 926
 927 (defun update-gfs-of-class (class)
 928   (when (and (class-finalized-p class)
 929              (let ((cpl (class-precedence-list class)))
 930                (or (member *the-class-slot-class* cpl)
 931                    (member *the-class-standard-effective-slot-definition*
 932                            cpl))))
 933     (let ((gf-table (make-hash-table :test 'eq)))
 934       (labels ((collect-gfs (class)
 935                  (dolist (gf (specializer-direct-generic-functions class))
 936                    (setf (gethash gf gf-table) t))
 937                  (mapc #'collect-gfs (class-direct-superclasses class))))
 938         (collect-gfs class)
 939         (maphash (lambda (gf ignore)
 940                    (declare (ignore ignore))
 941                    (update-gf-dfun class gf))
 942                  gf-table)))))
 943
 944 (defun update-initargs (class inits)
 945   (setf (plist-value class 'default-initargs) inits))
 946 \f
 947 (defmethod compute-default-initargs ((class slot-class))
 948   (let ((initargs (loop for c in (class-precedence-list class)
 949                         append (class-direct-default-initargs c))))
 950     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
 951 \f
 952 ;;;; protocols for constructing direct and effective slot definitions
 953
 954 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
 955   (declare (ignore initargs))
 956   (find-class 'standard-direct-slot-definition))
 957
 958 (defun make-direct-slotd (class initargs)
 959   (apply #'make-instance
 960          (apply #'direct-slot-definition-class class initargs)
 961          :class class
 962          initargs))
 963
 964 ;;; I (CSR) am not sure, but I believe that the particular order of
 965 ;;; slots is quite important: it is ideal to attempt to have a
 966 ;;; constant slot location for the same notional slots as much as
 967 ;;; possible, so that clever discriminating functions (ONE-INDEX et
 968 ;;; al.) have a chance of working.  The below at least walks through
 969 ;;; the slots predictably, but maybe it would be good to compute some
 970 ;;; kind of optimal slot layout by looking at locations of slots in
 971 ;;; superclasses?
 972 (defun std-compute-slots (class)
 973   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 974   ;; for each different slot name we find in our superclasses. Each
 975   ;; call receives the class and a list of the dslotds with that name.
 976   ;; The list is in most-specific-first order.
 977   (let ((name-dslotds-alist ()))
 978     (dolist (c (reverse (class-precedence-list class)))
 979       (dolist (slot (class-direct-slots c))
 980         (let* ((name (slot-definition-name slot))
 981                (entry (assq name name-dslotds-alist)))
 982           (if entry
 983               (push slot (cdr entry))
 984               (push (list name slot) name-dslotds-alist)))))
 985     (mapcar (lambda (direct)
 986               (compute-effective-slot-definition class
 987                                                  (car direct)
 988                                                  (cdr direct)))
 989             (nreverse name-dslotds-alist))))
 990
 991 (defmethod compute-slots ((class standard-class))
 992   (std-compute-slots class))
 993 (defmethod compute-slots ((class funcallable-standard-class))
 994   (std-compute-slots class))
 995
 996 (defun std-compute-slots-around (class eslotds)
 997   (let ((location -1))
 998     (dolist (eslotd eslotds eslotds)
 999       (setf (slot-definition-location eslotd)
1000             (case (slot-definition-allocation eslotd)
1001               (:instance
1002                (incf location))
1003               (:class
1004                (let* ((name (slot-definition-name eslotd))
1005                       (from-class
1006                        (or
1007                         (slot-definition-allocation-class eslotd)
1008                         ;; we get here if the user adds an extra slot
1009                         ;; himself...
1010                         (setf (slot-definition-allocation-class eslotd)
1011                               class)))
1012                       ;; which raises the question of what we should
1013                       ;; do if we find that said user has added a slot
1014                       ;; with the same name as another slot...
1015                       (cell (or (assq name (class-slot-cells from-class))
1016                                 (let ((c (cons name +slot-unbound+)))
1017                                   (push c (class-slot-cells from-class))
1018                                   c))))
1019                  (aver (consp cell))
1020                  (if (eq +slot-unbound+ (cdr cell))
1021                      ;; We may have inherited an initfunction
1022                      (let ((initfun (slot-definition-initfunction eslotd)))
1023                        (if initfun
1024                            (rplacd cell (funcall initfun))
1025                            cell))
1026                      cell)))))
1027       (unless (slot-definition-class eslotd)
1028         (setf (slot-definition-class eslotd) class))
1029       (initialize-internal-slot-functions eslotd))))
1030
1031 (defmethod compute-slots :around ((class standard-class))
1032   (let ((eslotds (call-next-method)))
1033     (std-compute-slots-around class eslotds)))
1034 (defmethod compute-slots :around ((class funcallable-standard-class))
1035   (let ((eslotds (call-next-method)))
1036     (std-compute-slots-around class eslotds)))
1037
1038 (defmethod compute-slots ((class structure-class))
1039   (mapcan (lambda (superclass)
1040             (mapcar (lambda (dslotd)
1041                       (compute-effective-slot-definition
1042                        class
1043                        (slot-definition-name dslotd)
1044                        (list dslotd)))
1045                     (class-direct-slots superclass)))
1046           (reverse (slot-value class '%class-precedence-list))))
1047
1048 (defmethod compute-slots :around ((class structure-class))
1049   (let ((eslotds (call-next-method)))
1050     (mapc #'initialize-internal-slot-functions eslotds)
1051     eslotds))
1052
1053 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1054   (declare (ignore name))
1055   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1056          (class (apply #'effective-slot-definition-class class initargs)))
1057     (apply #'make-instance class initargs)))
1058
1059 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1060   (declare (ignore initargs))
1061   (find-class 'standard-effective-slot-definition))
1062
1063 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1064   (declare (ignore initargs))
1065   (find-class 'structure-effective-slot-definition))
1066
1067 (defmethod compute-effective-slot-definition-initargs
1068     ((class slot-class) direct-slotds)
1069   (let* ((name nil)
1070          (initfunction nil)
1071          (initform nil)
1072          (initargs nil)
1073          (allocation nil)
1074          (allocation-class nil)
1075          (type t)
1076          (documentation nil)
1077          (documentationp nil)
1078          (namep  nil)
1079          (initp  nil)
1080          (allocp nil))
1081
1082     (dolist (slotd direct-slotds)
1083       (when slotd
1084         (unless namep
1085           (setq name (slot-definition-name slotd)
1086                 namep t))
1087         (unless initp
1088           (when (slot-definition-initfunction slotd)
1089             (setq initform (slot-definition-initform slotd)
1090                   initfunction (slot-definition-initfunction slotd)
1091                   initp t)))
1092         (unless documentationp
1093           (when (%slot-definition-documentation slotd)
1094             (setq documentation (%slot-definition-documentation slotd)
1095                   documentationp t)))
1096         (unless allocp
1097           (setq allocation (slot-definition-allocation slotd)
1098                 allocation-class (slot-definition-class slotd)
1099                 allocp t))
1100         (setq initargs (append (slot-definition-initargs slotd) initargs))
1101         (let ((slotd-type (slot-definition-type slotd)))
1102           (setq type (cond
1103                        ((eq type t) slotd-type)
1104                        ;; This pairwise type intersection is perhaps a
1105                        ;; little inefficient and inelegant, but it's
1106                        ;; unlikely to lie on the critical path.  Shout
1107                        ;; if I'm wrong.  -- CSR, 2005-11-24
1108                        (t (type-specifier
1109                            (specifier-type `(and ,type ,slotd-type)))))))))
1110     (list :name name
1111           :initform initform
1112           :initfunction initfunction
1113           :initargs initargs
1114           :allocation allocation
1115           :allocation-class allocation-class
1116           :type type
1117           :class class
1118           :documentation documentation)))
1119
1120 (defmethod compute-effective-slot-definition-initargs :around
1121     ((class structure-class) direct-slotds)
1122   (let ((slotd (car direct-slotds)))
1123     (list* :defstruct-accessor-symbol
1124            (slot-definition-defstruct-accessor-symbol slotd)
1125            :internal-reader-function
1126            (slot-definition-internal-reader-function slotd)
1127            :internal-writer-function
1128            (slot-definition-internal-writer-function slotd)
1129            (call-next-method))))
1130 \f
1131 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1132 ;;;       to make the method object. They have to use make-a-method which
1133 ;;;       is a specially bootstrapped mechanism for making standard methods.
1134 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1135   (declare (ignore direct-slot initargs))
1136   (find-class 'standard-reader-method))
1137
1138 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
1139   (add-method generic-function
1140               (make-a-method 'standard-reader-method
1141                              ()
1142                              (list (or (class-name class) 'object))
1143                              (list class)
1144                              (make-reader-method-function class slot-name)
1145                              "automatically generated reader method"
1146                              slot-name)))
1147
1148 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1149   (declare (ignore direct-slot initargs))
1150   (find-class 'standard-writer-method))
1151
1152 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
1153   (add-method generic-function
1154               (make-a-method 'standard-writer-method
1155                              ()
1156                              (list 'new-value (or (class-name class) 'object))
1157                              (list *the-class-t* class)
1158                              (make-writer-method-function class slot-name)
1159                              "automatically generated writer method"
1160                              slot-name)))
1161
1162 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
1163   (add-method generic-function
1164               (make-a-method 'standard-boundp-method
1165                              ()
1166                              (list (or (class-name class) 'object))
1167                              (list class)
1168                              (make-boundp-method-function class slot-name)
1169                              "automatically generated boundp method"
1170                              slot-name)))
1171
1172 (defmethod remove-reader-method ((class slot-class) generic-function)
1173   (let ((method (get-method generic-function () (list class) nil)))
1174     (when method (remove-method generic-function method))))
1175
1176 (defmethod remove-writer-method ((class slot-class) generic-function)
1177   (let ((method
1178           (get-method generic-function () (list *the-class-t* class) nil)))
1179     (when method (remove-method generic-function method))))
1180
1181 (defmethod remove-boundp-method ((class slot-class) generic-function)
1182   (let ((method (get-method generic-function () (list class) nil)))
1183     (when method (remove-method generic-function method))))
1184 \f
1185 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITE-METHOD function are NOT
1186 ;;; part of the standard protocol. They are however useful, PCL makes
1187 ;;; use of them internally and documents them for PCL users.
1188 ;;;
1189 ;;; *** This needs work to make type testing by the writer functions which
1190 ;;; *** do type testing faster. The idea would be to have one constructor
1191 ;;; *** for each possible type test.
1192 ;;;
1193 ;;; *** There is a subtle bug here which is going to have to be fixed.
1194 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1195 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1196 ;;; *** defined for this metaclass a chance to run.
1197
1198 (defmethod make-reader-method-function ((class slot-class) slot-name)
1199   (make-std-reader-method-function (class-name class) slot-name))
1200
1201 (defmethod make-writer-method-function ((class slot-class) slot-name)
1202   (make-std-writer-method-function (class-name class) slot-name))
1203
1204 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1205   (make-std-boundp-method-function (class-name class) slot-name))
1206 \f
1207 (defmethod compatible-meta-class-change-p (class proto-new-class)
1208   (eq (class-of class) (class-of proto-new-class)))
1209
1210 (defmethod validate-superclass ((class class) (superclass class))
1211   (or (eq superclass *the-class-t*)
1212       (eq (class-of class) (class-of superclass))
1213       (and (eq (class-of superclass) *the-class-standard-class*)
1214            (eq (class-of class) *the-class-funcallable-standard-class*))
1215       (and (eq (class-of superclass) *the-class-funcallable-standard-class*)
1216            (eq (class-of class) *the-class-standard-class*))))
1217 \f
1218 ;;; What this does depends on which of the four possible values of
1219 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1220 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1221 ;;; nothing to do, as the new wrapper has already been created.  If
1222 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1223 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1224 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1225 ;;;
1226 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1227 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1228 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1229 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1230 ;;; obsolete the wrapper.
1231 ;;;
1232 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1233 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1234 ;;;                    :UNINITIALIZED)))
1235 ;;;
1236 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1237 (defun force-cache-flushes (class)
1238   (let* ((owrapper (class-wrapper class)))
1239     ;; We only need to do something if the wrapper is still valid. If
1240     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1241     ;; both of those will already be doing what we want. In
1242     ;; particular, we must be sure we never change an OBSOLETE into a
1243     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1244     (when (or (not (invalid-wrapper-p owrapper))
1245               ;; KLUDGE: despite the observations above, this remains
1246               ;; a violation of locality or what might be considered
1247               ;; good style.  There has to be a better way!  -- CSR,
1248               ;; 2002-10-29
1249               (eq (layout-invalid owrapper) t))
1250       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1251                                     class)))
1252         (setf (wrapper-instance-slots-layout nwrapper)
1253               (wrapper-instance-slots-layout owrapper))
1254         (setf (wrapper-class-slots nwrapper)
1255               (wrapper-class-slots owrapper))
1256         (with-pcl-lock
1257           (update-lisp-class-layout class nwrapper)
1258           (setf (slot-value class 'wrapper) nwrapper)
1259           ;; Use :OBSOLETE instead of :FLUSH if any superclass has
1260           ;; been obsoleted.
1261           (if (find-if (lambda (x)
1262                          (and (consp x) (eq :obsolete (car x))))
1263                        (layout-inherits owrapper)
1264                        :key #'layout-invalid)
1265               (invalidate-wrapper owrapper :obsolete nwrapper)
1266               (invalidate-wrapper owrapper :flush nwrapper)))))))
1267
1268 (defun flush-cache-trap (owrapper nwrapper instance)
1269   (declare (ignore owrapper))
1270   (set-wrapper instance nwrapper))
1271 \f
1272 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1273 ;;; the next access to the instance (as defined in 88-002R) to trap
1274 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1275 (defmethod make-instances-obsolete ((class std-class))
1276   (let* ((owrapper (class-wrapper class))
1277          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1278                                  class)))
1279       (setf (wrapper-instance-slots-layout nwrapper)
1280             (wrapper-instance-slots-layout owrapper))
1281       (setf (wrapper-class-slots nwrapper)
1282             (wrapper-class-slots owrapper))
1283       (with-pcl-lock
1284         (update-lisp-class-layout class nwrapper)
1285         (setf (slot-value class 'wrapper) nwrapper)
1286         (invalidate-wrapper owrapper :obsolete nwrapper)
1287         class)))
1288
1289 (defmethod make-instances-obsolete ((class symbol))
1290   (make-instances-obsolete (find-class class))
1291   ;; ANSI wants the class name when called with a symbol.
1292   class)
1293
1294 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1295 ;;; see an obsolete instance. The times when it is called are:
1296 ;;;   - when the instance is involved in method lookup
1297 ;;;   - when attempting to access a slot of an instance
1298 ;;;
1299 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1300 ;;; instance access macros.
1301 ;;;
1302 ;;; Of course these times when it is called are an internal
1303 ;;; implementation detail of PCL and are not part of the documented
1304 ;;; description of when the obsolete instance update happens. The
1305 ;;; documented description is as it appears in 88-002R.
1306 ;;;
1307 ;;; This has to return the new wrapper, so it counts on all the
1308 ;;; methods on obsolete-instance-trap-internal to return the new
1309 ;;; wrapper. It also does a little internal error checking to make
1310 ;;; sure that the traps are only happening when they should, and that
1311 ;;; the trap methods are computing appropriate new wrappers.
1312
1313 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1314 ;;; after a structure is redefined. In most cases,
1315 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1316 ;;; so it must signal an error. The hard part of this is that the
1317 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1318 ;;; called again, so in that case, we have to return some reasonable
1319 ;;; wrapper, instead.
1320
1321 (defvar *in-obsolete-instance-trap* nil)
1322 (defvar *the-wrapper-of-structure-object*
1323   (class-wrapper (find-class 'structure-object)))
1324
1325 (define-condition obsolete-structure (error)
1326   ((datum :reader obsolete-structure-datum :initarg :datum))
1327   (:report
1328    (lambda (condition stream)
1329      ;; Don't try to print the structure, since it probably won't work.
1330      (format stream
1331              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1332              (type-of (obsolete-structure-datum condition))))))
1333
1334 (defun obsolete-instance-trap (owrapper nwrapper instance)
1335   (if (not (pcl-instance-p instance))
1336       (if *in-obsolete-instance-trap*
1337           *the-wrapper-of-structure-object*
1338            (let ((*in-obsolete-instance-trap* t))
1339              (error 'obsolete-structure :datum instance)))
1340       (let* ((class (wrapper-class* nwrapper))
1341              (copy (allocate-instance class)) ;??? allocate-instance ???
1342              (olayout (wrapper-instance-slots-layout owrapper))
1343              (nlayout (wrapper-instance-slots-layout nwrapper))
1344              (oslots (get-slots instance))
1345              (nslots (get-slots copy))
1346              (oclass-slots (wrapper-class-slots owrapper))
1347              (added ())
1348              (discarded ())
1349              (plist ()))
1350
1351         ;; local  --> local     transfer value
1352         ;; local  --> shared    discard value, discard slot
1353         ;; local  -->  --       discard slot
1354         ;; shared --> local     transfer value
1355         ;; shared --> shared    -- (cf SHARED-INITIALIZE :AFTER STD-CLASS)
1356         ;; shared -->  --       discard value
1357         ;;  --    --> local     add slot
1358         ;;  --    --> shared    --
1359
1360         ;; Collect class slots from inherited wrappers. Needed for
1361         ;; shared -> local transfers of inherited slots.
1362         (let ((inherited (layout-inherits owrapper)))
1363           (loop for i from (1- (length inherited)) downto 0
1364                 for layout = (aref inherited i)
1365                 when (typep layout 'wrapper)
1366                 do (dolist (slot (wrapper-class-slots layout))
1367                      (pushnew slot oclass-slots :key #'car))))
1368
1369         ;; Go through all the old local slots.
1370         (let ((opos 0))
1371           (dolist (name olayout)
1372             (let ((npos (posq name nlayout)))
1373               (if npos
1374                   (setf (clos-slots-ref nslots npos)
1375                         (clos-slots-ref oslots opos))
1376                   (progn
1377                     (push name discarded)
1378                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1379                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1380             (incf opos)))
1381
1382         ;; Go through all the old shared slots.
1383         (dolist (oclass-slot-and-val oclass-slots)
1384           (let ((name (car oclass-slot-and-val))
1385                 (val (cdr oclass-slot-and-val)))
1386             (let ((npos (posq name nlayout)))
1387               (when npos
1388                 (setf (clos-slots-ref nslots npos) val)))))
1389
1390         ;; Go through all the new local slots to compute the added slots.
1391         (dolist (nlocal nlayout)
1392           (unless (or (memq nlocal olayout)
1393                       (assq nlocal oclass-slots))
1394             (push nlocal added)))
1395
1396         (swap-wrappers-and-slots instance copy)
1397
1398         (update-instance-for-redefined-class instance
1399                                              added
1400                                              discarded
1401                                              plist)
1402         nwrapper)))
1403 \f
1404 (defun change-class-internal (instance new-class initargs)
1405   (let* ((old-class (class-of instance))
1406          (copy (allocate-instance new-class))
1407          (new-wrapper (get-wrapper copy))
1408          (old-wrapper (class-wrapper old-class))
1409          (old-layout (wrapper-instance-slots-layout old-wrapper))
1410          (new-layout (wrapper-instance-slots-layout new-wrapper))
1411          (old-slots (get-slots instance))
1412          (new-slots (get-slots copy))
1413          (old-class-slots (wrapper-class-slots old-wrapper)))
1414
1415     ;; "The values of local slots specified by both the class CTO and
1416     ;; CFROM are retained. If such a local slot was unbound, it
1417     ;; remains unbound."
1418     (let ((new-position 0))
1419       (dolist (new-slot new-layout)
1420         (let ((old-position (posq new-slot old-layout)))
1421           (when old-position
1422             (setf (clos-slots-ref new-slots new-position)
1423                   (clos-slots-ref old-slots old-position))))
1424         (incf new-position)))
1425
1426     ;; "The values of slots specified as shared in the class CFROM and
1427     ;; as local in the class CTO are retained."
1428     (dolist (slot-and-val old-class-slots)
1429       (let ((position (posq (car slot-and-val) new-layout)))
1430         (when position
1431           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1432
1433     ;; Make the copy point to the old instance's storage, and make the
1434     ;; old instance point to the new storage.
1435     (swap-wrappers-and-slots instance copy)
1436
1437     (apply #'update-instance-for-different-class copy instance initargs)
1438     instance))
1439
1440 (defmethod change-class ((instance standard-object) (new-class standard-class)
1441                          &rest initargs)
1442   (let ((cpl (class-precedence-list new-class)))
1443     (dolist (class cpl)
1444       (macrolet
1445           ((frob (class-name)
1446              `(when (eq class (find-class ',class-name))
1447                (error 'metaobject-initialization-violation
1448                 :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1449                 :format-arguments (list 'change-class ',class-name)
1450                 :references (list '(:amop :initialization ,class-name))))))
1451         (frob class)
1452         (frob generic-function)
1453         (frob method)
1454         (frob slot-definition))))
1455   (change-class-internal instance new-class initargs))
1456
1457 (defmethod change-class ((instance forward-referenced-class)
1458                          (new-class standard-class) &rest initargs)
1459   (let ((cpl (class-precedence-list new-class)))
1460     (dolist (class cpl
1461              (error 'metaobject-initialization-violation
1462                     :format-control
1463                     "~@<Cannot ~S ~S objects into non-~S objects.~@:>"
1464                     :format-arguments
1465                     (list 'change-class 'forward-referenced-class 'class)
1466                     :references
1467                     (list '(:amop :generic-function ensure-class-using-class)
1468                           '(:amop :initialization class))))
1469       (when (eq class (find-class 'class))
1470         (return nil))))
1471   (change-class-internal instance new-class initargs))
1472
1473 (defmethod change-class ((instance funcallable-standard-object)
1474                          (new-class funcallable-standard-class)
1475                          &rest initargs)
1476   (let ((cpl (class-precedence-list new-class)))
1477     (dolist (class cpl)
1478       (macrolet
1479           ((frob (class-name)
1480              `(when (eq class (find-class ',class-name))
1481                (error 'metaobject-initialization-violation
1482                 :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1483                 :format-arguments (list 'change-class ',class-name)
1484                 :references (list '(:amop :initialization ,class-name))))))
1485         (frob class)
1486         (frob generic-function)
1487         (frob method)
1488         (frob slot-definition))))
1489   (change-class-internal instance new-class initargs))
1490
1491 (defmethod change-class ((instance standard-object)
1492                          (new-class funcallable-standard-class)
1493                          &rest initargs)
1494   (declare (ignore initargs))
1495   (error "You can't change the class of ~S to ~S~@
1496           because it isn't already an instance with metaclass ~S."
1497          instance new-class 'standard-class))
1498
1499 (defmethod change-class ((instance funcallable-standard-object)
1500                          (new-class standard-class)
1501                          &rest initargs)
1502   (declare (ignore initargs))
1503   (error "You can't change the class of ~S to ~S~@
1504           because it isn't already an instance with metaclass ~S."
1505          instance new-class 'funcallable-standard-class))
1506
1507 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1508   (apply #'change-class instance (find-class new-class-name) initargs))
1509 \f
1510 ;;;; The metaclass BUILT-IN-CLASS
1511 ;;;;
1512 ;;;; This metaclass is something of a weird creature. By this point, all
1513 ;;;; instances of it which will exist have been created, and no instance
1514 ;;;; is ever created by calling MAKE-INSTANCE.
1515 ;;;;
1516 ;;;; But, there are other parts of the protocol we must follow and those
1517 ;;;; definitions appear here.
1518
1519 (macrolet ((def (name args control)
1520                `(defmethod ,name ,args
1521                  (declare (ignore initargs))
1522                  (error 'metaobject-initialization-violation
1523                   :format-control ,(format nil "~@<~A~@:>" control)
1524                   :format-arguments (list ',name)
1525                   :references (list '(:amop :initialization "Class"))))))
1526   (def initialize-instance ((class built-in-class) &rest initargs)
1527     "Cannot ~S an instance of BUILT-IN-CLASS.")
1528   (def reinitialize-instance ((class built-in-class) &rest initargs)
1529     "Cannot ~S an instance of BUILT-IN-CLASS."))
1530
1531 (macrolet ((def (name)
1532                `(defmethod ,name ((class built-in-class)) nil)))
1533   (def class-direct-slots)
1534   (def class-slots)
1535   (def class-direct-default-initargs)
1536   (def class-default-initargs))
1537
1538 (defmethod validate-superclass ((c class) (s built-in-class))
1539   (or (eq s *the-class-t*) (eq s *the-class-stream*)
1540       ;; FIXME: bad things happen if someone tries to mix in both
1541       ;; FILE-STREAM and STRING-STREAM (as they have the same
1542       ;; layout-depthoid).  Is there any way we can provide a useful
1543       ;; error message?  -- CSR, 2005-05-03
1544       (eq s *the-class-file-stream*) (eq s *the-class-string-stream*)))
1545 \f
1546 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1547 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1548 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1549 (macrolet ((def (method)
1550              `(defmethod ,method ((class forward-referenced-class))
1551                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1552                        ',method class))))
1553   (def class-default-initargs)
1554   (def class-precedence-list)
1555   (def class-slots))
1556
1557 (defmethod validate-superclass ((c slot-class)
1558                                 (f forward-referenced-class))
1559   t)
1560 \f
1561 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1562   (pushnew dependent (plist-value metaobject 'dependents)))
1563
1564 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1565   (setf (plist-value metaobject 'dependents)
1566         (delete dependent (plist-value metaobject 'dependents))))
1567
1568 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1569   (dolist (dependent (plist-value metaobject 'dependents))
1570     (funcall function dependent)))
1571