src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd 'class)))
  76     (let ((table (or (gethash name *name->class->slotd-table*)
  77                      (setf (gethash name *name->class->slotd-table*)
  78                            (make-hash-table :test 'eq :size 5)))))
  79       (setf (gethash class table) slotd))
  80     (dolist (type '(reader writer boundp))
  81       (let* ((gf-name (ecase type
  82                               (reader 'slot-value-using-class)
  83                               (writer '(setf slot-value-using-class))
  84                               (boundp 'slot-boundp-using-class)))
  85              (gf (gdefinition gf-name)))
  86         (compute-slot-accessor-info slotd type gf)))
  87     (initialize-internal-slot-gfs name)))
  88
  89 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
  90 ;;;
  91 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
  92 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
  93 ;;; writing/testing effective slot SLOTD.
  94 ;;;
  95 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
  96 ;;; GF.  Store the effective method in the effective slot definition
  97 ;;; object itself; these GFs have special dispatch functions calling
  98 ;;; effective methods directly retrieved from effective slot
  99 ;;; definition objects, as an optimization.
 100 ;;;
 101 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
 102 ;;; or some such.
 103 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
 104                                        type gf)
 105   (let* ((name (slot-value slotd 'name))
 106          (class (slot-value slotd 'class))
 107          (old-slotd (find-slot-definition class name))
 108          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
 109     (multiple-value-bind (function std-p)
 110         (if (eq *boot-state* 'complete)
 111             (get-accessor-method-function gf type class slotd)
 112             (get-optimized-std-accessor-method-function class slotd type))
 113       (setf (slot-accessor-std-p slotd type) std-p)
 114       (setf (slot-accessor-function slotd type) function))
 115     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 116       (push (cons class name) *pv-table-cache-update-info*))))
 117
 118 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 119   :instance)
 120 \f
 121 ;;;; various class accessors that are a little more complicated than can be
 122 ;;;; done with automatically generated reader methods
 123
 124 (defmethod class-prototype :before (class)
 125   (unless (class-finalized-p class)
 126     (error "~@<~S is not finalized.~:@>" class)))
 127
 128 ;;; KLUDGE: For some reason factoring the common body into a function
 129 ;;; breaks PCL bootstrapping, so just generate it with a macrolet for
 130 ;;; all.
 131 (macrolet ((def (class)
 132              `(defmethod class-prototype ((class ,class))
 133                 (with-slots (prototype) class
 134                   (or prototype
 135                       (setf prototype (allocate-instance class)))))))
 136   (def std-class)
 137   (def condition-class)
 138   (def structure-class))
 139
 140 (defmethod class-direct-default-initargs ((class slot-class))
 141   (plist-value class 'direct-default-initargs))
 142
 143 (defmethod class-default-initargs ((class slot-class))
 144   (plist-value class 'default-initargs))
 145
 146 (defmethod class-slot-cells ((class std-class))
 147   (plist-value class 'class-slot-cells))
 148 (defmethod (setf class-slot-cells) (new-value (class std-class))
 149   (setf (plist-value class 'class-slot-cells) new-value))
 150 \f
 151 ;;;; class accessors that are even a little bit more complicated than those
 152 ;;;; above. These have a protocol for updating them, we must implement that
 153 ;;;; protocol.
 154
 155 ;;; Maintaining the direct subclasses backpointers. The update methods are
 156 ;;; here, the values are read by an automatically generated reader method.
 157 (defmethod add-direct-subclass ((class class) (subclass class))
 158   (with-slots (direct-subclasses) class
 159     (pushnew subclass direct-subclasses)
 160     subclass))
 161 (defmethod remove-direct-subclass ((class class) (subclass class))
 162   (with-slots (direct-subclasses) class
 163     (setq direct-subclasses (remove subclass direct-subclasses))
 164     subclass))
 165
 166 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 167 ;;;
 168 ;;; There are four generic functions involved, each has one method for the
 169 ;;; class case and another method for the damned EQL specializers. All of
 170 ;;; these are specified methods and appear in their specified place in the
 171 ;;; class graph.
 172 ;;;
 173 ;;;   ADD-DIRECT-METHOD
 174 ;;;   REMOVE-DIRECT-METHOD
 175 ;;;   SPECIALIZER-DIRECT-METHODS
 176 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 177 ;;;
 178 ;;; In each case, we maintain one value which is a cons. The car is the list
 179 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 180 ;;; computed lazily.
 181 (defmethod add-direct-method ((specializer class) (method method))
 182   (with-slots (direct-methods) specializer
 183     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 184           (cdr direct-methods) ()))
 185   method)
 186 (defmethod remove-direct-method ((specializer class) (method method))
 187   (with-slots (direct-methods) specializer
 188     (setf (car direct-methods) (remove method (car direct-methods))
 189           (cdr direct-methods) ()))
 190   method)
 191
 192 (defmethod specializer-direct-methods ((specializer class))
 193   (with-slots (direct-methods) specializer
 194     (car direct-methods)))
 195
 196 (defmethod specializer-direct-generic-functions ((specializer class))
 197   (with-slots (direct-methods) specializer
 198     (or (cdr direct-methods)
 199         (setf (cdr direct-methods)
 200               (let (collect)
 201                 (dolist (m (car direct-methods))
 202                   ;; the old PCL code used COLLECTING-ONCE which used
 203                   ;; #'EQ to check for newness
 204                   (pushnew (method-generic-function m) collect :test #'eq))
 205                 (nreverse collect))))))
 206 \f
 207 ;;; This hash table is used to store the direct methods and direct generic
 208 ;;; functions of EQL specializers. Each value in the table is the cons.
 209 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 210 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 211
 212 (defmethod specializer-method-table ((specializer eql-specializer))
 213   *eql-specializer-methods*)
 214
 215 (defmethod specializer-method-table ((specializer class-eq-specializer))
 216   *class-eq-specializer-methods*)
 217
 218 (defmethod add-direct-method ((specializer specializer-with-object)
 219                               (method method))
 220   (let* ((object (specializer-object specializer))
 221          (table (specializer-method-table specializer))
 222          (entry (gethash object table)))
 223     (unless entry
 224       (setq entry
 225             (setf (gethash object table)
 226                   (cons nil nil))))
 227     (setf (car entry) (adjoin method (car entry))
 228           (cdr entry) ())
 229     method))
 230
 231 (defmethod remove-direct-method ((specializer specializer-with-object)
 232                                  (method method))
 233   (let* ((object (specializer-object specializer))
 234          (entry (gethash object (specializer-method-table specializer))))
 235     (when entry
 236       (setf (car entry) (remove method (car entry))
 237             (cdr entry) ()))
 238     method))
 239
 240 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 241   (car (gethash (specializer-object specializer)
 242                 (specializer-method-table specializer))))
 243
 244 (defmethod specializer-direct-generic-functions ((specializer
 245                                                   specializer-with-object))
 246   (let* ((object (specializer-object specializer))
 247          (entry (gethash object (specializer-method-table specializer))))
 248     (when entry
 249       (or (cdr entry)
 250           (setf (cdr entry)
 251                 (let (collect)
 252                   (dolist (m (car entry))
 253                     (pushnew (method-generic-function m) collect :test #'eq))
 254                   (nreverse collect)))))))
 255
 256 (defun map-specializers (function)
 257   (map-all-classes (lambda (class)
 258                      (funcall function (class-eq-specializer class))
 259                      (funcall function class)))
 260   (maphash (lambda (object methods)
 261              (declare (ignore methods))
 262              (intern-eql-specializer object))
 263            *eql-specializer-methods*)
 264   (maphash (lambda (object specl)
 265              (declare (ignore object))
 266              (funcall function specl))
 267            *eql-specializer-table*)
 268   nil)
 269
 270 (defun map-all-generic-functions (function)
 271   (let ((all-generic-functions (make-hash-table :test 'eq)))
 272     (map-specializers (lambda (specl)
 273                         (dolist (gf (specializer-direct-generic-functions
 274                                      specl))
 275                           (unless (gethash gf all-generic-functions)
 276                             (setf (gethash gf all-generic-functions) t)
 277                             (funcall function gf))))))
 278   nil)
 279
 280 (defmethod shared-initialize :after ((specl class-eq-specializer)
 281                                      slot-names
 282                                      &key)
 283   (declare (ignore slot-names))
 284   (setf (slot-value specl 'type) `(class-eq ,(specializer-class specl))))
 285
 286 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 287   (declare (ignore slot-names))
 288   (setf (slot-value specl 'type)
 289         `(eql ,(specializer-object specl)))
 290   (setf (info :type :translator specl)
 291         (constantly (make-member-type :members (list (specializer-object specl))))))
 292
 293 (defun real-load-defclass (name metaclass-name supers slots other
 294                            readers writers slot-names source-location)
 295   (with-single-package-locked-error (:symbol name "defining ~S as a class")
 296     (%compiler-defclass name readers writers slot-names)
 297     (let ((res (apply #'ensure-class name :metaclass metaclass-name
 298                       :direct-superclasses supers
 299                       :direct-slots slots
 300                       :definition-source source-location
 301                       other)))
 302       res)))
 303
 304 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 305
 306 (defun ensure-class (name &rest args)
 307   (apply #'ensure-class-using-class
 308          (let ((class (find-class name nil)))
 309            (when (and class (eq name (class-name class)))
 310              ;; NAME is the proper name of CLASS, so redefine it
 311              class))
 312          name
 313          args))
 314
 315 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 316   (multiple-value-bind (meta initargs)
 317       (ensure-class-values class args)
 318     (set-class-type-translation (class-prototype meta) name)
 319     (setf class (apply #'make-instance meta :name name initargs))
 320     (without-package-locks
 321       (setf (find-class name) class))
 322     (set-class-type-translation class name)
 323     class))
 324
 325 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 326   (multiple-value-bind (meta initargs)
 327       (ensure-class-values class args)
 328     (unless (eq (class-of class) meta)
 329       (apply #'change-class class meta initargs))
 330     (apply #'reinitialize-instance class initargs)
 331     (without-package-locks
 332       (setf (find-class name) class))
 333     (set-class-type-translation class name)
 334     class))
 335
 336 (defmethod class-predicate-name ((class t))
 337   'constantly-nil)
 338
 339 (defun fix-super (s)
 340   (cond ((classp s) s)
 341         ((not (legal-class-name-p s))
 342          (error "~S is not a class or a legal class name." s))
 343         (t
 344          (or (find-class s nil)
 345              (make-instance 'forward-referenced-class
 346                             :name s)))))
 347
 348 (defun ensure-class-values (class initargs)
 349   (let (metaclass metaclassp reversed-plist)
 350     (doplist (key val) initargs
 351       (cond ((eq key :metaclass)
 352              (setf metaclass val
 353                    metaclassp key))
 354             (t
 355              (when (eq key :direct-superclasses)
 356                (setf val (mapcar #'fix-super val)))
 357              (setf reversed-plist (list* val key reversed-plist)))))
 358     (values (cond (metaclassp
 359                    (if (classp metaclass)
 360                        metaclass
 361                        (find-class metaclass)))
 362                   ((or (null class) (forward-referenced-class-p class))
 363                    *the-class-standard-class*)
 364                   (t
 365                    (class-of class)))
 366             (nreverse reversed-plist))))
 367
 368 \f
 369 (defmethod shared-initialize :after
 370            ((class std-class)
 371             slot-names
 372             &key (direct-superclasses nil direct-superclasses-p)
 373                  (direct-slots nil direct-slots-p)
 374                  (direct-default-initargs nil direct-default-initargs-p)
 375                  (predicate-name nil predicate-name-p))
 376   (cond (direct-superclasses-p
 377          (setq direct-superclasses
 378                (or direct-superclasses
 379                    (list (if (funcallable-standard-class-p class)
 380                              *the-class-funcallable-standard-object*
 381                              *the-class-standard-object*))))
 382          (dolist (superclass direct-superclasses)
 383            (unless (validate-superclass class superclass)
 384              (error "~@<The class ~S was specified as a ~
 385                      super-class of the class ~S, ~
 386                      but the meta-classes ~S and ~S are incompatible.  ~
 387                      Define a method for ~S to avoid this error.~@:>"
 388                      superclass class (class-of superclass) (class-of class)
 389                      'validate-superclass)))
 390          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 391         (t
 392          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 393   (setq direct-slots
 394         (if direct-slots-p
 395             (setf (slot-value class 'direct-slots)
 396                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 397                           direct-slots))
 398             (slot-value class 'direct-slots)))
 399   (if direct-default-initargs-p
 400       (setf (plist-value class 'direct-default-initargs)
 401             direct-default-initargs)
 402       (setq direct-default-initargs
 403             (plist-value class 'direct-default-initargs)))
 404   (setf (plist-value class 'class-slot-cells)
 405         (let ((old-class-slot-cells (plist-value class 'class-slot-cells))
 406               (collect '()))
 407           (dolist (dslotd direct-slots)
 408             (when (eq :class (slot-definition-allocation dslotd))
 409               ;; see CLHS 4.3.6
 410               (let* ((name (slot-definition-name dslotd))
 411                      (old (assoc name old-class-slot-cells)))
 412                 (if (or (not old)
 413                         (eq t slot-names)
 414                         (member name slot-names))
 415                     (let* ((initfunction (slot-definition-initfunction dslotd))
 416                            (value (if initfunction
 417                                       (funcall initfunction)
 418                                       +slot-unbound+)))
 419                       (push (cons name value) collect))
 420                     (push old collect)))))
 421           (nreverse collect)))
 422   (setq predicate-name (if predicate-name-p
 423                            (setf (slot-value class 'predicate-name)
 424                                  (car predicate-name))
 425                            (or (slot-value class 'predicate-name)
 426                                (setf (slot-value class 'predicate-name)
 427                                      (make-class-predicate-name (class-name
 428                                                                  class))))))
 429   (add-direct-subclasses class direct-superclasses)
 430   (make-class-predicate class predicate-name)
 431   (update-class class nil)
 432   (do* ((slots (slot-value class 'slots) (cdr slots))
 433         (dupes nil))
 434        ((null slots) (when dupes
 435                        (style-warn
 436                         ;; FIXME: the indentation request ("~4I")
 437                         ;; below appears not to do anything.  Finding
 438                         ;; out why would be nice.  -- CSR, 2003-04-24
 439                         "~@<slot names with the same SYMBOL-NAME but ~
 440                          different SYMBOL-PACKAGE (possible package problem) ~
 441                          for class ~S:~@:_~4I~<~@{~S~^~:@_~}~:>~@:>"
 442                         class
 443                         dupes)))
 444     (let* ((slot (car slots))
 445            (oslots (remove (slot-definition-name slot) (cdr slots)
 446                            :test #'string/= :key #'slot-definition-name)))
 447       (when oslots
 448         (pushnew (cons (slot-definition-name slot)
 449                        (mapcar #'slot-definition-name oslots))
 450                  dupes
 451                  :test #'string= :key #'car))))
 452   (add-slot-accessors class direct-slots)
 453   (make-preliminary-layout class))
 454
 455 (defmethod shared-initialize :after ((class forward-referenced-class)
 456                                      slot-names &key &allow-other-keys)
 457   (declare (ignore slot-names))
 458   (make-preliminary-layout class))
 459
 460 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 461
 462 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 463 ;;; make it known to the type system.
 464 (defun make-preliminary-layout (class)
 465   (flet ((compute-preliminary-cpl (root)
 466            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 467              (compute-class-precedence-list root))))
 468     (without-package-locks
 469      (unless (class-finalized-p class)
 470        (let ((name (class-name class)))
 471          (setf (find-class name) class)
 472          ;; KLUDGE: This is fairly horrible.  We need to make a
 473          ;; full-fledged CLASSOID here, not just tell the compiler that
 474          ;; some class is forthcoming, because there are legitimate
 475          ;; questions one can ask of the type system, implemented in
 476          ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 477          (when (and (eq *boot-state* 'complete)
 478                     (null (find-classoid name nil)))
 479            (setf (find-classoid name)
 480                  (make-standard-classoid :name name)))
 481          (set-class-type-translation class name)
 482          (let ((layout (make-wrapper 0 class))
 483                (classoid (find-classoid name)))
 484            (setf (layout-classoid layout) classoid)
 485            (setf (classoid-pcl-class classoid) class)
 486            (setf (slot-value class 'wrapper) layout)
 487            (let ((cpl (compute-preliminary-cpl class)))
 488              (setf (layout-inherits layout)
 489                    (order-layout-inherits
 490                     (map 'simple-vector #'class-wrapper
 491                          (reverse (rest cpl))))))
 492            (register-layout layout :invalidate t)
 493            (setf (classoid-layout classoid) layout)
 494            (mapc #'make-preliminary-layout (class-direct-subclasses class))))))))
 495
 496
 497 (defmethod shared-initialize :before ((class class) slot-names &key name)
 498   (declare (ignore slot-names name))
 499   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 500   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 501   (setf (slot-value class 'type) `(class ,class))
 502   (setf (slot-value class 'class-eq-specializer)
 503         (make-instance 'class-eq-specializer :class class)))
 504
 505 (defmethod reinitialize-instance :before ((class slot-class) &key direct-superclasses)
 506   (dolist (old-super (set-difference (class-direct-superclasses class) direct-superclasses))
 507     (remove-direct-subclass old-super class))
 508   (remove-slot-accessors    class (class-direct-slots class)))
 509
 510 (defmethod reinitialize-instance :after ((class slot-class)
 511                                          &rest initargs
 512                                          &key)
 513   (map-dependents class
 514                   (lambda (dependent)
 515                     (apply #'update-dependent class dependent initargs))))
 516
 517 (defmethod shared-initialize :after ((class condition-class) slot-names
 518                                      &key direct-slots direct-superclasses)
 519   (declare (ignore slot-names))
 520   (let ((classoid (find-classoid (class-name class))))
 521     (with-slots (wrapper class-precedence-list cpl-available-p
 522                          prototype predicate-name
 523                          (direct-supers direct-superclasses))
 524         class
 525       (setf (slot-value class 'direct-slots)
 526             (mapcar (lambda (pl) (make-direct-slotd class pl))
 527                     direct-slots))
 528       (setf (slot-value class 'finalized-p) t)
 529       (setf (classoid-pcl-class classoid) class)
 530       (setq direct-supers direct-superclasses)
 531       (setq wrapper (classoid-layout classoid))
 532       (setq class-precedence-list (compute-class-precedence-list class))
 533       (setq cpl-available-p t)
 534       (add-direct-subclasses class direct-superclasses)
 535       (setq predicate-name (make-class-predicate-name (class-name class)))
 536       (make-class-predicate class predicate-name)
 537       (setf (slot-value class 'slots) (compute-slots class))))
 538   ;; Comment from Gerd's PCL, 2003-05-15:
 539   ;;
 540   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 541   ;; override condition accessors with generic functions.  We do this
 542   ;; differently.
 543   (update-pv-table-cache-info class))
 544
 545 (defmethod direct-slot-definition-class ((class condition-class)
 546                                          &rest initargs)
 547   (declare (ignore initargs))
 548   (find-class 'condition-direct-slot-definition))
 549
 550 (defmethod effective-slot-definition-class ((class condition-class)
 551                                             &rest initargs)
 552   (declare (ignore initargs))
 553   (find-class 'condition-effective-slot-definition))
 554
 555 (defmethod finalize-inheritance ((class condition-class))
 556   (aver (slot-value class 'finalized-p))
 557   nil)
 558
 559 (defmethod compute-effective-slot-definition
 560     ((class condition-class) slot-name dslotds)
 561   (let ((slotd (call-next-method)))
 562     (setf (slot-definition-reader-function slotd)
 563           (lambda (x)
 564             (handler-case (condition-reader-function x slot-name)
 565               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 566               ;; is unbound; maybe it should be a CELL-ERROR of some
 567               ;; sort?
 568               (error () (values (slot-unbound class x slot-name))))))
 569     (setf (slot-definition-writer-function slotd)
 570           (lambda (v x)
 571             (condition-writer-function x v slot-name)))
 572     (setf (slot-definition-boundp-function slotd)
 573           (lambda (x)
 574             (multiple-value-bind (v c)
 575                 (ignore-errors (condition-reader-function x slot-name))
 576               (declare (ignore v))
 577               (null c))))
 578     slotd))
 579
 580 (defmethod compute-slots ((class condition-class))
 581   (mapcan (lambda (superclass)
 582             (mapcar (lambda (dslotd)
 583                       (compute-effective-slot-definition
 584                        class (slot-definition-name dslotd) (list dslotd)))
 585                     (class-direct-slots superclass)))
 586           (reverse (slot-value class 'class-precedence-list))))
 587
 588 (defmethod compute-slots :around ((class condition-class))
 589   (let ((eslotds (call-next-method)))
 590     (mapc #'initialize-internal-slot-functions eslotds)
 591     eslotds))
 592
 593 (defmethod shared-initialize :after
 594     ((slotd structure-slot-definition) slot-names &key
 595      (allocation :instance) allocation-class)
 596   (declare (ignore slot-names allocation-class))
 597   (unless (eq allocation :instance)
 598     (error "Structure slots must have :INSTANCE allocation.")))
 599
 600 (defun make-structure-class-defstruct-form (name direct-slots include)
 601   (let* ((conc-name (format-symbol *package* "~S structure class " name))
 602          (constructor (format-symbol *package* "~Aconstructor" conc-name))
 603          (defstruct `(defstruct (,name
 604                                  ,@(when include
 605                                          `((:include ,(class-name include))))
 606                                  (:predicate nil)
 607                                  (:conc-name ,conc-name)
 608                                  (:constructor ,constructor ())
 609                                  (:copier nil))
 610                       ,@(mapcar (lambda (slot)
 611                                   `(,(slot-definition-name slot)
 612                                     +slot-unbound+))
 613                                 direct-slots)))
 614          (reader-names (mapcar (lambda (slotd)
 615                                  (list 'slot-accessor name
 616                                        (slot-definition-name slotd)
 617                                        'reader))
 618                                direct-slots))
 619          (writer-names (mapcar (lambda (slotd)
 620                                  (list 'slot-accessor name
 621                                        (slot-definition-name slotd)
 622                                        'writer))
 623                                direct-slots))
 624          (readers-init
 625            (mapcar (lambda (slotd reader-name)
 626                      (let ((accessor
 627                              (slot-definition-defstruct-accessor-symbol
 628                               slotd)))
 629                        `(defun ,reader-name (obj)
 630                          (declare (type ,name obj))
 631                          (,accessor obj))))
 632                    direct-slots reader-names))
 633          (writers-init
 634            (mapcar (lambda (slotd writer-name)
 635                      (let ((accessor
 636                              (slot-definition-defstruct-accessor-symbol
 637                               slotd)))
 638                        `(defun ,writer-name (nv obj)
 639                          (declare (type ,name obj))
 640                          (setf (,accessor obj) nv))))
 641                    direct-slots writer-names))
 642          (defstruct-form
 643              `(progn
 644                ,defstruct
 645                ,@readers-init ,@writers-init
 646                (cons nil nil))))
 647     (values defstruct-form constructor reader-names writer-names)))
 648
 649 (defun make-defstruct-allocation-function (class)
 650   (let ((dd (get-structure-dd (class-name class))))
 651     (lambda ()
 652       (sb-kernel::%make-instance-with-layout
 653        (sb-kernel::compiler-layout-or-lose (dd-name dd))))))
 654
 655 (defmethod shared-initialize :after
 656     ((class structure-class)
 657      slot-names
 658      &key (direct-superclasses nil direct-superclasses-p)
 659      (direct-slots nil direct-slots-p)
 660      direct-default-initargs
 661      (predicate-name nil predicate-name-p))
 662   (declare (ignore slot-names direct-default-initargs))
 663   (if direct-superclasses-p
 664       (setf (slot-value class 'direct-superclasses)
 665             (or direct-superclasses
 666                 (setq direct-superclasses
 667                       (and (not (eq (class-name class) 'structure-object))
 668                            (list *the-class-structure-object*)))))
 669       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 670   (let* ((name (class-name class))
 671          (from-defclass-p (slot-value class 'from-defclass-p))
 672          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 673     (if direct-slots-p
 674         (setf (slot-value class 'direct-slots)
 675               (setq direct-slots
 676                     (mapcar (lambda (pl)
 677                               (when defstruct-p
 678                                 (let* ((slot-name (getf pl :name))
 679                                        (accessor
 680                                         (format-symbol *package*
 681                                                        "~S structure class ~A"
 682                                                        name slot-name)))
 683                                   (setq pl (list* :defstruct-accessor-symbol
 684                                                   accessor pl))))
 685                               (make-direct-slotd class pl))
 686                             direct-slots)))
 687         (setq direct-slots (slot-value class 'direct-slots)))
 688     (if defstruct-p
 689         (let ((include (car (slot-value class 'direct-superclasses))))
 690           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 691               (make-structure-class-defstruct-form name direct-slots include)
 692             (unless (structure-type-p name) (eval defstruct-form))
 693             (mapc (lambda (dslotd reader-name writer-name)
 694                     (let* ((reader (gdefinition reader-name))
 695                            (writer (when (fboundp writer-name)
 696                                      (gdefinition writer-name))))
 697                       (setf (slot-value dslotd 'internal-reader-function)
 698                             reader)
 699                       (setf (slot-value dslotd 'internal-writer-function)
 700                             writer)))
 701                   direct-slots reader-names writer-names)
 702             (setf (slot-value class 'defstruct-form) defstruct-form)
 703             (setf (slot-value class 'defstruct-constructor) constructor)))
 704         (setf (slot-value class 'defstruct-constructor)
 705               (make-defstruct-allocation-function class)))
 706     (add-direct-subclasses class direct-superclasses)
 707     (setf (slot-value class 'class-precedence-list)
 708           (compute-class-precedence-list class))
 709     (setf (slot-value class 'cpl-available-p) t)
 710     (setf (slot-value class 'slots) (compute-slots class))
 711     (let ((lclass (find-classoid (class-name class))))
 712       (setf (classoid-pcl-class lclass) class)
 713       (setf (slot-value class 'wrapper) (classoid-layout lclass)))
 714     (setf (slot-value class 'finalized-p) t)
 715     (update-pv-table-cache-info class)
 716     (setq predicate-name (if predicate-name-p
 717                            (setf (slot-value class 'predicate-name)
 718                                    (car predicate-name))
 719                            (or (slot-value class 'predicate-name)
 720                                (setf (slot-value class 'predicate-name)
 721                                        (make-class-predicate-name
 722                                         (class-name class))))))
 723     (make-class-predicate class predicate-name)
 724     (add-slot-accessors class direct-slots)))
 725
 726 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 727   (declare (ignore initargs))
 728   (find-class 'structure-direct-slot-definition))
 729
 730 (defmethod finalize-inheritance ((class structure-class))
 731   nil) ; always finalized
 732 \f
 733 (defun add-slot-accessors (class dslotds)
 734   (fix-slot-accessors class dslotds 'add))
 735
 736 (defun remove-slot-accessors (class dslotds)
 737   (fix-slot-accessors class dslotds 'remove))
 738
 739 (defun fix-slot-accessors (class dslotds add/remove)
 740   (flet ((fix (gfspec name r/w)
 741            (let ((gf (cond ((eq add/remove 'add)
 742                             (if (fboundp gfspec)
 743                                 (without-package-locks
 744                                   (ensure-generic-function gfspec))
 745                                 (ensure-generic-function
 746                                  gfspec :lambda-list (case r/w
 747                                                        (r '(object))
 748                                                        (w '(new-value object))))))
 749                            ((generic-function-p (and (fboundp gfspec)
 750                                                      (fdefinition gfspec)))
 751                             (without-package-locks
 752                               (ensure-generic-function gfspec))))))
 753              (when gf
 754                (case r/w
 755                  (r (if (eq add/remove 'add)
 756                         (add-reader-method class gf name)
 757                         (remove-reader-method class gf)))
 758                  (w (if (eq add/remove 'add)
 759                         (add-writer-method class gf name)
 760                         (remove-writer-method class gf))))))))
 761     (dolist (dslotd dslotds)
 762       (let ((slot-name (slot-definition-name dslotd)))
 763         (dolist (r (slot-definition-readers dslotd))
 764           (fix r slot-name 'r))
 765         (dolist (w (slot-definition-writers dslotd))
 766           (fix w slot-name 'w))))))
 767 \f
 768 (defun add-direct-subclasses (class supers)
 769   (dolist (super supers)
 770     (unless (memq class (class-direct-subclasses class))
 771       (add-direct-subclass super class))))
 772
 773 (defmethod finalize-inheritance ((class std-class))
 774   (update-class class t))
 775
 776 (defmethod finalize-inheritance ((class forward-referenced-class))
 777   ;; FIXME: should we not be thinking a bit about what kinds of error
 778   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 779   ;; possibly a forward-referenced-class-error, though that's
 780   ;; difficult given e.g. class precedence list calculations...
 781   (error
 782    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 783        ~2I~_~S~:>"
 784    class))
 785
 786 \f
 787 (defun class-has-a-forward-referenced-superclass-p (class)
 788   (or (forward-referenced-class-p class)
 789       (some #'class-has-a-forward-referenced-superclass-p
 790             (class-direct-superclasses class))))
 791
 792 ;;; This is called by :after shared-initialize whenever a class is initialized
 793 ;;; or reinitialized. The class may or may not be finalized.
 794 (defun update-class (class finalizep)
 795   ;; Comment from Gerd Moellmann:
 796   ;;
 797   ;; Note that we can't simply delay the finalization when CLASS has
 798   ;; no forward referenced superclasses because that causes bootstrap
 799   ;; problems.
 800   (without-package-locks
 801    (when (and (not finalizep)
 802               (not (class-finalized-p class))
 803               (not (class-has-a-forward-referenced-superclass-p class)))
 804      (finalize-inheritance class)
 805      (return-from update-class))
 806    (when (or finalizep (class-finalized-p class)
 807              (not (class-has-a-forward-referenced-superclass-p class)))
 808      (setf (find-class (class-name class)) class)
 809      (update-cpl class (compute-class-precedence-list class))
 810      ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 811      ;; class.  The hoops above are to ensure that FINALIZE-INHERITANCE
 812      ;; is called at finalization, so that MOP programmers can hook
 813      ;; into the system as described in "Class Finalization Protocol"
 814      ;; (section 5.5.2 of AMOP).
 815      (update-slots class (compute-slots class))
 816      (update-gfs-of-class class)
 817      (update-initargs class (compute-default-initargs class))
 818      (update-ctors 'finalize-inheritance :class class))
 819    (unless finalizep
 820      (dolist (sub (class-direct-subclasses class))
 821        (update-class sub nil)))))
 822
 823 (define-condition cpl-protocol-violation (reference-condition error)
 824   ((class :initarg :class :reader cpl-protocol-violation-class)
 825    (cpl :initarg :cpl :reader cpl-protocol-violation-cpl))
 826   (:default-initargs :references (list '(:sbcl :node "Metaobject Protocol")))
 827   (:report
 828    (lambda (c s)
 829      (format s "~@<Protocol violation: the ~S class ~S ~
 830                 ~:[has~;does not have~] the class ~S in its ~
 831                 class precedence list: ~S.~@:>"
 832              (class-name (class-of (cpl-protocol-violation-class c)))
 833              (cpl-protocol-violation-class c)
 834              (eq (class-of (cpl-protocol-violation-class c))
 835                  *the-class-funcallable-standard-class*)
 836              (find-class 'function)
 837              (cpl-protocol-violation-cpl c)))))
 838
 839 (defun update-cpl (class cpl)
 840   (when (eq (class-of class) *the-class-standard-class*)
 841     (when (find (find-class 'function) cpl)
 842       (error 'cpl-protocol-violation :class class :cpl cpl)))
 843   (when (eq (class-of class) *the-class-funcallable-standard-class*)
 844     (unless (find (find-class 'function) cpl)
 845       (error 'cpl-protocol-violation :class class :cpl cpl)))
 846   (if (class-finalized-p class)
 847       (unless (and (equal (class-precedence-list class) cpl)
 848                    (dolist (c cpl t)
 849                      (when (position :class (class-direct-slots c)
 850                                      :key #'slot-definition-allocation)
 851                        (return nil))))
 852         ;; comment from the old CMU CL sources:
 853         ;;   Need to have the cpl setup before update-lisp-class-layout
 854         ;;   is called on CMU CL.
 855         (setf (slot-value class 'class-precedence-list) cpl)
 856         (setf (slot-value class 'cpl-available-p) t)
 857         (force-cache-flushes class))
 858       (progn
 859         (setf (slot-value class 'class-precedence-list) cpl)
 860         (setf (slot-value class 'cpl-available-p) t)))
 861   (update-class-can-precede-p cpl))
 862
 863 (defun update-class-can-precede-p (cpl)
 864   (when cpl
 865     (let ((first (car cpl)))
 866       (dolist (c (cdr cpl))
 867         (pushnew c (slot-value first 'can-precede-list))))
 868     (update-class-can-precede-p (cdr cpl))))
 869
 870 (defun class-can-precede-p (class1 class2)
 871   (member class2 (class-can-precede-list class1)))
 872
 873 (defun update-slots (class eslotds)
 874   (let ((instance-slots ())
 875         (class-slots    ()))
 876     (dolist (eslotd eslotds)
 877       (let ((alloc (slot-definition-allocation eslotd)))
 878         (case alloc
 879           (:instance (push eslotd instance-slots))
 880           (:class (push eslotd class-slots)))))
 881
 882     ;; If there is a change in the shape of the instances then the
 883     ;; old class is now obsolete.
 884     (let* ((nlayout (mapcar #'slot-definition-name
 885                             (sort instance-slots #'<
 886                                   :key #'slot-definition-location)))
 887            (nslots (length nlayout))
 888            (nwrapper-class-slots (compute-class-slots class-slots))
 889            (owrapper (when (class-finalized-p class)
 890                        (class-wrapper class)))
 891            (olayout (when owrapper
 892                       (wrapper-instance-slots-layout owrapper)))
 893            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 894            (nwrapper
 895             (cond ((null owrapper)
 896                    (make-wrapper nslots class))
 897                   ((and (equal nlayout olayout)
 898                         (not
 899                          (loop for o in owrapper-class-slots
 900                                for n in nwrapper-class-slots
 901                                do (unless (eq (car o) (car n)) (return t)))))
 902                    owrapper)
 903                   (t
 904                    ;; This will initialize the new wrapper to have the
 905                    ;; same state as the old wrapper. We will then have
 906                    ;; to change that. This may seem like wasted work
 907                    ;; (and it is), but the spec requires that we call
 908                    ;; MAKE-INSTANCES-OBSOLETE.
 909                    (make-instances-obsolete class)
 910                    (class-wrapper class)))))
 911
 912       (with-slots (wrapper slots) class
 913         (update-lisp-class-layout class nwrapper)
 914         (setf slots eslotds
 915               (wrapper-instance-slots-layout nwrapper) nlayout
 916               (wrapper-class-slots nwrapper) nwrapper-class-slots
 917               (wrapper-no-of-instance-slots nwrapper) nslots
 918               wrapper nwrapper))
 919       (setf (slot-value class 'finalized-p) t)
 920       (unless (eq owrapper nwrapper)
 921         (update-pv-table-cache-info class)
 922         (maybe-update-standard-class-locations class)))))
 923
 924 (defun compute-class-slots (eslotds)
 925   (let (collect)
 926     (dolist (eslotd eslotds)
 927       (push (assoc (slot-definition-name eslotd)
 928                    (class-slot-cells (slot-definition-class eslotd)))
 929             collect))
 930     (nreverse collect)))
 931
 932 (defun update-gfs-of-class (class)
 933   (when (and (class-finalized-p class)
 934              (let ((cpl (class-precedence-list class)))
 935                (or (member *the-class-slot-class* cpl)
 936                    (member *the-class-standard-effective-slot-definition*
 937                            cpl))))
 938     (let ((gf-table (make-hash-table :test 'eq)))
 939       (labels ((collect-gfs (class)
 940                  (dolist (gf (specializer-direct-generic-functions class))
 941                    (setf (gethash gf gf-table) t))
 942                  (mapc #'collect-gfs (class-direct-superclasses class))))
 943         (collect-gfs class)
 944         (maphash (lambda (gf ignore)
 945                    (declare (ignore ignore))
 946                    (update-gf-dfun class gf))
 947                  gf-table)))))
 948
 949 (defun update-initargs (class inits)
 950   (setf (plist-value class 'default-initargs) inits))
 951 \f
 952 (defmethod compute-default-initargs ((class slot-class))
 953   (let ((initargs (loop for c in (class-precedence-list class)
 954                         append (class-direct-default-initargs c))))
 955     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
 956 \f
 957 ;;;; protocols for constructing direct and effective slot definitions
 958
 959 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
 960   (declare (ignore initargs))
 961   (find-class 'standard-direct-slot-definition))
 962
 963 (defun make-direct-slotd (class initargs)
 964   (apply #'make-instance
 965          (apply #'direct-slot-definition-class class initargs)
 966          :class class
 967          initargs))
 968
 969 ;;; I (CSR) am not sure, but I believe that the particular order of
 970 ;;; slots is quite important: it is ideal to attempt to have a
 971 ;;; constant slot location for the same notional slots as much as
 972 ;;; possible, so that clever discriminating functions (ONE-INDEX et
 973 ;;; al.) have a chance of working.  The below at least walks through
 974 ;;; the slots predictably, but maybe it would be good to compute some
 975 ;;; kind of optimal slot layout by looking at locations of slots in
 976 ;;; superclasses?
 977 (defun std-compute-slots (class)
 978   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 979   ;; for each different slot name we find in our superclasses. Each
 980   ;; call receives the class and a list of the dslotds with that name.
 981   ;; The list is in most-specific-first order.
 982   (let ((name-dslotds-alist ()))
 983     (dolist (c (reverse (class-precedence-list class)))
 984       (dolist (slot (class-direct-slots c))
 985         (let* ((name (slot-definition-name slot))
 986                (entry (assq name name-dslotds-alist)))
 987           (if entry
 988               (push slot (cdr entry))
 989               (push (list name slot) name-dslotds-alist)))))
 990     (mapcar (lambda (direct)
 991               (compute-effective-slot-definition class
 992                                                  (car direct)
 993                                                  (cdr direct)))
 994             (nreverse name-dslotds-alist))))
 995
 996 (defmethod compute-slots ((class standard-class))
 997   (std-compute-slots class))
 998 (defmethod compute-slots ((class funcallable-standard-class))
 999   (std-compute-slots class))
1000
1001 (defun std-compute-slots-around (class eslotds)
1002   (let ((location -1))
1003     (dolist (eslotd eslotds eslotds)
1004       (setf (slot-definition-location eslotd)
1005             (case (slot-definition-allocation eslotd)
1006               (:instance
1007                (incf location))
1008               (:class
1009                (let* ((name (slot-definition-name eslotd))
1010                       (from-class
1011                        (or
1012                         (slot-definition-allocation-class eslotd)
1013                         ;; we get here if the user adds an extra slot
1014                         ;; himself...
1015                         (setf (slot-definition-allocation-class eslotd)
1016                               class)))
1017                       ;; which raises the question of what we should
1018                       ;; do if we find that said user has added a slot
1019                       ;; with the same name as another slot...
1020                       (cell (or (assq name (class-slot-cells from-class))
1021                                 (setf (class-slot-cells from-class)
1022                                       (cons (cons name +slot-unbound+)
1023                                             (class-slot-cells from-class))))))
1024                  (aver (consp cell))
1025                  (if (eq +slot-unbound+ (cdr cell))
1026                      ;; We may have inherited an initfunction
1027                      (let ((initfun (slot-definition-initfunction eslotd)))
1028                        (if initfun
1029                            (rplacd cell (funcall initfun))
1030                            cell))
1031                      cell)))))
1032       (unless (slot-definition-class eslotd)
1033         (setf (slot-definition-class eslotd) class))
1034       (initialize-internal-slot-functions eslotd))))
1035
1036 (defmethod compute-slots :around ((class standard-class))
1037   (let ((eslotds (call-next-method)))
1038     (std-compute-slots-around class eslotds)))
1039 (defmethod compute-slots :around ((class funcallable-standard-class))
1040   (let ((eslotds (call-next-method)))
1041     (std-compute-slots-around class eslotds)))
1042
1043 (defmethod compute-slots ((class structure-class))
1044   (mapcan (lambda (superclass)
1045             (mapcar (lambda (dslotd)
1046                       (compute-effective-slot-definition
1047                        class
1048                        (slot-definition-name dslotd)
1049                        (list dslotd)))
1050                     (class-direct-slots superclass)))
1051           (reverse (slot-value class 'class-precedence-list))))
1052
1053 (defmethod compute-slots :around ((class structure-class))
1054   (let ((eslotds (call-next-method)))
1055     (mapc #'initialize-internal-slot-functions eslotds)
1056     eslotds))
1057
1058 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1059   (declare (ignore name))
1060   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1061          (class (apply #'effective-slot-definition-class class initargs)))
1062     (apply #'make-instance class initargs)))
1063
1064 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1065   (declare (ignore initargs))
1066   (find-class 'standard-effective-slot-definition))
1067
1068 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1069   (declare (ignore initargs))
1070   (find-class 'structure-effective-slot-definition))
1071
1072 (defmethod compute-effective-slot-definition-initargs
1073     ((class slot-class) direct-slotds)
1074   (let* ((name nil)
1075          (initfunction nil)
1076          (initform nil)
1077          (initargs nil)
1078          (allocation nil)
1079          (allocation-class nil)
1080          (type t)
1081          (documentation nil)
1082          (documentationp nil)
1083          (namep  nil)
1084          (initp  nil)
1085          (allocp nil))
1086
1087     (dolist (slotd direct-slotds)
1088       (when slotd
1089         (unless namep
1090           (setq name (slot-definition-name slotd)
1091                 namep t))
1092         (unless initp
1093           (when (slot-definition-initfunction slotd)
1094             (setq initform (slot-definition-initform slotd)
1095                   initfunction (slot-definition-initfunction slotd)
1096                   initp t)))
1097         (unless documentationp
1098           (when (%slot-definition-documentation slotd)
1099             (setq documentation (%slot-definition-documentation slotd)
1100                   documentationp t)))
1101         (unless allocp
1102           (setq allocation (slot-definition-allocation slotd)
1103                 allocation-class (slot-definition-class slotd)
1104                 allocp t))
1105         (setq initargs (append (slot-definition-initargs slotd) initargs))
1106         (let ((slotd-type (slot-definition-type slotd)))
1107           (setq type (cond ((eq type t) slotd-type)
1108                            ((*subtypep type slotd-type) type)
1109                            (t `(and ,type ,slotd-type)))))))
1110     (list :name name
1111           :initform initform
1112           :initfunction initfunction
1113           :initargs initargs
1114           :allocation allocation
1115           :allocation-class allocation-class
1116           :type type
1117           :class class
1118           :documentation documentation)))
1119
1120 (defmethod compute-effective-slot-definition-initargs :around
1121     ((class structure-class) direct-slotds)
1122   (let ((slotd (car direct-slotds)))
1123     (list* :defstruct-accessor-symbol
1124            (slot-definition-defstruct-accessor-symbol slotd)
1125            :internal-reader-function
1126            (slot-definition-internal-reader-function slotd)
1127            :internal-writer-function
1128            (slot-definition-internal-writer-function slotd)
1129            (call-next-method))))
1130 \f
1131 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1132 ;;;       to make the method object. They have to use make-a-method which
1133 ;;;       is a specially bootstrapped mechanism for making standard methods.
1134 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1135   (declare (ignore direct-slot initargs))
1136   (find-class 'standard-reader-method))
1137
1138 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
1139   (add-method generic-function
1140               (make-a-method 'standard-reader-method
1141                              ()
1142                              (list (or (class-name class) 'object))
1143                              (list class)
1144                              (make-reader-method-function class slot-name)
1145                              "automatically generated reader method"
1146                              slot-name)))
1147
1148 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1149   (declare (ignore direct-slot initargs))
1150   (find-class 'standard-writer-method))
1151
1152 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
1153   (add-method generic-function
1154               (make-a-method 'standard-writer-method
1155                              ()
1156                              (list 'new-value (or (class-name class) 'object))
1157                              (list *the-class-t* class)
1158                              (make-writer-method-function class slot-name)
1159                              "automatically generated writer method"
1160                              slot-name)))
1161
1162 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
1163   (add-method generic-function
1164               (make-a-method 'standard-boundp-method
1165                              ()
1166                              (list (or (class-name class) 'object))
1167                              (list class)
1168                              (make-boundp-method-function class slot-name)
1169                              "automatically generated boundp method"
1170                              slot-name)))
1171
1172 (defmethod remove-reader-method ((class slot-class) generic-function)
1173   (let ((method (get-method generic-function () (list class) nil)))
1174     (when method (remove-method generic-function method))))
1175
1176 (defmethod remove-writer-method ((class slot-class) generic-function)
1177   (let ((method
1178           (get-method generic-function () (list *the-class-t* class) nil)))
1179     (when method (remove-method generic-function method))))
1180
1181 (defmethod remove-boundp-method ((class slot-class) generic-function)
1182   (let ((method (get-method generic-function () (list class) nil)))
1183     (when method (remove-method generic-function method))))
1184 \f
1185 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITE-METHOD function are NOT
1186 ;;; part of the standard protocol. They are however useful, PCL makes
1187 ;;; use of them internally and documents them for PCL users.
1188 ;;;
1189 ;;; *** This needs work to make type testing by the writer functions which
1190 ;;; *** do type testing faster. The idea would be to have one constructor
1191 ;;; *** for each possible type test.
1192 ;;;
1193 ;;; *** There is a subtle bug here which is going to have to be fixed.
1194 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1195 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1196 ;;; *** defined for this metaclass a chance to run.
1197
1198 (defmethod make-reader-method-function ((class slot-class) slot-name)
1199   (make-std-reader-method-function (class-name class) slot-name))
1200
1201 (defmethod make-writer-method-function ((class slot-class) slot-name)
1202   (make-std-writer-method-function (class-name class) slot-name))
1203
1204 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1205   (make-std-boundp-method-function (class-name class) slot-name))
1206 \f
1207 (defmethod compatible-meta-class-change-p (class proto-new-class)
1208   (eq (class-of class) (class-of proto-new-class)))
1209
1210 (defmethod validate-superclass ((class class) (superclass class))
1211   (or (eq superclass *the-class-t*)
1212       (eq (class-of class) (class-of superclass))
1213       (and (eq (class-of superclass) *the-class-standard-class*)
1214            (eq (class-of class) *the-class-funcallable-standard-class*))
1215       (and (eq (class-of superclass) *the-class-funcallable-standard-class*)
1216            (eq (class-of class) *the-class-standard-class*))))
1217 \f
1218 ;;; What this does depends on which of the four possible values of
1219 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1220 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1221 ;;; nothing to do, as the new wrapper has already been created.  If
1222 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1223 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1224 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1225 ;;;
1226 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1227 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1228 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1229 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1230 ;;; obsolete the wrapper.
1231 ;;;
1232 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1233 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1234 ;;;                    :UNINITIALIZED)))
1235 ;;;
1236 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1237 (defun force-cache-flushes (class)
1238   (let* ((owrapper (class-wrapper class)))
1239     ;; We only need to do something if the wrapper is still valid. If
1240     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1241     ;; both of those will already be doing what we want. In
1242     ;; particular, we must be sure we never change an OBSOLETE into a
1243     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1244     (when (or (not (invalid-wrapper-p owrapper))
1245               ;; KLUDGE: despite the observations above, this remains
1246               ;; a violation of locality or what might be considered
1247               ;; good style.  There has to be a better way!  -- CSR,
1248               ;; 2002-10-29
1249               (eq (layout-invalid owrapper) t))
1250       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1251                                     class)))
1252         (setf (wrapper-instance-slots-layout nwrapper)
1253               (wrapper-instance-slots-layout owrapper))
1254         (setf (wrapper-class-slots nwrapper)
1255               (wrapper-class-slots owrapper))
1256         (with-pcl-lock
1257           (update-lisp-class-layout class nwrapper)
1258           (setf (slot-value class 'wrapper) nwrapper)
1259           ;; Use :OBSOLETE instead of :FLUSH if any superclass has
1260           ;; been obsoleted.
1261           (if (find-if (lambda (x)
1262                          (and (consp x) (eq :obsolete (car x))))
1263                        (layout-inherits owrapper)
1264                        :key #'layout-invalid)
1265               (invalidate-wrapper owrapper :obsolete nwrapper)
1266               (invalidate-wrapper owrapper :flush nwrapper)))))))
1267
1268 (defun flush-cache-trap (owrapper nwrapper instance)
1269   (declare (ignore owrapper))
1270   (set-wrapper instance nwrapper))
1271 \f
1272 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1273 ;;; the next access to the instance (as defined in 88-002R) to trap
1274 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1275 (defmethod make-instances-obsolete ((class std-class))
1276   (let* ((owrapper (class-wrapper class))
1277          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1278                                  class)))
1279       (setf (wrapper-instance-slots-layout nwrapper)
1280             (wrapper-instance-slots-layout owrapper))
1281       (setf (wrapper-class-slots nwrapper)
1282             (wrapper-class-slots owrapper))
1283       (with-pcl-lock
1284         (update-lisp-class-layout class nwrapper)
1285         (setf (slot-value class 'wrapper) nwrapper)
1286         (invalidate-wrapper owrapper :obsolete nwrapper)
1287         class)))
1288
1289 (defmethod make-instances-obsolete ((class symbol))
1290   (make-instances-obsolete (find-class class))
1291   ;; ANSI wants the class name when called with a symbol.
1292   class)
1293
1294 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1295 ;;; see an obsolete instance. The times when it is called are:
1296 ;;;   - when the instance is involved in method lookup
1297 ;;;   - when attempting to access a slot of an instance
1298 ;;;
1299 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1300 ;;; instance access macros.
1301 ;;;
1302 ;;; Of course these times when it is called are an internal
1303 ;;; implementation detail of PCL and are not part of the documented
1304 ;;; description of when the obsolete instance update happens. The
1305 ;;; documented description is as it appears in 88-002R.
1306 ;;;
1307 ;;; This has to return the new wrapper, so it counts on all the
1308 ;;; methods on obsolete-instance-trap-internal to return the new
1309 ;;; wrapper. It also does a little internal error checking to make
1310 ;;; sure that the traps are only happening when they should, and that
1311 ;;; the trap methods are computing appropriate new wrappers.
1312
1313 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1314 ;;; after a structure is redefined. In most cases,
1315 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1316 ;;; so it must signal an error. The hard part of this is that the
1317 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1318 ;;; called again, so in that case, we have to return some reasonable
1319 ;;; wrapper, instead.
1320
1321 (defvar *in-obsolete-instance-trap* nil)
1322 (defvar *the-wrapper-of-structure-object*
1323   (class-wrapper (find-class 'structure-object)))
1324
1325 (define-condition obsolete-structure (error)
1326   ((datum :reader obsolete-structure-datum :initarg :datum))
1327   (:report
1328    (lambda (condition stream)
1329      ;; Don't try to print the structure, since it probably won't work.
1330      (format stream
1331              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1332              (type-of (obsolete-structure-datum condition))))))
1333
1334 (defun obsolete-instance-trap (owrapper nwrapper instance)
1335   (if (not (pcl-instance-p instance))
1336       (if *in-obsolete-instance-trap*
1337           *the-wrapper-of-structure-object*
1338            (let ((*in-obsolete-instance-trap* t))
1339              (error 'obsolete-structure :datum instance)))
1340       (let* ((class (wrapper-class* nwrapper))
1341              (copy (allocate-instance class)) ;??? allocate-instance ???
1342              (olayout (wrapper-instance-slots-layout owrapper))
1343              (nlayout (wrapper-instance-slots-layout nwrapper))
1344              (oslots (get-slots instance))
1345              (nslots (get-slots copy))
1346              (oclass-slots (wrapper-class-slots owrapper))
1347              (added ())
1348              (discarded ())
1349              (plist ()))
1350
1351         ;; local  --> local     transfer value
1352         ;; local  --> shared    discard value, discard slot
1353         ;; local  -->  --       discard slot
1354         ;; shared --> local     transfer value
1355         ;; shared --> shared    -- (cf SHARED-INITIALIZE :AFTER STD-CLASS)
1356         ;; shared -->  --       discard value
1357         ;;  --    --> local     add slot
1358         ;;  --    --> shared    --
1359
1360         ;; Collect class slots from inherited wrappers. Needed for
1361         ;; shared -> local transfers of inherited slots.
1362         (let ((inherited (layout-inherits owrapper)))
1363           (loop for i from (1- (length inherited)) downto 0
1364                 for layout = (aref inherited i)
1365                 when (typep layout 'wrapper)
1366                 do (dolist (slot (wrapper-class-slots layout))
1367                      (pushnew slot oclass-slots :key #'car))))
1368
1369         ;; Go through all the old local slots.
1370         (let ((opos 0))
1371           (dolist (name olayout)
1372             (let ((npos (posq name nlayout)))
1373               (if npos
1374                   (setf (clos-slots-ref nslots npos)
1375                         (clos-slots-ref oslots opos))
1376                   (progn
1377                     (push name discarded)
1378                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1379                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1380             (incf opos)))
1381
1382         ;; Go through all the old shared slots.
1383         (dolist (oclass-slot-and-val oclass-slots)
1384           (let ((name (car oclass-slot-and-val))
1385                 (val (cdr oclass-slot-and-val)))
1386             (let ((npos (posq name nlayout)))
1387               (when npos
1388                 (setf (clos-slots-ref nslots npos) val)))))
1389
1390         ;; Go through all the new local slots to compute the added slots.
1391         (dolist (nlocal nlayout)
1392           (unless (or (memq nlocal olayout)
1393                       (assq nlocal oclass-slots))
1394             (push nlocal added)))
1395
1396         (swap-wrappers-and-slots instance copy)
1397
1398         (update-instance-for-redefined-class instance
1399                                              added
1400                                              discarded
1401                                              plist)
1402         nwrapper)))
1403 \f
1404 (defun change-class-internal (instance new-class initargs)
1405   (let* ((old-class (class-of instance))
1406          (copy (allocate-instance new-class))
1407          (new-wrapper (get-wrapper copy))
1408          (old-wrapper (class-wrapper old-class))
1409          (old-layout (wrapper-instance-slots-layout old-wrapper))
1410          (new-layout (wrapper-instance-slots-layout new-wrapper))
1411          (old-slots (get-slots instance))
1412          (new-slots (get-slots copy))
1413          (old-class-slots (wrapper-class-slots old-wrapper)))
1414
1415     ;; "The values of local slots specified by both the class CTO and
1416     ;; CFROM are retained. If such a local slot was unbound, it
1417     ;; remains unbound."
1418     (let ((new-position 0))
1419       (dolist (new-slot new-layout)
1420         (let ((old-position (posq new-slot old-layout)))
1421           (when old-position
1422             (setf (clos-slots-ref new-slots new-position)
1423                   (clos-slots-ref old-slots old-position))))
1424         (incf new-position)))
1425
1426     ;; "The values of slots specified as shared in the class CFROM and
1427     ;; as local in the class CTO are retained."
1428     (dolist (slot-and-val old-class-slots)
1429       (let ((position (posq (car slot-and-val) new-layout)))
1430         (when position
1431           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1432
1433     ;; Make the copy point to the old instance's storage, and make the
1434     ;; old instance point to the new storage.
1435     (swap-wrappers-and-slots instance copy)
1436
1437     (apply #'update-instance-for-different-class copy instance initargs)
1438     instance))
1439
1440 (defmethod change-class ((instance standard-object) (new-class standard-class)
1441                          &rest initargs)
1442   (let ((cpl (class-precedence-list new-class)))
1443     (when (member (find-class 'method) cpl)
1444       (error 'metaobject-initialization-violation
1445              :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1446              :format-arguments (list 'change-class 'method)
1447              :references (list '(:amop :initialization "Method")))))
1448   (change-class-internal instance new-class initargs))
1449
1450 (defmethod change-class ((instance funcallable-standard-object)
1451                          (new-class funcallable-standard-class)
1452                          &rest initargs)
1453   (change-class-internal instance new-class initargs))
1454
1455 (defmethod change-class ((instance standard-object)
1456                          (new-class funcallable-standard-class)
1457                          &rest initargs)
1458   (declare (ignore initargs))
1459   (error "You can't change the class of ~S to ~S~@
1460           because it isn't already an instance with metaclass ~S."
1461          instance new-class 'standard-class))
1462
1463 (defmethod change-class ((instance funcallable-standard-object)
1464                          (new-class standard-class)
1465                          &rest initargs)
1466   (declare (ignore initargs))
1467   (error "You can't change the class of ~S to ~S~@
1468           because it isn't already an instance with metaclass ~S."
1469          instance new-class 'funcallable-standard-class))
1470
1471 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1472   (apply #'change-class instance (find-class new-class-name) initargs))
1473 \f
1474 ;;;; The metaclass BUILT-IN-CLASS
1475 ;;;;
1476 ;;;; This metaclass is something of a weird creature. By this point, all
1477 ;;;; instances of it which will exist have been created, and no instance
1478 ;;;; is ever created by calling MAKE-INSTANCE.
1479 ;;;;
1480 ;;;; But, there are other parts of the protocol we must follow and those
1481 ;;;; definitions appear here.
1482
1483 (macrolet ((def (name args control)
1484                `(defmethod ,name ,args
1485                  (declare (ignore initargs))
1486                  (error 'metaobject-initialization-violation
1487                   :format-control ,(format nil "~@<~A~@:>" control)
1488                   :format-arguments (list ',name)
1489                   :references (list '(:amop :initialization "Class"))))))
1490   (def initialize-instance ((class built-in-class) &rest initargs)
1491     "Cannot ~S an instance of BUILT-IN-CLASS.")
1492   (def reinitialize-instance ((class built-in-class) &rest initargs)
1493     "Cannot ~S an instance of BUILT-IN-CLASS."))
1494
1495 (macrolet ((def (name)
1496                `(defmethod ,name ((class built-in-class)) nil)))
1497   (def class-direct-slots)
1498   (def class-slots)
1499   (def class-direct-default-initargs)
1500   (def class-default-initargs))
1501
1502 (defmethod validate-superclass ((c class) (s built-in-class))
1503   (or (eq s *the-class-t*) (eq s *the-class-stream*)
1504       ;; FIXME: bad things happen if someone tries to mix in both
1505       ;; FILE-STREAM and STRING-STREAM (as they have the same
1506       ;; layout-depthoid).  Is there any way we can provide a useful
1507       ;; error message?  -- CSR, 2005-05-03
1508       (eq s *the-class-file-stream*) (eq s *the-class-string-stream*)))
1509 \f
1510 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1511 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1512 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1513 (macrolet ((def (method)
1514              `(defmethod ,method ((class forward-referenced-class))
1515                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1516                        ',method class))))
1517   (def class-default-initargs)
1518   (def class-precedence-list)
1519   (def class-slots))
1520
1521 (defmethod validate-superclass ((c slot-class)
1522                                 (f forward-referenced-class))
1523   t)
1524 \f
1525 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1526   (pushnew dependent (plist-value metaobject 'dependents)))
1527
1528 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1529   (setf (plist-value metaobject 'dependents)
1530         (delete dependent (plist-value metaobject 'dependents))))
1531
1532 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1533   (dolist (dependent (plist-value metaobject 'dependents))
1534     (funcall function dependent)))
1535