src/pcl/std-class.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
  27   (let ((info (slot-definition-info slotd)))
  28     (ecase type
  29       (reader (slot-info-reader info))
  30       (writer (slot-info-writer info))
  31       (boundp (slot-info-boundp info)))))
  32
  33 (defmethod (setf slot-accessor-function) (function
  34                                           (slotd effective-slot-definition)
  35                                           type)
  36   (let ((info (slot-definition-info slotd)))
  37     (ecase type
  38       (reader (setf (slot-info-reader info) function))
  39       (writer (setf (slot-info-writer info) function))
  40       (boundp (setf (slot-info-boundp info) function)))))
  41
  42 (defconstant +slotd-reader-function-std-p+ 1)
  43 (defconstant +slotd-writer-function-std-p+ 2)
  44 (defconstant +slotd-boundp-function-std-p+ 4)
  45 (defconstant +slotd-all-function-std-p+ 7)
  46
  47 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
  48   (let ((flags (slot-value slotd 'accessor-flags)))
  49     (declare (type fixnum flags))
  50     (if (eq type 'all)
  51         (eql +slotd-all-function-std-p+ flags)
  52         (let ((mask (ecase type
  53                       (reader +slotd-reader-function-std-p+)
  54                       (writer +slotd-writer-function-std-p+)
  55                       (boundp +slotd-boundp-function-std-p+))))
  56           (declare (type fixnum mask))
  57           (not (zerop (the fixnum (logand mask flags))))))))
  58
  59 (defmethod (setf slot-accessor-std-p) (value
  60                                        (slotd effective-slot-definition)
  61                                        type)
  62   (let ((mask (ecase type
  63                 (reader +slotd-reader-function-std-p+)
  64                 (writer +slotd-writer-function-std-p+)
  65                 (boundp +slotd-boundp-function-std-p+)))
  66         (flags (slot-value slotd 'accessor-flags)))
  67     (declare (type fixnum mask flags))
  68     (setf (slot-value slotd 'accessor-flags)
  69           (if value
  70               (the fixnum (logior mask flags))
  71               (the fixnum (logand (the fixnum (lognot mask)) flags)))))
  72   value)
  73
  74 (defmethod initialize-internal-slot-functions
  75     ((slotd effective-slot-definition))
  76   (let* ((name (slot-value slotd 'name))
  77          (class (slot-value slotd '%class)))
  78     (dolist (type '(reader writer boundp))
  79       (let* ((gf-name (ecase type
  80                               (reader 'slot-value-using-class)
  81                               (writer '(setf slot-value-using-class))
  82                               (boundp 'slot-boundp-using-class)))
  83              (gf (gdefinition gf-name)))
  84         ;; KLUDGE: this logic is cut'n'pasted from
  85         ;; GET-ACCESSOR-METHOD-FUNCTION, which (for STD-CLASSes) is
  86         ;; only called later, because it does things that can't be
  87         ;; computed this early in class finalization; however, we need
  88         ;; this bit as early as possible.  -- CSR, 2009-11-05
  89         (setf (slot-accessor-std-p slotd type)
  90               (let* ((std-method (standard-svuc-method type))
  91                      (str-method (structure-svuc-method type))
  92                      (types1 `((eql ,class) (class-eq ,class) (eql ,slotd)))
  93                      (types (if (eq type 'writer) `(t ,@types1) types1))
  94                      (methods (compute-applicable-methods-using-types gf types)))
  95                 (null (cdr methods))))
  96         (setf (slot-accessor-function slotd type)
  97               (lambda (&rest args)
  98                 (declare (dynamic-extent args))
  99                 ;; FIXME: a tiny amount of wasted SLOT-ACCESSOR-STD-P
 100                 ;; work here (see KLUDGE comment above).
 101                 (let ((fun (compute-slot-accessor-info slotd type gf)))
 102                   (apply fun args))))))))
 103
 104 (defmethod finalize-internal-slot-functions ((slotd effective-slot-definition))
 105   (dolist (type '(reader writer boundp))
 106     (let* ((gf-name (ecase type
 107                       (reader 'slot-value-using-class)
 108                       (writer '(setf slot-value-using-class))
 109                       (boundp 'slot-boundp-using-class)))
 110            (gf (gdefinition gf-name)))
 111       (compute-slot-accessor-info slotd type gf))))
 112
 113 ;;; CMUCL (Gerd PCL 2003-04-25) comment:
 114 ;;;
 115 ;;; Compute an effective method for SLOT-VALUE-USING-CLASS, (SETF
 116 ;;; SLOT-VALUE-USING-CLASS) or SLOT-BOUNDP-USING-CLASS for reading/
 117 ;;; writing/testing effective slot SLOTD.
 118 ;;;
 119 ;;; TYPE is one of the symbols READER, WRITER or BOUNDP, depending on
 120 ;;; GF.  Store the effective method in the effective slot definition
 121 ;;; object itself; these GFs have special dispatch functions calling
 122 ;;; effective methods directly retrieved from effective slot
 123 ;;; definition objects, as an optimization.
 124 ;;;
 125 ;;; FIXME: Change the function name to COMPUTE-SVUC-SLOTD-FUNCTION,
 126 ;;; or some such.
 127 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition)
 128                                        type gf)
 129   (let* ((name (slot-value slotd 'name))
 130          (class (slot-value slotd '%class)))
 131     (multiple-value-bind (function std-p)
 132         (if (eq **boot-state** 'complete)
 133             (get-accessor-method-function gf type class slotd)
 134             (get-optimized-std-accessor-method-function class slotd type))
 135       (setf (slot-accessor-std-p slotd type) std-p)
 136       (setf (slot-accessor-function slotd type) function))))
 137
 138 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
 139   :instance)
 140 \f
 141 ;;;; various class accessors that are a little more complicated than can be
 142 ;;;; done with automatically generated reader methods
 143
 144 (defmethod class-prototype :before (class)
 145   (unless (class-finalized-p class)
 146     (error "~@<~S is not finalized.~:@>" class)))
 147
 148 ;;; KLUDGE: For some reason factoring the common body into a function
 149 ;;; breaks PCL bootstrapping, so just generate it with a macrolet for
 150 ;;; all.
 151 (macrolet ((def (class)
 152              `(defmethod class-prototype ((class ,class))
 153                 (with-slots (prototype) class
 154                   (or prototype
 155                       (setf prototype (allocate-instance class)))))))
 156   (def std-class)
 157   (def condition-class)
 158   (def structure-class))
 159
 160 (defmethod class-direct-default-initargs ((class slot-class))
 161   (plist-value class 'direct-default-initargs))
 162
 163 (defmethod class-default-initargs ((class slot-class))
 164   (plist-value class 'default-initargs))
 165
 166 (defmethod class-slot-cells ((class std-class))
 167   (plist-value class 'class-slot-cells))
 168 (defmethod (setf class-slot-cells) (new-value (class std-class))
 169   (setf (plist-value class 'class-slot-cells) new-value))
 170 \f
 171 ;;;; class accessors that are even a little bit more complicated than those
 172 ;;;; above. These have a protocol for updating them, we must implement that
 173 ;;;; protocol.
 174
 175 ;;; Maintaining the direct subclasses backpointers. The update methods are
 176 ;;; here, the values are read by an automatically generated reader method.
 177 (defmethod add-direct-subclass ((class class) (subclass class))
 178   (with-slots (direct-subclasses) class
 179     (pushnew subclass direct-subclasses :test #'eq)
 180     subclass))
 181 (defmethod remove-direct-subclass ((class class) (subclass class))
 182   (with-slots (direct-subclasses) class
 183     (setq direct-subclasses (remove subclass direct-subclasses))
 184     subclass))
 185
 186 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
 187 ;;;
 188 ;;; There are four generic functions involved, each has one method for the
 189 ;;; class case and another method for the damned EQL specializers. All of
 190 ;;; these are specified methods and appear in their specified place in the
 191 ;;; class graph.
 192 ;;;
 193 ;;;   ADD-DIRECT-METHOD
 194 ;;;   REMOVE-DIRECT-METHOD
 195 ;;;   SPECIALIZER-DIRECT-METHODS
 196 ;;;   SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
 197 ;;;
 198 ;;; In each case, we maintain one value which is a cons. The car is the list
 199 ;;; methods. The cdr is a list of the generic functions. The cdr is always
 200 ;;; computed lazily.
 201
 202 ;;; This needs to be used recursively, in case a non-trivial user
 203 ;;; defined ADD/REMOVE-DIRECT-METHOD method ends up calling another
 204 ;;; function using the same lock.
 205 (defvar *specializer-lock* (sb-thread:make-mutex :name "Specializer lock"))
 206
 207 (defmethod add-direct-method :around ((specializer specializer) method)
 208   ;; All the actions done under this lock are done in an order
 209   ;; that is safe to unwind at any point.
 210   (sb-thread::with-recursive-system-lock (*specializer-lock*)
 211     (call-next-method)))
 212
 213 (defmethod remove-direct-method :around ((specializer specializer) method)
 214   ;; All the actions done under this lock are done in an order
 215   ;; that is safe to unwind at any point.
 216   (sb-thread::with-recursive-system-lock (*specializer-lock*)
 217     (call-next-method)))
 218
 219 (defmethod add-direct-method ((specializer class) (method method))
 220   (let ((cell (slot-value specializer 'direct-methods)))
 221     ;; We need to first smash the CDR, because a parallel read may
 222     ;; be in progress, and because if an interrupt catches us we
 223     ;; need to have a consistent state.
 224     (setf (cdr cell) ()
 225           (car cell) (adjoin method (car cell) :test #'eq)))
 226   method)
 227
 228 (defmethod remove-direct-method ((specializer class) (method method))
 229   (let ((cell (slot-value specializer 'direct-methods)))
 230     ;; We need to first smash the CDR, because a parallel read may
 231     ;; be in progress, and because if an interrupt catches us we
 232     ;; need to have a consistent state.
 233     (setf (cdr cell) ()
 234           (car cell) (remove method (car cell))))
 235   method)
 236
 237 (defmethod specializer-direct-methods ((specializer class))
 238   (with-slots (direct-methods) specializer
 239     (car direct-methods)))
 240
 241 (defmethod specializer-direct-generic-functions ((specializer class))
 242   (let ((cell (slot-value specializer 'direct-methods)))
 243     ;; If an ADD/REMOVE-METHOD is in progress, no matter: either
 244     ;; we behave as if we got just first or just after -- it's just
 245     ;; for update that we need to lock.
 246     (or (cdr cell)
 247         (sb-thread:with-mutex (*specializer-lock*)
 248           (setf (cdr cell)
 249                 (let (collect)
 250                   (dolist (m (car cell))
 251                     ;; the old PCL code used COLLECTING-ONCE which used
 252                     ;; #'EQ to check for newness
 253                     (pushnew (method-generic-function m) collect :test #'eq))
 254                   (nreverse collect)))))))
 255 \f
 256 ;;; This hash table is used to store the direct methods and direct generic
 257 ;;; functions of EQL specializers. Each value in the table is the cons.
 258 ;;;
 259 ;;; These tables are shared between threads, so they need to be synchronized.
 260 (defvar *eql-specializer-methods* (make-hash-table :test 'eql :synchronized t))
 261 (defvar *class-eq-specializer-methods* (make-hash-table :test 'eq :synchronized t))
 262
 263 (defmethod specializer-method-table ((specializer eql-specializer))
 264   *eql-specializer-methods*)
 265
 266 (defmethod specializer-method-table ((specializer class-eq-specializer))
 267   *class-eq-specializer-methods*)
 268
 269 (defmethod add-direct-method ((specializer specializer-with-object)
 270                               (method method))
 271   (let* ((object (specializer-object specializer))
 272          (table (specializer-method-table specializer))
 273          (entry (gethash object table)))
 274     (unless entry
 275       (setf entry
 276             (setf (gethash object table) (cons nil nil))))
 277     ;; We need to first smash the CDR, because a parallel read may
 278     ;; be in progress, and because if an interrupt catches us we
 279     ;; need to have a consistent state.
 280     (setf (cdr entry) ()
 281           (car entry) (adjoin method (car entry) :test #'eq))
 282     method))
 283
 284 (defmethod remove-direct-method ((specializer specializer-with-object)
 285                                  (method method))
 286   (let* ((object (specializer-object specializer))
 287          (entry (gethash object (specializer-method-table specializer))))
 288     (when entry
 289       ;; We need to first smash the CDR, because a parallel read may
 290       ;; be in progress, and because if an interrupt catches us we
 291       ;; need to have a consistent state.
 292       (setf (cdr entry) ()
 293             (car entry) (remove method (car entry))))
 294     method))
 295
 296 (defmethod specializer-direct-methods ((specializer specializer-with-object))
 297   (car (gethash (specializer-object specializer)
 298                 (specializer-method-table specializer))))
 299
 300 (defmethod specializer-direct-generic-functions ((specializer
 301                                                   specializer-with-object))
 302   (let* ((object (specializer-object specializer))
 303          (entry (gethash object (specializer-method-table specializer))))
 304     (when entry
 305       (or (cdr entry)
 306           (sb-thread:with-mutex (*specializer-lock*)
 307             (setf (cdr entry)
 308                   (let (collect)
 309                     (dolist (m (car entry))
 310                       (pushnew (method-generic-function m) collect :test #'eq))
 311                     (nreverse collect))))))))
 312
 313 (defun map-specializers (function)
 314   (map-all-classes (lambda (class)
 315                      (funcall function (class-eq-specializer class))
 316                      (funcall function class)))
 317   (maphash (lambda (object methods)
 318              (declare (ignore methods))
 319              (intern-eql-specializer object))
 320            *eql-specializer-methods*)
 321   (maphash (lambda (object specl)
 322              (declare (ignore object))
 323              (funcall function specl))
 324            *eql-specializer-table*)
 325   nil)
 326
 327 (defun map-all-generic-functions (function)
 328   (let ((all-generic-functions (make-hash-table :test 'eq)))
 329     (map-specializers (lambda (specl)
 330                         (dolist (gf (specializer-direct-generic-functions
 331                                      specl))
 332                           (unless (gethash gf all-generic-functions)
 333                             (setf (gethash gf all-generic-functions) t)
 334                             (funcall function gf))))))
 335   nil)
 336
 337 (defmethod shared-initialize :after ((specl class-eq-specializer)
 338                                      slot-names
 339                                      &key)
 340   (declare (ignore slot-names))
 341   (setf (slot-value specl '%type) `(class-eq ,(specializer-class specl))))
 342
 343 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
 344   (declare (ignore slot-names))
 345   (setf (slot-value specl '%type)
 346         `(eql ,(specializer-object specl)))
 347   (setf (info :type :translator specl)
 348         (constantly (make-member-type :members (list (specializer-object specl))))))
 349
 350 (defun real-load-defclass (name metaclass-name supers slots other
 351                            readers writers slot-names source-location safe-p)
 352   (with-single-package-locked-error (:symbol name "defining ~S as a class")
 353     (%compiler-defclass name readers writers slot-names)
 354     (let ((res (apply #'ensure-class name :metaclass metaclass-name
 355                       :direct-superclasses supers
 356                       :direct-slots slots
 357                       :definition-source source-location
 358                       'safe-p safe-p
 359                       other)))
 360       res)))
 361
 362 (setf (gdefinition 'load-defclass) #'real-load-defclass)
 363
 364 (defun ensure-class (name &rest args)
 365   (with-world-lock ()
 366     (apply #'ensure-class-using-class
 367            (let ((class (find-class name nil)))
 368              (when (and class (eq name (class-name class)))
 369                ;; NAME is the proper name of CLASS, so redefine it
 370                class))
 371            name
 372            args)))
 373
 374 (defmethod ensure-class-using-class ((class null) name &rest args &key)
 375   (with-world-lock ()
 376     (multiple-value-bind (meta initargs)
 377         (frob-ensure-class-args args)
 378       (setf class (apply #'make-instance meta :name name initargs))
 379       (without-package-locks
 380         (setf (find-class name) class))))
 381   ;; After boot (SETF FIND-CLASS) does this.
 382   (unless (eq **boot-state** 'complete)
 383     (%set-class-type-translation class name))
 384   class)
 385
 386 (defmethod ensure-class-using-class ((class pcl-class) name &rest args &key)
 387   (with-world-lock ()
 388     (multiple-value-bind (meta initargs)
 389         (frob-ensure-class-args args)
 390       (unless (eq (class-of class) meta)
 391         (apply #'change-class class meta initargs))
 392       (apply #'reinitialize-instance class initargs)
 393       (without-package-locks
 394         (setf (find-class name) class))))
 395   ;; After boot (SETF FIND-CLASS) does this.
 396   (unless (eq **boot-state** 'complete)
 397     (%set-class-type-translation class name))
 398   class)
 399
 400 (defun frob-ensure-class-args (args)
 401   (let (metaclass metaclassp reversed-plist)
 402     (flet ((frob-superclass (s)
 403              (cond
 404                ((classp s) s)
 405                ((legal-class-name-p s)
 406                 (or (find-class s nil)
 407                     (ensure-class s :metaclass 'forward-referenced-class)))
 408                (t (error "Not a class or a legal class name: ~S." s)))))
 409       (doplist (key val) args
 410         (cond ((eq key :metaclass)
 411                (unless metaclassp
 412                  (setf metaclass val metaclassp key)))
 413               (t
 414                (when (eq key :direct-superclasses)
 415                  (setf val (mapcar #'frob-superclass val)))
 416                (setf reversed-plist (list* val key reversed-plist)))))
 417       (values (cond (metaclassp
 418                      (if (classp metaclass)
 419                          metaclass
 420                          (find-class metaclass)))
 421                     (t *the-class-standard-class*))
 422               (nreverse reversed-plist)))))
 423
 424 ;;; This is used to call initfunctions of :allocation :class slots.
 425 (defun call-initfun (fun slotd safe)
 426   (declare (function fun))
 427   (let ((value (funcall fun)))
 428     (when safe
 429       (let ((type (slot-definition-type slotd)))
 430         (unless (or (eq t type)
 431                     (typep value type))
 432           (error 'type-error :expected-type type :datum value))))
 433     value))
 434 \f
 435 (defmethod shared-initialize :after
 436     ((class std-class) slot-names &key
 437      (direct-superclasses nil direct-superclasses-p)
 438      (direct-slots nil direct-slots-p)
 439      (direct-default-initargs nil direct-default-initargs-p)
 440      definition-source)
 441   (cond (direct-superclasses-p
 442          (setq direct-superclasses
 443                (or direct-superclasses
 444                    (list (if (funcallable-standard-class-p class)
 445                              *the-class-funcallable-standard-object*
 446                              *the-class-standard-object*))))
 447          (dolist (superclass direct-superclasses)
 448            (unless (validate-superclass class superclass)
 449              (error "~@<The class ~S was specified as a ~
 450                      super-class of the class ~S, ~
 451                      but the meta-classes ~S and ~S are incompatible.  ~
 452                      Define a method for ~S to avoid this error.~@:>"
 453                     superclass class (class-of superclass) (class-of class)
 454                     'validate-superclass)))
 455          (setf (slot-value class 'direct-superclasses) direct-superclasses))
 456         (t
 457          (setq direct-superclasses (slot-value class 'direct-superclasses))))
 458   (setq direct-slots
 459         (if direct-slots-p
 460             (setf (slot-value class 'direct-slots)
 461                   (mapcar (lambda (pl) (make-direct-slotd class pl))
 462                           direct-slots))
 463             (slot-value class 'direct-slots)))
 464   (if direct-default-initargs-p
 465       (setf (plist-value class 'direct-default-initargs)
 466             direct-default-initargs)
 467       (setq direct-default-initargs
 468             (plist-value class 'direct-default-initargs)))
 469   (setf (plist-value class 'class-slot-cells)
 470         (let ((old-class-slot-cells (plist-value class 'class-slot-cells))
 471               (safe (safe-p class))
 472               (collect '()))
 473           (dolist (dslotd direct-slots)
 474             (when (eq :class (slot-definition-allocation dslotd))
 475               ;; see CLHS 4.3.6
 476               (let* ((name (slot-definition-name dslotd))
 477                      (old (assoc name old-class-slot-cells)))
 478                 (if (or (not old)
 479                         (eq t slot-names)
 480                         (member name slot-names :test #'eq))
 481                     (let* ((initfunction (slot-definition-initfunction dslotd))
 482                            (value
 483                             (if initfunction
 484                                 (call-initfun initfunction dslotd safe)
 485                                 +slot-unbound+)))
 486                       (push (cons name value) collect))
 487                     (push old collect)))))
 488           (nreverse collect)))
 489   (add-direct-subclasses class direct-superclasses)
 490   (if (class-finalized-p class)
 491       ;; required by AMOP, "Reinitialization of Class Metaobjects"
 492       (finalize-inheritance class)
 493       (update-class class nil))
 494   (add-slot-accessors class direct-slots definition-source)
 495   (make-preliminary-layout class))
 496
 497 (defmethod shared-initialize :after ((class forward-referenced-class)
 498                                      slot-names &key &allow-other-keys)
 499   (declare (ignore slot-names))
 500   (make-preliminary-layout class))
 501
 502 (defvar *allow-forward-referenced-classes-in-cpl-p* nil)
 503
 504 ;;; Give CLASS a preliminary layout if it doesn't have one already, to
 505 ;;; make it known to the type system.
 506 (defun make-preliminary-layout (class)
 507   (flet ((compute-preliminary-cpl (root)
 508            (let ((*allow-forward-referenced-classes-in-cpl-p* t))
 509              (compute-class-precedence-list root))))
 510     (with-world-lock ()
 511       (without-package-locks
 512         (unless (class-finalized-p class)
 513           (let ((name (class-name class)))
 514             ;; KLUDGE: This is fairly horrible.  We need to make a
 515             ;; full-fledged CLASSOID here, not just tell the compiler that
 516             ;; some class is forthcoming, because there are legitimate
 517             ;; questions one can ask of the type system, implemented in
 518             ;; terms of CLASSOIDs, involving forward-referenced classes. So.
 519             (let ((layout (make-wrapper 0 class)))
 520               (setf (slot-value class 'wrapper) layout)
 521               (let ((cpl (compute-preliminary-cpl class)))
 522                 (setf (layout-inherits layout)
 523                       (order-layout-inherits
 524                        (map 'simple-vector #'class-wrapper
 525                             (reverse (rest cpl))))))
 526               (register-layout layout :invalidate t)
 527               (%set-class-type-translation class (layout-classoid layout)))))
 528         (mapc #'make-preliminary-layout (class-direct-subclasses class))))))
 529
 530
 531 (defmethod shared-initialize :before ((class class) slot-names &key name)
 532   (declare (ignore slot-names name))
 533   ;; FIXME: Could this just be CLASS instead of `(CLASS ,CLASS)? If not,
 534   ;; why not? (See also similar expression in !BOOTSTRAP-INITIALIZE-CLASS.)
 535   (setf (slot-value class '%type) `(class ,class))
 536   (setf (slot-value class 'class-eq-specializer)
 537         (make-instance 'class-eq-specializer :class class)))
 538
 539 (defmethod reinitialize-instance :before ((class slot-class) &key direct-superclasses)
 540   (dolist (old-super (set-difference (class-direct-superclasses class) direct-superclasses))
 541     (remove-direct-subclass old-super class))
 542   (remove-slot-accessors class (class-direct-slots class)))
 543
 544 (defmethod reinitialize-instance :after ((class slot-class)
 545                                          &rest initargs
 546                                          &key)
 547   (map-dependents class
 548                   (lambda (dependent)
 549                     (apply #'update-dependent class dependent initargs))))
 550
 551 (defmethod reinitialize-instance :after ((class condition-class) &key)
 552   (let* ((name (class-name class))
 553          (classoid (find-classoid name))
 554          (slots (condition-classoid-slots classoid)))
 555     ;; to balance the REMOVE-SLOT-ACCESSORS call in
 556     ;; REINITIALIZE-INSTANCE :BEFORE (SLOT-CLASS).
 557     (dolist (slot slots)
 558       (let ((slot-name (condition-slot-name slot)))
 559         (dolist (reader (condition-slot-readers slot))
 560           ;; FIXME: see comment in SHARED-INITIALIZE :AFTER
 561           ;; (CONDITION-CLASS T), below.  -- CSR, 2005-11-18
 562           (sb-kernel::install-condition-slot-reader reader name slot-name))
 563         (dolist (writer (condition-slot-writers slot))
 564           (sb-kernel::install-condition-slot-writer writer name slot-name))))))
 565
 566 (defmethod shared-initialize :after ((class condition-class) slot-names
 567                                      &key direct-slots direct-superclasses)
 568   (declare (ignore slot-names))
 569   (let ((classoid (find-classoid (slot-value class 'name))))
 570     (with-slots (wrapper %class-precedence-list cpl-available-p
 571                          prototype (direct-supers direct-superclasses))
 572         class
 573       (setf (slot-value class 'direct-slots)
 574             (mapcar (lambda (pl) (make-direct-slotd class pl))
 575                     direct-slots))
 576       (setf (slot-value class 'finalized-p) t)
 577       (setf (classoid-pcl-class classoid) class)
 578       (setq direct-supers direct-superclasses)
 579       (setq wrapper (classoid-layout classoid))
 580       (setq %class-precedence-list (compute-class-precedence-list class))
 581       (setq cpl-available-p t)
 582       (add-direct-subclasses class direct-superclasses)
 583       (let ((slots (compute-slots class)))
 584         (setf (slot-value class 'slots) slots)
 585         (setf (layout-slot-table wrapper) (make-slot-table class slots)))))
 586   ;; Comment from Gerd's PCL, 2003-05-15:
 587   ;;
 588   ;; We don't ADD-SLOT-ACCESSORS here because we don't want to
 589   ;; override condition accessors with generic functions.  We do this
 590   ;; differently.
 591   ;;
 592   ;; ??? What does the above comment mean and why is it a good idea?
 593   ;; CMUCL (which still as of 2005-11-18 uses this code and has this
 594   ;; comment) loses slot information in its condition classes:
 595   ;; DIRECT-SLOTS is always NIL.  We have the right information, so we
 596   ;; remove slot accessors but never put them back.  I've added a
 597   ;; REINITIALIZE-INSTANCE :AFTER (CONDITION-CLASS) method, but what
 598   ;; was meant to happen?  -- CSR, 2005-11-18
 599   )
 600
 601 (defmethod direct-slot-definition-class ((class condition-class)
 602                                          &rest initargs)
 603   (declare (ignore initargs))
 604   (find-class 'condition-direct-slot-definition))
 605
 606 (defmethod effective-slot-definition-class ((class condition-class)
 607                                             &rest initargs)
 608   (declare (ignore initargs))
 609   (find-class 'condition-effective-slot-definition))
 610
 611 (defmethod finalize-inheritance ((class condition-class))
 612   (aver (slot-value class 'finalized-p))
 613   nil)
 614
 615 (defmethod compute-effective-slot-definition
 616     ((class condition-class) slot-name dslotds)
 617   (let* ((slotd (call-next-method))
 618          (info (slot-definition-info slotd)))
 619     (setf (slot-info-reader info)
 620           (lambda (x)
 621             (handler-case (condition-reader-function x slot-name)
 622               ;; FIXME: FIND-SLOT-DEFAULT throws an error if the slot
 623               ;; is unbound; maybe it should be a CELL-ERROR of some
 624               ;; sort?
 625               (error () (values (slot-unbound class x slot-name))))))
 626     (setf (slot-info-writer info)
 627           (lambda (v x)
 628             (condition-writer-function x v slot-name)))
 629     (setf (slot-info-boundp info)
 630           (lambda (x)
 631             (multiple-value-bind (v c)
 632                 (ignore-errors (condition-reader-function x slot-name))
 633               (declare (ignore v))
 634               (null c))))
 635     slotd))
 636
 637 (defmethod compute-slots ((class condition-class))
 638   (mapcan (lambda (superclass)
 639             (mapcar (lambda (dslotd)
 640                       (compute-effective-slot-definition
 641                        class (slot-definition-name dslotd) (list dslotd)))
 642                     (class-direct-slots superclass)))
 643           (reverse (slot-value class '%class-precedence-list))))
 644
 645 (defmethod compute-slots :around ((class condition-class))
 646   (let ((eslotds (call-next-method)))
 647     (mapc #'finalize-internal-slot-functions eslotds)
 648     eslotds))
 649
 650 (defmethod shared-initialize :after
 651     ((slotd structure-slot-definition) slot-names &key
 652      (allocation :instance) allocation-class)
 653   (declare (ignore slot-names allocation-class))
 654   (unless (eq allocation :instance)
 655     (error "Structure slots must have :INSTANCE allocation.")))
 656
 657 (defun make-structure-class-defstruct-form (name direct-slots include)
 658   (let* ((conc-name (format-symbol *package* "~S structure class " name))
 659          (constructor (format-symbol *package* "~Aconstructor" conc-name))
 660          (included-name (class-name include))
 661          (included-slots
 662           (when include
 663             (mapcar #'dsd-name (dd-slots (find-defstruct-description included-name)))))
 664          (old-slots nil)
 665          (new-slots nil)
 666          (reader-names nil)
 667          (writer-names nil))
 668     (dolist (slotd (reverse direct-slots))
 669       (let* ((slot-name (slot-definition-name slotd))
 670              (initform (slot-definition-initform slotd))
 671              (type (slot-definition-type slotd))
 672              (desc `(,slot-name ,initform :type ,type)))
 673         (push `(slot-accessor ,name ,slot-name reader)
 674               reader-names)
 675         (push `(slot-accessor ,name ,slot-name writer)
 676               writer-names)
 677         (if (member slot-name included-slots :test #'eq)
 678             (push desc old-slots)
 679             (push desc new-slots))))
 680     (let* ((defstruct `(defstruct (,name
 681                                     ,@(when include
 682                                             `((:include ,included-name
 683                                                         ,@old-slots)))
 684                                     (:constructor ,constructor ())
 685                                     (:predicate nil)
 686                                     (:conc-name ,conc-name)
 687                                     (:copier nil))
 688                          ,@new-slots))
 689            (readers-init
 690             (mapcar (lambda (slotd reader-name)
 691                       (let ((accessor
 692                              (slot-definition-defstruct-accessor-symbol
 693                               slotd)))
 694                         `(defun ,reader-name (obj)
 695                            (declare (type ,name obj))
 696                            (,accessor obj))))
 697                     direct-slots reader-names))
 698            (writers-init
 699             (mapcar (lambda (slotd writer-name)
 700                       (let ((accessor
 701                              (slot-definition-defstruct-accessor-symbol
 702                               slotd)))
 703                         `(defun ,writer-name (nv obj)
 704                            (declare (type ,name obj))
 705                            (setf (,accessor obj) nv))))
 706                     direct-slots writer-names))
 707            (defstruct-form
 708             `(progn
 709                ,defstruct
 710                ,@readers-init ,@writers-init
 711                (cons nil nil))))
 712       (values defstruct-form constructor reader-names writer-names))))
 713
 714 (defun make-defstruct-allocation-function (name)
 715   ;; FIXME: Why don't we go class->layout->info == dd
 716   (let ((dd (find-defstruct-description name)))
 717     (ecase (dd-type dd)
 718       (structure
 719        (%make-structure-instance-allocator dd nil))
 720       (funcallable-structure
 721        (%make-funcallable-structure-instance-allocator dd nil)))))
 722
 723 (defmethod shared-initialize :after
 724     ((class structure-class) slot-names &key
 725      (direct-superclasses nil direct-superclasses-p)
 726      (direct-slots nil direct-slots-p)
 727      direct-default-initargs
 728      definition-source)
 729   (declare (ignore slot-names direct-default-initargs))
 730   (if direct-superclasses-p
 731       (setf (slot-value class 'direct-superclasses)
 732             (or direct-superclasses
 733                 (setq direct-superclasses
 734                       (and (not (eq (slot-value class 'name) 'structure-object))
 735                            (list *the-class-structure-object*)))))
 736       (setq direct-superclasses (slot-value class 'direct-superclasses)))
 737   (let* ((name (slot-value class 'name))
 738          (from-defclass-p (slot-value class 'from-defclass-p))
 739          (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
 740     (if direct-slots-p
 741         (setf (slot-value class 'direct-slots)
 742               (setq direct-slots
 743                     (mapcar (lambda (pl)
 744                               (when defstruct-p
 745                                 (let* ((slot-name (getf pl :name))
 746                                        (accessor
 747                                         (format-symbol *package*
 748                                                        "~S structure class ~A"
 749                                                        name slot-name)))
 750                                   (setq pl (list* :defstruct-accessor-symbol
 751                                                   accessor pl))))
 752                               (make-direct-slotd class pl))
 753                             direct-slots)))
 754         (setq direct-slots (slot-value class 'direct-slots)))
 755     (if defstruct-p
 756         (let ((include (car (slot-value class 'direct-superclasses))))
 757           (multiple-value-bind (defstruct-form constructor reader-names writer-names)
 758               (make-structure-class-defstruct-form name direct-slots include)
 759             (unless (structure-type-p name) (eval defstruct-form))
 760             (mapc (lambda (dslotd reader-name writer-name)
 761                     (let* ((reader (gdefinition reader-name))
 762                            (writer (when (fboundp writer-name)
 763                                      (gdefinition writer-name))))
 764                       (setf (slot-value dslotd 'internal-reader-function)
 765                             reader)
 766                       (setf (slot-value dslotd 'internal-writer-function)
 767                             writer)))
 768                   direct-slots reader-names writer-names)
 769             (setf (slot-value class 'defstruct-form) defstruct-form)
 770             (setf (slot-value class 'defstruct-constructor) constructor)))
 771         (setf (slot-value class 'defstruct-constructor)
 772               ;; KLUDGE: not class; in fixup.lisp, can't access slots
 773               ;; outside methods yet.
 774               (make-defstruct-allocation-function name)))
 775     (add-direct-subclasses class direct-superclasses)
 776     (setf (slot-value class '%class-precedence-list)
 777           (compute-class-precedence-list class))
 778     (setf (slot-value class 'cpl-available-p) t)
 779     (let ((slots (compute-slots class)))
 780       (setf (slot-value class 'slots) slots)
 781       (let* ((lclass (find-classoid (slot-value class 'name)))
 782              (layout (classoid-layout lclass)))
 783         (setf (classoid-pcl-class lclass) class)
 784         (setf (slot-value class 'wrapper) layout)
 785         (setf (layout-slot-table layout) (make-slot-table class slots))))
 786     (setf (slot-value class 'finalized-p) t)
 787     (add-slot-accessors class direct-slots definition-source)))
 788
 789 (defmethod direct-slot-definition-class ((class structure-class) &rest initargs)
 790   (declare (ignore initargs))
 791   (find-class 'structure-direct-slot-definition))
 792
 793 (defmethod finalize-inheritance ((class structure-class))
 794   nil) ; always finalized
 795 \f
 796 (defun add-slot-accessors (class dslotds &optional source-location)
 797   (fix-slot-accessors class dslotds 'add source-location))
 798
 799 (defun remove-slot-accessors (class dslotds)
 800   (fix-slot-accessors class dslotds 'remove))
 801
 802 (defun fix-slot-accessors (class dslotds add/remove &optional source-location)
 803   (flet ((fix (gfspec name r/w doc)
 804            (let ((gf (cond ((eq add/remove 'add)
 805                             (or (find-generic-function gfspec nil)
 806                                 (ensure-generic-function
 807                                  gfspec :lambda-list (case r/w
 808                                                        (r '(object))
 809                                                        (w '(new-value object))))))
 810                            (t
 811                             (find-generic-function gfspec nil)))))
 812              (when gf
 813                (case r/w
 814                  (r (if (eq add/remove 'add)
 815                         (add-reader-method class gf name doc source-location)
 816                         (remove-reader-method class gf)))
 817                  (w (if (eq add/remove 'add)
 818                         (add-writer-method class gf name doc source-location)
 819                         (remove-writer-method class gf))))))))
 820     (dolist (dslotd dslotds)
 821       (let ((slot-name (slot-definition-name dslotd))
 822             (slot-doc (%slot-definition-documentation dslotd)))
 823         (dolist (r (slot-definition-readers dslotd))
 824           (fix r slot-name 'r slot-doc))
 825         (dolist (w (slot-definition-writers dslotd))
 826           (fix w slot-name 'w slot-doc))))))
 827 \f
 828 (defun add-direct-subclasses (class supers)
 829   (dolist (super supers)
 830     (unless (memq class (class-direct-subclasses class))
 831       (add-direct-subclass super class))))
 832
 833 (defmethod finalize-inheritance ((class std-class))
 834   (update-class class t))
 835
 836 (defmethod finalize-inheritance ((class forward-referenced-class))
 837   ;; FIXME: should we not be thinking a bit about what kinds of error
 838   ;; we're throwing?  Maybe we need a clos-error type to mix in?  Or
 839   ;; possibly a forward-referenced-class-error, though that's
 840   ;; difficult given e.g. class precedence list calculations...
 841   (error
 842    "~@<FINALIZE-INHERITANCE was called on a forward referenced class:~
 843        ~2I~_~S~:>"
 844    class))
 845
 846 \f
 847 (defun class-has-a-forward-referenced-superclass-p (class)
 848   (or (forward-referenced-class-p class)
 849       (some #'class-has-a-forward-referenced-superclass-p
 850             (class-direct-superclasses class))))
 851
 852 ;;; This is called by :after shared-initialize whenever a class is initialized
 853 ;;; or reinitialized. The class may or may not be finalized.
 854 (defun update-class (class finalizep)
 855   (without-package-locks
 856     (with-world-lock ()
 857       (when (or finalizep (class-finalized-p class))
 858         (%update-cpl class (compute-class-precedence-list class))
 859         ;; This invocation of UPDATE-SLOTS, in practice, finalizes the
 860         ;; class.
 861         (%update-slots class (compute-slots class))
 862         (update-gfs-of-class class)
 863         (setf (plist-value class 'default-initargs) (compute-default-initargs class))
 864         (update-ctors 'finalize-inheritance :class class))
 865       (dolist (sub (class-direct-subclasses class))
 866         (update-class sub nil)))))
 867
 868 (define-condition cpl-protocol-violation (reference-condition error)
 869   ((class :initarg :class :reader cpl-protocol-violation-class)
 870    (cpl :initarg :cpl :reader cpl-protocol-violation-cpl))
 871   (:default-initargs :references (list '(:sbcl :node "Metaobject Protocol")))
 872   (:report
 873    (lambda (c s)
 874      (format s "~@<Protocol violation: the ~S class ~S ~
 875                 ~:[has~;does not have~] the class ~S in its ~
 876                 class precedence list: ~S.~@:>"
 877              (class-name (class-of (cpl-protocol-violation-class c)))
 878              (cpl-protocol-violation-class c)
 879              (eq (class-of (cpl-protocol-violation-class c))
 880                  *the-class-funcallable-standard-class*)
 881              (find-class 'function)
 882              (cpl-protocol-violation-cpl c)))))
 883
 884 (defun %update-cpl (class cpl)
 885   (when (eq (class-of class) *the-class-standard-class*)
 886     (when (find (find-class 'function) cpl)
 887       (error 'cpl-protocol-violation :class class :cpl cpl)))
 888   (when (eq (class-of class) *the-class-funcallable-standard-class*)
 889     (unless (find (find-class 'function) cpl)
 890       (error 'cpl-protocol-violation :class class :cpl cpl)))
 891   (if (class-finalized-p class)
 892       (unless (and (equal (class-precedence-list class) cpl)
 893                    (dolist (c cpl t)
 894                      (when (position :class (class-direct-slots c)
 895                                      :key #'slot-definition-allocation)
 896                        (return nil))))
 897         ;; comment from the old CMU CL sources:
 898         ;;   Need to have the cpl setup before %update-lisp-class-layout
 899         ;;   is called on CMU CL.
 900         (setf (slot-value class '%class-precedence-list) cpl)
 901         (setf (slot-value class 'cpl-available-p) t)
 902         (%force-cache-flushes class))
 903       (progn
 904         (setf (slot-value class '%class-precedence-list) cpl)
 905         (setf (slot-value class 'cpl-available-p) t)))
 906   (update-class-can-precede-p cpl))
 907
 908 (defun update-class-can-precede-p (cpl)
 909   (when cpl
 910     (let ((first (car cpl)))
 911       (dolist (c (cdr cpl))
 912         (pushnew c (slot-value first 'can-precede-list) :test #'eq)))
 913     (update-class-can-precede-p (cdr cpl))))
 914
 915 (defun class-can-precede-p (class1 class2)
 916   (member class2 (class-can-precede-list class1) :test #'eq))
 917
 918 ;;; This is called from %UPDATE-SLOTS to check if slot layouts are compatible.
 919 ;;;
 920 ;;; In addition to slot locations (implicit in the ordering of the slots), we
 921 ;;; must check classes: SLOT-INFO structures from old slotds may have been
 922 ;;; cached in permutation vectors, but new slotds have had new ones allocated
 923 ;;; to them. This is non-problematic for standard slotds, because we know the
 924 ;;; structure is compatible, but if a slot definition class changes, this can
 925 ;;; change the way SLOT-VALUE-USING-CLASS should dispatch.
 926 ;;;
 927 ;;; Also, if the slot has a non-standard allocation, we need to check that it
 928 ;;; doesn't change.
 929 (defun slot-layouts-compatible-p
 930     (oslotds new-instance-slotds new-class-slotds new-custom-slotds)
 931   (multiple-value-bind (old-instance-slotds old-class-slotds old-custom-slotds)
 932       (classify-slotds oslotds)
 933     (and
 934      ;; Instance slots: name, type, and class.
 935      (dolist (o old-instance-slotds (not new-instance-slotds))
 936        (let ((n (pop new-instance-slotds)))
 937          (unless (and n
 938                       (eq (slot-definition-name o) (slot-definition-name n))
 939                       (eq (slot-definition-type o) (slot-definition-type n))
 940                       (eq (class-of o) (class-of n)))
 941            (return nil))))
 942      ;; Class slots: name and class. (FIXME: class slots not typechecked?)
 943      (dolist (o old-class-slotds (not new-class-slotds))
 944        (let ((n (pop new-class-slotds)))
 945          (unless (and n
 946                       (eq (slot-definition-name o) (slot-definition-name n))
 947                       (eq (class-of n) (class-of o)))
 948            (return nil))))
 949      ;; Custom slots: check name, type, allocation, and class. (FIXME: should we just punt?)
 950      (dolist (o old-custom-slotds (not new-custom-slotds))
 951        (let ((n (pop new-custom-slotds)))
 952          (unless (and n
 953                       (eq (slot-definition-name o) (slot-definition-name n))
 954                       (eq (slot-definition-type o) (slot-definition-type n))
 955                       (eq (slot-definition-allocation o) (slot-definition-allocation n))
 956                       (eq (class-of o) (class-of n)))
 957            (return nil)))))))
 958
 959 (defun %update-slots (class eslotds)
 960   (multiple-value-bind (instance-slots class-slots custom-slots)
 961       (classify-slotds eslotds)
 962     (let* ((nslots (length instance-slots))
 963            (owrapper (when (class-finalized-p class) (class-wrapper class)))
 964            (nwrapper
 965              (cond ((null owrapper)
 966                     (make-wrapper nslots class))
 967                    ((slot-layouts-compatible-p (wrapper-slots owrapper)
 968                                                instance-slots class-slots custom-slots)
 969                     owrapper)
 970                    (t
 971                     ;; This will initialize the new wrapper to have the
 972                     ;; same state as the old wrapper. We will then have
 973                     ;; to change that. This may seem like wasted work
 974                     ;; (and it is), but the spec requires that we call
 975                     ;; MAKE-INSTANCES-OBSOLETE.
 976                     (make-instances-obsolete class)
 977                     (class-wrapper class)))))
 978       (%update-lisp-class-layout class nwrapper)
 979       (setf (slot-value class 'slots) eslotds
 980             (wrapper-slots nwrapper) eslotds
 981             (wrapper-slot-table nwrapper) (make-slot-table class eslotds)
 982             (wrapper-length nwrapper) nslots
 983             (slot-value class 'wrapper) nwrapper)
 984       (do* ((slots (slot-value class 'slots) (cdr slots))
 985             (dupes nil))
 986            ((null slots)
 987             (when dupes
 988               (style-warn
 989                "~@<slot names with the same SYMBOL-NAME but ~
 990                   different SYMBOL-PACKAGE (possible package problem) ~
 991                   for class ~S:~4I~@:_~<~@{~/sb-impl::print-symbol-with-prefix/~^~:@_~}~:>~@:>"
 992                class dupes)))
 993         (let* ((slot (car slots))
 994                (oslots (remove (slot-definition-name slot) (cdr slots)
 995                                :test #'string/=
 996                                :key #'slot-definition-name)))
 997           (when oslots
 998             (pushnew (cons (slot-definition-name slot)
 999                            (mapcar #'slot-definition-name oslots))
1000                      dupes
1001                      :test #'string= :key #'car))))
1002       (setf (slot-value class 'finalized-p) t)
1003       (unless (eq owrapper nwrapper)
1004         (maybe-update-standard-slot-locations class)))))
1005
1006 (defun update-gf-dfun (class gf)
1007   (let ((*new-class* class)
1008         (arg-info (gf-arg-info gf)))
1009     (cond
1010       ((special-case-for-compute-discriminating-function-p gf))
1011       ((gf-precompute-dfun-and-emf-p arg-info)
1012        (multiple-value-bind (dfun cache info) (make-final-dfun-internal gf)
1013          (update-dfun gf dfun cache info))))))
1014
1015 (defun update-gfs-of-class (class)
1016   (when (and (class-finalized-p class)
1017              (let ((cpl (class-precedence-list class)))
1018                (or (member *the-class-slot-class* cpl :test #'eq)
1019                    (member *the-class-standard-effective-slot-definition*
1020                            cpl :test #'eq))))
1021     (let ((gf-table (make-hash-table :test 'eq)))
1022       (labels ((collect-gfs (class)
1023                  (dolist (gf (specializer-direct-generic-functions class))
1024                    (setf (gethash gf gf-table) t))
1025                  (mapc #'collect-gfs (class-direct-superclasses class))))
1026         (collect-gfs class)
1027         (maphash (lambda (gf ignore)
1028                    (declare (ignore ignore))
1029                    (update-gf-dfun class gf))
1030                  gf-table)))))
1031 \f
1032 (defmethod compute-default-initargs ((class slot-class))
1033   (let ((initargs (loop for c in (class-precedence-list class)
1034                         append (class-direct-default-initargs c))))
1035     (delete-duplicates initargs :test #'eq :key #'car :from-end t)))
1036 \f
1037 ;;;; protocols for constructing direct and effective slot definitions
1038
1039 (defmethod direct-slot-definition-class ((class std-class) &rest initargs)
1040   (declare (ignore initargs))
1041   (find-class 'standard-direct-slot-definition))
1042
1043 (defun make-direct-slotd (class initargs)
1044   (apply #'make-instance
1045          (apply #'direct-slot-definition-class class initargs)
1046          :class class
1047          initargs))
1048
1049 ;;; I (CSR) am not sure, but I believe that the particular order of
1050 ;;; slots is quite important: it is ideal to attempt to have a
1051 ;;; constant slot location for the same notional slots as much as
1052 ;;; possible, so that clever discriminating functions (ONE-INDEX et
1053 ;;; al.) have a chance of working.  The below at least walks through
1054 ;;; the slots predictably, but maybe it would be good to compute some
1055 ;;; kind of optimal slot layout by looking at locations of slots in
1056 ;;; superclasses?
1057 (defun std-compute-slots (class)
1058   ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
1059   ;; for each different slot name we find in our superclasses. Each
1060   ;; call receives the class and a list of the dslotds with that name.
1061   ;; The list is in most-specific-first order.
1062   (let ((name-dslotds-alist ()))
1063     (dolist (c (reverse (class-precedence-list class)))
1064       (dolist (slot (class-direct-slots c))
1065         (let* ((name (slot-definition-name slot))
1066                (entry (assq name name-dslotds-alist)))
1067           (if entry
1068               (push slot (cdr entry))
1069               (push (list name slot) name-dslotds-alist)))))
1070     (mapcar (lambda (direct)
1071               (compute-effective-slot-definition class
1072                                                  (car direct)
1073                                                  (cdr direct)))
1074             (nreverse name-dslotds-alist))))
1075
1076 (defmethod compute-slots ((class standard-class))
1077   (std-compute-slots class))
1078 (defmethod compute-slots ((class funcallable-standard-class))
1079   (std-compute-slots class))
1080
1081 (defun std-compute-slots-around (class eslotds)
1082   (let ((location -1)
1083         (safe (safe-p class)))
1084     (dolist (eslotd eslotds eslotds)
1085       (setf (slot-definition-location eslotd)
1086             (case (slot-definition-allocation eslotd)
1087               (:instance
1088                (incf location))
1089               (:class
1090                (let* ((name (slot-definition-name eslotd))
1091                       (from-class
1092                        (or
1093                         (slot-definition-allocation-class eslotd)
1094                         ;; we get here if the user adds an extra slot
1095                         ;; himself...
1096                         (setf (slot-definition-allocation-class eslotd)
1097                               class)))
1098                       ;; which raises the question of what we should
1099                       ;; do if we find that said user has added a slot
1100                       ;; with the same name as another slot...
1101                       (cell (or (assq name (class-slot-cells from-class))
1102                                 (let ((c (cons name +slot-unbound+)))
1103                                   (push c (class-slot-cells from-class))
1104                                   c))))
1105                  (aver (consp cell))
1106                  (if (eq +slot-unbound+ (cdr cell))
1107                      ;; We may have inherited an initfunction FIXME: Is this
1108                      ;; really right? Is the initialization in
1109                      ;; SHARED-INITIALIZE (STD-CLASS) not enough?
1110                      (let ((initfun (slot-definition-initfunction eslotd)))
1111                        (if initfun
1112                            (rplacd cell (call-initfun initfun eslotd safe))
1113                            cell))
1114                      cell)))))
1115       (unless (slot-definition-class eslotd)
1116         (setf (slot-definition-class eslotd) class))
1117       (initialize-internal-slot-functions eslotd))))
1118
1119 (defmethod compute-slots :around ((class standard-class))
1120   (let ((eslotds (call-next-method)))
1121     (std-compute-slots-around class eslotds)))
1122 (defmethod compute-slots :around ((class funcallable-standard-class))
1123   (let ((eslotds (call-next-method)))
1124     (std-compute-slots-around class eslotds)))
1125
1126 (defmethod compute-slots ((class structure-class))
1127   (mapcan (lambda (superclass)
1128             (mapcar (lambda (dslotd)
1129                       (compute-effective-slot-definition
1130                        class
1131                        (slot-definition-name dslotd)
1132                        (list dslotd)))
1133                     (class-direct-slots superclass)))
1134           (reverse (slot-value class '%class-precedence-list))))
1135
1136 (defmethod compute-slots :around ((class structure-class))
1137   (let ((eslotds (call-next-method)))
1138     (mapc #'finalize-internal-slot-functions eslotds)
1139     eslotds))
1140
1141 (defmethod compute-effective-slot-definition ((class slot-class) name dslotds)
1142   (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
1143          (class (apply #'effective-slot-definition-class class initargs))
1144          (slotd (apply #'make-instance class initargs)))
1145     slotd))
1146
1147 (defmethod effective-slot-definition-class ((class std-class) &rest initargs)
1148   (declare (ignore initargs))
1149   (find-class 'standard-effective-slot-definition))
1150
1151 (defmethod effective-slot-definition-class ((class structure-class) &rest initargs)
1152   (declare (ignore initargs))
1153   (find-class 'structure-effective-slot-definition))
1154
1155 (defmethod compute-effective-slot-definition-initargs
1156     ((class slot-class) direct-slotds)
1157   (let* ((name nil)
1158          (initfunction nil)
1159          (initform nil)
1160          (initargs nil)
1161          (allocation nil)
1162          (allocation-class nil)
1163          (type t)
1164          (documentation nil)
1165          (documentationp nil)
1166          (namep  nil)
1167          (initp  nil)
1168          (allocp nil))
1169
1170     (dolist (slotd direct-slotds)
1171       (when slotd
1172         (unless namep
1173           (setq name (slot-definition-name slotd)
1174                 namep t))
1175         (unless initp
1176           (awhen (slot-definition-initfunction slotd)
1177             (setq initform (slot-definition-initform slotd)
1178                   initfunction it
1179                   initp t)))
1180         (unless documentationp
1181           (awhen (%slot-definition-documentation slotd)
1182             (setq documentation it
1183                   documentationp t)))
1184         (unless allocp
1185           (setq allocation (slot-definition-allocation slotd)
1186                 allocation-class (slot-definition-class slotd)
1187                 allocp t))
1188         (setq initargs (append (slot-definition-initargs slotd) initargs))
1189         (let ((slotd-type (slot-definition-type slotd)))
1190           (setq type (cond
1191                        ((eq type t) slotd-type)
1192                        ;; This pairwise type intersection is perhaps a
1193                        ;; little inefficient and inelegant, but it's
1194                        ;; unlikely to lie on the critical path.  Shout
1195                        ;; if I'm wrong.  -- CSR, 2005-11-24
1196                        (t (type-specifier
1197                            (specifier-type `(and ,type ,slotd-type)))))))))
1198     (list :name name
1199           :initform initform
1200           :initfunction initfunction
1201           :initargs initargs
1202           :allocation allocation
1203           :allocation-class allocation-class
1204           :type type
1205           :class class
1206           :documentation documentation)))
1207
1208 (defmethod compute-effective-slot-definition-initargs :around
1209     ((class structure-class) direct-slotds)
1210   (let* ((slotd (car direct-slotds))
1211          (accessor (slot-definition-defstruct-accessor-symbol slotd)))
1212     (list* :defstruct-accessor-symbol accessor
1213            :internal-reader-function
1214            (slot-definition-internal-reader-function slotd)
1215            :internal-writer-function
1216            (slot-definition-internal-writer-function slotd)
1217            (call-next-method))))
1218 \f
1219 ;;; NOTE: For bootstrapping considerations, these can't use MAKE-INSTANCE
1220 ;;;       to make the method object. They have to use make-a-method which
1221 ;;;       is a specially bootstrapped mechanism for making standard methods.
1222 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
1223   (declare (ignore direct-slot initargs))
1224   (find-class 'standard-reader-method))
1225
1226 (defmethod add-reader-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1227   (add-method generic-function
1228               (make-a-method 'standard-reader-method
1229                              ()
1230                              (list (or (class-name class) 'object))
1231                              (list class)
1232                              (make-reader-method-function class slot-name)
1233                              (or slot-documentation "automatically generated reader method")
1234                              :slot-name slot-name
1235                              :object-class class
1236                              :method-class-function #'reader-method-class
1237                              :definition-source source-location)))
1238
1239 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
1240   (declare (ignore direct-slot initargs))
1241   (find-class 'standard-writer-method))
1242
1243 (defmethod add-writer-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1244   (add-method generic-function
1245               (make-a-method 'standard-writer-method
1246                              ()
1247                              (list 'new-value (or (class-name class) 'object))
1248                              (list *the-class-t* class)
1249                              (make-writer-method-function class slot-name)
1250                              (or slot-documentation "automatically generated writer method")
1251                              :slot-name slot-name
1252                              :object-class class
1253                              :method-class-function #'writer-method-class
1254                              :definition-source source-location)))
1255
1256 (defmethod add-boundp-method ((class slot-class) generic-function slot-name slot-documentation source-location)
1257   (add-method generic-function
1258               (make-a-method (constantly (find-class 'standard-boundp-method))
1259                              class
1260                              ()
1261                              (list (or (class-name class) 'object))
1262                              (list class)
1263                              (make-boundp-method-function class slot-name)
1264                              (or slot-documentation "automatically generated boundp method")
1265                              :slot-name slot-name
1266                              :definition-source source-location)))
1267
1268 (defmethod remove-reader-method ((class slot-class) generic-function)
1269   (let ((method (get-method generic-function () (list class) nil)))
1270     (when method (remove-method generic-function method))))
1271
1272 (defmethod remove-writer-method ((class slot-class) generic-function)
1273   (let ((method
1274           (get-method generic-function () (list *the-class-t* class) nil)))
1275     (when method (remove-method generic-function method))))
1276
1277 (defmethod remove-boundp-method ((class slot-class) generic-function)
1278   (let ((method (get-method generic-function () (list class) nil)))
1279     (when method (remove-method generic-function method))))
1280 \f
1281 ;;; MAKE-READER-METHOD-FUNCTION and MAKE-WRITER-METHOD-FUNCTION
1282 ;;; function are NOT part of the standard protocol. They are however
1283 ;;; useful; PCL makes use of them internally and documents them for
1284 ;;; PCL users.  (FIXME: but SBCL certainly doesn't)
1285 ;;;
1286 ;;; *** This needs work to make type testing by the writer functions which
1287 ;;; *** do type testing faster. The idea would be to have one constructor
1288 ;;; *** for each possible type test.
1289 ;;;
1290 ;;; *** There is a subtle bug here which is going to have to be fixed.
1291 ;;; *** Namely, the simplistic use of the template has to be fixed. We
1292 ;;; *** have to give the OPTIMIZE-SLOT-VALUE method the user might have
1293 ;;; *** defined for this metaclass a chance to run.
1294
1295 (defmethod make-reader-method-function ((class slot-class) slot-name)
1296   (make-std-reader-method-function class slot-name))
1297
1298 (defmethod make-writer-method-function ((class slot-class) slot-name)
1299   (make-std-writer-method-function class slot-name))
1300
1301 (defmethod make-boundp-method-function ((class slot-class) slot-name)
1302   (make-std-boundp-method-function class slot-name))
1303 \f
1304 (defmethod compatible-meta-class-change-p (class proto-new-class)
1305   (eq (class-of class) (class-of proto-new-class)))
1306
1307 (defmethod validate-superclass ((class class) (superclass class))
1308   (or (eq superclass *the-class-t*)
1309       (eq (class-of class) (class-of superclass))
1310       (and (eq (class-of superclass) *the-class-standard-class*)
1311            (eq (class-of class) *the-class-funcallable-standard-class*))
1312       (and (eq (class-of superclass) *the-class-funcallable-standard-class*)
1313            (eq (class-of class) *the-class-standard-class*))))
1314 \f
1315 ;;; What this does depends on which of the four possible values of
1316 ;;; LAYOUT-INVALID the PCL wrapper has; the simplest case is when it
1317 ;;; is (:FLUSH <wrapper>) or (:OBSOLETE <wrapper>), when there is
1318 ;;; nothing to do, as the new wrapper has already been created.  If
1319 ;;; LAYOUT-INVALID returns NIL, then we invalidate it (setting it to
1320 ;;; (:FLUSH <wrapper>); UPDATE-SLOTS later gets to choose whether or
1321 ;;; not to "upgrade" this to (:OBSOLETE <wrapper>).
1322 ;;;
1323 ;;; This leaves the case where LAYOUT-INVALID returns T, which happens
1324 ;;; when REGISTER-LAYOUT has invalidated a superclass of CLASS (which
1325 ;;; invalidated all the subclasses in SB-KERNEL land).  Again, here we
1326 ;;; must flush the caches and allow UPDATE-SLOTS to decide whether to
1327 ;;; obsolete the wrapper.
1328 ;;;
1329 ;;; FIXME: either here or in INVALID-WRAPPER-P looks like a good place
1330 ;;; for (AVER (NOT (EQ (LAYOUT-INVALID OWRAPPER)
1331 ;;;                    :UNINITIALIZED)))
1332 ;;;
1333 ;;; Thanks to Gerd Moellmann for the explanation.  -- CSR, 2002-10-29
1334 (defun %force-cache-flushes (class)
1335   (let* ((owrapper (class-wrapper class)))
1336     ;; We only need to do something if the wrapper is still valid. If
1337     ;; the wrapper isn't valid, state will be FLUSH or OBSOLETE, and
1338     ;; both of those will already be doing what we want. In
1339     ;; particular, we must be sure we never change an OBSOLETE into a
1340     ;; FLUSH since OBSOLETE means do what FLUSH does and then some.
1341     (when (or (not (invalid-wrapper-p owrapper))
1342               ;; KLUDGE: despite the observations above, this remains
1343               ;; a violation of locality or what might be considered
1344               ;; good style.  There has to be a better way!  -- CSR,
1345               ;; 2002-10-29
1346               (eq (layout-invalid owrapper) t))
1347       (let ((nwrapper (make-wrapper (layout-length owrapper)
1348                                     class)))
1349         (setf (wrapper-slots nwrapper)
1350               (wrapper-slots owrapper))
1351         (setf (wrapper-slot-table nwrapper)
1352               (wrapper-slot-table owrapper))
1353         (%update-lisp-class-layout class nwrapper)
1354         (setf (slot-value class 'wrapper) nwrapper)
1355         ;; Use :OBSOLETE instead of :FLUSH if any superclass has
1356         ;; been obsoleted.
1357         (if (find-if (lambda (x)
1358                        (and (consp x) (eq :obsolete (car x))))
1359                      (layout-inherits owrapper)
1360                      :key #'layout-invalid)
1361             (%invalidate-wrapper owrapper :obsolete nwrapper)
1362             (%invalidate-wrapper owrapper :flush nwrapper))))))
1363 \f
1364 ;;; MAKE-INSTANCES-OBSOLETE can be called by user code. It will cause
1365 ;;; the next access to the instance (as defined in 88-002R) to trap
1366 ;;; through the UPDATE-INSTANCE-FOR-REDEFINED-CLASS mechanism.
1367 (defmethod make-instances-obsolete ((class std-class))
1368   (with-world-lock ()
1369     (let* ((owrapper (class-wrapper class))
1370            (nwrapper (make-wrapper (layout-length owrapper)
1371                                    class)))
1372       (unless (class-finalized-p class)
1373         (if (class-has-a-forward-referenced-superclass-p class)
1374             (return-from make-instances-obsolete class)
1375             (%update-cpl class (compute-class-precedence-list class))))
1376       (setf (wrapper-slots nwrapper)
1377             (wrapper-slots owrapper))
1378       (setf (wrapper-slot-table nwrapper)
1379             (wrapper-slot-table owrapper))
1380       (%update-lisp-class-layout class nwrapper)
1381       (setf (slot-value class 'wrapper) nwrapper)
1382       (%invalidate-wrapper owrapper :obsolete nwrapper)
1383       class)))
1384
1385 (defmethod make-instances-obsolete ((class symbol))
1386   (make-instances-obsolete (find-class class))
1387   ;; ANSI wants the class name when called with a symbol.
1388   class)
1389
1390 ;;; OBSOLETE-INSTANCE-TRAP is the internal trap that is called when we
1391 ;;; see an obsolete instance. The times when it is called are:
1392 ;;;   - when the instance is involved in method lookup
1393 ;;;   - when attempting to access a slot of an instance
1394 ;;;
1395 ;;; It is not called by class-of, wrapper-of, or any of the low-level
1396 ;;; instance access macros.
1397 ;;;
1398 ;;; Of course these times when it is called are an internal
1399 ;;; implementation detail of PCL and are not part of the documented
1400 ;;; description of when the obsolete instance update happens. The
1401 ;;; documented description is as it appears in 88-002R.
1402 ;;;
1403 ;;; This has to return the new wrapper, so it counts on all the
1404 ;;; methods on obsolete-instance-trap-internal to return the new
1405 ;;; wrapper. It also does a little internal error checking to make
1406 ;;; sure that the traps are only happening when they should, and that
1407 ;;; the trap methods are computing appropriate new wrappers.
1408
1409 ;;; OBSOLETE-INSTANCE-TRAP might be called on structure instances
1410 ;;; after a structure is redefined. In most cases,
1411 ;;; OBSOLETE-INSTANCE-TRAP will not be able to fix the old instance,
1412 ;;; so it must signal an error. The hard part of this is that the
1413 ;;; error system and debugger might cause OBSOLETE-INSTANCE-TRAP to be
1414 ;;; called again, so in that case, we have to return some reasonable
1415 ;;; wrapper, instead.
1416
1417 (defvar *in-obsolete-instance-trap* nil)
1418 (defvar *the-wrapper-of-structure-object*
1419   (class-wrapper (find-class 'structure-object)))
1420
1421 (define-condition obsolete-structure (error)
1422   ((datum :reader obsolete-structure-datum :initarg :datum))
1423   (:report
1424    (lambda (condition stream)
1425      ;; Don't try to print the structure, since it probably won't work.
1426      (format stream
1427              "~@<obsolete structure error for a structure of type ~2I~_~S~:>"
1428              (type-of (obsolete-structure-datum condition))))))
1429
1430 (defun %obsolete-instance-trap (owrapper nwrapper instance)
1431   (if (not (layout-for-std-class-p owrapper))
1432       (if *in-obsolete-instance-trap*
1433           *the-wrapper-of-structure-object*
1434           (let ((*in-obsolete-instance-trap* t))
1435             (error 'obsolete-structure :datum instance)))
1436       (let* ((class (wrapper-class* nwrapper))
1437              (copy (allocate-instance class)) ;??? allocate-instance ???
1438              (oslots (get-slots instance))
1439              (nslots (get-slots copy))
1440              (added ())
1441              (discarded ())
1442              (plist ())
1443              (safe (safe-p class)))
1444
1445         ;; local  --> local     transfer value, check type
1446         ;; local  --> shared    discard value, discard slot
1447         ;; local  -->  --       discard slot
1448         ;; local  --> custom    XXX
1449
1450         ;; shared --> local     transfer value, check type
1451         ;; shared --> shared    -- (cf SHARED-INITIALIZE :AFTER STD-CLASS)
1452         ;; shared -->  --       discard value
1453         ;; shared --> custom    XXX
1454
1455         ;;  --    --> local     add slot
1456         ;;  --    --> shared    --
1457         ;;  --    --> custom    XXX
1458
1459         (multiple-value-bind (new-instance-slots new-class-slots new-custom-slots)
1460             (classify-slotds (wrapper-slots nwrapper))
1461           (declare (ignore new-class-slots))
1462           (multiple-value-bind (old-instance-slots old-class-slots old-custom-slots)
1463               (classify-slotds (wrapper-slots owrapper))
1464
1465             (let ((layout (mapcar (lambda (slotd)
1466                                     ;; Get the names only once.
1467                                     (cons (slot-definition-name slotd) slotd))
1468                                   new-instance-slots)))
1469
1470               (flet ((set-value (value cell)
1471                        (let ((name (car cell))
1472                              (slotd (cdr cell)))
1473                          (when (and safe (neq value +slot-unbound+))
1474                            (let ((type (slot-definition-type slotd)))
1475                              (assert
1476                               (typep value type) (value)
1477                               "~@<Error updating obsolete instance. Current value in slot ~
1478                                ~S of an instance of ~S is ~S, which does not match the new ~
1479                                slot type ~S.~:@>"
1480                               name class value type)))
1481                          (setf (clos-slots-ref nslots (slot-definition-location slotd)) value
1482                                ;; Prune from the list now that it's been dealt with.
1483                                layout (remove cell layout)))))
1484
1485                 ;; Go through all the old local slots.
1486                 (dolist (old old-instance-slots)
1487                   (let* ((name (slot-definition-name old))
1488                          (value (clos-slots-ref oslots (slot-definition-location old))))
1489                     (unless (eq value +slot-unbound+)
1490                       (let ((new (assq name layout)))
1491                         (cond (new
1492                                (set-value value new))
1493                               (t
1494                                (push name discarded)
1495                                (setf (getf plist name) value)))))))
1496
1497                 ;; Go through all the old shared slots.
1498                 (dolist (old old-class-slots)
1499                   (let* ((cell (slot-definition-location old))
1500                          (name (car cell))
1501                          (new (assq name layout)))
1502                     (when new
1503                       (set-value (cdr cell) new))))
1504
1505                 ;; Go through all custom slots to find added ones. CLHS
1506                 ;; doesn't specify what to do about them, and neither does
1507                 ;; AMOP. We do want them to get initialized, though, so we
1508                 ;; list them in ADDED for the benefit of SHARED-INITIALIZE.
1509                 (dolist (new new-custom-slots)
1510                   (let* ((name (slot-definition-name new))
1511                          (old (find name old-custom-slots :key #'slot-definition-name)))
1512                     (unless old
1513                       (push name added))))
1514
1515                 ;; Go through all the remaining new local slots to compute the added slots.
1516                 (dolist (cell layout)
1517                   (push (car cell) added))))))
1518
1519         (%swap-wrappers-and-slots instance copy)
1520
1521         (update-instance-for-redefined-class instance
1522                                              added
1523                                              discarded
1524                                              plist)
1525         nwrapper)))
1526 \f
1527 (defun %change-class (instance new-class initargs)
1528   (let* ((old-class (class-of instance))
1529          (copy (allocate-instance new-class))
1530          (new-wrapper (get-wrapper copy))
1531          (old-wrapper (class-wrapper old-class))
1532          (old-slots (get-slots instance))
1533          (new-slots (get-slots copy))
1534          (safe (safe-p new-class)))
1535     (multiple-value-bind (new-instance-slots new-class-slots)
1536         (classify-slotds (wrapper-slots new-wrapper))
1537       (multiple-value-bind (old-instance-slots old-class-slots)
1538           (classify-slotds (wrapper-slots old-wrapper))
1539
1540         (flet ((set-value (value slotd)
1541                  (when safe
1542                    (assert (typep value (slot-definition-type slotd)) (value)
1543                            "~@<Error changing class. Current value in slot ~S ~
1544                             of an instance of ~S is ~S, which does not match the new ~
1545                             slot type ~S in class ~S.~:@>"
1546                            (slot-definition-name slotd) old-class value
1547                            (slot-definition-type slotd) new-class))
1548                  (setf (clos-slots-ref new-slots (slot-definition-location slotd)) value)))
1549
1550           ;; "The values of local slots specified by both the class CTO and
1551           ;; CFROM are retained. If such a local slot was unbound, it
1552           ;; remains unbound."
1553           (dolist (new new-instance-slots)
1554             (let* ((name (slot-definition-name new))
1555                    (old (find name old-instance-slots :key #'slot-definition-name)))
1556               (when old
1557                 (set-value (clos-slots-ref old-slots (slot-definition-location old))
1558                            new))))
1559
1560           ;; "The values of slots specified as shared in the class CFROM and
1561           ;; as local in the class CTO are retained."
1562           (dolist (old old-class-slots)
1563             (let* ((slot-and-val (slot-definition-location old))
1564                    (new (find (car slot-and-val) new-instance-slots
1565                               :key #'slot-definition-name)))
1566               (when new
1567                 (set-value (cdr slot-and-val) new)))))))
1568
1569     ;; Make the copy point to the old instance's storage, and make the
1570     ;; old instance point to the new storage.
1571     (%swap-wrappers-and-slots instance copy)
1572
1573     (apply #'update-instance-for-different-class copy instance initargs)
1574
1575     instance))
1576
1577 (defmethod change-class ((instance standard-object) (new-class standard-class)
1578                          &rest initargs)
1579   (with-world-lock ()
1580     (unless (class-finalized-p new-class)
1581       (finalize-inheritance new-class))
1582     (let ((cpl (class-precedence-list new-class)))
1583       (dolist (class cpl)
1584         (macrolet
1585             ((frob (class-name)
1586                `(when (eq class (find-class ',class-name))
1587                   (error 'metaobject-initialization-violation
1588                          :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1589                          :format-arguments (list 'change-class ',class-name)
1590                          :references (list '(:amop :initialization ,class-name))))))
1591           (frob class)
1592           (frob generic-function)
1593           (frob method)
1594           (frob slot-definition))))
1595     (%change-class instance new-class initargs)))
1596
1597 (defmethod change-class ((instance forward-referenced-class)
1598                          (new-class standard-class) &rest initargs)
1599   (with-world-lock ()
1600     (let ((cpl (class-precedence-list new-class)))
1601       (dolist (class cpl
1602                (error 'metaobject-initialization-violation
1603                       :format-control
1604                       "~@<Cannot ~S ~S objects into non-~S objects.~@:>"
1605                       :format-arguments
1606                       (list 'change-class 'forward-referenced-class 'class)
1607                       :references
1608                       (list '(:amop :generic-function ensure-class-using-class)
1609                             '(:amop :initialization class))))
1610         (when (eq class (find-class 'class))
1611           (return nil))))
1612     (%change-class instance new-class initargs)))
1613
1614 (defmethod change-class ((instance funcallable-standard-object)
1615                          (new-class funcallable-standard-class)
1616                          &rest initargs)
1617   (with-world-lock ()
1618     (let ((cpl (class-precedence-list new-class)))
1619       (dolist (class cpl)
1620         (macrolet
1621             ((frob (class-name)
1622                `(when (eq class (find-class ',class-name))
1623                   (error 'metaobject-initialization-violation
1624                          :format-control "~@<Cannot ~S objects into ~S metaobjects.~@:>"
1625                          :format-arguments (list 'change-class ',class-name)
1626                          :references (list '(:amop :initialization ,class-name))))))
1627           (frob class)
1628           (frob generic-function)
1629           (frob method)
1630           (frob slot-definition))))
1631     (%change-class instance new-class initargs)))
1632
1633 (defmethod change-class ((instance standard-object)
1634                          (new-class funcallable-standard-class)
1635                          &rest initargs)
1636   (declare (ignore initargs))
1637   (error "You can't change the class of ~S to ~S~@
1638           because it isn't already an instance with metaclass ~S."
1639          instance new-class 'standard-class))
1640
1641 (defmethod change-class ((instance funcallable-standard-object)
1642                          (new-class standard-class)
1643                          &rest initargs)
1644   (declare (ignore initargs))
1645   (error "You can't change the class of ~S to ~S~@
1646           because it isn't already an instance with metaclass ~S."
1647          instance new-class 'funcallable-standard-class))
1648
1649 (defmethod change-class ((instance t) (new-class-name symbol) &rest initargs)
1650   (apply #'change-class instance (find-class new-class-name) initargs))
1651 \f
1652 ;;;; The metaclass BUILT-IN-CLASS
1653 ;;;;
1654 ;;;; This metaclass is something of a weird creature. By this point, all
1655 ;;;; instances of it which will exist have been created, and no instance
1656 ;;;; is ever created by calling MAKE-INSTANCE.
1657 ;;;;
1658 ;;;; But, there are other parts of the protocol we must follow and those
1659 ;;;; definitions appear here.
1660
1661 (macrolet ((def (name args control)
1662                `(defmethod ,name ,args
1663                  (declare (ignore initargs))
1664                  (error 'metaobject-initialization-violation
1665                   :format-control ,(format nil "~@<~A~@:>" control)
1666                   :format-arguments (list ',name)
1667                   :references (list '(:amop :initialization "Class"))))))
1668   (def initialize-instance ((class built-in-class) &rest initargs)
1669     "Cannot ~S an instance of BUILT-IN-CLASS.")
1670   (def reinitialize-instance ((class built-in-class) &rest initargs)
1671     "Cannot ~S an instance of BUILT-IN-CLASS."))
1672
1673 (macrolet ((def (name)
1674                `(defmethod ,name ((class built-in-class)) nil)))
1675   (def class-direct-slots)
1676   (def class-slots)
1677   (def class-direct-default-initargs)
1678   (def class-default-initargs))
1679
1680 (defmethod validate-superclass ((c class) (s built-in-class))
1681   (or (eq s *the-class-t*) (eq s *the-class-stream*)
1682       ;; FIXME: bad things happen if someone tries to mix in both
1683       ;; FILE-STREAM and STRING-STREAM (as they have the same
1684       ;; layout-depthoid).  Is there any way we can provide a useful
1685       ;; error message?  -- CSR, 2005-05-03
1686       (eq s *the-class-file-stream*) (eq s *the-class-string-stream*)
1687       ;; This probably shouldn't be mixed in with certain other
1688       ;; classes, too, but it seems to work both with STANDARD-OBJECT
1689       ;; and FUNCALLABLE-STANDARD-OBJECT
1690       (eq s *the-class-sequence*)))
1691 \f
1692 ;;; Some necessary methods for FORWARD-REFERENCED-CLASS
1693 (defmethod class-direct-slots ((class forward-referenced-class)) ())
1694 (defmethod class-direct-default-initargs ((class forward-referenced-class)) ())
1695 (macrolet ((def (method)
1696              `(defmethod ,method ((class forward-referenced-class))
1697                 (error "~@<~I~S was called on a forward referenced class:~2I~_~S~:>"
1698                        ',method class))))
1699   (def class-default-initargs)
1700   (def class-precedence-list)
1701   (def class-slots))
1702
1703 (defmethod validate-superclass ((c slot-class)
1704                                 (f forward-referenced-class))
1705   t)
1706 \f
1707 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1708   (pushnew dependent (plist-value metaobject 'dependents) :test #'eq))
1709
1710 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1711   (setf (plist-value metaobject 'dependents)
1712         (delete dependent (plist-value metaobject 'dependents))))
1713
1714 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1715   (dolist (dependent (plist-value metaobject 'dependents))
1716     (funcall function dependent)))
1717