src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd 'class)))
  76     (let ((table (or (gethash name *name->class->slotd-table*)
  77                      (setf (gethash name *name->class->slotd-table*)
  78                            (make-hash-table :test 'eq :size 5)))))
  79       (setf (gethash class table) slotd))
  80     (dolist (type '(reader writer boundp))
  81       (let* ((gf-name (ecase type
  82                               (reader 'slot-value-using-class)
  83                               (writer '(setf slot-value-using-class))
  84                               (boundp 'slot-boundp-using-class)))
  85              (gf (gdefinition gf-name)))
  86         (compute-slot-accessor-info slotd type gf)))
  87     (initialize-internal-slot-gfs name)))
  88
  89 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  90                                        type gf)
  91   (let* ((name (slot-value slotd 'name))
  92          (class (slot-value slotd 'class))
  93          (old-slotd (find-slot-definition class name))
  94          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
  95     (multiple-value-bind (function std-p)
  96         (if (eq *boot-state* 'complete)
  97             (get-accessor-method-function gf type class slotd)
  98             (get-optimized-std-accessor-method-function class slotd type))
  99       (setf (slot-accessor-std-p slotd type) std-p)
 100       (setf (slot-accessor-function slotd type) function))
 101     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 102       (push (cons class name) *pv-table-cache-update-info*))))
 103
 104 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 105   :instance)
 106 \f
 107 (defmethod shared-initialize :after ((object documentation-mixin)
 108                                      slot-names
 109                                      &key (documentation nil documentation-p))
 110   (declare (ignore slot-names))
 111   (when documentation-p
 112     (setf (plist-value object 'documentation) documentation)))
 113
 114 ;;; default if DOC-TYPE doesn't match one of the specified types
 115 (defmethod documentation (object doc-type)
 116   (warn "unsupported DOCUMENTATION: type ~S for object ~S"
 117         doc-type
 118         (type-of object))
 119   nil)
 120
 121 ;;; default if DOC-TYPE doesn't match one of the specified types
 122 (defmethod (setf documentation) (new-value object doc-type)
 123   ;; CMU CL made this an error, but since ANSI says that even for supported
 124   ;; doc types an implementation is permitted to discard docs at any time
 125   ;; for any reason, this feels to me more like a warning. -- WHN 19991214
 126   (warn "discarding unsupported DOCUMENTATION of type ~S for object ~S"
 127         doc-type
 128         (type-of object))
 129   new-value)
 130
 131 (defmethod documentation ((object documentation-mixin) doc-type)
 132   (declare (ignore doc-type))
 133   (plist-value object 'documentation))
 134
 135 (defmethod (setf documentation) (new-value
 136                                  (object documentation-mixin)
 137                                  doc-type)
 138   (declare (ignore doc-type))
 139   (setf (plist-value object 'documentation) new-value))
 140
 141 (defmethod documentation ((slotd standard-slot-definition) doc-type)
 142   (declare (ignore doc-type))
 143   (slot-value slotd 'documentation))
 144
 145 (defmethod (setf documentation) (new-value
 146                                  (slotd standard-slot-definition)
 147                                  doc-type)
 148   (declare (ignore doc-type))
 149   (setf (slot-value slotd 'documentation) new-value))
 150 \f
 151 ;;;; various class accessors that are a little more complicated than can be
 152 ;;;; done with automatically generated reader methods
 153
 154 (defmethod class-finalized-p ((class pcl-class))
 155   (with-slots (wrapper) class
 156     (not (null wrapper))))
 157
 158 (defmethod class-prototype ((class std-class))
 159   (with-slots (prototype) class
 160     (or prototype (setq prototype (allocate-instance class)))))
 161
 162 (defmethod class-prototype ((class structure-class))
 163   (with-slots (prototype wrapper defstruct-constructor) class
 164     (or prototype
 165         (setq prototype
 166               (if defstruct-constructor
 167                   (allocate-instance class)
 168                   (allocate-standard-instance wrapper))))))
 169
 170 (defmethod class-direct-default-initargs ((class slot-class))
 171   (plist-value class 'direct-default-initargs))
 172
 173 (defmethod class-default-initargs ((class slot-class))
 174   (plist-value class 'default-initargs))
 175
 176 (defmethod class-slot-cells ((class std-class))
 177   (plist-value class 'class-slot-cells))
 178 \f
 179 ;;;; class accessors that are even a little bit more complicated than those
 180 ;;;; above. These have a protocol for updating them, we must implement that
 181 ;;;; protocol.
 182
 183 ;;; Maintaining the direct subclasses backpointers. The update methods are
 184 ;;; here, the values are read by an automatically generated reader method.
 185 (defmethod add-direct-subclass ((class class) (subclass class))
 186   (with-slots (direct-subclasses) class
 187     (pushnew subclass direct-subclasses)
 188     subclass))
 189 (defmethod remove-direct-subclass ((class class) (subclass class))
 190   (with-slots (direct-subclasses) class
 191     (setq direct-subclasses (remove subclass direct-subclasses))
 192     subclass))
 193
 194 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 195 ;;;
 196 ;;; There are four generic functions involved, each has one method for the
 197 ;;; class case and another method for the damned EQL specializers. All of
 198 ;;; these are specified methods and appear in their specified place in the
 199 ;;; class graph.
 200 ;;;
 201 ;;;   ADD-DIRECT-METHOD
 202 ;;;   REMOVE-DIRECT-METHOD
 203 ;;;   SPECIALIZER-DIRECT-METHODS
 204 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 205 ;;;
 206 ;;; In each case, we maintain one value which is a cons. The car is the list
 207 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 208 ;;; computed lazily.
 209 (defmethod add-direct-method ((specializer class) (method method))
 210   (with-slots (direct-methods) specializer
 211     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 212           (cdr direct-methods) ()))
 213   method)
 214 (defmethod remove-direct-method ((specializer class) (method method))
 215   (with-slots (direct-methods) specializer
 216     (setf (car direct-methods) (remove method (car direct-methods))
 217           (cdr direct-methods) ()))
 218   method)
 219
 220 (defmethod specializer-direct-methods ((specializer class))
 221   (with-slots (direct-methods) specializer
 222     (car direct-methods)))
 223
 224 (defmethod specializer-direct-generic-functions ((specializer class))
 225   (with-slots (direct-methods) specializer
 226     (or (cdr direct-methods)
 227         (setf (cdr direct-methods)
 228               (let (collect)
 229                 (dolist (m (car direct-methods))
 230                   ;; the old PCL code used COLLECTING-ONCE which used
 231                   ;; #'EQ to check for newness
 232                   (pushnew (method-generic-function m) collect :test #'eq))
 233                 (nreverse collect))))))
 234 \f
 235 ;;; This hash table is used to store the direct methods and direct generic
 236 ;;; functions of EQL specializers. Each value in the table is the cons.
 237 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 238 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 239
 240 (defmethod specializer-method-table ((specializer eql-specializer))
 241   *eql-specializer-methods*)
 242
 243 (defmethod specializer-method-table ((specializer class-eq-specializer))
 244   *class-eq-specializer-methods*)
 245
 246 (defmethod add-direct-method ((specializer specializer-with-object)
 247                               (method method))
 248   (let* ((object (specializer-object specializer))
 249          (table (specializer-method-table specializer))
 250          (entry (gethash object table)))
 251     (unless entry
 252       (setq entry
 253             (setf (gethash object table)
 254                   (cons nil nil))))
 255     (setf (car entry) (adjoin method (car entry))
 256           (cdr entry) ())
 257     method))
 258
 259 (defmethod remove-direct-method ((specializer specializer-with-object)
 260                                  (method method))
 261   (let* ((object (specializer-object specializer))
 262          (entry (gethash object (specializer-method-table specializer))))
 263     (when entry
 264       (setf (car entry) (remove method (car entry))
 265             (cdr entry) ()))
 266     method))
 267
 268 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 269   (car (gethash (specializer-object specializer)
 270                 (specializer-method-table specializer))))
 271
 272 (defmethod specializer-direct-generic-functions ((specializer
 273                                                   specializer-with-object))
 274   (let* ((object (specializer-object specializer))
 275          (entry (gethash object (specializer-method-table specializer))))
 276     (when entry
 277       (or (cdr entry)
 278           (setf (cdr entry)
 279                 (let (collect)
 280                   (dolist (m (car entry))
 281                     (pushnew (method-generic-function m) collect :test #'eq))
 282                   (nreverse collect)))))))
 283
 284 (defun map-specializers (function)
 285   (map-all-classes (lambda (class)
 286                      (funcall function (class-eq-specializer class))
 287                      (funcall function class)))
 288   (maphash (lambda (object methods)
 289              (declare (ignore methods))
 290              (intern-eql-specializer object))
 291            *eql-specializer-methods*)
 292   (maphash (lambda (object specl)
 293              (declare (ignore object))
 294              (funcall function specl))
 295            *eql-specializer-table*)
 296   nil)
 297
 298 (defun map-all-generic-functions (function)
 299   (let ((all-generic-functions (make-hash-table :test 'eq)))
 300     (map-specializers (lambda (specl)
 301                         (dolist (gf (specializer-direct-generic-functions
 302                                      specl))
 303                           (unless (gethash gf all-generic-functions)
 304                             (setf (gethash gf all-generic-functions) t)
 305                             (funcall function gf))))))
 306   nil)
 307
 308 (defmethod shared-initialize :after ((specl class-eq-specializer)
 309                                      slot-names
 310                                      &key)
 311   (declare (ignore slot-names))
 312   (setf (slot-value specl 'type) `(class-eq ,(specializer-class specl))))
 313
 314 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 315   (declare (ignore slot-names))
 316   (setf (slot-value specl 'type) `(eql ,(specializer-object specl))))
 317 \f
 318 (defun real-load-defclass (name metaclass-name supers slots other)
 319   (let ((res (apply #'ensure-class name :metaclass metaclass-name
 320                     :direct-superclasses supers
 321                     :direct-slots slots
 322                     :definition-source `((defclass ,name)
 323                                          ,*load-pathname*)
 324                     other)))
 325     ;; Defclass of a class with a forward-referenced superclass does not
 326     ;; have a wrapper. RES is the incomplete PCL class. The Lisp class
 327     ;; does not yet exist. Maybe should return NIL in that case as RES
 328     ;; is not useful to the user?
 329     (and (class-wrapper res) (sb-kernel:layout-class (class-wrapper res)))))
 330
 331 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 332
 333 (defun ensure-class (name &rest all)
 334   (apply #'ensure-class-using-class name (find-class name nil) all))
 335
 336 (defmethod ensure-class-using-class (name (class null) &rest args &key)
 337   (multiple-value-bind (meta initargs)
 338       (ensure-class-values class args)
 339     (setf class (apply #'make-instance meta :name name initargs)
 340           (find-class name) class)
 341     class))
 342
 343 (defmethod ensure-class-using-class (name (class pcl-class) &rest args &key)
 344   (multiple-value-bind (meta initargs)
 345       (ensure-class-values class args)
 346     (unless (eq (class-of class) meta) (change-class class meta))
 347     (apply #'reinitialize-instance class initargs)
 348     (setf (find-class name) class)
 349     class))
 350
 351 (defmethod class-predicate-name ((class t))
 352   'constantly-nil)
 353
 354 (defun fix-super (s)
 355   (cond ((classp s) s)
 356         ((not (legal-class-name-p s))
 357           (error "~S is not a class or a legal class name." s))
 358         (t
 359           (or (find-class s nil)
 360               (setf (find-class s)
 361                       (make-instance 'forward-referenced-class
 362                                      :name s))))))
 363
 364 (defun ensure-class-values (class args)
 365   (let* ((initargs (copy-list args))
 366          (unsupplied (list 1))
 367          (supplied-meta   (getf initargs :metaclass unsupplied))
 368          (supplied-supers (getf initargs :direct-superclasses unsupplied))
 369          (supplied-slots  (getf initargs :direct-slots unsupplied))
 370          (meta
 371            (cond ((neq supplied-meta unsupplied)
 372                   (find-class supplied-meta))
 373                  ((or (null class)
 374                       (forward-referenced-class-p class))
 375                   *the-class-standard-class*)
 376                  (t
 377                   (class-of class)))))
 378     ;; KLUDGE: It seemed to me initially that there ought to be a way
 379     ;; of collecting all the erroneous problems in one go, rather than
 380     ;; this way of solving the problem of signalling the errors that
 381     ;; we are required to, which stops at the first bogus input.
 382     ;; However, after playing around a little, I couldn't find that
 383     ;; way, so I've left it as is, but if someone does come up with a
 384     ;; better way... -- CSR, 2002-09-08
 385     (do ((direct-slots (getf initargs :direct-slots) (cdr direct-slots)))
 386         ((endp direct-slots) nil)
 387       (destructuring-bind (slot &rest more) direct-slots
 388         (let ((slot-name (getf slot :name)))
 389           (when (some (lambda (s) (eq slot-name (getf s :name))) more)
 390             ;; FIXME: It's quite possible that we ought to define an
 391             ;; SB-INT:PROGRAM-ERROR function to signal these and other
 392             ;; errors throughout the codebase that are required to be
 393             ;; of type PROGRAM-ERROR.
 394             (error 'simple-program-error
 395                    :format-control "~@<There is more than one direct slot ~
 396                                    with name ~S.~:>"
 397                    :format-arguments (list slot-name)))
 398           (do ((stuff slot (cddr stuff)))
 399               ((endp stuff) nil)
 400             (destructuring-bind (option value &rest more) stuff
 401               (cond
 402                 ((and (member option '(:allocation :type
 403                                        :initform :documentation))
 404                       (not (eq unsupplied
 405                                (getf more option unsupplied))))
 406                  (error 'simple-program-error
 407                         :format-control "~@<Duplicate slot option ~S for ~
 408                                         slot named ~S.~:>"
 409                         :format-arguments (list option slot-name)))
 410                 ((and (eq option :readers)
 411                       (notevery #'symbolp value))
 412                  (error 'simple-program-error
 413                         :format-control "~@<Slot reader names for slot ~
 414                                         named ~S must be symbols.~:>"
 415                         :format-arguments (list slot-name)))
 416                 ((and (eq option :initargs)
 417                       (notevery #'symbolp value))
 418                  (error 'simple-program-error
 419                         :format-control "~@<Slot initarg names for slot ~
 420                                         named ~S must be symbols.~:>"
 421                         :format-arguments (list slot-name)))))))))
 422     (loop for (initarg . more) on (getf initargs :direct-default-initargs)
 423           for name = (car initarg)
 424           when (some (lambda (a) (eq (car a) name)) more)
 425           do (error 'simple-program-error
 426                     :format-control "~@<Duplicate initialization argument ~
 427                                     name ~S in :DEFAULT-INITARGS.~:>"
 428                     :format-arguments (list name class)))
 429     (let ((metaclass 0)
 430           (default-initargs 0))
 431       (do ((args initargs (cddr args)))
 432           ((endp args) nil)
 433         (case (car args)
 434           (:metaclass
 435            (when (> (incf metaclass) 1)
 436              (error 'simple-program-error
 437                     :format-control "~@<More than one :METACLASS ~
 438                                     option specified.~:>")))
 439           (:direct-default-initargs
 440            (when (> (incf default-initargs) 1)
 441              (error 'simple-program-error
 442                     :format-control "~@<More than one :DEFAULT-INITARGS ~
 443                                     option specified.~:>"))))))
 444     (remf initargs :metaclass)
 445     (loop (unless (remf initargs :direct-superclasses) (return)))
 446     (loop (unless (remf initargs :direct-slots) (return)))
 447     (values meta
 448             (list* :direct-superclasses
 449                    (and (neq supplied-supers unsupplied)
 450                         (mapcar #'fix-super supplied-supers))
 451                    :direct-slots
 452                    (and (neq supplied-slots unsupplied) supplied-slots)
 453                    initargs))))
 454 \f
 455
 456 (defmethod shared-initialize :after
 457            ((class std-class)
 458             slot-names
 459             &key (direct-superclasses nil direct-superclasses-p)
 460                  (direct-slots nil direct-slots-p)
 461                  (direct-default-initargs nil direct-default-initargs-p)
 462                  (predicate-name nil predicate-name-p))
 463   (declare (ignore slot-names))
 464   (cond (direct-superclasses-p
 465          (setq direct-superclasses
 466                (or direct-superclasses
 467                    (list (if (funcallable-standard-class-p class)
 468                              *the-class-funcallable-standard-object*
 469                              *the-class-standard-object*))))
 470          (dolist (superclass direct-superclasses)
 471            (unless (validate-superclass class superclass)
 472              (error "The class ~S was specified as a~%
 473                      super-class of the class ~S;~%~
 474                      but the meta-classes ~S and~%~S are incompatible.~@
 475                      Define a method for ~S to avoid this error."
 476                      superclass class (class-of superclass) (class-of class)
 477                      'validate-superclass)))
 478          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 479         (t
 480          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 481   (setq direct-slots
 482         (if direct-slots-p
 483             (setf (slot-value class 'direct-slots)
 484                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 485                           direct-slots))
 486             (slot-value class 'direct-slots)))
 487   (if direct-default-initargs-p
 488       (setf (plist-value class 'direct-default-initargs)
 489             direct-default-initargs)
 490       (setq direct-default-initargs
 491             (plist-value class 'direct-default-initargs)))
 492   (setf (plist-value class 'class-slot-cells)
 493         (let (collect)
 494           (dolist (dslotd direct-slots)
 495             (when (eq :class (slot-definition-allocation dslotd))
 496               (let ((initfunction (slot-definition-initfunction dslotd)))
 497                 (push (cons (slot-definition-name dslotd)
 498                                (if initfunction
 499                                    (funcall initfunction)
 500                                    +slot-unbound+))
 501                       collect))))
 502           (nreverse collect)))
 503   (setq predicate-name (if predicate-name-p
 504                            (setf (slot-value class 'predicate-name)
 505                                  (car predicate-name))
 506                            (or (slot-value class 'predicate-name)
 507                                (setf (slot-value class 'predicate-name)
 508                                      (make-class-predicate-name (class-name
 509                                                                  class))))))
 510   (add-direct-subclasses class direct-superclasses)
 511   (update-class class nil)
 512   (make-class-predicate class predicate-name)
 513   (add-slot-accessors class direct-slots))
 514
 515 (defmethod shared-initialize :before ((class class) slot-names &key name)
 516   (declare (ignore slot-names name))
 517   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 518   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 519   (setf (slot-value class 'type) `(class ,class))
 520   (setf (slot-value class 'class-eq-specializer)
 521         (make-instance 'class-eq-specializer :class class)))
 522
 523 (defmethod reinitialize-instance :before ((class slot-class) &key)
 524   (remove-direct-subclasses class (class-direct-superclasses class))
 525   (remove-slot-accessors    class (class-direct-slots class)))
 526
 527 (defmethod reinitialize-instance :after ((class slot-class)
 528                                          &rest initargs
 529                                          &key)
 530   (map-dependents class
 531                   (lambda (dependent)
 532                     (apply #'update-dependent class dependent initargs))))
 533
 534 (defmethod shared-initialize :after
 535     ((slotd structure-slot-definition) slot-names &key
 536      (allocation :instance) allocation-class)
 537   (declare (ignore slot-names allocation-class))
 538   (unless (eq allocation :instance)
 539     (error "Structure slots must have :INSTANCE allocation.")))
 540
 541 (defun make-structure-class-defstruct-form (name direct-slots include)
 542   (let* ((conc-name (intern (format nil "~S structure class " name)))
 543          (constructor (intern (format nil "~Aconstructor" conc-name)))
 544          (defstruct `(defstruct (,name
 545                                  ,@(when include
 546                                          `((:include ,(class-name include))))
 547                                  (:predicate nil)
 548                                  (:conc-name ,conc-name)
 549                                  (:constructor ,constructor ())
 550                                  (:copier nil))
 551                       ,@(mapcar (lambda (slot)
 552                                   `(,(slot-definition-name slot)
 553                                     +slot-unbound+))
 554                                 direct-slots)))
 555          (reader-names (mapcar (lambda (slotd)
 556                                  (list 'slot-accessor name
 557                                        (slot-definition-name slotd)
 558                                        'reader))
 559                                direct-slots))
 560          (writer-names (mapcar (lambda (slotd)
 561                                  (list 'slot-accessor name
 562                                        (slot-definition-name slotd)
 563                                        'writer))
 564                                direct-slots))
 565          (readers-init
 566            (mapcar (lambda (slotd reader-name)
 567                      (let ((accessor
 568                              (slot-definition-defstruct-accessor-symbol
 569                               slotd)))
 570                        `(defun ,reader-name (obj)
 571                          (declare (type ,name obj))
 572                          (,accessor obj))))
 573                    direct-slots reader-names))
 574          (writers-init
 575            (mapcar (lambda (slotd writer-name)
 576                      (let ((accessor
 577                              (slot-definition-defstruct-accessor-symbol
 578                               slotd)))
 579                        `(defun ,writer-name (nv obj)
 580                          (declare (type ,name obj))
 581                          (setf (,accessor obj) nv))))
 582                    direct-slots writer-names))
 583          (defstruct-form
 584              `(progn
 585                ,defstruct
 586                ,@readers-init ,@writers-init
 587                (cons nil nil))))
 588     (values defstruct-form constructor reader-names writer-names)))
 589
 590 (defmethod shared-initialize :after
 591       ((class structure-class)
 592        slot-names
 593        &key (direct-superclasses nil direct-superclasses-p)
 594             (direct-slots nil direct-slots-p)
 595             direct-default-initargs
 596             (predicate-name nil predicate-name-p))
 597   (declare (ignore slot-names direct-default-initargs))
 598   (if direct-superclasses-p
 599       (setf (slot-value class 'direct-superclasses)
 600             (or direct-superclasses
 601                 (setq direct-superclasses
 602                       (and (not (eq (class-name class) 'structure-object))
 603                            (list *the-class-structure-object*)))))
 604       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 605   (let* ((name (class-name class))
 606          (from-defclass-p (slot-value class 'from-defclass-p))
 607          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 608     (if direct-slots-p
 609         (setf (slot-value class 'direct-slots)
 610               (setq direct-slots
 611                     (mapcar (lambda (pl)
 612                               (when defstruct-p
 613                                 (let* ((slot-name (getf pl :name))
 614                                        (acc-name
 615                                         (format nil
 616                                                 "~S structure class ~A"
 617                                                 name slot-name))
 618                                        (accessor (intern acc-name)))
 619                                   (setq pl (list* :defstruct-accessor-symbol
 620                                                   accessor pl))))
 621                               (make-direct-slotd class pl))
 622                             direct-slots)))
 623         (setq direct-slots (slot-value class 'direct-slots)))
 624     (when defstruct-p
 625       (let ((include (car (slot-value class 'direct-superclasses))))
 626         (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 627             (make-structure-class-defstruct-form name direct-slots include)
 628           (unless (structure-type-p name) (eval defstruct-form))
 629           (mapc (lambda (dslotd reader-name writer-name)
 630                   (let* ((reader (gdefinition reader-name))
 631                          (writer (when (gboundp writer-name)
 632                                    (gdefinition writer-name))))
 633                     (setf (slot-value dslotd 'internal-reader-function)
 634                           reader)
 635                     (setf (slot-value dslotd 'internal-writer-function)
 636                           writer)))
 637                 direct-slots reader-names writer-names)
 638           (setf (slot-value class 'defstruct-form) defstruct-form)
 639           (setf (slot-value class 'defstruct-constructor) constructor))))
 640     (add-direct-subclasses class direct-superclasses)
 641     (setf (slot-value class 'class-precedence-list)
 642             (compute-class-precedence-list class))
 643     (setf (slot-value class 'slots) (compute-slots class))
 644     (let ((lclass (cl:find-class (class-name class))))
 645       (setf (sb-kernel:class-pcl-class lclass) class)
 646       (setf (slot-value class 'wrapper) (sb-kernel:class-layout lclass)))
 647     (update-pv-table-cache-info class)
 648     (setq predicate-name (if predicate-name-p
 649                            (setf (slot-value class 'predicate-name)
 650                                    (car predicate-name))
 651                            (or (slot-value class 'predicate-name)
 652                                (setf (slot-value class 'predicate-name)
 653                                        (make-class-predicate-name
 654                                         (class-name class))))))
 655     (make-class-predicate class predicate-name)
 656     (add-slot-accessors class direct-slots)))
 657
 658 (defmethod direct-slot-definition-class ((class structure-class) initargs)
 659   (declare (ignore initargs))
 660   (find-class 'structure-direct-slot-definition))
 661
 662 (defmethod finalize-inheritance ((class structure-class))
 663   nil) ; always finalized
 664 \f
 665 (defun add-slot-accessors (class dslotds)
 666   (fix-slot-accessors class dslotds 'add))
 667
 668 (defun remove-slot-accessors (class dslotds)
 669   (fix-slot-accessors class dslotds 'remove))
 670
 671 (defun fix-slot-accessors (class dslotds add/remove)
 672   (flet ((fix (gfspec name r/w)
 673            (let ((gf (ensure-generic-function gfspec)))
 674              (case r/w
 675                (r (if (eq add/remove 'add)
 676                       (add-reader-method class gf name)
 677                       (remove-reader-method class gf)))
 678                (w (if (eq add/remove 'add)
 679                       (add-writer-method class gf name)
 680                       (remove-writer-method class gf)))))))
 681     (dolist (dslotd dslotds)
 682       (let ((slot-name (slot-definition-name dslotd)))
 683         (dolist (r (slot-definition-readers dslotd)) (fix r slot-name 'r))
 684         (dolist (w (slot-definition-writers dslotd)) (fix w slot-name 'w))))))
 685 \f
 686 (defun add-direct-subclasses (class supers)
 687   (dolist (super supers)
 688     (unless (memq class (class-direct-subclasses class))
 689       (add-direct-subclass super class))))
 690
 691 (defun remove-direct-subclasses (class supers)
 692   (let ((old (class-direct-superclasses class)))
 693     (dolist (o (set-difference old supers))
 694       (remove-direct-subclass o class))))
 695 \f
 696 (defmethod finalize-inheritance ((class std-class))
 697   (update-class class t))
 698
 699 (defmethod finalize-inheritance ((class forward-referenced-class))
 700   ;; FIXME: should we not be thinking a bit about what kinds of error
 701   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 702   ;; possibly a forward-referenced-class-error, though that's
 703   ;; difficult given e.g. class precedence list calculations...
 704   (error
 705    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 706        ~2I~_~S~:>"
 707    class))
 708
 709 \f
 710 (defun class-has-a-forward-referenced-superclass-p (class)
 711   (or (forward-referenced-class-p class)
 712       (some #'class-has-a-forward-referenced-superclass-p
 713             (class-direct-superclasses class))))
 714
 715 ;;; This is called by :after shared-initialize whenever a class is initialized
 716 ;;; or reinitialized. The class may or may not be finalized.
 717 (defun update-class (class finalizep)
 718   ;; Comment from Gerd Moellmann:
 719   ;;
 720   ;; Note that we can't simply delay the finalization when CLASS has
 721   ;; no forward referenced superclasses because that causes bootstrap
 722   ;; problems.
 723   (when (and (not finalizep)
 724              (not (class-finalized-p class))
 725              (not (class-has-a-forward-referenced-superclass-p class)))
 726     (finalize-inheritance class)
 727     (return-from update-class))
 728   (when (or finalizep (class-finalized-p class)
 729             (not (class-has-a-forward-referenced-superclass-p class)))
 730     (update-cpl class (compute-class-precedence-list class))
 731     ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 732     ;; class.  The hoops above are to ensure that FINALIZE-INHERITANCE
 733     ;; is called at finalization, so that MOP programmers can hook
 734     ;; into the system as described in "Class Finalization Protocol"
 735     ;; (section 5.5.2 of AMOP).
 736     (update-slots class (compute-slots class))
 737     (update-gfs-of-class class)
 738     (update-inits class (compute-default-initargs class))
 739     (update-ctors 'finalize-inheritance :class class))
 740   (unless finalizep
 741     (dolist (sub (class-direct-subclasses class)) (update-class sub nil))))
 742
 743 (defun update-cpl (class cpl)
 744   (if (class-finalized-p class)
 745       (unless (equal (class-precedence-list class) cpl)
 746         ;; comment from the old CMU CL sources:
 747         ;;   Need to have the cpl setup before update-lisp-class-layout
 748         ;;   is called on CMU CL.
 749         (setf (slot-value class 'class-precedence-list) cpl)
 750         (force-cache-flushes class))
 751       (setf (slot-value class 'class-precedence-list) cpl))
 752   (update-class-can-precede-p cpl))
 753
 754 (defun update-class-can-precede-p (cpl)
 755   (when cpl
 756     (let ((first (car cpl)))
 757       (dolist (c (cdr cpl))
 758         (pushnew c (slot-value first 'can-precede-list))))
 759     (update-class-can-precede-p (cdr cpl))))
 760
 761 (defun class-can-precede-p (class1 class2)
 762   (member class2 (class-can-precede-list class1)))
 763
 764 (defun update-slots (class eslotds)
 765   (let ((instance-slots ())
 766         (class-slots    ()))
 767     (dolist (eslotd eslotds)
 768       (let ((alloc (slot-definition-allocation eslotd)))
 769         (case alloc
 770           (:instance (push eslotd instance-slots))
 771           (:class (push eslotd class-slots)))))
 772
 773     ;; If there is a change in the shape of the instances then the
 774     ;; old class is now obsolete.
 775     (let* ((nlayout (mapcar #'slot-definition-name
 776                             (sort instance-slots #'<
 777                                   :key #'slot-definition-location)))
 778            (nslots (length nlayout))
 779            (nwrapper-class-slots (compute-class-slots class-slots))
 780            (owrapper (class-wrapper class))
 781            (olayout (and owrapper (wrapper-instance-slots-layout owrapper)))
 782            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 783            (nwrapper
 784             (cond ((null owrapper)
 785                    (make-wrapper nslots class))
 786                   ((and (equal nlayout olayout)
 787                         (not
 788                          (loop for o in owrapper-class-slots
 789                                for n in nwrapper-class-slots
 790                                do (unless (eq (car o) (car n)) (return t)))))
 791                    owrapper)
 792                   (t
 793                    ;; This will initialize the new wrapper to have the
 794                    ;; same state as the old wrapper. We will then have
 795                    ;; to change that. This may seem like wasted work
 796                    ;; (and it is), but the spec requires that we call
 797                    ;; MAKE-INSTANCES-OBSOLETE.
 798                    (make-instances-obsolete class)
 799                    (class-wrapper class)))))
 800
 801       (with-slots (wrapper slots) class
 802         (update-lisp-class-layout class nwrapper)
 803         (setf slots eslotds
 804               (wrapper-instance-slots-layout nwrapper) nlayout
 805               (wrapper-class-slots nwrapper) nwrapper-class-slots
 806               (wrapper-no-of-instance-slots nwrapper) nslots
 807               wrapper nwrapper))
 808
 809       (unless (eq owrapper nwrapper)
 810         (update-pv-table-cache-info class)))))
 811
 812 (defun compute-class-slots (eslotds)
 813   (let (collect)
 814     (dolist (eslotd eslotds)
 815       (push (assoc (slot-definition-name eslotd)
 816                    (class-slot-cells (slot-definition-class eslotd)))
 817             collect))
 818     (nreverse collect)))
 819
 820 (defun update-gfs-of-class (class)
 821   (when (and (class-finalized-p class)
 822              (let ((cpl (class-precedence-list class)))
 823                (or (member *the-class-slot-class* cpl)
 824                    (member *the-class-standard-effective-slot-definition*
 825                            cpl))))
 826     (let ((gf-table (make-hash-table :test 'eq)))
 827       (labels ((collect-gfs (class)
 828                  (dolist (gf (specializer-direct-generic-functions class))
 829                    (setf (gethash gf gf-table) t))
 830                  (mapc #'collect-gfs (class-direct-superclasses class))))
 831         (collect-gfs class)
 832         (maphash (lambda (gf ignore)
 833                    (declare (ignore ignore))
 834                    (update-gf-dfun class gf))
 835                  gf-table)))))
 836
 837 (defun update-inits (class inits)
 838   (setf (plist-value class 'default-initargs) inits))
 839 \f
 840 (defmethod compute-default-initargs ((class slot-class))
 841   (let ((cpl (class-precedence-list class))
 842         (direct (class-direct-default-initargs class)))
 843     (labels ((walk (tail)
 844                (if (null tail)
 845                    nil
 846                    (let ((c (pop tail)))
 847                      (append (if (eq c class)
 848                                  direct
 849                                  (class-direct-default-initargs c))
 850                              (walk tail))))))
 851       (let ((initargs (walk cpl)))
 852         (delete-duplicates initargs :test #'eq :key #'car :from-end t)))))
 853 \f
 854 ;;;; protocols for constructing direct and effective slot definitions
 855
 856 (defmethod direct-slot-definition-class ((class std-class) initargs)
 857   (declare (ignore initargs))
 858   (find-class 'standard-direct-slot-definition))
 859
 860 (defun make-direct-slotd (class initargs)
 861   (let ((initargs (list* :class class initargs)))
 862     (apply #'make-instance
 863            (direct-slot-definition-class class initargs)
 864            initargs)))
 865
 866 (defmethod compute-slots ((class std-class))
 867   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 868   ;; for each different slot name we find in our superclasses. Each
 869   ;; call receives the class and a list of the dslotds with that name.
 870   ;; The list is in most-specific-first order.
 871   (let ((name-dslotds-alist ()))
 872     (dolist (c (class-precedence-list class))
 873       (dolist (slot (class-direct-slots c))
 874         (let* ((name (slot-definition-name slot))
 875                (entry (assq name name-dslotds-alist)))
 876           (if entry
 877               (push slot (cdr entry))
 878               (push (list name slot) name-dslotds-alist)))))
 879     (mapcar (lambda (direct)
 880               (compute-effective-slot-definition class
 881                                                  (nreverse (cdr direct))))
 882             name-dslotds-alist)))
 883
 884 (defmethod compute-slots ((class standard-class))
 885   (call-next-method))
 886
 887 (defmethod compute-slots :around ((class standard-class))
 888   (let ((eslotds (call-next-method))
 889         (location -1))
 890     (dolist (eslotd eslotds eslotds)
 891       (setf (slot-definition-location eslotd)
 892             (ecase (slot-definition-allocation eslotd)
 893               (:instance
 894                (incf location))
 895               (:class
 896                (let* ((name (slot-definition-name eslotd))
 897                       (from-class (slot-definition-allocation-class eslotd))
 898                       (cell (assq name (class-slot-cells from-class))))
 899                  (aver (consp cell))
 900                  cell))))
 901       (initialize-internal-slot-functions eslotd))))
 902
 903 (defmethod compute-slots ((class funcallable-standard-class))
 904   (call-next-method))
 905
 906 (defmethod compute-slots :around ((class funcallable-standard-class))
 907   (labels ((instance-slot-names (slotds)
 908              (let (collect)
 909                (dolist (slotd slotds (nreverse collect))
 910                  (when (eq (slot-definition-allocation slotd) :instance)
 911                    (push (slot-definition-name slotd) collect)))))
 912            ;; This sorts slots so that slots of classes later in the CPL
 913            ;; come before slots of other classes.  This is crucial for
 914            ;; funcallable instances because it ensures that the slots of
 915            ;; FUNCALLABLE-STANDARD-OBJECT, which includes the slots of
 916            ;; KERNEL:FUNCALLABLE-INSTANCE, come first, which in turn
 917            ;; makes it possible to treat FUNCALLABLE-STANDARD-OBJECT as
 918            ;; a funcallable instance.
 919            (compute-layout (eslotds)
 920              (let ((first ())
 921                    (names (instance-slot-names eslotds)))
 922                (dolist (class
 923                         (reverse (class-precedence-list class))
 924                         (nreverse (nconc names first)))
 925                  (dolist (ss (class-slots class))
 926                    (let ((name (slot-definition-name ss)))
 927                      (when (member name names)
 928                        (push name first)
 929                        (setq names (delete name names)))))))))
 930     (let ((all-slotds (call-next-method))
 931           (instance-slots ())
 932           (class-slots ()))
 933       (dolist (slotd all-slotds)
 934         (ecase (slot-definition-allocation slotd)
 935           (:instance (push slotd instance-slots))
 936           (:class (push slotd class-slots))))
 937       (let ((layout (compute-layout instance-slots)))
 938         (dolist (slotd instance-slots)
 939           (setf (slot-definition-location slotd)
 940                 (position (slot-definition-name slotd) layout))
 941           (initialize-internal-slot-functions slotd)))
 942       (dolist (slotd class-slots)
 943         (let ((name (slot-definition-name slotd))
 944               (from-class (slot-definition-allocation-class slotd)))
 945           (setf (slot-definition-location slotd)
 946                 (assoc name (class-slot-cells from-class)))
 947           (aver (consp (slot-definition-location slotd)))
 948           (initialize-internal-slot-functions slotd)))
 949       all-slotds)))
 950
 951 (defmethod compute-slots ((class structure-class))
 952   (mapcan (lambda (superclass)
 953             (mapcar (lambda (dslotd)
 954                       (compute-effective-slot-definition class
 955                                                          (list dslotd)))
 956                     (class-direct-slots superclass)))
 957           (reverse (slot-value class 'class-precedence-list))))
 958
 959 (defmethod compute-slots :around ((class structure-class))
 960   (let ((eslotds (call-next-method)))
 961     (mapc #'initialize-internal-slot-functions eslotds)
 962     eslotds))
 963
 964 (defmethod compute-effective-slot-definition ((class slot-class) dslotds)
 965   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
 966          (class (effective-slot-definition-class class initargs)))
 967     (apply #'make-instance class initargs)))
 968
 969 (defmethod effective-slot-definition-class ((class std-class) initargs)
 970   (declare (ignore initargs))
 971   (find-class 'standard-effective-slot-definition))
 972
 973 (defmethod effective-slot-definition-class ((class structure-class) initargs)
 974   (declare (ignore initargs))
 975   (find-class 'structure-effective-slot-definition))
 976
 977 (defmethod compute-effective-slot-definition-initargs
 978     ((class slot-class) direct-slotds)
 979   (let* ((name nil)
 980          (initfunction nil)
 981          (initform nil)
 982          (initargs nil)
 983          (allocation nil)
 984          (allocation-class nil)
 985          (type t)
 986          (namep  nil)
 987          (initp  nil)
 988          (allocp nil))
 989
 990     (dolist (slotd direct-slotds)
 991       (when slotd
 992         (unless namep
 993           (setq name (slot-definition-name slotd)
 994                 namep t))
 995         (unless initp
 996           (when (slot-definition-initfunction slotd)
 997             (setq initform (slot-definition-initform slotd)
 998                   initfunction (slot-definition-initfunction slotd)
 999                   initp t)))
1000         (unless allocp
1001           (setq allocation (slot-definition-allocation slotd)
1002                 allocation-class (slot-definition-class slotd)
1003                 allocp t))
1004         (setq initargs (append (slot-definition-initargs slotd) initargs))
1005         (let ((slotd-type (slot-definition-type slotd)))
1006           (setq type (cond ((eq type t) slotd-type)
1007                            ((*subtypep type slotd-type) type)
1008                            (t `(and ,type ,slotd-type)))))))
1009     (list :name name
1010           :initform initform
1011           :initfunction initfunction
1012           :initargs initargs
1013           :allocation allocation
1014           :allocation-class allocation-class
1015           :type type
1016           :class class)))
1017
1018 (defmethod compute-effective-slot-definition-initargs :around
1019     ((class structure-class) direct-slotds)
1020   (let ((slotd (car direct-slotds)))
1021     (list* :defstruct-accessor-symbol
1022            (slot-definition-defstruct-accessor-symbol slotd)
1023            :internal-reader-function
1024            (slot-definition-internal-reader-function slotd)
1025            :internal-writer-function
1026            (slot-definition-internal-writer-function slotd)
1027            (call-next-method))))
1028 \f
1029 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1030 ;;;       to make the method object. They have to use make-a-method which
1031 ;;;       is a specially bootstrapped mechanism for making standard methods.
1032 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1033   (declare (ignore direct-slot initargs))
1034   (find-class 'standard-reader-method))
1035
1036 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
1037   (add-method generic-function
1038               (make-a-method 'standard-reader-method
1039                              ()
1040                              (list (or (class-name class) 'object))
1041                              (list class)
1042                              (make-reader-method-function class slot-name)
1043                              "automatically generated reader method"
1044                              slot-name)))
1045
1046 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1047   (declare (ignore direct-slot initargs))
1048   (find-class 'standard-writer-method))
1049
1050 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
1051   (add-method generic-function
1052               (make-a-method 'standard-writer-method
1053                              ()
1054                              (list 'new-value (or (class-name class) 'object))
1055                              (list *the-class-t* class)
1056                              (make-writer-method-function class slot-name)
1057                              "automatically generated writer method"
1058                              slot-name)))
1059
1060 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
1061   (add-method generic-function
1062               (make-a-method 'standard-boundp-method
1063                              ()
1064                              (list (or (class-name class) 'object))
1065                              (list class)
1066                              (make-boundp-method-function class slot-name)
1067                              "automatically generated boundp method"
1068                              slot-name)))
1069
1070 (defmethod remove-reader-method ((class slot-class) generic-function)
1071   (let ((method (get-method generic-function () (list class) nil)))
1072     (when method (remove-method generic-function method))))
1073
1074 (defmethod remove-writer-method ((class slot-class) generic-function)
1075   (let ((method
1076           (get-method generic-function () (list *the-class-t* class) nil)))
1077     (when method (remove-method generic-function method))))
1078
1079 (defmethod remove-boundp-method ((class slot-class) generic-function)
1080   (let ((method (get-method generic-function () (list class) nil)))
1081     (when method (remove-method generic-function method))))
1082 \f
1083 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITE-METHOD function are NOT
1084 ;;; part of the standard protocol. They are however useful, PCL makes
1085 ;;; use of them internally and documents them for PCL users.
1086 ;;;
1087 ;;; *** This needs work to make type testing by the writer functions which
1088 ;;; *** do type testing faster. The idea would be to have one constructor
1089 ;;; *** for each possible type test.
1090 ;;;
1091 ;;; *** There is a subtle bug here which is going to have to be fixed.
1092 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1093 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1094 ;;; *** defined for this metaclass a chance to run.
1095
1096 (defmethod make-reader-method-function ((class slot-class) slot-name)
1097   (make-std-reader-method-function (class-name class) slot-name))
1098
1099 (defmethod make-writer-method-function ((class slot-class) slot-name)
1100   (make-std-writer-method-function (class-name class) slot-name))
1101
1102 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1103   (make-std-boundp-method-function (class-name class) slot-name))
1104 \f
1105 (defmethod compatible-meta-class-change-p (class proto-new-class)
1106   (eq (class-of class) (class-of proto-new-class)))
1107
1108 (defmethod validate-superclass ((class class) (new-super class))
1109   (or (eq new-super *the-class-t*)
1110       (eq (class-of class) (class-of new-super))))
1111
1112 (defmethod validate-superclass ((class standard-class) (new-super std-class))
1113   (let ((new-super-meta-class (class-of new-super)))
1114     (or (eq new-super-meta-class *the-class-std-class*)
1115         (eq (class-of class) new-super-meta-class))))
1116 \f
1117 ;;; What this does depends on which of the four possible values of
1118 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1119 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1120 ;;; nothing to do, as the new wrapper has already been created.  If
1121 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1122 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1123 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1124 ;;;
1125 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1126 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1127 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1128 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1129 ;;; obsolete the wrapper.
1130 ;;;
1131 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1132 ;;; for (AVER (NOT (EQ (SB-KERNEL:LAYOUT-INVALID OWRAPPER)
1133 ;;;                    :UNINITIALIZED)))
1134 ;;;
1135 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1136 (defun force-cache-flushes (class)
1137   (let* ((owrapper (class-wrapper class)))
1138     ;; We only need to do something if the wrapper is still valid. If
1139     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1140     ;; both of those will already be doing what we want. In
1141     ;; particular, we must be sure we never change an OBSOLETE into a
1142     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1143     (when (or (not (invalid-wrapper-p owrapper))
1144               ;; KLUDGE: despite the observations above, this remains
1145               ;; a violation of locality or what might be considered
1146               ;; good style.  There has to be a better way!  -- CSR,
1147               ;; 2002-10-29
1148               (eq (sb-kernel:layout-invalid owrapper) t))
1149       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1150                                     class)))
1151         (setf (wrapper-instance-slots-layout nwrapper)
1152               (wrapper-instance-slots-layout owrapper))
1153         (setf (wrapper-class-slots nwrapper)
1154               (wrapper-class-slots owrapper))
1155         (sb-sys:without-interrupts
1156           (update-lisp-class-layout class nwrapper)
1157           (setf (slot-value class 'wrapper) nwrapper)
1158           (invalidate-wrapper owrapper :flush nwrapper))))))
1159
1160 (defun flush-cache-trap (owrapper nwrapper instance)
1161   (declare (ignore owrapper))
1162   (set-wrapper instance nwrapper))
1163 \f
1164 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1165 ;;; the next access to the instance (as defined in 88-002R) to trap
1166 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1167 (defmethod make-instances-obsolete ((class std-class))
1168   (let* ((owrapper (class-wrapper class))
1169          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1170                                  class)))
1171       (setf (wrapper-instance-slots-layout nwrapper)
1172             (wrapper-instance-slots-layout owrapper))
1173       (setf (wrapper-class-slots nwrapper)
1174             (wrapper-class-slots owrapper))
1175       (sb-sys:without-interrupts
1176         (update-lisp-class-layout class nwrapper)
1177         (setf (slot-value class 'wrapper) nwrapper)
1178         (invalidate-wrapper owrapper :obsolete nwrapper)
1179         class)))
1180
1181 (defmethod make-instances-obsolete ((class symbol))
1182   (make-instances-obsolete (find-class class)))
1183
1184 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1185 ;;; see an obsolete instance. The times when it is called are:
1186 ;;;   - when the instance is involved in method lookup
1187 ;;;   - when attempting to access a slot of an instance
1188 ;;;
1189 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1190 ;;; instance access macros.
1191 ;;;
1192 ;;; Of course these times when it is called are an internal
1193 ;;; implementation detail of PCL and are not part of the documented
1194 ;;; description of when the obsolete instance update happens. The
1195 ;;; documented description is as it appears in 88-002R.
1196 ;;;
1197 ;;; This has to return the new wrapper, so it counts on all the
1198 ;;; methods on obsolete-instance-trap-internal to return the new
1199 ;;; wrapper. It also does a little internal error checking to make
1200 ;;; sure that the traps are only happening when they should, and that
1201 ;;; the trap methods are computing appropriate new wrappers.
1202
1203 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1204 ;;; after a structure is redefined. In most cases,
1205 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1206 ;;; so it must signal an error. The hard part of this is that the
1207 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1208 ;;; called again, so in that case, we have to return some reasonable
1209 ;;; wrapper, instead.
1210
1211 (defvar *in-obsolete-instance-trap* nil)
1212 (defvar *the-wrapper-of-structure-object*
1213   (class-wrapper (find-class 'structure-object)))
1214
1215 (define-condition obsolete-structure (error)
1216   ((datum :reader obsolete-structure-datum :initarg :datum))
1217   (:report
1218    (lambda (condition stream)
1219      ;; Don't try to print the structure, since it probably won't work.
1220      (format stream
1221              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1222              (type-of (obsolete-structure-datum condition))))))
1223
1224 (defun obsolete-instance-trap (owrapper nwrapper instance)
1225   (if (not (pcl-instance-p instance))
1226       (if *in-obsolete-instance-trap*
1227           *the-wrapper-of-structure-object*
1228            (let ((*in-obsolete-instance-trap* t))
1229              (error 'obsolete-structure :datum instance)))
1230       (let* ((class (wrapper-class* nwrapper))
1231              (copy (allocate-instance class)) ;??? allocate-instance ???
1232              (olayout (wrapper-instance-slots-layout owrapper))
1233              (nlayout (wrapper-instance-slots-layout nwrapper))
1234              (oslots (get-slots instance))
1235              (nslots (get-slots copy))
1236              (oclass-slots (wrapper-class-slots owrapper))
1237              (added ())
1238              (discarded ())
1239              (plist ()))
1240         ;; local  --> local     transfer
1241         ;; local  --> shared       discard
1242         ;; local  -->  --         discard
1243         ;; shared --> local     transfer
1244         ;; shared --> shared       discard
1245         ;; shared -->  --         discard
1246         ;;  --    --> local     add
1247         ;;  --    --> shared    --
1248
1249         ;; Go through all the old local slots.
1250         (let ((opos 0))
1251           (dolist (name olayout)
1252             (let ((npos (posq name nlayout)))
1253               (if npos
1254                   (setf (clos-slots-ref nslots npos)
1255                         (clos-slots-ref oslots opos))
1256                   (progn
1257                     (push name discarded)
1258                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1259                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1260             (incf opos)))
1261
1262         ;; Go through all the old shared slots.
1263         (dolist (oclass-slot-and-val oclass-slots)
1264           (let ((name (car oclass-slot-and-val))
1265                 (val (cdr oclass-slot-and-val)))
1266             (let ((npos (posq name nlayout)))
1267               (if npos
1268                   (setf (clos-slots-ref nslots npos) (cdr oclass-slot-and-val))
1269                   (progn (push name discarded)
1270                          (unless (eq val +slot-unbound+)
1271                            (setf (getf plist name) val)))))))
1272
1273         ;; Go through all the new local slots to compute the added slots.
1274         (dolist (nlocal nlayout)
1275           (unless (or (memq nlocal olayout)
1276                       (assq nlocal oclass-slots))
1277             (push nlocal added)))
1278
1279         (swap-wrappers-and-slots instance copy)
1280
1281         (update-instance-for-redefined-class instance
1282                                              added
1283                                              discarded
1284                                              plist)
1285         nwrapper)))
1286 \f
1287 (defun change-class-internal (instance new-class initargs)
1288   (let* ((old-class (class-of instance))
1289          (copy (allocate-instance new-class))
1290          (new-wrapper (get-wrapper copy))
1291          (old-wrapper (class-wrapper old-class))
1292          (old-layout (wrapper-instance-slots-layout old-wrapper))
1293          (new-layout (wrapper-instance-slots-layout new-wrapper))
1294          (old-slots (get-slots instance))
1295          (new-slots (get-slots copy))
1296          (old-class-slots (wrapper-class-slots old-wrapper)))
1297
1298     ;; "The values of local slots specified by both the class CTO and
1299     ;; CFROM are retained. If such a local slot was unbound, it
1300     ;; remains unbound."
1301     (let ((new-position 0))
1302       (dolist (new-slot new-layout)
1303         (let ((old-position (posq new-slot old-layout)))
1304           (when old-position
1305             (setf (clos-slots-ref new-slots new-position)
1306                   (clos-slots-ref old-slots old-position))))
1307         (incf new-position)))
1308
1309     ;; "The values of slots specified as shared in the class CFROM and
1310     ;; as local in the class CTO are retained."
1311     (dolist (slot-and-val old-class-slots)
1312       (let ((position (posq (car slot-and-val) new-layout)))
1313         (when position
1314           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1315
1316     ;; Make the copy point to the old instance's storage, and make the
1317     ;; old instance point to the new storage.
1318     (swap-wrappers-and-slots instance copy)
1319
1320     (apply #'update-instance-for-different-class copy instance initargs)
1321     instance))
1322
1323 (defmethod change-class ((instance standard-object)
1324                          (new-class standard-class)
1325                          &rest initargs)
1326   (change-class-internal instance new-class initargs))
1327
1328 (defmethod change-class ((instance funcallable-standard-object)
1329                          (new-class funcallable-standard-class)
1330                          &rest initargs)
1331   (change-class-internal instance new-class initargs))
1332
1333 (defmethod change-class ((instance standard-object)
1334                          (new-class funcallable-standard-class)
1335                          &rest initargs)
1336   (declare (ignore initargs))
1337   (error "You can't change the class of ~S to ~S~@
1338           because it isn't already an instance with metaclass ~S."
1339          instance new-class 'standard-class))
1340
1341 (defmethod change-class ((instance funcallable-standard-object)
1342                          (new-class standard-class)
1343                          &rest initargs)
1344   (declare (ignore initargs))
1345   (error "You can't change the class of ~S to ~S~@
1346           because it isn't already an instance with metaclass ~S."
1347          instance new-class 'funcallable-standard-class))
1348
1349 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1350   (apply #'change-class instance (find-class new-class-name) initargs))
1351 \f
1352 ;;;; The metaclass BUILT-IN-CLASS
1353 ;;;;
1354 ;;;; This metaclass is something of a weird creature. By this point, all
1355 ;;;; instances of it which will exist have been created, and no instance
1356 ;;;; is ever created by calling MAKE-INSTANCE.
1357 ;;;;
1358 ;;;; But, there are other parts of the protocol we must follow and those
1359 ;;;; definitions appear here.
1360
1361 (defmethod shared-initialize :before
1362            ((class built-in-class) slot-names &rest initargs)
1363   (declare (ignore slot-names initargs))
1364   (error "attempt to initialize or reinitialize a built in class"))
1365
1366 (defmethod class-direct-slots       ((class built-in-class)) ())
1367 (defmethod class-slots             ((class built-in-class)) ())
1368 (defmethod class-direct-default-initargs ((class built-in-class)) ())
1369 (defmethod class-default-initargs       ((class built-in-class)) ())
1370
1371 (defmethod validate-superclass ((c class) (s built-in-class))
1372   (or (eq s *the-class-t*)
1373       (eq s *the-class-stream*)))
1374 \f
1375 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1376 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1377 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1378 (macrolet ((def (method)
1379              `(defmethod ,method ((class forward-referenced-class))
1380                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1381                        ',method class))))
1382   (def class-default-initargs)
1383   (def class-precedence-list)
1384   (def class-slots))
1385
1386 (defmethod validate-superclass ((c slot-class)
1387                                 (f forward-referenced-class))
1388   t)
1389 \f
1390 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1391   (pushnew dependent (plist-value metaobject 'dependents)))
1392
1393 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1394   (setf (plist-value metaobject 'dependents)
1395         (delete dependent (plist-value metaobject 'dependents))))
1396
1397 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1398   (dolist (dependent (plist-value metaobject 'dependents))
1399     (funcall function dependent)))
1400