src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd '%class)))
  76     (dolist (type '(reader writer boundp))
  77       (let* ((gf-name (ecase type
  78                               (reader 'slot-value-using-class)
  79                               (writer '(setf slot-value-using-class))
  80                               (boundp 'slot-boundp-using-class)))
  81              (gf (gdefinition gf-name)))
  82         (compute-slot-accessor-info slotd type gf)))))
  83
  84 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
  85 ;;;
  86 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
  87 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
  88 ;;; writing/testing effective slot SLOTD.
  89 ;;;
  90 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
  91 ;;; GF.  Store the effective method in the effective slot definition
  92 ;;; object itself; these GFs have special dispatch functions calling
  93 ;;; effective methods directly retrieved from effective slot
  94 ;;; definition objects, as an optimization.
  95 ;;;
  96 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
  97 ;;; or some such.
  98 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  99                                        type gf)
 100   (let* ((name (slot-value slotd 'name))
 101          (class (slot-value slotd '%class))
 102          (old-slotd (find-slot-definition class name))
 103          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
 104     (multiple-value-bind (function std-p)
 105         (if (eq *boot-state* 'complete)
 106             (get-accessor-method-function gf type class slotd)
 107             (get-optimized-std-accessor-method-function class slotd type))
 108       (setf (slot-accessor-std-p slotd type) std-p)
 109       (setf (slot-accessor-function slotd type) function))
 110     (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
 111       (push (cons class name) *pv-table-cache-update-info*))))
 112
 113 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 114   :instance)
 115 \f
 116 ;;;; various class accessors that are a little more complicated than can be
 117 ;;;; done with automatically generated reader methods
 118
 119 (defmethod class-prototype :before (class)
 120   (unless (class-finalized-p class)
 121     (error "~@<~S is not finalized.~:@>" class)))
 122
 123 ;;; KLUDGE: For some reason factoring the common body into a function
 124 ;;; breaks PCL bootstrapping, so just generate it with a macrolet for
 125 ;;; all.
 126 (macrolet ((def (class)
 127              `(defmethod class-prototype ((class ,class))
 128                 (with-slots (prototype) class
 129                   (or prototype
 130                       (setf prototype (allocate-instance class)))))))
 131   (def std-class)
 132   (def condition-class)
 133   (def structure-class))
 134
 135 (defmethod class-direct-default-initargs ((class slot-class))
 136   (plist-value class 'direct-default-initargs))
 137
 138 (defmethod class-default-initargs ((class slot-class))
 139   (plist-value class 'default-initargs))
 140
 141 (defmethod class-slot-cells ((class std-class))
 142   (plist-value class 'class-slot-cells))
 143 (defmethod (setf class-slot-cells) (new-value (class std-class))
 144   (setf (plist-value class 'class-slot-cells) new-value))
 145 \f
 146 ;;;; class accessors that are even a little bit more complicated than those
 147 ;;;; above. These have a protocol for updating them, we must implement that
 148 ;;;; protocol.
 149
 150 ;;; Maintaining the direct subclasses backpointers. The update methods are
 151 ;;; here, the values are read by an automatically generated reader method.
 152 (defmethod add-direct-subclass ((class class) (subclass class))
 153   (with-slots (direct-subclasses) class
 154     (pushnew subclass direct-subclasses)
 155     subclass))
 156 (defmethod remove-direct-subclass ((class class) (subclass class))
 157   (with-slots (direct-subclasses) class
 158     (setq direct-subclasses (remove subclass direct-subclasses))
 159     subclass))
 160
 161 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 162 ;;;
 163 ;;; There are four generic functions involved, each has one method for the
 164 ;;; class case and another method for the damned EQL specializers. All of
 165 ;;; these are specified methods and appear in their specified place in the
 166 ;;; class graph.
 167 ;;;
 168 ;;;   ADD-DIRECT-METHOD
 169 ;;;   REMOVE-DIRECT-METHOD
 170 ;;;   SPECIALIZER-DIRECT-METHODS
 171 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 172 ;;;
 173 ;;; In each case, we maintain one value which is a cons. The car is the list
 174 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 175 ;;; computed lazily.
 176 (defmethod add-direct-method ((specializer class) (method method))
 177   (with-slots (direct-methods) specializer
 178     (setf (car direct-methods) (adjoin method (car direct-methods))     ;PUSH
 179           (cdr direct-methods) ()))
 180   method)
 181 (defmethod remove-direct-method ((specializer class) (method method))
 182   (with-slots (direct-methods) specializer
 183     (setf (car direct-methods) (remove method (car direct-methods))
 184           (cdr direct-methods) ()))
 185   method)
 186
 187 (defmethod specializer-direct-methods ((specializer class))
 188   (with-slots (direct-methods) specializer
 189     (car direct-methods)))
 190
 191 (defmethod specializer-direct-generic-functions ((specializer class))
 192   (with-slots (direct-methods) specializer
 193     (or (cdr direct-methods)
 194         (setf (cdr direct-methods)
 195               (let (collect)
 196                 (dolist (m (car direct-methods))
 197                   ;; the old PCL code used COLLECTING-ONCE which used
 198                   ;; #'EQ to check for newness
 199                   (pushnew (method-generic-function m) collect :test #'eq))
 200                 (nreverse collect))))))
 201 \f
 202 ;;; This hash table is used to store the direct methods and direct generic
 203 ;;; functions of EQL specializers. Each value in the table is the cons.
 204 (defvar *eql-specializer-methods* (make-hash-table :test 'eql))
 205 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq))
 206
 207 (defmethod specializer-method-table ((specializer eql-specializer))
 208   *eql-specializer-methods*)
 209
 210 (defmethod specializer-method-table ((specializer class-eq-specializer))
 211   *class-eq-specializer-methods*)
 212
 213 (defmethod add-direct-method ((specializer specializer-with-object)
 214                               (method method))
 215   (let* ((object (specializer-object specializer))
 216          (table (specializer-method-table specializer))
 217          (entry (gethash object table)))
 218     (unless entry
 219       (setq entry
 220             (setf (gethash object table)
 221                   (cons nil nil))))
 222     (setf (car entry) (adjoin method (car entry))
 223           (cdr entry) ())
 224     method))
 225
 226 (defmethod remove-direct-method ((specializer specializer-with-object)
 227                                  (method method))
 228   (let* ((object (specializer-object specializer))
 229          (entry (gethash object (specializer-method-table specializer))))
 230     (when entry
 231       (setf (car entry) (remove method (car entry))
 232             (cdr entry) ()))
 233     method))
 234
 235 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 236   (car (gethash (specializer-object specializer)
 237                 (specializer-method-table specializer))))
 238
 239 (defmethod specializer-direct-generic-functions ((specializer
 240                                                   specializer-with-object))
 241   (let* ((object (specializer-object specializer))
 242          (entry (gethash object (specializer-method-table specializer))))
 243     (when entry
 244       (or (cdr entry)
 245           (setf (cdr entry)
 246                 (let (collect)
 247                   (dolist (m (car entry))
 248                     (pushnew (method-generic-function m) collect :test #'eq))
 249                   (nreverse collect)))))))
 250
 251 (defun map-specializers (function)
 252   (map-all-classes (lambda (class)
 253                      (funcall function (class-eq-specializer class))
 254                      (funcall function class)))
 255   (maphash (lambda (object methods)
 256              (declare (ignore methods))
 257              (intern-eql-specializer object))
 258            *eql-specializer-methods*)
 259   (maphash (lambda (object specl)
 260              (declare (ignore object))
 261              (funcall function specl))
 262            *eql-specializer-table*)
 263   nil)
 264
 265 (defun map-all-generic-functions (function)
 266   (let ((all-generic-functions (make-hash-table :test 'eq)))
 267     (map-specializers (lambda (specl)
 268                         (dolist (gf (specializer-direct-generic-functions
 269                                      specl))
 270                           (unless (gethash gf all-generic-functions)
 271                             (setf (gethash gf all-generic-functions) t)
 272                             (funcall function gf))))))
 273   nil)
 274
 275 (defmethod shared-initialize :after ((specl class-eq-specializer)
 276                                      slot-names
 277                                      &key)
 278   (declare (ignore slot-names))
 279   (setf (slot-value specl '%type) `(class-eq ,(specializer-class specl))))
 280
 281 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 282   (declare (ignore slot-names))
 283   (setf (slot-value specl '%type)
 284         `(eql ,(specializer-object specl)))
 285   (setf (info :type :translator specl)
 286         (constantly (make-member-type :members (list (specializer-object specl))))))
 287
 288 (defun real-load-defclass (name metaclass-name supers slots other
 289                            readers writers slot-names source-location)
 290   (with-single-package-locked-error (:symbol name "defining ~S as a class")
 291     (%compiler-defclass name readers writers slot-names)
 292     (let ((res (apply #'ensure-class name :metaclass metaclass-name
 293                       :direct-superclasses supers
 294                       :direct-slots slots
 295                       :definition-source source-location
 296                       other)))
 297       res)))
 298
 299 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 300
 301 (defun ensure-class (name &rest args)
 302   (apply #'ensure-class-using-class
 303          (let ((class (find-class name nil)))
 304            (when (and class (eq name (class-name class)))
 305              ;; NAME is the proper name of CLASS, so redefine it
 306              class))
 307          name
 308          args))
 309
 310 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 311   (multiple-value-bind (meta initargs)
 312       (ensure-class-values class args)
 313     (set-class-type-translation (class-prototype meta) name)
 314     (setf class (apply #'make-instance meta :name name initargs))
 315     (without-package-locks
 316       (setf (find-class name) class))
 317     (set-class-type-translation class name)
 318     class))
 319
 320 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 321   (multiple-value-bind (meta initargs)
 322       (ensure-class-values class args)
 323     (unless (eq (class-of class) meta)
 324       (apply #'change-class class meta initargs))
 325     (apply #'reinitialize-instance class initargs)
 326     (without-package-locks
 327       (setf (find-class name) class))
 328     (set-class-type-translation class name)
 329     class))
 330
 331 (defun fix-super (s)
 332   (cond ((classp s) s)
 333         ((not (legal-class-name-p s))
 334          (error "~S is not a class or a legal class name." s))
 335         (t
 336          (or (find-class s nil)
 337              (make-instance 'forward-referenced-class
 338                             :name s)))))
 339
 340 (defun ensure-class-values (class initargs)
 341   (let (metaclass metaclassp reversed-plist)
 342     (doplist (key val) initargs
 343       (cond ((eq key :metaclass)
 344              (setf metaclass val
 345                    metaclassp key))
 346             (t
 347              (when (eq key :direct-superclasses)
 348                (setf val (mapcar #'fix-super val)))
 349              (setf reversed-plist (list* val key reversed-plist)))))
 350     (values (cond (metaclassp
 351                    (if (classp metaclass)
 352                        metaclass
 353                        (find-class metaclass)))
 354                   ((or (null class) (forward-referenced-class-p class))
 355                    *the-class-standard-class*)
 356                   (t
 357                    (class-of class)))
 358             (nreverse reversed-plist))))
 359
 360 \f
 361 (defmethod shared-initialize :after
 362     ((class std-class) slot-names &key
 363      (direct-superclasses nil direct-superclasses-p)
 364      (direct-slots nil direct-slots-p)
 365      (direct-default-initargs nil direct-default-initargs-p))
 366   (cond (direct-superclasses-p
 367          (setq direct-superclasses
 368                (or direct-superclasses
 369                    (list (if (funcallable-standard-class-p class)
 370                              *the-class-funcallable-standard-object*
 371                              *the-class-standard-object*))))
 372          (dolist (superclass direct-superclasses)
 373            (unless (validate-superclass class superclass)
 374              (error "~@<The class ~S was specified as a ~
 375                      super-class of the class ~S, ~
 376                      but the meta-classes ~S and ~S are incompatible.  ~
 377                      Define a method for ~S to avoid this error.~@:>"
 378                      superclass class (class-of superclass) (class-of class)
 379                      'validate-superclass)))
 380          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 381         (t
 382          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 383   (setq direct-slots
 384         (if direct-slots-p
 385             (setf (slot-value class 'direct-slots)
 386                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 387                           direct-slots))
 388             (slot-value class 'direct-slots)))
 389   (if direct-default-initargs-p
 390       (setf (plist-value class 'direct-default-initargs)
 391             direct-default-initargs)
 392       (setq direct-default-initargs
 393             (plist-value class 'direct-default-initargs)))
 394   (setf (plist-value class 'class-slot-cells)
 395         (let ((old-class-slot-cells (plist-value class 'class-slot-cells))
 396               (collect '()))
 397           (dolist (dslotd direct-slots)
 398             (when (eq :class (slot-definition-allocation dslotd))
 399               ;; see CLHS 4.3.6
 400               (let* ((name (slot-definition-name dslotd))
 401                      (old (assoc name old-class-slot-cells)))
 402                 (if (or (not old)
 403                         (eq t slot-names)
 404                         (member name slot-names))
 405                     (let* ((initfunction (slot-definition-initfunction dslotd))
 406                            (value (if initfunction
 407                                       (funcall initfunction)
 408                                       +slot-unbound+)))
 409                       (push (cons name value) collect))
 410                     (push old collect)))))
 411           (nreverse collect)))
 412   (add-direct-subclasses class direct-superclasses)
 413   (update-class class nil)
 414   (do* ((slots (slot-value class 'slots) (cdr slots))
 415         (dupes nil))
 416        ((null slots) (when dupes
 417                        (style-warn
 418                         ;; FIXME: the indentation request ("~4I")
 419                         ;; below appears not to do anything.  Finding
 420                         ;; out why would be nice.  -- CSR, 2003-04-24
 421                         "~@<slot names with the same SYMBOL-NAME but ~
 422                          different SYMBOL-PACKAGE (possible package problem) ~
 423                          for class ~S:~@:_~4I~<~@{~S~^~:@_~}~:>~@:>"
 424                         class
 425                         dupes)))
 426     (let* ((slot (car slots))
 427            (oslots (remove (slot-definition-name slot) (cdr slots)
 428                            :test #'string/= :key #'slot-definition-name)))
 429       (when oslots
 430         (pushnew (cons (slot-definition-name slot)
 431                        (mapcar #'slot-definition-name oslots))
 432                  dupes
 433                  :test #'string= :key #'car))))
 434   (add-slot-accessors class direct-slots)
 435   (make-preliminary-layout class))
 436
 437 (defmethod shared-initialize :after ((class forward-referenced-class)
 438                                      slot-names &key &allow-other-keys)
 439   (declare (ignore slot-names))
 440   (make-preliminary-layout class))
 441
 442 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 443
 444 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 445 ;;; make it known to the type system.
 446 (defun make-preliminary-layout (class)
 447   (flet ((compute-preliminary-cpl (root)
 448            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 449              (compute-class-precedence-list root))))
 450     (without-package-locks
 451      (unless (class-finalized-p class)
 452        (let ((name (class-name class)))
 453          (setf (find-class name) class)
 454          ;; KLUDGE: This is fairly horrible.  We need to make a
 455          ;; full-fledged CLASSOID here, not just tell the compiler that
 456          ;; some class is forthcoming, because there are legitimate
 457          ;; questions one can ask of the type system, implemented in
 458          ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 459          (when (and (eq *boot-state* 'complete)
 460                     (null (find-classoid name nil)))
 461            (setf (find-classoid name)
 462                  (make-standard-classoid :name name)))
 463          (set-class-type-translation class name)
 464          (let ((layout (make-wrapper 0 class))
 465                (classoid (find-classoid name)))
 466            (setf (layout-classoid layout) classoid)
 467            (setf (classoid-pcl-class classoid) class)
 468            (setf (slot-value class 'wrapper) layout)
 469            (let ((cpl (compute-preliminary-cpl class)))
 470              (setf (layout-inherits layout)
 471                    (order-layout-inherits
 472                     (map 'simple-vector #'class-wrapper
 473                          (reverse (rest cpl))))))
 474            (register-layout layout :invalidate t)
 475            (setf (classoid-layout classoid) layout)
 476            (mapc #'make-preliminary-layout (class-direct-subclasses class))))))))
 477
 478
 479 (defmethod shared-initialize :before ((class class) slot-names &key name)
 480   (declare (ignore slot-names name))
 481   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 482   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 483   (setf (slot-value class '%type) `(class ,class))
 484   (setf (slot-value class 'class-eq-specializer)
 485         (make-instance 'class-eq-specializer :class class)))
 486
 487 (defmethod reinitialize-instance :before ((class slot-class) &key direct-superclasses)
 488   (dolist (old-super (set-difference (class-direct-superclasses class) direct-superclasses))
 489     (remove-direct-subclass old-super class))
 490   (remove-slot-accessors    class (class-direct-slots class)))
 491
 492 (defmethod reinitialize-instance :after ((class slot-class)
 493                                          &rest initargs
 494                                          &key)
 495   (map-dependents class
 496                   (lambda (dependent)
 497                     (apply #'update-dependent class dependent initargs))))
 498
 499 (defmethod reinitialize-instance :after ((class condition-class) &key)
 500   (let* ((name (class-name class))
 501          (classoid (find-classoid name))
 502          (slots (condition-classoid-slots classoid)))
 503     ;; to balance the REMOVE-SLOT-ACCESSORS call in
 504     ;; REINITIALIZE-INSTANCE :BEFORE (SLOT-CLASS).
 505     (dolist (slot slots)
 506       (let ((slot-name (condition-slot-name slot)))
 507         (dolist (reader (condition-slot-readers slot))
 508           ;; FIXME: see comment in SHARED-INITIALIZE :AFTER
 509           ;; (CONDITION-CLASS T), below.  -- CSR, 2005-11-18
 510           (sb-kernel::install-condition-slot-reader reader name slot-name))
 511         (dolist (writer (condition-slot-writers slot))
 512           (sb-kernel::install-condition-slot-writer writer name slot-name))))))
 513
 514 (defmethod shared-initialize :after ((class condition-class) slot-names
 515                                      &key direct-slots direct-superclasses)
 516   (declare (ignore slot-names))
 517   (let ((classoid (find-classoid (class-name class))))
 518     (with-slots (wrapper %class-precedence-list cpl-available-p
 519                          prototype (direct-supers direct-superclasses))
 520         class
 521       (setf (slot-value class 'direct-slots)
 522             (mapcar (lambda (pl) (make-direct-slotd class pl))
 523                     direct-slots))
 524       (setf (slot-value class 'finalized-p) t)
 525       (setf (classoid-pcl-class classoid) class)
 526       (setq direct-supers direct-superclasses)
 527       (setq wrapper (classoid-layout classoid))
 528       (setq %class-precedence-list (compute-class-precedence-list class))
 529       (setq cpl-available-p t)
 530       (add-direct-subclasses class direct-superclasses)
 531       (setf (slot-value class 'slots) (compute-slots class))))
 532   ;; Comment from Gerd's PCL, 2003-05-15:
 533   ;;
 534   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 535   ;; override condition accessors with generic functions.  We do this
 536   ;; differently.
 537   ;;
 538   ;; ??? What does the above comment mean and why is it a good idea?
 539   ;; CMUCL (which still as of 2005-11-18 uses this code and has this
 540   ;; comment) loses slot information in its condition classes:
 541   ;; DIRECT-SLOTS is always NIL.  We have the right information, so we
 542   ;; remove slot accessors but never put them back.  I've added a
 543   ;; REINITIALIZE-INSTANCE :AFTER (CONDITION-CLASS) method, but what
 544   ;; was meant to happen?  -- CSR, 2005-11-18
 545   (update-pv-table-cache-info class))
 546
 547 (defmethod direct-slot-definition-class ((class condition-class)
 548                                          &rest initargs)
 549   (declare (ignore initargs))
 550   (find-class 'condition-direct-slot-definition))
 551
 552 (defmethod effective-slot-definition-class ((class condition-class)
 553                                             &rest initargs)
 554   (declare (ignore initargs))
 555   (find-class 'condition-effective-slot-definition))
 556
 557 (defmethod finalize-inheritance ((class condition-class))
 558   (aver (slot-value class 'finalized-p))
 559   nil)
 560
 561 (defmethod compute-effective-slot-definition
 562     ((class condition-class) slot-name dslotds)
 563   (let ((slotd (call-next-method)))
 564     (setf (slot-definition-reader-function slotd)
 565           (lambda (x)
 566             (handler-case (condition-reader-function x slot-name)
 567               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 568               ;; is unbound; maybe it should be a CELL-ERROR of some
 569               ;; sort?
 570               (error () (values (slot-unbound class x slot-name))))))
 571     (setf (slot-definition-writer-function slotd)
 572           (lambda (v x)
 573             (condition-writer-function x v slot-name)))
 574     (setf (slot-definition-boundp-function slotd)
 575           (lambda (x)
 576             (multiple-value-bind (v c)
 577                 (ignore-errors (condition-reader-function x slot-name))
 578               (declare (ignore v))
 579               (null c))))
 580     slotd))
 581
 582 (defmethod compute-slots ((class condition-class))
 583   (mapcan (lambda (superclass)
 584             (mapcar (lambda (dslotd)
 585                       (compute-effective-slot-definition
 586                        class (slot-definition-name dslotd) (list dslotd)))
 587                     (class-direct-slots superclass)))
 588           (reverse (slot-value class '%class-precedence-list))))
 589
 590 (defmethod compute-slots :around ((class condition-class))
 591   (let ((eslotds (call-next-method)))
 592     (mapc #'initialize-internal-slot-functions eslotds)
 593     eslotds))
 594
 595 (defmethod shared-initialize :after
 596     ((slotd structure-slot-definition) slot-names &key
 597      (allocation :instance) allocation-class)
 598   (declare (ignore slot-names allocation-class))
 599   (unless (eq allocation :instance)
 600     (error "Structure slots must have :INSTANCE allocation.")))
 601
 602 (defun make-structure-class-defstruct-form (name direct-slots include)
 603   (let* ((conc-name (format-symbol *package* "~S structure class " name))
 604          (constructor (format-symbol *package* "~Aconstructor" conc-name))
 605          (defstruct `(defstruct (,name
 606                                  ,@(when include
 607                                          `((:include ,(class-name include))))
 608                                  (:predicate nil)
 609                                  (:conc-name ,conc-name)
 610                                  (:constructor ,constructor ())
 611                                  (:copier nil))
 612                       ,@(mapcar (lambda (slot)
 613                                   `(,(slot-definition-name slot)
 614                                     +slot-unbound+))
 615                                 direct-slots)))
 616          (reader-names (mapcar (lambda (slotd)
 617                                  (list 'slot-accessor name
 618                                        (slot-definition-name slotd)
 619                                        'reader))
 620                                direct-slots))
 621          (writer-names (mapcar (lambda (slotd)
 622                                  (list 'slot-accessor name
 623                                        (slot-definition-name slotd)
 624                                        'writer))
 625                                direct-slots))
 626          (readers-init
 627            (mapcar (lambda (slotd reader-name)
 628                      (let ((accessor
 629                              (slot-definition-defstruct-accessor-symbol
 630                               slotd)))
 631                        `(defun ,reader-name (obj)
 632                          (declare (type ,name obj))
 633                          (,accessor obj))))
 634                    direct-slots reader-names))
 635          (writers-init
 636            (mapcar (lambda (slotd writer-name)
 637                      (let ((accessor
 638                              (slot-definition-defstruct-accessor-symbol
 639                               slotd)))
 640                        `(defun ,writer-name (nv obj)
 641                          (declare (type ,name obj))
 642                          (setf (,accessor obj) nv))))
 643                    direct-slots writer-names))
 644          (defstruct-form
 645              `(progn
 646                ,defstruct
 647                ,@readers-init ,@writers-init
 648                (cons nil nil))))
 649     (values defstruct-form constructor reader-names writer-names)))
 650
 651 (defun make-defstruct-allocation-function (class)
 652   (let ((dd (get-structure-dd (class-name class))))
 653     (lambda ()
 654       (sb-kernel::%make-instance-with-layout
 655        (sb-kernel::compiler-layout-or-lose (dd-name dd))))))
 656
 657 (defmethod shared-initialize :after
 658     ((class structure-class) slot-names &key
 659      (direct-superclasses nil direct-superclasses-p)
 660      (direct-slots nil direct-slots-p)
 661      direct-default-initargs)
 662   (declare (ignore slot-names direct-default-initargs))
 663   (if direct-superclasses-p
 664       (setf (slot-value class 'direct-superclasses)
 665             (or direct-superclasses
 666                 (setq direct-superclasses
 667                       (and (not (eq (class-name class) 'structure-object))
 668                            (list *the-class-structure-object*)))))
 669       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 670   (let* ((name (class-name class))
 671          (from-defclass-p (slot-value class 'from-defclass-p))
 672          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 673     (if direct-slots-p
 674         (setf (slot-value class 'direct-slots)
 675               (setq direct-slots
 676                     (mapcar (lambda (pl)
 677                               (when defstruct-p
 678                                 (let* ((slot-name (getf pl :name))
 679                                        (accessor
 680                                         (format-symbol *package*
 681                                                        "~S structure class ~A"
 682                                                        name slot-name)))
 683                                   (setq pl (list* :defstruct-accessor-symbol
 684                                                   accessor pl))))
 685                               (make-direct-slotd class pl))
 686                             direct-slots)))
 687         (setq direct-slots (slot-value class 'direct-slots)))
 688     (if defstruct-p
 689         (let ((include (car (slot-value class 'direct-superclasses))))
 690           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 691               (make-structure-class-defstruct-form name direct-slots include)
 692             (unless (structure-type-p name) (eval defstruct-form))
 693             (mapc (lambda (dslotd reader-name writer-name)
 694                     (let* ((reader (gdefinition reader-name))
 695                            (writer (when (fboundp writer-name)
 696                                      (gdefinition writer-name))))
 697                       (setf (slot-value dslotd 'internal-reader-function)
 698                             reader)
 699                       (setf (slot-value dslotd 'internal-writer-function)
 700                             writer)))
 701                   direct-slots reader-names writer-names)
 702             (setf (slot-value class 'defstruct-form) defstruct-form)
 703             (setf (slot-value class 'defstruct-constructor) constructor)))
 704         (setf (slot-value class 'defstruct-constructor)
 705               (make-defstruct-allocation-function class)))
 706     (add-direct-subclasses class direct-superclasses)
 707     (setf (slot-value class '%class-precedence-list)
 708           (compute-class-precedence-list class))
 709     (setf (slot-value class 'cpl-available-p) t)
 710     (setf (slot-value class 'slots) (compute-slots class))
 711     (let ((lclass (find-classoid (class-name class))))
 712       (setf (classoid-pcl-class lclass) class)
 713       (setf (slot-value class 'wrapper) (classoid-layout lclass)))
 714     (setf (slot-value class 'finalized-p) t)
 715     (update-pv-table-cache-info class)
 716     (add-slot-accessors class direct-slots)))
 717
 718 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 719   (declare (ignore initargs))
 720   (find-class 'structure-direct-slot-definition))
 721
 722 (defmethod finalize-inheritance ((class structure-class))
 723   nil) ; always finalized
 724 \f
 725 (defun add-slot-accessors (class dslotds)
 726   (fix-slot-accessors class dslotds 'add))
 727
 728 (defun remove-slot-accessors (class dslotds)
 729   (fix-slot-accessors class dslotds 'remove))
 730
 731 (defun fix-slot-accessors (class dslotds add/remove)
 732   (flet ((fix (gfspec name r/w)
 733            (let ((gf (cond ((eq add/remove 'add)
 734                             (if (fboundp gfspec)
 735                                 (without-package-locks
 736                                   (ensure-generic-function gfspec))
 737                                 (ensure-generic-function
 738                                  gfspec :lambda-list (case r/w
 739                                                        (r '(object))
 740                                                        (w '(new-value object))))))
 741                            ((generic-function-p (and (fboundp gfspec)
 742                                                      (fdefinition gfspec)))
 743                             (without-package-locks
 744                               (ensure-generic-function gfspec))))))
 745              (when gf
 746                (case r/w
 747                  (r (if (eq add/remove 'add)
 748                         (add-reader-method class gf name)
 749                         (remove-reader-method class gf)))
 750                  (w (if (eq add/remove 'add)
 751                         (add-writer-method class gf name)
 752                         (remove-writer-method class gf))))))))
 753     (dolist (dslotd dslotds)
 754       (let ((slot-name (slot-definition-name dslotd)))
 755         (dolist (r (slot-definition-readers dslotd))
 756           (fix r slot-name 'r))
 757         (dolist (w (slot-definition-writers dslotd))
 758           (fix w slot-name 'w))))))
 759 \f
 760 (defun add-direct-subclasses (class supers)
 761   (dolist (super supers)
 762     (unless (memq class (class-direct-subclasses class))
 763       (add-direct-subclass super class))))
 764
 765 (defmethod finalize-inheritance ((class std-class))
 766   (update-class class t))
 767
 768 (defmethod finalize-inheritance ((class forward-referenced-class))
 769   ;; FIXME: should we not be thinking a bit about what kinds of error
 770   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 771   ;; possibly a forward-referenced-class-error, though that's
 772   ;; difficult given e.g. class precedence list calculations...
 773   (error
 774    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 775        ~2I~_~S~:>"
 776    class))
 777
 778 \f
 779 (defun class-has-a-forward-referenced-superclass-p (class)
 780   (or (forward-referenced-class-p class)
 781       (some #'class-has-a-forward-referenced-superclass-p
 782             (class-direct-superclasses class))))
 783
 784 ;;; This is called by :after shared-initialize whenever a class is initialized
 785 ;;; or reinitialized. The class may or may not be finalized.
 786 (defun update-class (class finalizep)
 787   ;; Comment from Gerd Moellmann:
 788   ;;
 789   ;; Note that we can't simply delay the finalization when CLASS has
 790   ;; no forward referenced superclasses because that causes bootstrap
 791   ;; problems.
 792   (without-package-locks
 793    (when (and (not finalizep)
 794               (not (class-finalized-p class))
 795               (not (class-has-a-forward-referenced-superclass-p class)))
 796      (finalize-inheritance class)
 797      (return-from update-class))
 798    (when (or finalizep (class-finalized-p class)
 799              (not (class-has-a-forward-referenced-superclass-p class)))
 800      (setf (find-class (class-name class)) class)
 801      (update-cpl class (compute-class-precedence-list class))
 802      ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 803      ;; class.  The hoops above are to ensure that FINALIZE-INHERITANCE
 804      ;; is called at finalization, so that MOP programmers can hook
 805      ;; into the system as described in "Class Finalization Protocol"
 806      ;; (section 5.5.2 of AMOP).
 807      (update-slots class (compute-slots class))
 808      (update-gfs-of-class class)
 809      (update-initargs class (compute-default-initargs class))
 810      (update-ctors 'finalize-inheritance :class class))
 811    (dolist (sub (class-direct-subclasses class))
 812      (update-class sub nil))))
 813
 814 (define-condition cpl-protocol-violation (reference-condition error)
 815   ((class :initarg :class :reader cpl-protocol-violation-class)
 816    (cpl :initarg :cpl :reader cpl-protocol-violation-cpl))
 817   (:default-initargs :references (list '(:sbcl :node "Metaobject Protocol")))
 818   (:report
 819    (lambda (c s)
 820      (format s "~@<Protocol violation: the ~S class ~S ~
 821                 ~:[has~;does not have~] the class ~S in its ~
 822                 class precedence list: ~S.~@:>"
 823              (class-name (class-of (cpl-protocol-violation-class c)))
 824              (cpl-protocol-violation-class c)
 825              (eq (class-of (cpl-protocol-violation-class c))
 826                  *the-class-funcallable-standard-class*)
 827              (find-class 'function)
 828              (cpl-protocol-violation-cpl c)))))
 829
 830 (defun update-cpl (class cpl)
 831   (when (eq (class-of class) *the-class-standard-class*)
 832     (when (find (find-class 'function) cpl)
 833       (error 'cpl-protocol-violation :class class :cpl cpl)))
 834   (when (eq (class-of class) *the-class-funcallable-standard-class*)
 835     (unless (find (find-class 'function) cpl)
 836       (error 'cpl-protocol-violation :class class :cpl cpl)))
 837   (if (class-finalized-p class)
 838       (unless (and (equal (class-precedence-list class) cpl)
 839                    (dolist (c cpl t)
 840                      (when (position :class (class-direct-slots c)
 841                                      :key #'slot-definition-allocation)
 842                        (return nil))))
 843         ;; comment from the old CMU CL sources:
 844         ;;   Need to have the cpl setup before update-lisp-class-layout
 845         ;;   is called on CMU CL.
 846         (setf (slot-value class '%class-precedence-list) cpl)
 847         (setf (slot-value class 'cpl-available-p) t)
 848         (force-cache-flushes class))
 849       (progn
 850         (setf (slot-value class '%class-precedence-list) cpl)
 851         (setf (slot-value class 'cpl-available-p) t)))
 852   (update-class-can-precede-p cpl))
 853
 854 (defun update-class-can-precede-p (cpl)
 855   (when cpl
 856     (let ((first (car cpl)))
 857       (dolist (c (cdr cpl))
 858         (pushnew c (slot-value first 'can-precede-list))))
 859     (update-class-can-precede-p (cdr cpl))))
 860
 861 (defun class-can-precede-p (class1 class2)
 862   (member class2 (class-can-precede-list class1)))
 863
 864 (defun update-slots (class eslotds)
 865   (let ((instance-slots ())
 866         (class-slots    ()))
 867     (dolist (eslotd eslotds)
 868       (let ((alloc (slot-definition-allocation eslotd)))
 869         (case alloc
 870           (:instance (push eslotd instance-slots))
 871           (:class (push eslotd class-slots)))))
 872
 873     ;; If there is a change in the shape of the instances then the
 874     ;; old class is now obsolete.
 875     (let* ((nlayout (mapcar #'slot-definition-name
 876                             (sort instance-slots #'<
 877                                   :key #'slot-definition-location)))
 878            (nslots (length nlayout))
 879            (nwrapper-class-slots (compute-class-slots class-slots))
 880            (owrapper (when (class-finalized-p class)
 881                        (class-wrapper class)))
 882            (olayout (when owrapper
 883                       (wrapper-instance-slots-layout owrapper)))
 884            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 885            (nwrapper
 886             (cond ((null owrapper)
 887                    (make-wrapper nslots class))
 888                   ((and (equal nlayout olayout)
 889                         (not
 890                          (loop for o in owrapper-class-slots
 891                                for n in nwrapper-class-slots
 892                                do (unless (eq (car o) (car n)) (return t)))))
 893                    owrapper)
 894                   (t
 895                    ;; This will initialize the new wrapper to have the
 896                    ;; same state as the old wrapper. We will then have
 897                    ;; to change that. This may seem like wasted work
 898                    ;; (and it is), but the spec requires that we call
 899                    ;; MAKE-INSTANCES-OBSOLETE.
 900                    (make-instances-obsolete class)
 901                    (class-wrapper class)))))
 902
 903       (with-slots (wrapper slots) class
 904         (update-lisp-class-layout class nwrapper)
 905         (setf slots eslotds
 906               (wrapper-instance-slots-layout nwrapper) nlayout
 907               (wrapper-class-slots nwrapper) nwrapper-class-slots
 908               (wrapper-no-of-instance-slots nwrapper) nslots
 909               wrapper nwrapper))
 910       (setf (slot-value class 'finalized-p) t)
 911       (unless (eq owrapper nwrapper)
 912         (update-pv-table-cache-info class)
 913         (maybe-update-standard-class-locations class)))))
 914
 915 (defun compute-class-slots (eslotds)
 916   (let (collect)
 917     (dolist (eslotd eslotds)
 918       (push (assoc (slot-definition-name eslotd)
 919                    (class-slot-cells (slot-definition-class eslotd)))
 920             collect))
 921     (nreverse collect)))
 922
 923 (defun update-gfs-of-class (class)
 924   (when (and (class-finalized-p class)
 925              (let ((cpl (class-precedence-list class)))
 926                (or (member *the-class-slot-class* cpl)
 927                    (member *the-class-standard-effective-slot-definition*
 928                            cpl))))
 929     (let ((gf-table (make-hash-table :test 'eq)))
 930       (labels ((collect-gfs (class)
 931                  (dolist (gf (specializer-direct-generic-functions class))
 932                    (setf (gethash gf gf-table) t))
 933                  (mapc #'collect-gfs (class-direct-superclasses class))))
 934         (collect-gfs class)
 935         (maphash (lambda (gf ignore)
 936                    (declare (ignore ignore))
 937                    (update-gf-dfun class gf))
 938                  gf-table)))))
 939
 940 (defun update-initargs (class inits)
 941   (setf (plist-value class 'default-initargs) inits))
 942 \f
 943 (defmethod compute-default-initargs ((class slot-class))
 944   (let ((initargs (loop for c in (class-precedence-list class)
 945                         append (class-direct-default-initargs c))))
 946     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
 947 \f
 948 ;;;; protocols for constructing direct and effective slot definitions
 949
 950 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
 951   (declare (ignore initargs))
 952   (find-class 'standard-direct-slot-definition))
 953
 954 (defun make-direct-slotd (class initargs)
 955   (apply #'make-instance
 956          (apply #'direct-slot-definition-class class initargs)
 957          :class class
 958          initargs))
 959
 960 ;;; I (CSR) am not sure, but I believe that the particular order of
 961 ;;; slots is quite important: it is ideal to attempt to have a
 962 ;;; constant slot location for the same notional slots as much as
 963 ;;; possible, so that clever discriminating functions (ONE-INDEX et
 964 ;;; al.) have a chance of working.  The below at least walks through
 965 ;;; the slots predictably, but maybe it would be good to compute some
 966 ;;; kind of optimal slot layout by looking at locations of slots in
 967 ;;; superclasses?
 968 (defun std-compute-slots (class)
 969   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
 970   ;; for each different slot name we find in our superclasses. Each
 971   ;; call receives the class and a list of the dslotds with that name.
 972   ;; The list is in most-specific-first order.
 973   (let ((name-dslotds-alist ()))
 974     (dolist (c (reverse (class-precedence-list class)))
 975       (dolist (slot (class-direct-slots c))
 976         (let* ((name (slot-definition-name slot))
 977                (entry (assq name name-dslotds-alist)))
 978           (if entry
 979               (push slot (cdr entry))
 980               (push (list name slot) name-dslotds-alist)))))
 981     (mapcar (lambda (direct)
 982               (compute-effective-slot-definition class
 983                                                  (car direct)
 984                                                  (cdr direct)))
 985             (nreverse name-dslotds-alist))))
 986
 987 (defmethod compute-slots ((class standard-class))
 988   (std-compute-slots class))
 989 (defmethod compute-slots ((class funcallable-standard-class))
 990   (std-compute-slots class))
 991
 992 (defun std-compute-slots-around (class eslotds)
 993   (let ((location -1))
 994     (dolist (eslotd eslotds eslotds)
 995       (setf (slot-definition-location eslotd)
 996             (case (slot-definition-allocation eslotd)
 997               (:instance
 998                (incf location))
 999               (:class
1000                (let* ((name (slot-definition-name eslotd))
1001                       (from-class
1002                        (or
1003                         (slot-definition-allocation-class eslotd)
1004                         ;; we get here if the user adds an extra slot
1005                         ;; himself...
1006                         (setf (slot-definition-allocation-class eslotd)
1007                               class)))
1008                       ;; which raises the question of what we should
1009                       ;; do if we find that said user has added a slot
1010                       ;; with the same name as another slot...
1011                       (cell (or (assq name (class-slot-cells from-class))
1012                                 (let ((c (cons name +slot-unbound+)))
1013                                   (push c (class-slot-cells from-class))
1014                                   c))))
1015                  (aver (consp cell))
1016                  (if (eq +slot-unbound+ (cdr cell))
1017                      ;; We may have inherited an initfunction
1018                      (let ((initfun (slot-definition-initfunction eslotd)))
1019                        (if initfun
1020                            (rplacd cell (funcall initfun))
1021                            cell))
1022                      cell)))))
1023       (unless (slot-definition-class eslotd)
1024         (setf (slot-definition-class eslotd) class))
1025       (initialize-internal-slot-functions eslotd))))
1026
1027 (defmethod compute-slots :around ((class standard-class))
1028   (let ((eslotds (call-next-method)))
1029     (std-compute-slots-around class eslotds)))
1030 (defmethod compute-slots :around ((class funcallable-standard-class))
1031   (let ((eslotds (call-next-method)))
1032     (std-compute-slots-around class eslotds)))
1033
1034 (defmethod compute-slots ((class structure-class))
1035   (mapcan (lambda (superclass)
1036             (mapcar (lambda (dslotd)
1037                       (compute-effective-slot-definition
1038                        class
1039                        (slot-definition-name dslotd)
1040                        (list dslotd)))
1041                     (class-direct-slots superclass)))
1042           (reverse (slot-value class '%class-precedence-list))))
1043
1044 (defmethod compute-slots :around ((class structure-class))
1045   (let ((eslotds (call-next-method)))
1046     (mapc #'initialize-internal-slot-functions eslotds)
1047     eslotds))
1048
1049 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1050   (declare (ignore name))
1051   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1052          (class (apply #'effective-slot-definition-class class initargs)))
1053     (apply #'make-instance class initargs)))
1054
1055 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1056   (declare (ignore initargs))
1057   (find-class 'standard-effective-slot-definition))
1058
1059 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1060   (declare (ignore initargs))
1061   (find-class 'structure-effective-slot-definition))
1062
1063 (defmethod compute-effective-slot-definition-initargs
1064     ((class slot-class) direct-slotds)
1065   (let* ((name nil)
1066          (initfunction nil)
1067          (initform nil)
1068          (initargs nil)
1069          (allocation nil)
1070          (allocation-class nil)
1071          (type t)
1072          (documentation nil)
1073          (documentationp nil)
1074          (namep  nil)
1075          (initp  nil)
1076          (allocp nil))
1077
1078     (dolist (slotd direct-slotds)
1079       (when slotd
1080         (unless namep
1081           (setq name (slot-definition-name slotd)
1082                 namep t))
1083         (unless initp
1084           (when (slot-definition-initfunction slotd)
1085             (setq initform (slot-definition-initform slotd)
1086                   initfunction (slot-definition-initfunction slotd)
1087                   initp t)))
1088         (unless documentationp
1089           (when (%slot-definition-documentation slotd)
1090             (setq documentation (%slot-definition-documentation slotd)
1091                   documentationp t)))
1092         (unless allocp
1093           (setq allocation (slot-definition-allocation slotd)
1094                 allocation-class (slot-definition-class slotd)
1095                 allocp t))
1096         (setq initargs (append (slot-definition-initargs slotd) initargs))
1097         (let ((slotd-type (slot-definition-type slotd)))
1098           (setq type (cond
1099                        ((eq type t) slotd-type)
1100                        ;; This pairwise type intersection is perhaps a
1101                        ;; little inefficient and inelegant, but it's
1102                        ;; unlikely to lie on the critical path.  Shout
1103                        ;; if I'm wrong.  -- CSR, 2005-11-24
1104                        (t (type-specifier
1105                            (specifier-type `(and ,type ,slotd-type)))))))))
1106     (list :name name
1107           :initform initform
1108           :initfunction initfunction
1109           :initargs initargs
1110           :allocation allocation
1111           :allocation-class allocation-class
1112           :type type
1113           :class class
1114           :documentation documentation)))
1115
1116 (defmethod compute-effective-slot-definition-initargs :around
1117     ((class structure-class) direct-slotds)
1118   (let ((slotd (car direct-slotds)))
1119     (list* :defstruct-accessor-symbol
1120            (slot-definition-defstruct-accessor-symbol slotd)
1121            :internal-reader-function
1122            (slot-definition-internal-reader-function slotd)
1123            :internal-writer-function
1124            (slot-definition-internal-writer-function slotd)
1125            (call-next-method))))
1126 \f
1127 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1128 ;;;       to make the method object. They have to use make-a-method which
1129 ;;;       is a specially bootstrapped mechanism for making standard methods.
1130 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1131   (declare (ignore direct-slot initargs))
1132   (find-class 'standard-reader-method))
1133
1134 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
1135   (add-method generic-function
1136               (make-a-method 'standard-reader-method
1137                              ()
1138                              (list (or (class-name class) 'object))
1139                              (list class)
1140                              (make-reader-method-function class slot-name)
1141                              "automatically generated reader method"
1142                              slot-name)))
1143
1144 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1145   (declare (ignore direct-slot initargs))
1146   (find-class 'standard-writer-method))
1147
1148 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
1149   (add-method generic-function
1150               (make-a-method 'standard-writer-method
1151                              ()
1152                              (list 'new-value (or (class-name class) 'object))
1153                              (list *the-class-t* class)
1154                              (make-writer-method-function class slot-name)
1155                              "automatically generated writer method"
1156                              slot-name)))
1157
1158 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
1159   (add-method generic-function
1160               (make-a-method 'standard-boundp-method
1161                              ()
1162                              (list (or (class-name class) 'object))
1163                              (list class)
1164                              (make-boundp-method-function class slot-name)
1165                              "automatically generated boundp method"
1166                              slot-name)))
1167
1168 (defmethod remove-reader-method ((class slot-class) generic-function)
1169   (let ((method (get-method generic-function () (list class) nil)))
1170     (when method (remove-method generic-function method))))
1171
1172 (defmethod remove-writer-method ((class slot-class) generic-function)
1173   (let ((method
1174           (get-method generic-function () (list *the-class-t* class) nil)))
1175     (when method (remove-method generic-function method))))
1176
1177 (defmethod remove-boundp-method ((class slot-class) generic-function)
1178   (let ((method (get-method generic-function () (list class) nil)))
1179     (when method (remove-method generic-function method))))
1180 \f
1181 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITE-METHOD function are NOT
1182 ;;; part of the standard protocol. They are however useful, PCL makes
1183 ;;; use of them internally and documents them for PCL users.
1184 ;;;
1185 ;;; *** This needs work to make type testing by the writer functions which
1186 ;;; *** do type testing faster. The idea would be to have one constructor
1187 ;;; *** for each possible type test.
1188 ;;;
1189 ;;; *** There is a subtle bug here which is going to have to be fixed.
1190 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1191 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1192 ;;; *** defined for this metaclass a chance to run.
1193
1194 (defmethod make-reader-method-function ((class slot-class) slot-name)
1195   (make-std-reader-method-function (class-name class) slot-name))
1196
1197 (defmethod make-writer-method-function ((class slot-class) slot-name)
1198   (make-std-writer-method-function (class-name class) slot-name))
1199
1200 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1201   (make-std-boundp-method-function (class-name class) slot-name))
1202 \f
1203 (defmethod compatible-meta-class-change-p (class proto-new-class)
1204   (eq (class-of class) (class-of proto-new-class)))
1205
1206 (defmethod validate-superclass ((class class) (superclass class))
1207   (or (eq superclass *the-class-t*)
1208       (eq (class-of class) (class-of superclass))
1209       (and (eq (class-of superclass) *the-class-standard-class*)
1210            (eq (class-of class) *the-class-funcallable-standard-class*))
1211       (and (eq (class-of superclass) *the-class-funcallable-standard-class*)
1212            (eq (class-of class) *the-class-standard-class*))))
1213 \f
1214 ;;; What this does depends on which of the four possible values of
1215 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1216 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1217 ;;; nothing to do, as the new wrapper has already been created.  If
1218 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1219 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1220 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1221 ;;;
1222 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1223 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1224 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1225 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1226 ;;; obsolete the wrapper.
1227 ;;;
1228 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1229 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1230 ;;;                    :UNINITIALIZED)))
1231 ;;;
1232 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1233 (defun force-cache-flushes (class)
1234   (let* ((owrapper (class-wrapper class)))
1235     ;; We only need to do something if the wrapper is still valid. If
1236     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1237     ;; both of those will already be doing what we want. In
1238     ;; particular, we must be sure we never change an OBSOLETE into a
1239     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1240     (when (or (not (invalid-wrapper-p owrapper))
1241               ;; KLUDGE: despite the observations above, this remains
1242               ;; a violation of locality or what might be considered
1243               ;; good style.  There has to be a better way!  -- CSR,
1244               ;; 2002-10-29
1245               (eq (layout-invalid owrapper) t))
1246       (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1247                                     class)))
1248         (setf (wrapper-instance-slots-layout nwrapper)
1249               (wrapper-instance-slots-layout owrapper))
1250         (setf (wrapper-class-slots nwrapper)
1251               (wrapper-class-slots owrapper))
1252         (with-pcl-lock
1253           (update-lisp-class-layout class nwrapper)
1254           (setf (slot-value class 'wrapper) nwrapper)
1255           ;; Use :OBSOLETE instead of :FLUSH if any superclass has
1256           ;; been obsoleted.
1257           (if (find-if (lambda (x)
1258                          (and (consp x) (eq :obsolete (car x))))
1259                        (layout-inherits owrapper)
1260                        :key #'layout-invalid)
1261               (invalidate-wrapper owrapper :obsolete nwrapper)
1262               (invalidate-wrapper owrapper :flush nwrapper)))))))
1263
1264 (defun flush-cache-trap (owrapper nwrapper instance)
1265   (declare (ignore owrapper))
1266   (set-wrapper instance nwrapper))
1267 \f
1268 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1269 ;;; the next access to the instance (as defined in 88-002R) to trap
1270 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1271 (defmethod make-instances-obsolete ((class std-class))
1272   (let* ((owrapper (class-wrapper class))
1273          (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1274                                  class)))
1275       (setf (wrapper-instance-slots-layout nwrapper)
1276             (wrapper-instance-slots-layout owrapper))
1277       (setf (wrapper-class-slots nwrapper)
1278             (wrapper-class-slots owrapper))
1279       (with-pcl-lock
1280         (update-lisp-class-layout class nwrapper)
1281         (setf (slot-value class 'wrapper) nwrapper)
1282         (invalidate-wrapper owrapper :obsolete nwrapper)
1283         class)))
1284
1285 (defmethod make-instances-obsolete ((class symbol))
1286   (make-instances-obsolete (find-class class))
1287   ;; ANSI wants the class name when called with a symbol.
1288   class)
1289
1290 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1291 ;;; see an obsolete instance. The times when it is called are:
1292 ;;;   - when the instance is involved in method lookup
1293 ;;;   - when attempting to access a slot of an instance
1294 ;;;
1295 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1296 ;;; instance access macros.
1297 ;;;
1298 ;;; Of course these times when it is called are an internal
1299 ;;; implementation detail of PCL and are not part of the documented
1300 ;;; description of when the obsolete instance update happens. The
1301 ;;; documented description is as it appears in 88-002R.
1302 ;;;
1303 ;;; This has to return the new wrapper, so it counts on all the
1304 ;;; methods on obsolete-instance-trap-internal to return the new
1305 ;;; wrapper. It also does a little internal error checking to make
1306 ;;; sure that the traps are only happening when they should, and that
1307 ;;; the trap methods are computing appropriate new wrappers.
1308
1309 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1310 ;;; after a structure is redefined. In most cases,
1311 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1312 ;;; so it must signal an error. The hard part of this is that the
1313 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1314 ;;; called again, so in that case, we have to return some reasonable
1315 ;;; wrapper, instead.
1316
1317 (defvar *in-obsolete-instance-trap* nil)
1318 (defvar *the-wrapper-of-structure-object*
1319   (class-wrapper (find-class 'structure-object)))
1320
1321 (define-condition obsolete-structure (error)
1322   ((datum :reader obsolete-structure-datum :initarg :datum))
1323   (:report
1324    (lambda (condition stream)
1325      ;; Don't try to print the structure, since it probably won't work.
1326      (format stream
1327              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1328              (type-of (obsolete-structure-datum condition))))))
1329
1330 (defun obsolete-instance-trap (owrapper nwrapper instance)
1331   (if (not (pcl-instance-p instance))
1332       (if *in-obsolete-instance-trap*
1333           *the-wrapper-of-structure-object*
1334            (let ((*in-obsolete-instance-trap* t))
1335              (error 'obsolete-structure :datum instance)))
1336       (let* ((class (wrapper-class* nwrapper))
1337              (copy (allocate-instance class)) ;??? allocate-instance ???
1338              (olayout (wrapper-instance-slots-layout owrapper))
1339              (nlayout (wrapper-instance-slots-layout nwrapper))
1340              (oslots (get-slots instance))
1341              (nslots (get-slots copy))
1342              (oclass-slots (wrapper-class-slots owrapper))
1343              (added ())
1344              (discarded ())
1345              (plist ()))
1346
1347         ;; local  --> local     transfer value
1348         ;; local  --> shared    discard value, discard slot
1349         ;; local  -->  --       discard slot
1350         ;; shared --> local     transfer value
1351         ;; shared --> shared    -- (cf SHARED-INITIALIZE :AFTER STD-CLASS)
1352         ;; shared -->  --       discard value
1353         ;;  --    --> local     add slot
1354         ;;  --    --> shared    --
1355
1356         ;; Collect class slots from inherited wrappers. Needed for
1357         ;; shared -> local transfers of inherited slots.
1358         (let ((inherited (layout-inherits owrapper)))
1359           (loop for i from (1- (length inherited)) downto 0
1360                 for layout = (aref inherited i)
1361                 when (typep layout 'wrapper)
1362                 do (dolist (slot (wrapper-class-slots layout))
1363                      (pushnew slot oclass-slots :key #'car))))
1364
1365         ;; Go through all the old local slots.
1366         (let ((opos 0))
1367           (dolist (name olayout)
1368             (let ((npos (posq name nlayout)))
1369               (if npos
1370                   (setf (clos-slots-ref nslots npos)
1371                         (clos-slots-ref oslots opos))
1372                   (progn
1373                     (push name discarded)
1374                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1375                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1376             (incf opos)))
1377
1378         ;; Go through all the old shared slots.
1379         (dolist (oclass-slot-and-val oclass-slots)
1380           (let ((name (car oclass-slot-and-val))
1381                 (val (cdr oclass-slot-and-val)))
1382             (let ((npos (posq name nlayout)))
1383               (when npos
1384                 (setf (clos-slots-ref nslots npos) val)))))
1385
1386         ;; Go through all the new local slots to compute the added slots.
1387         (dolist (nlocal nlayout)
1388           (unless (or (memq nlocal olayout)
1389                       (assq nlocal oclass-slots))
1390             (push nlocal added)))
1391
1392         (swap-wrappers-and-slots instance copy)
1393
1394         (update-instance-for-redefined-class instance
1395                                              added
1396                                              discarded
1397                                              plist)
1398         nwrapper)))
1399 \f
1400 (defun change-class-internal (instance new-class initargs)
1401   (let* ((old-class (class-of instance))
1402          (copy (allocate-instance new-class))
1403          (new-wrapper (get-wrapper copy))
1404          (old-wrapper (class-wrapper old-class))
1405          (old-layout (wrapper-instance-slots-layout old-wrapper))
1406          (new-layout (wrapper-instance-slots-layout new-wrapper))
1407          (old-slots (get-slots instance))
1408          (new-slots (get-slots copy))
1409          (old-class-slots (wrapper-class-slots old-wrapper)))
1410
1411     ;; "The values of local slots specified by both the class CTO and
1412     ;; CFROM are retained. If such a local slot was unbound, it
1413     ;; remains unbound."
1414     (let ((new-position 0))
1415       (dolist (new-slot new-layout)
1416         (let ((old-position (posq new-slot old-layout)))
1417           (when old-position
1418             (setf (clos-slots-ref new-slots new-position)
1419                   (clos-slots-ref old-slots old-position))))
1420         (incf new-position)))
1421
1422     ;; "The values of slots specified as shared in the class CFROM and
1423     ;; as local in the class CTO are retained."
1424     (dolist (slot-and-val old-class-slots)
1425       (let ((position (posq (car slot-and-val) new-layout)))
1426         (when position
1427           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1428
1429     ;; Make the copy point to the old instance's storage, and make the
1430     ;; old instance point to the new storage.
1431     (swap-wrappers-and-slots instance copy)
1432
1433     (apply #'update-instance-for-different-class copy instance initargs)
1434     instance))
1435
1436 (defmethod change-class ((instance standard-object) (new-class standard-class)
1437                          &rest initargs)
1438   (let ((cpl (class-precedence-list new-class)))
1439     (dolist (class cpl)
1440       (macrolet
1441           ((frob (class-name)
1442              `(when (eq class (find-class ',class-name))
1443                (error 'metaobject-initialization-violation
1444                 :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1445                 :format-arguments (list 'change-class ',class-name)
1446                 :references (list '(:amop :initialization ,class-name))))))
1447         (frob class)
1448         (frob generic-function)
1449         (frob method)
1450         (frob slot-definition))))
1451   (change-class-internal instance new-class initargs))
1452
1453 (defmethod change-class ((instance forward-referenced-class)
1454                          (new-class standard-class) &rest initargs)
1455   (let ((cpl (class-precedence-list new-class)))
1456     (dolist (class cpl
1457              (error 'metaobject-initialization-violation
1458                     :format-control
1459                     "~@<Cannot ~S ~S objects into non-~S objects.~@:>"
1460                     :format-arguments
1461                     (list 'change-class 'forward-referenced-class 'class)
1462                     :references
1463                     (list '(:amop :generic-function ensure-class-using-class)
1464                           '(:amop :initialization class))))
1465       (when (eq class (find-class 'class))
1466         (return nil))))
1467   (change-class-internal instance new-class initargs))
1468
1469 (defmethod change-class ((instance funcallable-standard-object)
1470                          (new-class funcallable-standard-class)
1471                          &rest initargs)
1472   (let ((cpl (class-precedence-list new-class)))
1473     (dolist (class cpl)
1474       (macrolet
1475           ((frob (class-name)
1476              `(when (eq class (find-class ',class-name))
1477                (error 'metaobject-initialization-violation
1478                 :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1479                 :format-arguments (list 'change-class ',class-name)
1480                 :references (list '(:amop :initialization ,class-name))))))
1481         (frob class)
1482         (frob generic-function)
1483         (frob method)
1484         (frob slot-definition))))
1485   (change-class-internal instance new-class initargs))
1486
1487 (defmethod change-class ((instance standard-object)
1488                          (new-class funcallable-standard-class)
1489                          &rest initargs)
1490   (declare (ignore initargs))
1491   (error "You can't change the class of ~S to ~S~@
1492           because it isn't already an instance with metaclass ~S."
1493          instance new-class 'standard-class))
1494
1495 (defmethod change-class ((instance funcallable-standard-object)
1496                          (new-class standard-class)
1497                          &rest initargs)
1498   (declare (ignore initargs))
1499   (error "You can't change the class of ~S to ~S~@
1500           because it isn't already an instance with metaclass ~S."
1501          instance new-class 'funcallable-standard-class))
1502
1503 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1504   (apply #'change-class instance (find-class new-class-name) initargs))
1505 \f
1506 ;;;; The metaclass BUILT-IN-CLASS
1507 ;;;;
1508 ;;;; This metaclass is something of a weird creature. By this point, all
1509 ;;;; instances of it which will exist have been created, and no instance
1510 ;;;; is ever created by calling MAKE-INSTANCE.
1511 ;;;;
1512 ;;;; But, there are other parts of the protocol we must follow and those
1513 ;;;; definitions appear here.
1514
1515 (macrolet ((def (name args control)
1516                `(defmethod ,name ,args
1517                  (declare (ignore initargs))
1518                  (error 'metaobject-initialization-violation
1519                   :format-control ,(format nil "~@<~A~@:>" control)
1520                   :format-arguments (list ',name)
1521                   :references (list '(:amop :initialization "Class"))))))
1522   (def initialize-instance ((class built-in-class) &rest initargs)
1523     "Cannot ~S an instance of BUILT-IN-CLASS.")
1524   (def reinitialize-instance ((class built-in-class) &rest initargs)
1525     "Cannot ~S an instance of BUILT-IN-CLASS."))
1526
1527 (macrolet ((def (name)
1528                `(defmethod ,name ((class built-in-class)) nil)))
1529   (def class-direct-slots)
1530   (def class-slots)
1531   (def class-direct-default-initargs)
1532   (def class-default-initargs))
1533
1534 (defmethod validate-superclass ((c class) (s built-in-class))
1535   (or (eq s *the-class-t*) (eq s *the-class-stream*)
1536       ;; FIXME: bad things happen if someone tries to mix in both
1537       ;; FILE-STREAM and STRING-STREAM (as they have the same
1538       ;; layout-depthoid).  Is there any way we can provide a useful
1539       ;; error message?  -- CSR, 2005-05-03
1540       (eq s *the-class-file-stream*) (eq s *the-class-string-stream*)))
1541 \f
1542 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1543 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1544 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1545 (macrolet ((def (method)
1546              `(defmethod ,method ((class forward-referenced-class))
1547                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1548                        ',method class))))
1549   (def class-default-initargs)
1550   (def class-precedence-list)
1551   (def class-slots))
1552
1553 (defmethod validate-superclass ((c slot-class)
1554                                 (f forward-referenced-class))
1555   t)
1556 \f
1557 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1558   (pushnew dependent (plist-value metaobject 'dependents)))
1559
1560 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1561   (setf (plist-value metaobject 'dependents)
1562         (delete dependent (plist-value metaobject 'dependents))))
1563
1564 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1565   (dolist (dependent (plist-value metaobject 'dependents))
1566     (funcall function dependent)))
1567