src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd 'class)))
  76     (let ((table (or (gethash name *name->class->slotd-table*)
  77                      (setf (gethash name *name->class->slotd-table*)
  78                            (make-hash-table :test 'eq :size 5)))))
  79       (setf (gethash class table) slotd))
  80     (dolist (type '(reader writer boundp))
  81       (let* ((gf-name (ecase type
  82                               (reader 'slot-value-using-class)
  83                               (writer '(setf slot-value-using-class))
  84                               (boundp 'slot-boundp-using-class)))
  85              (gf (gdefinition gf-name)))
  86         (compute-slot-accessor-info slotd type gf)))
  87     (initialize-internal-slot-gfs name)))
  88
  89 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  90                                        type gf)
  91   (let* ((name (slot-value slotd 'name))
  92          (class (slot-value slotd 'class))
  93          (old-slotd (find-slot-definition class name))
  94          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
  95     (multiple-value-bind (function std-p)
  96         (if (eq *boot-state* 'complete)
  97             (get-accessor-method-function gf type class slotd)
  98             (get-optimized-std-accessor-method-function class slotd type))
  99       (setf (slot-accessor-std-p slotd type) std-p)
 100       (setf (slot-accessor-function slotd type) function))
 101     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 102       (push (cons class name) *pv-table-cache-update-info*))))
 103
 104 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 105   :instance)
 106 \f
 107 (defmethod shared-initialize :after ((object documentation-mixin)
 108                                      slot-names
 109                                      &key (documentation nil documentation-p))
 110   (declare (ignore slot-names))
 111   (when documentation-p
 112     (setf (plist-value object 'documentation) documentation)))
 113
 114 ;;; default if DOC-TYPE doesn't match one of the specified types
 115 (defmethod documentation (object doc-type)
 116   (warn "unsupported DOCUMENTATION: type ~S for object ~S"
 117         doc-type
 118         (type-of object))
 119   nil)
 120
 121 ;;; default if DOC-TYPE doesn't match one of the specified types
 122 (defmethod (setf documentation) (new-value object doc-type)
 123   ;; CMU CL made this an error, but since ANSI says that even for supported
 124   ;; doc types an implementation is permitted to discard docs at any time
 125   ;; for any reason, this feels to me more like a warning. -- WHN 19991214
 126   (warn "discarding unsupported DOCUMENTATION of type ~S for object ~S"
 127         doc-type
 128         (type-of object))
 129   new-value)
 130
 131 (defmethod documentation ((object documentation-mixin) doc-type)
 132   (declare (ignore doc-type))
 133   (plist-value object 'documentation))
 134
 135 (defmethod (setf documentation) (new-value
 136                                  (object documentation-mixin)
 137                                  doc-type)
 138   (declare (ignore doc-type))
 139   (setf (plist-value object 'documentation) new-value))
 140
 141 (defmethod documentation ((slotd standard-slot-definition) doc-type)
 142   (declare (ignore doc-type))
 143   (slot-value slotd 'documentation))
 144
 145 (defmethod (setf documentation) (new-value
 146                                  (slotd standard-slot-definition)
 147                                  doc-type)
 148   (declare (ignore doc-type))
 149   (setf (slot-value slotd 'documentation) new-value))
 150 \f
 151 ;;;; various class accessors that are a little more complicated than can be
 152 ;;;; done with automatically generated reader methods
 153
 154 (defmethod class-finalized-p ((class pcl-class))
 155   (with-slots (wrapper) class
 156     (not (null wrapper))))
 157
 158 (defmethod class-prototype ((class std-class))
 159   (with-slots (prototype) class
 160     (or prototype (setq prototype (allocate-instance class)))))
 161
 162 (defmethod class-prototype ((class structure-class))
 163   (with-slots (prototype wrapper defstruct-constructor) class
 164     (or prototype
 165         (setq prototype
 166               (if defstruct-constructor
 167                   (allocate-instance class)
 168                   (allocate-standard-instance wrapper))))))
 169
 170 (defmethod class-direct-default-initargs ((class slot-class))
 171   (plist-value class 'direct-default-initargs))
 172
 173 (defmethod class-default-initargs ((class slot-class))
 174   (plist-value class 'default-initargs))
 175
 176 (defmethod class-slot-cells ((class std-class))
 177   (plist-value class 'class-slot-cells))
 178 \f
 179 ;;;; class accessors that are even a little bit more complicated than those
 180 ;;;; above. These have a protocol for updating them, we must implement that
 181 ;;;; protocol.
 182
 183 ;;; Maintaining the direct subclasses backpointers. The update methods are
 184 ;;; here, the values are read by an automatically generated reader method.
 185 (defmethod add-direct-subclass ((class class) (subclass class))
 186   (with-slots (direct-subclasses) class
 187     (pushnew subclass direct-subclasses)
 188     subclass))
 189 (defmethod remove-direct-subclass ((class class) (subclass class))
 190   (with-slots (direct-subclasses) class
 191     (setq direct-subclasses (remove subclass direct-subclasses))
 192     subclass))
 193
 194 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 195 ;;;
 196 ;;; There are four generic functions involved, each has one method for the
 197 ;;; class case and another method for the damned EQL specializers. All of
 198 ;;; these are specified methods and appear in their specified place in the
 199 ;;; class graph.
 200 ;;;
 201 ;;;   ADD-DIRECT-METHOD
 202 ;;;   REMOVE-DIRECT-METHOD
 203 ;;;   SPECIALIZER-DIRECT-METHODS
 204 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 205 ;;;
 206 ;;; In each case, we maintain one value which is a cons. The car is the list
 207 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 208 ;;; computed lazily.
 209 (defmethod add-direct-method ((specializer class) (method method))
 210   (with-slots (direct-methods) specializer
 211     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 212           (cdr direct-methods) ()))
 213   method)
 214 (defmethod remove-direct-method ((specializer class) (method method))
 215   (with-slots (direct-methods) specializer
 216     (setf (car direct-methods) (remove method (car direct-methods))
 217           (cdr direct-methods) ()))
 218   method)
 219
 220 (defmethod specializer-direct-methods ((specializer class))
 221   (with-slots (direct-methods) specializer
 222     (car direct-methods)))
 223
 224 (defmethod specializer-direct-generic-functions ((specializer class))
 225   (with-slots (direct-methods) specializer
 226     (or (cdr direct-methods)
 227         (setf (cdr direct-methods)
 228               (let (collect)
 229                 (dolist (m (car direct-methods))
 230                   ;; the old PCL code used COLLECTING-ONCE which used
 231                   ;; #'EQ to check for newness
 232                   (pushnew (method-generic-function m) collect :test #'eq))
 233                 (nreverse collect))))))
 234 \f
 235 ;;; This hash table is used to store the direct methods and direct generic
 236 ;;; functions of EQL specializers. Each value in the table is the cons.
 237 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 238 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 239
 240 (defmethod specializer-method-table ((specializer eql-specializer))
 241   *eql-specializer-methods*)
 242
 243 (defmethod specializer-method-table ((specializer class-eq-specializer))
 244   *class-eq-specializer-methods*)
 245
 246 (defmethod add-direct-method ((specializer specializer-with-object)
 247                               (method method))
 248   (let* ((object (specializer-object specializer))
 249          (table (specializer-method-table specializer))
 250          (entry (gethash object table)))
 251     (unless entry
 252       (setq entry
 253             (setf (gethash object table)
 254                   (cons nil nil))))
 255     (setf (car entry) (adjoin method (car entry))
 256           (cdr entry) ())
 257     method))
 258
 259 (defmethod remove-direct-method ((specializer specializer-with-object)
 260                                  (method method))
 261   (let* ((object (specializer-object specializer))
 262          (entry (gethash object (specializer-method-table specializer))))
 263     (when entry
 264       (setf (car entry) (remove method (car entry))
 265             (cdr entry) ()))
 266     method))
 267
 268 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 269   (car (gethash (specializer-object specializer)
 270                 (specializer-method-table specializer))))
 271
 272 (defmethod specializer-direct-generic-functions ((specializer
 273                                                   specializer-with-object))
 274   (let* ((object (specializer-object specializer))
 275          (entry (gethash object (specializer-method-table specializer))))
 276     (when entry
 277       (or (cdr entry)
 278           (setf (cdr entry)
 279                 (let (collect)
 280                   (dolist (m (car entry))
 281                     (pushnew (method-generic-function m) collect :test #'eq))
 282                   (nreverse collect)))))))
 283
 284 (defun map-specializers (function)
 285   (map-all-classes (lambda (class)
 286                      (funcall function (class-eq-specializer class))
 287                      (funcall function class)))
 288   (maphash (lambda (object methods)
 289              (declare (ignore methods))
 290              (intern-eql-specializer object))
 291            *eql-specializer-methods*)
 292   (maphash (lambda (object specl)
 293              (declare (ignore object))
 294              (funcall function specl))
 295            *eql-specializer-table*)
 296   nil)
 297
 298 (defun map-all-generic-functions (function)
 299   (let ((all-generic-functions (make-hash-table :test 'eq)))
 300     (map-specializers (lambda (specl)
 301                         (dolist (gf (specializer-direct-generic-functions
 302                                      specl))
 303                           (unless (gethash gf all-generic-functions)
 304                             (setf (gethash gf all-generic-functions) t)
 305                             (funcall function gf))))))
 306   nil)
 307
 308 (defmethod shared-initialize :after ((specl class-eq-specializer)
 309                                      slot-names
 310                                      &key)
 311   (declare (ignore slot-names))
 312   (setf (slot-value specl 'type) `(class-eq ,(specializer-class specl))))
 313
 314 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 315   (declare (ignore slot-names))
 316   (setf (slot-value specl 'type) `(eql ,(specializer-object specl))))
 317 \f
 318 (defun real-load-defclass (name metaclass-name supers slots other)
 319   (let ((res (apply #'ensure-class name :metaclass metaclass-name
 320                     :direct-superclasses supers
 321                     :direct-slots slots
 322                     :definition-source `((defclass ,name)
 323                                          ,*load-truename*)
 324                     other)))
 325     ;; Defclass of a class with a forward-referenced superclass does not
 326     ;; have a wrapper. RES is the incomplete PCL class. The Lisp class
 327     ;; does not yet exist. Maybe should return NIL in that case as RES
 328     ;; is not useful to the user?
 329     (and (class-wrapper res) (sb-kernel:layout-class (class-wrapper res)))))
 330
 331 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 332
 333 (defun ensure-class (name &rest all)
 334   (apply #'ensure-class-using-class name (find-class name nil) all))
 335
 336 (defmethod ensure-class-using-class (name (class null) &rest args &key)
 337   (multiple-value-bind (meta initargs)
 338       (ensure-class-values class args)
 339     (setf class (apply #'make-instance meta :name name initargs)
 340           (find-class name) class)
 341     class))
 342
 343 (defmethod ensure-class-using-class (name (class pcl-class) &rest args &key)
 344   (multiple-value-bind (meta initargs)
 345       (ensure-class-values class args)
 346     (unless (eq (class-of class) meta) (change-class class meta))
 347     (apply #'reinitialize-instance class initargs)
 348     (setf (find-class name) class)
 349     class))
 350
 351 (defmethod class-predicate-name ((class t))
 352   'constantly-nil)
 353
 354 (defun fix-super (s)
 355   (cond ((classp s) s)
 356         ((not (legal-class-name-p s))
 357           (error "~S is not a class or a legal class name." s))
 358         (t
 359           (or (find-class s nil)
 360               (setf (find-class s)
 361                       (make-instance 'forward-referenced-class
 362                                      :name s))))))
 363
 364 (defun ensure-class-values (class args)
 365   (let* ((initargs (copy-list args))
 366          (unsupplied (list 1))
 367          (supplied-meta   (getf initargs :metaclass unsupplied))
 368          (supplied-supers (getf initargs :direct-superclasses unsupplied))
 369          (supplied-slots  (getf initargs :direct-slots unsupplied))
 370          (meta
 371            (cond ((neq supplied-meta unsupplied)
 372                   (find-class supplied-meta))
 373                  ((or (null class)
 374                       (forward-referenced-class-p class))
 375                   *the-class-standard-class*)
 376                  (t
 377                   (class-of class)))))
 378     (loop (unless (remf initargs :metaclass) (return)))
 379     (loop (unless (remf initargs :direct-superclasses) (return)))
 380     (loop (unless (remf initargs :direct-slots) (return)))
 381     (values meta
 382             (list* :direct-superclasses
 383                    (and (neq supplied-supers unsupplied)
 384                         (mapcar #'fix-super supplied-supers))
 385                    :direct-slots
 386                    (and (neq supplied-slots unsupplied) supplied-slots)
 387                    initargs))))
 388 \f
 389
 390 (defmethod shared-initialize :after
 391            ((class std-class)
 392             slot-names
 393             &key (direct-superclasses nil direct-superclasses-p)
 394                  (direct-slots nil direct-slots-p)
 395                  (direct-default-initargs nil direct-default-initargs-p)
 396                  (predicate-name nil predicate-name-p))
 397   (declare (ignore slot-names))
 398   (cond (direct-superclasses-p
 399          (setq direct-superclasses
 400                (or direct-superclasses
 401                    (list (if (funcallable-standard-class-p class)
 402                              *the-class-funcallable-standard-object*
 403                              *the-class-standard-object*))))
 404          (dolist (superclass direct-superclasses)
 405            (unless (validate-superclass class superclass)
 406              (error "The class ~S was specified as a~%
 407                      super-class of the class ~S;~%~
 408                      but the meta-classes ~S and~%~S are incompatible.~@
 409                      Define a method for ~S to avoid this error."
 410                      superclass class (class-of superclass) (class-of class)
 411                      'validate-superclass)))
 412          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 413         (t
 414          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 415   (setq direct-slots
 416         (if direct-slots-p
 417             (setf (slot-value class 'direct-slots)
 418                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 419                           direct-slots))
 420             (slot-value class 'direct-slots)))
 421   (if direct-default-initargs-p
 422       (setf (plist-value class 'direct-default-initargs)
 423             direct-default-initargs)
 424       (setq direct-default-initargs
 425             (plist-value class 'direct-default-initargs)))
 426   (setf (plist-value class 'class-slot-cells)
 427         (let (collect)
 428           (dolist (dslotd direct-slots)
 429             (when (eq (slot-definition-allocation dslotd) class)
 430               (let ((initfunction (slot-definition-initfunction dslotd)))
 431                 (push (cons (slot-definition-name dslotd)
 432                                (if initfunction
 433                                    (funcall initfunction)
 434                                    +slot-unbound+))
 435                       collect))))
 436           (nreverse collect)))
 437   (setq predicate-name (if predicate-name-p
 438                            (setf (slot-value class 'predicate-name)
 439                                  (car predicate-name))
 440                            (or (slot-value class 'predicate-name)
 441                                (setf (slot-value class 'predicate-name)
 442                                      (make-class-predicate-name (class-name
 443                                                                  class))))))
 444   (add-direct-subclasses class direct-superclasses)
 445   (update-class class nil)
 446   (make-class-predicate class predicate-name)
 447   (add-slot-accessors class direct-slots))
 448
 449 (defmethod shared-initialize :before ((class class) slot-names &key name)
 450   (declare (ignore slot-names name))
 451   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 452   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 453   (setf (slot-value class 'type) `(class ,class))
 454   (setf (slot-value class 'class-eq-specializer)
 455         (make-instance 'class-eq-specializer :class class)))
 456
 457 (defmethod reinitialize-instance :before ((class slot-class) &key)
 458   (remove-direct-subclasses class (class-direct-superclasses class))
 459   (remove-slot-accessors    class (class-direct-slots class)))
 460
 461 (defmethod reinitialize-instance :after ((class slot-class)
 462                                          &rest initargs
 463                                          &key)
 464   (map-dependents class
 465                   (lambda (dependent)
 466                     (apply #'update-dependent class dependent initargs))))
 467
 468 (defmethod shared-initialize :after ((slotd standard-slot-definition)
 469                                      slot-names &key)
 470   (declare (ignore slot-names))
 471   (with-slots (allocation class)
 472     slotd
 473     (setq allocation (if (eq allocation :class) class allocation))))
 474
 475 (defmethod shared-initialize :after ((slotd structure-slot-definition)
 476                                      slot-names
 477                                      &key (allocation :instance))
 478   (declare (ignore slot-names))
 479   (unless (eq allocation :instance)
 480     (error "Structure slots must have :INSTANCE allocation.")))
 481
 482 (defun make-structure-class-defstruct-form (name direct-slots include)
 483   (let* ((conc-name (intern (format nil "~S structure class " name)))
 484          (constructor (intern (format nil "~A constructor" conc-name)))
 485          (defstruct `(defstruct (,name
 486                                  ,@(when include
 487                                          `((:include ,(class-name include))))
 488                                  (:print-function print-std-instance)
 489                                  (:predicate nil)
 490                                  (:conc-name ,conc-name)
 491                                  (:constructor ,constructor ())
 492                                  (:copier nil))
 493                       ,@(mapcar (lambda (slot)
 494                                   `(,(slot-definition-name slot)
 495                                     +slot-unbound+))
 496                                 direct-slots)))
 497          (reader-names (mapcar (lambda (slotd)
 498                                  (intern (format nil
 499                                                  "~A~A reader"
 500                                                  conc-name
 501                                                  (slot-definition-name
 502                                                   slotd))))
 503                                direct-slots))
 504          (writer-names (mapcar (lambda (slotd)
 505                                  (intern (format nil
 506                                                  "~A~A writer"
 507                                                  conc-name
 508                                                  (slot-definition-name
 509                                                   slotd))))
 510                                direct-slots))
 511          (readers-init
 512            (mapcar (lambda (slotd reader-name)
 513                      (let ((accessor
 514                              (slot-definition-defstruct-accessor-symbol
 515                               slotd)))
 516                        `(defun ,reader-name (obj)
 517                          (declare (type ,name obj))
 518                          (,accessor obj))))
 519                    direct-slots reader-names))
 520          (writers-init
 521            (mapcar (lambda (slotd writer-name)
 522                      (let ((accessor
 523                              (slot-definition-defstruct-accessor-symbol
 524                               slotd)))
 525                        `(defun ,writer-name (nv obj)
 526                          (declare (type ,name obj))
 527                          (setf (,accessor obj) nv))))
 528                    direct-slots writer-names))
 529          (defstruct-form
 530              `(progn
 531                ,defstruct
 532                ,@readers-init ,@writers-init
 533                (cons nil nil))))
 534     (values defstruct-form constructor reader-names writer-names)))
 535
 536 (defmethod shared-initialize :after
 537       ((class structure-class)
 538        slot-names
 539        &key (direct-superclasses nil direct-superclasses-p)
 540             (direct-slots nil direct-slots-p)
 541             direct-default-initargs
 542             (predicate-name nil predicate-name-p))
 543   (declare (ignore slot-names direct-default-initargs))
 544   (if direct-superclasses-p
 545       (setf (slot-value class 'direct-superclasses)
 546             (or direct-superclasses
 547                 (setq direct-superclasses
 548                       (and (not (eq (class-name class) 'structure-object))
 549                            (list *the-class-structure-object*)))))
 550       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 551   (let* ((name (class-name class))
 552          (from-defclass-p (slot-value class 'from-defclass-p))
 553          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 554     (if direct-slots-p
 555         (setf (slot-value class 'direct-slots)
 556               (setq direct-slots
 557                     (mapcar (lambda (pl)
 558                               (when defstruct-p
 559                                 (let* ((slot-name (getf pl :name))
 560                                        (acc-name
 561                                         (format nil
 562                                                 "~S structure class ~A"
 563                                                 name slot-name))
 564                                        (accessor (intern acc-name)))
 565                                   (setq pl (list* :defstruct-accessor-symbol
 566                                                   accessor pl))))
 567                               (make-direct-slotd class pl))
 568                             direct-slots)))
 569         (setq direct-slots (slot-value class 'direct-slots)))
 570     (when defstruct-p
 571       (let ((include (car (slot-value class 'direct-superclasses))))
 572         (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 573             (make-structure-class-defstruct-form name direct-slots include)
 574           (unless (structure-type-p name) (eval defstruct-form))
 575           (mapc (lambda (dslotd reader-name writer-name)
 576                   (let* ((reader (gdefinition reader-name))
 577                          (writer (when (gboundp writer-name)
 578                                    (gdefinition writer-name))))
 579                     (setf (slot-value dslotd 'internal-reader-function)
 580                           reader)
 581                     (setf (slot-value dslotd 'internal-writer-function)
 582                           writer)))
 583                 direct-slots reader-names writer-names)
 584           (setf (slot-value class 'defstruct-form) defstruct-form)
 585           (setf (slot-value class 'defstruct-constructor) constructor))))
 586     (add-direct-subclasses class direct-superclasses)
 587     (setf (slot-value class 'class-precedence-list)
 588             (compute-class-precedence-list class))
 589     (setf (slot-value class 'slots) (compute-slots class))
 590     (let ((lclass (cl:find-class (class-name class))))
 591       (setf (sb-kernel:class-pcl-class lclass) class)
 592       (setf (slot-value class 'wrapper) (sb-kernel:class-layout lclass)))
 593     (update-pv-table-cache-info class)
 594     (setq predicate-name (if predicate-name-p
 595                            (setf (slot-value class 'predicate-name)
 596                                    (car predicate-name))
 597                            (or (slot-value class 'predicate-name)
 598                                (setf (slot-value class 'predicate-name)
 599                                        (make-class-predicate-name
 600                                         (class-name class))))))
 601     (make-class-predicate class predicate-name)
 602     (add-slot-accessors class direct-slots)))
 603
 604 (defmethod direct-slot-definition-class ((class structure-class) initargs)
 605   (declare (ignore initargs))
 606   (find-class 'structure-direct-slot-definition))
 607
 608 (defmethod finalize-inheritance ((class structure-class))
 609   nil) ; always finalized
 610 \f
 611 (defun add-slot-accessors (class dslotds)
 612   (fix-slot-accessors class dslotds 'add))
 613
 614 (defun remove-slot-accessors (class dslotds)
 615   (fix-slot-accessors class dslotds 'remove))
 616
 617 (defun fix-slot-accessors (class dslotds add/remove)
 618   (flet ((fix (gfspec name r/w)
 619            (let ((gf (ensure-generic-function gfspec)))
 620              (case r/w
 621                (r (if (eq add/remove 'add)
 622                       (add-reader-method class gf name)
 623                       (remove-reader-method class gf)))
 624                (w (if (eq add/remove 'add)
 625                       (add-writer-method class gf name)
 626                       (remove-writer-method class gf)))))))
 627     (dolist (dslotd dslotds)
 628       (let ((slot-name (slot-definition-name dslotd)))
 629         (dolist (r (slot-definition-readers dslotd)) (fix r slot-name 'r))
 630         (dolist (w (slot-definition-writers dslotd)) (fix w slot-name 'w))))))
 631 \f
 632 (defun add-direct-subclasses (class supers)
 633   (dolist (super supers)
 634     (unless (memq class (class-direct-subclasses class))
 635       (add-direct-subclass super class))))
 636
 637 (defun remove-direct-subclasses (class supers)
 638   (let ((old (class-direct-superclasses class)))
 639     (dolist (o (set-difference old supers))
 640       (remove-direct-subclass o class))))
 641 \f
 642 (defmethod finalize-inheritance ((class std-class))
 643   (update-class class t))
 644 \f
 645 (defun class-has-a-forward-referenced-superclass-p (class)
 646   (or (forward-referenced-class-p class)
 647       (some #'class-has-a-forward-referenced-superclass-p
 648             (class-direct-superclasses class))))
 649
 650 ;;; This is called by :after shared-initialize whenever a class is initialized
 651 ;;; or reinitialized. The class may or may not be finalized.
 652 (defun update-class (class finalizep)
 653   (when (or finalizep (class-finalized-p class)
 654             (not (class-has-a-forward-referenced-superclass-p class)))
 655     (update-cpl class (compute-class-precedence-list class))
 656     (update-slots class (compute-slots class))
 657     (update-gfs-of-class class)
 658     (update-inits class (compute-default-initargs class))
 659     (update-make-instance-function-table class))
 660   (unless finalizep
 661     (dolist (sub (class-direct-subclasses class)) (update-class sub nil))))
 662
 663 (defun update-cpl (class cpl)
 664   (if (class-finalized-p class)
 665       (unless (equal (class-precedence-list class) cpl)
 666         ;; comment from the old CMU CL sources:
 667         ;;   Need to have the cpl setup before update-lisp-class-layout
 668         ;;   is called on CMU CL.
 669         (setf (slot-value class 'class-precedence-list) cpl)
 670         (force-cache-flushes class))
 671       (setf (slot-value class 'class-precedence-list) cpl))
 672   (update-class-can-precede-p cpl))
 673
 674 (defun update-class-can-precede-p (cpl)
 675   (when cpl
 676     (let ((first (car cpl)))
 677       (dolist (c (cdr cpl))
 678         (pushnew c (slot-value first 'can-precede-list))))
 679     (update-class-can-precede-p (cdr cpl))))
 680
 681 (defun class-can-precede-p (class1 class2)
 682   (member class2 (class-can-precede-list class1)))
 683
 684 (defun update-slots (class eslotds)
 685   (let ((instance-slots ())
 686         (class-slots    ()))
 687     (dolist (eslotd eslotds)
 688       (let ((alloc (slot-definition-allocation eslotd)))
 689         (cond ((eq alloc :instance) (push eslotd instance-slots))
 690               ((classp alloc)       (push eslotd class-slots)))))
 691
 692     ;; If there is a change in the shape of the instances then the
 693     ;; old class is now obsolete.
 694     (let* ((nlayout (mapcar #'slot-definition-name
 695                             (sort instance-slots #'<
 696                                   :key #'slot-definition-location)))
 697            (nslots (length nlayout))
 698            (nwrapper-class-slots (compute-class-slots class-slots))
 699            (owrapper (class-wrapper class))
 700            (olayout (and owrapper (wrapper-instance-slots-layout owrapper)))
 701            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 702            (nwrapper
 703             (cond ((null owrapper)
 704                    (make-wrapper nslots class))
 705                   ((and (equal nlayout olayout)
 706                         (not
 707                          (loop for o in owrapper-class-slots
 708                                for n in nwrapper-class-slots
 709                                do (unless (eq (car o) (car n)) (return t)))))
 710                    owrapper)
 711                   (t
 712                    ;; This will initialize the new wrapper to have the
 713                    ;; same state as the old wrapper. We will then have
 714                    ;; to change that. This may seem like wasted work
 715                    ;; (and it is), but the spec requires that we call
 716                    ;; MAKE-INSTANCES-OBSOLETE.
 717                    (make-instances-obsolete class)
 718                    (class-wrapper class)))))
 719
 720       (with-slots (wrapper slots) class
 721         (update-lisp-class-layout class nwrapper)
 722         (setf slots eslotds
 723               (wrapper-instance-slots-layout nwrapper) nlayout
 724               (wrapper-class-slots nwrapper) nwrapper-class-slots
 725               (wrapper-no-of-instance-slots nwrapper) nslots
 726               wrapper nwrapper))
 727
 728       (unless (eq owrapper nwrapper)
 729         (update-pv-table-cache-info class)))))
 730
 731 (defun compute-class-slots (eslotds)
 732   (let (collect)
 733     (dolist (eslotd eslotds)
 734       (push (assoc (slot-definition-name eslotd)
 735                    (class-slot-cells (slot-definition-allocation eslotd)))
 736             collect))
 737     (nreverse collect)))
 738
 739 (defun compute-layout (cpl instance-eslotds)
 740   (let* ((names
 741            (let (collect)
 742              (dolist (eslotd instance-eslotds)
 743                (when (eq (slot-definition-allocation eslotd) :instance)
 744                  (push (slot-definition-name eslotd) collect)))
 745              (nreverse collect)))
 746          (order ()))
 747     (labels ((rwalk (tail)
 748                (when tail
 749                  (rwalk (cdr tail))
 750                  (dolist (ss (class-slots (car tail)))
 751                    (let ((n (slot-definition-name ss)))
 752                      (when (member n names)
 753                        (setq order (cons n order)
 754                              names (remove n names))))))))
 755       (rwalk (if (slot-boundp (car cpl) 'slots)
 756                  cpl
 757                  (cdr cpl)))
 758       (reverse (append names order)))))
 759
 760 (defun update-gfs-of-class (class)
 761   (when (and (class-finalized-p class)
 762              (let ((cpl (class-precedence-list class)))
 763                (or (member *the-class-slot-class* cpl)
 764                    (member *the-class-standard-effective-slot-definition*
 765                            cpl))))
 766     (let ((gf-table (make-hash-table :test 'eq)))
 767       (labels ((collect-gfs (class)
 768                  (dolist (gf (specializer-direct-generic-functions class))
 769                    (setf (gethash gf gf-table) t))
 770                  (mapc #'collect-gfs (class-direct-superclasses class))))
 771         (collect-gfs class)
 772         (maphash (lambda (gf ignore)
 773                    (declare (ignore ignore))
 774                    (update-gf-dfun class gf))
 775                  gf-table)))))
 776
 777 (defun update-inits (class inits)
 778   (setf (plist-value class 'default-initargs) inits))
 779 \f
 780 (defmethod compute-default-initargs ((class slot-class))
 781   (let ((cpl (class-precedence-list class))
 782         (direct (class-direct-default-initargs class)))
 783     (labels ((walk (tail)
 784                (if (null tail)
 785                    nil
 786                    (let ((c (pop tail)))
 787                      (append (if (eq c class)
 788                                  direct
 789                                  (class-direct-default-initargs c))
 790                              (walk tail))))))
 791       (let ((initargs (walk cpl)))
 792         (delete-duplicates initargs :test #'eq :key #'car :from-end t)))))
 793 \f
 794 ;;;; protocols for constructing direct and effective slot definitions
 795
 796 (defmethod direct-slot-definition-class ((class std-class) initargs)
 797   (declare (ignore initargs))
 798   (find-class 'standard-direct-slot-definition))
 799
 800 (defun make-direct-slotd (class initargs)
 801   (let ((initargs (list* :class class initargs)))
 802     (apply #'make-instance
 803            (direct-slot-definition-class class initargs)
 804            initargs)))
 805
 806 (defmethod compute-slots ((class std-class))
 807   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 808   ;; for each different slot name we find in our superclasses. Each
 809   ;; call receives the class and a list of the dslotds with that name.
 810   ;; The list is in most-specific-first order.
 811   (let ((name-dslotds-alist ()))
 812     (dolist (c (class-precedence-list class))
 813       (let ((dslotds (class-direct-slots c)))
 814         (dolist (d dslotds)
 815           (let* ((name (slot-definition-name d))
 816                  (entry (assq name name-dslotds-alist)))
 817             (if entry
 818                 (push d (cdr entry))
 819                 (push (list name d) name-dslotds-alist))))))
 820     (mapcar (lambda (direct)
 821               (compute-effective-slot-definition class
 822                                                  (nreverse (cdr direct))))
 823             name-dslotds-alist)))
 824
 825 (defmethod compute-slots :around ((class std-class))
 826   (let ((eslotds (call-next-method))
 827         (cpl (class-precedence-list class))
 828         (instance-slots ())
 829         (class-slots    ()))
 830     (dolist (eslotd eslotds)
 831       (let ((alloc (slot-definition-allocation eslotd)))
 832         (cond ((eq alloc :instance) (push eslotd instance-slots))
 833               ((classp alloc)       (push eslotd class-slots)))))
 834     (let ((nlayout (compute-layout cpl instance-slots)))
 835       (dolist (eslotd instance-slots)
 836         (setf (slot-definition-location eslotd)
 837               (position (slot-definition-name eslotd) nlayout))))
 838     (dolist (eslotd class-slots)
 839       (setf (slot-definition-location eslotd)
 840             (assoc (slot-definition-name eslotd)
 841                    (class-slot-cells (slot-definition-allocation eslotd)))))
 842     (mapc #'initialize-internal-slot-functions eslotds)
 843     eslotds))
 844
 845 (defmethod compute-slots ((class structure-class))
 846   (mapcan (lambda (superclass)
 847             (mapcar (lambda (dslotd)
 848                       (compute-effective-slot-definition class
 849                                                          (list dslotd)))
 850                     (class-direct-slots superclass)))
 851           (reverse (slot-value class 'class-precedence-list))))
 852
 853 (defmethod compute-slots :around ((class structure-class))
 854   (let ((eslotds (call-next-method)))
 855     (mapc #'initialize-internal-slot-functions eslotds)
 856     eslotds))
 857
 858 (defmethod compute-effective-slot-definition ((class slot-class) dslotds)
 859   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
 860          (class (effective-slot-definition-class class initargs)))
 861     (apply #'make-instance class initargs)))
 862
 863 (defmethod effective-slot-definition-class ((class std-class) initargs)
 864   (declare (ignore initargs))
 865   (find-class 'standard-effective-slot-definition))
 866
 867 (defmethod effective-slot-definition-class ((class structure-class) initargs)
 868   (declare (ignore initargs))
 869   (find-class 'structure-effective-slot-definition))
 870
 871 (defmethod compute-effective-slot-definition-initargs
 872     ((class slot-class) direct-slotds)
 873   (let* ((name nil)
 874          (initfunction nil)
 875          (initform nil)
 876          (initargs nil)
 877          (allocation nil)
 878          (type t)
 879          (namep  nil)
 880          (initp  nil)
 881          (allocp nil))
 882
 883     (dolist (slotd direct-slotds)
 884       (when slotd
 885         (unless namep
 886           (setq name (slot-definition-name slotd)
 887                 namep t))
 888         (unless initp
 889           (when (slot-definition-initfunction slotd)
 890             (setq initform (slot-definition-initform slotd)
 891                   initfunction (slot-definition-initfunction slotd)
 892                   initp t)))
 893         (unless allocp
 894           (setq allocation (slot-definition-allocation slotd)
 895                 allocp t))
 896         (setq initargs (append (slot-definition-initargs slotd) initargs))
 897         (let ((slotd-type (slot-definition-type slotd)))
 898           (setq type (cond ((eq type t) slotd-type)
 899                            ((*subtypep type slotd-type) type)
 900                            (t `(and ,type ,slotd-type)))))))
 901     (list :name name
 902           :initform initform
 903           :initfunction initfunction
 904           :initargs initargs
 905           :allocation allocation
 906           :type type
 907           :class class)))
 908
 909 (defmethod compute-effective-slot-definition-initargs :around
 910     ((class structure-class) direct-slotds)
 911   (let ((slotd (car direct-slotds)))
 912     (list* :defstruct-accessor-symbol
 913            (slot-definition-defstruct-accessor-symbol slotd)
 914            :internal-reader-function
 915            (slot-definition-internal-reader-function slotd)
 916            :internal-writer-function
 917            (slot-definition-internal-writer-function slotd)
 918            (call-next-method))))
 919 \f
 920 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
 921 ;;;       to make the method object. They have to use make-a-method which
 922 ;;;       is a specially bootstrapped mechanism for making standard methods.
 923 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
 924   (declare (ignore direct-slot initargs))
 925   (find-class 'standard-reader-method))
 926
 927 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
 928   (add-method generic-function
 929               (make-a-method 'standard-reader-method
 930                              ()
 931                              (list (or (class-name class) 'object))
 932                              (list class)
 933                              (make-reader-method-function class slot-name)
 934                              "automatically generated reader method"
 935                              slot-name)))
 936
 937 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
 938   (declare (ignore direct-slot initargs))
 939   (find-class 'standard-writer-method))
 940
 941 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
 942   (add-method generic-function
 943               (make-a-method 'standard-writer-method
 944                              ()
 945                              (list 'new-value (or (class-name class) 'object))
 946                              (list *the-class-t* class)
 947                              (make-writer-method-function class slot-name)
 948                              "automatically generated writer method"
 949                              slot-name)))
 950
 951 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
 952   (add-method generic-function
 953               (make-a-method 'standard-boundp-method
 954                              ()
 955                              (list (or (class-name class) 'object))
 956                              (list class)
 957                              (make-boundp-method-function class slot-name)
 958                              "automatically generated boundp method"
 959                              slot-name)))
 960
 961 (defmethod remove-reader-method ((class slot-class) generic-function)
 962   (let ((method (get-method generic-function () (list class) nil)))
 963     (when method (remove-method generic-function method))))
 964
 965 (defmethod remove-writer-method ((class slot-class) generic-function)
 966   (let ((method
 967           (get-method generic-function () (list *the-class-t* class) nil)))
 968     (when method (remove-method generic-function method))))
 969
 970 (defmethod remove-boundp-method ((class slot-class) generic-function)
 971   (let ((method (get-method generic-function () (list class) nil)))
 972     (when method (remove-method generic-function method))))
 973 \f
 974 ;;; make-reader-method-function and make-write-method function are NOT part of
 975 ;;; the standard protocol. They are however useful, PCL makes uses makes use
 976 ;;; of them internally and documents them for PCL users.
 977 ;;;
 978 ;;; *** This needs work to make type testing by the writer functions which
 979 ;;; *** do type testing faster. The idea would be to have one constructor
 980 ;;; *** for each possible type test.
 981 ;;;
 982 ;;; *** There is a subtle bug here which is going to have to be fixed.
 983 ;;; *** Namely, the simplistic use of the template has to be fixed. We
 984 ;;; *** have to give the optimize-slot-value method the user might have
 985 ;;; *** defined for this metaclass a chance to run.
 986
 987 (defmethod make-reader-method-function ((class slot-class) slot-name)
 988   (make-std-reader-method-function (class-name class) slot-name))
 989
 990 (defmethod make-writer-method-function ((class slot-class) slot-name)
 991   (make-std-writer-method-function (class-name class) slot-name))
 992
 993 (defmethod make-boundp-method-function ((class slot-class) slot-name)
 994   (make-std-boundp-method-function (class-name class) slot-name))
 995 \f
 996 (defmethod compatible-meta-class-change-p (class proto-new-class)
 997   (eq (class-of class) (class-of proto-new-class)))
 998
 999 (defmethod validate-superclass ((class class) (new-super class))
1000   (or (eq new-super *the-class-t*)
1001       (eq (class-of class) (class-of new-super))))
1002
1003 (defmethod validate-superclass ((class standard-class) (new-super std-class))
1004   (let ((new-super-meta-class (class-of new-super)))
1005     (or (eq new-super-meta-class *the-class-std-class*)
1006         (eq (class-of class) new-super-meta-class))))
1007 \f
1008 (defun force-cache-flushes (class)
1009   (let* ((owrapper (class-wrapper class))
1010          (state (wrapper-state owrapper)))
1011     ;; We only need to do something if the state is still T. If the
1012     ;; state isn't T, it will be FLUSH or OBSOLETE, and both of those
1013     ;; will already be doing what we want. In particular, we must be
1014     ;; sure we never change an OBSOLETE into a FLUSH since OBSOLETE
1015     ;; means do what FLUSH does and then some.
1016     (when (eq state t) ; FIXME: should be done through INVALID-WRAPPER-P
1017       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1018                                     class)))
1019         (setf (wrapper-instance-slots-layout nwrapper)
1020               (wrapper-instance-slots-layout owrapper))
1021         (setf (wrapper-class-slots nwrapper)
1022               (wrapper-class-slots owrapper))
1023         (sb-sys:without-interrupts
1024           (update-lisp-class-layout class nwrapper)
1025           (setf (slot-value class 'wrapper) nwrapper)
1026           (invalidate-wrapper owrapper :flush nwrapper))))))
1027
1028 (defun flush-cache-trap (owrapper nwrapper instance)
1029   (declare (ignore owrapper))
1030   (set-wrapper instance nwrapper))
1031 \f
1032 ;;; make-instances-obsolete can be called by user code. It will cause the
1033 ;;; next access to the instance (as defined in 88-002R) to trap through the
1034 ;;; update-instance-for-redefined-class mechanism.
1035 (defmethod make-instances-obsolete ((class std-class))
1036   (let* ((owrapper (class-wrapper class))
1037          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1038                                  class)))
1039       (setf (wrapper-instance-slots-layout nwrapper)
1040             (wrapper-instance-slots-layout owrapper))
1041       (setf (wrapper-class-slots nwrapper)
1042             (wrapper-class-slots owrapper))
1043       (sb-sys:without-interrupts
1044         (update-lisp-class-layout class nwrapper)
1045         (setf (slot-value class 'wrapper) nwrapper)
1046         (invalidate-wrapper owrapper :obsolete nwrapper)
1047         class)))
1048
1049 (defmethod make-instances-obsolete ((class symbol))
1050   (make-instances-obsolete (find-class class)))
1051
1052 ;;; obsolete-instance-trap is the internal trap that is called when we see
1053 ;;; an obsolete instance. The times when it is called are:
1054 ;;;   - when the instance is involved in method lookup
1055 ;;;   - when attempting to access a slot of an instance
1056 ;;;
1057 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1058 ;;; instance access macros.
1059 ;;;
1060 ;;; Of course these times when it is called are an internal
1061 ;;; implementation detail of PCL and are not part of the documented
1062 ;;; description of when the obsolete instance update happens. The
1063 ;;; documented description is as it appears in 88-002R.
1064 ;;;
1065 ;;; This has to return the new wrapper, so it counts on all the
1066 ;;; methods on obsolete-instance-trap-internal to return the new
1067 ;;; wrapper. It also does a little internal error checking to make
1068 ;;; sure that the traps are only happening when they should, and that
1069 ;;; the trap methods are computing appropriate new wrappers.
1070
1071 ;;; obsolete-instance-trap might be called on structure instances
1072 ;;; after a structure is redefined. In most cases, obsolete-instance-trap
1073 ;;; will not be able to fix the old instance, so it must signal an
1074 ;;; error. The hard part of this is that the error system and debugger
1075 ;;; might cause obsolete-instance-trap to be called again, so in that
1076 ;;; case, we have to return some reasonable wrapper, instead.
1077
1078 (defvar *in-obsolete-instance-trap* nil)
1079 (defvar *the-wrapper-of-structure-object*
1080   (class-wrapper (find-class 'structure-object)))
1081
1082 (define-condition obsolete-structure (error)
1083   ((datum :reader obsolete-structure-datum :initarg :datum))
1084   (:report
1085    (lambda (condition stream)
1086      ;; Don't try to print the structure, since it probably won't work.
1087      (format stream
1088              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1089              (type-of (obsolete-structure-datum condition))))))
1090
1091 (defun obsolete-instance-trap (owrapper nwrapper instance)
1092   (if (not (pcl-instance-p instance))
1093       (if *in-obsolete-instance-trap*
1094           *the-wrapper-of-structure-object*
1095            (let ((*in-obsolete-instance-trap* t))
1096              (error 'obsolete-structure :datum instance)))
1097       (let* ((class (wrapper-class* nwrapper))
1098              (copy (allocate-instance class)) ;??? allocate-instance ???
1099              (olayout (wrapper-instance-slots-layout owrapper))
1100              (nlayout (wrapper-instance-slots-layout nwrapper))
1101              (oslots (get-slots instance))
1102              (nslots (get-slots copy))
1103              (oclass-slots (wrapper-class-slots owrapper))
1104              (added ())
1105              (discarded ())
1106              (plist ()))
1107         ;; local  --> local     transfer
1108         ;; local  --> shared       discard
1109         ;; local  -->  --         discard
1110         ;; shared --> local     transfer
1111         ;; shared --> shared       discard
1112         ;; shared -->  --         discard
1113         ;;  --    --> local     add
1114         ;;  --    --> shared    --
1115
1116         ;; Go through all the old local slots.
1117         (let ((opos 0))
1118           (dolist (name olayout)
1119             (let ((npos (posq name nlayout)))
1120               (if npos
1121                   (setf (clos-slots-ref nslots npos)
1122                         (clos-slots-ref oslots opos))
1123                   (progn
1124                     (push name discarded)
1125                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1126                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1127             (incf opos)))
1128
1129         ;; Go through all the old shared slots.
1130         (dolist (oclass-slot-and-val oclass-slots)
1131           (let ((name (car oclass-slot-and-val))
1132                 (val (cdr oclass-slot-and-val)))
1133             (let ((npos (posq name nlayout)))
1134               (if npos
1135                   (setf (clos-slots-ref nslots npos) (cdr oclass-slot-and-val))
1136                   (progn (push name discarded)
1137                          (unless (eq val +slot-unbound+)
1138                            (setf (getf plist name) val)))))))
1139
1140         ;; Go through all the new local slots to compute the added slots.
1141         (dolist (nlocal nlayout)
1142           (unless (or (memq nlocal olayout)
1143                       (assq nlocal oclass-slots))
1144             (push nlocal added)))
1145
1146         (swap-wrappers-and-slots instance copy)
1147
1148         (update-instance-for-redefined-class instance
1149                                              added
1150                                              discarded
1151                                              plist)
1152         nwrapper)))
1153 \f
1154 (defmacro copy-instance-internal (instance)
1155   `(progn
1156      (let* ((class (class-of instance))
1157             (copy (allocate-instance class)))
1158        (if (std-instance-p ,instance)
1159            (setf (std-instance-slots ,instance)
1160                  (std-instance-slots ,instance))
1161          (setf (fsc-instance-slots ,instance)
1162                (fsc-instance-slots ,instance)))
1163        copy)))
1164
1165 (defun change-class-internal (instance new-class)
1166   (let* ((old-class (class-of instance))
1167          (copy (allocate-instance new-class))
1168          (new-wrapper (get-wrapper copy))
1169          (old-wrapper (class-wrapper old-class))
1170          (old-layout (wrapper-instance-slots-layout old-wrapper))
1171          (new-layout (wrapper-instance-slots-layout new-wrapper))
1172          (old-slots (get-slots instance))
1173          (new-slots (get-slots copy))
1174          (old-class-slots (wrapper-class-slots old-wrapper)))
1175
1176     ;; "The values of local slots specified by both the class CTO and
1177     ;; CFROM are retained. If such a local slot was unbound, it
1178     ;; remains unbound."
1179     (let ((new-position 0))
1180       (dolist (new-slot new-layout)
1181         (let ((old-position (posq new-slot old-layout)))
1182           (when old-position
1183             (setf (clos-slots-ref new-slots new-position)
1184                   (clos-slots-ref old-slots old-position))))))
1185
1186     ;; "The values of slots specified as shared in the class CFROM and
1187     ;; as local in the class CTO are retained."
1188     (dolist (slot-and-val old-class-slots)
1189       (let ((position (posq (car slot-and-val) new-layout)))
1190         (when position
1191           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1192
1193     ;; Make the copy point to the old instance's storage, and make the
1194     ;; old instance point to the new storage.
1195     (swap-wrappers-and-slots instance copy)
1196
1197     (update-instance-for-different-class copy instance)
1198     instance))
1199
1200 (defmethod change-class ((instance standard-object)
1201                          (new-class standard-class))
1202   (change-class-internal instance new-class))
1203
1204 (defmethod change-class ((instance funcallable-standard-object)
1205                          (new-class funcallable-standard-class))
1206   (change-class-internal instance new-class))
1207
1208 (defmethod change-class ((instance standard-object)
1209                          (new-class funcallable-standard-class))
1210   (error "You can't change the class of ~S to ~S~@
1211           because it isn't already an instance with metaclass ~S."
1212          instance new-class 'standard-class))
1213
1214 (defmethod change-class ((instance funcallable-standard-object)
1215                          (new-class standard-class))
1216   (error "You can't change the class of ~S to ~S~@
1217           because it isn't already an instance with metaclass ~S."
1218          instance new-class 'funcallable-standard-class))
1219
1220 (defmethod change-class ((instance t) (new-class-name symbol))
1221   (change-class instance (find-class new-class-name)))
1222 \f
1223 ;;;; The metaclass BUILT-IN-CLASS
1224 ;;;;
1225 ;;;; This metaclass is something of a weird creature. By this point, all
1226 ;;;; instances of it which will exist have been created, and no instance
1227 ;;;; is ever created by calling MAKE-INSTANCE.
1228 ;;;;
1229 ;;;; But, there are other parts of the protocol we must follow and those
1230 ;;;; definitions appear here.
1231
1232 (defmethod shared-initialize :before
1233            ((class built-in-class) slot-names &rest initargs)
1234   (declare (ignore slot-names initargs))
1235   (error "attempt to initialize or reinitialize a built in class"))
1236
1237 (defmethod class-direct-slots       ((class built-in-class)) ())
1238 (defmethod class-slots             ((class built-in-class)) ())
1239 (defmethod class-direct-default-initargs ((class built-in-class)) ())
1240 (defmethod class-default-initargs       ((class built-in-class)) ())
1241
1242 (defmethod validate-superclass ((c class) (s built-in-class))
1243   (or (eq s *the-class-t*)
1244       (eq s *the-class-stream*)))
1245 \f
1246 (defmethod validate-superclass ((c slot-class)
1247                                 (f forward-referenced-class))
1248   t)
1249 \f
1250 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1251   (pushnew dependent (plist-value metaobject 'dependents)))
1252
1253 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1254   (setf (plist-value metaobject 'dependents)
1255         (delete dependent (plist-value metaobject 'dependents))))
1256
1257 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1258   (dolist (dependent (plist-value metaobject 'dependents))
1259     (funcall function dependent)))
1260