src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd 'class)))
  76     (let ((table (or (gethash name *name->class->slotd-table*)
  77                      (setf (gethash name *name->class->slotd-table*)
  78                            (make-hash-table :test 'eq :size 5)))))
  79       (setf (gethash class table) slotd))
  80     (dolist (type '(reader writer boundp))
  81       (let* ((gf-name (ecase type
  82                               (reader 'slot-value-using-class)
  83                               (writer '(setf slot-value-using-class))
  84                               (boundp 'slot-boundp-using-class)))
  85              (gf (gdefinition gf-name)))
  86         (compute-slot-accessor-info slotd type gf)))
  87     (initialize-internal-slot-gfs name)))
  88
  89 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
  90 ;;;
  91 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
  92 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
  93 ;;; writing/testing effective slot SLOTD.
  94 ;;;
  95 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
  96 ;;; GF.  Store the effective method in the effective slot definition
  97 ;;; object itself; these GFs have special dispatch functions calling
  98 ;;; effective methods directly retrieved from effective slot
  99 ;;; definition objects, as an optimization.
 100 ;;;
 101 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
 102 ;;; or some such.
 103 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
 104                                        type gf)
 105   (let* ((name (slot-value slotd 'name))
 106          (class (slot-value slotd 'class))
 107          (old-slotd (find-slot-definition class name))
 108          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
 109     (multiple-value-bind (function std-p)
 110         (if (eq *boot-state* 'complete)
 111             (get-accessor-method-function gf type class slotd)
 112             (get-optimized-std-accessor-method-function class slotd type))
 113       (setf (slot-accessor-std-p slotd type) std-p)
 114       (setf (slot-accessor-function slotd type) function))
 115     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 116       (push (cons class name) *pv-table-cache-update-info*))))
 117
 118 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 119   :instance)
 120 \f
 121 (defmethod shared-initialize :after ((object documentation-mixin)
 122                                      slot-names
 123                                      &key (documentation nil documentation-p))
 124   (declare (ignore slot-names))
 125   (when documentation-p
 126     (setf (plist-value object 'documentation) documentation)))
 127
 128 ;;; default if DOC-TYPE doesn't match one of the specified types
 129 (defmethod documentation (object doc-type)
 130   (warn "unsupported DOCUMENTATION: type ~S for object ~S"
 131         doc-type
 132         (type-of object))
 133   nil)
 134
 135 ;;; default if DOC-TYPE doesn't match one of the specified types
 136 (defmethod (setf documentation) (new-value object doc-type)
 137   ;; CMU CL made this an error, but since ANSI says that even for supported
 138   ;; doc types an implementation is permitted to discard docs at any time
 139   ;; for any reason, this feels to me more like a warning. -- WHN 19991214
 140   (warn "discarding unsupported DOCUMENTATION of type ~S for object ~S"
 141         doc-type
 142         (type-of object))
 143   new-value)
 144
 145 (defmethod documentation ((object documentation-mixin) doc-type)
 146   (declare (ignore doc-type))
 147   (plist-value object 'documentation))
 148
 149 (defmethod (setf documentation) (new-value
 150                                  (object documentation-mixin)
 151                                  doc-type)
 152   (declare (ignore doc-type))
 153   (setf (plist-value object 'documentation) new-value))
 154
 155 (defmethod documentation ((slotd standard-slot-definition) doc-type)
 156   (declare (ignore doc-type))
 157   (slot-value slotd 'documentation))
 158
 159 (defmethod (setf documentation) (new-value
 160                                  (slotd standard-slot-definition)
 161                                  doc-type)
 162   (declare (ignore doc-type))
 163   (setf (slot-value slotd 'documentation) new-value))
 164 \f
 165 ;;;; various class accessors that are a little more complicated than can be
 166 ;;;; done with automatically generated reader methods
 167
 168 (defmethod class-prototype ((class std-class))
 169   (with-slots (prototype) class
 170     (or prototype (setq prototype (allocate-instance class)))))
 171
 172 (defmethod class-prototype ((class structure-class))
 173   (with-slots (prototype wrapper defstruct-constructor) class
 174     (or prototype
 175         (setq prototype
 176               (if defstruct-constructor
 177                   (allocate-instance class)
 178                   (allocate-standard-instance wrapper))))))
 179
 180 (defmethod class-direct-default-initargs ((class slot-class))
 181   (plist-value class 'direct-default-initargs))
 182
 183 (defmethod class-default-initargs ((class slot-class))
 184   (plist-value class 'default-initargs))
 185
 186 (defmethod class-slot-cells ((class std-class))
 187   (plist-value class 'class-slot-cells))
 188 \f
 189 ;;;; class accessors that are even a little bit more complicated than those
 190 ;;;; above. These have a protocol for updating them, we must implement that
 191 ;;;; protocol.
 192
 193 ;;; Maintaining the direct subclasses backpointers. The update methods are
 194 ;;; here, the values are read by an automatically generated reader method.
 195 (defmethod add-direct-subclass ((class class) (subclass class))
 196   (with-slots (direct-subclasses) class
 197     (pushnew subclass direct-subclasses)
 198     subclass))
 199 (defmethod remove-direct-subclass ((class class) (subclass class))
 200   (with-slots (direct-subclasses) class
 201     (setq direct-subclasses (remove subclass direct-subclasses))
 202     subclass))
 203
 204 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 205 ;;;
 206 ;;; There are four generic functions involved, each has one method for the
 207 ;;; class case and another method for the damned EQL specializers. All of
 208 ;;; these are specified methods and appear in their specified place in the
 209 ;;; class graph.
 210 ;;;
 211 ;;;   ADD-DIRECT-METHOD
 212 ;;;   REMOVE-DIRECT-METHOD
 213 ;;;   SPECIALIZER-DIRECT-METHODS
 214 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 215 ;;;
 216 ;;; In each case, we maintain one value which is a cons. The car is the list
 217 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 218 ;;; computed lazily.
 219 (defmethod add-direct-method ((specializer class) (method method))
 220   (with-slots (direct-methods) specializer
 221     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 222           (cdr direct-methods) ()))
 223   method)
 224 (defmethod remove-direct-method ((specializer class) (method method))
 225   (with-slots (direct-methods) specializer
 226     (setf (car direct-methods) (remove method (car direct-methods))
 227           (cdr direct-methods) ()))
 228   method)
 229
 230 (defmethod specializer-direct-methods ((specializer class))
 231   (with-slots (direct-methods) specializer
 232     (car direct-methods)))
 233
 234 (defmethod specializer-direct-generic-functions ((specializer class))
 235   (with-slots (direct-methods) specializer
 236     (or (cdr direct-methods)
 237         (setf (cdr direct-methods)
 238               (let (collect)
 239                 (dolist (m (car direct-methods))
 240                   ;; the old PCL code used COLLECTING-ONCE which used
 241                   ;; #'EQ to check for newness
 242                   (pushnew (method-generic-function m) collect :test #'eq))
 243                 (nreverse collect))))))
 244 \f
 245 ;;; This hash table is used to store the direct methods and direct generic
 246 ;;; functions of EQL specializers. Each value in the table is the cons.
 247 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 248 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 249
 250 (defmethod specializer-method-table ((specializer eql-specializer))
 251   *eql-specializer-methods*)
 252
 253 (defmethod specializer-method-table ((specializer class-eq-specializer))
 254   *class-eq-specializer-methods*)
 255
 256 (defmethod add-direct-method ((specializer specializer-with-object)
 257                               (method method))
 258   (let* ((object (specializer-object specializer))
 259          (table (specializer-method-table specializer))
 260          (entry (gethash object table)))
 261     (unless entry
 262       (setq entry
 263             (setf (gethash object table)
 264                   (cons nil nil))))
 265     (setf (car entry) (adjoin method (car entry))
 266           (cdr entry) ())
 267     method))
 268
 269 (defmethod remove-direct-method ((specializer specializer-with-object)
 270                                  (method method))
 271   (let* ((object (specializer-object specializer))
 272          (entry (gethash object (specializer-method-table specializer))))
 273     (when entry
 274       (setf (car entry) (remove method (car entry))
 275             (cdr entry) ()))
 276     method))
 277
 278 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 279   (car (gethash (specializer-object specializer)
 280                 (specializer-method-table specializer))))
 281
 282 (defmethod specializer-direct-generic-functions ((specializer
 283                                                   specializer-with-object))
 284   (let* ((object (specializer-object specializer))
 285          (entry (gethash object (specializer-method-table specializer))))
 286     (when entry
 287       (or (cdr entry)
 288           (setf (cdr entry)
 289                 (let (collect)
 290                   (dolist (m (car entry))
 291                     (pushnew (method-generic-function m) collect :test #'eq))
 292                   (nreverse collect)))))))
 293
 294 (defun map-specializers (function)
 295   (map-all-classes (lambda (class)
 296                      (funcall function (class-eq-specializer class))
 297                      (funcall function class)))
 298   (maphash (lambda (object methods)
 299              (declare (ignore methods))
 300              (intern-eql-specializer object))
 301            *eql-specializer-methods*)
 302   (maphash (lambda (object specl)
 303              (declare (ignore object))
 304              (funcall function specl))
 305            *eql-specializer-table*)
 306   nil)
 307
 308 (defun map-all-generic-functions (function)
 309   (let ((all-generic-functions (make-hash-table :test 'eq)))
 310     (map-specializers (lambda (specl)
 311                         (dolist (gf (specializer-direct-generic-functions
 312                                      specl))
 313                           (unless (gethash gf all-generic-functions)
 314                             (setf (gethash gf all-generic-functions) t)
 315                             (funcall function gf))))))
 316   nil)
 317
 318 (defmethod shared-initialize :after ((specl class-eq-specializer)
 319                                      slot-names
 320                                      &key)
 321   (declare (ignore slot-names))
 322   (setf (slot-value specl 'type) `(class-eq ,(specializer-class specl))))
 323
 324 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 325   (declare (ignore slot-names))
 326   (setf (slot-value specl 'type) `(eql ,(specializer-object specl))))
 327 \f
 328 (defun real-load-defclass (name metaclass-name supers slots other)
 329   (let ((res (apply #'ensure-class name :metaclass metaclass-name
 330                     :direct-superclasses supers
 331                     :direct-slots slots
 332                     :definition-source `((defclass ,name)
 333                                          ,*load-pathname*)
 334                     other)))
 335     res))
 336
 337 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 338
 339 (defun ensure-class (name &rest all)
 340   (apply #'ensure-class-using-class (find-class name nil) name all))
 341
 342 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 343   (multiple-value-bind (meta initargs)
 344       (ensure-class-values class args)
 345     (set-class-type-translation (class-prototype meta) name)
 346     (setf class (apply #'make-instance meta :name name initargs)
 347           (find-class name) class)
 348     (set-class-type-translation class name)
 349     class))
 350
 351 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 352   (multiple-value-bind (meta initargs)
 353       (ensure-class-values class args)
 354     (unless (eq (class-of class) meta)
 355       (apply #'change-class class meta initargs))
 356     (apply #'reinitialize-instance class initargs)
 357     (setf (find-class name) class)
 358     (set-class-type-translation class name)
 359     class))
 360
 361 (defmethod class-predicate-name ((class t))
 362   'constantly-nil)
 363
 364 (defun fix-super (s)
 365   (cond ((classp s) s)
 366         ((not (legal-class-name-p s))
 367          (error "~S is not a class or a legal class name." s))
 368         (t
 369          (or (find-class s nil)
 370              (make-instance 'forward-referenced-class
 371                             :name s)))))
 372
 373 (defun ensure-class-values (class args)
 374   (let* ((initargs (copy-list args))
 375          (unsupplied (list 1))
 376          (supplied-meta   (getf initargs :metaclass unsupplied))
 377          (supplied-supers (getf initargs :direct-superclasses unsupplied))
 378          (supplied-slots  (getf initargs :direct-slots unsupplied))
 379          (meta
 380            (cond ((neq supplied-meta unsupplied)
 381                   (find-class supplied-meta))
 382                  ((or (null class)
 383                       (forward-referenced-class-p class))
 384                   *the-class-standard-class*)
 385                  (t
 386                   (class-of class)))))
 387     ;; KLUDGE: It seemed to me initially that there ought to be a way
 388     ;; of collecting all the erroneous problems in one go, rather than
 389     ;; this way of solving the problem of signalling the errors that
 390     ;; we are required to, which stops at the first bogus input.
 391     ;; However, after playing around a little, I couldn't find that
 392     ;; way, so I've left it as is, but if someone does come up with a
 393     ;; better way... -- CSR, 2002-09-08
 394     (do ((direct-slots (getf initargs :direct-slots) (cdr direct-slots)))
 395         ((endp direct-slots) nil)
 396       (destructuring-bind (slot &rest more) direct-slots
 397         (let ((slot-name (getf slot :name)))
 398           (when (some (lambda (s) (eq slot-name (getf s :name))) more)
 399             ;; FIXME: It's quite possible that we ought to define an
 400             ;; SB-INT:PROGRAM-ERROR function to signal these and other
 401             ;; errors throughout the codebase that are required to be
 402             ;; of type PROGRAM-ERROR.
 403             (error 'simple-program-error
 404                    :format-control "~@<There is more than one direct slot ~
 405                                    with name ~S.~:>"
 406                    :format-arguments (list slot-name)))
 407           (do ((stuff slot (cddr stuff)))
 408               ((endp stuff) nil)
 409             (destructuring-bind (option value &rest more) stuff
 410               (cond
 411                 ((and (member option '(:allocation :type
 412                                        :initform :documentation))
 413                       (not (eq unsupplied
 414                                (getf more option unsupplied))))
 415                  (error 'simple-program-error
 416                         :format-control "~@<Duplicate slot option ~S for ~
 417                                         slot named ~S.~:>"
 418                         :format-arguments (list option slot-name)))
 419                 ((and (eq option :readers)
 420                       (notevery #'symbolp value))
 421                  (error 'simple-program-error
 422                         :format-control "~@<Slot reader names for slot ~
 423                                         named ~S must be symbols.~:>"
 424                         :format-arguments (list slot-name)))
 425                 ((and (eq option :initargs)
 426                       (notevery #'symbolp value))
 427                  (error 'simple-program-error
 428                         :format-control "~@<Slot initarg names for slot ~
 429                                         named ~S must be symbols.~:>"
 430                         :format-arguments (list slot-name)))))))))
 431     (loop for (initarg . more) on (getf initargs :direct-default-initargs)
 432           for name = (car initarg)
 433           when (some (lambda (a) (eq (car a) name)) more)
 434           do (error 'simple-program-error
 435                     :format-control "~@<Duplicate initialization argument ~
 436                                     name ~S in :DEFAULT-INITARGS.~:>"
 437                     :format-arguments (list name class)))
 438     (let ((metaclass 0)
 439           (default-initargs 0))
 440       (do ((args initargs (cddr args)))
 441           ((endp args) nil)
 442         (case (car args)
 443           (:metaclass
 444            (when (> (incf metaclass) 1)
 445              (error 'simple-program-error
 446                     :format-control "~@<More than one :METACLASS ~
 447                                     option specified.~:>")))
 448           (:direct-default-initargs
 449            (when (> (incf default-initargs) 1)
 450              (error 'simple-program-error
 451                     :format-control "~@<More than one :DEFAULT-INITARGS ~
 452                                     option specified.~:>"))))))
 453     (remf initargs :metaclass)
 454     (loop (unless (remf initargs :direct-superclasses) (return)))
 455     (loop (unless (remf initargs :direct-slots) (return)))
 456     (values
 457      meta
 458      (nconc
 459       (when (neq supplied-supers unsupplied)
 460         (list :direct-superclasses (mapcar #'fix-super supplied-supers)))
 461       (when (neq supplied-slots unsupplied)
 462         (list :direct-slots supplied-slots))
 463       initargs))))
 464 \f
 465 (defmethod shared-initialize :after
 466            ((class std-class)
 467             slot-names
 468             &key (direct-superclasses nil direct-superclasses-p)
 469                  (direct-slots nil direct-slots-p)
 470                  (direct-default-initargs nil direct-default-initargs-p)
 471                  (predicate-name nil predicate-name-p))
 472   (declare (ignore slot-names))
 473   (cond (direct-superclasses-p
 474          (setq direct-superclasses
 475                (or direct-superclasses
 476                    (list (if (funcallable-standard-class-p class)
 477                              *the-class-funcallable-standard-object*
 478                              *the-class-standard-object*))))
 479          (dolist (superclass direct-superclasses)
 480            (unless (validate-superclass class superclass)
 481              (error "The class ~S was specified as a~%
 482                      super-class of the class ~S;~%~
 483                      but the meta-classes ~S and~%~S are incompatible.~@
 484                      Define a method for ~S to avoid this error."
 485                      superclass class (class-of superclass) (class-of class)
 486                      'validate-superclass)))
 487          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 488         (t
 489          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 490   (setq direct-slots
 491         (if direct-slots-p
 492             (setf (slot-value class 'direct-slots)
 493                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 494                           direct-slots))
 495             (slot-value class 'direct-slots)))
 496   (if direct-default-initargs-p
 497       (setf (plist-value class 'direct-default-initargs)
 498             direct-default-initargs)
 499       (setq direct-default-initargs
 500             (plist-value class 'direct-default-initargs)))
 501   (setf (plist-value class 'class-slot-cells)
 502         ;; The below initializes shared slots from direct initforms,
 503         ;; but one might inherit initforms from superclasses
 504         ;; (cf. UPDATE-SHARED-SLOT-VALUES).
 505         (let (collect)
 506           (dolist (dslotd direct-slots)
 507             (when (eq :class (slot-definition-allocation dslotd))
 508               (let ((initfunction (slot-definition-initfunction dslotd)))
 509                 (push (cons (slot-definition-name dslotd)
 510                                (if initfunction
 511                                    (funcall initfunction)
 512                                    +slot-unbound+))
 513                       collect))))
 514           (nreverse collect)))
 515   (setq predicate-name (if predicate-name-p
 516                            (setf (slot-value class 'predicate-name)
 517                                  (car predicate-name))
 518                            (or (slot-value class 'predicate-name)
 519                                (setf (slot-value class 'predicate-name)
 520                                      (make-class-predicate-name (class-name
 521                                                                  class))))))
 522   (add-direct-subclasses class direct-superclasses)
 523   (make-class-predicate class predicate-name)
 524   (update-class class nil)
 525   (do* ((slots (slot-value class 'slots) (cdr slots))
 526         (dupes nil))
 527        ((null slots) (when dupes
 528                        (style-warn
 529                         ;; FIXME: the indentation request ("~4I")
 530                         ;; below appears not to do anything.  Finding
 531                         ;; out why would be nice.  -- CSR, 2003-04-24
 532                         "~@<slot names with the same SYMBOL-NAME but ~
 533                          different SYMBOL-PACKAGE (possible package problem) ~
 534                          for class ~S:~@:_~4I~<~@{~S~^~:@_~}~:>~@:>"
 535                         class
 536                         dupes)))
 537     (let* ((slot (car slots))
 538            (oslots (remove (slot-definition-name slot) (cdr slots)
 539                            :test-not #'string= :key #'slot-definition-name)))
 540       (when oslots
 541         (pushnew (cons (slot-definition-name slot)
 542                        (mapcar #'slot-definition-name oslots))
 543                  dupes
 544                  :test #'string= :key #'car))))
 545   (add-slot-accessors class direct-slots)
 546   (make-preliminary-layout class))
 547
 548 (defmethod shared-initialize :after ((class forward-referenced-class)
 549                                      slot-names &key &allow-other-keys)
 550   (declare (ignore slot-names))
 551   (make-preliminary-layout class))
 552
 553 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 554
 555 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 556 ;;; make it known to the type system.
 557 (defun make-preliminary-layout (class)
 558   (flet ((compute-preliminary-cpl (root)
 559            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 560              (compute-class-precedence-list root))))
 561     (unless (class-finalized-p class)
 562       (let ((name (class-name class)))
 563         (setf (find-class name) class)
 564         ;; KLUDGE: This is fairly horrible.  We need to make a
 565         ;; full-fledged CLASSOID here, not just tell the compiler that
 566         ;; some class is forthcoming, because there are legitimate
 567         ;; questions one can ask of the type system, implemented in
 568         ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 569         (when (and (eq *boot-state* 'complete)
 570                    (null (find-classoid name nil)))
 571           (setf (find-classoid name)
 572                 (make-standard-classoid :name name)))
 573         (set-class-type-translation class name)
 574         (let ((layout (make-wrapper 0 class))
 575               (classoid (find-classoid name)))
 576           (setf (layout-classoid layout) classoid)
 577           (setf (classoid-pcl-class classoid) class)
 578           (setf (slot-value class 'wrapper) layout)
 579           (let ((cpl (compute-preliminary-cpl class)))
 580             (setf (layout-inherits layout)
 581                   (order-layout-inherits
 582                    (map 'simple-vector #'class-wrapper
 583                         (reverse (rest cpl))))))
 584           (register-layout layout :invalidate t)
 585           (setf (classoid-layout classoid) layout)
 586           (mapc #'make-preliminary-layout (class-direct-subclasses class)))))))
 587
 588
 589 (defmethod shared-initialize :before ((class class) slot-names &key name)
 590   (declare (ignore slot-names name))
 591   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 592   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 593   (setf (slot-value class 'type) `(class ,class))
 594   (setf (slot-value class 'class-eq-specializer)
 595         (make-instance 'class-eq-specializer :class class)))
 596
 597 (defmethod reinitialize-instance :before ((class slot-class) &key)
 598   (remove-direct-subclasses class (class-direct-superclasses class))
 599   (remove-slot-accessors    class (class-direct-slots class)))
 600
 601 (defmethod reinitialize-instance :after ((class slot-class)
 602                                          &rest initargs
 603                                          &key)
 604   (map-dependents class
 605                   (lambda (dependent)
 606                     (apply #'update-dependent class dependent initargs))))
 607
 608 (defmethod shared-initialize :after ((class condition-class) slot-names
 609                                      &key direct-slots direct-superclasses)
 610   (declare (ignore slot-names))
 611   (let ((classoid (find-classoid (class-name class))))
 612     (with-slots (wrapper class-precedence-list prototype predicate-name
 613                          (direct-supers direct-superclasses))
 614         class
 615       (setf (slot-value class 'direct-slots)
 616             (mapcar (lambda (pl) (make-direct-slotd class pl))
 617                     direct-slots))
 618       (setf (slot-value class 'finalized-p) t)
 619       (setf (classoid-pcl-class classoid) class)
 620       (setq direct-supers direct-superclasses)
 621       (setq wrapper (classoid-layout classoid))
 622       (setq class-precedence-list (compute-class-precedence-list class))
 623       (setq prototype (make-condition (class-name class)))
 624       (add-direct-subclasses class direct-superclasses)
 625       (setq predicate-name (make-class-predicate-name (class-name class)))
 626       (make-class-predicate class predicate-name)
 627       (setf (slot-value class 'slots) (compute-slots class))))
 628   ;; Comment from Gerd's PCL, 2003-05-15:
 629   ;;
 630   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 631   ;; override condition accessors with generic functions.  We do this
 632   ;; differently.
 633   (update-pv-table-cache-info class))
 634
 635 (defmethod direct-slot-definition-class ((class condition-class)
 636                                          &rest initargs)
 637   (declare (ignore initargs))
 638   (find-class 'condition-direct-slot-definition))
 639
 640 (defmethod effective-slot-definition-class ((class condition-class)
 641                                             &rest initargs)
 642   (declare (ignore initargs))
 643   (find-class 'condition-effective-slot-definition))
 644
 645 (defmethod finalize-inheritance ((class condition-class))
 646   (aver (slot-value class 'finalized-p))
 647   nil)
 648
 649 (defmethod compute-effective-slot-definition
 650     ((class condition-class) slot-name dslotds)
 651   (let ((slotd (call-next-method)))
 652     (setf (slot-definition-reader-function slotd)
 653           (lambda (x)
 654             (handler-case (condition-reader-function x slot-name)
 655               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 656               ;; is unbound; maybe it should be a CELL-ERROR of some
 657               ;; sort?
 658               (error () (slot-unbound class x slot-name)))))
 659     (setf (slot-definition-writer-function slotd)
 660           (lambda (v x)
 661             (condition-writer-function x v slot-name)))
 662     (setf (slot-definition-boundp-function slotd)
 663           (lambda (x)
 664             (multiple-value-bind (v c)
 665                 (ignore-errors (condition-reader-function x slot-name))
 666               (declare (ignore v))
 667               (null c))))
 668     slotd))
 669
 670 (defmethod compute-slots ((class condition-class))
 671   (mapcan (lambda (superclass)
 672             (mapcar (lambda (dslotd)
 673                       (compute-effective-slot-definition
 674                        class (slot-definition-name dslotd) (list dslotd)))
 675                     (class-direct-slots superclass)))
 676           (reverse (slot-value class 'class-precedence-list))))
 677
 678 (defmethod compute-slots :around ((class condition-class))
 679   (let ((eslotds (call-next-method)))
 680     (mapc #'initialize-internal-slot-functions eslotds)
 681     eslotds))
 682
 683 (defmethod shared-initialize :after
 684     ((slotd structure-slot-definition) slot-names &key
 685      (allocation :instance) allocation-class)
 686   (declare (ignore slot-names allocation-class))
 687   (unless (eq allocation :instance)
 688     (error "Structure slots must have :INSTANCE allocation.")))
 689
 690 (defun make-structure-class-defstruct-form (name direct-slots include)
 691   (let* ((conc-name (intern (format nil "~S structure class " name)))
 692          (constructor (intern (format nil "~Aconstructor" conc-name)))
 693          (defstruct `(defstruct (,name
 694                                  ,@(when include
 695                                          `((:include ,(class-name include))))
 696                                  (:predicate nil)
 697                                  (:conc-name ,conc-name)
 698                                  (:constructor ,constructor ())
 699                                  (:copier nil))
 700                       ,@(mapcar (lambda (slot)
 701                                   `(,(slot-definition-name slot)
 702                                     +slot-unbound+))
 703                                 direct-slots)))
 704          (reader-names (mapcar (lambda (slotd)
 705                                  (list 'slot-accessor name
 706                                        (slot-definition-name slotd)
 707                                        'reader))
 708                                direct-slots))
 709          (writer-names (mapcar (lambda (slotd)
 710                                  (list 'slot-accessor name
 711                                        (slot-definition-name slotd)
 712                                        'writer))
 713                                direct-slots))
 714          (readers-init
 715            (mapcar (lambda (slotd reader-name)
 716                      (let ((accessor
 717                              (slot-definition-defstruct-accessor-symbol
 718                               slotd)))
 719                        `(defun ,reader-name (obj)
 720                          (declare (type ,name obj))
 721                          (,accessor obj))))
 722                    direct-slots reader-names))
 723          (writers-init
 724            (mapcar (lambda (slotd writer-name)
 725                      (let ((accessor
 726                              (slot-definition-defstruct-accessor-symbol
 727                               slotd)))
 728                        `(defun ,writer-name (nv obj)
 729                          (declare (type ,name obj))
 730                          (setf (,accessor obj) nv))))
 731                    direct-slots writer-names))
 732          (defstruct-form
 733              `(progn
 734                ,defstruct
 735                ,@readers-init ,@writers-init
 736                (cons nil nil))))
 737     (values defstruct-form constructor reader-names writer-names)))
 738
 739 (defun make-defstruct-allocation-function (class)
 740   (let ((dd (get-structure-dd (class-name class))))
 741     (lambda ()
 742       (let ((instance (%make-instance (dd-length dd)))
 743             (raw-index (dd-raw-index dd)))
 744         (setf (%instance-layout instance)
 745               (sb-kernel::compiler-layout-or-lose (dd-name dd)))
 746         (when raw-index
 747           (setf (%instance-ref instance raw-index)
 748                 (make-array (dd-raw-length dd)
 749                             :element-type '(unsigned-byte 32))))
 750         instance))))
 751
 752 (defmethod shared-initialize :after
 753       ((class structure-class)
 754        slot-names
 755        &key (direct-superclasses nil direct-superclasses-p)
 756             (direct-slots nil direct-slots-p)
 757             direct-default-initargs
 758             (predicate-name nil predicate-name-p))
 759   (declare (ignore slot-names direct-default-initargs))
 760   (if direct-superclasses-p
 761       (setf (slot-value class 'direct-superclasses)
 762             (or direct-superclasses
 763                 (setq direct-superclasses
 764                       (and (not (eq (class-name class) 'structure-object))
 765                            (list *the-class-structure-object*)))))
 766       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 767   (let* ((name (class-name class))
 768          (from-defclass-p (slot-value class 'from-defclass-p))
 769          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 770     (if direct-slots-p
 771         (setf (slot-value class 'direct-slots)
 772               (setq direct-slots
 773                     (mapcar (lambda (pl)
 774                               (when defstruct-p
 775                                 (let* ((slot-name (getf pl :name))
 776                                        (acc-name
 777                                         (format nil
 778                                                 "~S structure class ~A"
 779                                                 name slot-name))
 780                                        (accessor (intern acc-name)))
 781                                   (setq pl (list* :defstruct-accessor-symbol
 782                                                   accessor pl))))
 783                               (make-direct-slotd class pl))
 784                             direct-slots)))
 785         (setq direct-slots (slot-value class 'direct-slots)))
 786     (if defstruct-p
 787         (let ((include (car (slot-value class 'direct-superclasses))))
 788           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 789               (make-structure-class-defstruct-form name direct-slots include)
 790             (unless (structure-type-p name) (eval defstruct-form))
 791             (mapc (lambda (dslotd reader-name writer-name)
 792                     (let* ((reader (gdefinition reader-name))
 793                            (writer (when (gboundp writer-name)
 794                                      (gdefinition writer-name))))
 795                       (setf (slot-value dslotd 'internal-reader-function)
 796                             reader)
 797                       (setf (slot-value dslotd 'internal-writer-function)
 798                             writer)))
 799                   direct-slots reader-names writer-names)
 800             (setf (slot-value class 'defstruct-form) defstruct-form)
 801             (setf (slot-value class 'defstruct-constructor) constructor)))
 802         (setf (slot-value class 'defstruct-constructor)
 803               (make-defstruct-allocation-function class)))
 804     (add-direct-subclasses class direct-superclasses)
 805     (setf (slot-value class 'class-precedence-list)
 806             (compute-class-precedence-list class))
 807     (setf (slot-value class 'slots) (compute-slots class))
 808     (let ((lclass (find-classoid (class-name class))))
 809       (setf (classoid-pcl-class lclass) class)
 810       (setf (slot-value class 'wrapper) (classoid-layout lclass)))
 811     (setf (slot-value class 'finalized-p) t)
 812     (update-pv-table-cache-info class)
 813     (setq predicate-name (if predicate-name-p
 814                            (setf (slot-value class 'predicate-name)
 815                                    (car predicate-name))
 816                            (or (slot-value class 'predicate-name)
 817                                (setf (slot-value class 'predicate-name)
 818                                        (make-class-predicate-name
 819                                         (class-name class))))))
 820     (make-class-predicate class predicate-name)
 821     (add-slot-accessors class direct-slots)))
 822
 823 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 824   (declare (ignore initargs))
 825   (find-class 'structure-direct-slot-definition))
 826
 827 (defmethod finalize-inheritance ((class structure-class))
 828   nil) ; always finalized
 829 \f
 830 (defun add-slot-accessors (class dslotds)
 831   (fix-slot-accessors class dslotds 'add))
 832
 833 (defun remove-slot-accessors (class dslotds)
 834   (fix-slot-accessors class dslotds 'remove))
 835
 836 (defun fix-slot-accessors (class dslotds add/remove)
 837   (flet ((fix (gfspec name r/w)
 838            (let ((gf (ensure-generic-function gfspec)))
 839              (case r/w
 840                (r (if (eq add/remove 'add)
 841                       (add-reader-method class gf name)
 842                       (remove-reader-method class gf)))
 843                (w (if (eq add/remove 'add)
 844                       (add-writer-method class gf name)
 845                       (remove-writer-method class gf)))))))
 846     (dolist (dslotd dslotds)
 847       (let ((slot-name (slot-definition-name dslotd)))
 848         (dolist (r (slot-definition-readers dslotd)) (fix r slot-name 'r))
 849         (dolist (w (slot-definition-writers dslotd)) (fix w slot-name 'w))))))
 850 \f
 851 (defun add-direct-subclasses (class supers)
 852   (dolist (super supers)
 853     (unless (memq class (class-direct-subclasses class))
 854       (add-direct-subclass super class))))
 855
 856 (defun remove-direct-subclasses (class supers)
 857   (let ((old (class-direct-superclasses class)))
 858     (dolist (o (set-difference old supers))
 859       (remove-direct-subclass o class))))
 860 \f
 861 (defmethod finalize-inheritance ((class std-class))
 862   (update-class class t))
 863
 864 (defmethod finalize-inheritance ((class forward-referenced-class))
 865   ;; FIXME: should we not be thinking a bit about what kinds of error
 866   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 867   ;; possibly a forward-referenced-class-error, though that's
 868   ;; difficult given e.g. class precedence list calculations...
 869   (error
 870    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 871        ~2I~_~S~:>"
 872    class))
 873
 874 \f
 875 (defun class-has-a-forward-referenced-superclass-p (class)
 876   (or (forward-referenced-class-p class)
 877       (some #'class-has-a-forward-referenced-superclass-p
 878             (class-direct-superclasses class))))
 879
 880 ;;; This is called by :after shared-initialize whenever a class is initialized
 881 ;;; or reinitialized. The class may or may not be finalized.
 882 (defun update-class (class finalizep)
 883   ;; Comment from Gerd Moellmann:
 884   ;;
 885   ;; Note that we can't simply delay the finalization when CLASS has
 886   ;; no forward referenced superclasses because that causes bootstrap
 887   ;; problems.
 888   (when (and (not finalizep)
 889              (not (class-finalized-p class))
 890              (not (class-has-a-forward-referenced-superclass-p class)))
 891     (finalize-inheritance class)
 892     (return-from update-class))
 893   (when (or finalizep (class-finalized-p class)
 894             (not (class-has-a-forward-referenced-superclass-p class)))
 895     (setf (find-class (class-name class)) class)
 896     (update-cpl class (compute-class-precedence-list class))
 897     ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 898     ;; class.  The hoops above are to ensure that FINALIZE-INHERITANCE
 899     ;; is called at finalization, so that MOP programmers can hook
 900     ;; into the system as described in "Class Finalization Protocol"
 901     ;; (section 5.5.2 of AMOP).
 902     (update-slots class (compute-slots class))
 903     (update-gfs-of-class class)
 904     (update-inits class (compute-default-initargs class))
 905     (update-shared-slot-values class)
 906     (update-ctors 'finalize-inheritance :class class))
 907   (unless finalizep
 908     (dolist (sub (class-direct-subclasses class)) (update-class sub nil))))
 909
 910 (defun update-shared-slot-values (class)
 911   (dolist (slot (class-slots class))
 912     (when (eq (slot-definition-allocation slot) :class)
 913       (let ((cell (assq (slot-definition-name slot) (class-slot-cells class))))
 914         (when cell
 915           (let ((initfn (slot-definition-initfunction slot)))
 916             (when initfn
 917               (setf (cdr cell) (funcall initfn)))))))))
 918
 919 (defun update-cpl (class cpl)
 920   (if (class-finalized-p class)
 921       (unless (and (equal (class-precedence-list class) cpl)
 922                    (dolist (c cpl t)
 923                      (when (position :class (class-direct-slots c)
 924                                      :key #'slot-definition-allocation)
 925                        (return nil))))
 926         ;; comment from the old CMU CL sources:
 927         ;;   Need to have the cpl setup before update-lisp-class-layout
 928         ;;   is called on CMU CL.
 929         (setf (slot-value class 'class-precedence-list) cpl)
 930         (force-cache-flushes class))
 931       (setf (slot-value class 'class-precedence-list) cpl))
 932   (update-class-can-precede-p cpl))
 933
 934 (defun update-class-can-precede-p (cpl)
 935   (when cpl
 936     (let ((first (car cpl)))
 937       (dolist (c (cdr cpl))
 938         (pushnew c (slot-value first 'can-precede-list))))
 939     (update-class-can-precede-p (cdr cpl))))
 940
 941 (defun class-can-precede-p (class1 class2)
 942   (member class2 (class-can-precede-list class1)))
 943
 944 (defun update-slots (class eslotds)
 945   (let ((instance-slots ())
 946         (class-slots    ()))
 947     (dolist (eslotd eslotds)
 948       (let ((alloc (slot-definition-allocation eslotd)))
 949         (case alloc
 950           (:instance (push eslotd instance-slots))
 951           (:class (push eslotd class-slots)))))
 952
 953     ;; If there is a change in the shape of the instances then the
 954     ;; old class is now obsolete.
 955     (let* ((nlayout (mapcar #'slot-definition-name
 956                             (sort instance-slots #'<
 957                                   :key #'slot-definition-location)))
 958            (nslots (length nlayout))
 959            (nwrapper-class-slots (compute-class-slots class-slots))
 960            (owrapper (when (class-finalized-p class)
 961                        (class-wrapper class)))
 962            (olayout (when owrapper
 963                       (wrapper-instance-slots-layout owrapper)))
 964            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 965            (nwrapper
 966             (cond ((null owrapper)
 967                    (make-wrapper nslots class))
 968                   ((and (equal nlayout olayout)
 969                         (not
 970                          (loop for o in owrapper-class-slots
 971                                for n in nwrapper-class-slots
 972                                do (unless (eq (car o) (car n)) (return t)))))
 973                    owrapper)
 974                   (t
 975                    ;; This will initialize the new wrapper to have the
 976                    ;; same state as the old wrapper. We will then have
 977                    ;; to change that. This may seem like wasted work
 978                    ;; (and it is), but the spec requires that we call
 979                    ;; MAKE-INSTANCES-OBSOLETE.
 980                    (make-instances-obsolete class)
 981                    (class-wrapper class)))))
 982
 983       (with-slots (wrapper slots) class
 984         (update-lisp-class-layout class nwrapper)
 985         (setf slots eslotds
 986               (wrapper-instance-slots-layout nwrapper) nlayout
 987               (wrapper-class-slots nwrapper) nwrapper-class-slots
 988               (wrapper-no-of-instance-slots nwrapper) nslots
 989               wrapper nwrapper))
 990       (setf (slot-value class 'finalized-p) t)
 991       (unless (eq owrapper nwrapper)
 992         (update-pv-table-cache-info class)
 993         (maybe-update-standard-class-locations class)))))
 994
 995 (defun compute-class-slots (eslotds)
 996   (let (collect)
 997     (dolist (eslotd eslotds)
 998       (push (assoc (slot-definition-name eslotd)
 999                    (class-slot-cells (slot-definition-class eslotd)))
1000             collect))
1001     (nreverse collect)))
1002
1003 (defun update-gfs-of-class (class)
1004   (when (and (class-finalized-p class)
1005              (let ((cpl (class-precedence-list class)))
1006                (or (member *the-class-slot-class* cpl)
1007                    (member *the-class-standard-effective-slot-definition*
1008                            cpl))))
1009     (let ((gf-table (make-hash-table :test 'eq)))
1010       (labels ((collect-gfs (class)
1011                  (dolist (gf (specializer-direct-generic-functions class))
1012                    (setf (gethash gf gf-table) t))
1013                  (mapc #'collect-gfs (class-direct-superclasses class))))
1014         (collect-gfs class)
1015         (maphash (lambda (gf ignore)
1016                    (declare (ignore ignore))
1017                    (update-gf-dfun class gf))
1018                  gf-table)))))
1019
1020 (defun update-inits (class inits)
1021   (setf (plist-value class 'default-initargs) inits))
1022 \f
1023 (defmethod compute-default-initargs ((class slot-class))
1024   (let ((initargs (loop for c in (class-precedence-list class)
1025                         append (class-direct-default-initargs c))))
1026     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
1027 \f
1028 ;;;; protocols for constructing direct and effective slot definitions
1029
1030 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
1031   (declare (ignore initargs))
1032   (find-class 'standard-direct-slot-definition))
1033
1034 (defun make-direct-slotd (class initargs)
1035   (let ((initargs (list* :class class initargs)))
1036     (apply #'make-instance
1037            (apply #'direct-slot-definition-class class initargs)
1038            initargs)))
1039
1040 (defmethod compute-slots ((class std-class))
1041   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
1042   ;; for each different slot name we find in our superclasses. Each
1043   ;; call receives the class and a list of the dslotds with that name.
1044   ;; The list is in most-specific-first order.
1045   (let ((name-dslotds-alist ()))
1046     (dolist (c (class-precedence-list class))
1047       (dolist (slot (class-direct-slots c))
1048         (let* ((name (slot-definition-name slot))
1049                (entry (assq name name-dslotds-alist)))
1050           (if entry
1051               (push slot (cdr entry))
1052               (push (list name slot) name-dslotds-alist)))))
1053     (mapcar (lambda (direct)
1054               (compute-effective-slot-definition class
1055                                                  (car direct)
1056                                                  (nreverse (cdr direct))))
1057             name-dslotds-alist)))
1058
1059 (defmethod compute-slots ((class standard-class))
1060   (call-next-method))
1061
1062 (defmethod compute-slots :around ((class standard-class))
1063   (let ((eslotds (call-next-method))
1064         (location -1))
1065     (dolist (eslotd eslotds eslotds)
1066       (setf (slot-definition-location eslotd)
1067             (ecase (slot-definition-allocation eslotd)
1068               (:instance
1069                (incf location))
1070               (:class
1071                (let* ((name (slot-definition-name eslotd))
1072                       (from-class (slot-definition-allocation-class eslotd))
1073                       (cell (assq name (class-slot-cells from-class))))
1074                  (aver (consp cell))
1075                  cell))))
1076       (initialize-internal-slot-functions eslotd))))
1077
1078 (defmethod compute-slots ((class funcallable-standard-class))
1079   (call-next-method))
1080
1081 (defmethod compute-slots :around ((class funcallable-standard-class))
1082   (labels ((instance-slot-names (slotds)
1083              (let (collect)
1084                (dolist (slotd slotds (nreverse collect))
1085                  (when (eq (slot-definition-allocation slotd) :instance)
1086                    (push (slot-definition-name slotd) collect)))))
1087            ;; This sorts slots so that slots of classes later in the CPL
1088            ;; come before slots of other classes.  This is crucial for
1089            ;; funcallable instances because it ensures that the slots of
1090            ;; FUNCALLABLE-STANDARD-OBJECT, which includes the slots of
1091            ;; KERNEL:FUNCALLABLE-INSTANCE, come first, which in turn
1092            ;; makes it possible to treat FUNCALLABLE-STANDARD-OBJECT as
1093            ;; a funcallable instance.
1094            (compute-layout (eslotds)
1095              (let ((first ())
1096                    (names (instance-slot-names eslotds)))
1097                (dolist (class
1098                         (reverse (class-precedence-list class))
1099                         (nreverse (nconc names first)))
1100                  (dolist (ss (class-slots class))
1101                    (let ((name (slot-definition-name ss)))
1102                      (when (member name names)
1103                        (push name first)
1104                        (setq names (delete name names)))))))))
1105     (let ((all-slotds (call-next-method))
1106           (instance-slots ())
1107           (class-slots ()))
1108       (dolist (slotd all-slotds)
1109         (ecase (slot-definition-allocation slotd)
1110           (:instance (push slotd instance-slots))
1111           (:class (push slotd class-slots))))
1112       (let ((layout (compute-layout instance-slots)))
1113         (dolist (slotd instance-slots)
1114           (setf (slot-definition-location slotd)
1115                 (position (slot-definition-name slotd) layout))
1116           (initialize-internal-slot-functions slotd)))
1117       (dolist (slotd class-slots)
1118         (let ((name (slot-definition-name slotd))
1119               (from-class (slot-definition-allocation-class slotd)))
1120           (setf (slot-definition-location slotd)
1121                 (assoc name (class-slot-cells from-class)))
1122           (aver (consp (slot-definition-location slotd)))
1123           (initialize-internal-slot-functions slotd)))
1124       all-slotds)))
1125
1126 (defmethod compute-slots ((class structure-class))
1127   (mapcan (lambda (superclass)
1128             (mapcar (lambda (dslotd)
1129                       (compute-effective-slot-definition
1130                        class
1131                        (slot-definition-name dslotd)
1132                        (list dslotd)))
1133                     (class-direct-slots superclass)))
1134           (reverse (slot-value class 'class-precedence-list))))
1135
1136 (defmethod compute-slots :around ((class structure-class))
1137   (let ((eslotds (call-next-method)))
1138     (mapc #'initialize-internal-slot-functions eslotds)
1139     eslotds))
1140
1141 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1142   (declare (ignore name))
1143   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1144          (class (apply #'effective-slot-definition-class class initargs)))
1145     (apply #'make-instance class initargs)))
1146
1147 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1148   (declare (ignore initargs))
1149   (find-class 'standard-effective-slot-definition))
1150
1151 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1152   (declare (ignore initargs))
1153   (find-class 'structure-effective-slot-definition))
1154
1155 (defmethod compute-effective-slot-definition-initargs
1156     ((class slot-class) direct-slotds)
1157   (let* ((name nil)
1158          (initfunction nil)
1159          (initform nil)
1160          (initargs nil)
1161          (allocation nil)
1162          (allocation-class nil)
1163          (type t)
1164          (namep  nil)
1165          (initp  nil)
1166          (allocp nil))
1167
1168     (dolist (slotd direct-slotds)
1169       (when slotd
1170         (unless namep
1171           (setq name (slot-definition-name slotd)
1172                 namep t))
1173         (unless initp
1174           (when (slot-definition-initfunction slotd)
1175             (setq initform (slot-definition-initform slotd)
1176                   initfunction (slot-definition-initfunction slotd)
1177                   initp t)))
1178         (unless allocp
1179           (setq allocation (slot-definition-allocation slotd)
1180                 allocation-class (slot-definition-class slotd)
1181                 allocp t))
1182         (setq initargs (append (slot-definition-initargs slotd) initargs))
1183         (let ((slotd-type (slot-definition-type slotd)))
1184           (setq type (cond ((eq type t) slotd-type)
1185                            ((*subtypep type slotd-type) type)
1186                            (t `(and ,type ,slotd-type)))))))
1187     (list :name name
1188           :initform initform
1189           :initfunction initfunction
1190           :initargs initargs
1191           :allocation allocation
1192           :allocation-class allocation-class
1193           :type type
1194           :class class)))
1195
1196 (defmethod compute-effective-slot-definition-initargs :around
1197     ((class structure-class) direct-slotds)
1198   (let ((slotd (car direct-slotds)))
1199     (list* :defstruct-accessor-symbol
1200            (slot-definition-defstruct-accessor-symbol slotd)
1201            :internal-reader-function
1202            (slot-definition-internal-reader-function slotd)
1203            :internal-writer-function
1204            (slot-definition-internal-writer-function slotd)
1205            (call-next-method))))
1206 \f
1207 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1208 ;;;       to make the method object. They have to use make-a-method which
1209 ;;;       is a specially bootstrapped mechanism for making standard methods.
1210 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1211   (declare (ignore direct-slot initargs))
1212   (find-class 'standard-reader-method))
1213
1214 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
1215   (add-method generic-function
1216               (make-a-method 'standard-reader-method
1217                              ()
1218                              (list (or (class-name class) 'object))
1219                              (list class)
1220                              (make-reader-method-function class slot-name)
1221                              "automatically generated reader method"
1222                              slot-name)))
1223
1224 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1225   (declare (ignore direct-slot initargs))
1226   (find-class 'standard-writer-method))
1227
1228 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
1229   (add-method generic-function
1230               (make-a-method 'standard-writer-method
1231                              ()
1232                              (list 'new-value (or (class-name class) 'object))
1233                              (list *the-class-t* class)
1234                              (make-writer-method-function class slot-name)
1235                              "automatically generated writer method"
1236                              slot-name)))
1237
1238 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
1239   (add-method generic-function
1240               (make-a-method 'standard-boundp-method
1241                              ()
1242                              (list (or (class-name class) 'object))
1243                              (list class)
1244                              (make-boundp-method-function class slot-name)
1245                              "automatically generated boundp method"
1246                              slot-name)))
1247
1248 (defmethod remove-reader-method ((class slot-class) generic-function)
1249   (let ((method (get-method generic-function () (list class) nil)))
1250     (when method (remove-method generic-function method))))
1251
1252 (defmethod remove-writer-method ((class slot-class) generic-function)
1253   (let ((method
1254           (get-method generic-function () (list *the-class-t* class) nil)))
1255     (when method (remove-method generic-function method))))
1256
1257 (defmethod remove-boundp-method ((class slot-class) generic-function)
1258   (let ((method (get-method generic-function () (list class) nil)))
1259     (when method (remove-method generic-function method))))
1260 \f
1261 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITE-METHOD function are NOT
1262 ;;; part of the standard protocol. They are however useful, PCL makes
1263 ;;; use of them internally and documents them for PCL users.
1264 ;;;
1265 ;;; *** This needs work to make type testing by the writer functions which
1266 ;;; *** do type testing faster. The idea would be to have one constructor
1267 ;;; *** for each possible type test.
1268 ;;;
1269 ;;; *** There is a subtle bug here which is going to have to be fixed.
1270 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1271 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1272 ;;; *** defined for this metaclass a chance to run.
1273
1274 (defmethod make-reader-method-function ((class slot-class) slot-name)
1275   (make-std-reader-method-function (class-name class) slot-name))
1276
1277 (defmethod make-writer-method-function ((class slot-class) slot-name)
1278   (make-std-writer-method-function (class-name class) slot-name))
1279
1280 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1281   (make-std-boundp-method-function (class-name class) slot-name))
1282 \f
1283 (defmethod compatible-meta-class-change-p (class proto-new-class)
1284   (eq (class-of class) (class-of proto-new-class)))
1285
1286 (defmethod validate-superclass ((class class) (new-super class))
1287   (or (eq new-super *the-class-t*)
1288       (eq (class-of class) (class-of new-super))))
1289
1290 (defmethod validate-superclass ((class standard-class) (new-super std-class))
1291   (let ((new-super-meta-class (class-of new-super)))
1292     (or (eq new-super-meta-class *the-class-std-class*)
1293         (eq (class-of class) new-super-meta-class))))
1294 \f
1295 ;;; What this does depends on which of the four possible values of
1296 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1297 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1298 ;;; nothing to do, as the new wrapper has already been created.  If
1299 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1300 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1301 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1302 ;;;
1303 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1304 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1305 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1306 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1307 ;;; obsolete the wrapper.
1308 ;;;
1309 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1310 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1311 ;;;                    :UNINITIALIZED)))
1312 ;;;
1313 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1314 (defun force-cache-flushes (class)
1315   (let* ((owrapper (class-wrapper class)))
1316     ;; We only need to do something if the wrapper is still valid. If
1317     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1318     ;; both of those will already be doing what we want. In
1319     ;; particular, we must be sure we never change an OBSOLETE into a
1320     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1321     (when (or (not (invalid-wrapper-p owrapper))
1322               ;; KLUDGE: despite the observations above, this remains
1323               ;; a violation of locality or what might be considered
1324               ;; good style.  There has to be a better way!  -- CSR,
1325               ;; 2002-10-29
1326               (eq (layout-invalid owrapper) t))
1327       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1328                                     class)))
1329         (setf (wrapper-instance-slots-layout nwrapper)
1330               (wrapper-instance-slots-layout owrapper))
1331         (setf (wrapper-class-slots nwrapper)
1332               (wrapper-class-slots owrapper))
1333         (with-pcl-lock
1334           (update-lisp-class-layout class nwrapper)
1335           (setf (slot-value class 'wrapper) nwrapper)
1336           (invalidate-wrapper owrapper :flush nwrapper))))))
1337
1338 (defun flush-cache-trap (owrapper nwrapper instance)
1339   (declare (ignore owrapper))
1340   (set-wrapper instance nwrapper))
1341 \f
1342 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1343 ;;; the next access to the instance (as defined in 88-002R) to trap
1344 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1345 (defmethod make-instances-obsolete ((class std-class))
1346   (let* ((owrapper (class-wrapper class))
1347          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1348                                  class)))
1349       (setf (wrapper-instance-slots-layout nwrapper)
1350             (wrapper-instance-slots-layout owrapper))
1351       (setf (wrapper-class-slots nwrapper)
1352             (wrapper-class-slots owrapper))
1353       (with-pcl-lock
1354         (update-lisp-class-layout class nwrapper)
1355         (setf (slot-value class 'wrapper) nwrapper)
1356         (invalidate-wrapper owrapper :obsolete nwrapper)
1357         class)))
1358
1359 (defmethod make-instances-obsolete ((class symbol))
1360   (make-instances-obsolete (find-class class)))
1361
1362 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1363 ;;; see an obsolete instance. The times when it is called are:
1364 ;;;   - when the instance is involved in method lookup
1365 ;;;   - when attempting to access a slot of an instance
1366 ;;;
1367 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1368 ;;; instance access macros.
1369 ;;;
1370 ;;; Of course these times when it is called are an internal
1371 ;;; implementation detail of PCL and are not part of the documented
1372 ;;; description of when the obsolete instance update happens. The
1373 ;;; documented description is as it appears in 88-002R.
1374 ;;;
1375 ;;; This has to return the new wrapper, so it counts on all the
1376 ;;; methods on obsolete-instance-trap-internal to return the new
1377 ;;; wrapper. It also does a little internal error checking to make
1378 ;;; sure that the traps are only happening when they should, and that
1379 ;;; the trap methods are computing appropriate new wrappers.
1380
1381 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1382 ;;; after a structure is redefined. In most cases,
1383 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1384 ;;; so it must signal an error. The hard part of this is that the
1385 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1386 ;;; called again, so in that case, we have to return some reasonable
1387 ;;; wrapper, instead.
1388
1389 (defvar *in-obsolete-instance-trap* nil)
1390 (defvar *the-wrapper-of-structure-object*
1391   (class-wrapper (find-class 'structure-object)))
1392
1393 (define-condition obsolete-structure (error)
1394   ((datum :reader obsolete-structure-datum :initarg :datum))
1395   (:report
1396    (lambda (condition stream)
1397      ;; Don't try to print the structure, since it probably won't work.
1398      (format stream
1399              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1400              (type-of (obsolete-structure-datum condition))))))
1401
1402 (defun obsolete-instance-trap (owrapper nwrapper instance)
1403   (if (not (pcl-instance-p instance))
1404       (if *in-obsolete-instance-trap*
1405           *the-wrapper-of-structure-object*
1406            (let ((*in-obsolete-instance-trap* t))
1407              (error 'obsolete-structure :datum instance)))
1408       (let* ((class (wrapper-class* nwrapper))
1409              (copy (allocate-instance class)) ;??? allocate-instance ???
1410              (olayout (wrapper-instance-slots-layout owrapper))
1411              (nlayout (wrapper-instance-slots-layout nwrapper))
1412              (oslots (get-slots instance))
1413              (nslots (get-slots copy))
1414              (oclass-slots (wrapper-class-slots owrapper))
1415              (added ())
1416              (discarded ())
1417              (plist ()))
1418         ;; local  --> local     transfer
1419         ;; local  --> shared       discard
1420         ;; local  -->  --         discard
1421         ;; shared --> local     transfer
1422         ;; shared --> shared       discard
1423         ;; shared -->  --         discard
1424         ;;  --    --> local     add
1425         ;;  --    --> shared    --
1426
1427         ;; Go through all the old local slots.
1428         (let ((opos 0))
1429           (dolist (name olayout)
1430             (let ((npos (posq name nlayout)))
1431               (if npos
1432                   (setf (clos-slots-ref nslots npos)
1433                         (clos-slots-ref oslots opos))
1434                   (progn
1435                     (push name discarded)
1436                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1437                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1438             (incf opos)))
1439
1440         ;; Go through all the old shared slots.
1441         (dolist (oclass-slot-and-val oclass-slots)
1442           (let ((name (car oclass-slot-and-val))
1443                 (val (cdr oclass-slot-and-val)))
1444             (let ((npos (posq name nlayout)))
1445               (if npos
1446                   (setf (clos-slots-ref nslots npos) (cdr oclass-slot-and-val))
1447                   (progn (push name discarded)
1448                          (unless (eq val +slot-unbound+)
1449                            (setf (getf plist name) val)))))))
1450
1451         ;; Go through all the new local slots to compute the added slots.
1452         (dolist (nlocal nlayout)
1453           (unless (or (memq nlocal olayout)
1454                       (assq nlocal oclass-slots))
1455             (push nlocal added)))
1456
1457         (swap-wrappers-and-slots instance copy)
1458
1459         (update-instance-for-redefined-class instance
1460                                              added
1461                                              discarded
1462                                              plist)
1463         nwrapper)))
1464 \f
1465 (defun change-class-internal (instance new-class initargs)
1466   (let* ((old-class (class-of instance))
1467          (copy (allocate-instance new-class))
1468          (new-wrapper (get-wrapper copy))
1469          (old-wrapper (class-wrapper old-class))
1470          (old-layout (wrapper-instance-slots-layout old-wrapper))
1471          (new-layout (wrapper-instance-slots-layout new-wrapper))
1472          (old-slots (get-slots instance))
1473          (new-slots (get-slots copy))
1474          (old-class-slots (wrapper-class-slots old-wrapper)))
1475
1476     ;; "The values of local slots specified by both the class CTO and
1477     ;; CFROM are retained. If such a local slot was unbound, it
1478     ;; remains unbound."
1479     (let ((new-position 0))
1480       (dolist (new-slot new-layout)
1481         (let ((old-position (posq new-slot old-layout)))
1482           (when old-position
1483             (setf (clos-slots-ref new-slots new-position)
1484                   (clos-slots-ref old-slots old-position))))
1485         (incf new-position)))
1486
1487     ;; "The values of slots specified as shared in the class CFROM and
1488     ;; as local in the class CTO are retained."
1489     (dolist (slot-and-val old-class-slots)
1490       (let ((position (posq (car slot-and-val) new-layout)))
1491         (when position
1492           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1493
1494     ;; Make the copy point to the old instance's storage, and make the
1495     ;; old instance point to the new storage.
1496     (swap-wrappers-and-slots instance copy)
1497
1498     (apply #'update-instance-for-different-class copy instance initargs)
1499     instance))
1500
1501 (defmethod change-class ((instance standard-object)
1502                          (new-class standard-class)
1503                          &rest initargs)
1504   (change-class-internal instance new-class initargs))
1505
1506 (defmethod change-class ((instance funcallable-standard-object)
1507                          (new-class funcallable-standard-class)
1508                          &rest initargs)
1509   (change-class-internal instance new-class initargs))
1510
1511 (defmethod change-class ((instance standard-object)
1512                          (new-class funcallable-standard-class)
1513                          &rest initargs)
1514   (declare (ignore initargs))
1515   (error "You can't change the class of ~S to ~S~@
1516           because it isn't already an instance with metaclass ~S."
1517          instance new-class 'standard-class))
1518
1519 (defmethod change-class ((instance funcallable-standard-object)
1520                          (new-class standard-class)
1521                          &rest initargs)
1522   (declare (ignore initargs))
1523   (error "You can't change the class of ~S to ~S~@
1524           because it isn't already an instance with metaclass ~S."
1525          instance new-class 'funcallable-standard-class))
1526
1527 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1528   (apply #'change-class instance (find-class new-class-name) initargs))
1529 \f
1530 ;;;; The metaclass BUILT-IN-CLASS
1531 ;;;;
1532 ;;;; This metaclass is something of a weird creature. By this point, all
1533 ;;;; instances of it which will exist have been created, and no instance
1534 ;;;; is ever created by calling MAKE-INSTANCE.
1535 ;;;;
1536 ;;;; But, there are other parts of the protocol we must follow and those
1537 ;;;; definitions appear here.
1538
1539 (defmethod shared-initialize :before
1540            ((class built-in-class) slot-names &rest initargs)
1541   (declare (ignore slot-names initargs))
1542   (error "attempt to initialize or reinitialize a built in class"))
1543
1544 (defmethod class-direct-slots       ((class built-in-class)) ())
1545 (defmethod class-slots             ((class built-in-class)) ())
1546 (defmethod class-direct-default-initargs ((class built-in-class)) ())
1547 (defmethod class-default-initargs       ((class built-in-class)) ())
1548
1549 (defmethod validate-superclass ((c class) (s built-in-class))
1550   (or (eq s *the-class-t*)
1551       (eq s *the-class-stream*)))
1552 \f
1553 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1554 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1555 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1556 (macrolet ((def (method)
1557              `(defmethod ,method ((class forward-referenced-class))
1558                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1559                        ',method class))))
1560   (def class-default-initargs)
1561   (def class-precedence-list)
1562   (def class-slots))
1563
1564 (defmethod validate-superclass ((c slot-class)
1565                                 (f forward-referenced-class))
1566   t)
1567 \f
1568 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1569   (pushnew dependent (plist-value metaobject 'dependents)))
1570
1571 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1572   (setf (plist-value metaobject 'dependents)
1573         (delete dependent (plist-value metaobject 'dependents))))
1574
1575 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1576   (dolist (dependent (plist-value metaobject 'dependents))
1577     (funcall function dependent)))
1578