src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd 'class)))
  76     (let ((table (or (gethash name *name->class->slotd-table*)
  77                      (setf (gethash name *name->class->slotd-table*)
  78                            (make-hash-table :test 'eq :size 5)))))
  79       (setf (gethash class table) slotd))
  80     (dolist (type '(reader writer boundp))
  81       (let* ((gf-name (ecase type
  82                               (reader 'slot-value-using-class)
  83                               (writer '(setf slot-value-using-class))
  84                               (boundp 'slot-boundp-using-class)))
  85              (gf (gdefinition gf-name)))
  86         (compute-slot-accessor-info slotd type gf)))
  87     (initialize-internal-slot-gfs name)))
  88
  89 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  90                                        type gf)
  91   (let* ((name (slot-value slotd 'name))
  92          (class (slot-value slotd 'class))
  93          (old-slotd (find-slot-definition class name))
  94          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
  95     (multiple-value-bind (function std-p)
  96         (if (eq *boot-state* 'complete)
  97             (get-accessor-method-function gf type class slotd)
  98             (get-optimized-std-accessor-method-function class slotd type))
  99       (setf (slot-accessor-std-p slotd type) std-p)
 100       (setf (slot-accessor-function slotd type) function))
 101     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 102       (push (cons class name) *pv-table-cache-update-info*))))
 103
 104 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 105   :instance)
 106 \f
 107 (defmethod shared-initialize :after ((object documentation-mixin)
 108                                      slot-names
 109                                      &key (documentation nil documentation-p))
 110   (declare (ignore slot-names))
 111   (when documentation-p
 112     (setf (plist-value object 'documentation) documentation)))
 113
 114 ;;; default if DOC-TYPE doesn't match one of the specified types
 115 (defmethod documentation (object doc-type)
 116   (warn "unsupported DOCUMENTATION: type ~S for object ~S"
 117         doc-type
 118         (type-of object))
 119   nil)
 120
 121 ;;; default if DOC-TYPE doesn't match one of the specified types
 122 (defmethod (setf documentation) (new-value object doc-type)
 123   ;; CMU CL made this an error, but since ANSI says that even for supported
 124   ;; doc types an implementation is permitted to discard docs at any time
 125   ;; for any reason, this feels to me more like a warning. -- WHN 19991214
 126   (warn "discarding unsupported DOCUMENTATION of type ~S for object ~S"
 127         doc-type
 128         (type-of object))
 129   new-value)
 130
 131 (defmethod documentation ((object documentation-mixin) doc-type)
 132   (declare (ignore doc-type))
 133   (plist-value object 'documentation))
 134
 135 (defmethod (setf documentation) (new-value
 136                                  (object documentation-mixin)
 137                                  doc-type)
 138   (declare (ignore doc-type))
 139   (setf (plist-value object 'documentation) new-value))
 140
 141 (defmethod documentation ((slotd standard-slot-definition) doc-type)
 142   (declare (ignore doc-type))
 143   (slot-value slotd 'documentation))
 144
 145 (defmethod (setf documentation) (new-value
 146                                  (slotd standard-slot-definition)
 147                                  doc-type)
 148   (declare (ignore doc-type))
 149   (setf (slot-value slotd 'documentation) new-value))
 150 \f
 151 ;;;; various class accessors that are a little more complicated than can be
 152 ;;;; done with automatically generated reader methods
 153
 154 (defmethod class-finalized-p ((class pcl-class))
 155   (with-slots (wrapper) class
 156     (not (null wrapper))))
 157
 158 (defmethod class-prototype ((class std-class))
 159   (with-slots (prototype) class
 160     (or prototype (setq prototype (allocate-instance class)))))
 161
 162 (defmethod class-prototype ((class structure-class))
 163   (with-slots (prototype wrapper defstruct-constructor) class
 164     (or prototype
 165         (setq prototype
 166               (if defstruct-constructor
 167                   (allocate-instance class)
 168                   (allocate-standard-instance wrapper))))))
 169
 170 (defmethod class-direct-default-initargs ((class slot-class))
 171   (plist-value class 'direct-default-initargs))
 172
 173 (defmethod class-default-initargs ((class slot-class))
 174   (plist-value class 'default-initargs))
 175
 176 (defmethod class-slot-cells ((class std-class))
 177   (plist-value class 'class-slot-cells))
 178 \f
 179 ;;;; class accessors that are even a little bit more complicated than those
 180 ;;;; above. These have a protocol for updating them, we must implement that
 181 ;;;; protocol.
 182
 183 ;;; Maintaining the direct subclasses backpointers. The update methods are
 184 ;;; here, the values are read by an automatically generated reader method.
 185 (defmethod add-direct-subclass ((class class) (subclass class))
 186   (with-slots (direct-subclasses) class
 187     (pushnew subclass direct-subclasses)
 188     subclass))
 189 (defmethod remove-direct-subclass ((class class) (subclass class))
 190   (with-slots (direct-subclasses) class
 191     (setq direct-subclasses (remove subclass direct-subclasses))
 192     subclass))
 193
 194 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 195 ;;;
 196 ;;; There are four generic functions involved, each has one method for the
 197 ;;; class case and another method for the damned EQL specializers. All of
 198 ;;; these are specified methods and appear in their specified place in the
 199 ;;; class graph.
 200 ;;;
 201 ;;;   ADD-DIRECT-METHOD
 202 ;;;   REMOVE-DIRECT-METHOD
 203 ;;;   SPECIALIZER-DIRECT-METHODS
 204 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 205 ;;;
 206 ;;; In each case, we maintain one value which is a cons. The car is the list
 207 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 208 ;;; computed lazily.
 209 (defmethod add-direct-method ((specializer class) (method method))
 210   (with-slots (direct-methods) specializer
 211     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 212           (cdr direct-methods) ()))
 213   method)
 214 (defmethod remove-direct-method ((specializer class) (method method))
 215   (with-slots (direct-methods) specializer
 216     (setf (car direct-methods) (remove method (car direct-methods))
 217           (cdr direct-methods) ()))
 218   method)
 219
 220 (defmethod specializer-direct-methods ((specializer class))
 221   (with-slots (direct-methods) specializer
 222     (car direct-methods)))
 223
 224 (defmethod specializer-direct-generic-functions ((specializer class))
 225   (with-slots (direct-methods) specializer
 226     (or (cdr direct-methods)
 227         (setf (cdr direct-methods)
 228               (let (collect)
 229                 (dolist (m (car direct-methods))
 230                   ;; the old PCL code used COLLECTING-ONCE which used
 231                   ;; #'EQ to check for newness
 232                   (pushnew (method-generic-function m) collect :test #'eq))
 233                 (nreverse collect))))))
 234 \f
 235 ;;; This hash table is used to store the direct methods and direct generic
 236 ;;; functions of EQL specializers. Each value in the table is the cons.
 237 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 238 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 239
 240 (defmethod specializer-method-table ((specializer eql-specializer))
 241   *eql-specializer-methods*)
 242
 243 (defmethod specializer-method-table ((specializer class-eq-specializer))
 244   *class-eq-specializer-methods*)
 245
 246 (defmethod add-direct-method ((specializer specializer-with-object)
 247                               (method method))
 248   (let* ((object (specializer-object specializer))
 249          (table (specializer-method-table specializer))
 250          (entry (gethash object table)))
 251     (unless entry
 252       (setq entry
 253             (setf (gethash object table)
 254                   (cons nil nil))))
 255     (setf (car entry) (adjoin method (car entry))
 256           (cdr entry) ())
 257     method))
 258
 259 (defmethod remove-direct-method ((specializer specializer-with-object)
 260                                  (method method))
 261   (let* ((object (specializer-object specializer))
 262          (entry (gethash object (specializer-method-table specializer))))
 263     (when entry
 264       (setf (car entry) (remove method (car entry))
 265             (cdr entry) ()))
 266     method))
 267
 268 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 269   (car (gethash (specializer-object specializer)
 270                 (specializer-method-table specializer))))
 271
 272 (defmethod specializer-direct-generic-functions ((specializer
 273                                                   specializer-with-object))
 274   (let* ((object (specializer-object specializer))
 275          (entry (gethash object (specializer-method-table specializer))))
 276     (when entry
 277       (or (cdr entry)
 278           (setf (cdr entry)
 279                 (let (collect)
 280                   (dolist (m (car entry))
 281                     (pushnew (method-generic-function m) collect :test #'eq))
 282                   (nreverse collect)))))))
 283
 284 (defun map-specializers (function)
 285   (map-all-classes (lambda (class)
 286                      (funcall function (class-eq-specializer class))
 287                      (funcall function class)))
 288   (maphash (lambda (object methods)
 289              (declare (ignore methods))
 290              (intern-eql-specializer object))
 291            *eql-specializer-methods*)
 292   (maphash (lambda (object specl)
 293              (declare (ignore object))
 294              (funcall function specl))
 295            *eql-specializer-table*)
 296   nil)
 297
 298 (defun map-all-generic-functions (function)
 299   (let ((all-generic-functions (make-hash-table :test 'eq)))
 300     (map-specializers (lambda (specl)
 301                         (dolist (gf (specializer-direct-generic-functions
 302                                      specl))
 303                           (unless (gethash gf all-generic-functions)
 304                             (setf (gethash gf all-generic-functions) t)
 305                             (funcall function gf))))))
 306   nil)
 307
 308 (defmethod shared-initialize :after ((specl class-eq-specializer)
 309                                      slot-names
 310                                      &key)
 311   (declare (ignore slot-names))
 312   (setf (slot-value specl 'type) `(class-eq ,(specializer-class specl))))
 313
 314 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 315   (declare (ignore slot-names))
 316   (setf (slot-value specl 'type) `(eql ,(specializer-object specl))))
 317 \f
 318 (defun real-load-defclass (name metaclass-name supers slots other)
 319   (let ((res (apply #'ensure-class name :metaclass metaclass-name
 320                     :direct-superclasses supers
 321                     :direct-slots slots
 322                     :definition-source `((defclass ,name)
 323                                          ,*load-truename*)
 324                     other)))
 325     ;; Defclass of a class with a forward-referenced superclass does not
 326     ;; have a wrapper. RES is the incomplete PCL class. The Lisp class
 327     ;; does not yet exist. Maybe should return NIL in that case as RES
 328     ;; is not useful to the user?
 329     (and (class-wrapper res) (sb-kernel:layout-class (class-wrapper res)))))
 330
 331 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 332
 333 (defun ensure-class (name &rest all)
 334   (apply #'ensure-class-using-class name (find-class name nil) all))
 335
 336 (defmethod ensure-class-using-class (name (class null) &rest args &key)
 337   (multiple-value-bind (meta initargs)
 338       (ensure-class-values class args)
 339     (setf class (apply #'make-instance meta :name name initargs)
 340           (find-class name) class)
 341     class))
 342
 343 (defmethod ensure-class-using-class (name (class pcl-class) &rest args &key)
 344   (multiple-value-bind (meta initargs)
 345       (ensure-class-values class args)
 346     (unless (eq (class-of class) meta) (change-class class meta))
 347     (apply #'reinitialize-instance class initargs)
 348     (setf (find-class name) class)
 349     class))
 350
 351 (defmethod class-predicate-name ((class t))
 352   'constantly-nil)
 353
 354 (defun fix-super (s)
 355   (cond ((classp s) s)
 356         ((not (legal-class-name-p s))
 357           (error "~S is not a class or a legal class name." s))
 358         (t
 359           (or (find-class s nil)
 360               (setf (find-class s)
 361                       (make-instance 'forward-referenced-class
 362                                      :name s))))))
 363
 364 (defun ensure-class-values (class args)
 365   (let* ((initargs (copy-list args))
 366          (unsupplied (list 1))
 367          (supplied-meta   (getf initargs :metaclass unsupplied))
 368          (supplied-supers (getf initargs :direct-superclasses unsupplied))
 369          (supplied-slots  (getf initargs :direct-slots unsupplied))
 370          (meta
 371            (cond ((neq supplied-meta unsupplied)
 372                   (find-class supplied-meta))
 373                  ((or (null class)
 374                       (forward-referenced-class-p class))
 375                   *the-class-standard-class*)
 376                  (t
 377                   (class-of class)))))
 378     ;; KLUDGE: It seemed to me initially that there ought to be a way
 379     ;; of collecting all the erroneous problems in one go, rather than
 380     ;; this way of solving the problem of signalling the errors that
 381     ;; we are required to, which stops at the first bogus input.
 382     ;; However, after playing around a little, I couldn't find that
 383     ;; way, so I've left it as is, but if someone does come up with a
 384     ;; better way... -- CSR, 2002-09-08
 385     (loop for (slot . more) on (getf initargs :direct-slots)
 386           for slot-name = (getf slot :name)
 387           if (some (lambda (s) (eq slot-name (getf s :name))) more)
 388           ;; FIXME: It's quite possible that we ought to define an
 389           ;; SB-INT:PROGRAM-ERROR function to signal these and other
 390           ;; errors throughout the code base that are required to be
 391           ;; of type PROGRAM-ERROR.
 392           do (error 'simple-program-error
 393                     :format-control "More than one direct slot with name ~S."
 394                     :format-arguments (list slot-name))
 395           else
 396           do (loop for (option value . more) on slot by #'cddr
 397                    when (and (member option
 398                                      '(:allocation :type
 399                                        :initform :documentation))
 400                              (not (eq unsupplied
 401                                       (getf more option unsupplied))))
 402                    do (error 'simple-program-error
 403                              :format-control "Duplicate slot option ~S for slot ~S."
 404                              :format-arguments (list option slot-name))))
 405     (loop for (initarg . more) on (getf initargs :direct-default-initargs)
 406           for name = (car initarg)
 407           when (some (lambda (a) (eq (car a) name)) more)
 408           do (error 'simple-program-error
 409                     :format-control "Duplicate initialization argument ~
 410                                      name ~S in :default-initargs of class ~A."
 411                     :format-arguments (list name class)))
 412     (loop (unless (remf initargs :metaclass) (return)))
 413     (loop (unless (remf initargs :direct-superclasses) (return)))
 414     (loop (unless (remf initargs :direct-slots) (return)))
 415     (values meta
 416             (list* :direct-superclasses
 417                    (and (neq supplied-supers unsupplied)
 418                         (mapcar #'fix-super supplied-supers))
 419                    :direct-slots
 420                    (and (neq supplied-slots unsupplied) supplied-slots)
 421                    initargs))))
 422 \f
 423
 424 (defmethod shared-initialize :after
 425            ((class std-class)
 426             slot-names
 427             &key (direct-superclasses nil direct-superclasses-p)
 428                  (direct-slots nil direct-slots-p)
 429                  (direct-default-initargs nil direct-default-initargs-p)
 430                  (predicate-name nil predicate-name-p))
 431   (declare (ignore slot-names))
 432   (cond (direct-superclasses-p
 433          (setq direct-superclasses
 434                (or direct-superclasses
 435                    (list (if (funcallable-standard-class-p class)
 436                              *the-class-funcallable-standard-object*
 437                              *the-class-standard-object*))))
 438          (dolist (superclass direct-superclasses)
 439            (unless (validate-superclass class superclass)
 440              (error "The class ~S was specified as a~%
 441                      super-class of the class ~S;~%~
 442                      but the meta-classes ~S and~%~S are incompatible.~@
 443                      Define a method for ~S to avoid this error."
 444                      superclass class (class-of superclass) (class-of class)
 445                      'validate-superclass)))
 446          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 447         (t
 448          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 449   (setq direct-slots
 450         (if direct-slots-p
 451             (setf (slot-value class 'direct-slots)
 452                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 453                           direct-slots))
 454             (slot-value class 'direct-slots)))
 455   (if direct-default-initargs-p
 456       (setf (plist-value class 'direct-default-initargs)
 457             direct-default-initargs)
 458       (setq direct-default-initargs
 459             (plist-value class 'direct-default-initargs)))
 460   (setf (plist-value class 'class-slot-cells)
 461         (let (collect)
 462           (dolist (dslotd direct-slots)
 463             (when (eq :class (slot-definition-allocation dslotd))
 464               (let ((initfunction (slot-definition-initfunction dslotd)))
 465                 (push (cons (slot-definition-name dslotd)
 466                                (if initfunction
 467                                    (funcall initfunction)
 468                                    +slot-unbound+))
 469                       collect))))
 470           (nreverse collect)))
 471   (setq predicate-name (if predicate-name-p
 472                            (setf (slot-value class 'predicate-name)
 473                                  (car predicate-name))
 474                            (or (slot-value class 'predicate-name)
 475                                (setf (slot-value class 'predicate-name)
 476                                      (make-class-predicate-name (class-name
 477                                                                  class))))))
 478   (add-direct-subclasses class direct-superclasses)
 479   (update-class class nil)
 480   (make-class-predicate class predicate-name)
 481   (add-slot-accessors class direct-slots))
 482
 483 (defmethod shared-initialize :before ((class class) slot-names &key name)
 484   (declare (ignore slot-names name))
 485   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 486   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 487   (setf (slot-value class 'type) `(class ,class))
 488   (setf (slot-value class 'class-eq-specializer)
 489         (make-instance 'class-eq-specializer :class class)))
 490
 491 (defmethod reinitialize-instance :before ((class slot-class) &key)
 492   (remove-direct-subclasses class (class-direct-superclasses class))
 493   (remove-slot-accessors    class (class-direct-slots class)))
 494
 495 (defmethod reinitialize-instance :after ((class slot-class)
 496                                          &rest initargs
 497                                          &key)
 498   (map-dependents class
 499                   (lambda (dependent)
 500                     (apply #'update-dependent class dependent initargs))))
 501
 502 (defmethod shared-initialize :after ((slotd structure-slot-definition)
 503                                      slot-names
 504                                      &key (allocation :instance))
 505   (declare (ignore slot-names))
 506   (unless (eq allocation :instance)
 507     (error "Structure slots must have :INSTANCE allocation.")))
 508
 509 (defun make-structure-class-defstruct-form (name direct-slots include)
 510   (let* ((conc-name (intern (format nil "~S structure class " name)))
 511          (constructor (intern (format nil "~Aconstructor" conc-name)))
 512          (defstruct `(defstruct (,name
 513                                  ,@(when include
 514                                          `((:include ,(class-name include))))
 515                                  (:predicate nil)
 516                                  (:conc-name ,conc-name)
 517                                  (:constructor ,constructor ())
 518                                  (:copier nil))
 519                       ,@(mapcar (lambda (slot)
 520                                   `(,(slot-definition-name slot)
 521                                     +slot-unbound+))
 522                                 direct-slots)))
 523          (reader-names (mapcar (lambda (slotd)
 524                                  (intern (format nil
 525                                                  "~A~A reader"
 526                                                  conc-name
 527                                                  (slot-definition-name
 528                                                   slotd))))
 529                                direct-slots))
 530          (writer-names (mapcar (lambda (slotd)
 531                                  (intern (format nil
 532                                                  "~A~A writer"
 533                                                  conc-name
 534                                                  (slot-definition-name
 535                                                   slotd))))
 536                                direct-slots))
 537          (readers-init
 538            (mapcar (lambda (slotd reader-name)
 539                      (let ((accessor
 540                              (slot-definition-defstruct-accessor-symbol
 541                               slotd)))
 542                        `(defun ,reader-name (obj)
 543                          (declare (type ,name obj))
 544                          (,accessor obj))))
 545                    direct-slots reader-names))
 546          (writers-init
 547            (mapcar (lambda (slotd writer-name)
 548                      (let ((accessor
 549                              (slot-definition-defstruct-accessor-symbol
 550                               slotd)))
 551                        `(defun ,writer-name (nv obj)
 552                          (declare (type ,name obj))
 553                          (setf (,accessor obj) nv))))
 554                    direct-slots writer-names))
 555          (defstruct-form
 556              `(progn
 557                ,defstruct
 558                ,@readers-init ,@writers-init
 559                (cons nil nil))))
 560     (values defstruct-form constructor reader-names writer-names)))
 561
 562 (defmethod shared-initialize :after
 563       ((class structure-class)
 564        slot-names
 565        &key (direct-superclasses nil direct-superclasses-p)
 566             (direct-slots nil direct-slots-p)
 567             direct-default-initargs
 568             (predicate-name nil predicate-name-p))
 569   (declare (ignore slot-names direct-default-initargs))
 570   (if direct-superclasses-p
 571       (setf (slot-value class 'direct-superclasses)
 572             (or direct-superclasses
 573                 (setq direct-superclasses
 574                       (and (not (eq (class-name class) 'structure-object))
 575                            (list *the-class-structure-object*)))))
 576       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 577   (let* ((name (class-name class))
 578          (from-defclass-p (slot-value class 'from-defclass-p))
 579          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 580     (if direct-slots-p
 581         (setf (slot-value class 'direct-slots)
 582               (setq direct-slots
 583                     (mapcar (lambda (pl)
 584                               (when defstruct-p
 585                                 (let* ((slot-name (getf pl :name))
 586                                        (acc-name
 587                                         (format nil
 588                                                 "~S structure class ~A"
 589                                                 name slot-name))
 590                                        (accessor (intern acc-name)))
 591                                   (setq pl (list* :defstruct-accessor-symbol
 592                                                   accessor pl))))
 593                               (make-direct-slotd class pl))
 594                             direct-slots)))
 595         (setq direct-slots (slot-value class 'direct-slots)))
 596     (when defstruct-p
 597       (let ((include (car (slot-value class 'direct-superclasses))))
 598         (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 599             (make-structure-class-defstruct-form name direct-slots include)
 600           (unless (structure-type-p name) (eval defstruct-form))
 601           (mapc (lambda (dslotd reader-name writer-name)
 602                   (let* ((reader (gdefinition reader-name))
 603                          (writer (when (gboundp writer-name)
 604                                    (gdefinition writer-name))))
 605                     (setf (slot-value dslotd 'internal-reader-function)
 606                           reader)
 607                     (setf (slot-value dslotd 'internal-writer-function)
 608                           writer)))
 609                 direct-slots reader-names writer-names)
 610           (setf (slot-value class 'defstruct-form) defstruct-form)
 611           (setf (slot-value class 'defstruct-constructor) constructor))))
 612     (add-direct-subclasses class direct-superclasses)
 613     (setf (slot-value class 'class-precedence-list)
 614             (compute-class-precedence-list class))
 615     (setf (slot-value class 'slots) (compute-slots class))
 616     (let ((lclass (cl:find-class (class-name class))))
 617       (setf (sb-kernel:class-pcl-class lclass) class)
 618       (setf (slot-value class 'wrapper) (sb-kernel:class-layout lclass)))
 619     (update-pv-table-cache-info class)
 620     (setq predicate-name (if predicate-name-p
 621                            (setf (slot-value class 'predicate-name)
 622                                    (car predicate-name))
 623                            (or (slot-value class 'predicate-name)
 624                                (setf (slot-value class 'predicate-name)
 625                                        (make-class-predicate-name
 626                                         (class-name class))))))
 627     (make-class-predicate class predicate-name)
 628     (add-slot-accessors class direct-slots)))
 629
 630 (defmethod direct-slot-definition-class ((class structure-class) initargs)
 631   (declare (ignore initargs))
 632   (find-class 'structure-direct-slot-definition))
 633
 634 (defmethod finalize-inheritance ((class structure-class))
 635   nil) ; always finalized
 636 \f
 637 (defun add-slot-accessors (class dslotds)
 638   (fix-slot-accessors class dslotds 'add))
 639
 640 (defun remove-slot-accessors (class dslotds)
 641   (fix-slot-accessors class dslotds 'remove))
 642
 643 (defun fix-slot-accessors (class dslotds add/remove)
 644   (flet ((fix (gfspec name r/w)
 645            (let ((gf (ensure-generic-function gfspec)))
 646              (case r/w
 647                (r (if (eq add/remove 'add)
 648                       (add-reader-method class gf name)
 649                       (remove-reader-method class gf)))
 650                (w (if (eq add/remove 'add)
 651                       (add-writer-method class gf name)
 652                       (remove-writer-method class gf)))))))
 653     (dolist (dslotd dslotds)
 654       (let ((slot-name (slot-definition-name dslotd)))
 655         (dolist (r (slot-definition-readers dslotd)) (fix r slot-name 'r))
 656         (dolist (w (slot-definition-writers dslotd)) (fix w slot-name 'w))))))
 657 \f
 658 (defun add-direct-subclasses (class supers)
 659   (dolist (super supers)
 660     (unless (memq class (class-direct-subclasses class))
 661       (add-direct-subclass super class))))
 662
 663 (defun remove-direct-subclasses (class supers)
 664   (let ((old (class-direct-superclasses class)))
 665     (dolist (o (set-difference old supers))
 666       (remove-direct-subclass o class))))
 667 \f
 668 (defmethod finalize-inheritance ((class std-class))
 669   (update-class class t))
 670 \f
 671 (defun class-has-a-forward-referenced-superclass-p (class)
 672   (or (forward-referenced-class-p class)
 673       (some #'class-has-a-forward-referenced-superclass-p
 674             (class-direct-superclasses class))))
 675
 676 ;;; This is called by :after shared-initialize whenever a class is initialized
 677 ;;; or reinitialized. The class may or may not be finalized.
 678 (defun update-class (class finalizep)
 679   (when (or finalizep (class-finalized-p class)
 680             (not (class-has-a-forward-referenced-superclass-p class)))
 681     (update-cpl class (compute-class-precedence-list class))
 682     (update-slots class (compute-slots class))
 683     (update-gfs-of-class class)
 684     (update-inits class (compute-default-initargs class))
 685     (update-make-instance-function-table class))
 686   (unless finalizep
 687     (dolist (sub (class-direct-subclasses class)) (update-class sub nil))))
 688
 689 (defun update-cpl (class cpl)
 690   (if (class-finalized-p class)
 691       (unless (equal (class-precedence-list class) cpl)
 692         ;; comment from the old CMU CL sources:
 693         ;;   Need to have the cpl setup before update-lisp-class-layout
 694         ;;   is called on CMU CL.
 695         (setf (slot-value class 'class-precedence-list) cpl)
 696         (force-cache-flushes class))
 697       (setf (slot-value class 'class-precedence-list) cpl))
 698   (update-class-can-precede-p cpl))
 699
 700 (defun update-class-can-precede-p (cpl)
 701   (when cpl
 702     (let ((first (car cpl)))
 703       (dolist (c (cdr cpl))
 704         (pushnew c (slot-value first 'can-precede-list))))
 705     (update-class-can-precede-p (cdr cpl))))
 706
 707 (defun class-can-precede-p (class1 class2)
 708   (member class2 (class-can-precede-list class1)))
 709
 710 (defun update-slots (class eslotds)
 711   (let ((instance-slots ())
 712         (class-slots    ()))
 713     (dolist (eslotd eslotds)
 714       (let ((alloc (slot-definition-allocation eslotd)))
 715         (case alloc
 716           (:instance (push eslotd instance-slots))
 717           (:class (push eslotd class-slots)))))
 718
 719     ;; If there is a change in the shape of the instances then the
 720     ;; old class is now obsolete.
 721     (let* ((nlayout (mapcar #'slot-definition-name
 722                             (sort instance-slots #'<
 723                                   :key #'slot-definition-location)))
 724            (nslots (length nlayout))
 725            (nwrapper-class-slots (compute-class-slots class-slots))
 726            (owrapper (class-wrapper class))
 727            (olayout (and owrapper (wrapper-instance-slots-layout owrapper)))
 728            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 729            (nwrapper
 730             (cond ((null owrapper)
 731                    (make-wrapper nslots class))
 732                   ((and (equal nlayout olayout)
 733                         (not
 734                          (loop for o in owrapper-class-slots
 735                                for n in nwrapper-class-slots
 736                                do (unless (eq (car o) (car n)) (return t)))))
 737                    owrapper)
 738                   (t
 739                    ;; This will initialize the new wrapper to have the
 740                    ;; same state as the old wrapper. We will then have
 741                    ;; to change that. This may seem like wasted work
 742                    ;; (and it is), but the spec requires that we call
 743                    ;; MAKE-INSTANCES-OBSOLETE.
 744                    (make-instances-obsolete class)
 745                    (class-wrapper class)))))
 746
 747       (with-slots (wrapper slots) class
 748         (update-lisp-class-layout class nwrapper)
 749         (setf slots eslotds
 750               (wrapper-instance-slots-layout nwrapper) nlayout
 751               (wrapper-class-slots nwrapper) nwrapper-class-slots
 752               (wrapper-no-of-instance-slots nwrapper) nslots
 753               wrapper nwrapper))
 754
 755       (unless (eq owrapper nwrapper)
 756         (update-pv-table-cache-info class)))))
 757
 758 (defun compute-class-slots (eslotds)
 759   (let (collect)
 760     (dolist (eslotd eslotds)
 761       (push (assoc (slot-definition-name eslotd)
 762                    (class-slot-cells (slot-definition-class eslotd)))
 763             collect))
 764     (nreverse collect)))
 765
 766 (defun compute-layout (cpl instance-eslotds)
 767   (let* ((names
 768            (let (collect)
 769              (dolist (eslotd instance-eslotds)
 770                (when (eq (slot-definition-allocation eslotd) :instance)
 771                  (push (slot-definition-name eslotd) collect)))
 772              (nreverse collect)))
 773          (order ()))
 774     (labels ((rwalk (tail)
 775                (when tail
 776                  (rwalk (cdr tail))
 777                  (dolist (ss (class-slots (car tail)))
 778                    (let ((n (slot-definition-name ss)))
 779                      (when (member n names)
 780                        (setq order (cons n order)
 781                              names (remove n names))))))))
 782       (rwalk (if (slot-boundp (car cpl) 'slots)
 783                  cpl
 784                  (cdr cpl)))
 785       (reverse (append names order)))))
 786
 787 (defun update-gfs-of-class (class)
 788   (when (and (class-finalized-p class)
 789              (let ((cpl (class-precedence-list class)))
 790                (or (member *the-class-slot-class* cpl)
 791                    (member *the-class-standard-effective-slot-definition*
 792                            cpl))))
 793     (let ((gf-table (make-hash-table :test 'eq)))
 794       (labels ((collect-gfs (class)
 795                  (dolist (gf (specializer-direct-generic-functions class))
 796                    (setf (gethash gf gf-table) t))
 797                  (mapc #'collect-gfs (class-direct-superclasses class))))
 798         (collect-gfs class)
 799         (maphash (lambda (gf ignore)
 800                    (declare (ignore ignore))
 801                    (update-gf-dfun class gf))
 802                  gf-table)))))
 803
 804 (defun update-inits (class inits)
 805   (setf (plist-value class 'default-initargs) inits))
 806 \f
 807 (defmethod compute-default-initargs ((class slot-class))
 808   (let ((cpl (class-precedence-list class))
 809         (direct (class-direct-default-initargs class)))
 810     (labels ((walk (tail)
 811                (if (null tail)
 812                    nil
 813                    (let ((c (pop tail)))
 814                      (append (if (eq c class)
 815                                  direct
 816                                  (class-direct-default-initargs c))
 817                              (walk tail))))))
 818       (let ((initargs (walk cpl)))
 819         (delete-duplicates initargs :test #'eq :key #'car :from-end t)))))
 820 \f
 821 ;;;; protocols for constructing direct and effective slot definitions
 822
 823 (defmethod direct-slot-definition-class ((class std-class) initargs)
 824   (declare (ignore initargs))
 825   (find-class 'standard-direct-slot-definition))
 826
 827 (defun make-direct-slotd (class initargs)
 828   (let ((initargs (list* :class class initargs)))
 829     (apply #'make-instance
 830            (direct-slot-definition-class class initargs)
 831            initargs)))
 832
 833 (defmethod compute-slots ((class std-class))
 834   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 835   ;; for each different slot name we find in our superclasses. Each
 836   ;; call receives the class and a list of the dslotds with that name.
 837   ;; The list is in most-specific-first order.
 838   (let ((name-dslotds-alist ()))
 839     (dolist (c (class-precedence-list class))
 840       (let ((dslotds (class-direct-slots c)))
 841         (dolist (d dslotds)
 842           (let* ((name (slot-definition-name d))
 843                  (entry (assq name name-dslotds-alist)))
 844             (if entry
 845                 (push d (cdr entry))
 846                 (push (list name d) name-dslotds-alist))))))
 847     (mapcar (lambda (direct)
 848               (compute-effective-slot-definition class
 849                                                  (nreverse (cdr direct))))
 850             name-dslotds-alist)))
 851
 852 (defmethod compute-slots :around ((class std-class))
 853   (let ((eslotds (call-next-method))
 854         (cpl (class-precedence-list class))
 855         (instance-slots ())
 856         (class-slots    ()))
 857     (dolist (eslotd eslotds)
 858       (let ((alloc (slot-definition-allocation eslotd)))
 859         (case alloc
 860           (:instance (push eslotd instance-slots))
 861           (:class (push eslotd class-slots)))))
 862     (let ((nlayout (compute-layout cpl instance-slots)))
 863       (dolist (eslotd instance-slots)
 864         (setf (slot-definition-location eslotd)
 865               (position (slot-definition-name eslotd) nlayout))))
 866     (dolist (eslotd class-slots)
 867       (setf (slot-definition-location eslotd)
 868             (assoc (slot-definition-name eslotd)
 869                    (class-slot-cells (slot-definition-class eslotd)))))
 870     (mapc #'initialize-internal-slot-functions eslotds)
 871     eslotds))
 872
 873 (defmethod compute-slots ((class structure-class))
 874   (mapcan (lambda (superclass)
 875             (mapcar (lambda (dslotd)
 876                       (compute-effective-slot-definition class
 877                                                          (list dslotd)))
 878                     (class-direct-slots superclass)))
 879           (reverse (slot-value class 'class-precedence-list))))
 880
 881 (defmethod compute-slots :around ((class structure-class))
 882   (let ((eslotds (call-next-method)))
 883     (mapc #'initialize-internal-slot-functions eslotds)
 884     eslotds))
 885
 886 (defmethod compute-effective-slot-definition ((class slot-class) dslotds)
 887   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
 888          (class (effective-slot-definition-class class initargs)))
 889     (apply #'make-instance class initargs)))
 890
 891 (defmethod effective-slot-definition-class ((class std-class) initargs)
 892   (declare (ignore initargs))
 893   (find-class 'standard-effective-slot-definition))
 894
 895 (defmethod effective-slot-definition-class ((class structure-class) initargs)
 896   (declare (ignore initargs))
 897   (find-class 'structure-effective-slot-definition))
 898
 899 (defmethod compute-effective-slot-definition-initargs
 900     ((class slot-class) direct-slotds)
 901   (let* ((name nil)
 902          (initfunction nil)
 903          (initform nil)
 904          (initargs nil)
 905          (allocation nil)
 906          (type t)
 907          (namep  nil)
 908          (initp  nil)
 909          (allocp nil))
 910
 911     (dolist (slotd direct-slotds)
 912       (when slotd
 913         (unless namep
 914           (setq name (slot-definition-name slotd)
 915                 namep t))
 916         (unless initp
 917           (when (slot-definition-initfunction slotd)
 918             (setq initform (slot-definition-initform slotd)
 919                   initfunction (slot-definition-initfunction slotd)
 920                   initp t)))
 921         (unless allocp
 922           (setq allocation (slot-definition-allocation slotd)
 923                 allocp t))
 924         (setq initargs (append (slot-definition-initargs slotd) initargs))
 925         (let ((slotd-type (slot-definition-type slotd)))
 926           (setq type (cond ((eq type t) slotd-type)
 927                            ((*subtypep type slotd-type) type)
 928                            (t `(and ,type ,slotd-type)))))))
 929     (list :name name
 930           :initform initform
 931           :initfunction initfunction
 932           :initargs initargs
 933           :allocation allocation
 934           :type type
 935           :class class)))
 936
 937 (defmethod compute-effective-slot-definition-initargs :around
 938     ((class structure-class) direct-slotds)
 939   (let ((slotd (car direct-slotds)))
 940     (list* :defstruct-accessor-symbol
 941            (slot-definition-defstruct-accessor-symbol slotd)
 942            :internal-reader-function
 943            (slot-definition-internal-reader-function slotd)
 944            :internal-writer-function
 945            (slot-definition-internal-writer-function slotd)
 946            (call-next-method))))
 947 \f
 948 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
 949 ;;;       to make the method object. They have to use make-a-method which
 950 ;;;       is a specially bootstrapped mechanism for making standard methods.
 951 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
 952   (declare (ignore direct-slot initargs))
 953   (find-class 'standard-reader-method))
 954
 955 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
 956   (add-method generic-function
 957               (make-a-method 'standard-reader-method
 958                              ()
 959                              (list (or (class-name class) 'object))
 960                              (list class)
 961                              (make-reader-method-function class slot-name)
 962                              "automatically generated reader method"
 963                              slot-name)))
 964
 965 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
 966   (declare (ignore direct-slot initargs))
 967   (find-class 'standard-writer-method))
 968
 969 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
 970   (add-method generic-function
 971               (make-a-method 'standard-writer-method
 972                              ()
 973                              (list 'new-value (or (class-name class) 'object))
 974                              (list *the-class-t* class)
 975                              (make-writer-method-function class slot-name)
 976                              "automatically generated writer method"
 977                              slot-name)))
 978
 979 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
 980   (add-method generic-function
 981               (make-a-method 'standard-boundp-method
 982                              ()
 983                              (list (or (class-name class) 'object))
 984                              (list class)
 985                              (make-boundp-method-function class slot-name)
 986                              "automatically generated boundp method"
 987                              slot-name)))
 988
 989 (defmethod remove-reader-method ((class slot-class) generic-function)
 990   (let ((method (get-method generic-function () (list class) nil)))
 991     (when method (remove-method generic-function method))))
 992
 993 (defmethod remove-writer-method ((class slot-class) generic-function)
 994   (let ((method
 995           (get-method generic-function () (list *the-class-t* class) nil)))
 996     (when method (remove-method generic-function method))))
 997
 998 (defmethod remove-boundp-method ((class slot-class) generic-function)
 999   (let ((method (get-method generic-function () (list class) nil)))
1000     (when method (remove-method generic-function method))))
1001 \f
1002 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITE-METHOD function are NOT
1003 ;;; part of the standard protocol. They are however useful, PCL makes
1004 ;;; use of them internally and documents them for PCL users.
1005 ;;;
1006 ;;; *** This needs work to make type testing by the writer functions which
1007 ;;; *** do type testing faster. The idea would be to have one constructor
1008 ;;; *** for each possible type test.
1009 ;;;
1010 ;;; *** There is a subtle bug here which is going to have to be fixed.
1011 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1012 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1013 ;;; *** defined for this metaclass a chance to run.
1014
1015 (defmethod make-reader-method-function ((class slot-class) slot-name)
1016   (make-std-reader-method-function (class-name class) slot-name))
1017
1018 (defmethod make-writer-method-function ((class slot-class) slot-name)
1019   (make-std-writer-method-function (class-name class) slot-name))
1020
1021 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1022   (make-std-boundp-method-function (class-name class) slot-name))
1023 \f
1024 (defmethod compatible-meta-class-change-p (class proto-new-class)
1025   (eq (class-of class) (class-of proto-new-class)))
1026
1027 (defmethod validate-superclass ((class class) (new-super class))
1028   (or (eq new-super *the-class-t*)
1029       (eq (class-of class) (class-of new-super))))
1030
1031 (defmethod validate-superclass ((class standard-class) (new-super std-class))
1032   (let ((new-super-meta-class (class-of new-super)))
1033     (or (eq new-super-meta-class *the-class-std-class*)
1034         (eq (class-of class) new-super-meta-class))))
1035 \f
1036 (defun force-cache-flushes (class)
1037   (let* ((owrapper (class-wrapper class)))
1038     ;; We only need to do something if the state is still T. If the
1039     ;; state isn't T, it will be FLUSH or OBSOLETE, and both of those
1040     ;; will already be doing what we want. In particular, we must be
1041     ;; sure we never change an OBSOLETE into a FLUSH since OBSOLETE
1042     ;; means do what FLUSH does and then some.
1043     (unless (invalid-wrapper-p owrapper)
1044       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1045                                     class)))
1046         (setf (wrapper-instance-slots-layout nwrapper)
1047               (wrapper-instance-slots-layout owrapper))
1048         (setf (wrapper-class-slots nwrapper)
1049               (wrapper-class-slots owrapper))
1050         (sb-sys:without-interrupts
1051           (update-lisp-class-layout class nwrapper)
1052           (setf (slot-value class 'wrapper) nwrapper)
1053           (invalidate-wrapper owrapper :flush nwrapper))))))
1054
1055 (defun flush-cache-trap (owrapper nwrapper instance)
1056   (declare (ignore owrapper))
1057   (set-wrapper instance nwrapper))
1058 \f
1059 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1060 ;;; the next access to the instance (as defined in 88-002R) to trap
1061 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1062 (defmethod make-instances-obsolete ((class std-class))
1063   (let* ((owrapper (class-wrapper class))
1064          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1065                                  class)))
1066       (setf (wrapper-instance-slots-layout nwrapper)
1067             (wrapper-instance-slots-layout owrapper))
1068       (setf (wrapper-class-slots nwrapper)
1069             (wrapper-class-slots owrapper))
1070       (sb-sys:without-interrupts
1071         (update-lisp-class-layout class nwrapper)
1072         (setf (slot-value class 'wrapper) nwrapper)
1073         (invalidate-wrapper owrapper :obsolete nwrapper)
1074         class)))
1075
1076 (defmethod make-instances-obsolete ((class symbol))
1077   (make-instances-obsolete (find-class class)))
1078
1079 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1080 ;;; see an obsolete instance. The times when it is called are:
1081 ;;;   - when the instance is involved in method lookup
1082 ;;;   - when attempting to access a slot of an instance
1083 ;;;
1084 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1085 ;;; instance access macros.
1086 ;;;
1087 ;;; Of course these times when it is called are an internal
1088 ;;; implementation detail of PCL and are not part of the documented
1089 ;;; description of when the obsolete instance update happens. The
1090 ;;; documented description is as it appears in 88-002R.
1091 ;;;
1092 ;;; This has to return the new wrapper, so it counts on all the
1093 ;;; methods on obsolete-instance-trap-internal to return the new
1094 ;;; wrapper. It also does a little internal error checking to make
1095 ;;; sure that the traps are only happening when they should, and that
1096 ;;; the trap methods are computing appropriate new wrappers.
1097
1098 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1099 ;;; after a structure is redefined. In most cases,
1100 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1101 ;;; so it must signal an error. The hard part of this is that the
1102 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1103 ;;; called again, so in that case, we have to return some reasonable
1104 ;;; wrapper, instead.
1105
1106 (defvar *in-obsolete-instance-trap* nil)
1107 (defvar *the-wrapper-of-structure-object*
1108   (class-wrapper (find-class 'structure-object)))
1109
1110 (define-condition obsolete-structure (error)
1111   ((datum :reader obsolete-structure-datum :initarg :datum))
1112   (:report
1113    (lambda (condition stream)
1114      ;; Don't try to print the structure, since it probably won't work.
1115      (format stream
1116              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1117              (type-of (obsolete-structure-datum condition))))))
1118
1119 (defun obsolete-instance-trap (owrapper nwrapper instance)
1120   (if (not (pcl-instance-p instance))
1121       (if *in-obsolete-instance-trap*
1122           *the-wrapper-of-structure-object*
1123            (let ((*in-obsolete-instance-trap* t))
1124              (error 'obsolete-structure :datum instance)))
1125       (let* ((class (wrapper-class* nwrapper))
1126              (copy (allocate-instance class)) ;??? allocate-instance ???
1127              (olayout (wrapper-instance-slots-layout owrapper))
1128              (nlayout (wrapper-instance-slots-layout nwrapper))
1129              (oslots (get-slots instance))
1130              (nslots (get-slots copy))
1131              (oclass-slots (wrapper-class-slots owrapper))
1132              (added ())
1133              (discarded ())
1134              (plist ()))
1135         ;; local  --> local     transfer
1136         ;; local  --> shared       discard
1137         ;; local  -->  --         discard
1138         ;; shared --> local     transfer
1139         ;; shared --> shared       discard
1140         ;; shared -->  --         discard
1141         ;;  --    --> local     add
1142         ;;  --    --> shared    --
1143
1144         ;; Go through all the old local slots.
1145         (let ((opos 0))
1146           (dolist (name olayout)
1147             (let ((npos (posq name nlayout)))
1148               (if npos
1149                   (setf (clos-slots-ref nslots npos)
1150                         (clos-slots-ref oslots opos))
1151                   (progn
1152                     (push name discarded)
1153                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1154                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1155             (incf opos)))
1156
1157         ;; Go through all the old shared slots.
1158         (dolist (oclass-slot-and-val oclass-slots)
1159           (let ((name (car oclass-slot-and-val))
1160                 (val (cdr oclass-slot-and-val)))
1161             (let ((npos (posq name nlayout)))
1162               (if npos
1163                   (setf (clos-slots-ref nslots npos) (cdr oclass-slot-and-val))
1164                   (progn (push name discarded)
1165                          (unless (eq val +slot-unbound+)
1166                            (setf (getf plist name) val)))))))
1167
1168         ;; Go through all the new local slots to compute the added slots.
1169         (dolist (nlocal nlayout)
1170           (unless (or (memq nlocal olayout)
1171                       (assq nlocal oclass-slots))
1172             (push nlocal added)))
1173
1174         (swap-wrappers-and-slots instance copy)
1175
1176         (update-instance-for-redefined-class instance
1177                                              added
1178                                              discarded
1179                                              plist)
1180         nwrapper)))
1181 \f
1182 (defun change-class-internal (instance new-class initargs)
1183   (let* ((old-class (class-of instance))
1184          (copy (allocate-instance new-class))
1185          (new-wrapper (get-wrapper copy))
1186          (old-wrapper (class-wrapper old-class))
1187          (old-layout (wrapper-instance-slots-layout old-wrapper))
1188          (new-layout (wrapper-instance-slots-layout new-wrapper))
1189          (old-slots (get-slots instance))
1190          (new-slots (get-slots copy))
1191          (old-class-slots (wrapper-class-slots old-wrapper)))
1192
1193     ;; "The values of local slots specified by both the class CTO and
1194     ;; CFROM are retained. If such a local slot was unbound, it
1195     ;; remains unbound."
1196     (let ((new-position 0))
1197       (dolist (new-slot new-layout)
1198         (let ((old-position (posq new-slot old-layout)))
1199           (when old-position
1200             (setf (clos-slots-ref new-slots new-position)
1201                   (clos-slots-ref old-slots old-position))))
1202         (incf new-position)))
1203
1204     ;; "The values of slots specified as shared in the class CFROM and
1205     ;; as local in the class CTO are retained."
1206     (dolist (slot-and-val old-class-slots)
1207       (let ((position (posq (car slot-and-val) new-layout)))
1208         (when position
1209           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1210
1211     ;; Make the copy point to the old instance's storage, and make the
1212     ;; old instance point to the new storage.
1213     (swap-wrappers-and-slots instance copy)
1214
1215     (apply #'update-instance-for-different-class copy instance initargs)
1216     instance))
1217
1218 (defmethod change-class ((instance standard-object)
1219                          (new-class standard-class)
1220                          &rest initargs)
1221   (change-class-internal instance new-class initargs))
1222
1223 (defmethod change-class ((instance funcallable-standard-object)
1224                          (new-class funcallable-standard-class)
1225                          &rest initargs)
1226   (change-class-internal instance new-class initargs))
1227
1228 (defmethod change-class ((instance standard-object)
1229                          (new-class funcallable-standard-class)
1230                          &rest initargs)
1231   (declare (ignore initargs))
1232   (error "You can't change the class of ~S to ~S~@
1233           because it isn't already an instance with metaclass ~S."
1234          instance new-class 'standard-class))
1235
1236 (defmethod change-class ((instance funcallable-standard-object)
1237                          (new-class standard-class)
1238                          &rest initargs)
1239   (declare (ignore initargs))
1240   (error "You can't change the class of ~S to ~S~@
1241           because it isn't already an instance with metaclass ~S."
1242          instance new-class 'funcallable-standard-class))
1243
1244 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1245   (apply #'change-class instance (find-class new-class-name) initargs))
1246 \f
1247 ;;;; The metaclass BUILT-IN-CLASS
1248 ;;;;
1249 ;;;; This metaclass is something of a weird creature. By this point, all
1250 ;;;; instances of it which will exist have been created, and no instance
1251 ;;;; is ever created by calling MAKE-INSTANCE.
1252 ;;;;
1253 ;;;; But, there are other parts of the protocol we must follow and those
1254 ;;;; definitions appear here.
1255
1256 (defmethod shared-initialize :before
1257            ((class built-in-class) slot-names &rest initargs)
1258   (declare (ignore slot-names initargs))
1259   (error "attempt to initialize or reinitialize a built in class"))
1260
1261 (defmethod class-direct-slots       ((class built-in-class)) ())
1262 (defmethod class-slots             ((class built-in-class)) ())
1263 (defmethod class-direct-default-initargs ((class built-in-class)) ())
1264 (defmethod class-default-initargs       ((class built-in-class)) ())
1265
1266 (defmethod validate-superclass ((c class) (s built-in-class))
1267   (or (eq s *the-class-t*)
1268       (eq s *the-class-stream*)))
1269 \f
1270 (defmethod validate-superclass ((c slot-class)
1271                                 (f forward-referenced-class))
1272   t)
1273 \f
1274 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1275   (pushnew dependent (plist-value metaobject 'dependents)))
1276
1277 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1278   (setf (plist-value metaobject 'dependents)
1279         (delete dependent (plist-value metaobject 'dependents))))
1280
1281 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1282   (dolist (dependent (plist-value metaobject 'dependents))
1283     (funcall function dependent)))
1284