src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd 'class)))
  76     (let ((table (or (gethash name *name->class->slotd-table*)
  77                      (setf (gethash name *name->class->slotd-table*)
  78                            (make-hash-table :test 'eq :size 5)))))
  79       (setf (gethash class table) slotd))
  80     (dolist (type '(reader writer boundp))
  81       (let* ((gf-name (ecase type
  82                               (reader 'slot-value-using-class)
  83                               (writer '(setf slot-value-using-class))
  84                               (boundp 'slot-boundp-using-class)))
  85              (gf (gdefinition gf-name)))
  86         (compute-slot-accessor-info slotd type gf)))
  87     (initialize-internal-slot-gfs name)))
  88
  89 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  90                                        type gf)
  91   (let* ((name (slot-value slotd 'name))
  92          (class (slot-value slotd 'class))
  93          (old-slotd (find-slot-definition class name))
  94          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
  95     (multiple-value-bind (function std-p)
  96         (if (eq *boot-state* 'complete)
  97             (get-accessor-method-function gf type class slotd)
  98             (get-optimized-std-accessor-method-function class slotd type))
  99       (setf (slot-accessor-std-p slotd type) std-p)
 100       (setf (slot-accessor-function slotd type) function))
 101     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 102       (push (cons class name) *pv-table-cache-update-info*))))
 103
 104 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 105   :instance)
 106 \f
 107 (defmethod shared-initialize :after ((object documentation-mixin)
 108                                      slot-names
 109                                      &key (documentation nil documentation-p))
 110   (declare (ignore slot-names))
 111   (when documentation-p
 112     (setf (plist-value object 'documentation) documentation)))
 113
 114 ;;; default if DOC-TYPE doesn't match one of the specified types
 115 (defmethod documentation (object doc-type)
 116   (warn "unsupported DOCUMENTATION: type ~S for object ~S"
 117         doc-type
 118         (type-of object))
 119   nil)
 120
 121 ;;; default if DOC-TYPE doesn't match one of the specified types
 122 (defmethod (setf documentation) (new-value object doc-type)
 123   ;; CMU CL made this an error, but since ANSI says that even for supported
 124   ;; doc types an implementation is permitted to discard docs at any time
 125   ;; for any reason, this feels to me more like a warning. -- WHN 19991214
 126   (warn "discarding unsupported DOCUMENTATION of type ~S for object ~S"
 127         doc-type
 128         (type-of object))
 129   new-value)
 130
 131 (defmethod documentation ((object documentation-mixin) doc-type)
 132   (declare (ignore doc-type))
 133   (plist-value object 'documentation))
 134
 135 (defmethod (setf documentation) (new-value
 136                                  (object documentation-mixin)
 137                                  doc-type)
 138   (declare (ignore doc-type))
 139   (setf (plist-value object 'documentation) new-value))
 140
 141 (defmethod documentation ((slotd standard-slot-definition) doc-type)
 142   (declare (ignore doc-type))
 143   (slot-value slotd 'documentation))
 144
 145 (defmethod (setf documentation) (new-value
 146                                  (slotd standard-slot-definition)
 147                                  doc-type)
 148   (declare (ignore doc-type))
 149   (setf (slot-value slotd 'documentation) new-value))
 150 \f
 151 ;;;; various class accessors that are a little more complicated than can be
 152 ;;;; done with automatically generated reader methods
 153
 154 (defmethod class-finalized-p ((class pcl-class))
 155   (with-slots (wrapper) class
 156     (not (null wrapper))))
 157
 158 (defmethod class-prototype ((class std-class))
 159   (with-slots (prototype) class
 160     (or prototype (setq prototype (allocate-instance class)))))
 161
 162 (defmethod class-prototype ((class structure-class))
 163   (with-slots (prototype wrapper defstruct-constructor) class
 164     (or prototype
 165         (setq prototype
 166               (if defstruct-constructor
 167                   (allocate-instance class)
 168                   (allocate-standard-instance wrapper))))))
 169
 170 (defmethod class-direct-default-initargs ((class slot-class))
 171   (plist-value class 'direct-default-initargs))
 172
 173 (defmethod class-default-initargs ((class slot-class))
 174   (plist-value class 'default-initargs))
 175
 176 (defmethod class-constructors ((class slot-class))
 177   (plist-value class 'constructors))
 178
 179 (defmethod class-slot-cells ((class std-class))
 180   (plist-value class 'class-slot-cells))
 181 \f
 182 ;;;; class accessors that are even a little bit more complicated than those
 183 ;;;; above. These have a protocol for updating them, we must implement that
 184 ;;;; protocol.
 185
 186 ;;; Maintaining the direct subclasses backpointers. The update methods are
 187 ;;; here, the values are read by an automatically generated reader method.
 188 (defmethod add-direct-subclass ((class class) (subclass class))
 189   (with-slots (direct-subclasses) class
 190     (pushnew subclass direct-subclasses)
 191     subclass))
 192 (defmethod remove-direct-subclass ((class class) (subclass class))
 193   (with-slots (direct-subclasses) class
 194     (setq direct-subclasses (remove subclass direct-subclasses))
 195     subclass))
 196
 197 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 198 ;;;
 199 ;;; There are four generic functions involved, each has one method for the
 200 ;;; class case and another method for the damned EQL specializers. All of
 201 ;;; these are specified methods and appear in their specified place in the
 202 ;;; class graph.
 203 ;;;
 204 ;;;   ADD-DIRECT-METHOD
 205 ;;;   REMOVE-DIRECT-METHOD
 206 ;;;   SPECIALIZER-DIRECT-METHODS
 207 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 208 ;;;
 209 ;;; In each case, we maintain one value which is a cons. The car is the list
 210 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 211 ;;; computed lazily.
 212 (defmethod add-direct-method ((specializer class) (method method))
 213   (with-slots (direct-methods) specializer
 214     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 215           (cdr direct-methods) ()))
 216   method)
 217 (defmethod remove-direct-method ((specializer class) (method method))
 218   (with-slots (direct-methods) specializer
 219     (setf (car direct-methods) (remove method (car direct-methods))
 220           (cdr direct-methods) ()))
 221   method)
 222
 223 (defmethod specializer-direct-methods ((specializer class))
 224   (with-slots (direct-methods) specializer
 225     (car direct-methods)))
 226
 227 (defmethod specializer-direct-generic-functions ((specializer class))
 228   (with-slots (direct-methods) specializer
 229     (or (cdr direct-methods)
 230         (setf (cdr direct-methods)
 231               (gathering1 (collecting-once)
 232                 (dolist (m (car direct-methods))
 233                   (gather1 (method-generic-function m))))))))
 234 \f
 235 ;;; This hash table is used to store the direct methods and direct generic
 236 ;;; functions of EQL specializers. Each value in the table is the cons.
 237 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 238 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 239
 240 (defmethod specializer-method-table ((specializer eql-specializer))
 241   *eql-specializer-methods*)
 242
 243 (defmethod specializer-method-table ((specializer class-eq-specializer))
 244   *class-eq-specializer-methods*)
 245
 246 (defmethod add-direct-method ((specializer specializer-with-object)
 247                               (method method))
 248   (let* ((object (specializer-object specializer))
 249          (table (specializer-method-table specializer))
 250          (entry (gethash object table)))
 251     (unless entry
 252       (setq entry
 253             (setf (gethash object table)
 254                   (cons nil nil))))
 255     (setf (car entry) (adjoin method (car entry))
 256           (cdr entry) ())
 257     method))
 258
 259 (defmethod remove-direct-method ((specializer specializer-with-object)
 260                                  (method method))
 261   (let* ((object (specializer-object specializer))
 262          (entry (gethash object (specializer-method-table specializer))))
 263     (when entry
 264       (setf (car entry) (remove method (car entry))
 265             (cdr entry) ()))
 266     method))
 267
 268 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 269   (car (gethash (specializer-object specializer)
 270                 (specializer-method-table specializer))))
 271
 272 (defmethod specializer-direct-generic-functions ((specializer
 273                                                   specializer-with-object))
 274   (let* ((object (specializer-object specializer))
 275          (entry (gethash object (specializer-method-table specializer))))
 276     (when entry
 277       (or (cdr entry)
 278           (setf (cdr entry)
 279                 (gathering1 (collecting-once)
 280                   (dolist (m (car entry))
 281                     (gather1 (method-generic-function m)))))))))
 282
 283 (defun map-specializers (function)
 284   (map-all-classes #'(lambda (class)
 285                        (funcall function (class-eq-specializer class))
 286                        (funcall function class)))
 287   (maphash #'(lambda (object methods)
 288                (declare (ignore methods))
 289                (intern-eql-specializer object))
 290            *eql-specializer-methods*)
 291   (maphash #'(lambda (object specl)
 292                (declare (ignore object))
 293                (funcall function specl))
 294            *eql-specializer-table*)
 295   nil)
 296
 297 (defun map-all-generic-functions (function)
 298   (let ((all-generic-functions (make-hash-table :test 'eq)))
 299     (map-specializers #'(lambda (specl)
 300                           (dolist (gf (specializer-direct-generic-functions
 301                                        specl))
 302                             (unless (gethash gf all-generic-functions)
 303                               (setf (gethash gf all-generic-functions) t)
 304                               (funcall function gf))))))
 305   nil)
 306
 307 (defmethod shared-initialize :after ((specl class-eq-specializer)
 308                                      slot-names
 309                                      &key)
 310   (declare (ignore slot-names))
 311   (setf (slot-value specl 'type) `(class-eq ,(specializer-class specl))))
 312
 313 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 314   (declare (ignore slot-names))
 315   (setf (slot-value specl 'type) `(eql ,(specializer-object specl))))
 316 \f
 317 (defun real-load-defclass (name metaclass-name supers slots other)
 318   (let ((res (apply #'ensure-class name :metaclass metaclass-name
 319                     :direct-superclasses supers
 320                     :direct-slots slots
 321                     :definition-source `((defclass ,name)
 322                                          ,*load-truename*)
 323                     other)))
 324     ;; Defclass of a class with a forward-referenced superclass does not
 325     ;; have a wrapper. RES is the incomplete PCL class. The Lisp class
 326     ;; does not yet exist. Maybe should return NIL in that case as RES
 327     ;; is not useful to the user?
 328     (and (class-wrapper res) (sb-kernel:layout-class (class-wrapper res)))))
 329
 330 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 331
 332 (defun ensure-class (name &rest all)
 333   (apply #'ensure-class-using-class name (find-class name nil) all))
 334
 335 (defmethod ensure-class-using-class (name (class null) &rest args &key)
 336   (multiple-value-bind (meta initargs)
 337       (ensure-class-values class args)
 338     (inform-type-system-about-class (class-prototype meta) name);***
 339     (setf class (apply #'make-instance meta :name name initargs)
 340           (find-class name) class)
 341     (inform-type-system-about-class class name)                 ;***
 342     class))
 343
 344 (defmethod ensure-class-using-class (name (class pcl-class) &rest args &key)
 345   (multiple-value-bind (meta initargs)
 346       (ensure-class-values class args)
 347     (unless (eq (class-of class) meta) (change-class class meta))
 348     (apply #'reinitialize-instance class initargs)
 349     (setf (find-class name) class)
 350     (inform-type-system-about-class class name)                 ;***
 351     class))
 352
 353 (defmethod class-predicate-name ((class t))
 354   'constantly-nil)
 355
 356 (defun ensure-class-values (class args)
 357   (let* ((initargs (copy-list args))
 358          (unsupplied (list 1))
 359          (supplied-meta   (getf initargs :metaclass unsupplied))
 360          (supplied-supers (getf initargs :direct-superclasses unsupplied))
 361          (supplied-slots  (getf initargs :direct-slots unsupplied))
 362          (meta
 363            (cond ((neq supplied-meta unsupplied)
 364                   (find-class supplied-meta))
 365                  ((or (null class)
 366                       (forward-referenced-class-p class))
 367                   *the-class-standard-class*)
 368                  (t
 369                   (class-of class)))))
 370     (flet ((fix-super (s)
 371              (cond ((classp s) s)
 372                    ((not (legal-class-name-p s))
 373                     (error "~S is not a class or a legal class name." s))
 374                    (t
 375                     (or (find-class s nil)
 376                         (setf (find-class s)
 377                               (make-instance 'forward-referenced-class
 378                                              :name s)))))))
 379       (loop (unless (remf initargs :metaclass) (return)))
 380       (loop (unless (remf initargs :direct-superclasses) (return)))
 381       (loop (unless (remf initargs :direct-slots) (return)))
 382       (values meta
 383               (list* :direct-superclasses
 384                      (and (neq supplied-supers unsupplied)
 385                           (mapcar #'fix-super supplied-supers))
 386                      :direct-slots
 387                      (and (neq supplied-slots unsupplied) supplied-slots)
 388                      initargs)))))
 389 \f
 390 #|| ; since it doesn't do anything
 391 (defmethod shared-initialize :before ((class std-class)
 392                                       slot-names
 393                                       &key direct-superclasses)
 394   (declare (ignore slot-names))
 395   ;; *** error checking
 396   )
 397 ||#
 398
 399 (defmethod shared-initialize :after
 400            ((class std-class)
 401             slot-names
 402             &key (direct-superclasses nil direct-superclasses-p)
 403                  (direct-slots nil direct-slots-p)
 404                  (direct-default-initargs nil direct-default-initargs-p)
 405                  (predicate-name nil predicate-name-p))
 406   (declare (ignore slot-names))
 407   (cond (direct-superclasses-p
 408          (setq direct-superclasses
 409                (or direct-superclasses
 410                    (list (if (funcallable-standard-class-p class)
 411                              *the-class-funcallable-standard-object*
 412                              *the-class-standard-object*))))
 413          (dolist (superclass direct-superclasses)
 414            (unless (validate-superclass class superclass)
 415              (error "The class ~S was specified as a~%
 416                      super-class of the class ~S;~%~
 417                      but the meta-classes ~S and~%~S are incompatible.~@
 418                      Define a method for ~S to avoid this error."
 419                      superclass class (class-of superclass) (class-of class)
 420                      'validate-superclass)))
 421          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 422         (t
 423          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 424   (setq direct-slots
 425         (if direct-slots-p
 426             (setf (slot-value class 'direct-slots)
 427                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 428                           direct-slots))
 429             (slot-value class 'direct-slots)))
 430   (if direct-default-initargs-p
 431       (setf (plist-value class 'direct-default-initargs)
 432             direct-default-initargs)
 433       (setq direct-default-initargs
 434             (plist-value class 'direct-default-initargs)))
 435   (setf (plist-value class 'class-slot-cells)
 436         (gathering1 (collecting)
 437           (dolist (dslotd direct-slots)
 438             (when (eq (slot-definition-allocation dslotd) class)
 439               (let ((initfunction (slot-definition-initfunction dslotd)))
 440                 (gather1 (cons (slot-definition-name dslotd)
 441                                (if initfunction
 442                                    (funcall initfunction)
 443                                    +slot-unbound+))))))))
 444   (setq predicate-name (if predicate-name-p
 445                            (setf (slot-value class 'predicate-name)
 446                                  (car predicate-name))
 447                            (or (slot-value class 'predicate-name)
 448                                (setf (slot-value class 'predicate-name)
 449                                      (make-class-predicate-name (class-name
 450                                                                  class))))))
 451   (add-direct-subclasses class direct-superclasses)
 452   (update-class class nil)
 453   (make-class-predicate class predicate-name)
 454   (add-slot-accessors class direct-slots))
 455
 456 (defmethod shared-initialize :before ((class class) slot-names &key name)
 457   (declare (ignore slot-names name))
 458   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 459   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 460   (setf (slot-value class 'type) `(class ,class))
 461   (setf (slot-value class 'class-eq-specializer)
 462         (make-instance 'class-eq-specializer :class class)))
 463
 464 (defmethod reinitialize-instance :before ((class slot-class) &key)
 465   (remove-direct-subclasses class (class-direct-superclasses class))
 466   (remove-slot-accessors    class (class-direct-slots class)))
 467
 468 (defmethod reinitialize-instance :after ((class slot-class)
 469                                          &rest initargs
 470                                          &key)
 471   (map-dependents class
 472                   #'(lambda (dependent)
 473                       (apply #'update-dependent class dependent initargs))))
 474
 475 (defmethod shared-initialize :after
 476       ((class structure-class)
 477        slot-names
 478        &key (direct-superclasses nil direct-superclasses-p)
 479             (direct-slots nil direct-slots-p)
 480             direct-default-initargs
 481             (predicate-name nil predicate-name-p))
 482   (declare (ignore slot-names direct-default-initargs))
 483   (if direct-superclasses-p
 484       (setf (slot-value class 'direct-superclasses)
 485             (or direct-superclasses
 486                 (setq direct-superclasses
 487                       (and (not (eq (class-name class) 'structure-object))
 488                            (list *the-class-structure-object*)))))
 489       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 490   (let* ((name (class-name class))
 491          (from-defclass-p (slot-value class 'from-defclass-p))
 492          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 493     (if direct-slots-p
 494         (setf (slot-value class 'direct-slots)
 495               (setq direct-slots
 496                     (mapcar #'(lambda (pl)
 497                                 (when defstruct-p
 498                                   (let* ((slot-name (getf pl :name))
 499                                          (acc-name
 500                                           (format nil
 501                                                   "~S structure class ~A"
 502                                                   name slot-name))
 503                                          (accessor (intern acc-name)))
 504                                     (setq pl (list* :defstruct-accessor-symbol
 505                                                     accessor pl))))
 506                                 (make-direct-slotd class pl))
 507                             direct-slots)))
 508         (setq direct-slots (slot-value class 'direct-slots)))
 509     (when defstruct-p
 510       (let* ((include (car (slot-value class 'direct-superclasses)))
 511              (conc-name (intern (format nil "~S structure class " name)))
 512              (constructor (intern (format nil "~A constructor" conc-name)))
 513              (defstruct `(defstruct (,name
 514                                       ,@(when include
 515                                           `((:include ,(class-name include))))
 516                                       (:print-function print-std-instance)
 517                                       (:predicate nil)
 518                                       (:conc-name ,conc-name)
 519                                       (:constructor ,constructor ()))
 520                            ,@(mapcar #'(lambda (slot)
 521                                          `(,(slot-definition-name slot)
 522                                            +slot-unbound+))
 523                                      direct-slots)))
 524              (reader-names (mapcar (lambda (slotd)
 525                                      (intern (format nil
 526                                                      "~A~A reader"
 527                                                      conc-name
 528                                                      (slot-definition-name
 529                                                       slotd))))
 530                                    direct-slots))
 531              (writer-names (mapcar (lambda (slotd)
 532                                      (intern (format nil
 533                                                      "~A~A writer"
 534                                                      conc-name
 535                                                      (slot-definition-name
 536                                                       slotd))))
 537                                    direct-slots))
 538              (readers-init
 539               (mapcar (lambda (slotd reader-name)
 540                         (let ((accessor
 541                                (slot-definition-defstruct-accessor-symbol
 542                                 slotd)))
 543                           `(defun ,reader-name (obj)
 544                              (declare (type ,name obj))
 545                              (,accessor obj))))
 546                       direct-slots reader-names))
 547              (writers-init
 548               (mapcar (lambda (slotd writer-name)
 549                         (let ((accessor
 550                                (slot-definition-defstruct-accessor-symbol
 551                                 slotd)))
 552                           `(defun ,writer-name (nv obj)
 553                              (declare (type ,name obj))
 554                              (setf (,accessor obj) nv))))
 555                       direct-slots writer-names))
 556              (defstruct-form
 557                `(progn
 558                   ,defstruct
 559                   ,@readers-init ,@writers-init
 560                   (cons nil nil))))
 561         (unless (structure-type-p name) (eval defstruct-form))
 562         (mapc #'(lambda (dslotd reader-name writer-name)
 563                   (let* ((reader (gdefinition reader-name))
 564                          (writer (when (gboundp writer-name)
 565                                    (gdefinition writer-name))))
 566                     (setf (slot-value dslotd 'internal-reader-function)
 567                           reader)
 568                     (setf (slot-value dslotd 'internal-writer-function)
 569                           writer)))
 570               direct-slots reader-names writer-names)
 571         (setf (slot-value class 'defstruct-form) defstruct-form)
 572         (setf (slot-value class 'defstruct-constructor) constructor))))
 573   (add-direct-subclasses class direct-superclasses)
 574   (setf (slot-value class 'class-precedence-list)
 575         (compute-class-precedence-list class))
 576   (setf (slot-value class 'slots) (compute-slots class))
 577   (let ((lclass (cl:find-class (class-name class))))
 578     (setf (sb-kernel:class-pcl-class lclass) class)
 579     (setf (slot-value class 'wrapper) (sb-kernel:class-layout lclass)))
 580   (update-pv-table-cache-info class)
 581   (setq predicate-name (if predicate-name-p
 582                            (setf (slot-value class 'predicate-name)
 583                                  (car predicate-name))
 584                            (or (slot-value class 'predicate-name)
 585                                (setf (slot-value class 'predicate-name)
 586                                      (make-class-predicate-name
 587                                       (class-name class))))))
 588   (make-class-predicate class predicate-name)
 589   (add-slot-accessors class direct-slots))
 590
 591 (defmethod direct-slot-definition-class ((class structure-class) initargs)
 592   (declare (ignore initargs))
 593   (find-class 'structure-direct-slot-definition))
 594
 595 (defmethod finalize-inheritance ((class structure-class))
 596   nil) ; always finalized
 597 \f
 598 (defun add-slot-accessors (class dslotds)
 599   (fix-slot-accessors class dslotds 'add))
 600
 601 (defun remove-slot-accessors (class dslotds)
 602   (fix-slot-accessors class dslotds 'remove))
 603
 604 (defun fix-slot-accessors (class dslotds add/remove)
 605   (flet ((fix (gfspec name r/w)
 606            (let ((gf (ensure-generic-function gfspec)))
 607              (case r/w
 608                (r (if (eq add/remove 'add)
 609                       (add-reader-method class gf name)
 610                       (remove-reader-method class gf)))
 611                (w (if (eq add/remove 'add)
 612                       (add-writer-method class gf name)
 613                       (remove-writer-method class gf)))))))
 614     (dolist (dslotd dslotds)
 615       (let ((slot-name (slot-definition-name dslotd)))
 616         (dolist (r (slot-definition-readers dslotd)) (fix r slot-name 'r))
 617         (dolist (w (slot-definition-writers dslotd)) (fix w slot-name 'w))))))
 618 \f
 619 (defun add-direct-subclasses (class new)
 620   (dolist (n new)
 621     (unless (memq class (class-direct-subclasses class))
 622       (add-direct-subclass n class))))
 623
 624 (defun remove-direct-subclasses (class new)
 625   (let ((old (class-direct-superclasses class)))
 626     (dolist (o (set-difference old new))
 627       (remove-direct-subclass o class))))
 628 \f
 629 (defmethod finalize-inheritance ((class std-class))
 630   (update-class class t))
 631 \f
 632 (defun class-has-a-forward-referenced-superclass-p (class)
 633   (or (forward-referenced-class-p class)
 634       (some #'class-has-a-forward-referenced-superclass-p
 635             (class-direct-superclasses class))))
 636
 637 ;;; This is called by :after shared-initialize whenever a class is initialized
 638 ;;; or reinitialized. The class may or may not be finalized.
 639 (defun update-class (class finalizep)
 640   (when (or finalizep (class-finalized-p class)
 641             (not (class-has-a-forward-referenced-superclass-p class)))
 642     (update-cpl class (compute-class-precedence-list class))
 643     (update-slots class (compute-slots class))
 644     (update-gfs-of-class class)
 645     (update-inits class (compute-default-initargs class))
 646     (update-make-instance-function-table class))
 647   (unless finalizep
 648     (dolist (sub (class-direct-subclasses class)) (update-class sub nil))))
 649
 650 (defun update-cpl (class cpl)
 651   (if (class-finalized-p class)
 652       (unless (equal (class-precedence-list class) cpl)
 653         ;; comment from the old CMU CL sources:
 654         ;;   Need to have the cpl setup before update-lisp-class-layout
 655         ;;   is called on CMU CL.
 656         (setf (slot-value class 'class-precedence-list) cpl)
 657         (force-cache-flushes class))
 658       (setf (slot-value class 'class-precedence-list) cpl))
 659   (update-class-can-precede-p cpl))
 660
 661 (defun update-class-can-precede-p (cpl)
 662   (when cpl
 663     (let ((first (car cpl)))
 664       (dolist (c (cdr cpl))
 665         (pushnew c (slot-value first 'can-precede-list))))
 666     (update-class-can-precede-p (cdr cpl))))
 667
 668 (defun class-can-precede-p (class1 class2)
 669   (member class2 (class-can-precede-list class1)))
 670
 671 (defun update-slots (class eslotds)
 672   (let ((instance-slots ())
 673         (class-slots    ()))
 674     (dolist (eslotd eslotds)
 675       (let ((alloc (slot-definition-allocation eslotd)))
 676         (cond ((eq alloc :instance) (push eslotd instance-slots))
 677               ((classp alloc)       (push eslotd class-slots)))))
 678
 679     ;; If there is a change in the shape of the instances then the
 680     ;; old class is now obsolete.
 681     (let* ((nlayout (mapcar #'slot-definition-name
 682                             (sort instance-slots #'<
 683                                   :key #'slot-definition-location)))
 684            (nslots (length nlayout))
 685            (nwrapper-class-slots (compute-class-slots class-slots))
 686            (owrapper (class-wrapper class))
 687            (olayout (and owrapper (wrapper-instance-slots-layout owrapper)))
 688            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 689            (nwrapper
 690             (cond ((null owrapper)
 691                    (make-wrapper nslots class))
 692                   ((and (equal nlayout olayout)
 693                         (not
 694                          (iterate ((o (list-elements owrapper-class-slots))
 695                                    (n (list-elements nwrapper-class-slots)))
 696                                   (unless (eq (car o) (car n)) (return t)))))
 697                    owrapper)
 698                   (t
 699                    ;; This will initialize the new wrapper to have the same
 700                    ;; state as the old wrapper. We will then have to change
 701                    ;; that. This may seem like wasted work (it is), but the
 702                    ;; spec requires that we call make-instances-obsolete.
 703                    (make-instances-obsolete class)
 704                    (class-wrapper class)))))
 705
 706       (with-slots (wrapper slots) class
 707         (update-lisp-class-layout class nwrapper)
 708         (setf slots eslotds
 709               (wrapper-instance-slots-layout nwrapper) nlayout
 710               (wrapper-class-slots nwrapper) nwrapper-class-slots
 711               (wrapper-no-of-instance-slots nwrapper) nslots
 712               wrapper nwrapper))
 713
 714       (unless (eq owrapper nwrapper)
 715         (update-pv-table-cache-info class)))))
 716
 717 (defun compute-class-slots (eslotds)
 718   (gathering1 (collecting)
 719     (dolist (eslotd eslotds)
 720       (gather1
 721         (assoc (slot-definition-name eslotd)
 722                (class-slot-cells (slot-definition-allocation eslotd)))))))
 723
 724 (defun compute-layout (cpl instance-eslotds)
 725   (let* ((names
 726            (gathering1 (collecting)
 727              (dolist (eslotd instance-eslotds)
 728                (when (eq (slot-definition-allocation eslotd) :instance)
 729                  (gather1 (slot-definition-name eslotd))))))
 730          (order ()))
 731     (labels ((rwalk (tail)
 732                (when tail
 733                  (rwalk (cdr tail))
 734                  (dolist (ss (class-slots (car tail)))
 735                    (let ((n (slot-definition-name ss)))
 736                      (when (member n names)
 737                        (setq order (cons n order)
 738                              names (remove n names))))))))
 739       (rwalk (if (slot-boundp (car cpl) 'slots)
 740                  cpl
 741                  (cdr cpl)))
 742       (reverse (append names order)))))
 743
 744 (defun update-gfs-of-class (class)
 745   (when (and (class-finalized-p class)
 746              (let ((cpl (class-precedence-list class)))
 747                (or (member *the-class-slot-class* cpl)
 748                    (member *the-class-standard-effective-slot-definition*
 749                            cpl))))
 750     (let ((gf-table (make-hash-table :test 'eq)))
 751       (labels ((collect-gfs (class)
 752                  (dolist (gf (specializer-direct-generic-functions class))
 753                    (setf (gethash gf gf-table) t))
 754                  (mapc #'collect-gfs (class-direct-superclasses class))))
 755         (collect-gfs class)
 756         (maphash #'(lambda (gf ignore)
 757                      (declare (ignore ignore))
 758                      (update-gf-dfun class gf))
 759                  gf-table)))))
 760
 761 (defun update-inits (class inits)
 762   (setf (plist-value class 'default-initargs) inits))
 763 \f
 764 (defmethod compute-default-initargs ((class slot-class))
 765   (let ((cpl (class-precedence-list class))
 766         (direct (class-direct-default-initargs class)))
 767     (labels ((walk (tail)
 768                (if (null tail)
 769                    nil
 770                    (let ((c (pop tail)))
 771                      (append (if (eq c class)
 772                                  direct
 773                                  (class-direct-default-initargs c))
 774                              (walk tail))))))
 775       (let ((initargs (walk cpl)))
 776         (delete-duplicates initargs :test #'eq :key #'car :from-end t)))))
 777 \f
 778 ;;;; protocols for constructing direct and effective slot definitions
 779
 780 (defmethod direct-slot-definition-class ((class std-class) initargs)
 781   (declare (ignore initargs))
 782   (find-class 'standard-direct-slot-definition))
 783
 784 (defun make-direct-slotd (class initargs)
 785   (let ((initargs (list* :class class initargs)))
 786     (apply #'make-instance
 787            (direct-slot-definition-class class initargs)
 788            initargs)))
 789
 790 (defmethod compute-slots ((class std-class))
 791   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 792   ;; for each different slot name we find in our superclasses. Each
 793   ;; call receives the class and a list of the dslotds with that name.
 794   ;; The list is in most-specific-first order.
 795   (let ((name-dslotds-alist ()))
 796     (dolist (c (class-precedence-list class))
 797       (let ((dslotds (class-direct-slots c)))
 798         (dolist (d dslotds)
 799           (let* ((name (slot-definition-name d))
 800                  (entry (assq name name-dslotds-alist)))
 801             (if entry
 802                 (push d (cdr entry))
 803                 (push (list name d) name-dslotds-alist))))))
 804     (mapcar #'(lambda (direct)
 805                 (compute-effective-slot-definition class
 806                                                    (nreverse (cdr direct))))
 807             name-dslotds-alist)))
 808
 809 (defmethod compute-slots :around ((class std-class))
 810   (let ((eslotds (call-next-method))
 811         (cpl (class-precedence-list class))
 812         (instance-slots ())
 813         (class-slots    ()))
 814     (dolist (eslotd eslotds)
 815       (let ((alloc (slot-definition-allocation eslotd)))
 816         (cond ((eq alloc :instance) (push eslotd instance-slots))
 817               ((classp alloc)       (push eslotd class-slots)))))
 818     (let ((nlayout (compute-layout cpl instance-slots)))
 819       (dolist (eslotd instance-slots)
 820         (setf (slot-definition-location eslotd)
 821               (position (slot-definition-name eslotd) nlayout))))
 822     (dolist (eslotd class-slots)
 823       (setf (slot-definition-location eslotd)
 824             (assoc (slot-definition-name eslotd)
 825                    (class-slot-cells (slot-definition-allocation eslotd)))))
 826     (mapc #'initialize-internal-slot-functions eslotds)
 827     eslotds))
 828
 829 (defmethod compute-slots ((class structure-class))
 830   (mapcan #'(lambda (superclass)
 831               (mapcar #'(lambda (dslotd)
 832                           (compute-effective-slot-definition class
 833                                                              (list dslotd)))
 834                       (class-direct-slots superclass)))
 835           (reverse (slot-value class 'class-precedence-list))))
 836
 837 (defmethod compute-slots :around ((class structure-class))
 838   (let ((eslotds (call-next-method)))
 839     (mapc #'initialize-internal-slot-functions eslotds)
 840     eslotds))
 841
 842 (defmethod compute-effective-slot-definition ((class slot-class) dslotds)
 843   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
 844          (class (effective-slot-definition-class class initargs)))
 845     (apply #'make-instance class initargs)))
 846
 847 (defmethod effective-slot-definition-class ((class std-class) initargs)
 848   (declare (ignore initargs))
 849   (find-class 'standard-effective-slot-definition))
 850
 851 (defmethod effective-slot-definition-class ((class structure-class) initargs)
 852   (declare (ignore initargs))
 853   (find-class 'structure-effective-slot-definition))
 854
 855 (defmethod compute-effective-slot-definition-initargs
 856     ((class slot-class) direct-slotds)
 857   (let* ((name nil)
 858          (initfunction nil)
 859          (initform nil)
 860          (initargs nil)
 861          (allocation nil)
 862          (type t)
 863          (namep  nil)
 864          (initp  nil)
 865          (allocp nil))
 866
 867     (dolist (slotd direct-slotds)
 868       (when slotd
 869         (unless namep
 870           (setq name (slot-definition-name slotd)
 871                 namep t))
 872         (unless initp
 873           (when (slot-definition-initfunction slotd)
 874             (setq initform (slot-definition-initform slotd)
 875                   initfunction (slot-definition-initfunction slotd)
 876                   initp t)))
 877         (unless allocp
 878           (setq allocation (slot-definition-allocation slotd)
 879                 allocp t))
 880         (setq initargs (append (slot-definition-initargs slotd) initargs))
 881         (let ((slotd-type (slot-definition-type slotd)))
 882           (setq type (cond ((eq type t) slotd-type)
 883                            ((*subtypep type slotd-type) type)
 884                            (t `(and ,type ,slotd-type)))))))
 885     (list :name name
 886           :initform initform
 887           :initfunction initfunction
 888           :initargs initargs
 889           :allocation allocation
 890           :type type
 891           :class class)))
 892
 893 (defmethod compute-effective-slot-definition-initargs :around
 894     ((class structure-class) direct-slotds)
 895   (let ((slotd (car direct-slotds)))
 896     (list* :defstruct-accessor-symbol
 897            (slot-definition-defstruct-accessor-symbol slotd)
 898            :internal-reader-function
 899            (slot-definition-internal-reader-function slotd)
 900            :internal-writer-function
 901            (slot-definition-internal-writer-function slotd)
 902            (call-next-method))))
 903 \f
 904 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
 905 ;;;       to make the method object. They have to use make-a-method which
 906 ;;;       is a specially bootstrapped mechanism for making standard methods.
 907 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
 908   (declare (ignore direct-slot initargs))
 909   (find-class 'standard-reader-method))
 910
 911 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
 912   (add-method generic-function
 913               (make-a-method 'standard-reader-method
 914                              ()
 915                              (list (or (class-name class) 'object))
 916                              (list class)
 917                              (make-reader-method-function class slot-name)
 918                              "automatically generated reader method"
 919                              slot-name)))
 920
 921 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
 922   (declare (ignore direct-slot initargs))
 923   (find-class 'standard-writer-method))
 924
 925 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
 926   (add-method generic-function
 927               (make-a-method 'standard-writer-method
 928                              ()
 929                              (list 'new-value (or (class-name class) 'object))
 930                              (list *the-class-t* class)
 931                              (make-writer-method-function class slot-name)
 932                              "automatically generated writer method"
 933                              slot-name)))
 934
 935 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
 936   (add-method generic-function
 937               (make-a-method 'standard-boundp-method
 938                              ()
 939                              (list (or (class-name class) 'object))
 940                              (list class)
 941                              (make-boundp-method-function class slot-name)
 942                              "automatically generated boundp method"
 943                              slot-name)))
 944
 945 (defmethod remove-reader-method ((class slot-class) generic-function)
 946   (let ((method (get-method generic-function () (list class) nil)))
 947     (when method (remove-method generic-function method))))
 948
 949 (defmethod remove-writer-method ((class slot-class) generic-function)
 950   (let ((method
 951           (get-method generic-function () (list *the-class-t* class) nil)))
 952     (when method (remove-method generic-function method))))
 953
 954 (defmethod remove-boundp-method ((class slot-class) generic-function)
 955   (let ((method (get-method generic-function () (list class) nil)))
 956     (when method (remove-method generic-function method))))
 957 \f
 958 ;;; make-reader-method-function and make-write-method function are NOT part of
 959 ;;; the standard protocol. They are however useful, PCL makes uses makes use
 960 ;;; of them internally and documents them for PCL users.
 961 ;;;
 962 ;;; *** This needs work to make type testing by the writer functions which
 963 ;;; *** do type testing faster. The idea would be to have one constructor
 964 ;;; *** for each possible type test. In order to do this it would be nice
 965 ;;; *** to have help from inform-type-system-about-class and friends.
 966 ;;;
 967 ;;; *** There is a subtle bug here which is going to have to be fixed.
 968 ;;; *** Namely, the simplistic use of the template has to be fixed. We
 969 ;;; *** have to give the optimize-slot-value method the user might have
 970 ;;; *** defined for this metclass a chance to run.
 971
 972 (defmethod make-reader-method-function ((class slot-class) slot-name)
 973   (make-std-reader-method-function (class-name class) slot-name))
 974
 975 (defmethod make-writer-method-function ((class slot-class) slot-name)
 976   (make-std-writer-method-function (class-name class) slot-name))
 977
 978 (defmethod make-boundp-method-function ((class slot-class) slot-name)
 979   (make-std-boundp-method-function (class-name class) slot-name))
 980 \f
 981 ;;;; inform-type-system-about-class
 982 ;;;; make-type-predicate
 983 ;;;
 984 ;;; These are NOT part of the standard protocol. They are internal
 985 ;;; mechanism which PCL uses to *try* and tell the type system about
 986 ;;; class definitions. In a more fully integrated implementation of
 987 ;;; CLOS, the type system would know about class objects and class
 988 ;;; names in a more fundamental way and the mechanism used to inform
 989 ;;; the type system about new classes would be different.
 990 (defmethod inform-type-system-about-class ((class std-class) name)
 991   (inform-type-system-about-std-class name))
 992 \f
 993 (defmethod compatible-meta-class-change-p (class proto-new-class)
 994   (eq (class-of class) (class-of proto-new-class)))
 995
 996 (defmethod validate-superclass ((class class) (new-super class))
 997   (or (eq new-super *the-class-t*)
 998       (eq (class-of class) (class-of new-super))))
 999
1000 (defmethod validate-superclass ((class standard-class) (new-super std-class))
1001   (let ((new-super-meta-class (class-of new-super)))
1002     (or (eq new-super-meta-class *the-class-std-class*)
1003         (eq (class-of class) new-super-meta-class))))
1004 \f
1005 (defun force-cache-flushes (class)
1006   (let* ((owrapper (class-wrapper class))
1007          (state (wrapper-state owrapper)))
1008     ;; We only need to do something if the state is still T. If the
1009     ;; state isn't T, it will be FLUSH or OBSOLETE, and both of those
1010     ;; will already be doing what we want. In particular, we must be
1011     ;; sure we never change an OBSOLETE into a FLUSH since OBSOLETE
1012     ;; means do what FLUSH does and then some.
1013     (when (eq state t) ; FIXME: should be done through INVALID-WRAPPER-P
1014       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1015                                     class)))
1016         (setf (wrapper-instance-slots-layout nwrapper)
1017               (wrapper-instance-slots-layout owrapper))
1018         (setf (wrapper-class-slots nwrapper)
1019               (wrapper-class-slots owrapper))
1020         (sb-sys:without-interrupts
1021           (update-lisp-class-layout class nwrapper)
1022           (setf (slot-value class 'wrapper) nwrapper)
1023           (invalidate-wrapper owrapper ':flush nwrapper))))))
1024
1025 (defun flush-cache-trap (owrapper nwrapper instance)
1026   (declare (ignore owrapper))
1027   (set-wrapper instance nwrapper))
1028 \f
1029 ;;; make-instances-obsolete can be called by user code. It will cause the
1030 ;;; next access to the instance (as defined in 88-002R) to trap through the
1031 ;;; update-instance-for-redefined-class mechanism.
1032 (defmethod make-instances-obsolete ((class std-class))
1033   (let* ((owrapper (class-wrapper class))
1034          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1035                                  class)))
1036       (setf (wrapper-instance-slots-layout nwrapper)
1037             (wrapper-instance-slots-layout owrapper))
1038       (setf (wrapper-class-slots nwrapper)
1039             (wrapper-class-slots owrapper))
1040       (sb-sys:without-interrupts
1041         (update-lisp-class-layout class nwrapper)
1042         (setf (slot-value class 'wrapper) nwrapper)
1043         (invalidate-wrapper owrapper ':obsolete nwrapper)
1044         class)))
1045
1046 (defmethod make-instances-obsolete ((class symbol))
1047   (make-instances-obsolete (find-class class)))
1048
1049 ;;; obsolete-instance-trap is the internal trap that is called when we see
1050 ;;; an obsolete instance. The times when it is called are:
1051 ;;;   - when the instance is involved in method lookup
1052 ;;;   - when attempting to access a slot of an instance
1053 ;;;
1054 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1055 ;;; instance access macros.
1056 ;;;
1057 ;;; Of course these times when it is called are an internal
1058 ;;; implementation detail of PCL and are not part of the documented
1059 ;;; description of when the obsolete instance update happens. The
1060 ;;; documented description is as it appears in 88-002R.
1061 ;;;
1062 ;;; This has to return the new wrapper, so it counts on all the
1063 ;;; methods on obsolete-instance-trap-internal to return the new
1064 ;;; wrapper. It also does a little internal error checking to make
1065 ;;; sure that the traps are only happening when they should, and that
1066 ;;; the trap methods are computing appropriate new wrappers.
1067
1068 ;;; obsolete-instance-trap might be called on structure instances
1069 ;;; after a structure is redefined. In most cases, obsolete-instance-trap
1070 ;;; will not be able to fix the old instance, so it must signal an
1071 ;;; error. The hard part of this is that the error system and debugger
1072 ;;; might cause obsolete-instance-trap to be called again, so in that
1073 ;;; case, we have to return some reasonable wrapper, instead.
1074
1075 (defvar *in-obsolete-instance-trap* nil)
1076 (defvar *the-wrapper-of-structure-object*
1077   (class-wrapper (find-class 'structure-object)))
1078
1079 (define-condition obsolete-structure (error)
1080   ((datum :reader obsolete-structure-datum :initarg :datum))
1081   (:report
1082    (lambda (condition stream)
1083      ;; Don't try to print the structure, since it probably won't work.
1084      (format stream
1085              "obsolete structure error in ~S:~@
1086               for a structure of type: ~S"
1087              (sb-kernel::condition-function-name condition)
1088              (type-of (obsolete-structure-datum condition))))))
1089
1090 (defun obsolete-instance-trap (owrapper nwrapper instance)
1091   (if (not (pcl-instance-p instance))
1092       (if *in-obsolete-instance-trap*
1093           *the-wrapper-of-structure-object*
1094            (let ((*in-obsolete-instance-trap* t))
1095              (error 'obsolete-structure :datum instance)))
1096       (let* ((class (wrapper-class* nwrapper))
1097              (copy (allocate-instance class)) ;??? allocate-instance ???
1098              (olayout (wrapper-instance-slots-layout owrapper))
1099              (nlayout (wrapper-instance-slots-layout nwrapper))
1100              (oslots (get-slots instance))
1101              (nslots (get-slots copy))
1102              (oclass-slots (wrapper-class-slots owrapper))
1103              (added ())
1104              (discarded ())
1105              (plist ()))
1106         ;; local  --> local     transfer
1107         ;; local  --> shared       discard
1108         ;; local  -->  --         discard
1109         ;; shared --> local     transfer
1110         ;; shared --> shared       discard
1111         ;; shared -->  --         discard
1112         ;;  --    --> local     add
1113         ;;  --    --> shared    --
1114
1115         ;; Go through all the old local slots.
1116         (iterate ((name (list-elements olayout))
1117                   (opos (interval :from 0)))
1118           (let ((npos (posq name nlayout)))
1119             (if npos
1120                 (setf (clos-slots-ref nslots npos)
1121                       (clos-slots-ref oslots opos))
1122                 (progn
1123                   (push name discarded)
1124                   (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1125                     (setf (getf plist name) (clos-slots-ref oslots opos)))))))
1126
1127         ;; Go through all the old shared slots.
1128         (iterate ((oclass-slot-and-val (list-elements oclass-slots)))
1129           (let ((name (car oclass-slot-and-val))
1130                 (val (cdr oclass-slot-and-val)))
1131             (let ((npos (posq name nlayout)))
1132               (if npos
1133                   (setf (clos-slots-ref nslots npos) (cdr oclass-slot-and-val))
1134                   (progn (push name discarded)
1135                          (unless (eq val +slot-unbound+)
1136                            (setf (getf plist name) val)))))))
1137
1138         ;; Go through all the new local slots to compute the added slots.
1139         (dolist (nlocal nlayout)
1140           (unless (or (memq nlocal olayout)
1141                       (assq nlocal oclass-slots))
1142             (push nlocal added)))
1143
1144         (swap-wrappers-and-slots instance copy)
1145
1146         (update-instance-for-redefined-class instance
1147                                              added
1148                                              discarded
1149                                              plist)
1150         nwrapper)))
1151 \f
1152 (defmacro copy-instance-internal (instance)
1153   `(progn
1154      (let* ((class (class-of instance))
1155             (copy (allocate-instance class)))
1156        (if (std-instance-p ,instance)
1157            (setf (std-instance-slots ,instance)
1158                  (std-instance-slots ,instance))
1159          (setf (fsc-instance-slots ,instance)
1160                (fsc-instance-slots ,instance)))
1161        copy)))
1162
1163 (defun change-class-internal (instance new-class)
1164   (let* ((old-class (class-of instance))
1165          (copy (allocate-instance new-class))
1166          (new-wrapper (get-wrapper copy))
1167          (old-wrapper (class-wrapper old-class))
1168          (old-layout (wrapper-instance-slots-layout old-wrapper))
1169          (new-layout (wrapper-instance-slots-layout new-wrapper))
1170          (old-slots (get-slots instance))
1171          (new-slots (get-slots copy))
1172          (old-class-slots (wrapper-class-slots old-wrapper)))
1173
1174     ;; "The values of local slots specified by both the class CTO and
1175     ;; CFROM are retained. If such a local slot was unbound, it remains
1176     ;; unbound."
1177     (iterate ((new-slot (list-elements new-layout))
1178               (new-position (interval :from 0)))
1179       (let ((old-position (posq new-slot old-layout)))
1180         (when old-position
1181           (setf (clos-slots-ref new-slots new-position)
1182                 (clos-slots-ref old-slots old-position)))))
1183
1184     ;; "The values of slots specified as shared in the class CFROM and
1185     ;; as local in the class CTO are retained."
1186     (iterate ((slot-and-val (list-elements old-class-slots)))
1187       (let ((position (posq (car slot-and-val) new-layout)))
1188         (when position
1189           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1190
1191     ;; Make the copy point to the old instance's storage, and make the
1192     ;; old instance point to the new storage.
1193     (swap-wrappers-and-slots instance copy)
1194
1195     (update-instance-for-different-class copy instance)
1196     instance))
1197
1198 (defmethod change-class ((instance standard-object)
1199                          (new-class standard-class))
1200   (change-class-internal instance new-class))
1201
1202 (defmethod change-class ((instance funcallable-standard-object)
1203                          (new-class funcallable-standard-class))
1204   (change-class-internal instance new-class))
1205
1206 (defmethod change-class ((instance standard-object)
1207                          (new-class funcallable-standard-class))
1208   (error "You can't change the class of ~S to ~S~@
1209           because it isn't already an instance with metaclass ~S."
1210          instance new-class 'standard-class))
1211
1212 (defmethod change-class ((instance funcallable-standard-object)
1213                          (new-class standard-class))
1214   (error "You can't change the class of ~S to ~S~@
1215           because it isn't already an instance with metaclass ~S."
1216          instance new-class 'funcallable-standard-class))
1217
1218 (defmethod change-class ((instance t) (new-class-name symbol))
1219   (change-class instance (find-class new-class-name)))
1220 \f
1221 ;;;; The metaclass BUILT-IN-CLASS
1222 ;;;;
1223 ;;;; This metaclass is something of a weird creature. By this point, all
1224 ;;;; instances of it which will exist have been created, and no instance
1225 ;;;; is ever created by calling MAKE-INSTANCE.
1226 ;;;;
1227 ;;;; But, there are other parts of the protocol we must follow and those
1228 ;;;; definitions appear here.
1229
1230 (defmethod shared-initialize :before
1231            ((class built-in-class) slot-names &rest initargs)
1232   (declare (ignore slot-names initargs))
1233   (error "attempt to initialize or reinitialize a built in class"))
1234
1235 (defmethod class-direct-slots       ((class built-in-class)) ())
1236 (defmethod class-slots             ((class built-in-class)) ())
1237 (defmethod class-direct-default-initargs ((class built-in-class)) ())
1238 (defmethod class-default-initargs       ((class built-in-class)) ())
1239
1240 (defmethod validate-superclass ((c class) (s built-in-class))
1241   (or (eq s *the-class-t*)
1242       (eq s *the-class-stream*)))
1243 \f
1244 (defmethod validate-superclass ((c slot-class)
1245                                 (f forward-referenced-class))
1246   t)
1247 \f
1248 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1249   (pushnew dependent (plist-value metaobject 'dependents)))
1250
1251 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1252   (setf (plist-value metaobject 'dependents)
1253         (delete dependent (plist-value metaobject 'dependents))))
1254
1255 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1256   (dolist (dependent (plist-value metaobject 'dependents))
1257     (funcall function dependent)))
1258