src/pcl/vector.lisp

   1 ;;;; permutation vectors
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5
   6 ;;;; This software is derived from software originally released by Xerox
   7 ;;;; Corporation. Copyright and release statements follow. Later modifications
   8 ;;;; to the software are in the public domain and are provided with
   9 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  10 ;;;; information.
  11
  12 ;;;; copyright information from original PCL sources:
  13 ;;;;
  14 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  15 ;;;; All rights reserved.
  16 ;;;;
  17 ;;;; Use and copying of this software and preparation of derivative works based
  18 ;;;; upon this software are permitted. Any distribution of this software or
  19 ;;;; derivative works must comply with all applicable United States export
  20 ;;;; control laws.
  21 ;;;;
  22 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  23 ;;;; warranty about the software, its performance or its conformity to any
  24 ;;;; specification.
  25
  26 (in-package "SB-PCL")
  27 \f
  28 (defmacro instance-slot-index (wrapper slot-name)
  29   `(let ((pos 0))
  30      (declare (fixnum pos))
  31      (block loop
  32        (dolist (sn (wrapper-instance-slots-layout ,wrapper))
  33          (when (eq ,slot-name sn) (return-from loop pos))
  34          (incf pos)))))
  35 \f
  36 (defun pv-cache-limit-fn (nlines)
  37   (default-limit-fn nlines))
  38
  39 (defstruct (pv-table (:predicate pv-tablep)
  40                      (:constructor make-pv-table-internal
  41                                    (slot-name-lists call-list))
  42                      (:copier nil))
  43   (cache nil :type (or cache null))
  44   (pv-size 0 :type fixnum)
  45   (slot-name-lists nil :type list)
  46   (call-list nil :type list))
  47
  48 #-sb-fluid (declaim (sb-ext:freeze-type pv-table))
  49
  50 (defvar *initial-pv-table* (make-pv-table-internal nil nil))
  51
  52 ; help new slot-value-using-class methods affect fast iv access
  53 (defvar *all-pv-table-list* nil)
  54
  55 (defun make-pv-table (&key slot-name-lists call-list)
  56   (let ((pv-table (make-pv-table-internal slot-name-lists call-list)))
  57     (push pv-table *all-pv-table-list*)
  58     pv-table))
  59
  60 (defun make-pv-table-type-declaration (var)
  61   `(type pv-table ,var))
  62
  63 (defvar *slot-name-lists-inner* (make-hash-table :test 'equal))
  64 (defvar *slot-name-lists-outer* (make-hash-table :test 'equal))
  65
  66 ;;; Entries in this are lists of (table . pv-offset-list).
  67 (defvar *pv-key-to-pv-table-table* (make-hash-table :test 'equal))
  68
  69 (defun intern-pv-table (&key slot-name-lists call-list)
  70   (let ((new-p nil))
  71     (flet ((inner (x)
  72              (or (gethash x *slot-name-lists-inner*)
  73                  (setf (gethash x *slot-name-lists-inner*) (copy-list x))))
  74            (outer (x)
  75              (or (gethash x *slot-name-lists-outer*)
  76                  (setf (gethash x *slot-name-lists-outer*)
  77                        (let ((snl (copy-list (cdr x)))
  78                              (cl (car x)))
  79                          (setq new-p t)
  80                          (make-pv-table :slot-name-lists snl
  81                                         :call-list cl))))))
  82     (let ((pv-table (outer (mapcar #'inner (cons call-list slot-name-lists)))))
  83       (when new-p
  84         (let ((pv-index 1))
  85           (dolist (slot-name-list slot-name-lists)
  86             (dolist (slot-name (cdr slot-name-list))
  87               (note-pv-table-reference slot-name pv-index pv-table)
  88               (incf pv-index)))
  89           (dolist (gf-call call-list)
  90             (note-pv-table-reference gf-call pv-index pv-table)
  91             (incf pv-index))
  92           (setf (pv-table-pv-size pv-table) pv-index)))
  93       pv-table))))
  94
  95 (defun note-pv-table-reference (ref pv-offset pv-table)
  96   (let ((entry (gethash ref *pv-key-to-pv-table-table*)))
  97     (when (listp entry)
  98       (let ((table-entry (assq pv-table entry)))
  99         (when (and (null table-entry)
 100                    (> (length entry) 8))
 101           (let ((new-table-table (make-hash-table :size 16 :test 'eq)))
 102             (dolist (table-entry entry)
 103               (setf (gethash (car table-entry) new-table-table)
 104                     (cdr table-entry)))
 105             (setf (gethash ref *pv-key-to-pv-table-table*) new-table-table)))
 106         (when (listp entry)
 107           (if (null table-entry)
 108               (let ((new (cons pv-table pv-offset)))
 109                 (if (consp entry)
 110                     (push new (cdr entry))
 111                     (setf (gethash ref *pv-key-to-pv-table-table*)
 112                           (list new))))
 113               (push pv-offset (cdr table-entry)))
 114           (return-from note-pv-table-reference nil))))
 115     (let ((list (gethash pv-table entry)))
 116       (if (consp list)
 117           (push pv-offset (cdr list))
 118           (setf (gethash pv-table entry) (list pv-offset)))))
 119   nil)
 120
 121 (defun map-pv-table-references-of (ref function)
 122   (let ((entry (gethash ref *pv-key-to-pv-table-table*)))
 123     (if (listp entry)
 124         (dolist (table+pv-offset-list entry)
 125           (funcall function
 126                    (car table+pv-offset-list)
 127                    (cdr table+pv-offset-list)))
 128         (maphash function entry)))
 129   ref)
 130 \f
 131 (defvar *pvs* (make-hash-table :test 'equal))
 132
 133 (defun optimize-slot-value-by-class-p (class slot-name type)
 134   (or (not (eq *boot-state* 'complete))
 135       (let ((slotd (find-slot-definition class slot-name)))
 136         (and slotd
 137              (slot-accessor-std-p slotd type)))))
 138
 139 (defun compute-pv-slot (slot-name wrapper class class-slots class-slot-p-cell)
 140   (if (symbolp slot-name)
 141       (when (optimize-slot-value-by-class-p class slot-name 'all)
 142         (or (instance-slot-index wrapper slot-name)
 143             (let ((cell (assq slot-name class-slots)))
 144               (when cell
 145                 (setf (car class-slot-p-cell) t)
 146                 cell))))
 147       (when (consp slot-name)
 148         (dolist (type '(reader writer) nil)
 149           (when (eq (car slot-name) type)
 150             (return
 151               (let* ((gf-name (cadr slot-name))
 152                      (gf (gdefinition gf-name))
 153                      (location (when (eq *boot-state* 'complete)
 154                                  (accessor-values1 gf type class))))
 155                 (when (consp location)
 156                   (setf (car class-slot-p-cell) t))
 157                 location)))))))
 158
 159 (defun compute-pv (slot-name-lists wrappers)
 160   (unless (listp wrappers) (setq wrappers (list wrappers)))
 161   (let* ((not-simple-p-cell (list nil))
 162          (elements
 163           (let ((elements nil))
 164             (dolist (slot-names slot-name-lists)
 165               (when slot-names
 166                 (let* ((wrapper     (pop wrappers))
 167                        (std-p (typep wrapper 'wrapper))
 168                        (class       (wrapper-class* wrapper))
 169                        (class-slots (and std-p (wrapper-class-slots wrapper))))
 170                   (dolist (slot-name (cdr slot-names))
 171                     ;; Original PCL code had this idiom.  why not:
 172                     ;;
 173                     ;; (WHEN STD-P
 174                     ;;   (PUSH ...)) ?
 175                     (push (when std-p
 176                             (compute-pv-slot slot-name wrapper class
 177                                              class-slots not-simple-p-cell))
 178                           elements)))))
 179             (nreverse elements))))
 180     (if (car not-simple-p-cell)
 181         (make-permutation-vector (cons t elements))
 182         (or (gethash elements *pvs*)
 183             (setf (gethash elements *pvs*)
 184                   (make-permutation-vector (cons nil elements)))))))
 185
 186 (defun compute-calls (call-list wrappers)
 187   (declare (ignore call-list wrappers))
 188   #||
 189   (map 'vector
 190        (lambda (call)
 191          (compute-emf-from-wrappers call wrappers))
 192        call-list)
 193   ||#
 194   '#())
 195
 196 #|| ; Need to finish this, then write the maintenance functions.
 197 (defun compute-emf-from-wrappers (call wrappers)
 198   (when call
 199     (destructuring-bind (gf-name nreq restp arg-info) call
 200       (if (eq gf-name 'make-instance)
 201           (error "should not get here") ; there is another mechanism for this.
 202           (lambda (&rest args)
 203             (if (not (eq *boot-state* 'complete))
 204                 (apply (gdefinition gf-name) args)
 205                 (let* ((gf (gdefinition gf-name))
 206                        (arg-info (arg-info-reader gf))
 207                        (classes '?)
 208                        (types '?)
 209                        (emf (cache-miss-values-internal gf arg-info
 210                                                         wrappers classes types
 211                                                         'caching)))
 212                   (update-all-pv-tables call wrappers emf)
 213                   (invoke-emf emf args))))))))
 214 ||#
 215
 216 (defun make-permutation-vector (indexes)
 217   (make-array (length indexes) :initial-contents indexes))
 218
 219 (defun pv-table-lookup (pv-table pv-wrappers)
 220   (let* ((slot-name-lists (pv-table-slot-name-lists pv-table))
 221          (call-list (pv-table-call-list pv-table))
 222          (cache (or (pv-table-cache pv-table)
 223                     (setf (pv-table-cache pv-table)
 224                           (get-cache (- (length slot-name-lists)
 225                                         (count nil slot-name-lists))
 226                                      t
 227                                      #'pv-cache-limit-fn
 228                                      2)))))
 229     (or (probe-cache cache pv-wrappers)
 230         (let* ((pv (compute-pv slot-name-lists pv-wrappers))
 231                (calls (compute-calls call-list pv-wrappers))
 232                (pv-cell (cons pv calls))
 233                (new-cache (fill-cache cache pv-wrappers pv-cell)))
 234           (unless (eq new-cache cache)
 235             (setf (pv-table-cache pv-table) new-cache))
 236           pv-cell))))
 237
 238 (defun make-pv-type-declaration (var)
 239   `(type simple-vector ,var))
 240
 241 (defvar *empty-pv* #())
 242
 243 (defmacro pvref (pv index)
 244   `(svref ,pv ,index))
 245
 246 (defmacro copy-pv (pv)
 247   `(copy-seq ,pv))
 248
 249 (defun make-calls-type-declaration (var)
 250   `(type simple-vector ,var))
 251
 252 (defmacro callsref (calls index)
 253   `(svref ,calls ,index))
 254
 255 (defvar *pv-table-cache-update-info* nil)
 256
 257 (defun update-pv-table-cache-info (class)
 258   (let ((slot-names-for-pv-table-update nil)
 259         (new-icui nil))
 260     (dolist (icu *pv-table-cache-update-info*)
 261       (if (eq (car icu) class)
 262           (pushnew (cdr icu) slot-names-for-pv-table-update)
 263           (push icu new-icui)))
 264     (setq *pv-table-cache-update-info* new-icui)
 265     (when slot-names-for-pv-table-update
 266       (update-all-pv-table-caches class slot-names-for-pv-table-update))))
 267
 268 (defun update-all-pv-table-caches (class slot-names)
 269   (let* ((cwrapper (class-wrapper class))
 270          (std-p (typep cwrapper 'wrapper))
 271          (class-slots (and std-p (wrapper-class-slots cwrapper)))
 272          (class-slot-p-cell (list nil))
 273          (new-values (mapcar (lambda (slot-name)
 274                                (cons slot-name
 275                                      (when std-p
 276                                        (compute-pv-slot
 277                                         slot-name cwrapper class
 278                                         class-slots class-slot-p-cell))))
 279                              slot-names))
 280          (pv-tables nil))
 281     (dolist (slot-name slot-names)
 282       (map-pv-table-references-of
 283        slot-name
 284        (lambda (pv-table pv-offset-list)
 285          (declare (ignore pv-offset-list))
 286          (pushnew pv-table pv-tables))))
 287     (dolist (pv-table pv-tables)
 288       (let* ((cache (pv-table-cache pv-table))
 289              (slot-name-lists (pv-table-slot-name-lists pv-table))
 290              (pv-size (pv-table-pv-size pv-table))
 291              (pv-map (make-array pv-size :initial-element nil)))
 292         (let ((map-index 1) (param-index 0))
 293           (dolist (slot-name-list slot-name-lists)
 294             (dolist (slot-name (cdr slot-name-list))
 295               (let ((a (assoc slot-name new-values)))
 296                 (setf (svref pv-map map-index)
 297                       (and a (cons param-index (cdr a)))))
 298               (incf map-index))
 299             (incf param-index)))
 300         (when cache
 301           (map-cache (lambda (wrappers pv-cell)
 302                        (setf (car pv-cell)
 303                              (update-slots-in-pv wrappers (car pv-cell)
 304                                                  cwrapper pv-size pv-map)))
 305                      cache))))))
 306
 307 (defun update-slots-in-pv (wrappers pv cwrapper pv-size pv-map)
 308   (if (not (if (atom wrappers)
 309                (eq cwrapper wrappers)
 310                (dolist (wrapper wrappers nil)
 311                  (when (eq wrapper cwrapper)
 312                    (return t)))))
 313       pv
 314       (let* ((old-intern-p (listp (pvref pv 0)))
 315              (new-pv (if old-intern-p
 316                          (copy-pv pv)
 317                          pv))
 318              (new-intern-p t))
 319         (if (atom wrappers)
 320             (dotimes-fixnum (i pv-size)
 321               (when (consp (let ((map (svref pv-map i)))
 322                              (if map
 323                                  (setf (pvref new-pv i) (cdr map))
 324                                  (pvref new-pv i))))
 325                 (setq new-intern-p nil)))
 326             (let ((param 0))
 327               (dolist (wrapper wrappers)
 328                 (when (eq wrapper cwrapper)
 329                   (dotimes-fixnum (i pv-size)
 330                     (when (consp (let ((map (svref pv-map i)))
 331                                    (if (and map (= (car map) param))
 332                                        (setf (pvref new-pv i) (cdr map))
 333                                        (pvref new-pv i))))
 334                       (setq new-intern-p nil))))
 335                 (incf param))))
 336         (when new-intern-p
 337           (setq new-pv (let ((list-pv (coerce pv 'list)))
 338                          (or (gethash (cdr list-pv) *pvs*)
 339                              (setf (gethash (cdr list-pv) *pvs*)
 340                                    (if old-intern-p
 341                                        new-pv
 342                                        (make-permutation-vector list-pv)))))))
 343         new-pv)))
 344 \f
 345 (defun maybe-expand-accessor-form (form required-parameters slots env)
 346   (let* ((fname (car form))
 347          #||(len (length form))||#
 348          (gf (if (symbolp fname)
 349                  (unencapsulated-fdefinition fname)
 350                  (gdefinition fname))))
 351     (macrolet ((maybe-optimize-reader ()
 352                  `(let ((parameter
 353                          (can-optimize-access1 (cadr form)
 354                                                required-parameters env)))
 355                    (when parameter
 356                      (optimize-reader slots parameter gf-name form))))
 357                (maybe-optimize-writer ()
 358                  `(let ((parameter
 359                          (can-optimize-access1 (caddr form)
 360                                                required-parameters env)))
 361                    (when parameter
 362                      (optimize-writer slots parameter gf-name form)))))
 363       (unless (and (consp (cadr form))
 364                    (eq 'instance-accessor-parameter (caadr form)))
 365         (when (and (eq *boot-state* 'complete)
 366                    (generic-function-p gf))
 367           (let ((methods (generic-function-methods gf)))
 368             (when methods
 369               (let* ((gf-name (generic-function-name gf))
 370                      (arg-info (gf-arg-info gf))
 371                      (metatypes (arg-info-metatypes arg-info))
 372                      (nreq (length metatypes))
 373                      (applyp (arg-info-applyp arg-info)))
 374                 (when (null applyp)
 375                   (cond ((= nreq 1)
 376                          (when (some #'standard-reader-method-p methods)
 377                            (maybe-optimize-reader)))
 378                         ((and (= nreq 2)
 379                               (consp gf-name)
 380                               (eq (car gf-name) 'setf))
 381                          (when (some #'standard-writer-method-p methods)
 382                            (maybe-optimize-writer)))))))))))))
 383
 384 (defun optimize-generic-function-call (form
 385                                        required-parameters
 386                                        env
 387                                        slots
 388                                        calls)
 389   (declare (ignore required-parameters env slots calls))
 390   (or ; (optimize-reader ...)?
 391       form))
 392 \f
 393 (defun can-optimize-access (form required-parameters env)
 394   (let ((type (ecase (car form)
 395                 (slot-value 'reader)
 396                 (set-slot-value 'writer)
 397                 (slot-boundp 'boundp)))
 398         (var (cadr form))
 399         (slot-name (eval (caddr form)))) ; known to be constant
 400     (can-optimize-access1 var required-parameters env type slot-name)))
 401
 402 ;;; FIXME: This looks like an internal helper function for
 403 ;;; CAN-OPTIMIZE-ACCESS, and it is used that way, but it's also called
 404 ;;; bare from several places in the code. Perhaps the two functions
 405 ;;; should be renamed CAN-OPTIMIZE-ACCESS-FOR-FORM and
 406 ;;; CAN-OPTIMIZE-ACCESS-FOR-VAR. If so, I'd just as soon use keyword
 407 ;;; args instead of optional ones, too.
 408 (defun can-optimize-access1 (var required-parameters env
 409                              &optional type slot-name)
 410   (when (and (consp var) (eq 'the (car var)))
 411     ;; FIXME: We should assert list of length 3 here. Or maybe we
 412     ;; should just define EXTRACT-THE, replace the whole
 413     ;;   (WHEN ..)
 414     ;; form with
 415     ;;   (AWHEN (EXTRACT-THE VAR)
 416     ;;     (SETF VAR IT))
 417     ;; and then use EXTRACT-THE similarly to clean up the other tests
 418     ;; against 'THE scattered through the PCL code.
 419     (setq var (caddr var)))
 420   (when (symbolp var)
 421     (let* ((rebound? (caddr (var-declaration '%variable-rebinding var env)))
 422            (parameter-or-nil (car (memq (or rebound? var)
 423                                         required-parameters))))
 424       (when parameter-or-nil
 425         (let* ((class-name (caddr (var-declaration '%class
 426                                                    parameter-or-nil
 427                                                    env)))
 428                (class (find-class class-name nil)))
 429           (when (or (not (eq *boot-state* 'complete))
 430                     (and class (not (class-finalized-p class))))
 431             (setq class nil))
 432           (when (and class-name (not (eq class-name t)))
 433             (when (or (null type)
 434                       (not (and class
 435                                 (memq *the-class-structure-object*
 436                                       (class-precedence-list class))))
 437                       (optimize-slot-value-by-class-p class slot-name type))
 438               (cons parameter-or-nil (or class class-name)))))))))
 439
 440 (defun optimize-slot-value (slots sparameter form)
 441   (if sparameter
 442       (destructuring-bind (ignore1 ignore2 slot-name-form) form
 443         (declare (ignore ignore1 ignore2))
 444         (let ((slot-name (eval slot-name-form)))
 445           (optimize-instance-access slots :read sparameter slot-name nil)))
 446       `(accessor-slot-value ,@(cdr form))))
 447
 448 (defun optimize-set-slot-value (slots sparameter form)
 449   (if sparameter
 450       (destructuring-bind (ignore1 ignore2 slot-name-form new-value) form
 451         (declare (ignore ignore1 ignore2))
 452         (let ((slot-name (eval slot-name-form)))
 453           (optimize-instance-access slots
 454                                     :write
 455                                     sparameter
 456                                     slot-name
 457                                     new-value)))
 458       `(accessor-set-slot-value ,@(cdr form))))
 459
 460 (defun optimize-slot-boundp (slots sparameter form)
 461   (if sparameter
 462       (destructuring-bind
 463           ;; FIXME: In CMU CL ca. 19991205, this binding list had a
 464           ;; fourth element in it, NEW-VALUE. It's hard to see how
 465           ;; that could possibly be right, since SLOT-BOUNDP has no
 466           ;; NEW-VALUE. Since it was causing a failure in building PCL
 467           ;; for SBCL, so I changed it to match the definition of
 468           ;; SLOT-BOUNDP (and also to match the list used in the
 469           ;; similar OPTIMIZE-SLOT-VALUE, above). However, I'm weirded
 470           ;; out by this, since this is old code which has worked for
 471           ;; ages to build PCL for CMU CL, so it's hard to see why it
 472           ;; should need a patch like this in order to build PCL for
 473           ;; SBCL. I'd like to return to this and find a test case
 474           ;; which exercises this function both in CMU CL, to see
 475           ;; whether it's really a previously-unexercised bug or
 476           ;; whether I've misunderstood something (and, presumably,
 477           ;; patched it wrong).
 478           (slot-boundp-symbol instance slot-name-form)
 479           form
 480         (declare (ignore slot-boundp-symbol instance))
 481         (let ((slot-name (eval slot-name-form)))
 482           (optimize-instance-access slots
 483                                     :boundp
 484                                     sparameter
 485                                     slot-name
 486                                     nil)))
 487       `(accessor-slot-boundp ,@(cdr form))))
 488
 489 (defun optimize-reader (slots sparameter gf-name form)
 490   (if sparameter
 491       (optimize-accessor-call slots :read sparameter gf-name nil)
 492       form))
 493
 494 (defun optimize-writer (slots sparameter gf-name form)
 495   (if sparameter
 496       (destructuring-bind (ignore1 ignore2 new-value) form
 497         (declare (ignore ignore1 ignore2))
 498         (optimize-accessor-call slots :write sparameter gf-name new-value))
 499       form))
 500
 501 ;;; The SLOTS argument is an alist, the CAR of each entry is the name
 502 ;;; of a required parameter to the function. The alist is in order, so
 503 ;;; the position of an entry in the alist corresponds to the
 504 ;;; argument's position in the lambda list.
 505 (defun optimize-instance-access (slots
 506                                  read/write
 507                                  sparameter
 508                                  slot-name
 509                                  new-value)
 510   (let ((class (if (consp sparameter) (cdr sparameter) *the-class-t*))
 511         (parameter (if (consp sparameter) (car sparameter) sparameter)))
 512     (if (and (eq *boot-state* 'complete)
 513              (classp class)
 514              (memq *the-class-structure-object* (class-precedence-list class)))
 515         (let ((slotd (find-slot-definition class slot-name)))
 516           (ecase read/write
 517             (:read
 518              `(,(slot-definition-defstruct-accessor-symbol slotd) ,parameter))
 519             (:write
 520              `(setf (,(slot-definition-defstruct-accessor-symbol slotd)
 521                      ,parameter)
 522                     ,new-value))
 523             (:boundp
 524              t)))
 525         (let* ((parameter-entry (assq parameter slots))
 526                (slot-entry      (assq slot-name (cdr parameter-entry)))
 527                (position (posq parameter-entry slots))
 528                (pv-offset-form (list 'pv-offset ''.PV-OFFSET.)))
 529           (unless parameter-entry
 530             (bug "slot optimization bewilderment: O-I-A"))
 531           (unless slot-entry
 532             (setq slot-entry (list slot-name))
 533             (push slot-entry (cdr parameter-entry)))
 534           (push pv-offset-form (cdr slot-entry))
 535           (ecase read/write
 536             (:read
 537              `(instance-read ,pv-offset-form ,parameter ,position
 538                              ',slot-name ',class))
 539             (:write
 540              `(let ((.new-value. ,new-value))
 541                 (instance-write ,pv-offset-form ,parameter ,position
 542                                 ',slot-name ',class .new-value.)))
 543             (:boundp
 544              `(instance-boundp ,pv-offset-form ,parameter ,position
 545                                ',slot-name ',class)))))))
 546
 547 (defun optimize-accessor-call (slots read/write sparameter gf-name new-value)
 548   (let* ((class (if (consp sparameter) (cdr sparameter) *the-class-t*))
 549          (parameter (if (consp sparameter) (car sparameter) sparameter))
 550          (parameter-entry (assq parameter slots))
 551          (name (case read/write
 552                  (:read `(reader ,gf-name))
 553                  (:write `(writer ,gf-name))))
 554          (slot-entry      (assoc name (cdr parameter-entry) :test #'equal))
 555          (position (posq parameter-entry slots))
 556          (pv-offset-form (list 'pv-offset ''.PV-OFFSET.)))
 557     (unless parameter-entry
 558       (error "slot optimization bewilderment: O-A-C"))
 559     (unless slot-entry
 560       (setq slot-entry (list name))
 561       (push slot-entry (cdr parameter-entry)))
 562     (push pv-offset-form (cdr slot-entry))
 563     (ecase read/write
 564       (:read
 565        `(instance-reader ,pv-offset-form ,parameter ,position ,gf-name ',class))
 566       (:write
 567        `(let ((.new-value. ,new-value))
 568           (instance-writer ,pv-offset-form ,parameter ,position ,gf-name ',class
 569                            .new-value.))))))
 570
 571 (defvar *unspecific-arg* '..unspecific-arg..)
 572
 573 (defun optimize-gf-call-internal (form slots env)
 574   (when (and (consp form)
 575              (eq (car form) 'the))
 576     (setq form (caddr form)))
 577   (or (and (symbolp form)
 578            (let* ((rebound? (caddr (var-declaration '%variable-rebinding
 579                                                     form
 580                                                     env)))
 581                   (parameter-or-nil (car (assq (or rebound? form) slots))))
 582              (when parameter-or-nil
 583                (let* ((class-name (caddr (var-declaration 'class
 584                                                           parameter-or-nil
 585                                                           env))))
 586                  (when (and class-name (not (eq class-name t)))
 587                    (position parameter-or-nil slots :key #'car))))))
 588       (if (constantp form)
 589           (let ((form (eval form)))
 590             (if (symbolp form)
 591                 form
 592                 *unspecific-arg*))
 593           *unspecific-arg*)))
 594
 595 (defun optimize-gf-call (slots calls gf-call-form nreq restp env)
 596   (unless (eq (car gf-call-form) 'make-instance) ; XXX needs more work
 597     (let* ((args (cdr gf-call-form))
 598            (all-args-p (eq (car gf-call-form) 'make-instance))
 599            (non-required-args (nthcdr nreq args))
 600            (required-args (ldiff args non-required-args))
 601            (call-spec (list (car gf-call-form) nreq restp
 602                             (mapcar (lambda (form)
 603                                       (optimize-gf-call-internal form slots env))
 604                                     (if all-args-p
 605                                         args
 606                                         required-args))))
 607            (call-entry (assoc call-spec calls :test #'equal))
 608            (pv-offset-form (list 'pv-offset ''.PV-OFFSET.)))
 609       (unless (some #'integerp
 610                     (let ((spec-args (cdr call-spec)))
 611                       (if all-args-p
 612                           (ldiff spec-args (nthcdr nreq spec-args))
 613                           spec-args)))
 614         (return-from optimize-gf-call nil))
 615       (unless call-entry
 616         (setq call-entry (list call-spec))
 617         (push call-entry (cdr calls)))
 618       (push pv-offset-form (cdr call-entry))
 619       (if (eq (car call-spec) 'make-instance)
 620           `(funcall (pv-ref .pv. ,pv-offset-form) ,@(cdr gf-call-form))
 621           `(let ((.emf. (pv-ref .pv. ,pv-offset-form)))
 622             (invoke-effective-method-function .emf. ,restp
 623              ,@required-args ,@(when restp `((list ,@non-required-args)))))))))
 624
 625 (define-walker-template pv-offset) ; These forms get munged by mutate slots.
 626 (defmacro pv-offset (arg) arg)
 627 (define-walker-template instance-accessor-parameter)
 628 (defmacro instance-accessor-parameter (x) x)
 629
 630 ;;; It is safe for these two functions to be wrong. They just try to
 631 ;;; guess what the most likely case will be.
 632 (defun generate-fast-class-slot-access-p (class-form slot-name-form)
 633   (let ((class (and (constantp class-form) (eval class-form)))
 634         (slot-name (and (constantp slot-name-form) (eval slot-name-form))))
 635     (and (eq *boot-state* 'complete)
 636          (standard-class-p class)
 637          (not (eq class *the-class-t*)) ; shouldn't happen, though.
 638          (let ((slotd (find-slot-definition class slot-name)))
 639            (and slotd (eq :class (slot-definition-allocation slotd)))))))
 640
 641 (defun skip-fast-slot-access-p (class-form slot-name-form type)
 642   (let ((class (and (constantp class-form) (eval class-form)))
 643         (slot-name (and (constantp slot-name-form) (eval slot-name-form))))
 644     (and (eq *boot-state* 'complete)
 645          (standard-class-p class)
 646          (not (eq class *the-class-t*)) ; shouldn't happen, though.
 647          (let ((slotd (find-slot-definition class slot-name)))
 648            (and slotd (skip-optimize-slot-value-by-class-p class
 649                                                            slot-name
 650                                                            type))))))
 651
 652 (defun skip-optimize-slot-value-by-class-p (class slot-name type)
 653   (let ((slotd (find-slot-definition class slot-name)))
 654     (and slotd
 655          (eq *boot-state* 'complete)
 656          (not (slot-accessor-std-p slotd type)))))
 657
 658 (defmacro instance-read-internal (pv slots pv-offset default &optional type)
 659   (unless (member type '(nil :instance :class :default))
 660     (error "illegal type argument to ~S: ~S" 'instance-read-internal type))
 661   (if (eq type :default)
 662       default
 663       (let* ((index (gensym))
 664              (value index))
 665         `(locally (declare #.*optimize-speed*)
 666           (let ((,index (pvref ,pv ,pv-offset)))
 667             (setq ,value (typecase ,index
 668                            ,@(when (or (null type) (eq type :instance))
 669                                `((fixnum (clos-slots-ref ,slots ,index))))
 670                            ,@(when (or (null type) (eq type :class))
 671                                `((cons (cdr ,index))))
 672                            (t +slot-unbound+)))
 673             (if (eq ,value +slot-unbound+)
 674                 ,default
 675                 ,value))))))
 676
 677 (defmacro instance-read (pv-offset parameter position slot-name class)
 678   (if (skip-fast-slot-access-p class slot-name 'reader)
 679       `(accessor-slot-value ,parameter ,slot-name)
 680       `(instance-read-internal .pv. ,(slot-vector-symbol position)
 681         ,pv-offset (accessor-slot-value ,parameter ,slot-name)
 682         ,(if (generate-fast-class-slot-access-p class slot-name)
 683              :class :instance))))
 684
 685 (defmacro instance-reader (pv-offset parameter position gf-name class)
 686   (declare (ignore class))
 687   `(instance-read-internal .pv. ,(slot-vector-symbol position)
 688     ,pv-offset
 689     (,gf-name (instance-accessor-parameter ,parameter))
 690     :instance))
 691
 692 (defmacro instance-write-internal (pv slots pv-offset new-value default
 693                                       &optional type)
 694   (unless (member type '(nil :instance :class :default))
 695     (error "illegal type argument to ~S: ~S" 'instance-write-internal type))
 696   (if (eq type :default)
 697       default
 698       (let* ((index (gensym)))
 699         `(locally (declare #.*optimize-speed*)
 700           (let ((,index (pvref ,pv ,pv-offset)))
 701             (typecase ,index
 702               ,@(when (or (null type) (eq type :instance))
 703                       `((fixnum (setf (clos-slots-ref ,slots ,index)
 704                                       ,new-value))))
 705               ,@(when (or (null type) (eq type :class))
 706                   `((cons (setf (cdr ,index) ,new-value))))
 707               (t ,default)))))))
 708
 709 (defmacro instance-write (pv-offset
 710                           parameter
 711                           position
 712                           slot-name
 713                           class
 714                           new-value)
 715   (if (skip-fast-slot-access-p class slot-name 'writer)
 716       `(accessor-set-slot-value ,parameter ,slot-name ,new-value)
 717       `(instance-write-internal .pv. ,(slot-vector-symbol position)
 718         ,pv-offset ,new-value
 719         (accessor-set-slot-value ,parameter ,slot-name ,new-value)
 720         ,(if (generate-fast-class-slot-access-p class slot-name)
 721              :class :instance))))
 722
 723 (defmacro instance-writer (pv-offset
 724                            parameter
 725                            position
 726                            gf-name
 727                            class
 728                            new-value)
 729   (declare (ignore class))
 730   `(instance-write-internal .pv. ,(slot-vector-symbol position)
 731     ,pv-offset ,new-value
 732     (,(if (consp gf-name)
 733           (get-setf-fun-name gf-name)
 734           gf-name)
 735      (instance-accessor-parameter ,parameter)
 736      ,new-value)
 737     :instance))
 738
 739 (defmacro instance-boundp-internal (pv slots pv-offset default
 740                                        &optional type)
 741   (unless (member type '(nil :instance :class :default))
 742     (error "illegal type argument to ~S: ~S" 'instance-boundp-internal type))
 743   (if (eq type :default)
 744       default
 745       (let* ((index (gensym)))
 746         `(locally (declare #.*optimize-speed*)
 747           (let ((,index (pvref ,pv ,pv-offset)))
 748             (typecase ,index
 749               ,@(when (or (null type) (eq type :instance))
 750                   `((fixnum (not (and ,slots
 751                                       (eq (clos-slots-ref ,slots ,index)
 752                                           +slot-unbound+))))))
 753               ,@(when (or (null type) (eq type :class))
 754                   `((cons (not (eq (cdr ,index) +slot-unbound+)))))
 755               (t ,default)))))))
 756
 757 (defmacro instance-boundp (pv-offset parameter position slot-name class)
 758   (if (skip-fast-slot-access-p class slot-name 'boundp)
 759       `(accessor-slot-boundp ,parameter ,slot-name)
 760       `(instance-boundp-internal .pv. ,(slot-vector-symbol position)
 761         ,pv-offset (accessor-slot-boundp ,parameter ,slot-name)
 762         ,(if (generate-fast-class-slot-access-p class slot-name)
 763              :class :instance))))
 764
 765 ;;; This magic function has quite a job to do indeed.
 766 ;;;
 767 ;;; The careful reader will recall that <slots> contains all of the
 768 ;;; optimized slot access forms produced by OPTIMIZE-INSTANCE-ACCESS.
 769 ;;; Each of these is a call to either INSTANCE-READ or INSTANCE-WRITE.
 770 ;;;
 771 ;;; At the time these calls were produced, the first argument was
 772 ;;; specified as the symbol .PV-OFFSET.; what we have to do now is
 773 ;;; convert those pv-offset arguments into the actual number that is
 774 ;;; the correct offset into the pv.
 775 ;;;
 776 ;;; But first, oh but first, we sort <slots> a bit so that for each
 777 ;;; argument we have the slots in alphabetical order. This
 778 ;;; canonicalizes the PV-TABLE's a bit and will hopefully lead to
 779 ;;; having fewer PV's floating around. Even if the gain is only
 780 ;;; modest, it costs nothing.
 781 (defun slot-name-lists-from-slots (slots calls)
 782   (multiple-value-bind (slots calls) (mutate-slots-and-calls slots calls)
 783     (let* ((slot-name-lists
 784             (mapcar (lambda (parameter-entry)
 785                       (cons nil (mapcar #'car (cdr parameter-entry))))
 786                     slots))
 787            (call-list
 788             (mapcar #'car calls)))
 789       (dolist (call call-list)
 790         (dolist (arg (cdr call))
 791           (when (integerp arg)
 792             (setf (car (nth arg slot-name-lists)) t))))
 793       (setq slot-name-lists (mapcar (lambda (r+snl)
 794                                       (when (or (car r+snl) (cdr r+snl))
 795                                         r+snl))
 796                                     slot-name-lists))
 797       (let ((cvt (apply #'vector
 798                         (let ((i -1))
 799                           (mapcar (lambda (r+snl)
 800                                     (when r+snl (incf i)))
 801                                   slot-name-lists)))))
 802         (setq call-list (mapcar (lambda (call)
 803                                   (cons (car call)
 804                                         (mapcar (lambda (arg)
 805                                                   (if (integerp arg)
 806                                                       (svref cvt arg)
 807                                                       arg))
 808                                                 (cdr call))))
 809                                 call-list)))
 810       (values slot-name-lists call-list))))
 811
 812 (defun mutate-slots-and-calls (slots calls)
 813   (let ((sorted-slots (sort-slots slots))
 814         (sorted-calls (sort-calls (cdr calls)))
 815         (pv-offset 0))  ; index 0 is for info
 816     (dolist (parameter-entry sorted-slots)
 817       (dolist (slot-entry (cdr parameter-entry))
 818         (incf pv-offset)
 819         (dolist (form (cdr slot-entry))
 820           (setf (cadr form) pv-offset))))
 821     (dolist (call-entry sorted-calls)
 822       (incf pv-offset)
 823       (dolist (form (cdr call-entry))
 824         (setf (cadr form) pv-offset)))
 825     (values sorted-slots sorted-calls)))
 826
 827 (defun symbol-pkg-name (sym)
 828   (let ((pkg (symbol-package sym)))
 829     (if pkg (package-name pkg) "")))
 830
 831 ;;; FIXME: Because of the existence of UNINTERN and RENAME-PACKAGE,
 832 ;;; the part of this ordering which is based on SYMBOL-PKG-NAME is not
 833 ;;; stable. This ordering is only used in to
 834 ;;; SLOT-NAME-LISTS-FROM-SLOTS, where it serves to "canonicalize the
 835 ;;; PV-TABLE's a bit and will hopefully lead to having fewer PV's
 836 ;;; floating around", so it sounds as though the instability won't
 837 ;;; actually lead to bugs, just small inefficiency. But still, it
 838 ;;; would be better to reimplement this function as a comparison based
 839 ;;; on SYMBOL-HASH:
 840 ;;;   * stable comparison
 841 ;;;   * smaller code (here, and in being able to discard SYMBOL-PKG-NAME)
 842 ;;;   * faster code.
 843 (defun symbol-lessp (a b)
 844   (if (eq (symbol-package a)
 845           (symbol-package b))
 846       (string-lessp (symbol-name a)
 847                     (symbol-name b))
 848       (string-lessp (symbol-pkg-name a)
 849                     (symbol-pkg-name b))))
 850
 851 (defun symbol-or-cons-lessp (a b)
 852   (etypecase a
 853     (symbol (etypecase b
 854               (symbol (symbol-lessp a b))
 855               (cons t)))
 856     (cons   (etypecase b
 857               (symbol nil)
 858               (cons (if (eq (car a) (car b))
 859                         (symbol-or-cons-lessp (cdr a) (cdr b))
 860                         (symbol-or-cons-lessp (car a) (car b))))))))
 861
 862 (defun sort-slots (slots)
 863   (mapcar (lambda (parameter-entry)
 864             (cons (car parameter-entry)
 865                   (sort (cdr parameter-entry)   ;slot entries
 866                         #'symbol-or-cons-lessp
 867                         :key #'car)))
 868           slots))
 869
 870 (defun sort-calls (calls)
 871   (sort calls #'symbol-or-cons-lessp :key #'car))
 872 \f
 873 ;;;; This needs to work in terms of metatypes and also needs to work
 874 ;;;; for automatically generated reader and writer functions.
 875 ;;;; Automatically generated reader and writer functions use this
 876 ;;;; stuff too.
 877
 878 (defmacro pv-binding ((required-parameters slot-name-lists pv-table-symbol)
 879                       &body body)
 880   (let (slot-vars pv-parameters)
 881     (loop for slots in slot-name-lists
 882           for required-parameter in required-parameters
 883           for i from 0
 884           do (when slots
 885                (push required-parameter pv-parameters)
 886                (push (slot-vector-symbol i) slot-vars)))
 887     `(pv-binding1 (.pv. .calls. ,pv-table-symbol
 888                    ,(nreverse pv-parameters) ,(nreverse slot-vars))
 889        ,@body)))
 890
 891 (defmacro pv-binding1 ((pv calls pv-table-symbol pv-parameters slot-vars)
 892                        &body body)
 893   `(pv-env (,pv ,calls ,pv-table-symbol ,pv-parameters)
 894      (let (,@(mapcar (lambda (slot-var p) `(,slot-var (get-slots-or-nil ,p)))
 895                      slot-vars pv-parameters))
 896         ,@body)))
 897
 898 ;;; This gets used only when the default MAKE-METHOD-LAMBDA is
 899 ;;; overridden.
 900 (defmacro pv-env ((pv calls pv-table-symbol pv-parameters)
 901                   &rest forms)
 902   `(let* ((.pv-table. ,pv-table-symbol)
 903           (.pv-cell. (pv-table-lookup-pv-args .pv-table. ,@pv-parameters))
 904           (,pv (car .pv-cell.))
 905           (,calls (cdr .pv-cell.)))
 906      (declare ,(make-pv-type-declaration pv))
 907      (declare ,(make-calls-type-declaration calls))
 908      ,@(when (symbolp pv-table-symbol)
 909          `((declare (special ,pv-table-symbol))))
 910      ,pv ,calls
 911      ,@forms))
 912
 913 (defvar *non-var-declarations*
 914   ;; FIXME: VALUES was in this list, conditionalized with #+CMU, but I
 915   ;; don't *think* CMU CL had, or SBCL has, VALUES declarations. If
 916   ;; SBCL doesn't have 'em, VALUES should probably be removed from
 917   ;; this list.
 918   '(values
 919     %method-name
 920     %method-lambda-list
 921     optimize
 922     ftype
 923     inline
 924     notinline))
 925
 926 (defvar *var-declarations-with-arg*
 927   '(%class
 928     type))
 929
 930 (defvar *var-declarations-without-arg*
 931   '(ignore
 932     ignorable special dynamic-extent
 933     ;; FIXME: Possibly this entire list and variable could go away.
 934     ;; If not, certainly we should remove all these built-in typenames
 935     ;; from the list, and replace them with a test for "is it a type
 936     ;; name?" (CLTL1 allowed only built-in type names as declarations,
 937     ;; but ANSI CL allows any type name as a declaration.)
 938     array atom base-char bignum bit bit-vector character compiled-function
 939     complex cons double-float extended-char
 940     fixnum float function hash-table integer
 941     keyword list long-float nil null number package pathname random-state ratio
 942     rational readtable sequence short-float signed-byte simple-array
 943     simple-bit-vector simple-string simple-vector single-float standard-char
 944     stream string symbol t unsigned-byte vector))
 945
 946 (defun split-declarations (body args calls-next-method-p)
 947   (let ((inner-decls nil)
 948         (outer-decls nil)
 949         decl)
 950     (loop (when (null body) (return nil))
 951           (setq decl (car body))
 952           (unless (and (consp decl)
 953                        (eq (car decl) 'declare))
 954             (return nil))
 955           (dolist (form (cdr decl))
 956             (when (consp form)
 957               (let ((declaration-name (car form)))
 958                 (if (member declaration-name *non-var-declarations*)
 959                     (push `(declare ,form) outer-decls)
 960                     (let ((arg-p
 961                            (member declaration-name
 962                                    *var-declarations-with-arg*))
 963                           (non-arg-p
 964                            (member declaration-name
 965                                    *var-declarations-without-arg*))
 966                           (dname (list (pop form)))
 967                           (inners nil) (outers nil))
 968                       (unless (or arg-p non-arg-p)
 969                         ;; FIXME: This warning, and perhaps the
 970                         ;; various *VAR-DECLARATIONS-FOO* and/or
 971                         ;; *NON-VAR-DECLARATIONS* variables,
 972                         ;; could probably go away now that we're not
 973                         ;; trying to be portable between different
 974                         ;; CLTL1 hosts the way PCL was. (Note that to
 975                         ;; do this right, we need to be able to handle
 976                         ;; user-defined (DECLAIM (DECLARATION FOO))
 977                         ;; stuff.)
 978                         (warn "The declaration ~S is not understood by ~S.~@
 979                                Please put ~S on one of the lists ~S,~%~S, or~%~S.~@
 980                         (Assuming it is a variable declaration without argument)."
 981                               declaration-name 'split-declarations
 982                               declaration-name
 983                               '*non-var-declarations*
 984                               '*var-declarations-with-arg*
 985                               '*var-declarations-without-arg*)
 986                         (push declaration-name *var-declarations-without-arg*))
 987                       (when arg-p
 988                         (setq dname (append dname (list (pop form)))))
 989                       (case (car dname)
 990                         (%class (push `(declare (,@dname ,@form)) inner-decls))
 991                         (t
 992                          (dolist (var form)
 993                            (if (member var args)
 994                                ;; Quietly remove IGNORE declarations
 995                                ;; on args when a next-method is
 996                                ;; involved, to prevent compiler
 997                                ;; warnings about ignored args being
 998                                ;; read.
 999                                (unless (and calls-next-method-p
1000                                             (eq (car dname) 'ignore))
1001                                  (push var outers))
1002                                (push var inners)))
1003                          (when outers
1004                            (push `(declare (,@dname ,@outers)) outer-decls))
1005                          (when inners
1006                            (push
1007                             `(declare (,@dname ,@inners))
1008                             inner-decls)))))))))
1009           (setq body (cdr body)))
1010     (values outer-decls inner-decls body)))
1011
1012 ;;; Pull a name out of the %METHOD-NAME declaration in the function
1013 ;;; body given, or return NIL if no %METHOD-NAME declaration is found.
1014 (defun body-method-name (body)
1015   (multiple-value-bind (real-body declarations documentation)
1016       (parse-body body nil)
1017     (declare (ignore documentation real-body))
1018     (let ((name-decl (get-declaration '%method-name declarations)))
1019       (and name-decl
1020            (destructuring-bind (name) name-decl
1021              name)))))
1022
1023 ;;; Convert a lambda expression containing a SB-PCL::%METHOD-NAME
1024 ;;; declaration (which is a naming style internal to PCL) into an
1025 ;;; SB-INT:NAMED-LAMBDA expression (which is a naming style used
1026 ;;; throughout SBCL, understood by the main compiler); or if there's
1027 ;;; no SB-PCL::%METHOD-NAME declaration, then just return the original
1028 ;;; lambda expression.
1029 (defun name-method-lambda (method-lambda)
1030   (let ((method-name (body-method-name (cddr method-lambda))))
1031     (if method-name
1032         `(named-lambda ,method-name ,(rest method-lambda))
1033         method-lambda)))
1034
1035 (defun make-method-initargs-form-internal (method-lambda initargs env)
1036   (declare (ignore env))
1037   (let (method-lambda-args
1038         lmf ; becomes body of function
1039         lmf-params)
1040     (if (not (and (= 3 (length method-lambda))
1041                   (= 2 (length (setq method-lambda-args (cadr method-lambda))))
1042                   (consp (setq lmf (third method-lambda)))
1043                   (eq 'simple-lexical-method-functions (car lmf))
1044                   (eq (car method-lambda-args)
1045                       (cadr (setq lmf-params (cadr lmf))))
1046                   (eq (cadr method-lambda-args)
1047                       (caddr lmf-params))))
1048         `(list* :function ,(name-method-lambda method-lambda)
1049                 ',initargs)
1050         (let* ((lambda-list (car lmf-params))
1051                (nreq 0)
1052                (restp nil)
1053                (args nil))
1054           (dolist (arg lambda-list)
1055             (when (member arg '(&optional &rest &key))
1056               (setq restp t)
1057               (return nil))
1058             (when (eq arg '&aux)
1059               (return nil))
1060             (incf nreq)
1061             (push arg args))
1062           (setq args (nreverse args))
1063           (setf (getf (getf initargs :plist) :arg-info) (cons nreq restp))
1064           (make-method-initargs-form-internal1
1065            initargs (cddr lmf) args lmf-params restp)))))
1066
1067 (defun make-method-initargs-form-internal1
1068     (initargs body req-args lmf-params restp)
1069   (multiple-value-bind (outer-decls inner-decls body-sans-decls)
1070       (split-declarations
1071        body req-args (getf (cdr lmf-params) :call-next-method-p))
1072     (let* ((rest-arg (when restp '.rest-arg.))
1073            (args+rest-arg (if restp
1074                               (append req-args (list rest-arg))
1075                               req-args)))
1076       `(list*
1077         :fast-function
1078         (named-lambda
1079          ,(or (body-method-name body) '.method.) ; function name
1080          (.pv-cell. .next-method-call. ,@args+rest-arg) ; function args
1081          ;; body of the function
1082          (declare (ignorable .pv-cell. .next-method-call.))
1083          ,@outer-decls
1084          (macrolet ((pv-env ((pv calls pv-table-symbol pv-parameters)
1085                              &rest forms)
1086                             (declare (ignore pv-table-symbol
1087                                              pv-parameters))
1088                             `(let ((,pv (car .pv-cell.))
1089                                    (,calls (cdr .pv-cell.)))
1090                                (declare ,(make-pv-type-declaration pv)
1091                                         ,(make-calls-type-declaration calls))
1092                                ,pv ,calls
1093                                ,@forms)))
1094            (fast-lexical-method-functions
1095             (,(car lmf-params) .next-method-call. ,req-args ,rest-arg
1096              ,@(cdddr lmf-params))
1097             ,@inner-decls
1098             ,@body-sans-decls)))
1099         ',initargs))))
1100
1101 ;;; Use arrays and hash tables and the fngen stuff to make this much
1102 ;;; better. It doesn't really matter, though, because a function
1103 ;;; returned by this will get called only when the user explicitly
1104 ;;; funcalls a result of method-function. BUT, this is needed to make
1105 ;;; early methods work.
1106 (defun method-function-from-fast-function (fmf)
1107   (declare (type function fmf))
1108   (let* ((method-function nil) (pv-table nil)
1109          (arg-info (method-function-get fmf :arg-info))
1110          (nreq (car arg-info))
1111          (restp (cdr arg-info)))
1112     (setq method-function
1113           (lambda (method-args next-methods)
1114             (unless pv-table
1115               (setq pv-table (method-function-pv-table fmf)))
1116             (let* ((pv-cell (when pv-table
1117                               (get-method-function-pv-cell
1118                                method-function method-args pv-table)))
1119                    (nm (car next-methods))
1120                    (nms (cdr next-methods))
1121                    (nmc (when nm
1122                           (make-method-call
1123                            :function (if (std-instance-p nm)
1124                                          (method-function nm)
1125                                          nm)
1126                            :call-method-args (list nms)))))
1127               (if restp
1128                   (let* ((rest (nthcdr nreq method-args))
1129                          (args (ldiff method-args rest)))
1130                     (apply fmf pv-cell nmc (nconc args (list rest))))
1131                   (apply fmf pv-cell nmc method-args)))))
1132     (let* ((fname (method-function-get fmf :name))
1133            (name `(,(or (get (car fname) 'method-sym)
1134                         (setf (get (car fname) 'method-sym)
1135                               (let ((str (symbol-name (car fname))))
1136                                 (if (string= "FAST-" str :end2 5)
1137                                     (intern (subseq str 5) *pcl-package*)
1138                                     (car fname)))))
1139                     ,@(cdr fname))))
1140       (set-fun-name method-function name))
1141     (setf (method-function-get method-function :fast-function) fmf)
1142     method-function))
1143
1144 (defun get-method-function-pv-cell (method-function
1145                                     method-args
1146                                     &optional pv-table)
1147   (let ((pv-table (or pv-table (method-function-pv-table method-function))))
1148     (when pv-table
1149       (let ((pv-wrappers (pv-wrappers-from-all-args pv-table method-args)))
1150         (when pv-wrappers
1151           (pv-table-lookup pv-table pv-wrappers))))))
1152
1153 (defun pv-table-lookup-pv-args (pv-table &rest pv-parameters)
1154   (pv-table-lookup pv-table (pv-wrappers-from-pv-args pv-parameters)))
1155
1156 (defun pv-wrappers-from-pv-args (&rest args)
1157   (let (wrappers)
1158     (dolist (arg args (if (cdr wrappers) (nreverse wrappers) (car wrappers)))
1159       (let ((wrapper (wrapper-of arg)))
1160         (push (if (invalid-wrapper-p wrapper)
1161                   (check-wrapper-validity wrapper)
1162                   wrapper)
1163               wrappers)))))
1164
1165 (defun pv-wrappers-from-all-args (pv-table args)
1166   (loop for snl in (pv-table-slot-name-lists pv-table) and arg in args
1167         when snl
1168           collect (wrapper-of arg) into wrappers
1169         finally (return (if (cdr wrappers) wrappers (car wrappers)))))
1170
1171 ;;; Return the subset of WRAPPERS which is used in the cache
1172 ;;; of PV-TABLE.
1173 (defun pv-wrappers-from-all-wrappers (pv-table wrappers)
1174   (loop for snl in (pv-table-slot-name-lists pv-table) and w in wrappers
1175         when snl
1176           collect w into result
1177         finally (return (if (cdr result) result (car result)))))