src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd 'class)))
  76     (let ((table (or (gethash name *name->class->slotd-table*)
  77                      (setf (gethash name *name->class->slotd-table*)
  78                            (make-hash-table :test 'eq :size 5)))))
  79       (setf (gethash class table) slotd))
  80     (dolist (type '(reader writer boundp))
  81       (let* ((gf-name (ecase type
  82                               (reader 'slot-value-using-class)
  83                               (writer '(setf slot-value-using-class))
  84                               (boundp 'slot-boundp-using-class)))
  85              (gf (gdefinition gf-name)))
  86         (compute-slot-accessor-info slotd type gf)))
  87     (initialize-internal-slot-gfs name)))
  88
  89 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  90                                        type gf)
  91   (let* ((name (slot-value slotd 'name))
  92          (class (slot-value slotd 'class))
  93          (old-slotd (find-slot-definition class name))
  94          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
  95     (multiple-value-bind (function std-p)
  96         (if (eq *boot-state* 'complete)
  97             (get-accessor-method-function gf type class slotd)
  98             (get-optimized-std-accessor-method-function class slotd type))
  99       (setf (slot-accessor-std-p slotd type) std-p)
 100       (setf (slot-accessor-function slotd type) function))
 101     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 102       (push (cons class name) *pv-table-cache-update-info*))))
 103
 104 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 105   :instance)
 106 \f
 107 (defmethod shared-initialize :after ((object documentation-mixin)
 108                                      slot-names
 109                                      &key (documentation nil documentation-p))
 110   (declare (ignore slot-names))
 111   (when documentation-p
 112     (setf (plist-value object 'documentation) documentation)))
 113
 114 ;;; default if DOC-TYPE doesn't match one of the specified types
 115 (defmethod documentation (object doc-type)
 116   (warn "unsupported DOCUMENTATION: type ~S for object ~S"
 117         doc-type
 118         (type-of object))
 119   nil)
 120
 121 ;;; default if DOC-TYPE doesn't match one of the specified types
 122 (defmethod (setf documentation) (new-value object doc-type)
 123   ;; CMU CL made this an error, but since ANSI says that even for supported
 124   ;; doc types an implementation is permitted to discard docs at any time
 125   ;; for any reason, this feels to me more like a warning. -- WHN 19991214
 126   (warn "discarding unsupported DOCUMENTATION of type ~S for object ~S"
 127         doc-type
 128         (type-of object))
 129   new-value)
 130
 131 (defmethod documentation ((object documentation-mixin) doc-type)
 132   (declare (ignore doc-type))
 133   (plist-value object 'documentation))
 134
 135 (defmethod (setf documentation) (new-value
 136                                  (object documentation-mixin)
 137                                  doc-type)
 138   (declare (ignore doc-type))
 139   (setf (plist-value object 'documentation) new-value))
 140
 141 (defmethod documentation ((slotd standard-slot-definition) doc-type)
 142   (declare (ignore doc-type))
 143   (slot-value slotd 'documentation))
 144
 145 (defmethod (setf documentation) (new-value
 146                                  (slotd standard-slot-definition)
 147                                  doc-type)
 148   (declare (ignore doc-type))
 149   (setf (slot-value slotd 'documentation) new-value))
 150 \f
 151 ;;;; various class accessors that are a little more complicated than can be
 152 ;;;; done with automatically generated reader methods
 153
 154 (defmethod class-finalized-p ((class pcl-class))
 155   (with-slots (wrapper) class
 156     (not (null wrapper))))
 157
 158 (defmethod class-prototype ((class std-class))
 159   (with-slots (prototype) class
 160     (or prototype (setq prototype (allocate-instance class)))))
 161
 162 (defmethod class-prototype ((class structure-class))
 163   (with-slots (prototype wrapper defstruct-constructor) class
 164     (or prototype
 165         (setq prototype
 166               (if defstruct-constructor
 167                   (allocate-instance class)
 168                   (allocate-standard-instance wrapper))))))
 169
 170 (defmethod class-direct-default-initargs ((class slot-class))
 171   (plist-value class 'direct-default-initargs))
 172
 173 (defmethod class-default-initargs ((class slot-class))
 174   (plist-value class 'default-initargs))
 175
 176 (defmethod class-slot-cells ((class std-class))
 177   (plist-value class 'class-slot-cells))
 178 \f
 179 ;;;; class accessors that are even a little bit more complicated than those
 180 ;;;; above. These have a protocol for updating them, we must implement that
 181 ;;;; protocol.
 182
 183 ;;; Maintaining the direct subclasses backpointers. The update methods are
 184 ;;; here, the values are read by an automatically generated reader method.
 185 (defmethod add-direct-subclass ((class class) (subclass class))
 186   (with-slots (direct-subclasses) class
 187     (pushnew subclass direct-subclasses)
 188     subclass))
 189 (defmethod remove-direct-subclass ((class class) (subclass class))
 190   (with-slots (direct-subclasses) class
 191     (setq direct-subclasses (remove subclass direct-subclasses))
 192     subclass))
 193
 194 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 195 ;;;
 196 ;;; There are four generic functions involved, each has one method for the
 197 ;;; class case and another method for the damned EQL specializers. All of
 198 ;;; these are specified methods and appear in their specified place in the
 199 ;;; class graph.
 200 ;;;
 201 ;;;   ADD-DIRECT-METHOD
 202 ;;;   REMOVE-DIRECT-METHOD
 203 ;;;   SPECIALIZER-DIRECT-METHODS
 204 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 205 ;;;
 206 ;;; In each case, we maintain one value which is a cons. The car is the list
 207 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 208 ;;; computed lazily.
 209 (defmethod add-direct-method ((specializer class) (method method))
 210   (with-slots (direct-methods) specializer
 211     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 212           (cdr direct-methods) ()))
 213   method)
 214 (defmethod remove-direct-method ((specializer class) (method method))
 215   (with-slots (direct-methods) specializer
 216     (setf (car direct-methods) (remove method (car direct-methods))
 217           (cdr direct-methods) ()))
 218   method)
 219
 220 (defmethod specializer-direct-methods ((specializer class))
 221   (with-slots (direct-methods) specializer
 222     (car direct-methods)))
 223
 224 (defmethod specializer-direct-generic-functions ((specializer class))
 225   (with-slots (direct-methods) specializer
 226     (or (cdr direct-methods)
 227         (setf (cdr direct-methods)
 228               (let (collect)
 229                 (dolist (m (car direct-methods))
 230                   ;; the old PCL code used COLLECTING-ONCE which used
 231                   ;; #'EQ to check for newness
 232                   (pushnew (method-generic-function m) collect :test #'eq))
 233                 (nreverse collect))))))
 234 \f
 235 ;;; This hash table is used to store the direct methods and direct generic
 236 ;;; functions of EQL specializers. Each value in the table is the cons.
 237 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 238 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 239
 240 (defmethod specializer-method-table ((specializer eql-specializer))
 241   *eql-specializer-methods*)
 242
 243 (defmethod specializer-method-table ((specializer class-eq-specializer))
 244   *class-eq-specializer-methods*)
 245
 246 (defmethod add-direct-method ((specializer specializer-with-object)
 247                               (method method))
 248   (let* ((object (specializer-object specializer))
 249          (table (specializer-method-table specializer))
 250          (entry (gethash object table)))
 251     (unless entry
 252       (setq entry
 253             (setf (gethash object table)
 254                   (cons nil nil))))
 255     (setf (car entry) (adjoin method (car entry))
 256           (cdr entry) ())
 257     method))
 258
 259 (defmethod remove-direct-method ((specializer specializer-with-object)
 260                                  (method method))
 261   (let* ((object (specializer-object specializer))
 262          (entry (gethash object (specializer-method-table specializer))))
 263     (when entry
 264       (setf (car entry) (remove method (car entry))
 265             (cdr entry) ()))
 266     method))
 267
 268 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 269   (car (gethash (specializer-object specializer)
 270                 (specializer-method-table specializer))))
 271
 272 (defmethod specializer-direct-generic-functions ((specializer
 273                                                   specializer-with-object))
 274   (let* ((object (specializer-object specializer))
 275          (entry (gethash object (specializer-method-table specializer))))
 276     (when entry
 277       (or (cdr entry)
 278           (setf (cdr entry)
 279                 (let (collect)
 280                   (dolist (m (car entry))
 281                     (pushnew (method-generic-function m) collect :test #'eq))
 282                   (nreverse collect)))))))
 283
 284 (defun map-specializers (function)
 285   (map-all-classes (lambda (class)
 286                      (funcall function (class-eq-specializer class))
 287                      (funcall function class)))
 288   (maphash (lambda (object methods)
 289              (declare (ignore methods))
 290              (intern-eql-specializer object))
 291            *eql-specializer-methods*)
 292   (maphash (lambda (object specl)
 293              (declare (ignore object))
 294              (funcall function specl))
 295            *eql-specializer-table*)
 296   nil)
 297
 298 (defun map-all-generic-functions (function)
 299   (let ((all-generic-functions (make-hash-table :test 'eq)))
 300     (map-specializers (lambda (specl)
 301                         (dolist (gf (specializer-direct-generic-functions
 302                                      specl))
 303                           (unless (gethash gf all-generic-functions)
 304                             (setf (gethash gf all-generic-functions) t)
 305                             (funcall function gf))))))
 306   nil)
 307
 308 (defmethod shared-initialize :after ((specl class-eq-specializer)
 309                                      slot-names
 310                                      &key)
 311   (declare (ignore slot-names))
 312   (setf (slot-value specl 'type) `(class-eq ,(specializer-class specl))))
 313
 314 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 315   (declare (ignore slot-names))
 316   (setf (slot-value specl 'type) `(eql ,(specializer-object specl))))
 317 \f
 318 (defun real-load-defclass (name metaclass-name supers slots other)
 319   (let ((res (apply #'ensure-class name :metaclass metaclass-name
 320                     :direct-superclasses supers
 321                     :direct-slots slots
 322                     :definition-source `((defclass ,name)
 323                                          ,*load-pathname*)
 324                     other)))
 325     res))
 326
 327 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 328
 329 (defun ensure-class (name &rest all)
 330   (apply #'ensure-class-using-class name (find-class name nil) all))
 331
 332 (defmethod ensure-class-using-class (name (class null) &rest args &key)
 333   (multiple-value-bind (meta initargs)
 334       (ensure-class-values class args)
 335     (set-class-type-translation (class-prototype meta) name)
 336     (setf class (apply #'make-instance meta :name name initargs)
 337           (find-class name) class)
 338     (set-class-type-translation class name)
 339     class))
 340
 341 (defmethod ensure-class-using-class (name (class pcl-class) &rest args &key)
 342   (multiple-value-bind (meta initargs)
 343       (ensure-class-values class args)
 344     (unless (eq (class-of class) meta) (change-class class meta))
 345     (apply #'reinitialize-instance class initargs)
 346     (setf (find-class name) class)
 347     (set-class-type-translation class name)
 348     class))
 349
 350 (defmethod class-predicate-name ((class t))
 351   'constantly-nil)
 352
 353 (defun fix-super (s)
 354   (cond ((classp s) s)
 355         ((not (legal-class-name-p s))
 356           (error "~S is not a class or a legal class name." s))
 357         (t
 358           (or (find-class s nil)
 359               (setf (find-class s)
 360                       (make-instance 'forward-referenced-class
 361                                      :name s))))))
 362
 363 (defun ensure-class-values (class args)
 364   (let* ((initargs (copy-list args))
 365          (unsupplied (list 1))
 366          (supplied-meta   (getf initargs :metaclass unsupplied))
 367          (supplied-supers (getf initargs :direct-superclasses unsupplied))
 368          (supplied-slots  (getf initargs :direct-slots unsupplied))
 369          (meta
 370            (cond ((neq supplied-meta unsupplied)
 371                   (find-class supplied-meta))
 372                  ((or (null class)
 373                       (forward-referenced-class-p class))
 374                   *the-class-standard-class*)
 375                  (t
 376                   (class-of class)))))
 377     ;; KLUDGE: It seemed to me initially that there ought to be a way
 378     ;; of collecting all the erroneous problems in one go, rather than
 379     ;; this way of solving the problem of signalling the errors that
 380     ;; we are required to, which stops at the first bogus input.
 381     ;; However, after playing around a little, I couldn't find that
 382     ;; way, so I've left it as is, but if someone does come up with a
 383     ;; better way... -- CSR, 2002-09-08
 384     (do ((direct-slots (getf initargs :direct-slots) (cdr direct-slots)))
 385         ((endp direct-slots) nil)
 386       (destructuring-bind (slot &rest more) direct-slots
 387         (let ((slot-name (getf slot :name)))
 388           (when (some (lambda (s) (eq slot-name (getf s :name))) more)
 389             ;; FIXME: It's quite possible that we ought to define an
 390             ;; SB-INT:PROGRAM-ERROR function to signal these and other
 391             ;; errors throughout the codebase that are required to be
 392             ;; of type PROGRAM-ERROR.
 393             (error 'simple-program-error
 394                    :format-control "~@<There is more than one direct slot ~
 395                                    with name ~S.~:>"
 396                    :format-arguments (list slot-name)))
 397           (do ((stuff slot (cddr stuff)))
 398               ((endp stuff) nil)
 399             (destructuring-bind (option value &rest more) stuff
 400               (cond
 401                 ((and (member option '(:allocation :type
 402                                        :initform :documentation))
 403                       (not (eq unsupplied
 404                                (getf more option unsupplied))))
 405                  (error 'simple-program-error
 406                         :format-control "~@<Duplicate slot option ~S for ~
 407                                         slot named ~S.~:>"
 408                         :format-arguments (list option slot-name)))
 409                 ((and (eq option :readers)
 410                       (notevery #'symbolp value))
 411                  (error 'simple-program-error
 412                         :format-control "~@<Slot reader names for slot ~
 413                                         named ~S must be symbols.~:>"
 414                         :format-arguments (list slot-name)))
 415                 ((and (eq option :initargs)
 416                       (notevery #'symbolp value))
 417                  (error 'simple-program-error
 418                         :format-control "~@<Slot initarg names for slot ~
 419                                         named ~S must be symbols.~:>"
 420                         :format-arguments (list slot-name)))))))))
 421     (loop for (initarg . more) on (getf initargs :direct-default-initargs)
 422           for name = (car initarg)
 423           when (some (lambda (a) (eq (car a) name)) more)
 424           do (error 'simple-program-error
 425                     :format-control "~@<Duplicate initialization argument ~
 426                                     name ~S in :DEFAULT-INITARGS.~:>"
 427                     :format-arguments (list name class)))
 428     (let ((metaclass 0)
 429           (default-initargs 0))
 430       (do ((args initargs (cddr args)))
 431           ((endp args) nil)
 432         (case (car args)
 433           (:metaclass
 434            (when (> (incf metaclass) 1)
 435              (error 'simple-program-error
 436                     :format-control "~@<More than one :METACLASS ~
 437                                     option specified.~:>")))
 438           (:direct-default-initargs
 439            (when (> (incf default-initargs) 1)
 440              (error 'simple-program-error
 441                     :format-control "~@<More than one :DEFAULT-INITARGS ~
 442                                     option specified.~:>"))))))
 443     (remf initargs :metaclass)
 444     (loop (unless (remf initargs :direct-superclasses) (return)))
 445     (loop (unless (remf initargs :direct-slots) (return)))
 446     (values meta
 447             (list* :direct-superclasses
 448                    (and (neq supplied-supers unsupplied)
 449                         (mapcar #'fix-super supplied-supers))
 450                    :direct-slots
 451                    (and (neq supplied-slots unsupplied) supplied-slots)
 452                    initargs))))
 453 \f
 454
 455 (defmethod shared-initialize :after
 456            ((class std-class)
 457             slot-names
 458             &key (direct-superclasses nil direct-superclasses-p)
 459                  (direct-slots nil direct-slots-p)
 460                  (direct-default-initargs nil direct-default-initargs-p)
 461                  (predicate-name nil predicate-name-p))
 462   (declare (ignore slot-names))
 463   (cond (direct-superclasses-p
 464          (setq direct-superclasses
 465                (or direct-superclasses
 466                    (list (if (funcallable-standard-class-p class)
 467                              *the-class-funcallable-standard-object*
 468                              *the-class-standard-object*))))
 469          (dolist (superclass direct-superclasses)
 470            (unless (validate-superclass class superclass)
 471              (error "The class ~S was specified as a~%
 472                      super-class of the class ~S;~%~
 473                      but the meta-classes ~S and~%~S are incompatible.~@
 474                      Define a method for ~S to avoid this error."
 475                      superclass class (class-of superclass) (class-of class)
 476                      'validate-superclass)))
 477          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 478         (t
 479          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 480   (setq direct-slots
 481         (if direct-slots-p
 482             (setf (slot-value class 'direct-slots)
 483                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 484                           direct-slots))
 485             (slot-value class 'direct-slots)))
 486   (if direct-default-initargs-p
 487       (setf (plist-value class 'direct-default-initargs)
 488             direct-default-initargs)
 489       (setq direct-default-initargs
 490             (plist-value class 'direct-default-initargs)))
 491   (setf (plist-value class 'class-slot-cells)
 492         (let (collect)
 493           (dolist (dslotd direct-slots)
 494             (when (eq :class (slot-definition-allocation dslotd))
 495               (let ((initfunction (slot-definition-initfunction dslotd)))
 496                 (push (cons (slot-definition-name dslotd)
 497                                (if initfunction
 498                                    (funcall initfunction)
 499                                    +slot-unbound+))
 500                       collect))))
 501           (nreverse collect)))
 502   (setq predicate-name (if predicate-name-p
 503                            (setf (slot-value class 'predicate-name)
 504                                  (car predicate-name))
 505                            (or (slot-value class 'predicate-name)
 506                                (setf (slot-value class 'predicate-name)
 507                                      (make-class-predicate-name (class-name
 508                                                                  class))))))
 509   (add-direct-subclasses class direct-superclasses)
 510   (update-class class nil)
 511   (make-class-predicate class predicate-name)
 512   (add-slot-accessors class direct-slots))
 513
 514 (defmethod shared-initialize :before ((class class) slot-names &key name)
 515   (declare (ignore slot-names name))
 516   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 517   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 518   (setf (slot-value class 'type) `(class ,class))
 519   (setf (slot-value class 'class-eq-specializer)
 520         (make-instance 'class-eq-specializer :class class)))
 521
 522 (defmethod reinitialize-instance :before ((class slot-class) &key)
 523   (remove-direct-subclasses class (class-direct-superclasses class))
 524   (remove-slot-accessors    class (class-direct-slots class)))
 525
 526 (defmethod reinitialize-instance :after ((class slot-class)
 527                                          &rest initargs
 528                                          &key)
 529   (map-dependents class
 530                   (lambda (dependent)
 531                     (apply #'update-dependent class dependent initargs))))
 532
 533 (defmethod shared-initialize :after
 534     ((slotd structure-slot-definition) slot-names &key
 535      (allocation :instance) allocation-class)
 536   (declare (ignore slot-names allocation-class))
 537   (unless (eq allocation :instance)
 538     (error "Structure slots must have :INSTANCE allocation.")))
 539
 540 (defun make-structure-class-defstruct-form (name direct-slots include)
 541   (let* ((conc-name (intern (format nil "~S structure class " name)))
 542          (constructor (intern (format nil "~Aconstructor" conc-name)))
 543          (defstruct `(defstruct (,name
 544                                  ,@(when include
 545                                          `((:include ,(class-name include))))
 546                                  (:predicate nil)
 547                                  (:conc-name ,conc-name)
 548                                  (:constructor ,constructor ())
 549                                  (:copier nil))
 550                       ,@(mapcar (lambda (slot)
 551                                   `(,(slot-definition-name slot)
 552                                     +slot-unbound+))
 553                                 direct-slots)))
 554          (reader-names (mapcar (lambda (slotd)
 555                                  (list 'slot-accessor name
 556                                        (slot-definition-name slotd)
 557                                        'reader))
 558                                direct-slots))
 559          (writer-names (mapcar (lambda (slotd)
 560                                  (list 'slot-accessor name
 561                                        (slot-definition-name slotd)
 562                                        'writer))
 563                                direct-slots))
 564          (readers-init
 565            (mapcar (lambda (slotd reader-name)
 566                      (let ((accessor
 567                              (slot-definition-defstruct-accessor-symbol
 568                               slotd)))
 569                        `(defun ,reader-name (obj)
 570                          (declare (type ,name obj))
 571                          (,accessor obj))))
 572                    direct-slots reader-names))
 573          (writers-init
 574            (mapcar (lambda (slotd writer-name)
 575                      (let ((accessor
 576                              (slot-definition-defstruct-accessor-symbol
 577                               slotd)))
 578                        `(defun ,writer-name (nv obj)
 579                          (declare (type ,name obj))
 580                          (setf (,accessor obj) nv))))
 581                    direct-slots writer-names))
 582          (defstruct-form
 583              `(progn
 584                ,defstruct
 585                ,@readers-init ,@writers-init
 586                (cons nil nil))))
 587     (values defstruct-form constructor reader-names writer-names)))
 588
 589 (defmethod shared-initialize :after
 590       ((class structure-class)
 591        slot-names
 592        &key (direct-superclasses nil direct-superclasses-p)
 593             (direct-slots nil direct-slots-p)
 594             direct-default-initargs
 595             (predicate-name nil predicate-name-p))
 596   (declare (ignore slot-names direct-default-initargs))
 597   (if direct-superclasses-p
 598       (setf (slot-value class 'direct-superclasses)
 599             (or direct-superclasses
 600                 (setq direct-superclasses
 601                       (and (not (eq (class-name class) 'structure-object))
 602                            (list *the-class-structure-object*)))))
 603       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 604   (let* ((name (class-name class))
 605          (from-defclass-p (slot-value class 'from-defclass-p))
 606          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 607     (if direct-slots-p
 608         (setf (slot-value class 'direct-slots)
 609               (setq direct-slots
 610                     (mapcar (lambda (pl)
 611                               (when defstruct-p
 612                                 (let* ((slot-name (getf pl :name))
 613                                        (acc-name
 614                                         (format nil
 615                                                 "~S structure class ~A"
 616                                                 name slot-name))
 617                                        (accessor (intern acc-name)))
 618                                   (setq pl (list* :defstruct-accessor-symbol
 619                                                   accessor pl))))
 620                               (make-direct-slotd class pl))
 621                             direct-slots)))
 622         (setq direct-slots (slot-value class 'direct-slots)))
 623     (when defstruct-p
 624       (let ((include (car (slot-value class 'direct-superclasses))))
 625         (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 626             (make-structure-class-defstruct-form name direct-slots include)
 627           (unless (structure-type-p name) (eval defstruct-form))
 628           (mapc (lambda (dslotd reader-name writer-name)
 629                   (let* ((reader (gdefinition reader-name))
 630                          (writer (when (gboundp writer-name)
 631                                    (gdefinition writer-name))))
 632                     (setf (slot-value dslotd 'internal-reader-function)
 633                           reader)
 634                     (setf (slot-value dslotd 'internal-writer-function)
 635                           writer)))
 636                 direct-slots reader-names writer-names)
 637           (setf (slot-value class 'defstruct-form) defstruct-form)
 638           (setf (slot-value class 'defstruct-constructor) constructor))))
 639     (add-direct-subclasses class direct-superclasses)
 640     (setf (slot-value class 'class-precedence-list)
 641             (compute-class-precedence-list class))
 642     (setf (slot-value class 'slots) (compute-slots class))
 643     (let ((lclass (find-classoid (class-name class))))
 644       (setf (classoid-pcl-class lclass) class)
 645       (setf (slot-value class 'wrapper) (classoid-layout lclass)))
 646     (update-pv-table-cache-info class)
 647     (setq predicate-name (if predicate-name-p
 648                            (setf (slot-value class 'predicate-name)
 649                                    (car predicate-name))
 650                            (or (slot-value class 'predicate-name)
 651                                (setf (slot-value class 'predicate-name)
 652                                        (make-class-predicate-name
 653                                         (class-name class))))))
 654     (make-class-predicate class predicate-name)
 655     (add-slot-accessors class direct-slots)))
 656
 657 (defmethod direct-slot-definition-class ((class structure-class) initargs)
 658   (declare (ignore initargs))
 659   (find-class 'structure-direct-slot-definition))
 660
 661 (defmethod finalize-inheritance ((class structure-class))
 662   nil) ; always finalized
 663 \f
 664 (defun add-slot-accessors (class dslotds)
 665   (fix-slot-accessors class dslotds 'add))
 666
 667 (defun remove-slot-accessors (class dslotds)
 668   (fix-slot-accessors class dslotds 'remove))
 669
 670 (defun fix-slot-accessors (class dslotds add/remove)
 671   (flet ((fix (gfspec name r/w)
 672            (let ((gf (ensure-generic-function gfspec)))
 673              (case r/w
 674                (r (if (eq add/remove 'add)
 675                       (add-reader-method class gf name)
 676                       (remove-reader-method class gf)))
 677                (w (if (eq add/remove 'add)
 678                       (add-writer-method class gf name)
 679                       (remove-writer-method class gf)))))))
 680     (dolist (dslotd dslotds)
 681       (let ((slot-name (slot-definition-name dslotd)))
 682         (dolist (r (slot-definition-readers dslotd)) (fix r slot-name 'r))
 683         (dolist (w (slot-definition-writers dslotd)) (fix w slot-name 'w))))))
 684 \f
 685 (defun add-direct-subclasses (class supers)
 686   (dolist (super supers)
 687     (unless (memq class (class-direct-subclasses class))
 688       (add-direct-subclass super class))))
 689
 690 (defun remove-direct-subclasses (class supers)
 691   (let ((old (class-direct-superclasses class)))
 692     (dolist (o (set-difference old supers))
 693       (remove-direct-subclass o class))))
 694 \f
 695 (defmethod finalize-inheritance ((class std-class))
 696   (update-class class t))
 697
 698 (defmethod finalize-inheritance ((class forward-referenced-class))
 699   ;; FIXME: should we not be thinking a bit about what kinds of error
 700   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 701   ;; possibly a forward-referenced-class-error, though that's
 702   ;; difficult given e.g. class precedence list calculations...
 703   (error
 704    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 705        ~2I~_~S~:>"
 706    class))
 707
 708 \f
 709 (defun class-has-a-forward-referenced-superclass-p (class)
 710   (or (forward-referenced-class-p class)
 711       (some #'class-has-a-forward-referenced-superclass-p
 712             (class-direct-superclasses class))))
 713
 714 ;;; This is called by :after shared-initialize whenever a class is initialized
 715 ;;; or reinitialized. The class may or may not be finalized.
 716 (defun update-class (class finalizep)
 717   ;; Comment from Gerd Moellmann:
 718   ;;
 719   ;; Note that we can't simply delay the finalization when CLASS has
 720   ;; no forward referenced superclasses because that causes bootstrap
 721   ;; problems.
 722   (when (and (not finalizep)
 723              (not (class-finalized-p class))
 724              (not (class-has-a-forward-referenced-superclass-p class)))
 725     (finalize-inheritance class)
 726     (return-from update-class))
 727   (when (or finalizep (class-finalized-p class)
 728             (not (class-has-a-forward-referenced-superclass-p class)))
 729     (update-cpl class (compute-class-precedence-list class))
 730     ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 731     ;; class.  The hoops above are to ensure that FINALIZE-INHERITANCE
 732     ;; is called at finalization, so that MOP programmers can hook
 733     ;; into the system as described in "Class Finalization Protocol"
 734     ;; (section 5.5.2 of AMOP).
 735     (update-slots class (compute-slots class))
 736     (update-gfs-of-class class)
 737     (update-inits class (compute-default-initargs class))
 738     (update-ctors 'finalize-inheritance :class class))
 739   (unless finalizep
 740     (dolist (sub (class-direct-subclasses class)) (update-class sub nil))))
 741
 742 (defun update-cpl (class cpl)
 743   (if (class-finalized-p class)
 744       (unless (equal (class-precedence-list class) cpl)
 745         ;; comment from the old CMU CL sources:
 746         ;;   Need to have the cpl setup before update-lisp-class-layout
 747         ;;   is called on CMU CL.
 748         (setf (slot-value class 'class-precedence-list) cpl)
 749         (force-cache-flushes class))
 750       (setf (slot-value class 'class-precedence-list) cpl))
 751   (update-class-can-precede-p cpl))
 752
 753 (defun update-class-can-precede-p (cpl)
 754   (when cpl
 755     (let ((first (car cpl)))
 756       (dolist (c (cdr cpl))
 757         (pushnew c (slot-value first 'can-precede-list))))
 758     (update-class-can-precede-p (cdr cpl))))
 759
 760 (defun class-can-precede-p (class1 class2)
 761   (member class2 (class-can-precede-list class1)))
 762
 763 (defun update-slots (class eslotds)
 764   (let ((instance-slots ())
 765         (class-slots    ()))
 766     (dolist (eslotd eslotds)
 767       (let ((alloc (slot-definition-allocation eslotd)))
 768         (case alloc
 769           (:instance (push eslotd instance-slots))
 770           (:class (push eslotd class-slots)))))
 771
 772     ;; If there is a change in the shape of the instances then the
 773     ;; old class is now obsolete.
 774     (let* ((nlayout (mapcar #'slot-definition-name
 775                             (sort instance-slots #'<
 776                                   :key #'slot-definition-location)))
 777            (nslots (length nlayout))
 778            (nwrapper-class-slots (compute-class-slots class-slots))
 779            (owrapper (class-wrapper class))
 780            (olayout (and owrapper (wrapper-instance-slots-layout owrapper)))
 781            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 782            (nwrapper
 783             (cond ((null owrapper)
 784                    (make-wrapper nslots class))
 785                   ((and (equal nlayout olayout)
 786                         (not
 787                          (loop for o in owrapper-class-slots
 788                                for n in nwrapper-class-slots
 789                                do (unless (eq (car o) (car n)) (return t)))))
 790                    owrapper)
 791                   (t
 792                    ;; This will initialize the new wrapper to have the
 793                    ;; same state as the old wrapper. We will then have
 794                    ;; to change that. This may seem like wasted work
 795                    ;; (and it is), but the spec requires that we call
 796                    ;; MAKE-INSTANCES-OBSOLETE.
 797                    (make-instances-obsolete class)
 798                    (class-wrapper class)))))
 799
 800       (with-slots (wrapper slots) class
 801         (update-lisp-class-layout class nwrapper)
 802         (setf slots eslotds
 803               (wrapper-instance-slots-layout nwrapper) nlayout
 804               (wrapper-class-slots nwrapper) nwrapper-class-slots
 805               (wrapper-no-of-instance-slots nwrapper) nslots
 806               wrapper nwrapper))
 807
 808       (unless (eq owrapper nwrapper)
 809         (update-pv-table-cache-info class)))))
 810
 811 (defun compute-class-slots (eslotds)
 812   (let (collect)
 813     (dolist (eslotd eslotds)
 814       (push (assoc (slot-definition-name eslotd)
 815                    (class-slot-cells (slot-definition-class eslotd)))
 816             collect))
 817     (nreverse collect)))
 818
 819 (defun update-gfs-of-class (class)
 820   (when (and (class-finalized-p class)
 821              (let ((cpl (class-precedence-list class)))
 822                (or (member *the-class-slot-class* cpl)
 823                    (member *the-class-standard-effective-slot-definition*
 824                            cpl))))
 825     (let ((gf-table (make-hash-table :test 'eq)))
 826       (labels ((collect-gfs (class)
 827                  (dolist (gf (specializer-direct-generic-functions class))
 828                    (setf (gethash gf gf-table) t))
 829                  (mapc #'collect-gfs (class-direct-superclasses class))))
 830         (collect-gfs class)
 831         (maphash (lambda (gf ignore)
 832                    (declare (ignore ignore))
 833                    (update-gf-dfun class gf))
 834                  gf-table)))))
 835
 836 (defun update-inits (class inits)
 837   (setf (plist-value class 'default-initargs) inits))
 838 \f
 839 (defmethod compute-default-initargs ((class slot-class))
 840   (let ((cpl (class-precedence-list class))
 841         (direct (class-direct-default-initargs class)))
 842     (labels ((walk (tail)
 843                (if (null tail)
 844                    nil
 845                    (let ((c (pop tail)))
 846                      (append (if (eq c class)
 847                                  direct
 848                                  (class-direct-default-initargs c))
 849                              (walk tail))))))
 850       (let ((initargs (walk cpl)))
 851         (delete-duplicates initargs :test #'eq :key #'car :from-end t)))))
 852 \f
 853 ;;;; protocols for constructing direct and effective slot definitions
 854
 855 (defmethod direct-slot-definition-class ((class std-class) initargs)
 856   (declare (ignore initargs))
 857   (find-class 'standard-direct-slot-definition))
 858
 859 (defun make-direct-slotd (class initargs)
 860   (let ((initargs (list* :class class initargs)))
 861     (apply #'make-instance
 862            (direct-slot-definition-class class initargs)
 863            initargs)))
 864
 865 (defmethod compute-slots ((class std-class))
 866   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 867   ;; for each different slot name we find in our superclasses. Each
 868   ;; call receives the class and a list of the dslotds with that name.
 869   ;; The list is in most-specific-first order.
 870   (let ((name-dslotds-alist ()))
 871     (dolist (c (class-precedence-list class))
 872       (dolist (slot (class-direct-slots c))
 873         (let* ((name (slot-definition-name slot))
 874                (entry (assq name name-dslotds-alist)))
 875           (if entry
 876               (push slot (cdr entry))
 877               (push (list name slot) name-dslotds-alist)))))
 878     (mapcar (lambda (direct)
 879               (compute-effective-slot-definition class
 880                                                  (nreverse (cdr direct))))
 881             name-dslotds-alist)))
 882
 883 (defmethod compute-slots ((class standard-class))
 884   (call-next-method))
 885
 886 (defmethod compute-slots :around ((class standard-class))
 887   (let ((eslotds (call-next-method))
 888         (location -1))
 889     (dolist (eslotd eslotds eslotds)
 890       (setf (slot-definition-location eslotd)
 891             (ecase (slot-definition-allocation eslotd)
 892               (:instance
 893                (incf location))
 894               (:class
 895                (let* ((name (slot-definition-name eslotd))
 896                       (from-class (slot-definition-allocation-class eslotd))
 897                       (cell (assq name (class-slot-cells from-class))))
 898                  (aver (consp cell))
 899                  cell))))
 900       (initialize-internal-slot-functions eslotd))))
 901
 902 (defmethod compute-slots ((class funcallable-standard-class))
 903   (call-next-method))
 904
 905 (defmethod compute-slots :around ((class funcallable-standard-class))
 906   (labels ((instance-slot-names (slotds)
 907              (let (collect)
 908                (dolist (slotd slotds (nreverse collect))
 909                  (when (eq (slot-definition-allocation slotd) :instance)
 910                    (push (slot-definition-name slotd) collect)))))
 911            ;; This sorts slots so that slots of classes later in the CPL
 912            ;; come before slots of other classes.  This is crucial for
 913            ;; funcallable instances because it ensures that the slots of
 914            ;; FUNCALLABLE-STANDARD-OBJECT, which includes the slots of
 915            ;; KERNEL:FUNCALLABLE-INSTANCE, come first, which in turn
 916            ;; makes it possible to treat FUNCALLABLE-STANDARD-OBJECT as
 917            ;; a funcallable instance.
 918            (compute-layout (eslotds)
 919              (let ((first ())
 920                    (names (instance-slot-names eslotds)))
 921                (dolist (class
 922                         (reverse (class-precedence-list class))
 923                         (nreverse (nconc names first)))
 924                  (dolist (ss (class-slots class))
 925                    (let ((name (slot-definition-name ss)))
 926                      (when (member name names)
 927                        (push name first)
 928                        (setq names (delete name names)))))))))
 929     (let ((all-slotds (call-next-method))
 930           (instance-slots ())
 931           (class-slots ()))
 932       (dolist (slotd all-slotds)
 933         (ecase (slot-definition-allocation slotd)
 934           (:instance (push slotd instance-slots))
 935           (:class (push slotd class-slots))))
 936       (let ((layout (compute-layout instance-slots)))
 937         (dolist (slotd instance-slots)
 938           (setf (slot-definition-location slotd)
 939                 (position (slot-definition-name slotd) layout))
 940           (initialize-internal-slot-functions slotd)))
 941       (dolist (slotd class-slots)
 942         (let ((name (slot-definition-name slotd))
 943               (from-class (slot-definition-allocation-class slotd)))
 944           (setf (slot-definition-location slotd)
 945                 (assoc name (class-slot-cells from-class)))
 946           (aver (consp (slot-definition-location slotd)))
 947           (initialize-internal-slot-functions slotd)))
 948       all-slotds)))
 949
 950 (defmethod compute-slots ((class structure-class))
 951   (mapcan (lambda (superclass)
 952             (mapcar (lambda (dslotd)
 953                       (compute-effective-slot-definition class
 954                                                          (list dslotd)))
 955                     (class-direct-slots superclass)))
 956           (reverse (slot-value class 'class-precedence-list))))
 957
 958 (defmethod compute-slots :around ((class structure-class))
 959   (let ((eslotds (call-next-method)))
 960     (mapc #'initialize-internal-slot-functions eslotds)
 961     eslotds))
 962
 963 (defmethod compute-effective-slot-definition ((class slot-class) dslotds)
 964   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
 965          (class (effective-slot-definition-class class initargs)))
 966     (apply #'make-instance class initargs)))
 967
 968 (defmethod effective-slot-definition-class ((class std-class) initargs)
 969   (declare (ignore initargs))
 970   (find-class 'standard-effective-slot-definition))
 971
 972 (defmethod effective-slot-definition-class ((class structure-class) initargs)
 973   (declare (ignore initargs))
 974   (find-class 'structure-effective-slot-definition))
 975
 976 (defmethod compute-effective-slot-definition-initargs
 977     ((class slot-class) direct-slotds)
 978   (let* ((name nil)
 979          (initfunction nil)
 980          (initform nil)
 981          (initargs nil)
 982          (allocation nil)
 983          (allocation-class nil)
 984          (type t)
 985          (namep  nil)
 986          (initp  nil)
 987          (allocp nil))
 988
 989     (dolist (slotd direct-slotds)
 990       (when slotd
 991         (unless namep
 992           (setq name (slot-definition-name slotd)
 993                 namep t))
 994         (unless initp
 995           (when (slot-definition-initfunction slotd)
 996             (setq initform (slot-definition-initform slotd)
 997                   initfunction (slot-definition-initfunction slotd)
 998                   initp t)))
 999         (unless allocp
1000           (setq allocation (slot-definition-allocation slotd)
1001                 allocation-class (slot-definition-class slotd)
1002                 allocp t))
1003         (setq initargs (append (slot-definition-initargs slotd) initargs))
1004         (let ((slotd-type (slot-definition-type slotd)))
1005           (setq type (cond ((eq type t) slotd-type)
1006                            ((*subtypep type slotd-type) type)
1007                            (t `(and ,type ,slotd-type)))))))
1008     (list :name name
1009           :initform initform
1010           :initfunction initfunction
1011           :initargs initargs
1012           :allocation allocation
1013           :allocation-class allocation-class
1014           :type type
1015           :class class)))
1016
1017 (defmethod compute-effective-slot-definition-initargs :around
1018     ((class structure-class) direct-slotds)
1019   (let ((slotd (car direct-slotds)))
1020     (list* :defstruct-accessor-symbol
1021            (slot-definition-defstruct-accessor-symbol slotd)
1022            :internal-reader-function
1023            (slot-definition-internal-reader-function slotd)
1024            :internal-writer-function
1025            (slot-definition-internal-writer-function slotd)
1026            (call-next-method))))
1027 \f
1028 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1029 ;;;       to make the method object. They have to use make-a-method which
1030 ;;;       is a specially bootstrapped mechanism for making standard methods.
1031 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1032   (declare (ignore direct-slot initargs))
1033   (find-class 'standard-reader-method))
1034
1035 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
1036   (add-method generic-function
1037               (make-a-method 'standard-reader-method
1038                              ()
1039                              (list (or (class-name class) 'object))
1040                              (list class)
1041                              (make-reader-method-function class slot-name)
1042                              "automatically generated reader method"
1043                              slot-name)))
1044
1045 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1046   (declare (ignore direct-slot initargs))
1047   (find-class 'standard-writer-method))
1048
1049 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
1050   (add-method generic-function
1051               (make-a-method 'standard-writer-method
1052                              ()
1053                              (list 'new-value (or (class-name class) 'object))
1054                              (list *the-class-t* class)
1055                              (make-writer-method-function class slot-name)
1056                              "automatically generated writer method"
1057                              slot-name)))
1058
1059 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
1060   (add-method generic-function
1061               (make-a-method 'standard-boundp-method
1062                              ()
1063                              (list (or (class-name class) 'object))
1064                              (list class)
1065                              (make-boundp-method-function class slot-name)
1066                              "automatically generated boundp method"
1067                              slot-name)))
1068
1069 (defmethod remove-reader-method ((class slot-class) generic-function)
1070   (let ((method (get-method generic-function () (list class) nil)))
1071     (when method (remove-method generic-function method))))
1072
1073 (defmethod remove-writer-method ((class slot-class) generic-function)
1074   (let ((method
1075           (get-method generic-function () (list *the-class-t* class) nil)))
1076     (when method (remove-method generic-function method))))
1077
1078 (defmethod remove-boundp-method ((class slot-class) generic-function)
1079   (let ((method (get-method generic-function () (list class) nil)))
1080     (when method (remove-method generic-function method))))
1081 \f
1082 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITE-METHOD function are NOT
1083 ;;; part of the standard protocol. They are however useful, PCL makes
1084 ;;; use of them internally and documents them for PCL users.
1085 ;;;
1086 ;;; *** This needs work to make type testing by the writer functions which
1087 ;;; *** do type testing faster. The idea would be to have one constructor
1088 ;;; *** for each possible type test.
1089 ;;;
1090 ;;; *** There is a subtle bug here which is going to have to be fixed.
1091 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1092 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1093 ;;; *** defined for this metaclass a chance to run.
1094
1095 (defmethod make-reader-method-function ((class slot-class) slot-name)
1096   (make-std-reader-method-function (class-name class) slot-name))
1097
1098 (defmethod make-writer-method-function ((class slot-class) slot-name)
1099   (make-std-writer-method-function (class-name class) slot-name))
1100
1101 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1102   (make-std-boundp-method-function (class-name class) slot-name))
1103 \f
1104 (defmethod compatible-meta-class-change-p (class proto-new-class)
1105   (eq (class-of class) (class-of proto-new-class)))
1106
1107 (defmethod validate-superclass ((class class) (new-super class))
1108   (or (eq new-super *the-class-t*)
1109       (eq (class-of class) (class-of new-super))))
1110
1111 (defmethod validate-superclass ((class standard-class) (new-super std-class))
1112   (let ((new-super-meta-class (class-of new-super)))
1113     (or (eq new-super-meta-class *the-class-std-class*)
1114         (eq (class-of class) new-super-meta-class))))
1115 \f
1116 ;;; What this does depends on which of the four possible values of
1117 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1118 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1119 ;;; nothing to do, as the new wrapper has already been created.  If
1120 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1121 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1122 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1123 ;;;
1124 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1125 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1126 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1127 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1128 ;;; obsolete the wrapper.
1129 ;;;
1130 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1131 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1132 ;;;                    :UNINITIALIZED)))
1133 ;;;
1134 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1135 (defun force-cache-flushes (class)
1136   (let* ((owrapper (class-wrapper class)))
1137     ;; We only need to do something if the wrapper is still valid. If
1138     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1139     ;; both of those will already be doing what we want. In
1140     ;; particular, we must be sure we never change an OBSOLETE into a
1141     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1142     (when (or (not (invalid-wrapper-p owrapper))
1143               ;; KLUDGE: despite the observations above, this remains
1144               ;; a violation of locality or what might be considered
1145               ;; good style.  There has to be a better way!  -- CSR,
1146               ;; 2002-10-29
1147               (eq (layout-invalid owrapper) t))
1148       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1149                                     class)))
1150         (setf (wrapper-instance-slots-layout nwrapper)
1151               (wrapper-instance-slots-layout owrapper))
1152         (setf (wrapper-class-slots nwrapper)
1153               (wrapper-class-slots owrapper))
1154         (sb-sys:without-interrupts
1155           (update-lisp-class-layout class nwrapper)
1156           (setf (slot-value class 'wrapper) nwrapper)
1157           (invalidate-wrapper owrapper :flush nwrapper))))))
1158
1159 (defun flush-cache-trap (owrapper nwrapper instance)
1160   (declare (ignore owrapper))
1161   (set-wrapper instance nwrapper))
1162 \f
1163 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1164 ;;; the next access to the instance (as defined in 88-002R) to trap
1165 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1166 (defmethod make-instances-obsolete ((class std-class))
1167   (let* ((owrapper (class-wrapper class))
1168          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1169                                  class)))
1170       (setf (wrapper-instance-slots-layout nwrapper)
1171             (wrapper-instance-slots-layout owrapper))
1172       (setf (wrapper-class-slots nwrapper)
1173             (wrapper-class-slots owrapper))
1174       (sb-sys:without-interrupts
1175         (update-lisp-class-layout class nwrapper)
1176         (setf (slot-value class 'wrapper) nwrapper)
1177         (invalidate-wrapper owrapper :obsolete nwrapper)
1178         class)))
1179
1180 (defmethod make-instances-obsolete ((class symbol))
1181   (make-instances-obsolete (find-class class)))
1182
1183 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1184 ;;; see an obsolete instance. The times when it is called are:
1185 ;;;   - when the instance is involved in method lookup
1186 ;;;   - when attempting to access a slot of an instance
1187 ;;;
1188 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1189 ;;; instance access macros.
1190 ;;;
1191 ;;; Of course these times when it is called are an internal
1192 ;;; implementation detail of PCL and are not part of the documented
1193 ;;; description of when the obsolete instance update happens. The
1194 ;;; documented description is as it appears in 88-002R.
1195 ;;;
1196 ;;; This has to return the new wrapper, so it counts on all the
1197 ;;; methods on obsolete-instance-trap-internal to return the new
1198 ;;; wrapper. It also does a little internal error checking to make
1199 ;;; sure that the traps are only happening when they should, and that
1200 ;;; the trap methods are computing appropriate new wrappers.
1201
1202 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1203 ;;; after a structure is redefined. In most cases,
1204 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1205 ;;; so it must signal an error. The hard part of this is that the
1206 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1207 ;;; called again, so in that case, we have to return some reasonable
1208 ;;; wrapper, instead.
1209
1210 (defvar *in-obsolete-instance-trap* nil)
1211 (defvar *the-wrapper-of-structure-object*
1212   (class-wrapper (find-class 'structure-object)))
1213
1214 (define-condition obsolete-structure (error)
1215   ((datum :reader obsolete-structure-datum :initarg :datum))
1216   (:report
1217    (lambda (condition stream)
1218      ;; Don't try to print the structure, since it probably won't work.
1219      (format stream
1220              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1221              (type-of (obsolete-structure-datum condition))))))
1222
1223 (defun obsolete-instance-trap (owrapper nwrapper instance)
1224   (if (not (pcl-instance-p instance))
1225       (if *in-obsolete-instance-trap*
1226           *the-wrapper-of-structure-object*
1227            (let ((*in-obsolete-instance-trap* t))
1228              (error 'obsolete-structure :datum instance)))
1229       (let* ((class (wrapper-class* nwrapper))
1230              (copy (allocate-instance class)) ;??? allocate-instance ???
1231              (olayout (wrapper-instance-slots-layout owrapper))
1232              (nlayout (wrapper-instance-slots-layout nwrapper))
1233              (oslots (get-slots instance))
1234              (nslots (get-slots copy))
1235              (oclass-slots (wrapper-class-slots owrapper))
1236              (added ())
1237              (discarded ())
1238              (plist ()))
1239         ;; local  --> local     transfer
1240         ;; local  --> shared       discard
1241         ;; local  -->  --         discard
1242         ;; shared --> local     transfer
1243         ;; shared --> shared       discard
1244         ;; shared -->  --         discard
1245         ;;  --    --> local     add
1246         ;;  --    --> shared    --
1247
1248         ;; Go through all the old local slots.
1249         (let ((opos 0))
1250           (dolist (name olayout)
1251             (let ((npos (posq name nlayout)))
1252               (if npos
1253                   (setf (clos-slots-ref nslots npos)
1254                         (clos-slots-ref oslots opos))
1255                   (progn
1256                     (push name discarded)
1257                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1258                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1259             (incf opos)))
1260
1261         ;; Go through all the old shared slots.
1262         (dolist (oclass-slot-and-val oclass-slots)
1263           (let ((name (car oclass-slot-and-val))
1264                 (val (cdr oclass-slot-and-val)))
1265             (let ((npos (posq name nlayout)))
1266               (if npos
1267                   (setf (clos-slots-ref nslots npos) (cdr oclass-slot-and-val))
1268                   (progn (push name discarded)
1269                          (unless (eq val +slot-unbound+)
1270                            (setf (getf plist name) val)))))))
1271
1272         ;; Go through all the new local slots to compute the added slots.
1273         (dolist (nlocal nlayout)
1274           (unless (or (memq nlocal olayout)
1275                       (assq nlocal oclass-slots))
1276             (push nlocal added)))
1277
1278         (swap-wrappers-and-slots instance copy)
1279
1280         (update-instance-for-redefined-class instance
1281                                              added
1282                                              discarded
1283                                              plist)
1284         nwrapper)))
1285 \f
1286 (defun change-class-internal (instance new-class initargs)
1287   (let* ((old-class (class-of instance))
1288          (copy (allocate-instance new-class))
1289          (new-wrapper (get-wrapper copy))
1290          (old-wrapper (class-wrapper old-class))
1291          (old-layout (wrapper-instance-slots-layout old-wrapper))
1292          (new-layout (wrapper-instance-slots-layout new-wrapper))
1293          (old-slots (get-slots instance))
1294          (new-slots (get-slots copy))
1295          (old-class-slots (wrapper-class-slots old-wrapper)))
1296
1297     ;; "The values of local slots specified by both the class CTO and
1298     ;; CFROM are retained. If such a local slot was unbound, it
1299     ;; remains unbound."
1300     (let ((new-position 0))
1301       (dolist (new-slot new-layout)
1302         (let ((old-position (posq new-slot old-layout)))
1303           (when old-position
1304             (setf (clos-slots-ref new-slots new-position)
1305                   (clos-slots-ref old-slots old-position))))
1306         (incf new-position)))
1307
1308     ;; "The values of slots specified as shared in the class CFROM and
1309     ;; as local in the class CTO are retained."
1310     (dolist (slot-and-val old-class-slots)
1311       (let ((position (posq (car slot-and-val) new-layout)))
1312         (when position
1313           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1314
1315     ;; Make the copy point to the old instance's storage, and make the
1316     ;; old instance point to the new storage.
1317     (swap-wrappers-and-slots instance copy)
1318
1319     (apply #'update-instance-for-different-class copy instance initargs)
1320     instance))
1321
1322 (defmethod change-class ((instance standard-object)
1323                          (new-class standard-class)
1324                          &rest initargs)
1325   (change-class-internal instance new-class initargs))
1326
1327 (defmethod change-class ((instance funcallable-standard-object)
1328                          (new-class funcallable-standard-class)
1329                          &rest initargs)
1330   (change-class-internal instance new-class initargs))
1331
1332 (defmethod change-class ((instance standard-object)
1333                          (new-class funcallable-standard-class)
1334                          &rest initargs)
1335   (declare (ignore initargs))
1336   (error "You can't change the class of ~S to ~S~@
1337           because it isn't already an instance with metaclass ~S."
1338          instance new-class 'standard-class))
1339
1340 (defmethod change-class ((instance funcallable-standard-object)
1341                          (new-class standard-class)
1342                          &rest initargs)
1343   (declare (ignore initargs))
1344   (error "You can't change the class of ~S to ~S~@
1345           because it isn't already an instance with metaclass ~S."
1346          instance new-class 'funcallable-standard-class))
1347
1348 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1349   (apply #'change-class instance (find-class new-class-name) initargs))
1350 \f
1351 ;;;; The metaclass BUILT-IN-CLASS
1352 ;;;;
1353 ;;;; This metaclass is something of a weird creature. By this point, all
1354 ;;;; instances of it which will exist have been created, and no instance
1355 ;;;; is ever created by calling MAKE-INSTANCE.
1356 ;;;;
1357 ;;;; But, there are other parts of the protocol we must follow and those
1358 ;;;; definitions appear here.
1359
1360 (defmethod shared-initialize :before
1361            ((class built-in-class) slot-names &rest initargs)
1362   (declare (ignore slot-names initargs))
1363   (error "attempt to initialize or reinitialize a built in class"))
1364
1365 (defmethod class-direct-slots       ((class built-in-class)) ())
1366 (defmethod class-slots             ((class built-in-class)) ())
1367 (defmethod class-direct-default-initargs ((class built-in-class)) ())
1368 (defmethod class-default-initargs       ((class built-in-class)) ())
1369
1370 (defmethod validate-superclass ((c class) (s built-in-class))
1371   (or (eq s *the-class-t*)
1372       (eq s *the-class-stream*)))
1373 \f
1374 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1375 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1376 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1377 (macrolet ((def (method)
1378              `(defmethod ,method ((class forward-referenced-class))
1379                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1380                        ',method class))))
1381   (def class-default-initargs)
1382   (def class-precedence-list)
1383   (def class-slots))
1384
1385 (defmethod validate-superclass ((c slot-class)
1386                                 (f forward-referenced-class))
1387   t)
1388 \f
1389 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1390   (pushnew dependent (plist-value metaobject 'dependents)))
1391
1392 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1393   (setf (plist-value metaobject 'dependents)
1394         (delete dependent (plist-value metaobject 'dependents))))
1395
1396 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1397   (dolist (dependent (plist-value metaobject 'dependents))
1398     (funcall function dependent)))
1399