src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (let ((info (slot-definition-info slotd)))
  28     (ecase type
  29       (reader (slot-info-reader info))
  30       (writer (slot-info-writer info))
  31       (boundp (slot-info-boundp info)))))
  32
  33 (defmethod (setf slot-accessor-function) (function
  34                                           (slotd effective-slot-definition)
  35                                           type)
  36   (let ((info (slot-definition-info slotd)))
  37     (ecase type
  38       (reader (setf (slot-info-reader info) function))
  39       (writer (setf (slot-info-writer info) function))
  40       (boundp (setf (slot-info-boundp info) function)))))
  41
  42 (defconstant +slotd-reader-function-std-p+ 1)
  43 (defconstant +slotd-writer-function-std-p+ 2)
  44 (defconstant +slotd-boundp-function-std-p+ 4)
  45 (defconstant +slotd-all-function-std-p+ 7)
  46
  47 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  48   (let ((flags (slot-value slotd 'accessor-flags)))
  49     (declare (type fixnum flags))
  50     (if (eq type 'all)
  51         (eql +slotd-all-function-std-p+ flags)
  52         (let ((mask (ecase type
  53                       (reader +slotd-reader-function-std-p+)
  54                       (writer +slotd-writer-function-std-p+)
  55                       (boundp +slotd-boundp-function-std-p+))))
  56           (declare (type fixnum mask))
  57           (not (zerop (the fixnum (logand mask flags))))))))
  58
  59 (defmethod (setf slot-accessor-std-p) (value
  60                                        (slotd effective-slot-definition)
  61                                        type)
  62   (let ((mask (ecase type
  63                 (reader +slotd-reader-function-std-p+)
  64                 (writer +slotd-writer-function-std-p+)
  65                 (boundp +slotd-boundp-function-std-p+)))
  66         (flags (slot-value slotd 'accessor-flags)))
  67     (declare (type fixnum mask flags))
  68     (setf (slot-value slotd 'accessor-flags)
  69           (if value
  70               (the fixnum (logior mask flags))
  71               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  72   value)
  73
  74 (defmethod initialize-internal-slot-functions
  75     ((slotd effective-slot-definition))
  76   (let* ((name (slot-value slotd 'name))
  77          (class (slot-value slotd '%class)))
  78     (dolist (type '(reader writer boundp))
  79       (let* ((gf-name (ecase type
  80                               (reader 'slot-value-using-class)
  81                               (writer '(setf slot-value-using-class))
  82                               (boundp 'slot-boundp-using-class)))
  83              (gf (gdefinition gf-name)))
  84         ;; KLUDGE: this logic is cut'n'pasted from
  85         ;; GET-ACCESSOR-METHOD-FUNCTION, which (for STD-CLASSes) is
  86         ;; only called later, because it does things that can't be
  87         ;; computed this early in class finalization; however, we need
  88         ;; this bit as early as possible.  -- CSR, 2009-11-05
  89         (setf (slot-accessor-std-p slotd type)
  90               (let* ((std-method (standard-svuc-method type))
  91                      (str-method (structure-svuc-method type))
  92                      (types1 `((eql ,class) (class-eq ,class) (eql ,slotd)))
  93                      (types (if (eq type 'writer) `(t ,@types1) types1))
  94                      (methods (compute-applicable-methods-using-types gf types)))
  95                 (null (cdr methods))))
  96         (setf (slot-accessor-function slotd type)
  97               (lambda (&rest args)
  98                 (declare (dynamic-extent args))
  99                 ;; FIXME: a tiny amount of wasted SLOT-ACCESSOR-STD-P
 100                 ;; work here (see KLUDGE comment above).
 101                 (let ((fun (compute-slot-accessor-info slotd type gf)))
 102                   (apply fun args))))))))
 103
 104 (defmethod finalize-internal-slot-functions ((slotd effective-slot-definition))
 105   (dolist (type '(reader writer boundp))
 106     (let* ((gf-name (ecase type
 107                       (reader 'slot-value-using-class)
 108                       (writer '(setf slot-value-using-class))
 109                       (boundp 'slot-boundp-using-class)))
 110            (gf (gdefinition gf-name)))
 111       (compute-slot-accessor-info slotd type gf))))
 112
 113 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
 114 ;;;
 115 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
 116 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
 117 ;;; writing/testing effective slot SLOTD.
 118 ;;;
 119 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
 120 ;;; GF.  Store the effective method in the effective slot definition
 121 ;;; object itself; these GFs have special dispatch functions calling
 122 ;;; effective methods directly retrieved from effective slot
 123 ;;; definition objects, as an optimization.
 124 ;;;
 125 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
 126 ;;; or some such.
 127 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
 128                                        type gf)
 129   (let* ((name (slot-value slotd 'name))
 130          (class (slot-value slotd '%class)))
 131     (multiple-value-bind (function std-p)
 132         (if (eq **boot-state** 'complete)
 133             (get-accessor-method-function gf type class slotd)
 134             (get-optimized-std-accessor-method-function class slotd type))
 135       (setf (slot-accessor-std-p slotd type) std-p)
 136       (setf (slot-accessor-function slotd type) function))))
 137
 138 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 139   :instance)
 140 \f
 141 ;;;; various class accessors that are a little more complicated than can be
 142 ;;;; done with automatically generated reader methods
 143
 144 (defmethod class-prototype :before (class)
 145   (unless (class-finalized-p class)
 146     (error "~@<~S is not finalized.~:@>" class)))
 147
 148 ;;; KLUDGE: For some reason factoring the common body into a function
 149 ;;; breaks PCL bootstrapping, so just generate it with a macrolet for
 150 ;;; all.
 151 (macrolet ((def (class)
 152              `(defmethod class-prototype ((class ,class))
 153                 (with-slots (prototype) class
 154                   (or prototype
 155                       (setf prototype (allocate-instance class)))))))
 156   (def std-class)
 157   (def condition-class)
 158   (def structure-class))
 159
 160 (defmethod class-direct-default-initargs ((class slot-class))
 161   (plist-value class 'direct-default-initargs))
 162
 163 (defmethod class-default-initargs ((class slot-class))
 164   (plist-value class 'default-initargs))
 165
 166 (defmethod class-slot-cells ((class std-class))
 167   (plist-value class 'class-slot-cells))
 168 (defmethod (setf class-slot-cells) (new-value (class std-class))
 169   (setf (plist-value class 'class-slot-cells) new-value))
 170 \f
 171 ;;;; class accessors that are even a little bit more complicated than those
 172 ;;;; above. These have a protocol for updating them, we must implement that
 173 ;;;; protocol.
 174
 175 ;;; Maintaining the direct subclasses backpointers. The update methods are
 176 ;;; here, the values are read by an automatically generated reader method.
 177 (defmethod add-direct-subclass ((class class) (subclass class))
 178   (with-slots (direct-subclasses) class
 179     (pushnew subclass direct-subclasses :test #'eq)
 180     subclass))
 181 (defmethod remove-direct-subclass ((class class) (subclass class))
 182   (with-slots (direct-subclasses) class
 183     (setq direct-subclasses (remove subclass direct-subclasses))
 184     subclass))
 185
 186 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 187 ;;;
 188 ;;; There are four generic functions involved, each has one method for the
 189 ;;; class case and another method for the damned EQL specializers. All of
 190 ;;; these are specified methods and appear in their specified place in the
 191 ;;; class graph.
 192 ;;;
 193 ;;;   ADD-DIRECT-METHOD
 194 ;;;   REMOVE-DIRECT-METHOD
 195 ;;;   SPECIALIZER-DIRECT-METHODS
 196 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 197 ;;;
 198 ;;; In each case, we maintain one value which is a cons. The car is the list
 199 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 200 ;;; computed lazily.
 201
 202 ;;; This needs to be used recursively, in case a non-trivial user
 203 ;;; defined ADD/REMOVE-DIRECT-METHOD method ends up calling another
 204 ;;; function using the same lock.
 205 (defvar *specializer-lock* (sb-thread:make-mutex :name "Specializer lock"))
 206
 207 (defmethod add-direct-method :around ((specializer specializer) method)
 208   ;; All the actions done under this lock are done in an order
 209   ;; that is safe to unwind at any point.
 210   (sb-thread::with-recursive-system-lock (*specializer-lock*)
 211     (call-next-method)))
 212
 213 (defmethod remove-direct-method :around ((specializer specializer) method)
 214   ;; All the actions done under this lock are done in an order
 215   ;; that is safe to unwind at any point.
 216   (sb-thread::with-recursive-system-lock (*specializer-lock*)
 217     (call-next-method)))
 218
 219 (defmethod add-direct-method ((specializer class) (method method))
 220   (let ((cell (slot-value specializer 'direct-methods)))
 221     ;; We need to first smash the CDR, because a parallel read may
 222     ;; be in progress, and because if an interrupt catches us we
 223     ;; need to have a consistent state.
 224     (setf (cdr cell) ()
 225           (car cell) (adjoin method (car cell) :test #'eq)))
 226   method)
 227
 228 (defmethod remove-direct-method ((specializer class) (method method))
 229   (let ((cell (slot-value specializer 'direct-methods)))
 230     ;; We need to first smash the CDR, because a parallel read may
 231     ;; be in progress, and because if an interrupt catches us we
 232     ;; need to have a consistent state.
 233     (setf (cdr cell) ()
 234           (car cell) (remove method (car cell))))
 235   method)
 236
 237 (defmethod specializer-direct-methods ((specializer class))
 238   (with-slots (direct-methods) specializer
 239     (car direct-methods)))
 240
 241 (defmethod specializer-direct-generic-functions ((specializer class))
 242   (let ((cell (slot-value specializer 'direct-methods)))
 243     ;; If an ADD/REMOVE-METHOD is in progress, no matter: either
 244     ;; we behave as if we got just first or just after -- it's just
 245     ;; for update that we need to lock.
 246     (or (cdr cell)
 247         (sb-thread:with-mutex (*specializer-lock*)
 248           (setf (cdr cell)
 249                 (let (collect)
 250                   (dolist (m (car cell))
 251                     ;; the old PCL code used COLLECTING-ONCE which used
 252                     ;; #'EQ to check for newness
 253                     (pushnew (method-generic-function m) collect :test #'eq))
 254                   (nreverse collect)))))))
 255 \f
 256 ;;; This hash table is used to store the direct methods and direct generic
 257 ;;; functions of EQL specializers. Each value in the table is the cons.
 258 ;;;
 259 ;;; These tables are shared between threads, so they need to be synchronized.
 260 (defvar *eql-specializer-methods* (make-hash-table :test 'eql :synchronized t))
 261 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq :synchronized t))
 262
 263 (defmethod specializer-method-table ((specializer eql-specializer))
 264   *eql-specializer-methods*)
 265
 266 (defmethod specializer-method-table ((specializer class-eq-specializer))
 267   *class-eq-specializer-methods*)
 268
 269 (defmethod add-direct-method ((specializer specializer-with-object)
 270                               (method method))
 271   (let* ((object (specializer-object specializer))
 272          (table (specializer-method-table specializer))
 273          (entry (gethash object table)))
 274     (unless entry
 275       (setf entry
 276             (setf (gethash object table) (cons nil nil))))
 277     ;; We need to first smash the CDR, because a parallel read may
 278     ;; be in progress, and because if an interrupt catches us we
 279     ;; need to have a consistent state.
 280     (setf (cdr entry) ()
 281           (car entry) (adjoin method (car entry) :test #'eq))
 282     method))
 283
 284 (defmethod remove-direct-method ((specializer specializer-with-object)
 285                                  (method method))
 286   (let* ((object (specializer-object specializer))
 287          (entry (gethash object (specializer-method-table specializer))))
 288     (when entry
 289       ;; We need to first smash the CDR, because a parallel read may
 290       ;; be in progress, and because if an interrupt catches us we
 291       ;; need to have a consistent state.
 292       (setf (cdr entry) ()
 293             (car entry) (remove method (car entry))))
 294     method))
 295
 296 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 297   (car (gethash (specializer-object specializer)
 298                 (specializer-method-table specializer))))
 299
 300 (defmethod specializer-direct-generic-functions ((specializer
 301                                                   specializer-with-object))
 302   (let* ((object (specializer-object specializer))
 303          (entry (gethash object (specializer-method-table specializer))))
 304     (when entry
 305       (or (cdr entry)
 306           (sb-thread:with-mutex (*specializer-lock*)
 307             (setf (cdr entry)
 308                   (let (collect)
 309                     (dolist (m (car entry))
 310                       (pushnew (method-generic-function m) collect :test #'eq))
 311                     (nreverse collect))))))))
 312
 313 (defun map-specializers (function)
 314   (map-all-classes (lambda (class)
 315                      (funcall function (class-eq-specializer class))
 316                      (funcall function class)))
 317   (maphash (lambda (object methods)
 318              (declare (ignore methods))
 319              (intern-eql-specializer object))
 320            *eql-specializer-methods*)
 321   (maphash (lambda (object specl)
 322              (declare (ignore object))
 323              (funcall function specl))
 324            *eql-specializer-table*)
 325   nil)
 326
 327 (defun map-all-generic-functions (function)
 328   (let ((all-generic-functions (make-hash-table :test 'eq)))
 329     (map-specializers (lambda (specl)
 330                         (dolist (gf (specializer-direct-generic-functions
 331                                      specl))
 332                           (unless (gethash gf all-generic-functions)
 333                             (setf (gethash gf all-generic-functions) t)
 334                             (funcall function gf))))))
 335   nil)
 336
 337 (defmethod shared-initialize :after ((specl class-eq-specializer)
 338                                      slot-names
 339                                      &key)
 340   (declare (ignore slot-names))
 341   (setf (slot-value specl '%type) `(class-eq ,(specializer-class specl))))
 342
 343 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 344   (declare (ignore slot-names))
 345   (setf (slot-value specl '%type)
 346         `(eql ,(specializer-object specl)))
 347   (setf (info :type :translator specl)
 348         (constantly (make-member-type :members (list (specializer-object specl))))))
 349
 350 (defun real-load-defclass (name metaclass-name supers slots other
 351                            readers writers slot-names source-location safe-p)
 352   (with-single-package-locked-error (:symbol name "defining ~S as a class")
 353     (%compiler-defclass name readers writers slot-names)
 354     (let ((res (apply #'ensure-class name :metaclass metaclass-name
 355                       :direct-superclasses supers
 356                       :direct-slots slots
 357                       :definition-source source-location
 358                       'safe-p safe-p
 359                       other)))
 360       res)))
 361
 362 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 363
 364 (defun ensure-class (name &rest args)
 365   (with-world-lock ()
 366     (apply #'ensure-class-using-class
 367            (let ((class (find-class name nil)))
 368              (when (and class (eq name (class-name class)))
 369                ;; NAME is the proper name of CLASS, so redefine it
 370                class))
 371            name
 372            args)))
 373
 374 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 375   (with-world-lock ()
 376     (multiple-value-bind (meta initargs)
 377         (frob-ensure-class-args args)
 378       (setf class (apply #'make-instance meta :name name initargs))
 379       (without-package-locks
 380         (setf (find-class name) class))))
 381   ;; After boot (SETF FIND-CLASS) does this.
 382   (unless (eq **boot-state** 'complete)
 383     (%set-class-type-translation class name))
 384   class)
 385
 386 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 387   (with-world-lock ()
 388     (multiple-value-bind (meta initargs)
 389         (frob-ensure-class-args args)
 390       (unless (eq (class-of class) meta)
 391         (apply #'change-class class meta initargs))
 392       (apply #'reinitialize-instance class initargs)
 393       (without-package-locks
 394         (setf (find-class name) class))))
 395   ;; After boot (SETF FIND-CLASS) does this.
 396   (unless (eq **boot-state** 'complete)
 397     (%set-class-type-translation class name))
 398   class)
 399
 400 (defun frob-ensure-class-args (args)
 401   (let (metaclass metaclassp reversed-plist)
 402     (flet ((frob-superclass (s)
 403              (cond
 404                ((classp s) s)
 405                ((legal-class-name-p s)
 406                 (or (find-class s nil)
 407                     (ensure-class s :metaclass 'forward-referenced-class)))
 408                (t (error "Not a class or a legal class name: ~S." s)))))
 409       (doplist (key val) args
 410         (cond ((eq key :metaclass)
 411                (unless metaclassp
 412                  (setf metaclass val metaclassp key)))
 413               (t
 414                (when (eq key :direct-superclasses)
 415                  (setf val (mapcar #'frob-superclass val)))
 416                (setf reversed-plist (list* val key reversed-plist)))))
 417       (values (cond (metaclassp
 418                      (if (classp metaclass)
 419                          metaclass
 420                          (find-class metaclass)))
 421                     (t *the-class-standard-class*))
 422               (nreverse reversed-plist)))))
 423
 424 ;;; This is used to call initfunctions of :allocation :class slots.
 425 (defun call-initfun (fun slotd safe)
 426   (declare (function fun))
 427   (let ((value (funcall fun)))
 428     (when safe
 429       (let ((type (slot-definition-type slotd)))
 430         (unless (or (eq t type)
 431                     (typep value type))
 432           (error 'type-error :expected-type type :datum value))))
 433     value))
 434 \f
 435 (defmethod shared-initialize :after
 436     ((class std-class) slot-names &key
 437      (direct-superclasses nil direct-superclasses-p)
 438      (direct-slots nil direct-slots-p)
 439      (direct-default-initargs nil direct-default-initargs-p)
 440      definition-source)
 441   (cond (direct-superclasses-p
 442          (setq direct-superclasses
 443                (or direct-superclasses
 444                    (list (if (funcallable-standard-class-p class)
 445                              *the-class-funcallable-standard-object*
 446                              *the-class-standard-object*))))
 447          (dolist (superclass direct-superclasses)
 448            (unless (validate-superclass class superclass)
 449              (error "~@<The class ~S was specified as a ~
 450                      super-class of the class ~S, ~
 451                      but the meta-classes ~S and ~S are incompatible.  ~
 452                      Define a method for ~S to avoid this error.~@:>"
 453                     superclass class (class-of superclass) (class-of class)
 454                     'validate-superclass)))
 455          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 456         (t
 457          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 458   (setq direct-slots
 459         (if direct-slots-p
 460             (setf (slot-value class 'direct-slots)
 461                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 462                           direct-slots))
 463             (slot-value class 'direct-slots)))
 464   (if direct-default-initargs-p
 465       (setf (plist-value class 'direct-default-initargs)
 466             direct-default-initargs)
 467       (setq direct-default-initargs
 468             (plist-value class 'direct-default-initargs)))
 469   (setf (plist-value class 'class-slot-cells)
 470         (let ((old-class-slot-cells (plist-value class 'class-slot-cells))
 471               (safe (safe-p class))
 472               (collect '()))
 473           (dolist (dslotd direct-slots)
 474             (when (eq :class (slot-definition-allocation dslotd))
 475               ;; see CLHS 4.3.6
 476               (let* ((name (slot-definition-name dslotd))
 477                      (old (assoc name old-class-slot-cells)))
 478                 (if (or (not old)
 479                         (eq t slot-names)
 480                         (member name slot-names :test #'eq))
 481                     (let* ((initfunction (slot-definition-initfunction dslotd))
 482                            (value
 483                             (if initfunction
 484                                 (call-initfun initfunction dslotd safe)
 485                                 +slot-unbound+)))
 486                       (push (cons name value) collect))
 487                     (push old collect)))))
 488           (nreverse collect)))
 489   (add-direct-subclasses class direct-superclasses)
 490   (if (class-finalized-p class)
 491       ;; required by AMOP, "Reinitialization of Class Metaobjects"
 492       (finalize-inheritance class)
 493       (update-class class nil))
 494   (add-slot-accessors class direct-slots definition-source)
 495   (make-preliminary-layout class))
 496
 497 (defmethod shared-initialize :after ((class forward-referenced-class)
 498                                      slot-names &key &allow-other-keys)
 499   (declare (ignore slot-names))
 500   (make-preliminary-layout class))
 501
 502 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 503
 504 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 505 ;;; make it known to the type system.
 506 (defun make-preliminary-layout (class)
 507   (flet ((compute-preliminary-cpl (root)
 508            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 509              (compute-class-precedence-list root))))
 510     (with-world-lock ()
 511       (without-package-locks
 512         (unless (class-finalized-p class)
 513           (let ((name (class-name class)))
 514             ;; KLUDGE: This is fairly horrible.  We need to make a
 515             ;; full-fledged CLASSOID here, not just tell the compiler that
 516             ;; some class is forthcoming, because there are legitimate
 517             ;; questions one can ask of the type system, implemented in
 518             ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 519             (let ((layout (make-wrapper 0 class)))
 520               (setf (slot-value class 'wrapper) layout)
 521               (let ((cpl (compute-preliminary-cpl class)))
 522                 (setf (layout-inherits layout)
 523                       (order-layout-inherits
 524                        (map 'simple-vector #'class-wrapper
 525                             (reverse (rest cpl))))))
 526               (register-layout layout :invalidate t)
 527               (%set-class-type-translation class (layout-classoid layout)))))
 528         (mapc #'make-preliminary-layout (class-direct-subclasses class))))))
 529
 530
 531 (defmethod shared-initialize :before ((class class) slot-names &key name)
 532   (declare (ignore slot-names name))
 533   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 534   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 535   (setf (slot-value class '%type) `(class ,class))
 536   (setf (slot-value class 'class-eq-specializer)
 537         (make-instance 'class-eq-specializer :class class)))
 538
 539 (defmethod reinitialize-instance :before ((class slot-class) &key direct-superclasses)
 540   (dolist (old-super (set-difference (class-direct-superclasses class) direct-superclasses))
 541     (remove-direct-subclass old-super class))
 542   (remove-slot-accessors class (class-direct-slots class)))
 543
 544 (defmethod reinitialize-instance :after ((class slot-class)
 545                                          &rest initargs
 546                                          &key)
 547   (map-dependents class
 548                   (lambda (dependent)
 549                     (apply #'update-dependent class dependent initargs))))
 550
 551 (defmethod reinitialize-instance :after ((class condition-class) &key)
 552   (let* ((name (class-name class))
 553          (classoid (find-classoid name))
 554          (slots (condition-classoid-slots classoid)))
 555     ;; to balance the REMOVE-SLOT-ACCESSORS call in
 556     ;; REINITIALIZE-INSTANCE :BEFORE (SLOT-CLASS).
 557     (dolist (slot slots)
 558       (let ((slot-name (condition-slot-name slot)))
 559         (dolist (reader (condition-slot-readers slot))
 560           ;; FIXME: see comment in SHARED-INITIALIZE :AFTER
 561           ;; (CONDITION-CLASS T), below.  -- CSR, 2005-11-18
 562           (sb-kernel::install-condition-slot-reader reader name slot-name))
 563         (dolist (writer (condition-slot-writers slot))
 564           (sb-kernel::install-condition-slot-writer writer name slot-name))))))
 565
 566 (defmethod shared-initialize :after ((class condition-class) slot-names
 567                                      &key direct-slots direct-superclasses)
 568   (declare (ignore slot-names))
 569   (let ((classoid (find-classoid (slot-value class 'name))))
 570     (with-slots (wrapper
 571                  %class-precedence-list cpl-available-p finalized-p
 572                  prototype (direct-supers direct-superclasses)
 573                  plist)
 574         class
 575       (setf (slot-value class 'direct-slots)
 576             (mapcar (lambda (pl) (make-direct-slotd class pl))
 577                     direct-slots)
 578             finalized-p t
 579             (classoid-pcl-class classoid) class
 580             direct-supers direct-superclasses
 581             wrapper (classoid-layout classoid)
 582             %class-precedence-list (compute-class-precedence-list class)
 583             cpl-available-p t
 584             (getf plist 'direct-default-initargs)
 585             (sb-kernel::condition-classoid-direct-default-initargs classoid))
 586       (add-direct-subclasses class direct-superclasses)
 587       (let ((slots (compute-slots class)))
 588         (setf (slot-value class 'slots) slots)
 589         (setf (layout-slot-table wrapper) (make-slot-table class slots)))))
 590   ;; Comment from Gerd's PCL, 2003-05-15:
 591   ;;
 592   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 593   ;; override condition accessors with generic functions.  We do this
 594   ;; differently.
 595   ;;
 596   ;; ??? What does the above comment mean and why is it a good idea?
 597   ;; CMUCL (which still as of 2005-11-18 uses this code and has this
 598   ;; comment) loses slot information in its condition classes:
 599   ;; DIRECT-SLOTS is always NIL.  We have the right information, so we
 600   ;; remove slot accessors but never put them back.  I've added a
 601   ;; REINITIALIZE-INSTANCE :AFTER (CONDITION-CLASS) method, but what
 602   ;; was meant to happen?  -- CSR, 2005-11-18
 603   )
 604
 605 (defmethod direct-slot-definition-class ((class condition-class)
 606                                          &rest initargs)
 607   (declare (ignore initargs))
 608   (find-class 'condition-direct-slot-definition))
 609
 610 (defmethod effective-slot-definition-class ((class condition-class)
 611                                             &rest initargs)
 612   (declare (ignore initargs))
 613   (find-class 'condition-effective-slot-definition))
 614
 615 (defmethod finalize-inheritance ((class condition-class))
 616   (aver (slot-value class 'finalized-p))
 617   nil)
 618
 619 (defmethod compute-effective-slot-definition
 620     ((class condition-class) slot-name dslotds)
 621   (let* ((slotd (call-next-method))
 622          (info (slot-definition-info slotd)))
 623     (setf (slot-info-reader info)
 624           (lambda (x)
 625             (handler-case (condition-reader-function x slot-name)
 626               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 627               ;; is unbound; maybe it should be a CELL-ERROR of some
 628               ;; sort?
 629               (error () (values (slot-unbound class x slot-name))))))
 630     (setf (slot-info-writer info)
 631           (lambda (v x)
 632             (condition-writer-function x v slot-name)))
 633     (setf (slot-info-boundp info)
 634           (lambda (x)
 635             (multiple-value-bind (v c)
 636                 (ignore-errors (condition-reader-function x slot-name))
 637               (declare (ignore v))
 638               (null c))))
 639     slotd))
 640
 641 (defmethod compute-slots ((class condition-class))
 642   (mapcan (lambda (superclass)
 643             (mapcar (lambda (dslotd)
 644                       (compute-effective-slot-definition
 645                        class (slot-definition-name dslotd) (list dslotd)))
 646                     (class-direct-slots superclass)))
 647           (reverse (slot-value class '%class-precedence-list))))
 648
 649 (defmethod compute-slots :around ((class condition-class))
 650   (let ((eslotds (call-next-method)))
 651     (mapc #'finalize-internal-slot-functions eslotds)
 652     eslotds))
 653
 654 (defmethod shared-initialize :after
 655     ((slotd structure-slot-definition) slot-names &key
 656      (allocation :instance) allocation-class)
 657   (declare (ignore slot-names allocation-class))
 658   (unless (eq allocation :instance)
 659     (error "Structure slots must have :INSTANCE allocation.")))
 660
 661 (defun make-structure-class-defstruct-form (name direct-slots include)
 662   (let* ((conc-name (format-symbol *package* "~S structure class " name))
 663          (constructor (format-symbol *package* "~Aconstructor" conc-name))
 664          (included-name (class-name include))
 665          (included-slots
 666           (when include
 667             (mapcar #'dsd-name (dd-slots (find-defstruct-description included-name)))))
 668          (old-slots nil)
 669          (new-slots nil)
 670          (reader-names nil)
 671          (writer-names nil))
 672     (dolist (slotd (reverse direct-slots))
 673       (let* ((slot-name (slot-definition-name slotd))
 674              (initform (slot-definition-initform slotd))
 675              (type (slot-definition-type slotd))
 676              (desc `(,slot-name ,initform :type ,type)))
 677         (push `(slot-accessor ,name ,slot-name reader)
 678               reader-names)
 679         (push `(slot-accessor ,name ,slot-name writer)
 680               writer-names)
 681         (if (member slot-name included-slots :test #'eq)
 682             (push desc old-slots)
 683             (push desc new-slots))))
 684     (let* ((defstruct `(defstruct (,name
 685                                     ,@(when include
 686                                             `((:include ,included-name
 687                                                         ,@old-slots)))
 688                                     (:constructor ,constructor ())
 689                                     (:predicate nil)
 690                                     (:conc-name ,conc-name)
 691                                     (:copier nil))
 692                          ,@new-slots))
 693            (readers-init
 694             (mapcar (lambda (slotd reader-name)
 695                       (let ((accessor
 696                              (slot-definition-defstruct-accessor-symbol
 697                               slotd)))
 698                         `(defun ,reader-name (obj)
 699                            (declare (type ,name obj))
 700                            (,accessor obj))))
 701                     direct-slots reader-names))
 702            (writers-init
 703             (mapcar (lambda (slotd writer-name)
 704                       (let ((accessor
 705                              (slot-definition-defstruct-accessor-symbol
 706                               slotd)))
 707                         `(defun ,writer-name (nv obj)
 708                            (declare (type ,name obj))
 709                            (setf (,accessor obj) nv))))
 710                     direct-slots writer-names))
 711            (defstruct-form
 712             `(progn
 713                ,defstruct
 714                ,@readers-init ,@writers-init
 715                (cons nil nil))))
 716       (values defstruct-form constructor reader-names writer-names))))
 717
 718 (defun make-defstruct-allocation-function (name)
 719   ;; FIXME: Why don't we go class->layout->info == dd
 720   (let ((dd (find-defstruct-description name)))
 721     (ecase (dd-type dd)
 722       (structure
 723        (%make-structure-instance-allocator dd nil))
 724       (funcallable-structure
 725        (%make-funcallable-structure-instance-allocator dd nil)))))
 726
 727 (defmethod shared-initialize :after
 728     ((class structure-class) slot-names &key
 729      (direct-superclasses nil direct-superclasses-p)
 730      (direct-slots nil direct-slots-p)
 731      direct-default-initargs
 732      definition-source)
 733   (declare (ignore slot-names direct-default-initargs))
 734   (if direct-superclasses-p
 735       (setf (slot-value class 'direct-superclasses)
 736             (or direct-superclasses
 737                 (setq direct-superclasses
 738                       (and (not (eq (slot-value class 'name) 'structure-object))
 739                            (list *the-class-structure-object*)))))
 740       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 741   (let* ((name (slot-value class 'name))
 742          (from-defclass-p (slot-value class 'from-defclass-p))
 743          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 744     (if direct-slots-p
 745         (setf (slot-value class 'direct-slots)
 746               (setq direct-slots
 747                     (mapcar (lambda (pl)
 748                               (when defstruct-p
 749                                 (let* ((slot-name (getf pl :name))
 750                                        (accessor
 751                                         (format-symbol *package*
 752                                                        "~S structure class ~A"
 753                                                        name slot-name)))
 754                                   (setq pl (list* :defstruct-accessor-symbol
 755                                                   accessor pl))))
 756                               (make-direct-slotd class pl))
 757                             direct-slots)))
 758         (setq direct-slots (slot-value class 'direct-slots)))
 759     (if defstruct-p
 760         (let ((include (car (slot-value class 'direct-superclasses))))
 761           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 762               (make-structure-class-defstruct-form name direct-slots include)
 763             (unless (structure-type-p name) (eval defstruct-form))
 764             (mapc (lambda (dslotd reader-name writer-name)
 765                     (let* ((reader (gdefinition reader-name))
 766                            (writer (when (fboundp writer-name)
 767                                      (gdefinition writer-name))))
 768                       (setf (slot-value dslotd 'internal-reader-function)
 769                             reader)
 770                       (setf (slot-value dslotd 'internal-writer-function)
 771                             writer)))
 772                   direct-slots reader-names writer-names)
 773             (setf (slot-value class 'defstruct-form) defstruct-form)
 774             (setf (slot-value class 'defstruct-constructor) constructor)))
 775         (setf (slot-value class 'defstruct-constructor)
 776               ;; KLUDGE: not class; in fixup.lisp, can't access slots
 777               ;; outside methods yet.
 778               (make-defstruct-allocation-function name)))
 779     (add-direct-subclasses class direct-superclasses)
 780     (setf (slot-value class '%class-precedence-list)
 781           (compute-class-precedence-list class))
 782     (setf (slot-value class 'cpl-available-p) t)
 783     (let ((slots (compute-slots class)))
 784       (setf (slot-value class 'slots) slots)
 785       (let* ((lclass (find-classoid (slot-value class 'name)))
 786              (layout (classoid-layout lclass)))
 787         (setf (classoid-pcl-class lclass) class)
 788         (setf (slot-value class 'wrapper) layout)
 789         (setf (layout-slot-table layout) (make-slot-table class slots))))
 790     (setf (slot-value class 'finalized-p) t)
 791     (add-slot-accessors class direct-slots definition-source)))
 792
 793 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 794   (declare (ignore initargs))
 795   (find-class 'structure-direct-slot-definition))
 796
 797 (defmethod finalize-inheritance ((class structure-class))
 798   nil) ; always finalized
 799 \f
 800 (defun add-slot-accessors (class dslotds &optional source-location)
 801   (fix-slot-accessors class dslotds 'add source-location))
 802
 803 (defun remove-slot-accessors (class dslotds)
 804   (fix-slot-accessors class dslotds 'remove))
 805
 806 (defun fix-slot-accessors (class dslotds add/remove &optional source-location)
 807   (flet ((fix (gfspec name r/w doc)
 808            (let ((gf (cond ((eq add/remove 'add)
 809                             (or (find-generic-function gfspec nil)
 810                                 (ensure-generic-function
 811                                  gfspec :lambda-list (case r/w
 812                                                        (r '(object))
 813                                                        (w '(new-value object))))))
 814                            (t
 815                             (find-generic-function gfspec nil)))))
 816              (when gf
 817                (case r/w
 818                  (r (if (eq add/remove 'add)
 819                         (add-reader-method class gf name doc source-location)
 820                         (remove-reader-method class gf)))
 821                  (w (if (eq add/remove 'add)
 822                         (add-writer-method class gf name doc source-location)
 823                         (remove-writer-method class gf))))))))
 824     (dolist (dslotd dslotds)
 825       (let ((slot-name (slot-definition-name dslotd))
 826             (slot-doc (%slot-definition-documentation dslotd)))
 827         (dolist (r (slot-definition-readers dslotd))
 828           (fix r slot-name 'r slot-doc))
 829         (dolist (w (slot-definition-writers dslotd))
 830           (fix w slot-name 'w slot-doc))))))
 831 \f
 832 (defun add-direct-subclasses (class supers)
 833   (dolist (super supers)
 834     (unless (memq class (class-direct-subclasses class))
 835       (add-direct-subclass super class))))
 836
 837 (defmethod finalize-inheritance ((class std-class))
 838   (update-class class t))
 839
 840 (defmethod finalize-inheritance ((class forward-referenced-class))
 841   ;; FIXME: should we not be thinking a bit about what kinds of error
 842   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 843   ;; possibly a forward-referenced-class-error, though that's
 844   ;; difficult given e.g. class precedence list calculations...
 845   (error
 846    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 847        ~2I~_~S~:>"
 848    class))
 849
 850 \f
 851 (defun class-has-a-forward-referenced-superclass-p (class)
 852   (or (when (forward-referenced-class-p class)
 853         class)
 854       (some #'class-has-a-forward-referenced-superclass-p
 855             (class-direct-superclasses class))))
 856
 857 ;;; This is called by :after shared-initialize whenever a class is initialized
 858 ;;; or reinitialized. The class may or may not be finalized.
 859 (defun update-class (class finalizep)
 860   (without-package-locks
 861     (with-world-lock ()
 862       (when (or finalizep (class-finalized-p class))
 863         (%update-cpl class (compute-class-precedence-list class))
 864         ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 865         ;; class.
 866         (%update-slots class (compute-slots class))
 867         (update-gfs-of-class class)
 868         (setf (plist-value class 'default-initargs) (compute-default-initargs class))
 869         (update-ctors 'finalize-inheritance :class class))
 870       (dolist (sub (class-direct-subclasses class))
 871         (update-class sub nil)))))
 872
 873 (define-condition cpl-protocol-violation (reference-condition error)
 874   ((class :initarg :class :reader cpl-protocol-violation-class)
 875    (cpl :initarg :cpl :reader cpl-protocol-violation-cpl))
 876   (:default-initargs :references (list '(:sbcl :node "Metaobject Protocol")))
 877   (:report
 878    (lambda (c s)
 879      (format s "~@<Protocol violation: the ~S class ~S ~
 880                 ~:[has~;does not have~] the class ~S in its ~
 881                 class precedence list: ~S.~@:>"
 882              (class-name (class-of (cpl-protocol-violation-class c)))
 883              (cpl-protocol-violation-class c)
 884              (eq (class-of (cpl-protocol-violation-class c))
 885                  *the-class-funcallable-standard-class*)
 886              (find-class 'function)
 887              (cpl-protocol-violation-cpl c)))))
 888
 889 (defun %update-cpl (class cpl)
 890   (when (eq (class-of class) *the-class-standard-class*)
 891     (when (find (find-class 'function) cpl)
 892       (error 'cpl-protocol-violation :class class :cpl cpl)))
 893   (when (eq (class-of class) *the-class-funcallable-standard-class*)
 894     (unless (find (find-class 'function) cpl)
 895       (error 'cpl-protocol-violation :class class :cpl cpl)))
 896   (if (class-finalized-p class)
 897       (unless (and (equal (class-precedence-list class) cpl)
 898                    (dolist (c cpl t)
 899                      (when (position :class (class-direct-slots c)
 900                                      :key #'slot-definition-allocation)
 901                        (return nil))))
 902         ;; comment from the old CMU CL sources:
 903         ;;   Need to have the cpl setup before %update-lisp-class-layout
 904         ;;   is called on CMU CL.
 905         (setf (slot-value class '%class-precedence-list) cpl)
 906         (setf (slot-value class 'cpl-available-p) t)
 907         (%force-cache-flushes class))
 908       (progn
 909         (setf (slot-value class '%class-precedence-list) cpl)
 910         (setf (slot-value class 'cpl-available-p) t)))
 911   (update-class-can-precede-p cpl))
 912
 913 (defun update-class-can-precede-p (cpl)
 914   (when cpl
 915     (let ((first (car cpl)))
 916       (dolist (c (cdr cpl))
 917         (pushnew c (slot-value first 'can-precede-list) :test #'eq)))
 918     (update-class-can-precede-p (cdr cpl))))
 919
 920 (defun class-can-precede-p (class1 class2)
 921   (member class2 (class-can-precede-list class1) :test #'eq))
 922
 923 ;;; This is called from %UPDATE-SLOTS to check if slot layouts are compatible.
 924 ;;;
 925 ;;; In addition to slot locations (implicit in the ordering of the slots), we
 926 ;;; must check classes: SLOT-INFO structures from old slotds may have been
 927 ;;; cached in permutation vectors, but new slotds have had new ones allocated
 928 ;;; to them. This is non-problematic for standard slotds, because we know the
 929 ;;; structure is compatible, but if a slot definition class changes, this can
 930 ;;; change the way SLOT-VALUE-USING-CLASS should dispatch.
 931 ;;;
 932 ;;; Also, if the slot has a non-standard allocation, we need to check that it
 933 ;;; doesn't change.
 934 (defun slot-layouts-compatible-p
 935     (oslotds new-instance-slotds new-class-slotds new-custom-slotds)
 936   (multiple-value-bind (old-instance-slotds old-class-slotds old-custom-slotds)
 937       (classify-slotds oslotds)
 938     (and
 939      ;; Instance slots: name, type, and class.
 940      (dolist (o old-instance-slotds (not new-instance-slotds))
 941        (let ((n (pop new-instance-slotds)))
 942          (unless (and n
 943                       (eq (slot-definition-name o) (slot-definition-name n))
 944                       (eq (slot-definition-type o) (slot-definition-type n))
 945                       (eq (class-of o) (class-of n)))
 946            (return nil))))
 947      ;; Class slots: name and class. (FIXME: class slots not typechecked?)
 948      (dolist (o old-class-slotds (not new-class-slotds))
 949        (let ((n (pop new-class-slotds)))
 950          (unless (and n
 951                       (eq (slot-definition-name o) (slot-definition-name n))
 952                       (eq (class-of n) (class-of o)))
 953            (return nil))))
 954      ;; Custom slots: check name, type, allocation, and class. (FIXME: should we just punt?)
 955      (dolist (o old-custom-slotds (not new-custom-slotds))
 956        (let ((n (pop new-custom-slotds)))
 957          (unless (and n
 958                       (eq (slot-definition-name o) (slot-definition-name n))
 959                       (eq (slot-definition-type o) (slot-definition-type n))
 960                       (eq (slot-definition-allocation o) (slot-definition-allocation n))
 961                       (eq (class-of o) (class-of n)))
 962            (return nil)))))))
 963
 964 (defun style-warn-about-duplicate-slots (class)
 965   (do* ((slots (slot-value class 'slots) (cdr slots))
 966         (dupes nil))
 967        ((null slots)
 968         (when dupes
 969           (style-warn
 970            "~@<slot names with the same SYMBOL-NAME but ~
 971                   different SYMBOL-PACKAGE (possible package problem) ~
 972                   for class ~S:~4I~@:_~<~@{~/sb-impl::print-symbol-with-prefix/~^~:@_~}~:>~@:>"
 973            class dupes)))
 974     (let* ((slot-name (slot-definition-name (car slots)))
 975            (oslots (and (not (eq (symbol-package slot-name)
 976                                  *pcl-package*))
 977                         (remove-if
 978                          (lambda (slot-name-2)
 979                            (or (eq (symbol-package slot-name-2)
 980                                    *pcl-package*)
 981                                (string/= slot-name slot-name-2)))
 982                          (cdr slots)
 983                          :key #'slot-definition-name))))
 984       (when oslots
 985         (pushnew (cons slot-name
 986                        (mapcar #'slot-definition-name oslots))
 987                  dupes
 988                  :test #'string= :key #'car)))))
 989
 990 (defun %update-slots (class eslotds)
 991   (multiple-value-bind (instance-slots class-slots custom-slots)
 992       (classify-slotds eslotds)
 993     (let* ((nslots (length instance-slots))
 994            (owrapper (when (class-finalized-p class) (class-wrapper class)))
 995            (nwrapper
 996              (cond ((null owrapper)
 997                     (make-wrapper nslots class))
 998                    ((slot-layouts-compatible-p (wrapper-slots owrapper)
 999                                                instance-slots class-slots custom-slots)
1000                     owrapper)
1001                    (t
1002                     ;; This will initialize the new wrapper to have the
1003                     ;; same state as the old wrapper. We will then have
1004                     ;; to change that. This may seem like wasted work
1005                     ;; (and it is), but the spec requires that we call
1006                     ;; MAKE-INSTANCES-OBSOLETE.
1007                     (make-instances-obsolete class)
1008                     (class-wrapper class)))))
1009       (%update-lisp-class-layout class nwrapper)
1010       (setf (slot-value class 'slots) eslotds
1011             (wrapper-slots nwrapper) eslotds
1012             (wrapper-slot-table nwrapper) (make-slot-table class eslotds)
1013             (wrapper-length nwrapper) nslots
1014             (slot-value class 'wrapper) nwrapper)
1015       (style-warn-about-duplicate-slots class)
1016       (setf (slot-value class 'finalized-p) t)
1017       (unless (eq owrapper nwrapper)
1018         (maybe-update-standard-slot-locations class)))))
1019
1020 (defun update-gf-dfun (class gf)
1021   (let ((*new-class* class)
1022         (arg-info (gf-arg-info gf)))
1023     (cond
1024       ((special-case-for-compute-discriminating-function-p gf))
1025       ((gf-precompute-dfun-and-emf-p arg-info)
1026        (multiple-value-bind (dfun cache info) (make-final-dfun-internal gf)
1027          (update-dfun gf dfun cache info))))))
1028
1029 (defun update-gfs-of-class (class)
1030   (when (and (class-finalized-p class)
1031              (let ((cpl (class-precedence-list class)))
1032                (or (member *the-class-slot-class* cpl :test #'eq)
1033                    (member *the-class-standard-effective-slot-definition*
1034                            cpl :test #'eq))))
1035     (let ((gf-table (make-hash-table :test 'eq)))
1036       (labels ((collect-gfs (class)
1037                  (dolist (gf (specializer-direct-generic-functions class))
1038                    (setf (gethash gf gf-table) t))
1039                  (mapc #'collect-gfs (class-direct-superclasses class))))
1040         (collect-gfs class)
1041         (maphash (lambda (gf ignore)
1042                    (declare (ignore ignore))
1043                    (update-gf-dfun class gf))
1044                  gf-table)))))
1045 \f
1046 (defmethod compute-default-initargs ((class slot-class))
1047   (let ((initargs (loop for c in (class-precedence-list class)
1048                         append (class-direct-default-initargs c))))
1049     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
1050 \f
1051 ;;;; protocols for constructing direct and effective slot definitions
1052
1053 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
1054   (declare (ignore initargs))
1055   (find-class 'standard-direct-slot-definition))
1056
1057 (defun make-direct-slotd (class initargs)
1058   (apply #'make-instance
1059          (apply #'direct-slot-definition-class class initargs)
1060          :class class
1061          initargs))
1062
1063 ;;; I (CSR) am not sure, but I believe that the particular order of
1064 ;;; slots is quite important: it is ideal to attempt to have a
1065 ;;; constant slot location for the same notional slots as much as
1066 ;;; possible, so that clever discriminating functions (ONE-INDEX et
1067 ;;; al.) have a chance of working.  The below at least walks through
1068 ;;; the slots predictably, but maybe it would be good to compute some
1069 ;;; kind of optimal slot layout by looking at locations of slots in
1070 ;;; superclasses?
1071 (defun std-compute-slots (class)
1072   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
1073   ;; for each different slot name we find in our superclasses. Each
1074   ;; call receives the class and a list of the dslotds with that name.
1075   ;; The list is in most-specific-first order.
1076   (let ((name-dslotds-alist ()))
1077     (dolist (c (reverse (class-precedence-list class)))
1078       (dolist (slot (class-direct-slots c))
1079         (let* ((name (slot-definition-name slot))
1080                (entry (assq name name-dslotds-alist)))
1081           (if entry
1082               (push slot (cdr entry))
1083               (push (list name slot) name-dslotds-alist)))))
1084     (mapcar (lambda (direct)
1085               (compute-effective-slot-definition class
1086                                                  (car direct)
1087                                                  (cdr direct)))
1088             (nreverse name-dslotds-alist))))
1089
1090 (defmethod compute-slots ((class standard-class))
1091   (std-compute-slots class))
1092 (defmethod compute-slots ((class funcallable-standard-class))
1093   (std-compute-slots class))
1094
1095 (defun std-compute-slots-around (class eslotds)
1096   (let ((location -1)
1097         (safe (safe-p class)))
1098     (dolist (eslotd eslotds eslotds)
1099       (setf (slot-definition-location eslotd)
1100             (case (slot-definition-allocation eslotd)
1101               (:instance
1102                (incf location))
1103               (:class
1104                (let* ((name (slot-definition-name eslotd))
1105                       (from-class
1106                        (or
1107                         (slot-definition-allocation-class eslotd)
1108                         ;; we get here if the user adds an extra slot
1109                         ;; himself...
1110                         (setf (slot-definition-allocation-class eslotd)
1111                               class)))
1112                       ;; which raises the question of what we should
1113                       ;; do if we find that said user has added a slot
1114                       ;; with the same name as another slot...
1115                       (cell (or (assq name (class-slot-cells from-class))
1116                                 (let ((c (cons name +slot-unbound+)))
1117                                   (push c (class-slot-cells from-class))
1118                                   c))))
1119                  (aver (consp cell))
1120                  (if (eq +slot-unbound+ (cdr cell))
1121                      ;; We may have inherited an initfunction FIXME: Is this
1122                      ;; really right? Is the initialization in
1123                      ;; SHARED-INITIALIZE (STD-CLASS) not enough?
1124                      (let ((initfun (slot-definition-initfunction eslotd)))
1125                        (if initfun
1126                            (rplacd cell (call-initfun initfun eslotd safe))
1127                            cell))
1128                      cell)))))
1129       (unless (slot-definition-class eslotd)
1130         (setf (slot-definition-class eslotd) class))
1131       (initialize-internal-slot-functions eslotd))))
1132
1133 (defmethod compute-slots :around ((class standard-class))
1134   (let ((eslotds (call-next-method)))
1135     (std-compute-slots-around class eslotds)))
1136 (defmethod compute-slots :around ((class funcallable-standard-class))
1137   (let ((eslotds (call-next-method)))
1138     (std-compute-slots-around class eslotds)))
1139
1140 (defmethod compute-slots ((class structure-class))
1141   (mapcan (lambda (superclass)
1142             (mapcar (lambda (dslotd)
1143                       (compute-effective-slot-definition
1144                        class
1145                        (slot-definition-name dslotd)
1146                        (list dslotd)))
1147                     (class-direct-slots superclass)))
1148           (reverse (slot-value class '%class-precedence-list))))
1149
1150 (defmethod compute-slots :around ((class structure-class))
1151   (let ((eslotds (call-next-method)))
1152     (mapc #'finalize-internal-slot-functions eslotds)
1153     eslotds))
1154
1155 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1156   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1157          (class (apply #'effective-slot-definition-class class initargs))
1158          (slotd (apply #'make-instance class initargs)))
1159     slotd))
1160
1161 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1162   (declare (ignore initargs))
1163   (find-class 'standard-effective-slot-definition))
1164
1165 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1166   (declare (ignore initargs))
1167   (find-class 'structure-effective-slot-definition))
1168
1169 (defmethod compute-effective-slot-definition-initargs
1170     ((class slot-class) direct-slotds)
1171   (let* ((name nil)
1172          (initfunction nil)
1173          (initform nil)
1174          (initargs nil)
1175          (allocation nil)
1176          (allocation-class nil)
1177          (type t)
1178          (documentation nil)
1179          (documentationp nil)
1180          (namep  nil)
1181          (initp  nil)
1182          (allocp nil))
1183
1184     (dolist (slotd direct-slotds)
1185       (when slotd
1186         (unless namep
1187           (setq name (slot-definition-name slotd)
1188                 namep t))
1189         (unless initp
1190           (awhen (slot-definition-initfunction slotd)
1191             (setq initform (slot-definition-initform slotd)
1192                   initfunction it
1193                   initp t)))
1194         (unless documentationp
1195           (awhen (%slot-definition-documentation slotd)
1196             (setq documentation it
1197                   documentationp t)))
1198         (unless allocp
1199           (setq allocation (slot-definition-allocation slotd)
1200                 allocation-class (slot-definition-class slotd)
1201                 allocp t))
1202         (setq initargs (append (slot-definition-initargs slotd) initargs))
1203         (let ((slotd-type (slot-definition-type slotd)))
1204           (setq type (cond
1205                        ((eq type t) slotd-type)
1206                        ;; This pairwise type intersection is perhaps a
1207                        ;; little inefficient and inelegant, but it's
1208                        ;; unlikely to lie on the critical path.  Shout
1209                        ;; if I'm wrong.  -- CSR, 2005-11-24
1210                        (t (type-specifier
1211                            (specifier-type `(and ,type ,slotd-type)))))))))
1212     (list :name name
1213           :initform initform
1214           :initfunction initfunction
1215           :initargs initargs
1216           :allocation allocation
1217           :allocation-class allocation-class
1218           :type type
1219           :class class
1220           :documentation documentation)))
1221
1222 (defmethod compute-effective-slot-definition-initargs :around
1223     ((class structure-class) direct-slotds)
1224   (let* ((slotd (car direct-slotds))
1225          (accessor (slot-definition-defstruct-accessor-symbol slotd)))
1226     (list* :defstruct-accessor-symbol accessor
1227            :internal-reader-function
1228            (slot-definition-internal-reader-function slotd)
1229            :internal-writer-function
1230            (slot-definition-internal-writer-function slotd)
1231            (call-next-method))))
1232 \f
1233 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1234 ;;;       to make the method object. They have to use make-a-method which
1235 ;;;       is a specially bootstrapped mechanism for making standard methods.
1236 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1237   (declare (ignore direct-slot initargs))
1238   (find-class 'standard-reader-method))
1239
1240 (defmethod add-reader-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1241   (add-method generic-function
1242               (make-a-method 'standard-reader-method
1243                              ()
1244                              (list (or (class-name class) 'object))
1245                              (list class)
1246                              (make-reader-method-function class slot-name)
1247                              (or slot-documentation "automatically generated reader method")
1248                              :slot-name slot-name
1249                              :object-class class
1250                              :method-class-function #'reader-method-class
1251                              :definition-source source-location)))
1252
1253 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1254   (declare (ignore direct-slot initargs))
1255   (find-class 'standard-writer-method))
1256
1257 (defmethod add-writer-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1258   (add-method generic-function
1259               (make-a-method 'standard-writer-method
1260                              ()
1261                              (list 'new-value (or (class-name class) 'object))
1262                              (list *the-class-t* class)
1263                              (make-writer-method-function class slot-name)
1264                              (or slot-documentation "automatically generated writer method")
1265                              :slot-name slot-name
1266                              :object-class class
1267                              :method-class-function #'writer-method-class
1268                              :definition-source source-location)))
1269
1270 (defmethod add-boundp-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1271   (add-method generic-function
1272               (make-a-method (constantly (find-class 'standard-boundp-method))
1273                              class
1274                              ()
1275                              (list (or (class-name class) 'object))
1276                              (list class)
1277                              (make-boundp-method-function class slot-name)
1278                              (or slot-documentation "automatically generated boundp method")
1279                              :slot-name slot-name
1280                              :definition-source source-location)))
1281
1282 (defmethod remove-reader-method ((class slot-class) generic-function)
1283   (let ((method (get-method generic-function () (list class) nil)))
1284     (when method (remove-method generic-function method))))
1285
1286 (defmethod remove-writer-method ((class slot-class) generic-function)
1287   (let ((method
1288           (get-method generic-function () (list *the-class-t* class) nil)))
1289     (when method (remove-method generic-function method))))
1290
1291 (defmethod remove-boundp-method ((class slot-class) generic-function)
1292   (let ((method (get-method generic-function () (list class) nil)))
1293     (when method (remove-method generic-function method))))
1294 \f
1295 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITER-METHOD-FUNCTION
1296 ;;; function are NOT part of the standard protocol. They are however
1297 ;;; useful; PCL makes use of them internally and documents them for
1298 ;;; PCL users.  (FIXME: but SBCL certainly doesn't)
1299 ;;;
1300 ;;; *** This needs work to make type testing by the writer functions which
1301 ;;; *** do type testing faster. The idea would be to have one constructor
1302 ;;; *** for each possible type test.
1303 ;;;
1304 ;;; *** There is a subtle bug here which is going to have to be fixed.
1305 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1306 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1307 ;;; *** defined for this metaclass a chance to run.
1308
1309 (defmethod make-reader-method-function ((class slot-class) slot-name)
1310   (make-std-reader-method-function class slot-name))
1311
1312 (defmethod make-writer-method-function ((class slot-class) slot-name)
1313   (make-std-writer-method-function class slot-name))
1314
1315 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1316   (make-std-boundp-method-function class slot-name))
1317 \f
1318 (defmethod compatible-meta-class-change-p (class proto-new-class)
1319   (eq (class-of class) (class-of proto-new-class)))
1320
1321 (defmethod validate-superclass ((class class) (superclass class))
1322   (or (eq superclass *the-class-t*)
1323       (eq (class-of class) (class-of superclass))
1324       (and (eq (class-of superclass) *the-class-standard-class*)
1325            (eq (class-of class) *the-class-funcallable-standard-class*))
1326       (and (eq (class-of superclass) *the-class-funcallable-standard-class*)
1327            (eq (class-of class) *the-class-standard-class*))))
1328 \f
1329 ;;; What this does depends on which of the four possible values of
1330 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1331 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1332 ;;; nothing to do, as the new wrapper has already been created.  If
1333 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1334 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1335 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1336 ;;;
1337 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1338 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1339 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1340 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1341 ;;; obsolete the wrapper.
1342 ;;;
1343 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1344 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1345 ;;;                    :UNINITIALIZED)))
1346 ;;;
1347 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1348 (defun %force-cache-flushes (class)
1349   (let* ((owrapper (class-wrapper class)))
1350     ;; We only need to do something if the wrapper is still valid. If
1351     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1352     ;; both of those will already be doing what we want. In
1353     ;; particular, we must be sure we never change an OBSOLETE into a
1354     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1355     (when (or (not (invalid-wrapper-p owrapper))
1356               ;; KLUDGE: despite the observations above, this remains
1357               ;; a violation of locality or what might be considered
1358               ;; good style.  There has to be a better way!  -- CSR,
1359               ;; 2002-10-29
1360               (eq (layout-invalid owrapper) t))
1361       (let ((nwrapper (make-wrapper (layout-length owrapper)
1362                                     class)))
1363         (setf (wrapper-slots nwrapper)
1364               (wrapper-slots owrapper))
1365         (setf (wrapper-slot-table nwrapper)
1366               (wrapper-slot-table owrapper))
1367         (%update-lisp-class-layout class nwrapper)
1368         (setf (slot-value class 'wrapper) nwrapper)
1369         ;; Use :OBSOLETE instead of :FLUSH if any superclass has
1370         ;; been obsoleted.
1371         (if (find-if (lambda (x)
1372                        (and (consp x) (eq :obsolete (car x))))
1373                      (layout-inherits owrapper)
1374                      :key #'layout-invalid)
1375             (%invalidate-wrapper owrapper :obsolete nwrapper)
1376             (%invalidate-wrapper owrapper :flush nwrapper))))))
1377 \f
1378 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1379 ;;; the next access to the instance (as defined in 88-002R) to trap
1380 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1381 (defmethod make-instances-obsolete ((class std-class))
1382   (with-world-lock ()
1383     (let* ((owrapper (class-wrapper class))
1384            (nwrapper (make-wrapper (layout-length owrapper)
1385                                    class)))
1386       (unless (class-finalized-p class)
1387         (if (class-has-a-forward-referenced-superclass-p class)
1388             (return-from make-instances-obsolete class)
1389             (%update-cpl class (compute-class-precedence-list class))))
1390       (setf (wrapper-slots nwrapper)
1391             (wrapper-slots owrapper))
1392       (setf (wrapper-slot-table nwrapper)
1393             (wrapper-slot-table owrapper))
1394       (%update-lisp-class-layout class nwrapper)
1395       (setf (slot-value class 'wrapper) nwrapper)
1396       (%invalidate-wrapper owrapper :obsolete nwrapper)
1397       class)))
1398
1399 (defmethod make-instances-obsolete ((class symbol))
1400   (make-instances-obsolete (find-class class))
1401   ;; ANSI wants the class name when called with a symbol.
1402   class)
1403
1404 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1405 ;;; see an obsolete instance. The times when it is called are:
1406 ;;;   - when the instance is involved in method lookup
1407 ;;;   - when attempting to access a slot of an instance
1408 ;;;
1409 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1410 ;;; instance access macros.
1411 ;;;
1412 ;;; Of course these times when it is called are an internal
1413 ;;; implementation detail of PCL and are not part of the documented
1414 ;;; description of when the obsolete instance update happens. The
1415 ;;; documented description is as it appears in 88-002R.
1416 ;;;
1417 ;;; This has to return the new wrapper, so it counts on all the
1418 ;;; methods on obsolete-instance-trap-internal to return the new
1419 ;;; wrapper. It also does a little internal error checking to make
1420 ;;; sure that the traps are only happening when they should, and that
1421 ;;; the trap methods are computing appropriate new wrappers.
1422
1423 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1424 ;;; after a structure is redefined. In most cases,
1425 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1426 ;;; so it must signal an error. The hard part of this is that the
1427 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1428 ;;; called again, so in that case, we have to return some reasonable
1429 ;;; wrapper, instead.
1430
1431 (defvar *in-obsolete-instance-trap* nil)
1432 (defvar *the-wrapper-of-structure-object*
1433   (class-wrapper (find-class 'structure-object)))
1434
1435 (define-condition obsolete-structure (error)
1436   ((datum :reader obsolete-structure-datum :initarg :datum))
1437   (:report
1438    (lambda (condition stream)
1439      ;; Don't try to print the structure, since it probably won't work.
1440      (format stream
1441              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1442              (type-of (obsolete-structure-datum condition))))))
1443
1444 (defun %obsolete-instance-trap (owrapper nwrapper instance)
1445   (if (not (layout-for-std-class-p owrapper))
1446       (if *in-obsolete-instance-trap*
1447           *the-wrapper-of-structure-object*
1448           (let ((*in-obsolete-instance-trap* t))
1449             (error 'obsolete-structure :datum instance)))
1450       (let* ((class (wrapper-class* nwrapper))
1451              (copy (allocate-instance class)) ;??? allocate-instance ???
1452              (oslots (get-slots instance))
1453              (nslots (get-slots copy))
1454              (added ())
1455              (discarded ())
1456              (plist ())
1457              (safe (safe-p class)))
1458
1459         ;; local  --> local     transfer value, check type
1460         ;; local  --> shared    discard value, discard slot
1461         ;; local  -->  --       discard slot
1462         ;; local  --> custom    XXX
1463
1464         ;; shared --> local     transfer value, check type
1465         ;; shared --> shared    -- (cf SHARED-INITIALIZE :AFTER STD-CLASS)
1466         ;; shared -->  --       discard value
1467         ;; shared --> custom    XXX
1468
1469         ;;  --    --> local     add slot
1470         ;;  --    --> shared    --
1471         ;;  --    --> custom    XXX
1472
1473         (multiple-value-bind (new-instance-slots new-class-slots new-custom-slots)
1474             (classify-slotds (wrapper-slots nwrapper))
1475           (declare (ignore new-class-slots))
1476           (multiple-value-bind (old-instance-slots old-class-slots old-custom-slots)
1477               (classify-slotds (wrapper-slots owrapper))
1478
1479             (let ((layout (mapcar (lambda (slotd)
1480                                     ;; Get the names only once.
1481                                     (cons (slot-definition-name slotd) slotd))
1482                                   new-instance-slots)))
1483
1484               (flet ((set-value (value cell)
1485                        (let ((name (car cell))
1486                              (slotd (cdr cell)))
1487                          (when (and safe (neq value +slot-unbound+))
1488                            (let ((type (slot-definition-type slotd)))
1489                              (assert
1490                               (typep value type) (value)
1491                               "~@<Error updating obsolete instance. Current value in slot ~
1492                                ~S of an instance of ~S is ~S, which does not match the new ~
1493                                slot type ~S.~:@>"
1494                               name class value type)))
1495                          (setf (clos-slots-ref nslots (slot-definition-location slotd)) value
1496                                ;; Prune from the list now that it's been dealt with.
1497                                layout (remove cell layout)))))
1498
1499                 ;; Go through all the old local slots.
1500                 (dolist (old old-instance-slots)
1501                   (let* ((name (slot-definition-name old))
1502                          (value (clos-slots-ref oslots (slot-definition-location old))))
1503                     (unless (eq value +slot-unbound+)
1504                       (let ((new (assq name layout)))
1505                         (cond (new
1506                                (set-value value new))
1507                               (t
1508                                (push name discarded)
1509                                (setf (getf plist name) value)))))))
1510
1511                 ;; Go through all the old shared slots.
1512                 (dolist (old old-class-slots)
1513                   (let* ((cell (slot-definition-location old))
1514                          (name (car cell))
1515                          (new (assq name layout)))
1516                     (when new
1517                       (set-value (cdr cell) new))))
1518
1519                 ;; Go through all custom slots to find added ones. CLHS
1520                 ;; doesn't specify what to do about them, and neither does
1521                 ;; AMOP. We do want them to get initialized, though, so we
1522                 ;; list them in ADDED for the benefit of SHARED-INITIALIZE.
1523                 (dolist (new new-custom-slots)
1524                   (let* ((name (slot-definition-name new))
1525                          (old (find name old-custom-slots :key #'slot-definition-name)))
1526                     (unless old
1527                       (push name added))))
1528
1529                 ;; Go through all the remaining new local slots to compute the added slots.
1530                 (dolist (cell layout)
1531                   (push (car cell) added))))))
1532
1533         (%swap-wrappers-and-slots instance copy)
1534
1535         (update-instance-for-redefined-class instance
1536                                              added
1537                                              discarded
1538                                              plist)
1539         nwrapper)))
1540 \f
1541 (defun %change-class (instance new-class initargs)
1542   (let* ((old-class (class-of instance))
1543          (copy (allocate-instance new-class))
1544          (new-wrapper (get-wrapper copy))
1545          (old-wrapper (class-wrapper old-class))
1546          (old-slots (get-slots instance))
1547          (new-slots (get-slots copy))
1548          (safe (safe-p new-class)))
1549     (multiple-value-bind (new-instance-slots new-class-slots)
1550         (classify-slotds (wrapper-slots new-wrapper))
1551       (multiple-value-bind (old-instance-slots old-class-slots)
1552           (classify-slotds (wrapper-slots old-wrapper))
1553
1554         (flet ((set-value (value slotd)
1555                  (when safe
1556                    (assert (typep value (slot-definition-type slotd)) (value)
1557                            "~@<Error changing class. Current value in slot ~S ~
1558                             of an instance of ~S is ~S, which does not match the new ~
1559                             slot type ~S in class ~S.~:@>"
1560                            (slot-definition-name slotd) old-class value
1561                            (slot-definition-type slotd) new-class))
1562                  (setf (clos-slots-ref new-slots (slot-definition-location slotd)) value)))
1563
1564           ;; "The values of local slots specified by both the class CTO and
1565           ;; CFROM are retained. If such a local slot was unbound, it
1566           ;; remains unbound."
1567           (dolist (new new-instance-slots)
1568             (let* ((name (slot-definition-name new))
1569                    (old (find name old-instance-slots :key #'slot-definition-name)))
1570               (when old
1571                 (set-value (clos-slots-ref old-slots (slot-definition-location old))
1572                            new))))
1573
1574           ;; "The values of slots specified as shared in the class CFROM and
1575           ;; as local in the class CTO are retained."
1576           (dolist (old old-class-slots)
1577             (let* ((slot-and-val (slot-definition-location old))
1578                    (new (find (car slot-and-val) new-instance-slots
1579                               :key #'slot-definition-name)))
1580               (when new
1581                 (set-value (cdr slot-and-val) new)))))))
1582
1583     ;; Make the copy point to the old instance's storage, and make the
1584     ;; old instance point to the new storage.
1585     (%swap-wrappers-and-slots instance copy)
1586
1587     (apply #'update-instance-for-different-class copy instance initargs)
1588
1589     instance))
1590
1591 (defmethod change-class ((instance standard-object) (new-class standard-class)
1592                          &rest initargs)
1593   (with-world-lock ()
1594     (unless (class-finalized-p new-class)
1595       (finalize-inheritance new-class))
1596     (let ((cpl (class-precedence-list new-class)))
1597       (dolist (class cpl)
1598         (macrolet
1599             ((frob (class-name)
1600                `(when (eq class (find-class ',class-name))
1601                   (error 'metaobject-initialization-violation
1602                          :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1603                          :format-arguments (list 'change-class ',class-name)
1604                          :references (list '(:amop :initialization ,class-name))))))
1605           (frob class)
1606           (frob generic-function)
1607           (frob method)
1608           (frob slot-definition))))
1609     (%change-class instance new-class initargs)))
1610
1611 (defmethod change-class ((instance forward-referenced-class)
1612                          (new-class standard-class) &rest initargs)
1613   (with-world-lock ()
1614     (let ((cpl (class-precedence-list new-class)))
1615       (dolist (class cpl
1616                (error 'metaobject-initialization-violation
1617                       :format-control
1618                       "~@<Cannot ~S ~S objects into non-~S objects.~@:>"
1619                       :format-arguments
1620                       (list 'change-class 'forward-referenced-class 'class)
1621                       :references
1622                       (list '(:amop :generic-function ensure-class-using-class)
1623                             '(:amop :initialization class))))
1624         (when (eq class (find-class 'class))
1625           (return nil))))
1626     (%change-class instance new-class initargs)))
1627
1628 (defmethod change-class ((instance funcallable-standard-object)
1629                          (new-class funcallable-standard-class)
1630                          &rest initargs)
1631   (with-world-lock ()
1632     (let ((cpl (class-precedence-list new-class)))
1633       (dolist (class cpl)
1634         (macrolet
1635             ((frob (class-name)
1636                `(when (eq class (find-class ',class-name))
1637                   (error 'metaobject-initialization-violation
1638                          :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1639                          :format-arguments (list 'change-class ',class-name)
1640                          :references (list '(:amop :initialization ,class-name))))))
1641           (frob class)
1642           (frob generic-function)
1643           (frob method)
1644           (frob slot-definition))))
1645     (%change-class instance new-class initargs)))
1646
1647 (defmethod change-class ((instance standard-object)
1648                          (new-class funcallable-standard-class)
1649                          &rest initargs)
1650   (declare (ignore initargs))
1651   (error "You can't change the class of ~S to ~S~@
1652           because it isn't already an instance with metaclass ~S."
1653          instance new-class 'standard-class))
1654
1655 (defmethod change-class ((instance funcallable-standard-object)
1656                          (new-class standard-class)
1657                          &rest initargs)
1658   (declare (ignore initargs))
1659   (error "You can't change the class of ~S to ~S~@
1660           because it isn't already an instance with metaclass ~S."
1661          instance new-class 'funcallable-standard-class))
1662
1663 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1664   (apply #'change-class instance (find-class new-class-name) initargs))
1665 \f
1666 ;;;; The metaclass BUILT-IN-CLASS
1667 ;;;;
1668 ;;;; This metaclass is something of a weird creature. By this point, all
1669 ;;;; instances of it which will exist have been created, and no instance
1670 ;;;; is ever created by calling MAKE-INSTANCE.
1671 ;;;;
1672 ;;;; But, there are other parts of the protocol we must follow and those
1673 ;;;; definitions appear here.
1674
1675 (macrolet ((def (name args control)
1676                `(defmethod ,name ,args
1677                  (declare (ignore initargs))
1678                  (error 'metaobject-initialization-violation
1679                   :format-control ,(format nil "~@<~A~@:>" control)
1680                   :format-arguments (list ',name)
1681                   :references (list '(:amop :initialization "Class"))))))
1682   (def initialize-instance ((class built-in-class) &rest initargs)
1683     "Cannot ~S an instance of BUILT-IN-CLASS.")
1684   (def reinitialize-instance ((class built-in-class) &rest initargs)
1685     "Cannot ~S an instance of BUILT-IN-CLASS."))
1686
1687 (macrolet ((def (name)
1688                `(defmethod ,name ((class built-in-class)) nil)))
1689   (def class-direct-slots)
1690   (def class-slots)
1691   (def class-direct-default-initargs)
1692   (def class-default-initargs))
1693
1694 (defmethod validate-superclass ((c class) (s built-in-class))
1695   (or (eq s *the-class-t*) (eq s *the-class-stream*)
1696       ;; FIXME: bad things happen if someone tries to mix in both
1697       ;; FILE-STREAM and STRING-STREAM (as they have the same
1698       ;; layout-depthoid).  Is there any way we can provide a useful
1699       ;; error message?  -- CSR, 2005-05-03
1700       (eq s *the-class-file-stream*) (eq s *the-class-string-stream*)
1701       ;; This probably shouldn't be mixed in with certain other
1702       ;; classes, too, but it seems to work both with STANDARD-OBJECT
1703       ;; and FUNCALLABLE-STANDARD-OBJECT
1704       (eq s *the-class-sequence*)))
1705 \f
1706 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1707 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1708 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1709 (macrolet ((def (method)
1710              `(defmethod ,method ((class forward-referenced-class))
1711                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1712                        ',method class))))
1713   (def class-default-initargs)
1714   (def class-precedence-list)
1715   (def class-slots))
1716
1717 (defmethod validate-superclass ((c slot-class)
1718                                 (f forward-referenced-class))
1719   t)
1720 \f
1721 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1722   (pushnew dependent (plist-value metaobject 'dependents) :test #'eq))
1723
1724 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1725   (setf (plist-value metaobject 'dependents)
1726         (delete dependent (plist-value metaobject 'dependents))))
1727
1728 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1729   (dolist (dependent (plist-value metaobject 'dependents))
1730     (funcall function dependent)))
1731