src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd '%class)))
  76     (dolist (type '(reader writer boundp))
  77       (let* ((gf-name (ecase type
  78                               (reader 'slot-value-using-class)
  79                               (writer '(setf slot-value-using-class))
  80                               (boundp 'slot-boundp-using-class)))
  81              (gf (gdefinition gf-name)))
  82         (compute-slot-accessor-info slotd type gf)))))
  83
  84 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
  85 ;;;
  86 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
  87 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
  88 ;;; writing/testing effective slot SLOTD.
  89 ;;;
  90 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
  91 ;;; GF.  Store the effective method in the effective slot definition
  92 ;;; object itself; these GFs have special dispatch functions calling
  93 ;;; effective methods directly retrieved from effective slot
  94 ;;; definition objects, as an optimization.
  95 ;;;
  96 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
  97 ;;; or some such.
  98 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  99                                        type gf)
 100   (let* ((name (slot-value slotd 'name))
 101          (class (slot-value slotd '%class))
 102          (old-slotd (find-slot-definition class name))
 103          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
 104     (multiple-value-bind (function std-p)
 105         (if (eq *boot-state* 'complete)
 106             (get-accessor-method-function gf type class slotd)
 107             (get-optimized-std-accessor-method-function class slotd type))
 108       (setf (slot-accessor-std-p slotd type) std-p)
 109       (setf (slot-accessor-function slotd type) function))
 110     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 111       (push (cons class name) *pv-table-cache-update-info*))))
 112
 113 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 114   :instance)
 115 \f
 116 ;;;; various class accessors that are a little more complicated than can be
 117 ;;;; done with automatically generated reader methods
 118
 119 (defmethod class-prototype :before (class)
 120   (unless (class-finalized-p class)
 121     (error "~@<~S is not finalized.~:@>" class)))
 122
 123 ;;; KLUDGE: For some reason factoring the common body into a function
 124 ;;; breaks PCL bootstrapping, so just generate it with a macrolet for
 125 ;;; all.
 126 (macrolet ((def (class)
 127              `(defmethod class-prototype ((class ,class))
 128                 (with-slots (prototype) class
 129                   (or prototype
 130                       (setf prototype (allocate-instance class)))))))
 131   (def std-class)
 132   (def condition-class)
 133   (def structure-class))
 134
 135 (defmethod class-direct-default-initargs ((class slot-class))
 136   (plist-value class 'direct-default-initargs))
 137
 138 (defmethod class-default-initargs ((class slot-class))
 139   (plist-value class 'default-initargs))
 140
 141 (defmethod class-slot-cells ((class std-class))
 142   (plist-value class 'class-slot-cells))
 143 (defmethod (setf class-slot-cells) (new-value (class std-class))
 144   (setf (plist-value class 'class-slot-cells) new-value))
 145 \f
 146 ;;;; class accessors that are even a little bit more complicated than those
 147 ;;;; above. These have a protocol for updating them, we must implement that
 148 ;;;; protocol.
 149
 150 ;;; Maintaining the direct subclasses backpointers. The update methods are
 151 ;;; here, the values are read by an automatically generated reader method.
 152 (defmethod add-direct-subclass ((class class) (subclass class))
 153   (with-slots (direct-subclasses) class
 154     (pushnew subclass direct-subclasses)
 155     subclass))
 156 (defmethod remove-direct-subclass ((class class) (subclass class))
 157   (with-slots (direct-subclasses) class
 158     (setq direct-subclasses (remove subclass direct-subclasses))
 159     subclass))
 160
 161 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 162 ;;;
 163 ;;; There are four generic functions involved, each has one method for the
 164 ;;; class case and another method for the damned EQL specializers. All of
 165 ;;; these are specified methods and appear in their specified place in the
 166 ;;; class graph.
 167 ;;;
 168 ;;;   ADD-DIRECT-METHOD
 169 ;;;   REMOVE-DIRECT-METHOD
 170 ;;;   SPECIALIZER-DIRECT-METHODS
 171 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 172 ;;;
 173 ;;; In each case, we maintain one value which is a cons. The car is the list
 174 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 175 ;;; computed lazily.
 176 (defmethod add-direct-method ((specializer class) (method method))
 177   (with-slots (direct-methods) specializer
 178     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 179           (cdr direct-methods) ()))
 180   method)
 181 (defmethod remove-direct-method ((specializer class) (method method))
 182   (with-slots (direct-methods) specializer
 183     (setf (car direct-methods) (remove method (car direct-methods))
 184           (cdr direct-methods) ()))
 185   method)
 186
 187 (defmethod specializer-direct-methods ((specializer class))
 188   (with-slots (direct-methods) specializer
 189     (car direct-methods)))
 190
 191 (defmethod specializer-direct-generic-functions ((specializer class))
 192   (with-slots (direct-methods) specializer
 193     (or (cdr direct-methods)
 194         (setf (cdr direct-methods)
 195               (let (collect)
 196                 (dolist (m (car direct-methods))
 197                   ;; the old PCL code used COLLECTING-ONCE which used
 198                   ;; #'EQ to check for newness
 199                   (pushnew (method-generic-function m) collect :test #'eq))
 200                 (nreverse collect))))))
 201 \f
 202 ;;; This hash table is used to store the direct methods and direct generic
 203 ;;; functions of EQL specializers. Each value in the table is the cons.
 204 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 205 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 206
 207 (defmethod specializer-method-table ((specializer eql-specializer))
 208   *eql-specializer-methods*)
 209
 210 (defmethod specializer-method-table ((specializer class-eq-specializer))
 211   *class-eq-specializer-methods*)
 212
 213 (defmethod add-direct-method ((specializer specializer-with-object)
 214                               (method method))
 215   (let* ((object (specializer-object specializer))
 216          (table (specializer-method-table specializer))
 217          (entry (gethash object table)))
 218     (unless entry
 219       (setq entry
 220             (setf (gethash object table)
 221                   (cons nil nil))))
 222     (setf (car entry) (adjoin method (car entry))
 223           (cdr entry) ())
 224     method))
 225
 226 (defmethod remove-direct-method ((specializer specializer-with-object)
 227                                  (method method))
 228   (let* ((object (specializer-object specializer))
 229          (entry (gethash object (specializer-method-table specializer))))
 230     (when entry
 231       (setf (car entry) (remove method (car entry))
 232             (cdr entry) ()))
 233     method))
 234
 235 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 236   (car (gethash (specializer-object specializer)
 237                 (specializer-method-table specializer))))
 238
 239 (defmethod specializer-direct-generic-functions ((specializer
 240                                                   specializer-with-object))
 241   (let* ((object (specializer-object specializer))
 242          (entry (gethash object (specializer-method-table specializer))))
 243     (when entry
 244       (or (cdr entry)
 245           (setf (cdr entry)
 246                 (let (collect)
 247                   (dolist (m (car entry))
 248                     (pushnew (method-generic-function m) collect :test #'eq))
 249                   (nreverse collect)))))))
 250
 251 (defun map-specializers (function)
 252   (map-all-classes (lambda (class)
 253                      (funcall function (class-eq-specializer class))
 254                      (funcall function class)))
 255   (maphash (lambda (object methods)
 256              (declare (ignore methods))
 257              (intern-eql-specializer object))
 258            *eql-specializer-methods*)
 259   (maphash (lambda (object specl)
 260              (declare (ignore object))
 261              (funcall function specl))
 262            *eql-specializer-table*)
 263   nil)
 264
 265 (defun map-all-generic-functions (function)
 266   (let ((all-generic-functions (make-hash-table :test 'eq)))
 267     (map-specializers (lambda (specl)
 268                         (dolist (gf (specializer-direct-generic-functions
 269                                      specl))
 270                           (unless (gethash gf all-generic-functions)
 271                             (setf (gethash gf all-generic-functions) t)
 272                             (funcall function gf))))))
 273   nil)
 274
 275 (defmethod shared-initialize :after ((specl class-eq-specializer)
 276                                      slot-names
 277                                      &key)
 278   (declare (ignore slot-names))
 279   (setf (slot-value specl '%type) `(class-eq ,(specializer-class specl))))
 280
 281 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 282   (declare (ignore slot-names))
 283   (setf (slot-value specl '%type)
 284         `(eql ,(specializer-object specl)))
 285   (setf (info :type :translator specl)
 286         (constantly (make-member-type :members (list (specializer-object specl))))))
 287
 288 (defun real-load-defclass (name metaclass-name supers slots other
 289                            readers writers slot-names source-location safe-p)
 290   (with-single-package-locked-error (:symbol name "defining ~S as a class")
 291     (%compiler-defclass name readers writers slot-names)
 292     (let ((res (apply #'ensure-class name :metaclass metaclass-name
 293                       :direct-superclasses supers
 294                       :direct-slots slots
 295                       :definition-source source-location
 296                       'safe-p safe-p
 297                       other)))
 298       res)))
 299
 300 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 301
 302 (defun ensure-class (name &rest args)
 303   (apply #'ensure-class-using-class
 304          (let ((class (find-class name nil)))
 305            (when (and class (eq name (class-name class)))
 306              ;; NAME is the proper name of CLASS, so redefine it
 307              class))
 308          name
 309          args))
 310
 311 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 312   (multiple-value-bind (meta initargs)
 313       (frob-ensure-class-args args)
 314     (setf class (apply #'make-instance meta :name name initargs))
 315     (without-package-locks
 316       (setf (find-class name) class))
 317     (set-class-type-translation class name)
 318     class))
 319
 320 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 321   (multiple-value-bind (meta initargs)
 322       (frob-ensure-class-args args)
 323     (unless (eq (class-of class) meta)
 324       (apply #'change-class class meta initargs))
 325     (apply #'reinitialize-instance class initargs)
 326     (without-package-locks
 327       (setf (find-class name) class))
 328     (set-class-type-translation class name)
 329     class))
 330
 331 (defun frob-ensure-class-args (args)
 332   (let (metaclass metaclassp reversed-plist)
 333     (flet ((frob-superclass (s)
 334              (cond
 335                ((classp s) s)
 336                ((legal-class-name-p s)
 337                 (or (find-class s nil)
 338                     (ensure-class s :metaclass 'forward-referenced-class)))
 339                (t (error "Not a class or a legal class name: ~S." s)))))
 340       (doplist (key val) args
 341         (cond ((eq key :metaclass)
 342                (unless metaclassp
 343                  (setf metaclass val metaclassp key)))
 344               (t
 345                (when (eq key :direct-superclasses)
 346                  (setf val (mapcar #'frob-superclass val)))
 347                (setf reversed-plist (list* val key reversed-plist)))))
 348       (values (cond (metaclassp
 349                      (if (classp metaclass)
 350                          metaclass
 351                          (find-class metaclass)))
 352                     (t *the-class-standard-class*))
 353               (nreverse reversed-plist)))))
 354 \f
 355 (defmethod shared-initialize :after
 356     ((class std-class) slot-names &key
 357      (direct-superclasses nil direct-superclasses-p)
 358      (direct-slots nil direct-slots-p)
 359      (direct-default-initargs nil direct-default-initargs-p))
 360   (cond (direct-superclasses-p
 361          (setq direct-superclasses
 362                (or direct-superclasses
 363                    (list (if (funcallable-standard-class-p class)
 364                              *the-class-funcallable-standard-object*
 365                              *the-class-standard-object*))))
 366          (dolist (superclass direct-superclasses)
 367            (unless (validate-superclass class superclass)
 368              (error "~@<The class ~S was specified as a ~
 369                      super-class of the class ~S, ~
 370                      but the meta-classes ~S and ~S are incompatible.  ~
 371                      Define a method for ~S to avoid this error.~@:>"
 372                      superclass class (class-of superclass) (class-of class)
 373                      'validate-superclass)))
 374          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 375         (t
 376          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 377   (setq direct-slots
 378         (if direct-slots-p
 379             (setf (slot-value class 'direct-slots)
 380                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 381                           direct-slots))
 382             (slot-value class 'direct-slots)))
 383   (if direct-default-initargs-p
 384       (setf (plist-value class 'direct-default-initargs)
 385             direct-default-initargs)
 386       (setq direct-default-initargs
 387             (plist-value class 'direct-default-initargs)))
 388   (setf (plist-value class 'class-slot-cells)
 389         (let ((old-class-slot-cells (plist-value class 'class-slot-cells))
 390               (collect '()))
 391           (dolist (dslotd direct-slots)
 392             (when (eq :class (slot-definition-allocation dslotd))
 393               ;; see CLHS 4.3.6
 394               (let* ((name (slot-definition-name dslotd))
 395                      (old (assoc name old-class-slot-cells)))
 396                 (if (or (not old)
 397                         (eq t slot-names)
 398                         (member name slot-names))
 399                     (let* ((initfunction (slot-definition-initfunction dslotd))
 400                            (value (if initfunction
 401                                       (funcall initfunction)
 402                                       +slot-unbound+)))
 403                       (push (cons name value) collect))
 404                     (push old collect)))))
 405           (nreverse collect)))
 406   (add-direct-subclasses class direct-superclasses)
 407   (if (class-finalized-p class)
 408       ;; required by AMOP, "Reinitialization of Class Metaobjects"
 409       (finalize-inheritance class)
 410       (update-class class nil))
 411   (add-slot-accessors class direct-slots)
 412   (make-preliminary-layout class))
 413
 414 (defmethod shared-initialize :after ((class forward-referenced-class)
 415                                      slot-names &key &allow-other-keys)
 416   (declare (ignore slot-names))
 417   (make-preliminary-layout class))
 418
 419 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 420
 421 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 422 ;;; make it known to the type system.
 423 (defun make-preliminary-layout (class)
 424   (flet ((compute-preliminary-cpl (root)
 425            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 426              (compute-class-precedence-list root))))
 427     (without-package-locks
 428      (unless (class-finalized-p class)
 429        (let ((name (class-name class)))
 430          ;; KLUDGE: This is fairly horrible.  We need to make a
 431          ;; full-fledged CLASSOID here, not just tell the compiler that
 432          ;; some class is forthcoming, because there are legitimate
 433          ;; questions one can ask of the type system, implemented in
 434          ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 435          (let ((layout (make-wrapper 0 class)))
 436            (setf (slot-value class 'wrapper) layout)
 437            (let ((cpl (compute-preliminary-cpl class)))
 438              (setf (layout-inherits layout)
 439                    (order-layout-inherits
 440                     (map 'simple-vector #'class-wrapper
 441                          (reverse (rest cpl))))))
 442            (register-layout layout :invalidate t)
 443            (set-class-type-translation class (layout-classoid layout)))))
 444      (mapc #'make-preliminary-layout (class-direct-subclasses class)))))
 445
 446
 447 (defmethod shared-initialize :before ((class class) slot-names &key name)
 448   (declare (ignore slot-names name))
 449   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 450   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 451   (setf (slot-value class '%type) `(class ,class))
 452   (setf (slot-value class 'class-eq-specializer)
 453         (make-instance 'class-eq-specializer :class class)))
 454
 455 (defmethod reinitialize-instance :before ((class slot-class) &key direct-superclasses)
 456   (dolist (old-super (set-difference (class-direct-superclasses class) direct-superclasses))
 457     (remove-direct-subclass old-super class))
 458   (remove-slot-accessors    class (class-direct-slots class)))
 459
 460 (defmethod reinitialize-instance :after ((class slot-class)
 461                                          &rest initargs
 462                                          &key)
 463   (map-dependents class
 464                   (lambda (dependent)
 465                     (apply #'update-dependent class dependent initargs))))
 466
 467 (defmethod reinitialize-instance :after ((class condition-class) &key)
 468   (let* ((name (class-name class))
 469          (classoid (find-classoid name))
 470          (slots (condition-classoid-slots classoid)))
 471     ;; to balance the REMOVE-SLOT-ACCESSORS call in
 472     ;; REINITIALIZE-INSTANCE :BEFORE (SLOT-CLASS).
 473     (dolist (slot slots)
 474       (let ((slot-name (condition-slot-name slot)))
 475         (dolist (reader (condition-slot-readers slot))
 476           ;; FIXME: see comment in SHARED-INITIALIZE :AFTER
 477           ;; (CONDITION-CLASS T), below.  -- CSR, 2005-11-18
 478           (sb-kernel::install-condition-slot-reader reader name slot-name))
 479         (dolist (writer (condition-slot-writers slot))
 480           (sb-kernel::install-condition-slot-writer writer name slot-name))))))
 481
 482 (defmethod shared-initialize :after ((class condition-class) slot-names
 483                                      &key direct-slots direct-superclasses)
 484   (declare (ignore slot-names))
 485   (let ((classoid (find-classoid (class-name class))))
 486     (with-slots (wrapper %class-precedence-list cpl-available-p
 487                          prototype (direct-supers direct-superclasses))
 488         class
 489       (setf (slot-value class 'direct-slots)
 490             (mapcar (lambda (pl) (make-direct-slotd class pl))
 491                     direct-slots))
 492       (setf (slot-value class 'finalized-p) t)
 493       (setf (classoid-pcl-class classoid) class)
 494       (setq direct-supers direct-superclasses)
 495       (setq wrapper (classoid-layout classoid))
 496       (setq %class-precedence-list (compute-class-precedence-list class))
 497       (setq cpl-available-p t)
 498       (add-direct-subclasses class direct-superclasses)
 499       (setf (slot-value class 'slots) (compute-slots class))))
 500   ;; Comment from Gerd's PCL, 2003-05-15:
 501   ;;
 502   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 503   ;; override condition accessors with generic functions.  We do this
 504   ;; differently.
 505   ;;
 506   ;; ??? What does the above comment mean and why is it a good idea?
 507   ;; CMUCL (which still as of 2005-11-18 uses this code and has this
 508   ;; comment) loses slot information in its condition classes:
 509   ;; DIRECT-SLOTS is always NIL.  We have the right information, so we
 510   ;; remove slot accessors but never put them back.  I've added a
 511   ;; REINITIALIZE-INSTANCE :AFTER (CONDITION-CLASS) method, but what
 512   ;; was meant to happen?  -- CSR, 2005-11-18
 513   (update-pv-table-cache-info class))
 514
 515 (defmethod direct-slot-definition-class ((class condition-class)
 516                                          &rest initargs)
 517   (declare (ignore initargs))
 518   (find-class 'condition-direct-slot-definition))
 519
 520 (defmethod effective-slot-definition-class ((class condition-class)
 521                                             &rest initargs)
 522   (declare (ignore initargs))
 523   (find-class 'condition-effective-slot-definition))
 524
 525 (defmethod finalize-inheritance ((class condition-class))
 526   (aver (slot-value class 'finalized-p))
 527   nil)
 528
 529 (defmethod compute-effective-slot-definition
 530     ((class condition-class) slot-name dslotds)
 531   (let ((slotd (call-next-method)))
 532     (setf (slot-definition-reader-function slotd)
 533           (lambda (x)
 534             (handler-case (condition-reader-function x slot-name)
 535               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 536               ;; is unbound; maybe it should be a CELL-ERROR of some
 537               ;; sort?
 538               (error () (values (slot-unbound class x slot-name))))))
 539     (setf (slot-definition-writer-function slotd)
 540           (lambda (v x)
 541             (condition-writer-function x v slot-name)))
 542     (setf (slot-definition-boundp-function slotd)
 543           (lambda (x)
 544             (multiple-value-bind (v c)
 545                 (ignore-errors (condition-reader-function x slot-name))
 546               (declare (ignore v))
 547               (null c))))
 548     slotd))
 549
 550 (defmethod compute-slots ((class condition-class))
 551   (mapcan (lambda (superclass)
 552             (mapcar (lambda (dslotd)
 553                       (compute-effective-slot-definition
 554                        class (slot-definition-name dslotd) (list dslotd)))
 555                     (class-direct-slots superclass)))
 556           (reverse (slot-value class '%class-precedence-list))))
 557
 558 (defmethod compute-slots :around ((class condition-class))
 559   (let ((eslotds (call-next-method)))
 560     (mapc #'initialize-internal-slot-functions eslotds)
 561     eslotds))
 562
 563 (defmethod shared-initialize :after
 564     ((slotd structure-slot-definition) slot-names &key
 565      (allocation :instance) allocation-class)
 566   (declare (ignore slot-names allocation-class))
 567   (unless (eq allocation :instance)
 568     (error "Structure slots must have :INSTANCE allocation.")))
 569
 570 (defun make-structure-class-defstruct-form (name direct-slots include)
 571   (let* ((conc-name (format-symbol *package* "~S structure class " name))
 572          (constructor (format-symbol *package* "~Aconstructor" conc-name))
 573          (defstruct `(defstruct (,name
 574                                  ,@(when include
 575                                          `((:include ,(class-name include))))
 576                                  (:predicate nil)
 577                                  (:conc-name ,conc-name)
 578                                  (:constructor ,constructor ())
 579                                  (:copier nil))
 580                       ,@(mapcar (lambda (slot)
 581                                   `(,(slot-definition-name slot)
 582                                     +slot-unbound+))
 583                                 direct-slots)))
 584          (reader-names (mapcar (lambda (slotd)
 585                                  (list 'slot-accessor name
 586                                        (slot-definition-name slotd)
 587                                        'reader))
 588                                direct-slots))
 589          (writer-names (mapcar (lambda (slotd)
 590                                  (list 'slot-accessor name
 591                                        (slot-definition-name slotd)
 592                                        'writer))
 593                                direct-slots))
 594          (readers-init
 595            (mapcar (lambda (slotd reader-name)
 596                      (let ((accessor
 597                              (slot-definition-defstruct-accessor-symbol
 598                               slotd)))
 599                        `(defun ,reader-name (obj)
 600                          (declare (type ,name obj))
 601                          (,accessor obj))))
 602                    direct-slots reader-names))
 603          (writers-init
 604            (mapcar (lambda (slotd writer-name)
 605                      (let ((accessor
 606                              (slot-definition-defstruct-accessor-symbol
 607                               slotd)))
 608                        `(defun ,writer-name (nv obj)
 609                          (declare (type ,name obj))
 610                          (setf (,accessor obj) nv))))
 611                    direct-slots writer-names))
 612          (defstruct-form
 613              `(progn
 614                ,defstruct
 615                ,@readers-init ,@writers-init
 616                (cons nil nil))))
 617     (values defstruct-form constructor reader-names writer-names)))
 618
 619 (defun make-defstruct-allocation-function (class)
 620   ;; FIXME: Why don't we go class->layout->info == dd
 621   (let ((dd (find-defstruct-description (class-name class))))
 622     (lambda ()
 623       (sb-kernel::%make-instance-with-layout
 624        (sb-kernel::compiler-layout-or-lose (dd-name dd))))))
 625
 626 (defmethod shared-initialize :after
 627     ((class structure-class) slot-names &key
 628      (direct-superclasses nil direct-superclasses-p)
 629      (direct-slots nil direct-slots-p)
 630      direct-default-initargs)
 631   (declare (ignore slot-names direct-default-initargs))
 632   (if direct-superclasses-p
 633       (setf (slot-value class 'direct-superclasses)
 634             (or direct-superclasses
 635                 (setq direct-superclasses
 636                       (and (not (eq (class-name class) 'structure-object))
 637                            (list *the-class-structure-object*)))))
 638       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 639   (let* ((name (class-name class))
 640          (from-defclass-p (slot-value class 'from-defclass-p))
 641          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 642     (if direct-slots-p
 643         (setf (slot-value class 'direct-slots)
 644               (setq direct-slots
 645                     (mapcar (lambda (pl)
 646                               (when defstruct-p
 647                                 (let* ((slot-name (getf pl :name))
 648                                        (accessor
 649                                         (format-symbol *package*
 650                                                        "~S structure class ~A"
 651                                                        name slot-name)))
 652                                   (setq pl (list* :defstruct-accessor-symbol
 653                                                   accessor pl))))
 654                               (make-direct-slotd class pl))
 655                             direct-slots)))
 656         (setq direct-slots (slot-value class 'direct-slots)))
 657     (if defstruct-p
 658         (let ((include (car (slot-value class 'direct-superclasses))))
 659           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 660               (make-structure-class-defstruct-form name direct-slots include)
 661             (unless (structure-type-p name) (eval defstruct-form))
 662             (mapc (lambda (dslotd reader-name writer-name)
 663                     (let* ((reader (gdefinition reader-name))
 664                            (writer (when (fboundp writer-name)
 665                                      (gdefinition writer-name))))
 666                       (setf (slot-value dslotd 'internal-reader-function)
 667                             reader)
 668                       (setf (slot-value dslotd 'internal-writer-function)
 669                             writer)))
 670                   direct-slots reader-names writer-names)
 671             (setf (slot-value class 'defstruct-form) defstruct-form)
 672             (setf (slot-value class 'defstruct-constructor) constructor)))
 673         (setf (slot-value class 'defstruct-constructor)
 674               (make-defstruct-allocation-function class)))
 675     (add-direct-subclasses class direct-superclasses)
 676     (setf (slot-value class '%class-precedence-list)
 677           (compute-class-precedence-list class))
 678     (setf (slot-value class 'cpl-available-p) t)
 679     (setf (slot-value class 'slots) (compute-slots class))
 680     (let ((lclass (find-classoid (class-name class))))
 681       (setf (classoid-pcl-class lclass) class)
 682       (setf (slot-value class 'wrapper) (classoid-layout lclass)))
 683     (setf (slot-value class 'finalized-p) t)
 684     (update-pv-table-cache-info class)
 685     (add-slot-accessors class direct-slots)))
 686
 687 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 688   (declare (ignore initargs))
 689   (find-class 'structure-direct-slot-definition))
 690
 691 (defmethod finalize-inheritance ((class structure-class))
 692   nil) ; always finalized
 693 \f
 694 (defun add-slot-accessors (class dslotds)
 695   (fix-slot-accessors class dslotds 'add))
 696
 697 (defun remove-slot-accessors (class dslotds)
 698   (fix-slot-accessors class dslotds 'remove))
 699
 700 (defun fix-slot-accessors (class dslotds add/remove)
 701   (flet ((fix (gfspec name r/w doc)
 702            (let ((gf (cond ((eq add/remove 'add)
 703                             (or (find-generic-function gfspec nil)
 704                                 (ensure-generic-function
 705                                  gfspec :lambda-list (case r/w
 706                                                        (r '(object))
 707                                                        (w '(new-value object))))))
 708                            (t
 709                             (find-generic-function gfspec nil)))))
 710              (when gf
 711                (case r/w
 712                  (r (if (eq add/remove 'add)
 713                         (add-reader-method class gf name doc)
 714                         (remove-reader-method class gf)))
 715                  (w (if (eq add/remove 'add)
 716                         (add-writer-method class gf name doc)
 717                         (remove-writer-method class gf))))))))
 718     (dolist (dslotd dslotds)
 719       (let ((slot-name (slot-definition-name dslotd))
 720             (slot-doc (%slot-definition-documentation dslotd)))
 721         (dolist (r (slot-definition-readers dslotd))
 722           (fix r slot-name 'r slot-doc))
 723         (dolist (w (slot-definition-writers dslotd))
 724           (fix w slot-name 'w slot-doc))))))
 725 \f
 726 (defun add-direct-subclasses (class supers)
 727   (dolist (super supers)
 728     (unless (memq class (class-direct-subclasses class))
 729       (add-direct-subclass super class))))
 730
 731 (defmethod finalize-inheritance ((class std-class))
 732   (update-class class t))
 733
 734 (defmethod finalize-inheritance ((class forward-referenced-class))
 735   ;; FIXME: should we not be thinking a bit about what kinds of error
 736   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 737   ;; possibly a forward-referenced-class-error, though that's
 738   ;; difficult given e.g. class precedence list calculations...
 739   (error
 740    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 741        ~2I~_~S~:>"
 742    class))
 743
 744 \f
 745 (defun class-has-a-forward-referenced-superclass-p (class)
 746   (or (forward-referenced-class-p class)
 747       (some #'class-has-a-forward-referenced-superclass-p
 748             (class-direct-superclasses class))))
 749
 750 ;;; This is called by :after shared-initialize whenever a class is initialized
 751 ;;; or reinitialized. The class may or may not be finalized.
 752 (defun update-class (class finalizep)
 753   (without-package-locks
 754     (when (or finalizep (class-finalized-p class))
 755       (update-cpl class (compute-class-precedence-list class))
 756       ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 757       ;; class.
 758       (update-slots class (compute-slots class))
 759       (update-gfs-of-class class)
 760       (update-initargs class (compute-default-initargs class))
 761       (update-ctors 'finalize-inheritance :class class))
 762     (dolist (sub (class-direct-subclasses class))
 763       (update-class sub nil))))
 764
 765 (define-condition cpl-protocol-violation (reference-condition error)
 766   ((class :initarg :class :reader cpl-protocol-violation-class)
 767    (cpl :initarg :cpl :reader cpl-protocol-violation-cpl))
 768   (:default-initargs :references (list '(:sbcl :node "Metaobject Protocol")))
 769   (:report
 770    (lambda (c s)
 771      (format s "~@<Protocol violation: the ~S class ~S ~
 772                 ~:[has~;does not have~] the class ~S in its ~
 773                 class precedence list: ~S.~@:>"
 774              (class-name (class-of (cpl-protocol-violation-class c)))
 775              (cpl-protocol-violation-class c)
 776              (eq (class-of (cpl-protocol-violation-class c))
 777                  *the-class-funcallable-standard-class*)
 778              (find-class 'function)
 779              (cpl-protocol-violation-cpl c)))))
 780
 781 (defun update-cpl (class cpl)
 782   (when (eq (class-of class) *the-class-standard-class*)
 783     (when (find (find-class 'function) cpl)
 784       (error 'cpl-protocol-violation :class class :cpl cpl)))
 785   (when (eq (class-of class) *the-class-funcallable-standard-class*)
 786     (unless (find (find-class 'function) cpl)
 787       (error 'cpl-protocol-violation :class class :cpl cpl)))
 788   (if (class-finalized-p class)
 789       (unless (and (equal (class-precedence-list class) cpl)
 790                    (dolist (c cpl t)
 791                      (when (position :class (class-direct-slots c)
 792                                      :key #'slot-definition-allocation)
 793                        (return nil))))
 794         ;; comment from the old CMU CL sources:
 795         ;;   Need to have the cpl setup before update-lisp-class-layout
 796         ;;   is called on CMU CL.
 797         (setf (slot-value class '%class-precedence-list) cpl)
 798         (setf (slot-value class 'cpl-available-p) t)
 799         (force-cache-flushes class))
 800       (progn
 801         (setf (slot-value class '%class-precedence-list) cpl)
 802         (setf (slot-value class 'cpl-available-p) t)))
 803   (update-class-can-precede-p cpl))
 804
 805 (defun update-class-can-precede-p (cpl)
 806   (when cpl
 807     (let ((first (car cpl)))
 808       (dolist (c (cdr cpl))
 809         (pushnew c (slot-value first 'can-precede-list))))
 810     (update-class-can-precede-p (cdr cpl))))
 811
 812 (defun class-can-precede-p (class1 class2)
 813   (member class2 (class-can-precede-list class1)))
 814
 815 (defun update-slots (class eslotds)
 816   (let ((instance-slots ())
 817         (class-slots    ()))
 818     (dolist (eslotd eslotds)
 819       (let ((alloc (slot-definition-allocation eslotd)))
 820         (case alloc
 821           (:instance (push eslotd instance-slots))
 822           (:class (push eslotd class-slots)))))
 823
 824     ;; If there is a change in the shape of the instances then the
 825     ;; old class is now obsolete.
 826     (let* ((nlayout (mapcar #'slot-definition-name
 827                             (sort instance-slots #'<
 828                                   :key #'slot-definition-location)))
 829            (nslots (length nlayout))
 830            (nwrapper-class-slots (compute-class-slots class-slots))
 831            (owrapper (when (class-finalized-p class)
 832                        (class-wrapper class)))
 833            (olayout (when owrapper
 834                       (wrapper-instance-slots-layout owrapper)))
 835            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 836            (nwrapper
 837             (cond ((null owrapper)
 838                    (make-wrapper nslots class))
 839                   ((and (equal nlayout olayout)
 840                         (not
 841                          (loop for o in owrapper-class-slots
 842                                for n in nwrapper-class-slots
 843                                do (unless (eq (car o) (car n)) (return t)))))
 844                    owrapper)
 845                   (t
 846                    ;; This will initialize the new wrapper to have the
 847                    ;; same state as the old wrapper. We will then have
 848                    ;; to change that. This may seem like wasted work
 849                    ;; (and it is), but the spec requires that we call
 850                    ;; MAKE-INSTANCES-OBSOLETE.
 851                    (make-instances-obsolete class)
 852                    (class-wrapper class)))))
 853
 854       (with-slots (wrapper slots) class
 855         (update-lisp-class-layout class nwrapper)
 856         (setf slots eslotds
 857               (wrapper-instance-slots-layout nwrapper) nlayout
 858               (wrapper-class-slots nwrapper) nwrapper-class-slots
 859               (layout-length nwrapper) nslots
 860               wrapper nwrapper)
 861         (do* ((slots (slot-value class 'slots) (cdr slots))
 862               (dupes nil))
 863              ((null slots)
 864               (when dupes
 865                 (style-warn
 866                  "~@<slot names with the same SYMBOL-NAME but ~
 867                   different SYMBOL-PACKAGE (possible package problem) ~
 868                   for class ~S:~4I~@:_~<~@{~S~^~:@_~}~:>~@:>"
 869                   class dupes)))
 870           (let* ((slot (car slots))
 871                  (oslots (remove (slot-definition-name slot) (cdr slots)
 872                                  :test #'string/=
 873                                  :key #'slot-definition-name)))
 874             (when oslots
 875               (pushnew (cons (slot-definition-name slot)
 876                              (mapcar #'slot-definition-name oslots))
 877                        dupes
 878                        :test #'string= :key #'car)))))
 879       (setf (slot-value class 'finalized-p) t)
 880       (unless (eq owrapper nwrapper)
 881         (update-pv-table-cache-info class)
 882         (maybe-update-standard-class-locations class)))))
 883
 884 (defun compute-class-slots (eslotds)
 885   (let (collect)
 886     (dolist (eslotd eslotds (nreverse collect))
 887       (let ((cell (assoc (slot-definition-name eslotd)
 888                          (class-slot-cells
 889                           (slot-definition-allocation-class eslotd)))))
 890         (aver cell)
 891         (push cell collect)))))
 892
 893 (defun update-gfs-of-class (class)
 894   (when (and (class-finalized-p class)
 895              (let ((cpl (class-precedence-list class)))
 896                (or (member *the-class-slot-class* cpl)
 897                    (member *the-class-standard-effective-slot-definition*
 898                            cpl))))
 899     (let ((gf-table (make-hash-table :test 'eq)))
 900       (labels ((collect-gfs (class)
 901                  (dolist (gf (specializer-direct-generic-functions class))
 902                    (setf (gethash gf gf-table) t))
 903                  (mapc #'collect-gfs (class-direct-superclasses class))))
 904         (collect-gfs class)
 905         (maphash (lambda (gf ignore)
 906                    (declare (ignore ignore))
 907                    (update-gf-dfun class gf))
 908                  gf-table)))))
 909
 910 (defun update-initargs (class inits)
 911   (setf (plist-value class 'default-initargs) inits))
 912 \f
 913 (defmethod compute-default-initargs ((class slot-class))
 914   (let ((initargs (loop for c in (class-precedence-list class)
 915                         append (class-direct-default-initargs c))))
 916     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
 917 \f
 918 ;;;; protocols for constructing direct and effective slot definitions
 919
 920 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
 921   (declare (ignore initargs))
 922   (find-class 'standard-direct-slot-definition))
 923
 924 (defun make-direct-slotd (class initargs)
 925   (apply #'make-instance
 926          (apply #'direct-slot-definition-class class initargs)
 927          :class class
 928          initargs))
 929
 930 ;;; I (CSR) am not sure, but I believe that the particular order of
 931 ;;; slots is quite important: it is ideal to attempt to have a
 932 ;;; constant slot location for the same notional slots as much as
 933 ;;; possible, so that clever discriminating functions (ONE-INDEX et
 934 ;;; al.) have a chance of working.  The below at least walks through
 935 ;;; the slots predictably, but maybe it would be good to compute some
 936 ;;; kind of optimal slot layout by looking at locations of slots in
 937 ;;; superclasses?
 938 (defun std-compute-slots (class)
 939   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 940   ;; for each different slot name we find in our superclasses. Each
 941   ;; call receives the class and a list of the dslotds with that name.
 942   ;; The list is in most-specific-first order.
 943   (let ((name-dslotds-alist ()))
 944     (dolist (c (reverse (class-precedence-list class)))
 945       (dolist (slot (class-direct-slots c))
 946         (let* ((name (slot-definition-name slot))
 947                (entry (assq name name-dslotds-alist)))
 948           (if entry
 949               (push slot (cdr entry))
 950               (push (list name slot) name-dslotds-alist)))))
 951     (mapcar (lambda (direct)
 952               (compute-effective-slot-definition class
 953                                                  (car direct)
 954                                                  (cdr direct)))
 955             (nreverse name-dslotds-alist))))
 956
 957 (defmethod compute-slots ((class standard-class))
 958   (std-compute-slots class))
 959 (defmethod compute-slots ((class funcallable-standard-class))
 960   (std-compute-slots class))
 961
 962 (defun std-compute-slots-around (class eslotds)
 963   (let ((location -1))
 964     (dolist (eslotd eslotds eslotds)
 965       (setf (slot-definition-location eslotd)
 966             (case (slot-definition-allocation eslotd)
 967               (:instance
 968                (incf location))
 969               (:class
 970                (let* ((name (slot-definition-name eslotd))
 971                       (from-class
 972                        (or
 973                         (slot-definition-allocation-class eslotd)
 974                         ;; we get here if the user adds an extra slot
 975                         ;; himself...
 976                         (setf (slot-definition-allocation-class eslotd)
 977                               class)))
 978                       ;; which raises the question of what we should
 979                       ;; do if we find that said user has added a slot
 980                       ;; with the same name as another slot...
 981                       (cell (or (assq name (class-slot-cells from-class))
 982                                 (let ((c (cons name +slot-unbound+)))
 983                                   (push c (class-slot-cells from-class))
 984                                   c))))
 985                  (aver (consp cell))
 986                  (if (eq +slot-unbound+ (cdr cell))
 987                      ;; We may have inherited an initfunction
 988                      (let ((initfun (slot-definition-initfunction eslotd)))
 989                        (if initfun
 990                            (rplacd cell (funcall initfun))
 991                            cell))
 992                      cell)))))
 993       (unless (slot-definition-class eslotd)
 994         (setf (slot-definition-class eslotd) class))
 995       (initialize-internal-slot-functions eslotd))))
 996
 997 (defmethod compute-slots :around ((class standard-class))
 998   (let ((eslotds (call-next-method)))
 999     (std-compute-slots-around class eslotds)))
1000 (defmethod compute-slots :around ((class funcallable-standard-class))
1001   (let ((eslotds (call-next-method)))
1002     (std-compute-slots-around class eslotds)))
1003
1004 (defmethod compute-slots ((class structure-class))
1005   (mapcan (lambda (superclass)
1006             (mapcar (lambda (dslotd)
1007                       (compute-effective-slot-definition
1008                        class
1009                        (slot-definition-name dslotd)
1010                        (list dslotd)))
1011                     (class-direct-slots superclass)))
1012           (reverse (slot-value class '%class-precedence-list))))
1013
1014 (defmethod compute-slots :around ((class structure-class))
1015   (let ((eslotds (call-next-method)))
1016     (mapc #'initialize-internal-slot-functions eslotds)
1017     eslotds))
1018
1019 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1020   (declare (ignore name))
1021   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1022          (class (apply #'effective-slot-definition-class class initargs)))
1023     (apply #'make-instance class initargs)))
1024
1025 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1026   (declare (ignore initargs))
1027   (find-class 'standard-effective-slot-definition))
1028
1029 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1030   (declare (ignore initargs))
1031   (find-class 'structure-effective-slot-definition))
1032
1033 (defmethod compute-effective-slot-definition-initargs
1034     ((class slot-class) direct-slotds)
1035   (let* ((name nil)
1036          (initfunction nil)
1037          (initform nil)
1038          (initargs nil)
1039          (allocation nil)
1040          (allocation-class nil)
1041          (type t)
1042          (type-check-function nil)
1043          (documentation nil)
1044          (documentationp nil)
1045          (namep  nil)
1046          (initp  nil)
1047          (allocp nil))
1048
1049     (dolist (slotd direct-slotds)
1050       (when slotd
1051         (unless namep
1052           (setq name (slot-definition-name slotd)
1053                 namep t))
1054         (unless initp
1055           (when (slot-definition-initfunction slotd)
1056             (setq initform (slot-definition-initform slotd)
1057                   initfunction (slot-definition-initfunction slotd)
1058                   initp t)))
1059         (unless documentationp
1060           (when (%slot-definition-documentation slotd)
1061             (setq documentation (%slot-definition-documentation slotd)
1062                   documentationp t)))
1063         (unless allocp
1064           (setq allocation (slot-definition-allocation slotd)
1065                 allocation-class (slot-definition-class slotd)
1066                 allocp t))
1067         (setq initargs (append (slot-definition-initargs slotd) initargs))
1068         (let ((fun (slot-definition-type-check-function slotd)))
1069           (when fun
1070             (setf type-check-function
1071                   (if type-check-function
1072                       (let ((old-function type-check-function))
1073                         (lambda (value)
1074                           (funcall old-function value)
1075                           (funcall fun value)))
1076                       fun))))
1077         (let ((slotd-type (slot-definition-type slotd)))
1078           (setq type (cond
1079                        ((eq type t) slotd-type)
1080                        ;; This pairwise type intersection is perhaps a
1081                        ;; little inefficient and inelegant, but it's
1082                        ;; unlikely to lie on the critical path.  Shout
1083                        ;; if I'm wrong.  -- CSR, 2005-11-24
1084                        (t (type-specifier
1085                            (specifier-type `(and ,type ,slotd-type)))))))))
1086     (list :name name
1087           :initform initform
1088           :initfunction initfunction
1089           :initargs initargs
1090           :allocation allocation
1091           :allocation-class allocation-class
1092           :type type
1093           'type-check-function type-check-function
1094           :class class
1095           :documentation documentation)))
1096
1097 (defmethod compute-effective-slot-definition-initargs :around
1098     ((class structure-class) direct-slotds)
1099   (let ((slotd (car direct-slotds)))
1100     (list* :defstruct-accessor-symbol
1101            (slot-definition-defstruct-accessor-symbol slotd)
1102            :internal-reader-function
1103            (slot-definition-internal-reader-function slotd)
1104            :internal-writer-function
1105            (slot-definition-internal-writer-function slotd)
1106            (call-next-method))))
1107 \f
1108 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1109 ;;;       to make the method object. They have to use make-a-method which
1110 ;;;       is a specially bootstrapped mechanism for making standard methods.
1111 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1112   (declare (ignore direct-slot initargs))
1113   (find-class 'standard-reader-method))
1114
1115 (defmethod add-reader-method ((class slot-class) generic-function slot-name slot-documentation)
1116   (add-method generic-function
1117               (make-a-method 'standard-reader-method
1118                              ()
1119                              (list (or (class-name class) 'object))
1120                              (list class)
1121                              (make-reader-method-function class slot-name)
1122                              (or slot-documentation "automatically generated reader method")
1123                              :slot-name slot-name
1124                              :object-class class
1125                              :method-class-function #'reader-method-class)))
1126
1127 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1128   (declare (ignore direct-slot initargs))
1129   (find-class 'standard-writer-method))
1130
1131 (defmethod add-writer-method ((class slot-class) generic-function slot-name slot-documentation)
1132   (add-method generic-function
1133               (make-a-method 'standard-writer-method
1134                              ()
1135                              (list 'new-value (or (class-name class) 'object))
1136                              (list *the-class-t* class)
1137                              (make-writer-method-function class slot-name)
1138                              (or slot-documentation "automatically generated writer method")
1139                              :slot-name slot-name
1140                              :object-class class
1141                              :method-class-function #'writer-method-class)))
1142
1143 (defmethod add-boundp-method ((class slot-class) generic-function slot-name slot-documentation)
1144   (add-method generic-function
1145               (make-a-method (constantly (find-class 'standard-boundp-method))
1146                              class
1147                              ()
1148                              (list (or (class-name class) 'object))
1149                              (list class)
1150                              (make-boundp-method-function class slot-name)
1151                              (or slot-documentation "automatically generated boundp method")
1152                              slot-name)))
1153
1154 (defmethod remove-reader-method ((class slot-class) generic-function)
1155   (let ((method (get-method generic-function () (list class) nil)))
1156     (when method (remove-method generic-function method))))
1157
1158 (defmethod remove-writer-method ((class slot-class) generic-function)
1159   (let ((method
1160           (get-method generic-function () (list *the-class-t* class) nil)))
1161     (when method (remove-method generic-function method))))
1162
1163 (defmethod remove-boundp-method ((class slot-class) generic-function)
1164   (let ((method (get-method generic-function () (list class) nil)))
1165     (when method (remove-method generic-function method))))
1166 \f
1167 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITER-METHOD-FUNCTION
1168 ;;; function are NOT part of the standard protocol. They are however
1169 ;;; useful; PCL makes use of them internally and documents them for
1170 ;;; PCL users.  (FIXME: but SBCL certainly doesn't)
1171 ;;;
1172 ;;; *** This needs work to make type testing by the writer functions which
1173 ;;; *** do type testing faster. The idea would be to have one constructor
1174 ;;; *** for each possible type test.
1175 ;;;
1176 ;;; *** There is a subtle bug here which is going to have to be fixed.
1177 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1178 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1179 ;;; *** defined for this metaclass a chance to run.
1180
1181 (defmethod make-reader-method-function ((class slot-class) slot-name)
1182   (make-std-reader-method-function class slot-name))
1183
1184 (defmethod make-writer-method-function ((class slot-class) slot-name)
1185   (make-std-writer-method-function class slot-name))
1186
1187 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1188   (make-std-boundp-method-function class slot-name))
1189 \f
1190 (defmethod compatible-meta-class-change-p (class proto-new-class)
1191   (eq (class-of class) (class-of proto-new-class)))
1192
1193 (defmethod validate-superclass ((class class) (superclass class))
1194   (or (eq superclass *the-class-t*)
1195       (eq (class-of class) (class-of superclass))
1196       (and (eq (class-of superclass) *the-class-standard-class*)
1197            (eq (class-of class) *the-class-funcallable-standard-class*))
1198       (and (eq (class-of superclass) *the-class-funcallable-standard-class*)
1199            (eq (class-of class) *the-class-standard-class*))))
1200 \f
1201 ;;; What this does depends on which of the four possible values of
1202 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1203 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1204 ;;; nothing to do, as the new wrapper has already been created.  If
1205 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1206 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1207 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1208 ;;;
1209 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1210 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1211 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1212 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1213 ;;; obsolete the wrapper.
1214 ;;;
1215 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1216 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1217 ;;;                    :UNINITIALIZED)))
1218 ;;;
1219 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1220 (defun force-cache-flushes (class)
1221   (let* ((owrapper (class-wrapper class)))
1222     ;; We only need to do something if the wrapper is still valid. If
1223     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1224     ;; both of those will already be doing what we want. In
1225     ;; particular, we must be sure we never change an OBSOLETE into a
1226     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1227     (when (or (not (invalid-wrapper-p owrapper))
1228               ;; KLUDGE: despite the observations above, this remains
1229               ;; a violation of locality or what might be considered
1230               ;; good style.  There has to be a better way!  -- CSR,
1231               ;; 2002-10-29
1232               (eq (layout-invalid owrapper) t))
1233       (let ((nwrapper (make-wrapper (layout-length owrapper)
1234                                     class)))
1235         (setf (wrapper-instance-slots-layout nwrapper)
1236               (wrapper-instance-slots-layout owrapper))
1237         (setf (wrapper-class-slots nwrapper)
1238               (wrapper-class-slots owrapper))
1239         (with-pcl-lock
1240           (update-lisp-class-layout class nwrapper)
1241           (setf (slot-value class 'wrapper) nwrapper)
1242           ;; Use :OBSOLETE instead of :FLUSH if any superclass has
1243           ;; been obsoleted.
1244           (if (find-if (lambda (x)
1245                          (and (consp x) (eq :obsolete (car x))))
1246                        (layout-inherits owrapper)
1247                        :key #'layout-invalid)
1248               (invalidate-wrapper owrapper :obsolete nwrapper)
1249               (invalidate-wrapper owrapper :flush nwrapper)))))))
1250
1251 (defun flush-cache-trap (owrapper nwrapper instance)
1252   (declare (ignore owrapper))
1253   (set-wrapper instance nwrapper))
1254 \f
1255 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1256 ;;; the next access to the instance (as defined in 88-002R) to trap
1257 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1258 (defmethod make-instances-obsolete ((class std-class))
1259   (let* ((owrapper (class-wrapper class))
1260          (nwrapper (make-wrapper (layout-length owrapper)
1261                                  class)))
1262     (unless (class-finalized-p class)
1263       (if (class-has-a-forward-referenced-superclass-p class)
1264           (return-from make-instances-obsolete class)
1265           (update-cpl class (compute-class-precedence-list class))))
1266     (setf (wrapper-instance-slots-layout nwrapper)
1267           (wrapper-instance-slots-layout owrapper))
1268     (setf (wrapper-class-slots nwrapper)
1269           (wrapper-class-slots owrapper))
1270     (with-pcl-lock
1271         (update-lisp-class-layout class nwrapper)
1272       (setf (slot-value class 'wrapper) nwrapper)
1273       (invalidate-wrapper owrapper :obsolete nwrapper)
1274       class)))
1275
1276 (defmethod make-instances-obsolete ((class symbol))
1277   (make-instances-obsolete (find-class class))
1278   ;; ANSI wants the class name when called with a symbol.
1279   class)
1280
1281 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1282 ;;; see an obsolete instance. The times when it is called are:
1283 ;;;   - when the instance is involved in method lookup
1284 ;;;   - when attempting to access a slot of an instance
1285 ;;;
1286 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1287 ;;; instance access macros.
1288 ;;;
1289 ;;; Of course these times when it is called are an internal
1290 ;;; implementation detail of PCL and are not part of the documented
1291 ;;; description of when the obsolete instance update happens. The
1292 ;;; documented description is as it appears in 88-002R.
1293 ;;;
1294 ;;; This has to return the new wrapper, so it counts on all the
1295 ;;; methods on obsolete-instance-trap-internal to return the new
1296 ;;; wrapper. It also does a little internal error checking to make
1297 ;;; sure that the traps are only happening when they should, and that
1298 ;;; the trap methods are computing appropriate new wrappers.
1299
1300 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1301 ;;; after a structure is redefined. In most cases,
1302 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1303 ;;; so it must signal an error. The hard part of this is that the
1304 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1305 ;;; called again, so in that case, we have to return some reasonable
1306 ;;; wrapper, instead.
1307
1308 (defvar *in-obsolete-instance-trap* nil)
1309 (defvar *the-wrapper-of-structure-object*
1310   (class-wrapper (find-class 'structure-object)))
1311
1312 (define-condition obsolete-structure (error)
1313   ((datum :reader obsolete-structure-datum :initarg :datum))
1314   (:report
1315    (lambda (condition stream)
1316      ;; Don't try to print the structure, since it probably won't work.
1317      (format stream
1318              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1319              (type-of (obsolete-structure-datum condition))))))
1320
1321 (defun obsolete-instance-trap (owrapper nwrapper instance)
1322   (if (not (pcl-instance-p instance))
1323       (if *in-obsolete-instance-trap*
1324           *the-wrapper-of-structure-object*
1325            (let ((*in-obsolete-instance-trap* t))
1326              (error 'obsolete-structure :datum instance)))
1327       (let* ((class (wrapper-class* nwrapper))
1328              (copy (allocate-instance class)) ;??? allocate-instance ???
1329              (olayout (wrapper-instance-slots-layout owrapper))
1330              (nlayout (wrapper-instance-slots-layout nwrapper))
1331              (oslots (get-slots instance))
1332              (nslots (get-slots copy))
1333              (oclass-slots (wrapper-class-slots owrapper))
1334              (added ())
1335              (discarded ())
1336              (plist ()))
1337
1338         ;; local  --> local     transfer value
1339         ;; local  --> shared    discard value, discard slot
1340         ;; local  -->  --       discard slot
1341         ;; shared --> local     transfer value
1342         ;; shared --> shared    -- (cf SHARED-INITIALIZE :AFTER STD-CLASS)
1343         ;; shared -->  --       discard value
1344         ;;  --    --> local     add slot
1345         ;;  --    --> shared    --
1346
1347         ;; Go through all the old local slots.
1348         (let ((opos 0))
1349           (dolist (name olayout)
1350             (let ((npos (posq name nlayout)))
1351               (if npos
1352                   (setf (clos-slots-ref nslots npos)
1353                         (clos-slots-ref oslots opos))
1354                   (progn
1355                     (push name discarded)
1356                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1357                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1358             (incf opos)))
1359
1360         ;; Go through all the old shared slots.
1361         (dolist (oclass-slot-and-val oclass-slots)
1362           (let ((name (car oclass-slot-and-val))
1363                 (val (cdr oclass-slot-and-val)))
1364             (let ((npos (posq name nlayout)))
1365               (when npos
1366                 (setf (clos-slots-ref nslots npos) val)))))
1367
1368         ;; Go through all the new local slots to compute the added slots.
1369         (dolist (nlocal nlayout)
1370           (unless (or (memq nlocal olayout)
1371                       (assq nlocal oclass-slots))
1372             (push nlocal added)))
1373
1374         (swap-wrappers-and-slots instance copy)
1375
1376         (update-instance-for-redefined-class instance
1377                                              added
1378                                              discarded
1379                                              plist)
1380         nwrapper)))
1381 \f
1382 (defun change-class-internal (instance new-class initargs)
1383   (let* ((old-class (class-of instance))
1384          (copy (allocate-instance new-class))
1385          (new-wrapper (get-wrapper copy))
1386          (old-wrapper (class-wrapper old-class))
1387          (old-layout (wrapper-instance-slots-layout old-wrapper))
1388          (new-layout (wrapper-instance-slots-layout new-wrapper))
1389          (old-slots (get-slots instance))
1390          (new-slots (get-slots copy))
1391          (old-class-slots (wrapper-class-slots old-wrapper)))
1392
1393     ;; "The values of local slots specified by both the class CTO and
1394     ;; CFROM are retained. If such a local slot was unbound, it
1395     ;; remains unbound."
1396     (let ((new-position 0))
1397       (dolist (new-slot new-layout)
1398         (let ((old-position (posq new-slot old-layout)))
1399           (when old-position
1400             (setf (clos-slots-ref new-slots new-position)
1401                   (clos-slots-ref old-slots old-position))))
1402         (incf new-position)))
1403
1404     ;; "The values of slots specified as shared in the class CFROM and
1405     ;; as local in the class CTO are retained."
1406     (dolist (slot-and-val old-class-slots)
1407       (let ((position (posq (car slot-and-val) new-layout)))
1408         (when position
1409           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1410
1411     ;; Make the copy point to the old instance's storage, and make the
1412     ;; old instance point to the new storage.
1413     (swap-wrappers-and-slots instance copy)
1414
1415     (apply #'update-instance-for-different-class copy instance initargs)
1416     instance))
1417
1418 (defmethod change-class ((instance standard-object) (new-class standard-class)
1419                          &rest initargs)
1420   (unless (class-finalized-p new-class)
1421     (finalize-inheritance new-class))
1422   (let ((cpl (class-precedence-list new-class)))
1423     (dolist (class cpl)
1424       (macrolet
1425           ((frob (class-name)
1426              `(when (eq class (find-class ',class-name))
1427                (error 'metaobject-initialization-violation
1428                 :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1429                 :format-arguments (list 'change-class ',class-name)
1430                 :references (list '(:amop :initialization ,class-name))))))
1431         (frob class)
1432         (frob generic-function)
1433         (frob method)
1434         (frob slot-definition))))
1435   (change-class-internal instance new-class initargs))
1436
1437 (defmethod change-class ((instance forward-referenced-class)
1438                          (new-class standard-class) &rest initargs)
1439   (let ((cpl (class-precedence-list new-class)))
1440     (dolist (class cpl
1441              (error 'metaobject-initialization-violation
1442                     :format-control
1443                     "~@<Cannot ~S ~S objects into non-~S objects.~@:>"
1444                     :format-arguments
1445                     (list 'change-class 'forward-referenced-class 'class)
1446                     :references
1447                     (list '(:amop :generic-function ensure-class-using-class)
1448                           '(:amop :initialization class))))
1449       (when (eq class (find-class 'class))
1450         (return nil))))
1451   (change-class-internal instance new-class initargs))
1452
1453 (defmethod change-class ((instance funcallable-standard-object)
1454                          (new-class funcallable-standard-class)
1455                          &rest initargs)
1456   (let ((cpl (class-precedence-list new-class)))
1457     (dolist (class cpl)
1458       (macrolet
1459           ((frob (class-name)
1460              `(when (eq class (find-class ',class-name))
1461                (error 'metaobject-initialization-violation
1462                 :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1463                 :format-arguments (list 'change-class ',class-name)
1464                 :references (list '(:amop :initialization ,class-name))))))
1465         (frob class)
1466         (frob generic-function)
1467         (frob method)
1468         (frob slot-definition))))
1469   (change-class-internal instance new-class initargs))
1470
1471 (defmethod change-class ((instance standard-object)
1472                          (new-class funcallable-standard-class)
1473                          &rest initargs)
1474   (declare (ignore initargs))
1475   (error "You can't change the class of ~S to ~S~@
1476           because it isn't already an instance with metaclass ~S."
1477          instance new-class 'standard-class))
1478
1479 (defmethod change-class ((instance funcallable-standard-object)
1480                          (new-class standard-class)
1481                          &rest initargs)
1482   (declare (ignore initargs))
1483   (error "You can't change the class of ~S to ~S~@
1484           because it isn't already an instance with metaclass ~S."
1485          instance new-class 'funcallable-standard-class))
1486
1487 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1488   (apply #'change-class instance (find-class new-class-name) initargs))
1489 \f
1490 ;;;; The metaclass BUILT-IN-CLASS
1491 ;;;;
1492 ;;;; This metaclass is something of a weird creature. By this point, all
1493 ;;;; instances of it which will exist have been created, and no instance
1494 ;;;; is ever created by calling MAKE-INSTANCE.
1495 ;;;;
1496 ;;;; But, there are other parts of the protocol we must follow and those
1497 ;;;; definitions appear here.
1498
1499 (macrolet ((def (name args control)
1500                `(defmethod ,name ,args
1501                  (declare (ignore initargs))
1502                  (error 'metaobject-initialization-violation
1503                   :format-control ,(format nil "~@<~A~@:>" control)
1504                   :format-arguments (list ',name)
1505                   :references (list '(:amop :initialization "Class"))))))
1506   (def initialize-instance ((class built-in-class) &rest initargs)
1507     "Cannot ~S an instance of BUILT-IN-CLASS.")
1508   (def reinitialize-instance ((class built-in-class) &rest initargs)
1509     "Cannot ~S an instance of BUILT-IN-CLASS."))
1510
1511 (macrolet ((def (name)
1512                `(defmethod ,name ((class built-in-class)) nil)))
1513   (def class-direct-slots)
1514   (def class-slots)
1515   (def class-direct-default-initargs)
1516   (def class-default-initargs))
1517
1518 (defmethod validate-superclass ((c class) (s built-in-class))
1519   (or (eq s *the-class-t*) (eq s *the-class-stream*)
1520       ;; FIXME: bad things happen if someone tries to mix in both
1521       ;; FILE-STREAM and STRING-STREAM (as they have the same
1522       ;; layout-depthoid).  Is there any way we can provide a useful
1523       ;; error message?  -- CSR, 2005-05-03
1524       (eq s *the-class-file-stream*) (eq s *the-class-string-stream*)
1525       ;; This probably shouldn't be mixed in with certain other
1526       ;; classes, too, but it seems to work both with STANDARD-OBJECT
1527       ;; and FUNCALLABLE-STANDARD-OBJECT
1528       (eq s *the-class-sequence*)))
1529 \f
1530 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1531 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1532 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1533 (macrolet ((def (method)
1534              `(defmethod ,method ((class forward-referenced-class))
1535                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1536                        ',method class))))
1537   (def class-default-initargs)
1538   (def class-precedence-list)
1539   (def class-slots))
1540
1541 (defmethod validate-superclass ((c slot-class)
1542                                 (f forward-referenced-class))
1543   t)
1544 \f
1545 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1546   (pushnew dependent (plist-value metaobject 'dependents)))
1547
1548 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1549   (setf (plist-value metaobject 'dependents)
1550         (delete dependent (plist-value metaobject 'dependents))))
1551
1552 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1553   (dolist (dependent (plist-value metaobject 'dependents))
1554     (funcall function dependent)))
1555