src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd 'class)))
  76     (let ((table (or (gethash name *name->class->slotd-table*)
  77                      (setf (gethash name *name->class->slotd-table*)
  78                            (make-hash-table :test 'eq :size 5)))))
  79       (setf (gethash class table) slotd))
  80     (dolist (type '(reader writer boundp))
  81       (let* ((gf-name (ecase type
  82                               (reader 'slot-value-using-class)
  83                               (writer '(setf slot-value-using-class))
  84                               (boundp 'slot-boundp-using-class)))
  85              (gf (gdefinition gf-name)))
  86         (compute-slot-accessor-info slotd type gf)))
  87     (initialize-internal-slot-gfs name)))
  88
  89 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  90                                        type gf)
  91   (let* ((name (slot-value slotd 'name))
  92          (class (slot-value slotd 'class))
  93          (old-slotd (find-slot-definition class name))
  94          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
  95     (multiple-value-bind (function std-p)
  96         (if (eq *boot-state* 'complete)
  97             (get-accessor-method-function gf type class slotd)
  98             (get-optimized-std-accessor-method-function class slotd type))
  99       (setf (slot-accessor-std-p slotd type) std-p)
 100       (setf (slot-accessor-function slotd type) function))
 101     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 102       (push (cons class name) *pv-table-cache-update-info*))))
 103
 104 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 105   :instance)
 106 \f
 107 (defmethod shared-initialize :after ((object documentation-mixin)
 108                                      slot-names
 109                                      &key (documentation nil documentation-p))
 110   (declare (ignore slot-names))
 111   (when documentation-p
 112     (setf (plist-value object 'documentation) documentation)))
 113
 114 ;;; default if DOC-TYPE doesn't match one of the specified types
 115 (defmethod documentation (object doc-type)
 116   (warn "unsupported DOCUMENTATION: type ~S for object ~S"
 117         doc-type
 118         (type-of object))
 119   nil)
 120
 121 ;;; default if DOC-TYPE doesn't match one of the specified types
 122 (defmethod (setf documentation) (new-value object doc-type)
 123   ;; CMU CL made this an error, but since ANSI says that even for supported
 124   ;; doc types an implementation is permitted to discard docs at any time
 125   ;; for any reason, this feels to me more like a warning. -- WHN 19991214
 126   (warn "discarding unsupported DOCUMENTATION of type ~S for object ~S"
 127         doc-type
 128         (type-of object))
 129   new-value)
 130
 131 (defmethod documentation ((object documentation-mixin) doc-type)
 132   (declare (ignore doc-type))
 133   (plist-value object 'documentation))
 134
 135 (defmethod (setf documentation) (new-value
 136                                  (object documentation-mixin)
 137                                  doc-type)
 138   (declare (ignore doc-type))
 139   (setf (plist-value object 'documentation) new-value))
 140
 141 (defmethod documentation ((slotd standard-slot-definition) doc-type)
 142   (declare (ignore doc-type))
 143   (slot-value slotd 'documentation))
 144
 145 (defmethod (setf documentation) (new-value
 146                                  (slotd standard-slot-definition)
 147                                  doc-type)
 148   (declare (ignore doc-type))
 149   (setf (slot-value slotd 'documentation) new-value))
 150 \f
 151 ;;;; various class accessors that are a little more complicated than can be
 152 ;;;; done with automatically generated reader methods
 153
 154 (defmethod class-finalized-p ((class pcl-class))
 155   (with-slots (wrapper) class
 156     (not (null wrapper))))
 157
 158 (defmethod class-prototype ((class std-class))
 159   (with-slots (prototype) class
 160     (or prototype (setq prototype (allocate-instance class)))))
 161
 162 (defmethod class-prototype ((class structure-class))
 163   (with-slots (prototype wrapper defstruct-constructor) class
 164     (or prototype
 165         (setq prototype
 166               (if defstruct-constructor
 167                   (allocate-instance class)
 168                   (allocate-standard-instance wrapper))))))
 169
 170 (defmethod class-direct-default-initargs ((class slot-class))
 171   (plist-value class 'direct-default-initargs))
 172
 173 (defmethod class-default-initargs ((class slot-class))
 174   (plist-value class 'default-initargs))
 175
 176 (defmethod class-constructors ((class slot-class))
 177   (plist-value class 'constructors))
 178
 179 (defmethod class-slot-cells ((class std-class))
 180   (plist-value class 'class-slot-cells))
 181 \f
 182 ;;;; class accessors that are even a little bit more complicated than those
 183 ;;;; above. These have a protocol for updating them, we must implement that
 184 ;;;; protocol.
 185
 186 ;;; Maintaining the direct subclasses backpointers. The update methods are
 187 ;;; here, the values are read by an automatically generated reader method.
 188 (defmethod add-direct-subclass ((class class) (subclass class))
 189   (with-slots (direct-subclasses) class
 190     (pushnew subclass direct-subclasses)
 191     subclass))
 192 (defmethod remove-direct-subclass ((class class) (subclass class))
 193   (with-slots (direct-subclasses) class
 194     (setq direct-subclasses (remove subclass direct-subclasses))
 195     subclass))
 196
 197 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 198 ;;;
 199 ;;; There are four generic functions involved, each has one method for the
 200 ;;; class case and another method for the damned EQL specializers. All of
 201 ;;; these are specified methods and appear in their specified place in the
 202 ;;; class graph.
 203 ;;;
 204 ;;;   ADD-DIRECT-METHOD
 205 ;;;   REMOVE-DIRECT-METHOD
 206 ;;;   SPECIALIZER-DIRECT-METHODS
 207 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 208 ;;;
 209 ;;; In each case, we maintain one value which is a cons. The car is the list
 210 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 211 ;;; computed lazily.
 212 (defmethod add-direct-method ((specializer class) (method method))
 213   (with-slots (direct-methods) specializer
 214     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 215           (cdr direct-methods) ()))
 216   method)
 217 (defmethod remove-direct-method ((specializer class) (method method))
 218   (with-slots (direct-methods) specializer
 219     (setf (car direct-methods) (remove method (car direct-methods))
 220           (cdr direct-methods) ()))
 221   method)
 222
 223 (defmethod specializer-direct-methods ((specializer class))
 224   (with-slots (direct-methods) specializer
 225     (car direct-methods)))
 226
 227 (defmethod specializer-direct-generic-functions ((specializer class))
 228   (with-slots (direct-methods) specializer
 229     (or (cdr direct-methods)
 230         (setf (cdr direct-methods)
 231               (gathering1 (collecting-once)
 232                 (dolist (m (car direct-methods))
 233                   (gather1 (method-generic-function m))))))))
 234 \f
 235 ;;; This hash table is used to store the direct methods and direct generic
 236 ;;; functions of EQL specializers. Each value in the table is the cons.
 237 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 238 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 239
 240 (defmethod specializer-method-table ((specializer eql-specializer))
 241   *eql-specializer-methods*)
 242
 243 (defmethod specializer-method-table ((specializer class-eq-specializer))
 244   *class-eq-specializer-methods*)
 245
 246 (defmethod add-direct-method ((specializer specializer-with-object)
 247                               (method method))
 248   (let* ((object (specializer-object specializer))
 249          (table (specializer-method-table specializer))
 250          (entry (gethash object table)))
 251     (unless entry
 252       (setq entry
 253             (setf (gethash object table)
 254                   (cons nil nil))))
 255     (setf (car entry) (adjoin method (car entry))
 256           (cdr entry) ())
 257     method))
 258
 259 (defmethod remove-direct-method ((specializer specializer-with-object)
 260                                  (method method))
 261   (let* ((object (specializer-object specializer))
 262          (entry (gethash object (specializer-method-table specializer))))
 263     (when entry
 264       (setf (car entry) (remove method (car entry))
 265             (cdr entry) ()))
 266     method))
 267
 268 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 269   (car (gethash (specializer-object specializer)
 270                 (specializer-method-table specializer))))
 271
 272 (defmethod specializer-direct-generic-functions ((specializer
 273                                                   specializer-with-object))
 274   (let* ((object (specializer-object specializer))
 275          (entry (gethash object (specializer-method-table specializer))))
 276     (when entry
 277       (or (cdr entry)
 278           (setf (cdr entry)
 279                 (gathering1 (collecting-once)
 280                   (dolist (m (car entry))
 281                     (gather1 (method-generic-function m)))))))))
 282
 283 (defun map-specializers (function)
 284   (map-all-classes #'(lambda (class)
 285                        (funcall function (class-eq-specializer class))
 286                        (funcall function class)))
 287   (maphash #'(lambda (object methods)
 288                (declare (ignore methods))
 289                (intern-eql-specializer object))
 290            *eql-specializer-methods*)
 291   (maphash #'(lambda (object specl)
 292                (declare (ignore object))
 293                (funcall function specl))
 294            *eql-specializer-table*)
 295   nil)
 296
 297 (defun map-all-generic-functions (function)
 298   (let ((all-generic-functions (make-hash-table :test 'eq)))
 299     (map-specializers #'(lambda (specl)
 300                           (dolist (gf (specializer-direct-generic-functions
 301                                        specl))
 302                             (unless (gethash gf all-generic-functions)
 303                               (setf (gethash gf all-generic-functions) t)
 304                               (funcall function gf))))))
 305   nil)
 306
 307 (defmethod shared-initialize :after ((specl class-eq-specializer)
 308                                      slot-names
 309                                      &key)
 310   (declare (ignore slot-names))
 311   (setf (slot-value specl 'type) `(class-eq ,(specializer-class specl))))
 312
 313 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 314   (declare (ignore slot-names))
 315   (setf (slot-value specl 'type) `(eql ,(specializer-object specl))))
 316 \f
 317 (defun real-load-defclass (name metaclass-name supers slots other)
 318   (let ((res (apply #'ensure-class name :metaclass metaclass-name
 319                     :direct-superclasses supers
 320                     :direct-slots slots
 321                     :definition-source `((defclass ,name)
 322                                          ,*load-truename*)
 323                     other)))
 324     ;; Defclass of a class with a forward-referenced superclass does not
 325     ;; have a wrapper. RES is the incomplete PCL class. The Lisp class
 326     ;; does not yet exist. Maybe should return NIL in that case as RES
 327     ;; is not useful to the user?
 328     (and (class-wrapper res) (sb-kernel:layout-class (class-wrapper res)))))
 329
 330 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 331
 332 (defun ensure-class (name &rest all)
 333   (apply #'ensure-class-using-class name (find-class name nil) all))
 334
 335 (defmethod ensure-class-using-class (name (class null) &rest args &key)
 336   (multiple-value-bind (meta initargs)
 337       (ensure-class-values class args)
 338     (setf class (apply #'make-instance meta :name name initargs)
 339           (find-class name) class)
 340     (inform-type-system-about-class class name)
 341     class))
 342
 343 (defmethod ensure-class-using-class (name (class pcl-class) &rest args &key)
 344   (multiple-value-bind (meta initargs)
 345       (ensure-class-values class args)
 346     (unless (eq (class-of class) meta) (change-class class meta))
 347     (apply #'reinitialize-instance class initargs)
 348     (setf (find-class name) class)
 349     (inform-type-system-about-class class name)
 350     class))
 351
 352 (defmethod class-predicate-name ((class t))
 353   'constantly-nil)
 354
 355 (defun ensure-class-values (class args)
 356   (let* ((initargs (copy-list args))
 357          (unsupplied (list 1))
 358          (supplied-meta   (getf initargs :metaclass unsupplied))
 359          (supplied-supers (getf initargs :direct-superclasses unsupplied))
 360          (supplied-slots  (getf initargs :direct-slots unsupplied))
 361          (meta
 362            (cond ((neq supplied-meta unsupplied)
 363                   (find-class supplied-meta))
 364                  ((or (null class)
 365                       (forward-referenced-class-p class))
 366                   *the-class-standard-class*)
 367                  (t
 368                   (class-of class)))))
 369     (flet ((fix-super (s)
 370              (cond ((classp s) s)
 371                    ((not (legal-class-name-p s))
 372                     (error "~S is not a class or a legal class name." s))
 373                    (t
 374                     (or (find-class s nil)
 375                         (setf (find-class s)
 376                               (make-instance 'forward-referenced-class
 377                                              :name s)))))))
 378       (loop (unless (remf initargs :metaclass) (return)))
 379       (loop (unless (remf initargs :direct-superclasses) (return)))
 380       (loop (unless (remf initargs :direct-slots) (return)))
 381       (values meta
 382               (list* :direct-superclasses
 383                      (and (neq supplied-supers unsupplied)
 384                           (mapcar #'fix-super supplied-supers))
 385                      :direct-slots
 386                      (and (neq supplied-slots unsupplied) supplied-slots)
 387                      initargs)))))
 388 \f
 389
 390 (defmethod shared-initialize :after
 391            ((class std-class)
 392             slot-names
 393             &key (direct-superclasses nil direct-superclasses-p)
 394                  (direct-slots nil direct-slots-p)
 395                  (direct-default-initargs nil direct-default-initargs-p)
 396                  (predicate-name nil predicate-name-p))
 397   (declare (ignore slot-names))
 398   (cond (direct-superclasses-p
 399          (setq direct-superclasses
 400                (or direct-superclasses
 401                    (list (if (funcallable-standard-class-p class)
 402                              *the-class-funcallable-standard-object*
 403                              *the-class-standard-object*))))
 404          (dolist (superclass direct-superclasses)
 405            (unless (validate-superclass class superclass)
 406              (error "The class ~S was specified as a~%
 407                      super-class of the class ~S;~%~
 408                      but the meta-classes ~S and~%~S are incompatible.~@
 409                      Define a method for ~S to avoid this error."
 410                      superclass class (class-of superclass) (class-of class)
 411                      'validate-superclass)))
 412          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 413         (t
 414          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 415   (setq direct-slots
 416         (if direct-slots-p
 417             (setf (slot-value class 'direct-slots)
 418                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 419                           direct-slots))
 420             (slot-value class 'direct-slots)))
 421   (if direct-default-initargs-p
 422       (setf (plist-value class 'direct-default-initargs)
 423             direct-default-initargs)
 424       (setq direct-default-initargs
 425             (plist-value class 'direct-default-initargs)))
 426   (setf (plist-value class 'class-slot-cells)
 427         (gathering1 (collecting)
 428           (dolist (dslotd direct-slots)
 429             (when (eq (slot-definition-allocation dslotd) class)
 430               (let ((initfunction (slot-definition-initfunction dslotd)))
 431                 (gather1 (cons (slot-definition-name dslotd)
 432                                (if initfunction
 433                                    (funcall initfunction)
 434                                    +slot-unbound+))))))))
 435   (setq predicate-name (if predicate-name-p
 436                            (setf (slot-value class 'predicate-name)
 437                                  (car predicate-name))
 438                            (or (slot-value class 'predicate-name)
 439                                (setf (slot-value class 'predicate-name)
 440                                      (make-class-predicate-name (class-name
 441                                                                  class))))))
 442   (add-direct-subclasses class direct-superclasses)
 443   (update-class class nil)
 444   (make-class-predicate class predicate-name)
 445   (add-slot-accessors class direct-slots))
 446
 447 (defmethod shared-initialize :before ((class class) slot-names &key name)
 448   (declare (ignore slot-names name))
 449   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 450   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 451   (setf (slot-value class 'type) `(class ,class))
 452   (setf (slot-value class 'class-eq-specializer)
 453         (make-instance 'class-eq-specializer :class class)))
 454
 455 (defmethod reinitialize-instance :before ((class slot-class) &key)
 456   (remove-direct-subclasses class (class-direct-superclasses class))
 457   (remove-slot-accessors    class (class-direct-slots class)))
 458
 459 (defmethod reinitialize-instance :after ((class slot-class)
 460                                          &rest initargs
 461                                          &key)
 462   (map-dependents class
 463                   #'(lambda (dependent)
 464                       (apply #'update-dependent class dependent initargs))))
 465
 466 (defmethod shared-initialize :after ((slotd standard-slot-definition)
 467                                      slot-names &key)
 468   (declare (ignore slot-names))
 469   (with-slots (allocation class)
 470     slotd
 471     (setq allocation (if (eq allocation :class) class allocation))))
 472
 473 (defmethod shared-initialize :after ((slotd structure-slot-definition)
 474                                      slot-names
 475                                      &key (allocation :instance))
 476   (declare (ignore slot-names))
 477   (unless (eq allocation :instance)
 478     (error "Structure slots must have :INSTANCE allocation.")))
 479
 480 (defmethod shared-initialize :after
 481       ((class structure-class)
 482        slot-names
 483        &key (direct-superclasses nil direct-superclasses-p)
 484             (direct-slots nil direct-slots-p)
 485             direct-default-initargs
 486             (predicate-name nil predicate-name-p))
 487   (declare (ignore slot-names direct-default-initargs))
 488   (if direct-superclasses-p
 489       (setf (slot-value class 'direct-superclasses)
 490             (or direct-superclasses
 491                 (setq direct-superclasses
 492                       (and (not (eq (class-name class) 'structure-object))
 493                            (list *the-class-structure-object*)))))
 494       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 495   (let* ((name (class-name class))
 496          (from-defclass-p (slot-value class 'from-defclass-p))
 497          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 498     (if direct-slots-p
 499         (setf (slot-value class 'direct-slots)
 500               (setq direct-slots
 501                     (mapcar #'(lambda (pl)
 502                                 (when defstruct-p
 503                                   (let* ((slot-name (getf pl :name))
 504                                          (acc-name
 505                                           (format nil
 506                                                   "~S structure class ~A"
 507                                                   name slot-name))
 508                                          (accessor (intern acc-name)))
 509                                     (setq pl (list* :defstruct-accessor-symbol
 510                                                     accessor pl))))
 511                                 (make-direct-slotd class pl))
 512                             direct-slots)))
 513         (setq direct-slots (slot-value class 'direct-slots)))
 514     (when defstruct-p
 515       (let* ((include (car (slot-value class 'direct-superclasses)))
 516              (conc-name (intern (format nil "~S structure class " name)))
 517              (constructor (intern (format nil "~A constructor" conc-name)))
 518              (defstruct `(defstruct (,name
 519                                       ,@(when include
 520                                           `((:include ,(class-name include))))
 521                                       (:print-function print-std-instance)
 522                                       (:predicate nil)
 523                                       (:conc-name ,conc-name)
 524                                       (:constructor ,constructor ())
 525                                       (:copier nil))
 526                            ,@(mapcar (lambda (slot)
 527                                        `(,(slot-definition-name slot)
 528                                          +slot-unbound+))
 529                                      direct-slots)))
 530              (reader-names (mapcar (lambda (slotd)
 531                                      (intern (format nil
 532                                                      "~A~A reader"
 533                                                      conc-name
 534                                                      (slot-definition-name
 535                                                       slotd))))
 536                                    direct-slots))
 537              (writer-names (mapcar (lambda (slotd)
 538                                      (intern (format nil
 539                                                      "~A~A writer"
 540                                                      conc-name
 541                                                      (slot-definition-name
 542                                                       slotd))))
 543                                    direct-slots))
 544              (readers-init
 545               (mapcar (lambda (slotd reader-name)
 546                         (let ((accessor
 547                                (slot-definition-defstruct-accessor-symbol
 548                                 slotd)))
 549                           `(defun ,reader-name (obj)
 550                              (declare (type ,name obj))
 551                              (,accessor obj))))
 552                       direct-slots reader-names))
 553              (writers-init
 554               (mapcar (lambda (slotd writer-name)
 555                         (let ((accessor
 556                                (slot-definition-defstruct-accessor-symbol
 557                                 slotd)))
 558                           `(defun ,writer-name (nv obj)
 559                              (declare (type ,name obj))
 560                              (setf (,accessor obj) nv))))
 561                       direct-slots writer-names))
 562              (defstruct-form
 563                `(progn
 564                   ,defstruct
 565                   ,@readers-init ,@writers-init
 566                   (cons nil nil))))
 567         (unless (structure-type-p name) (eval defstruct-form))
 568         (mapc #'(lambda (dslotd reader-name writer-name)
 569                   (let* ((reader (gdefinition reader-name))
 570                          (writer (when (gboundp writer-name)
 571                                    (gdefinition writer-name))))
 572                     (setf (slot-value dslotd 'internal-reader-function)
 573                           reader)
 574                     (setf (slot-value dslotd 'internal-writer-function)
 575                           writer)))
 576               direct-slots reader-names writer-names)
 577         (setf (slot-value class 'defstruct-form) defstruct-form)
 578         (setf (slot-value class 'defstruct-constructor) constructor))))
 579   (add-direct-subclasses class direct-superclasses)
 580   (setf (slot-value class 'class-precedence-list)
 581         (compute-class-precedence-list class))
 582   (setf (slot-value class 'slots) (compute-slots class))
 583   (let ((lclass (cl:find-class (class-name class))))
 584     (setf (sb-kernel:class-pcl-class lclass) class)
 585     (setf (slot-value class 'wrapper) (sb-kernel:class-layout lclass)))
 586   (update-pv-table-cache-info class)
 587   (setq predicate-name (if predicate-name-p
 588                            (setf (slot-value class 'predicate-name)
 589                                  (car predicate-name))
 590                            (or (slot-value class 'predicate-name)
 591                                (setf (slot-value class 'predicate-name)
 592                                      (make-class-predicate-name
 593                                       (class-name class))))))
 594   (make-class-predicate class predicate-name)
 595   (add-slot-accessors class direct-slots))
 596
 597 (defmethod direct-slot-definition-class ((class structure-class) initargs)
 598   (declare (ignore initargs))
 599   (find-class 'structure-direct-slot-definition))
 600
 601 (defmethod finalize-inheritance ((class structure-class))
 602   nil) ; always finalized
 603 \f
 604 (defun add-slot-accessors (class dslotds)
 605   (fix-slot-accessors class dslotds 'add))
 606
 607 (defun remove-slot-accessors (class dslotds)
 608   (fix-slot-accessors class dslotds 'remove))
 609
 610 (defun fix-slot-accessors (class dslotds add/remove)
 611   (flet ((fix (gfspec name r/w)
 612            (let ((gf (ensure-generic-function gfspec)))
 613              (case r/w
 614                (r (if (eq add/remove 'add)
 615                       (add-reader-method class gf name)
 616                       (remove-reader-method class gf)))
 617                (w (if (eq add/remove 'add)
 618                       (add-writer-method class gf name)
 619                       (remove-writer-method class gf)))))))
 620     (dolist (dslotd dslotds)
 621       (let ((slot-name (slot-definition-name dslotd)))
 622         (dolist (r (slot-definition-readers dslotd)) (fix r slot-name 'r))
 623         (dolist (w (slot-definition-writers dslotd)) (fix w slot-name 'w))))))
 624 \f
 625 (defun add-direct-subclasses (class new)
 626   (dolist (n new)
 627     (unless (memq class (class-direct-subclasses class))
 628       (add-direct-subclass n class))))
 629
 630 (defun remove-direct-subclasses (class new)
 631   (let ((old (class-direct-superclasses class)))
 632     (dolist (o (set-difference old new))
 633       (remove-direct-subclass o class))))
 634 \f
 635 (defmethod finalize-inheritance ((class std-class))
 636   (update-class class t))
 637 \f
 638 (defun class-has-a-forward-referenced-superclass-p (class)
 639   (or (forward-referenced-class-p class)
 640       (some #'class-has-a-forward-referenced-superclass-p
 641             (class-direct-superclasses class))))
 642
 643 ;;; This is called by :after shared-initialize whenever a class is initialized
 644 ;;; or reinitialized. The class may or may not be finalized.
 645 (defun update-class (class finalizep)
 646   (when (or finalizep (class-finalized-p class)
 647             (not (class-has-a-forward-referenced-superclass-p class)))
 648     (update-cpl class (compute-class-precedence-list class))
 649     (update-slots class (compute-slots class))
 650     (update-gfs-of-class class)
 651     (update-inits class (compute-default-initargs class))
 652     (update-make-instance-function-table class))
 653   (unless finalizep
 654     (dolist (sub (class-direct-subclasses class)) (update-class sub nil))))
 655
 656 (defun update-cpl (class cpl)
 657   (if (class-finalized-p class)
 658       (unless (equal (class-precedence-list class) cpl)
 659         ;; comment from the old CMU CL sources:
 660         ;;   Need to have the cpl setup before update-lisp-class-layout
 661         ;;   is called on CMU CL.
 662         (setf (slot-value class 'class-precedence-list) cpl)
 663         (force-cache-flushes class))
 664       (setf (slot-value class 'class-precedence-list) cpl))
 665   (update-class-can-precede-p cpl))
 666
 667 (defun update-class-can-precede-p (cpl)
 668   (when cpl
 669     (let ((first (car cpl)))
 670       (dolist (c (cdr cpl))
 671         (pushnew c (slot-value first 'can-precede-list))))
 672     (update-class-can-precede-p (cdr cpl))))
 673
 674 (defun class-can-precede-p (class1 class2)
 675   (member class2 (class-can-precede-list class1)))
 676
 677 (defun update-slots (class eslotds)
 678   (let ((instance-slots ())
 679         (class-slots    ()))
 680     (dolist (eslotd eslotds)
 681       (let ((alloc (slot-definition-allocation eslotd)))
 682         (cond ((eq alloc :instance) (push eslotd instance-slots))
 683               ((classp alloc)       (push eslotd class-slots)))))
 684
 685     ;; If there is a change in the shape of the instances then the
 686     ;; old class is now obsolete.
 687     (let* ((nlayout (mapcar #'slot-definition-name
 688                             (sort instance-slots #'<
 689                                   :key #'slot-definition-location)))
 690            (nslots (length nlayout))
 691            (nwrapper-class-slots (compute-class-slots class-slots))
 692            (owrapper (class-wrapper class))
 693            (olayout (and owrapper (wrapper-instance-slots-layout owrapper)))
 694            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 695            (nwrapper
 696             (cond ((null owrapper)
 697                    (make-wrapper nslots class))
 698                   ((and (equal nlayout olayout)
 699                         (not
 700                          (iterate ((o (list-elements owrapper-class-slots))
 701                                    (n (list-elements nwrapper-class-slots)))
 702                                   (unless (eq (car o) (car n)) (return t)))))
 703                    owrapper)
 704                   (t
 705                    ;; This will initialize the new wrapper to have the same
 706                    ;; state as the old wrapper. We will then have to change
 707                    ;; that. This may seem like wasted work (it is), but the
 708                    ;; spec requires that we call make-instances-obsolete.
 709                    (make-instances-obsolete class)
 710                    (class-wrapper class)))))
 711
 712       (with-slots (wrapper slots) class
 713         (update-lisp-class-layout class nwrapper)
 714         (setf slots eslotds
 715               (wrapper-instance-slots-layout nwrapper) nlayout
 716               (wrapper-class-slots nwrapper) nwrapper-class-slots
 717               (wrapper-no-of-instance-slots nwrapper) nslots
 718               wrapper nwrapper))
 719
 720       (unless (eq owrapper nwrapper)
 721         (update-pv-table-cache-info class)))))
 722
 723 (defun compute-class-slots (eslotds)
 724   (gathering1 (collecting)
 725     (dolist (eslotd eslotds)
 726       (gather1
 727         (assoc (slot-definition-name eslotd)
 728                (class-slot-cells (slot-definition-allocation eslotd)))))))
 729
 730 (defun compute-layout (cpl instance-eslotds)
 731   (let* ((names
 732            (gathering1 (collecting)
 733              (dolist (eslotd instance-eslotds)
 734                (when (eq (slot-definition-allocation eslotd) :instance)
 735                  (gather1 (slot-definition-name eslotd))))))
 736          (order ()))
 737     (labels ((rwalk (tail)
 738                (when tail
 739                  (rwalk (cdr tail))
 740                  (dolist (ss (class-slots (car tail)))
 741                    (let ((n (slot-definition-name ss)))
 742                      (when (member n names)
 743                        (setq order (cons n order)
 744                              names (remove n names))))))))
 745       (rwalk (if (slot-boundp (car cpl) 'slots)
 746                  cpl
 747                  (cdr cpl)))
 748       (reverse (append names order)))))
 749
 750 (defun update-gfs-of-class (class)
 751   (when (and (class-finalized-p class)
 752              (let ((cpl (class-precedence-list class)))
 753                (or (member *the-class-slot-class* cpl)
 754                    (member *the-class-standard-effective-slot-definition*
 755                            cpl))))
 756     (let ((gf-table (make-hash-table :test 'eq)))
 757       (labels ((collect-gfs (class)
 758                  (dolist (gf (specializer-direct-generic-functions class))
 759                    (setf (gethash gf gf-table) t))
 760                  (mapc #'collect-gfs (class-direct-superclasses class))))
 761         (collect-gfs class)
 762         (maphash #'(lambda (gf ignore)
 763                      (declare (ignore ignore))
 764                      (update-gf-dfun class gf))
 765                  gf-table)))))
 766
 767 (defun update-inits (class inits)
 768   (setf (plist-value class 'default-initargs) inits))
 769 \f
 770 (defmethod compute-default-initargs ((class slot-class))
 771   (let ((cpl (class-precedence-list class))
 772         (direct (class-direct-default-initargs class)))
 773     (labels ((walk (tail)
 774                (if (null tail)
 775                    nil
 776                    (let ((c (pop tail)))
 777                      (append (if (eq c class)
 778                                  direct
 779                                  (class-direct-default-initargs c))
 780                              (walk tail))))))
 781       (let ((initargs (walk cpl)))
 782         (delete-duplicates initargs :test #'eq :key #'car :from-end t)))))
 783 \f
 784 ;;;; protocols for constructing direct and effective slot definitions
 785
 786 (defmethod direct-slot-definition-class ((class std-class) initargs)
 787   (declare (ignore initargs))
 788   (find-class 'standard-direct-slot-definition))
 789
 790 (defun make-direct-slotd (class initargs)
 791   (let ((initargs (list* :class class initargs)))
 792     (apply #'make-instance
 793            (direct-slot-definition-class class initargs)
 794            initargs)))
 795
 796 (defmethod compute-slots ((class std-class))
 797   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 798   ;; for each different slot name we find in our superclasses. Each
 799   ;; call receives the class and a list of the dslotds with that name.
 800   ;; The list is in most-specific-first order.
 801   (let ((name-dslotds-alist ()))
 802     (dolist (c (class-precedence-list class))
 803       (let ((dslotds (class-direct-slots c)))
 804         (dolist (d dslotds)
 805           (let* ((name (slot-definition-name d))
 806                  (entry (assq name name-dslotds-alist)))
 807             (if entry
 808                 (push d (cdr entry))
 809                 (push (list name d) name-dslotds-alist))))))
 810     (mapcar #'(lambda (direct)
 811                 (compute-effective-slot-definition class
 812                                                    (nreverse (cdr direct))))
 813             name-dslotds-alist)))
 814
 815 (defmethod compute-slots :around ((class std-class))
 816   (let ((eslotds (call-next-method))
 817         (cpl (class-precedence-list class))
 818         (instance-slots ())
 819         (class-slots    ()))
 820     (dolist (eslotd eslotds)
 821       (let ((alloc (slot-definition-allocation eslotd)))
 822         (cond ((eq alloc :instance) (push eslotd instance-slots))
 823               ((classp alloc)       (push eslotd class-slots)))))
 824     (let ((nlayout (compute-layout cpl instance-slots)))
 825       (dolist (eslotd instance-slots)
 826         (setf (slot-definition-location eslotd)
 827               (position (slot-definition-name eslotd) nlayout))))
 828     (dolist (eslotd class-slots)
 829       (setf (slot-definition-location eslotd)
 830             (assoc (slot-definition-name eslotd)
 831                    (class-slot-cells (slot-definition-allocation eslotd)))))
 832     (mapc #'initialize-internal-slot-functions eslotds)
 833     eslotds))
 834
 835 (defmethod compute-slots ((class structure-class))
 836   (mapcan #'(lambda (superclass)
 837               (mapcar #'(lambda (dslotd)
 838                           (compute-effective-slot-definition class
 839                                                              (list dslotd)))
 840                       (class-direct-slots superclass)))
 841           (reverse (slot-value class 'class-precedence-list))))
 842
 843 (defmethod compute-slots :around ((class structure-class))
 844   (let ((eslotds (call-next-method)))
 845     (mapc #'initialize-internal-slot-functions eslotds)
 846     eslotds))
 847
 848 (defmethod compute-effective-slot-definition ((class slot-class) dslotds)
 849   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
 850          (class (effective-slot-definition-class class initargs)))
 851     (apply #'make-instance class initargs)))
 852
 853 (defmethod effective-slot-definition-class ((class std-class) initargs)
 854   (declare (ignore initargs))
 855   (find-class 'standard-effective-slot-definition))
 856
 857 (defmethod effective-slot-definition-class ((class structure-class) initargs)
 858   (declare (ignore initargs))
 859   (find-class 'structure-effective-slot-definition))
 860
 861 (defmethod compute-effective-slot-definition-initargs
 862     ((class slot-class) direct-slotds)
 863   (let* ((name nil)
 864          (initfunction nil)
 865          (initform nil)
 866          (initargs nil)
 867          (allocation nil)
 868          (type t)
 869          (namep  nil)
 870          (initp  nil)
 871          (allocp nil))
 872
 873     (dolist (slotd direct-slotds)
 874       (when slotd
 875         (unless namep
 876           (setq name (slot-definition-name slotd)
 877                 namep t))
 878         (unless initp
 879           (when (slot-definition-initfunction slotd)
 880             (setq initform (slot-definition-initform slotd)
 881                   initfunction (slot-definition-initfunction slotd)
 882                   initp t)))
 883         (unless allocp
 884           (setq allocation (slot-definition-allocation slotd)
 885                 allocp t))
 886         (setq initargs (append (slot-definition-initargs slotd) initargs))
 887         (let ((slotd-type (slot-definition-type slotd)))
 888           (setq type (cond ((eq type t) slotd-type)
 889                            ((*subtypep type slotd-type) type)
 890                            (t `(and ,type ,slotd-type)))))))
 891     (list :name name
 892           :initform initform
 893           :initfunction initfunction
 894           :initargs initargs
 895           :allocation allocation
 896           :type type
 897           :class class)))
 898
 899 (defmethod compute-effective-slot-definition-initargs :around
 900     ((class structure-class) direct-slotds)
 901   (let ((slotd (car direct-slotds)))
 902     (list* :defstruct-accessor-symbol
 903            (slot-definition-defstruct-accessor-symbol slotd)
 904            :internal-reader-function
 905            (slot-definition-internal-reader-function slotd)
 906            :internal-writer-function
 907            (slot-definition-internal-writer-function slotd)
 908            (call-next-method))))
 909 \f
 910 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
 911 ;;;       to make the method object. They have to use make-a-method which
 912 ;;;       is a specially bootstrapped mechanism for making standard methods.
 913 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
 914   (declare (ignore direct-slot initargs))
 915   (find-class 'standard-reader-method))
 916
 917 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
 918   (add-method generic-function
 919               (make-a-method 'standard-reader-method
 920                              ()
 921                              (list (or (class-name class) 'object))
 922                              (list class)
 923                              (make-reader-method-function class slot-name)
 924                              "automatically generated reader method"
 925                              slot-name)))
 926
 927 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
 928   (declare (ignore direct-slot initargs))
 929   (find-class 'standard-writer-method))
 930
 931 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
 932   (add-method generic-function
 933               (make-a-method 'standard-writer-method
 934                              ()
 935                              (list 'new-value (or (class-name class) 'object))
 936                              (list *the-class-t* class)
 937                              (make-writer-method-function class slot-name)
 938                              "automatically generated writer method"
 939                              slot-name)))
 940
 941 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
 942   (add-method generic-function
 943               (make-a-method 'standard-boundp-method
 944                              ()
 945                              (list (or (class-name class) 'object))
 946                              (list class)
 947                              (make-boundp-method-function class slot-name)
 948                              "automatically generated boundp method"
 949                              slot-name)))
 950
 951 (defmethod remove-reader-method ((class slot-class) generic-function)
 952   (let ((method (get-method generic-function () (list class) nil)))
 953     (when method (remove-method generic-function method))))
 954
 955 (defmethod remove-writer-method ((class slot-class) generic-function)
 956   (let ((method
 957           (get-method generic-function () (list *the-class-t* class) nil)))
 958     (when method (remove-method generic-function method))))
 959
 960 (defmethod remove-boundp-method ((class slot-class) generic-function)
 961   (let ((method (get-method generic-function () (list class) nil)))
 962     (when method (remove-method generic-function method))))
 963 \f
 964 ;;; make-reader-method-function and make-write-method function are NOT part of
 965 ;;; the standard protocol. They are however useful, PCL makes uses makes use
 966 ;;; of them internally and documents them for PCL users.
 967 ;;;
 968 ;;; *** This needs work to make type testing by the writer functions which
 969 ;;; *** do type testing faster. The idea would be to have one constructor
 970 ;;; *** for each possible type test. In order to do this it would be nice
 971 ;;; *** to have help from inform-type-system-about-class and friends.
 972 ;;;
 973 ;;; *** There is a subtle bug here which is going to have to be fixed.
 974 ;;; *** Namely, the simplistic use of the template has to be fixed. We
 975 ;;; *** have to give the optimize-slot-value method the user might have
 976 ;;; *** defined for this metaclass a chance to run.
 977
 978 (defmethod make-reader-method-function ((class slot-class) slot-name)
 979   (make-std-reader-method-function (class-name class) slot-name))
 980
 981 (defmethod make-writer-method-function ((class slot-class) slot-name)
 982   (make-std-writer-method-function (class-name class) slot-name))
 983
 984 (defmethod make-boundp-method-function ((class slot-class) slot-name)
 985   (make-std-boundp-method-function (class-name class) slot-name))
 986 \f
 987 ;;;; inform-type-system-about-class
 988 ;;;
 989 ;;; These are NOT part of the standard protocol. They are internal
 990 ;;; mechanism which PCL uses to *try* and tell the type system about
 991 ;;; class definitions. In a more fully integrated implementation of
 992 ;;; CLOS, the type system would know about class objects and class
 993 ;;; names in a more fundamental way and the mechanism used to inform
 994 ;;; the type system about new classes would be different.
 995 (defmethod inform-type-system-about-class ((class std-class) name)
 996   (inform-type-system-about-std-class name))
 997
 998 (defmethod inform-type-system-about-class ((class structure-class) (name t))
 999   nil)
1000 \f
1001 (defmethod compatible-meta-class-change-p (class proto-new-class)
1002   (eq (class-of class) (class-of proto-new-class)))
1003
1004 (defmethod validate-superclass ((class class) (new-super class))
1005   (or (eq new-super *the-class-t*)
1006       (eq (class-of class) (class-of new-super))))
1007
1008 (defmethod validate-superclass ((class standard-class) (new-super std-class))
1009   (let ((new-super-meta-class (class-of new-super)))
1010     (or (eq new-super-meta-class *the-class-std-class*)
1011         (eq (class-of class) new-super-meta-class))))
1012 \f
1013 (defun force-cache-flushes (class)
1014   (let* ((owrapper (class-wrapper class))
1015          (state (wrapper-state owrapper)))
1016     ;; We only need to do something if the state is still T. If the
1017     ;; state isn't T, it will be FLUSH or OBSOLETE, and both of those
1018     ;; will already be doing what we want. In particular, we must be
1019     ;; sure we never change an OBSOLETE into a FLUSH since OBSOLETE
1020     ;; means do what FLUSH does and then some.
1021     (when (eq state t) ; FIXME: should be done through INVALID-WRAPPER-P
1022       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1023                                     class)))
1024         (setf (wrapper-instance-slots-layout nwrapper)
1025               (wrapper-instance-slots-layout owrapper))
1026         (setf (wrapper-class-slots nwrapper)
1027               (wrapper-class-slots owrapper))
1028         (sb-sys:without-interrupts
1029           (update-lisp-class-layout class nwrapper)
1030           (setf (slot-value class 'wrapper) nwrapper)
1031           (invalidate-wrapper owrapper ':flush nwrapper))))))
1032
1033 (defun flush-cache-trap (owrapper nwrapper instance)
1034   (declare (ignore owrapper))
1035   (set-wrapper instance nwrapper))
1036 \f
1037 ;;; make-instances-obsolete can be called by user code. It will cause the
1038 ;;; next access to the instance (as defined in 88-002R) to trap through the
1039 ;;; update-instance-for-redefined-class mechanism.
1040 (defmethod make-instances-obsolete ((class std-class))
1041   (let* ((owrapper (class-wrapper class))
1042          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1043                                  class)))
1044       (setf (wrapper-instance-slots-layout nwrapper)
1045             (wrapper-instance-slots-layout owrapper))
1046       (setf (wrapper-class-slots nwrapper)
1047             (wrapper-class-slots owrapper))
1048       (sb-sys:without-interrupts
1049         (update-lisp-class-layout class nwrapper)
1050         (setf (slot-value class 'wrapper) nwrapper)
1051         (invalidate-wrapper owrapper ':obsolete nwrapper)
1052         class)))
1053
1054 (defmethod make-instances-obsolete ((class symbol))
1055   (make-instances-obsolete (find-class class)))
1056
1057 ;;; obsolete-instance-trap is the internal trap that is called when we see
1058 ;;; an obsolete instance. The times when it is called are:
1059 ;;;   - when the instance is involved in method lookup
1060 ;;;   - when attempting to access a slot of an instance
1061 ;;;
1062 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1063 ;;; instance access macros.
1064 ;;;
1065 ;;; Of course these times when it is called are an internal
1066 ;;; implementation detail of PCL and are not part of the documented
1067 ;;; description of when the obsolete instance update happens. The
1068 ;;; documented description is as it appears in 88-002R.
1069 ;;;
1070 ;;; This has to return the new wrapper, so it counts on all the
1071 ;;; methods on obsolete-instance-trap-internal to return the new
1072 ;;; wrapper. It also does a little internal error checking to make
1073 ;;; sure that the traps are only happening when they should, and that
1074 ;;; the trap methods are computing appropriate new wrappers.
1075
1076 ;;; obsolete-instance-trap might be called on structure instances
1077 ;;; after a structure is redefined. In most cases, obsolete-instance-trap
1078 ;;; will not be able to fix the old instance, so it must signal an
1079 ;;; error. The hard part of this is that the error system and debugger
1080 ;;; might cause obsolete-instance-trap to be called again, so in that
1081 ;;; case, we have to return some reasonable wrapper, instead.
1082
1083 (defvar *in-obsolete-instance-trap* nil)
1084 (defvar *the-wrapper-of-structure-object*
1085   (class-wrapper (find-class 'structure-object)))
1086
1087 (define-condition obsolete-structure (error)
1088   ((datum :reader obsolete-structure-datum :initarg :datum))
1089   (:report
1090    (lambda (condition stream)
1091      ;; Don't try to print the structure, since it probably won't work.
1092      (format stream
1093              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1094              (type-of (obsolete-structure-datum condition))))))
1095
1096 (defun obsolete-instance-trap (owrapper nwrapper instance)
1097   (if (not (pcl-instance-p instance))
1098       (if *in-obsolete-instance-trap*
1099           *the-wrapper-of-structure-object*
1100            (let ((*in-obsolete-instance-trap* t))
1101              (error 'obsolete-structure :datum instance)))
1102       (let* ((class (wrapper-class* nwrapper))
1103              (copy (allocate-instance class)) ;??? allocate-instance ???
1104              (olayout (wrapper-instance-slots-layout owrapper))
1105              (nlayout (wrapper-instance-slots-layout nwrapper))
1106              (oslots (get-slots instance))
1107              (nslots (get-slots copy))
1108              (oclass-slots (wrapper-class-slots owrapper))
1109              (added ())
1110              (discarded ())
1111              (plist ()))
1112         ;; local  --> local     transfer
1113         ;; local  --> shared       discard
1114         ;; local  -->  --         discard
1115         ;; shared --> local     transfer
1116         ;; shared --> shared       discard
1117         ;; shared -->  --         discard
1118         ;;  --    --> local     add
1119         ;;  --    --> shared    --
1120
1121         ;; Go through all the old local slots.
1122         (iterate ((name (list-elements olayout))
1123                   (opos (interval :from 0)))
1124           (let ((npos (posq name nlayout)))
1125             (if npos
1126                 (setf (clos-slots-ref nslots npos)
1127                       (clos-slots-ref oslots opos))
1128                 (progn
1129                   (push name discarded)
1130                   (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1131                     (setf (getf plist name) (clos-slots-ref oslots opos)))))))
1132
1133         ;; Go through all the old shared slots.
1134         (iterate ((oclass-slot-and-val (list-elements oclass-slots)))
1135           (let ((name (car oclass-slot-and-val))
1136                 (val (cdr oclass-slot-and-val)))
1137             (let ((npos (posq name nlayout)))
1138               (if npos
1139                   (setf (clos-slots-ref nslots npos) (cdr oclass-slot-and-val))
1140                   (progn (push name discarded)
1141                          (unless (eq val +slot-unbound+)
1142                            (setf (getf plist name) val)))))))
1143
1144         ;; Go through all the new local slots to compute the added slots.
1145         (dolist (nlocal nlayout)
1146           (unless (or (memq nlocal olayout)
1147                       (assq nlocal oclass-slots))
1148             (push nlocal added)))
1149
1150         (swap-wrappers-and-slots instance copy)
1151
1152         (update-instance-for-redefined-class instance
1153                                              added
1154                                              discarded
1155                                              plist)
1156         nwrapper)))
1157 \f
1158 (defmacro copy-instance-internal (instance)
1159   `(progn
1160      (let* ((class (class-of instance))
1161             (copy (allocate-instance class)))
1162        (if (std-instance-p ,instance)
1163            (setf (std-instance-slots ,instance)
1164                  (std-instance-slots ,instance))
1165          (setf (fsc-instance-slots ,instance)
1166                (fsc-instance-slots ,instance)))
1167        copy)))
1168
1169 (defun change-class-internal (instance new-class)
1170   (let* ((old-class (class-of instance))
1171          (copy (allocate-instance new-class))
1172          (new-wrapper (get-wrapper copy))
1173          (old-wrapper (class-wrapper old-class))
1174          (old-layout (wrapper-instance-slots-layout old-wrapper))
1175          (new-layout (wrapper-instance-slots-layout new-wrapper))
1176          (old-slots (get-slots instance))
1177          (new-slots (get-slots copy))
1178          (old-class-slots (wrapper-class-slots old-wrapper)))
1179
1180     ;; "The values of local slots specified by both the class CTO and
1181     ;; CFROM are retained. If such a local slot was unbound, it remains
1182     ;; unbound."
1183     (iterate ((new-slot (list-elements new-layout))
1184               (new-position (interval :from 0)))
1185       (let ((old-position (posq new-slot old-layout)))
1186         (when old-position
1187           (setf (clos-slots-ref new-slots new-position)
1188                 (clos-slots-ref old-slots old-position)))))
1189
1190     ;; "The values of slots specified as shared in the class CFROM and
1191     ;; as local in the class CTO are retained."
1192     (iterate ((slot-and-val (list-elements old-class-slots)))
1193       (let ((position (posq (car slot-and-val) new-layout)))
1194         (when position
1195           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1196
1197     ;; Make the copy point to the old instance's storage, and make the
1198     ;; old instance point to the new storage.
1199     (swap-wrappers-and-slots instance copy)
1200
1201     (update-instance-for-different-class copy instance)
1202     instance))
1203
1204 (defmethod change-class ((instance standard-object)
1205                          (new-class standard-class))
1206   (change-class-internal instance new-class))
1207
1208 (defmethod change-class ((instance funcallable-standard-object)
1209                          (new-class funcallable-standard-class))
1210   (change-class-internal instance new-class))
1211
1212 (defmethod change-class ((instance standard-object)
1213                          (new-class funcallable-standard-class))
1214   (error "You can't change the class of ~S to ~S~@
1215           because it isn't already an instance with metaclass ~S."
1216          instance new-class 'standard-class))
1217
1218 (defmethod change-class ((instance funcallable-standard-object)
1219                          (new-class standard-class))
1220   (error "You can't change the class of ~S to ~S~@
1221           because it isn't already an instance with metaclass ~S."
1222          instance new-class 'funcallable-standard-class))
1223
1224 (defmethod change-class ((instance t) (new-class-name symbol))
1225   (change-class instance (find-class new-class-name)))
1226 \f
1227 ;;;; The metaclass BUILT-IN-CLASS
1228 ;;;;
1229 ;;;; This metaclass is something of a weird creature. By this point, all
1230 ;;;; instances of it which will exist have been created, and no instance
1231 ;;;; is ever created by calling MAKE-INSTANCE.
1232 ;;;;
1233 ;;;; But, there are other parts of the protocol we must follow and those
1234 ;;;; definitions appear here.
1235
1236 (defmethod shared-initialize :before
1237            ((class built-in-class) slot-names &rest initargs)
1238   (declare (ignore slot-names initargs))
1239   (error "attempt to initialize or reinitialize a built in class"))
1240
1241 (defmethod class-direct-slots       ((class built-in-class)) ())
1242 (defmethod class-slots             ((class built-in-class)) ())
1243 (defmethod class-direct-default-initargs ((class built-in-class)) ())
1244 (defmethod class-default-initargs       ((class built-in-class)) ())
1245
1246 (defmethod validate-superclass ((c class) (s built-in-class))
1247   (or (eq s *the-class-t*)
1248       (eq s *the-class-stream*)))
1249 \f
1250 (defmethod validate-superclass ((c slot-class)
1251                                 (f forward-referenced-class))
1252   t)
1253 \f
1254 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1255   (pushnew dependent (plist-value metaobject 'dependents)))
1256
1257 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1258   (setf (plist-value metaobject 'dependents)
1259         (delete dependent (plist-value metaobject 'dependents))))
1260
1261 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1262   (dolist (dependent (plist-value metaobject 'dependents))
1263     (funcall function dependent)))
1264