src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (ecase type
  28     (reader (slot-definition-reader-function slotd))
  29     (writer (slot-definition-writer-function slotd))
  30     (boundp (slot-definition-boundp-function slotd))))
  31
  32 (defmethod (setf slot-accessor-function) (function
  33                                           (slotd effective-slot-definition)
  34                                           type)
  35   (ecase type
  36     (reader (setf (slot-definition-reader-function slotd) function))
  37     (writer (setf (slot-definition-writer-function slotd) function))
  38     (boundp (setf (slot-definition-boundp-function slotd) function))))
  39
  40 (defconstant +slotd-reader-function-std-p+ 1)
  41 (defconstant +slotd-writer-function-std-p+ 2)
  42 (defconstant +slotd-boundp-function-std-p+ 4)
  43 (defconstant +slotd-all-function-std-p+ 7)
  44
  45 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  46   (let ((flags (slot-value slotd 'accessor-flags)))
  47     (declare (type fixnum flags))
  48     (if (eq type 'all)
  49         (eql +slotd-all-function-std-p+ flags)
  50         (let ((mask (ecase type
  51                       (reader +slotd-reader-function-std-p+)
  52                       (writer +slotd-writer-function-std-p+)
  53                       (boundp +slotd-boundp-function-std-p+))))
  54           (declare (type fixnum mask))
  55           (not (zerop (the fixnum (logand mask flags))))))))
  56
  57 (defmethod (setf slot-accessor-std-p) (value
  58                                        (slotd effective-slot-definition)
  59                                        type)
  60   (let ((mask (ecase type
  61                 (reader +slotd-reader-function-std-p+)
  62                 (writer +slotd-writer-function-std-p+)
  63                 (boundp +slotd-boundp-function-std-p+)))
  64         (flags (slot-value slotd 'accessor-flags)))
  65     (declare (type fixnum mask flags))
  66     (setf (slot-value slotd 'accessor-flags)
  67           (if value
  68               (the fixnum (logior mask flags))
  69               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  70   value)
  71
  72 (defmethod initialize-internal-slot-functions ((slotd
  73                                                 effective-slot-definition))
  74   (let* ((name (slot-value slotd 'name))
  75          (class (slot-value slotd '%class)))
  76     (dolist (type '(reader writer boundp))
  77       (let* ((gf-name (ecase type
  78                               (reader 'slot-value-using-class)
  79                               (writer '(setf slot-value-using-class))
  80                               (boundp 'slot-boundp-using-class)))
  81              (gf (gdefinition gf-name)))
  82         (compute-slot-accessor-info slotd type gf)))))
  83
  84 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
  85 ;;;
  86 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
  87 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
  88 ;;; writing/testing effective slot SLOTD.
  89 ;;;
  90 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
  91 ;;; GF.  Store the effective method in the effective slot definition
  92 ;;; object itself; these GFs have special dispatch functions calling
  93 ;;; effective methods directly retrieved from effective slot
  94 ;;; definition objects, as an optimization.
  95 ;;;
  96 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
  97 ;;; or some such.
  98 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
  99                                        type gf)
 100   (let* ((name (slot-value slotd 'name))
 101          (class (slot-value slotd '%class))
 102          (old-slotd (when (class-finalized-p class)
 103                       (find-slot-definition class name)))
 104          (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
 105     (multiple-value-bind (function std-p)
 106         (if (eq *boot-state* 'complete)
 107             (get-accessor-method-function gf type class slotd)
 108             (get-optimized-std-accessor-method-function class slotd type))
 109       (setf (slot-accessor-std-p slotd type) std-p)
 110       (setf (slot-accessor-function slotd type) function))))
 111
 112 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 113   :instance)
 114 \f
 115 ;;;; various class accessors that are a little more complicated than can be
 116 ;;;; done with automatically generated reader methods
 117
 118 (defmethod class-prototype :before (class)
 119   (unless (class-finalized-p class)
 120     (error "~@<~S is not finalized.~:@>" class)))
 121
 122 ;;; KLUDGE: For some reason factoring the common body into a function
 123 ;;; breaks PCL bootstrapping, so just generate it with a macrolet for
 124 ;;; all.
 125 (macrolet ((def (class)
 126              `(defmethod class-prototype ((class ,class))
 127                 (with-slots (prototype) class
 128                   (or prototype
 129                       (setf prototype (allocate-instance class)))))))
 130   (def std-class)
 131   (def condition-class)
 132   (def structure-class))
 133
 134 (defmethod class-direct-default-initargs ((class slot-class))
 135   (plist-value class 'direct-default-initargs))
 136
 137 (defmethod class-default-initargs ((class slot-class))
 138   (plist-value class 'default-initargs))
 139
 140 (defmethod class-slot-cells ((class std-class))
 141   (plist-value class 'class-slot-cells))
 142 (defmethod (setf class-slot-cells) (new-value (class std-class))
 143   (setf (plist-value class 'class-slot-cells) new-value))
 144 \f
 145 ;;;; class accessors that are even a little bit more complicated than those
 146 ;;;; above. These have a protocol for updating them, we must implement that
 147 ;;;; protocol.
 148
 149 ;;; Maintaining the direct subclasses backpointers. The update methods are
 150 ;;; here, the values are read by an automatically generated reader method.
 151 (defmethod add-direct-subclass ((class class) (subclass class))
 152   (with-slots (direct-subclasses) class
 153     (pushnew subclass direct-subclasses :test #'eq)
 154     subclass))
 155 (defmethod remove-direct-subclass ((class class) (subclass class))
 156   (with-slots (direct-subclasses) class
 157     (setq direct-subclasses (remove subclass direct-subclasses))
 158     subclass))
 159
 160 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 161 ;;;
 162 ;;; There are four generic functions involved, each has one method for the
 163 ;;; class case and another method for the damned EQL specializers. All of
 164 ;;; these are specified methods and appear in their specified place in the
 165 ;;; class graph.
 166 ;;;
 167 ;;;   ADD-DIRECT-METHOD
 168 ;;;   REMOVE-DIRECT-METHOD
 169 ;;;   SPECIALIZER-DIRECT-METHODS
 170 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 171 ;;;
 172 ;;; In each case, we maintain one value which is a cons. The car is the list
 173 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 174 ;;; computed lazily.
 175
 176 ;;; This needs to be used recursively, in case a non-trivial user
 177 ;;; defined ADD/REMOVE-DIRECT-METHOD method ends up calling another
 178 ;;; function using the same lock.
 179 (defvar *specializer-lock* (sb-thread::make-spinlock :name "Specializer lock"))
 180
 181 (defmethod add-direct-method :around ((specializer specializer) method)
 182   ;; All the actions done under this lock are done in an order
 183   ;; that is safe to unwind at any point.
 184   (sb-thread::with-recursive-spinlock (*specializer-lock*)
 185     (call-next-method)))
 186
 187 (defmethod remove-direct-method :around ((specializer specializer) method)
 188   ;; All the actions done under this lock are done in an order
 189   ;; that is safe to unwind at any point.
 190   (sb-thread::with-recursive-spinlock (*specializer-lock*)
 191     (call-next-method)))
 192
 193 (defmethod add-direct-method ((specializer class) (method method))
 194   (let ((cell (slot-value specializer 'direct-methods)))
 195     ;; We need to first smash the CDR, because a parallel read may
 196     ;; be in progress, and because if an interrupt catches us we
 197     ;; need to have a consistent state.
 198     (setf (cdr cell) ()
 199           (car cell) (adjoin method (car cell) :test #'eq)))
 200   method)
 201
 202 (defmethod remove-direct-method ((specializer class) (method method))
 203   (let ((cell (slot-value specializer 'direct-methods)))
 204     ;; We need to first smash the CDR, because a parallel read may
 205     ;; be in progress, and because if an interrupt catches us we
 206     ;; need to have a consistent state.
 207     (setf (cdr cell) ()
 208           (car cell) (remove method (car cell))))
 209   method)
 210
 211 (defmethod specializer-direct-methods ((specializer class))
 212   (with-slots (direct-methods) specializer
 213     (car direct-methods)))
 214
 215 (defmethod specializer-direct-generic-functions ((specializer class))
 216   (let ((cell (slot-value specializer 'direct-methods)))
 217     ;; If an ADD/REMOVE-METHOD is in progress, no matter: either
 218     ;; we behave as if we got just first or just after -- it's just
 219     ;; for update that we need to lock.
 220     (or (cdr cell)
 221         (sb-thread::with-spinlock (*specializer-lock*)
 222           (setf (cdr cell)
 223                 (let (collect)
 224                   (dolist (m (car cell))
 225                     ;; the old PCL code used COLLECTING-ONCE which used
 226                     ;; #'EQ to check for newness
 227                     (pushnew (method-generic-function m) collect :test #'eq))
 228                   (nreverse collect)))))))
 229 \f
 230 ;;; This hash table is used to store the direct methods and direct generic
 231 ;;; functions of EQL specializers. Each value in the table is the cons.
 232 ;;;
 233 ;;; These tables are shared between threads, so they need to be synchronized.
 234 (defvar *eql-specializer-methods* (make-hash-table :test 'eql :synchronized t))
 235 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq :synchronized t))
 236
 237 (defmethod specializer-method-table ((specializer eql-specializer))
 238   *eql-specializer-methods*)
 239
 240 (defmethod specializer-method-table ((specializer class-eq-specializer))
 241   *class-eq-specializer-methods*)
 242
 243 (defmethod add-direct-method ((specializer specializer-with-object)
 244                               (method method))
 245   (let* ((object (specializer-object specializer))
 246          (table (specializer-method-table specializer))
 247          (entry (gethash object table)))
 248     (unless entry
 249       (setf entry
 250             (setf (gethash object table) (cons nil nil))))
 251     ;; We need to first smash the CDR, because a parallel read may
 252     ;; be in progress, and because if an interrupt catches us we
 253     ;; need to have a consistent state.
 254     (setf (cdr entry) ()
 255           (car entry) (adjoin method (car entry) :test #'eq))
 256     method))
 257
 258 (defmethod remove-direct-method ((specializer specializer-with-object)
 259                                  (method method))
 260   (let* ((object (specializer-object specializer))
 261          (entry (gethash object (specializer-method-table specializer))))
 262     (when entry
 263       ;; We need to first smash the CDR, because a parallel read may
 264       ;; be in progress, and because if an interrupt catches us we
 265       ;; need to have a consistent state.
 266       (setf (cdr entry) ()
 267             (car entry) (remove method (car entry))))
 268     method))
 269
 270 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 271   (car (gethash (specializer-object specializer)
 272                 (specializer-method-table specializer))))
 273
 274 (defmethod specializer-direct-generic-functions ((specializer
 275                                                   specializer-with-object))
 276   (let* ((object (specializer-object specializer))
 277          (entry (gethash object (specializer-method-table specializer))))
 278     (when entry
 279       (or (cdr entry)
 280           (sb-thread::with-spinlock (*specializer-lock*)
 281             (setf (cdr entry)
 282                   (let (collect)
 283                     (dolist (m (car entry))
 284                       (pushnew (method-generic-function m) collect :test #'eq))
 285                     (nreverse collect))))))))
 286
 287 (defun map-specializers (function)
 288   (map-all-classes (lambda (class)
 289                      (funcall function (class-eq-specializer class))
 290                      (funcall function class)))
 291   (maphash (lambda (object methods)
 292              (declare (ignore methods))
 293              (intern-eql-specializer object))
 294            *eql-specializer-methods*)
 295   (maphash (lambda (object specl)
 296              (declare (ignore object))
 297              (funcall function specl))
 298            *eql-specializer-table*)
 299   nil)
 300
 301 (defun map-all-generic-functions (function)
 302   (let ((all-generic-functions (make-hash-table :test 'eq)))
 303     (map-specializers (lambda (specl)
 304                         (dolist (gf (specializer-direct-generic-functions
 305                                      specl))
 306                           (unless (gethash gf all-generic-functions)
 307                             (setf (gethash gf all-generic-functions) t)
 308                             (funcall function gf))))))
 309   nil)
 310
 311 (defmethod shared-initialize :after ((specl class-eq-specializer)
 312                                      slot-names
 313                                      &key)
 314   (declare (ignore slot-names))
 315   (setf (slot-value specl '%type) `(class-eq ,(specializer-class specl))))
 316
 317 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 318   (declare (ignore slot-names))
 319   (setf (slot-value specl '%type)
 320         `(eql ,(specializer-object specl)))
 321   (setf (info :type :translator specl)
 322         (constantly (make-member-type :members (list (specializer-object specl))))))
 323
 324 (defun real-load-defclass (name metaclass-name supers slots other
 325                            readers writers slot-names source-location safe-p)
 326   (with-single-package-locked-error (:symbol name "defining ~S as a class")
 327     (%compiler-defclass name readers writers slot-names)
 328     (let ((res (apply #'ensure-class name :metaclass metaclass-name
 329                       :direct-superclasses supers
 330                       :direct-slots slots
 331                       :definition-source source-location
 332                       'safe-p safe-p
 333                       other)))
 334       res)))
 335
 336 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 337
 338 (defun ensure-class (name &rest args)
 339   (with-world-lock ()
 340     (apply #'ensure-class-using-class
 341            (let ((class (find-class name nil)))
 342              (when (and class (eq name (class-name class)))
 343                ;; NAME is the proper name of CLASS, so redefine it
 344                class))
 345            name
 346            args)))
 347
 348 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 349   (with-world-lock ()
 350     (multiple-value-bind (meta initargs)
 351         (frob-ensure-class-args args)
 352       (setf class (apply #'make-instance meta :name name initargs))
 353       (without-package-locks
 354         (setf (find-class name) class))))
 355   ;; After boot (SETF FIND-CLASS) does this.
 356   (unless (eq *boot-state* 'complete)
 357     (%set-class-type-translation class name))
 358   class)
 359
 360 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 361   (with-world-lock ()
 362     (multiple-value-bind (meta initargs)
 363         (frob-ensure-class-args args)
 364       (unless (eq (class-of class) meta)
 365         (apply #'change-class class meta initargs))
 366       (apply #'reinitialize-instance class initargs)
 367       (without-package-locks
 368         (setf (find-class name) class))))
 369   ;; After boot (SETF FIND-CLASS) does this.
 370   (unless (eq *boot-state* 'complete)
 371     (%set-class-type-translation class name))
 372   class)
 373
 374 (defun frob-ensure-class-args (args)
 375   (let (metaclass metaclassp reversed-plist)
 376     (flet ((frob-superclass (s)
 377              (cond
 378                ((classp s) s)
 379                ((legal-class-name-p s)
 380                 (or (find-class s nil)
 381                     (ensure-class s :metaclass 'forward-referenced-class)))
 382                (t (error "Not a class or a legal class name: ~S." s)))))
 383       (doplist (key val) args
 384         (cond ((eq key :metaclass)
 385                (unless metaclassp
 386                  (setf metaclass val metaclassp key)))
 387               (t
 388                (when (eq key :direct-superclasses)
 389                  (setf val (mapcar #'frob-superclass val)))
 390                (setf reversed-plist (list* val key reversed-plist)))))
 391       (values (cond (metaclassp
 392                      (if (classp metaclass)
 393                          metaclass
 394                          (find-class metaclass)))
 395                     (t *the-class-standard-class*))
 396               (nreverse reversed-plist)))))
 397
 398 (defun call-initfun (fun slotd safe)
 399   (declare (function fun))
 400   (let ((value (funcall fun)))
 401     (when safe
 402       (let ((typecheck (slot-definition-type-check-function slotd)))
 403         (when typecheck
 404           (funcall (the function typecheck) value))))
 405     value))
 406 \f
 407 (defmethod shared-initialize :after
 408     ((class std-class) slot-names &key
 409      (direct-superclasses nil direct-superclasses-p)
 410      (direct-slots nil direct-slots-p)
 411      (direct-default-initargs nil direct-default-initargs-p)
 412      definition-source)
 413   (cond (direct-superclasses-p
 414          (setq direct-superclasses
 415                (or direct-superclasses
 416                    (list (if (funcallable-standard-class-p class)
 417                              *the-class-funcallable-standard-object*
 418                              *the-class-standard-object*))))
 419          (dolist (superclass direct-superclasses)
 420            (unless (validate-superclass class superclass)
 421              (error "~@<The class ~S was specified as a ~
 422                      super-class of the class ~S, ~
 423                      but the meta-classes ~S and ~S are incompatible.  ~
 424                      Define a method for ~S to avoid this error.~@:>"
 425                     superclass class (class-of superclass) (class-of class)
 426                     'validate-superclass)))
 427          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 428         (t
 429          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 430   (setq direct-slots
 431         (if direct-slots-p
 432             (setf (slot-value class 'direct-slots)
 433                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 434                           direct-slots))
 435             (slot-value class 'direct-slots)))
 436   (if direct-default-initargs-p
 437       (setf (plist-value class 'direct-default-initargs)
 438             direct-default-initargs)
 439       (setq direct-default-initargs
 440             (plist-value class 'direct-default-initargs)))
 441   (setf (plist-value class 'class-slot-cells)
 442         (let ((old-class-slot-cells (plist-value class 'class-slot-cells))
 443               (safe (safe-p class))
 444               (collect '()))
 445           (dolist (dslotd direct-slots)
 446             (when (eq :class (slot-definition-allocation dslotd))
 447               ;; see CLHS 4.3.6
 448               (let* ((name (slot-definition-name dslotd))
 449                      (old (assoc name old-class-slot-cells)))
 450                 (if (or (not old)
 451                         (eq t slot-names)
 452                         (member name slot-names :test #'eq))
 453                     (let* ((initfunction (slot-definition-initfunction dslotd))
 454                            (value
 455                             (if initfunction
 456                                 (call-initfun initfunction dslotd safe)
 457                                 +slot-unbound+)))
 458                       (push (cons name value) collect))
 459                     (push old collect)))))
 460           (nreverse collect)))
 461   (add-direct-subclasses class direct-superclasses)
 462   (if (class-finalized-p class)
 463       ;; required by AMOP, "Reinitialization of Class Metaobjects"
 464       (finalize-inheritance class)
 465       (update-class class nil))
 466   (add-slot-accessors class direct-slots definition-source)
 467   (make-preliminary-layout class))
 468
 469 (defmethod shared-initialize :after ((class forward-referenced-class)
 470                                      slot-names &key &allow-other-keys)
 471   (declare (ignore slot-names))
 472   (make-preliminary-layout class))
 473
 474 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 475
 476 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 477 ;;; make it known to the type system.
 478 (defun make-preliminary-layout (class)
 479   (flet ((compute-preliminary-cpl (root)
 480            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 481              (compute-class-precedence-list root))))
 482     (with-world-lock ()
 483       (without-package-locks
 484         (unless (class-finalized-p class)
 485           (let ((name (class-name class)))
 486             ;; KLUDGE: This is fairly horrible.  We need to make a
 487             ;; full-fledged CLASSOID here, not just tell the compiler that
 488             ;; some class is forthcoming, because there are legitimate
 489             ;; questions one can ask of the type system, implemented in
 490             ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 491             (let ((layout (make-wrapper 0 class)))
 492               (setf (slot-value class 'wrapper) layout)
 493               (let ((cpl (compute-preliminary-cpl class)))
 494                 (setf (layout-inherits layout)
 495                       (order-layout-inherits
 496                        (map 'simple-vector #'class-wrapper
 497                             (reverse (rest cpl))))))
 498               (register-layout layout :invalidate t)
 499               (%set-class-type-translation class (layout-classoid layout)))))
 500         (mapc #'make-preliminary-layout (class-direct-subclasses class))))))
 501
 502
 503 (defmethod shared-initialize :before ((class class) slot-names &key name)
 504   (declare (ignore slot-names name))
 505   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 506   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 507   (setf (slot-value class '%type) `(class ,class))
 508   (setf (slot-value class 'class-eq-specializer)
 509         (make-instance 'class-eq-specializer :class class)))
 510
 511 (defmethod reinitialize-instance :before ((class slot-class) &key direct-superclasses)
 512   (dolist (old-super (set-difference (class-direct-superclasses class) direct-superclasses))
 513     (remove-direct-subclass old-super class))
 514   (remove-slot-accessors    class (class-direct-slots class)))
 515
 516 (defmethod reinitialize-instance :after ((class slot-class)
 517                                          &rest initargs
 518                                          &key)
 519   (map-dependents class
 520                   (lambda (dependent)
 521                     (apply #'update-dependent class dependent initargs))))
 522
 523 (defmethod reinitialize-instance :after ((class condition-class) &key)
 524   (let* ((name (class-name class))
 525          (classoid (find-classoid name))
 526          (slots (condition-classoid-slots classoid)))
 527     ;; to balance the REMOVE-SLOT-ACCESSORS call in
 528     ;; REINITIALIZE-INSTANCE :BEFORE (SLOT-CLASS).
 529     (dolist (slot slots)
 530       (let ((slot-name (condition-slot-name slot)))
 531         (dolist (reader (condition-slot-readers slot))
 532           ;; FIXME: see comment in SHARED-INITIALIZE :AFTER
 533           ;; (CONDITION-CLASS T), below.  -- CSR, 2005-11-18
 534           (sb-kernel::install-condition-slot-reader reader name slot-name))
 535         (dolist (writer (condition-slot-writers slot))
 536           (sb-kernel::install-condition-slot-writer writer name slot-name))))))
 537
 538 (defmethod shared-initialize :after ((class condition-class) slot-names
 539                                      &key direct-slots direct-superclasses)
 540   (declare (ignore slot-names))
 541   (let ((classoid (find-classoid (slot-value class 'name))))
 542     (with-slots (wrapper %class-precedence-list cpl-available-p
 543                          prototype (direct-supers direct-superclasses))
 544         class
 545       (setf (slot-value class 'direct-slots)
 546             (mapcar (lambda (pl) (make-direct-slotd class pl))
 547                     direct-slots))
 548       (setf (slot-value class 'finalized-p) t)
 549       (setf (classoid-pcl-class classoid) class)
 550       (setq direct-supers direct-superclasses)
 551       (setq wrapper (classoid-layout classoid))
 552       (setq %class-precedence-list (compute-class-precedence-list class))
 553       (setq cpl-available-p t)
 554       (add-direct-subclasses class direct-superclasses)
 555       (let ((slots (compute-slots class)))
 556         (setf (slot-value class 'slots) slots)
 557         (setf (layout-slot-table wrapper) (make-slot-table class slots)))))
 558   ;; Comment from Gerd's PCL, 2003-05-15:
 559   ;;
 560   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 561   ;; override condition accessors with generic functions.  We do this
 562   ;; differently.
 563   ;;
 564   ;; ??? What does the above comment mean and why is it a good idea?
 565   ;; CMUCL (which still as of 2005-11-18 uses this code and has this
 566   ;; comment) loses slot information in its condition classes:
 567   ;; DIRECT-SLOTS is always NIL.  We have the right information, so we
 568   ;; remove slot accessors but never put them back.  I've added a
 569   ;; REINITIALIZE-INSTANCE :AFTER (CONDITION-CLASS) method, but what
 570   ;; was meant to happen?  -- CSR, 2005-11-18
 571   )
 572
 573 (defmethod direct-slot-definition-class ((class condition-class)
 574                                          &rest initargs)
 575   (declare (ignore initargs))
 576   (find-class 'condition-direct-slot-definition))
 577
 578 (defmethod effective-slot-definition-class ((class condition-class)
 579                                             &rest initargs)
 580   (declare (ignore initargs))
 581   (find-class 'condition-effective-slot-definition))
 582
 583 (defmethod finalize-inheritance ((class condition-class))
 584   (aver (slot-value class 'finalized-p))
 585   nil)
 586
 587 (defmethod compute-effective-slot-definition
 588     ((class condition-class) slot-name dslotds)
 589   (let ((slotd (call-next-method)))
 590     (setf (slot-definition-reader-function slotd)
 591           (lambda (x)
 592             (handler-case (condition-reader-function x slot-name)
 593               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 594               ;; is unbound; maybe it should be a CELL-ERROR of some
 595               ;; sort?
 596               (error () (values (slot-unbound class x slot-name))))))
 597     (setf (slot-definition-writer-function slotd)
 598           (lambda (v x)
 599             (condition-writer-function x v slot-name)))
 600     (setf (slot-definition-boundp-function slotd)
 601           (lambda (x)
 602             (multiple-value-bind (v c)
 603                 (ignore-errors (condition-reader-function x slot-name))
 604               (declare (ignore v))
 605               (null c))))
 606     slotd))
 607
 608 (defmethod compute-slots ((class condition-class))
 609   (mapcan (lambda (superclass)
 610             (mapcar (lambda (dslotd)
 611                       (compute-effective-slot-definition
 612                        class (slot-definition-name dslotd) (list dslotd)))
 613                     (class-direct-slots superclass)))
 614           (reverse (slot-value class '%class-precedence-list))))
 615
 616 (defmethod compute-slots :around ((class condition-class))
 617   (let ((eslotds (call-next-method)))
 618     (mapc #'initialize-internal-slot-functions eslotds)
 619     eslotds))
 620
 621 (defmethod shared-initialize :after
 622     ((slotd structure-slot-definition) slot-names &key
 623      (allocation :instance) allocation-class)
 624   (declare (ignore slot-names allocation-class))
 625   (unless (eq allocation :instance)
 626     (error "Structure slots must have :INSTANCE allocation.")))
 627
 628 (defun make-structure-class-defstruct-form (name direct-slots include)
 629   (let* ((conc-name (format-symbol *package* "~S structure class " name))
 630          (constructor (format-symbol *package* "~Aconstructor" conc-name))
 631          (defstruct `(defstruct (,name
 632                                  ,@(when include
 633                                          `((:include ,(class-name include))))
 634                                  (:predicate nil)
 635                                  (:conc-name ,conc-name)
 636                                  (:constructor ,constructor ())
 637                                  (:copier nil))
 638                       ,@(mapcar (lambda (slot)
 639                                   `(,(slot-definition-name slot)
 640                                     +slot-unbound+))
 641                                 direct-slots)))
 642          (reader-names (mapcar (lambda (slotd)
 643                                  (list 'slot-accessor name
 644                                        (slot-definition-name slotd)
 645                                        'reader))
 646                                direct-slots))
 647          (writer-names (mapcar (lambda (slotd)
 648                                  (list 'slot-accessor name
 649                                        (slot-definition-name slotd)
 650                                        'writer))
 651                                direct-slots))
 652          (readers-init
 653            (mapcar (lambda (slotd reader-name)
 654                      (let ((accessor
 655                              (slot-definition-defstruct-accessor-symbol
 656                               slotd)))
 657                        `(defun ,reader-name (obj)
 658                          (declare (type ,name obj))
 659                          (,accessor obj))))
 660                    direct-slots reader-names))
 661          (writers-init
 662            (mapcar (lambda (slotd writer-name)
 663                      (let ((accessor
 664                              (slot-definition-defstruct-accessor-symbol
 665                               slotd)))
 666                        `(defun ,writer-name (nv obj)
 667                          (declare (type ,name obj))
 668                          (setf (,accessor obj) nv))))
 669                    direct-slots writer-names))
 670          (defstruct-form
 671              `(progn
 672                ,defstruct
 673                ,@readers-init ,@writers-init
 674                (cons nil nil))))
 675     (values defstruct-form constructor reader-names writer-names)))
 676
 677 (defun make-defstruct-allocation-function (name)
 678   ;; FIXME: Why don't we go class->layout->info == dd
 679   (let ((dd (find-defstruct-description name)))
 680     (ecase (dd-type dd)
 681       (structure
 682        (%make-structure-instance-allocator dd nil))
 683       (funcallable-structure
 684        (%make-funcallable-structure-instance-allocator dd nil)))))
 685
 686 (defmethod shared-initialize :after
 687     ((class structure-class) slot-names &key
 688      (direct-superclasses nil direct-superclasses-p)
 689      (direct-slots nil direct-slots-p)
 690      direct-default-initargs
 691      definition-source)
 692   (declare (ignore slot-names direct-default-initargs))
 693   (if direct-superclasses-p
 694       (setf (slot-value class 'direct-superclasses)
 695             (or direct-superclasses
 696                 (setq direct-superclasses
 697                       (and (not (eq (slot-value class 'name) 'structure-object))
 698                            (list *the-class-structure-object*)))))
 699       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 700   (let* ((name (slot-value class 'name))
 701          (from-defclass-p (slot-value class 'from-defclass-p))
 702          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 703     (if direct-slots-p
 704         (setf (slot-value class 'direct-slots)
 705               (setq direct-slots
 706                     (mapcar (lambda (pl)
 707                               (when defstruct-p
 708                                 (let* ((slot-name (getf pl :name))
 709                                        (accessor
 710                                         (format-symbol *package*
 711                                                        "~S structure class ~A"
 712                                                        name slot-name)))
 713                                   (setq pl (list* :defstruct-accessor-symbol
 714                                                   accessor pl))))
 715                               (make-direct-slotd class pl))
 716                             direct-slots)))
 717         (setq direct-slots (slot-value class 'direct-slots)))
 718     (if defstruct-p
 719         (let ((include (car (slot-value class 'direct-superclasses))))
 720           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 721               (make-structure-class-defstruct-form name direct-slots include)
 722             (unless (structure-type-p name) (eval defstruct-form))
 723             (mapc (lambda (dslotd reader-name writer-name)
 724                     (let* ((reader (gdefinition reader-name))
 725                            (writer (when (fboundp writer-name)
 726                                      (gdefinition writer-name))))
 727                       (setf (slot-value dslotd 'internal-reader-function)
 728                             reader)
 729                       (setf (slot-value dslotd 'internal-writer-function)
 730                             writer)))
 731                   direct-slots reader-names writer-names)
 732             (setf (slot-value class 'defstruct-form) defstruct-form)
 733             (setf (slot-value class 'defstruct-constructor) constructor)))
 734         (setf (slot-value class 'defstruct-constructor)
 735               ;; KLUDGE: not class; in fixup.lisp, can't access slots
 736               ;; outside methods yet.
 737               (make-defstruct-allocation-function name)))
 738     (add-direct-subclasses class direct-superclasses)
 739     (setf (slot-value class '%class-precedence-list)
 740           (compute-class-precedence-list class))
 741     (setf (slot-value class 'cpl-available-p) t)
 742     (let ((slots (compute-slots class)))
 743       (setf (slot-value class 'slots) slots)
 744       (let* ((lclass (find-classoid (slot-value class 'name)))
 745              (layout (classoid-layout lclass)))
 746         (setf (classoid-pcl-class lclass) class)
 747         (setf (slot-value class 'wrapper) layout)
 748         (setf (layout-slot-table layout) (make-slot-table class slots))))
 749     (setf (slot-value class 'finalized-p) t)
 750     (add-slot-accessors class direct-slots definition-source)))
 751
 752 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 753   (declare (ignore initargs))
 754   (find-class 'structure-direct-slot-definition))
 755
 756 (defmethod finalize-inheritance ((class structure-class))
 757   nil) ; always finalized
 758 \f
 759 (defun add-slot-accessors (class dslotds &optional source-location)
 760   (fix-slot-accessors class dslotds 'add source-location))
 761
 762 (defun remove-slot-accessors (class dslotds)
 763   (fix-slot-accessors class dslotds 'remove))
 764
 765 (defun fix-slot-accessors (class dslotds add/remove &optional source-location)
 766   (flet ((fix (gfspec name r/w doc)
 767            (let ((gf (cond ((eq add/remove 'add)
 768                             (or (find-generic-function gfspec nil)
 769                                 (ensure-generic-function
 770                                  gfspec :lambda-list (case r/w
 771                                                        (r '(object))
 772                                                        (w '(new-value object))))))
 773                            (t
 774                             (find-generic-function gfspec nil)))))
 775              (when gf
 776                (case r/w
 777                  (r (if (eq add/remove 'add)
 778                         (add-reader-method class gf name doc source-location)
 779                         (remove-reader-method class gf)))
 780                  (w (if (eq add/remove 'add)
 781                         (add-writer-method class gf name doc source-location)
 782                         (remove-writer-method class gf))))))))
 783     (dolist (dslotd dslotds)
 784       (let ((slot-name (slot-definition-name dslotd))
 785             (slot-doc (%slot-definition-documentation dslotd)))
 786         (dolist (r (slot-definition-readers dslotd))
 787           (fix r slot-name 'r slot-doc))
 788         (dolist (w (slot-definition-writers dslotd))
 789           (fix w slot-name 'w slot-doc))))))
 790 \f
 791 (defun add-direct-subclasses (class supers)
 792   (dolist (super supers)
 793     (unless (memq class (class-direct-subclasses class))
 794       (add-direct-subclass super class))))
 795
 796 (defmethod finalize-inheritance ((class std-class))
 797   (update-class class t))
 798
 799 (defmethod finalize-inheritance ((class forward-referenced-class))
 800   ;; FIXME: should we not be thinking a bit about what kinds of error
 801   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 802   ;; possibly a forward-referenced-class-error, though that's
 803   ;; difficult given e.g. class precedence list calculations...
 804   (error
 805    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 806        ~2I~_~S~:>"
 807    class))
 808
 809 \f
 810 (defun class-has-a-forward-referenced-superclass-p (class)
 811   (or (forward-referenced-class-p class)
 812       (some #'class-has-a-forward-referenced-superclass-p
 813             (class-direct-superclasses class))))
 814
 815 ;;; This is called by :after shared-initialize whenever a class is initialized
 816 ;;; or reinitialized. The class may or may not be finalized.
 817 (defun update-class (class finalizep)
 818   (without-package-locks
 819     (with-world-lock ()
 820       (when (or finalizep (class-finalized-p class))
 821         (%update-cpl class (compute-class-precedence-list class))
 822         ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 823         ;; class.
 824         (%update-slots class (compute-slots class))
 825         (update-gfs-of-class class)
 826         (setf (plist-value class 'default-initargs) (compute-default-initargs class))
 827         (update-ctors 'finalize-inheritance :class class))
 828       (dolist (sub (class-direct-subclasses class))
 829         (update-class sub nil)))))
 830
 831 (define-condition cpl-protocol-violation (reference-condition error)
 832   ((class :initarg :class :reader cpl-protocol-violation-class)
 833    (cpl :initarg :cpl :reader cpl-protocol-violation-cpl))
 834   (:default-initargs :references (list '(:sbcl :node "Metaobject Protocol")))
 835   (:report
 836    (lambda (c s)
 837      (format s "~@<Protocol violation: the ~S class ~S ~
 838                 ~:[has~;does not have~] the class ~S in its ~
 839                 class precedence list: ~S.~@:>"
 840              (class-name (class-of (cpl-protocol-violation-class c)))
 841              (cpl-protocol-violation-class c)
 842              (eq (class-of (cpl-protocol-violation-class c))
 843                  *the-class-funcallable-standard-class*)
 844              (find-class 'function)
 845              (cpl-protocol-violation-cpl c)))))
 846
 847 (defun %update-cpl (class cpl)
 848   (when (eq (class-of class) *the-class-standard-class*)
 849     (when (find (find-class 'function) cpl)
 850       (error 'cpl-protocol-violation :class class :cpl cpl)))
 851   (when (eq (class-of class) *the-class-funcallable-standard-class*)
 852     (unless (find (find-class 'function) cpl)
 853       (error 'cpl-protocol-violation :class class :cpl cpl)))
 854   (if (class-finalized-p class)
 855       (unless (and (equal (class-precedence-list class) cpl)
 856                    (dolist (c cpl t)
 857                      (when (position :class (class-direct-slots c)
 858                                      :key #'slot-definition-allocation)
 859                        (return nil))))
 860         ;; comment from the old CMU CL sources:
 861         ;;   Need to have the cpl setup before %update-lisp-class-layout
 862         ;;   is called on CMU CL.
 863         (setf (slot-value class '%class-precedence-list) cpl)
 864         (setf (slot-value class 'cpl-available-p) t)
 865         (%force-cache-flushes class))
 866       (progn
 867         (setf (slot-value class '%class-precedence-list) cpl)
 868         (setf (slot-value class 'cpl-available-p) t)))
 869   (update-class-can-precede-p cpl))
 870
 871 (defun update-class-can-precede-p (cpl)
 872   (when cpl
 873     (let ((first (car cpl)))
 874       (dolist (c (cdr cpl))
 875         (pushnew c (slot-value first 'can-precede-list) :test #'eq)))
 876     (update-class-can-precede-p (cdr cpl))))
 877
 878 (defun class-can-precede-p (class1 class2)
 879   (member class2 (class-can-precede-list class1) :test #'eq))
 880
 881 (defun %update-slots (class eslotds)
 882   (let ((instance-slots ())
 883         (class-slots    ()))
 884     (dolist (eslotd eslotds)
 885       (let ((alloc (slot-definition-allocation eslotd)))
 886         (case alloc
 887           (:instance (push eslotd instance-slots))
 888           (:class (push eslotd class-slots)))))
 889
 890     ;; If there is a change in the shape of the instances then the
 891     ;; old class is now obsolete.
 892     (let* ((nlayout (mapcar #'slot-definition-name
 893                             (sort instance-slots #'<
 894                                   :key #'slot-definition-location)))
 895            (nslots (length nlayout))
 896            (nwrapper-class-slots (compute-class-slots class-slots))
 897            (owrapper (when (class-finalized-p class)
 898                        (class-wrapper class)))
 899            (olayout (when owrapper
 900                       (wrapper-instance-slots-layout owrapper)))
 901            (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
 902            (nwrapper
 903             (cond ((null owrapper)
 904                    (make-wrapper nslots class))
 905                   ((and (equal nlayout olayout)
 906                         (not
 907                          (loop for o in owrapper-class-slots
 908                                for n in nwrapper-class-slots
 909                                do (unless (eq (car o) (car n)) (return t)))))
 910                    owrapper)
 911                   (t
 912                    ;; This will initialize the new wrapper to have the
 913                    ;; same state as the old wrapper. We will then have
 914                    ;; to change that. This may seem like wasted work
 915                    ;; (and it is), but the spec requires that we call
 916                    ;; MAKE-INSTANCES-OBSOLETE.
 917                    (make-instances-obsolete class)
 918                    (class-wrapper class)))))
 919
 920       (%update-lisp-class-layout class nwrapper)
 921       (setf (slot-value class 'slots) eslotds
 922             (wrapper-slot-table nwrapper) (make-slot-table class eslotds)
 923             (wrapper-instance-slots-layout nwrapper) nlayout
 924             (wrapper-class-slots nwrapper) nwrapper-class-slots
 925             (wrapper-length nwrapper) nslots
 926             (slot-value class 'wrapper) nwrapper)
 927       (do* ((slots (slot-value class 'slots) (cdr slots))
 928             (dupes nil))
 929            ((null slots)
 930             (when dupes
 931               (style-warn
 932                "~@<slot names with the same SYMBOL-NAME but ~
 933                   different SYMBOL-PACKAGE (possible package problem) ~
 934                   for class ~S:~4I~@:_~<~@{~S~^~:@_~}~:>~@:>"
 935                class dupes)))
 936         (let* ((slot (car slots))
 937                (oslots (remove (slot-definition-name slot) (cdr slots)
 938                                :test #'string/=
 939                                :key #'slot-definition-name)))
 940           (when oslots
 941             (pushnew (cons (slot-definition-name slot)
 942                            (mapcar #'slot-definition-name oslots))
 943                      dupes
 944                      :test #'string= :key #'car))))
 945       (setf (slot-value class 'finalized-p) t)
 946       (unless (eq owrapper nwrapper)
 947         (maybe-update-standard-slot-locations class)))))
 948
 949 (defun compute-class-slots (eslotds)
 950   (let (collect)
 951     (dolist (eslotd eslotds (nreverse collect))
 952       (let ((cell (assoc (slot-definition-name eslotd)
 953                          (class-slot-cells
 954                           (slot-definition-allocation-class eslotd)))))
 955         (aver cell)
 956         (push cell collect)))))
 957
 958 (defun update-gf-dfun (class gf)
 959   (let ((*new-class* class)
 960         (arg-info (gf-arg-info gf)))
 961     (cond
 962       ((special-case-for-compute-discriminating-function-p gf))
 963       ((gf-precompute-dfun-and-emf-p arg-info)
 964        (multiple-value-bind (dfun cache info) (make-final-dfun-internal gf)
 965          (update-dfun gf dfun cache info))))))
 966
 967 (defun update-gfs-of-class (class)
 968   (when (and (class-finalized-p class)
 969              (let ((cpl (class-precedence-list class)))
 970                (or (member *the-class-slot-class* cpl :test #'eq)
 971                    (member *the-class-standard-effective-slot-definition*
 972                            cpl :test #'eq))))
 973     (let ((gf-table (make-hash-table :test 'eq)))
 974       (labels ((collect-gfs (class)
 975                  (dolist (gf (specializer-direct-generic-functions class))
 976                    (setf (gethash gf gf-table) t))
 977                  (mapc #'collect-gfs (class-direct-superclasses class))))
 978         (collect-gfs class)
 979         (maphash (lambda (gf ignore)
 980                    (declare (ignore ignore))
 981                    (update-gf-dfun class gf))
 982                  gf-table)))))
 983 \f
 984 (defmethod compute-default-initargs ((class slot-class))
 985   (let ((initargs (loop for c in (class-precedence-list class)
 986                         append (class-direct-default-initargs c))))
 987     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
 988 \f
 989 ;;;; protocols for constructing direct and effective slot definitions
 990
 991 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
 992   (declare (ignore initargs))
 993   (find-class 'standard-direct-slot-definition))
 994
 995 (defun make-direct-slotd (class initargs)
 996   (apply #'make-instance
 997          (apply #'direct-slot-definition-class class initargs)
 998          :class class
 999          initargs))
1000
1001 ;;; I (CSR) am not sure, but I believe that the particular order of
1002 ;;; slots is quite important: it is ideal to attempt to have a
1003 ;;; constant slot location for the same notional slots as much as
1004 ;;; possible, so that clever discriminating functions (ONE-INDEX et
1005 ;;; al.) have a chance of working.  The below at least walks through
1006 ;;; the slots predictably, but maybe it would be good to compute some
1007 ;;; kind of optimal slot layout by looking at locations of slots in
1008 ;;; superclasses?
1009 (defun std-compute-slots (class)
1010   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
1011   ;; for each different slot name we find in our superclasses. Each
1012   ;; call receives the class and a list of the dslotds with that name.
1013   ;; The list is in most-specific-first order.
1014   (let ((name-dslotds-alist ()))
1015     (dolist (c (reverse (class-precedence-list class)))
1016       (dolist (slot (class-direct-slots c))
1017         (let* ((name (slot-definition-name slot))
1018                (entry (assq name name-dslotds-alist)))
1019           (if entry
1020               (push slot (cdr entry))
1021               (push (list name slot) name-dslotds-alist)))))
1022     (mapcar (lambda (direct)
1023               (compute-effective-slot-definition class
1024                                                  (car direct)
1025                                                  (cdr direct)))
1026             (nreverse name-dslotds-alist))))
1027
1028 (defmethod compute-slots ((class standard-class))
1029   (std-compute-slots class))
1030 (defmethod compute-slots ((class funcallable-standard-class))
1031   (std-compute-slots class))
1032
1033 (defun std-compute-slots-around (class eslotds)
1034   (let ((location -1)
1035         (safe (safe-p class)))
1036     (dolist (eslotd eslotds eslotds)
1037       (setf (slot-definition-location eslotd)
1038             (case (slot-definition-allocation eslotd)
1039               (:instance
1040                (incf location))
1041               (:class
1042                (let* ((name (slot-definition-name eslotd))
1043                       (from-class
1044                        (or
1045                         (slot-definition-allocation-class eslotd)
1046                         ;; we get here if the user adds an extra slot
1047                         ;; himself...
1048                         (setf (slot-definition-allocation-class eslotd)
1049                               class)))
1050                       ;; which raises the question of what we should
1051                       ;; do if we find that said user has added a slot
1052                       ;; with the same name as another slot...
1053                       (cell (or (assq name (class-slot-cells from-class))
1054                                 (let ((c (cons name +slot-unbound+)))
1055                                   (push c (class-slot-cells from-class))
1056                                   c))))
1057                  (aver (consp cell))
1058                  (if (eq +slot-unbound+ (cdr cell))
1059                      ;; We may have inherited an initfunction FIXME: Is this
1060                      ;; really right? Is the initialization in
1061                      ;; SHARED-INITIALIZE (STD-CLASS) not enough?
1062                      (let ((initfun (slot-definition-initfunction eslotd)))
1063                        (if initfun
1064                            (rplacd cell (call-initfun initfun eslotd safe))
1065                            cell))
1066                      cell)))))
1067       (unless (slot-definition-class eslotd)
1068         (setf (slot-definition-class eslotd) class))
1069       (initialize-internal-slot-functions eslotd))))
1070
1071 (defmethod compute-slots :around ((class standard-class))
1072   (let ((eslotds (call-next-method)))
1073     (std-compute-slots-around class eslotds)))
1074 (defmethod compute-slots :around ((class funcallable-standard-class))
1075   (let ((eslotds (call-next-method)))
1076     (std-compute-slots-around class eslotds)))
1077
1078 (defmethod compute-slots ((class structure-class))
1079   (mapcan (lambda (superclass)
1080             (mapcar (lambda (dslotd)
1081                       (compute-effective-slot-definition
1082                        class
1083                        (slot-definition-name dslotd)
1084                        (list dslotd)))
1085                     (class-direct-slots superclass)))
1086           (reverse (slot-value class '%class-precedence-list))))
1087
1088 (defmethod compute-slots :around ((class structure-class))
1089   (let ((eslotds (call-next-method)))
1090     (mapc #'initialize-internal-slot-functions eslotds)
1091     eslotds))
1092
1093 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1094   (declare (ignore name))
1095   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1096          (class (apply #'effective-slot-definition-class class initargs)))
1097     (apply #'make-instance class initargs)))
1098
1099 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1100   (declare (ignore initargs))
1101   (find-class 'standard-effective-slot-definition))
1102
1103 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1104   (declare (ignore initargs))
1105   (find-class 'structure-effective-slot-definition))
1106
1107 (defmethod compute-effective-slot-definition-initargs
1108     ((class slot-class) direct-slotds)
1109   (let* ((name nil)
1110          (initfunction nil)
1111          (initform nil)
1112          (initargs nil)
1113          (allocation nil)
1114          (allocation-class nil)
1115          (type t)
1116          (type-check-function nil)
1117          (documentation nil)
1118          (documentationp nil)
1119          (namep  nil)
1120          (initp  nil)
1121          (allocp nil))
1122
1123     (dolist (slotd direct-slotds)
1124       (when slotd
1125         (unless namep
1126           (setq name (slot-definition-name slotd)
1127                 namep t))
1128         (unless initp
1129           (awhen (slot-definition-initfunction slotd)
1130             (setq initform (slot-definition-initform slotd)
1131                   initfunction it
1132                   initp t)))
1133         (unless documentationp
1134           (awhen (%slot-definition-documentation slotd)
1135             (setq documentation it
1136                   documentationp t)))
1137         (unless allocp
1138           (setq allocation (slot-definition-allocation slotd)
1139                 allocation-class (slot-definition-class slotd)
1140                 allocp t))
1141         (setq initargs (append (slot-definition-initargs slotd) initargs))
1142         (let ((fun (slot-definition-type-check-function slotd)))
1143           (when fun
1144             (setf type-check-function
1145                   (if type-check-function
1146                       (let ((old-function type-check-function))
1147                         (declare (function old-function fun))
1148                         (lambda (value)
1149                           (funcall old-function value)
1150                           (funcall fun value)))
1151                       fun))))
1152         (let ((slotd-type (slot-definition-type slotd)))
1153           (setq type (cond
1154                        ((eq type t) slotd-type)
1155                        ;; This pairwise type intersection is perhaps a
1156                        ;; little inefficient and inelegant, but it's
1157                        ;; unlikely to lie on the critical path.  Shout
1158                        ;; if I'm wrong.  -- CSR, 2005-11-24
1159                        (t (type-specifier
1160                            (specifier-type `(and ,type ,slotd-type)))))))))
1161     (list :name name
1162           :initform initform
1163           :initfunction initfunction
1164           :initargs initargs
1165           :allocation allocation
1166           :allocation-class allocation-class
1167           :type type
1168           'type-check-function type-check-function
1169           :class class
1170           :documentation documentation)))
1171
1172 (defmethod compute-effective-slot-definition-initargs :around
1173     ((class structure-class) direct-slotds)
1174   (let ((slotd (car direct-slotds)))
1175     (list* :defstruct-accessor-symbol
1176            (slot-definition-defstruct-accessor-symbol slotd)
1177            :internal-reader-function
1178            (slot-definition-internal-reader-function slotd)
1179            :internal-writer-function
1180            (slot-definition-internal-writer-function slotd)
1181            (call-next-method))))
1182 \f
1183 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1184 ;;;       to make the method object. They have to use make-a-method which
1185 ;;;       is a specially bootstrapped mechanism for making standard methods.
1186 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1187   (declare (ignore direct-slot initargs))
1188   (find-class 'standard-reader-method))
1189
1190 (defmethod add-reader-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1191   (add-method generic-function
1192               (make-a-method 'standard-reader-method
1193                              ()
1194                              (list (or (class-name class) 'object))
1195                              (list class)
1196                              (make-reader-method-function class slot-name)
1197                              (or slot-documentation "automatically generated reader method")
1198                              :slot-name slot-name
1199                              :object-class class
1200                              :method-class-function #'reader-method-class
1201                              :definition-source source-location)))
1202
1203 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1204   (declare (ignore direct-slot initargs))
1205   (find-class 'standard-writer-method))
1206
1207 (defmethod add-writer-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1208   (add-method generic-function
1209               (make-a-method 'standard-writer-method
1210                              ()
1211                              (list 'new-value (or (class-name class) 'object))
1212                              (list *the-class-t* class)
1213                              (make-writer-method-function class slot-name)
1214                              (or slot-documentation "automatically generated writer method")
1215                              :slot-name slot-name
1216                              :object-class class
1217                              :method-class-function #'writer-method-class
1218                              :definition-source source-location)))
1219
1220 (defmethod add-boundp-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1221   (add-method generic-function
1222               (make-a-method (constantly (find-class 'standard-boundp-method))
1223                              class
1224                              ()
1225                              (list (or (class-name class) 'object))
1226                              (list class)
1227                              (make-boundp-method-function class slot-name)
1228                              (or slot-documentation "automatically generated boundp method")
1229                              :slot-name slot-name
1230                              :definition-source source-location)))
1231
1232 (defmethod remove-reader-method ((class slot-class) generic-function)
1233   (let ((method (get-method generic-function () (list class) nil)))
1234     (when method (remove-method generic-function method))))
1235
1236 (defmethod remove-writer-method ((class slot-class) generic-function)
1237   (let ((method
1238           (get-method generic-function () (list *the-class-t* class) nil)))
1239     (when method (remove-method generic-function method))))
1240
1241 (defmethod remove-boundp-method ((class slot-class) generic-function)
1242   (let ((method (get-method generic-function () (list class) nil)))
1243     (when method (remove-method generic-function method))))
1244 \f
1245 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITER-METHOD-FUNCTION
1246 ;;; function are NOT part of the standard protocol. They are however
1247 ;;; useful; PCL makes use of them internally and documents them for
1248 ;;; PCL users.  (FIXME: but SBCL certainly doesn't)
1249 ;;;
1250 ;;; *** This needs work to make type testing by the writer functions which
1251 ;;; *** do type testing faster. The idea would be to have one constructor
1252 ;;; *** for each possible type test.
1253 ;;;
1254 ;;; *** There is a subtle bug here which is going to have to be fixed.
1255 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1256 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1257 ;;; *** defined for this metaclass a chance to run.
1258
1259 (defmethod make-reader-method-function ((class slot-class) slot-name)
1260   (make-std-reader-method-function class slot-name))
1261
1262 (defmethod make-writer-method-function ((class slot-class) slot-name)
1263   (make-std-writer-method-function class slot-name))
1264
1265 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1266   (make-std-boundp-method-function class slot-name))
1267 \f
1268 (defmethod compatible-meta-class-change-p (class proto-new-class)
1269   (eq (class-of class) (class-of proto-new-class)))
1270
1271 (defmethod validate-superclass ((class class) (superclass class))
1272   (or (eq superclass *the-class-t*)
1273       (eq (class-of class) (class-of superclass))
1274       (and (eq (class-of superclass) *the-class-standard-class*)
1275            (eq (class-of class) *the-class-funcallable-standard-class*))
1276       (and (eq (class-of superclass) *the-class-funcallable-standard-class*)
1277            (eq (class-of class) *the-class-standard-class*))))
1278 \f
1279 ;;; What this does depends on which of the four possible values of
1280 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1281 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1282 ;;; nothing to do, as the new wrapper has already been created.  If
1283 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1284 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1285 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1286 ;;;
1287 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1288 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1289 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1290 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1291 ;;; obsolete the wrapper.
1292 ;;;
1293 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1294 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1295 ;;;                    :UNINITIALIZED)))
1296 ;;;
1297 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1298 (defun %force-cache-flushes (class)
1299   (let* ((owrapper (class-wrapper class)))
1300     ;; We only need to do something if the wrapper is still valid. If
1301     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1302     ;; both of those will already be doing what we want. In
1303     ;; particular, we must be sure we never change an OBSOLETE into a
1304     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1305     (when (or (not (invalid-wrapper-p owrapper))
1306               ;; KLUDGE: despite the observations above, this remains
1307               ;; a violation of locality or what might be considered
1308               ;; good style.  There has to be a better way!  -- CSR,
1309               ;; 2002-10-29
1310               (eq (layout-invalid owrapper) t))
1311       (let ((nwrapper (make-wrapper (layout-length owrapper)
1312                                     class)))
1313         (setf (wrapper-instance-slots-layout nwrapper)
1314               (wrapper-instance-slots-layout owrapper))
1315         (setf (wrapper-class-slots nwrapper)
1316               (wrapper-class-slots owrapper))
1317         (setf (wrapper-slot-table nwrapper)
1318               (wrapper-slot-table owrapper))
1319         (%update-lisp-class-layout class nwrapper)
1320         (setf (slot-value class 'wrapper) nwrapper)
1321         ;; Use :OBSOLETE instead of :FLUSH if any superclass has
1322         ;; been obsoleted.
1323         (if (find-if (lambda (x)
1324                        (and (consp x) (eq :obsolete (car x))))
1325                      (layout-inherits owrapper)
1326                      :key #'layout-invalid)
1327             (%invalidate-wrapper owrapper :obsolete nwrapper)
1328             (%invalidate-wrapper owrapper :flush nwrapper))))))
1329 \f
1330 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1331 ;;; the next access to the instance (as defined in 88-002R) to trap
1332 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1333 (defmethod make-instances-obsolete ((class std-class))
1334   (with-world-lock ()
1335     (let* ((owrapper (class-wrapper class))
1336            (nwrapper (make-wrapper (layout-length owrapper)
1337                                    class)))
1338       (unless (class-finalized-p class)
1339         (if (class-has-a-forward-referenced-superclass-p class)
1340             (return-from make-instances-obsolete class)
1341             (%update-cpl class (compute-class-precedence-list class))))
1342       (setf (wrapper-instance-slots-layout nwrapper)
1343             (wrapper-instance-slots-layout owrapper))
1344       (setf (wrapper-class-slots nwrapper)
1345             (wrapper-class-slots owrapper))
1346       (setf (wrapper-slot-table nwrapper)
1347             (wrapper-slot-table owrapper))
1348       (%update-lisp-class-layout class nwrapper)
1349       (setf (slot-value class 'wrapper) nwrapper)
1350       (%invalidate-wrapper owrapper :obsolete nwrapper)
1351       class)))
1352
1353 (defmethod make-instances-obsolete ((class symbol))
1354   (make-instances-obsolete (find-class class))
1355   ;; ANSI wants the class name when called with a symbol.
1356   class)
1357
1358 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1359 ;;; see an obsolete instance. The times when it is called are:
1360 ;;;   - when the instance is involved in method lookup
1361 ;;;   - when attempting to access a slot of an instance
1362 ;;;
1363 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1364 ;;; instance access macros.
1365 ;;;
1366 ;;; Of course these times when it is called are an internal
1367 ;;; implementation detail of PCL and are not part of the documented
1368 ;;; description of when the obsolete instance update happens. The
1369 ;;; documented description is as it appears in 88-002R.
1370 ;;;
1371 ;;; This has to return the new wrapper, so it counts on all the
1372 ;;; methods on obsolete-instance-trap-internal to return the new
1373 ;;; wrapper. It also does a little internal error checking to make
1374 ;;; sure that the traps are only happening when they should, and that
1375 ;;; the trap methods are computing appropriate new wrappers.
1376
1377 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1378 ;;; after a structure is redefined. In most cases,
1379 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1380 ;;; so it must signal an error. The hard part of this is that the
1381 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1382 ;;; called again, so in that case, we have to return some reasonable
1383 ;;; wrapper, instead.
1384
1385 (defvar *in-obsolete-instance-trap* nil)
1386 (defvar *the-wrapper-of-structure-object*
1387   (class-wrapper (find-class 'structure-object)))
1388
1389 (define-condition obsolete-structure (error)
1390   ((datum :reader obsolete-structure-datum :initarg :datum))
1391   (:report
1392    (lambda (condition stream)
1393      ;; Don't try to print the structure, since it probably won't work.
1394      (format stream
1395              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1396              (type-of (obsolete-structure-datum condition))))))
1397
1398 (defun %obsolete-instance-trap (owrapper nwrapper instance)
1399   (if (not (layout-for-std-class-p owrapper))
1400       (if *in-obsolete-instance-trap*
1401           *the-wrapper-of-structure-object*
1402           (let ((*in-obsolete-instance-trap* t))
1403             (error 'obsolete-structure :datum instance)))
1404       (let* ((class (wrapper-class* nwrapper))
1405              (copy (allocate-instance class)) ;??? allocate-instance ???
1406              (olayout (wrapper-instance-slots-layout owrapper))
1407              (nlayout (wrapper-instance-slots-layout nwrapper))
1408              (oslots (get-slots instance))
1409              (nslots (get-slots copy))
1410              (oclass-slots (wrapper-class-slots owrapper))
1411              (added ())
1412              (discarded ())
1413              (plist ()))
1414
1415         ;; local  --> local     transfer value
1416         ;; local  --> shared    discard value, discard slot
1417         ;; local  -->  --       discard slot
1418         ;; shared --> local     transfer value
1419         ;; shared --> shared    -- (cf SHARED-INITIALIZE :AFTER STD-CLASS)
1420         ;; shared -->  --       discard value
1421         ;;  --    --> local     add slot
1422         ;;  --    --> shared    --
1423
1424         ;; Go through all the old local slots.
1425         (let ((opos 0))
1426           (dolist (name olayout)
1427             (let ((npos (posq name nlayout)))
1428               (if npos
1429                   (setf (clos-slots-ref nslots npos)
1430                         (clos-slots-ref oslots opos))
1431                   (progn
1432                     (push name discarded)
1433                     (unless (eq (clos-slots-ref oslots opos) +slot-unbound+)
1434                       (setf (getf plist name) (clos-slots-ref oslots opos))))))
1435             (incf opos)))
1436
1437         ;; Go through all the old shared slots.
1438         (dolist (oclass-slot-and-val oclass-slots)
1439           (let ((name (car oclass-slot-and-val))
1440                 (val (cdr oclass-slot-and-val)))
1441             (let ((npos (posq name nlayout)))
1442               (when npos
1443                 (setf (clos-slots-ref nslots npos) val)))))
1444
1445         ;; Go through all the new local slots to compute the added slots.
1446         (dolist (nlocal nlayout)
1447           (unless (or (memq nlocal olayout)
1448                       (assq nlocal oclass-slots))
1449             (push nlocal added)))
1450
1451         (%swap-wrappers-and-slots instance copy)
1452
1453         (update-instance-for-redefined-class instance
1454                                              added
1455                                              discarded
1456                                              plist)
1457         nwrapper)))
1458 \f
1459 (defun %change-class (instance new-class initargs)
1460   (let* ((old-class (class-of instance))
1461          (copy (allocate-instance new-class))
1462          (new-wrapper (get-wrapper copy))
1463          (old-wrapper (class-wrapper old-class))
1464          (old-layout (wrapper-instance-slots-layout old-wrapper))
1465          (new-layout (wrapper-instance-slots-layout new-wrapper))
1466          (old-slots (get-slots instance))
1467          (new-slots (get-slots copy))
1468          (old-class-slots (wrapper-class-slots old-wrapper)))
1469
1470     ;; "The values of local slots specified by both the class CTO and
1471     ;; CFROM are retained. If such a local slot was unbound, it
1472     ;; remains unbound."
1473     (let ((new-position 0))
1474       (dolist (new-slot new-layout)
1475         (let ((old-position (posq new-slot old-layout)))
1476           (when old-position
1477             (setf (clos-slots-ref new-slots new-position)
1478                   (clos-slots-ref old-slots old-position))))
1479         (incf new-position)))
1480
1481     ;; "The values of slots specified as shared in the class CFROM and
1482     ;; as local in the class CTO are retained."
1483     (dolist (slot-and-val old-class-slots)
1484       (let ((position (posq (car slot-and-val) new-layout)))
1485         (when position
1486           (setf (clos-slots-ref new-slots position) (cdr slot-and-val)))))
1487
1488     ;; Make the copy point to the old instance's storage, and make the
1489     ;; old instance point to the new storage.
1490     (%swap-wrappers-and-slots instance copy)
1491
1492     (apply #'update-instance-for-different-class copy instance initargs)
1493
1494     instance))
1495
1496 (defmethod change-class ((instance standard-object) (new-class standard-class)
1497                          &rest initargs)
1498   (with-world-lock ()
1499     (unless (class-finalized-p new-class)
1500       (finalize-inheritance new-class))
1501     (let ((cpl (class-precedence-list new-class)))
1502       (dolist (class cpl)
1503         (macrolet
1504             ((frob (class-name)
1505                `(when (eq class (find-class ',class-name))
1506                   (error 'metaobject-initialization-violation
1507                          :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1508                          :format-arguments (list 'change-class ',class-name)
1509                          :references (list '(:amop :initialization ,class-name))))))
1510           (frob class)
1511           (frob generic-function)
1512           (frob method)
1513           (frob slot-definition))))
1514     (%change-class instance new-class initargs)))
1515
1516 (defmethod change-class ((instance forward-referenced-class)
1517                          (new-class standard-class) &rest initargs)
1518   (with-world-lock ()
1519     (let ((cpl (class-precedence-list new-class)))
1520       (dolist (class cpl
1521                (error 'metaobject-initialization-violation
1522                       :format-control
1523                       "~@<Cannot ~S ~S objects into non-~S objects.~@:>"
1524                       :format-arguments
1525                       (list 'change-class 'forward-referenced-class 'class)
1526                       :references
1527                       (list '(:amop :generic-function ensure-class-using-class)
1528                             '(:amop :initialization class))))
1529         (when (eq class (find-class 'class))
1530           (return nil))))
1531     (%change-class instance new-class initargs)))
1532
1533 (defmethod change-class ((instance funcallable-standard-object)
1534                          (new-class funcallable-standard-class)
1535                          &rest initargs)
1536   (with-world-lock ()
1537     (let ((cpl (class-precedence-list new-class)))
1538       (dolist (class cpl)
1539         (macrolet
1540             ((frob (class-name)
1541                `(when (eq class (find-class ',class-name))
1542                   (error 'metaobject-initialization-violation
1543                          :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1544                          :format-arguments (list 'change-class ',class-name)
1545                          :references (list '(:amop :initialization ,class-name))))))
1546           (frob class)
1547           (frob generic-function)
1548           (frob method)
1549           (frob slot-definition))))
1550     (%change-class instance new-class initargs)))
1551
1552 (defmethod change-class ((instance standard-object)
1553                          (new-class funcallable-standard-class)
1554                          &rest initargs)
1555   (declare (ignore initargs))
1556   (error "You can't change the class of ~S to ~S~@
1557           because it isn't already an instance with metaclass ~S."
1558          instance new-class 'standard-class))
1559
1560 (defmethod change-class ((instance funcallable-standard-object)
1561                          (new-class standard-class)
1562                          &rest initargs)
1563   (declare (ignore initargs))
1564   (error "You can't change the class of ~S to ~S~@
1565           because it isn't already an instance with metaclass ~S."
1566          instance new-class 'funcallable-standard-class))
1567
1568 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1569   (apply #'change-class instance (find-class new-class-name) initargs))
1570 \f
1571 ;;;; The metaclass BUILT-IN-CLASS
1572 ;;;;
1573 ;;;; This metaclass is something of a weird creature. By this point, all
1574 ;;;; instances of it which will exist have been created, and no instance
1575 ;;;; is ever created by calling MAKE-INSTANCE.
1576 ;;;;
1577 ;;;; But, there are other parts of the protocol we must follow and those
1578 ;;;; definitions appear here.
1579
1580 (macrolet ((def (name args control)
1581                `(defmethod ,name ,args
1582                  (declare (ignore initargs))
1583                  (error 'metaobject-initialization-violation
1584                   :format-control ,(format nil "~@<~A~@:>" control)
1585                   :format-arguments (list ',name)
1586                   :references (list '(:amop :initialization "Class"))))))
1587   (def initialize-instance ((class built-in-class) &rest initargs)
1588     "Cannot ~S an instance of BUILT-IN-CLASS.")
1589   (def reinitialize-instance ((class built-in-class) &rest initargs)
1590     "Cannot ~S an instance of BUILT-IN-CLASS."))
1591
1592 (macrolet ((def (name)
1593                `(defmethod ,name ((class built-in-class)) nil)))
1594   (def class-direct-slots)
1595   (def class-slots)
1596   (def class-direct-default-initargs)
1597   (def class-default-initargs))
1598
1599 (defmethod validate-superclass ((c class) (s built-in-class))
1600   (or (eq s *the-class-t*) (eq s *the-class-stream*)
1601       ;; FIXME: bad things happen if someone tries to mix in both
1602       ;; FILE-STREAM and STRING-STREAM (as they have the same
1603       ;; layout-depthoid).  Is there any way we can provide a useful
1604       ;; error message?  -- CSR, 2005-05-03
1605       (eq s *the-class-file-stream*) (eq s *the-class-string-stream*)
1606       ;; This probably shouldn't be mixed in with certain other
1607       ;; classes, too, but it seems to work both with STANDARD-OBJECT
1608       ;; and FUNCALLABLE-STANDARD-OBJECT
1609       (eq s *the-class-sequence*)))
1610 \f
1611 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1612 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1613 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1614 (macrolet ((def (method)
1615              `(defmethod ,method ((class forward-referenced-class))
1616                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1617                        ',method class))))
1618   (def class-default-initargs)
1619   (def class-precedence-list)
1620   (def class-slots))
1621
1622 (defmethod validate-superclass ((c slot-class)
1623                                 (f forward-referenced-class))
1624   t)
1625 \f
1626 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1627   (pushnew dependent (plist-value metaobject 'dependents) :test #'eq))
1628
1629 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1630   (setf (plist-value metaobject 'dependents)
1631         (delete dependent (plist-value metaobject 'dependents))))
1632
1633 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1634   (dolist (dependent (plist-value metaobject 'dependents))
1635     (funcall function dependent)))
1636