src/pcl/walk.lisp

   1 ;;;; a simple code walker
   2 ;;;;
   3 ;;;; The code which implements the macroexpansion environment
   4 ;;;; manipulation mechanisms is in the first part of the file, the
   5 ;;;; real walker follows it.
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9
  10 ;;;; This software is derived from software originally released by Xerox
  11 ;;;; Corporation. Copyright and release statements follow. Later modifications
  12 ;;;; to the software are in the public domain and are provided with
  13 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
  14 ;;;; information.
  15
  16 ;;;; copyright information from original PCL sources:
  17 ;;;;
  18 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  19 ;;;; All rights reserved.
  20 ;;;;
  21 ;;;; Use and copying of this software and preparation of derivative works based
  22 ;;;; upon this software are permitted. Any distribution of this software or
  23 ;;;; derivative works must comply with all applicable United States export
  24 ;;;; control laws.
  25 ;;;;
  26 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  27 ;;;; warranty about the software, its performance or its conformity to any
  28 ;;;; specification.
  29
  30 (in-package "SB!WALKER")
  31 \f
  32 ;;;; forward references
  33
  34 (defvar *key-to-walker-environment*)
  35 \f
  36 ;;;; environment hacking stuff, necessarily SBCL-specific
  37
  38 ;;; Here in the original PCL were implementations of the
  39 ;;; implementation-specific environment hacking functions for each of
  40 ;;; the implementations this walker had been ported to. This
  41 ;;; functionality was originally factored out in order to make PCL
  42 ;;; portable from one Common Lisp to another. As of 19981107, that
  43 ;;; portability was fairly stale and (because of the scarcity of CLTL1
  44 ;;; implementations and the strong interdependence of the rest of ANSI
  45 ;;; Common Lisp on the CLOS system) fairly irrelevant. It was fairly
  46 ;;; thoroughly put out of its misery by WHN in his quest to clean up
  47 ;;; the system enough that it can be built from scratch using any ANSI
  48 ;;; Common Lisp.
  49 ;;;
  50 ;;; This code just hacks 'macroexpansion environments'. That is, it is
  51 ;;; only concerned with the function binding of symbols in the
  52 ;;; environment. The walker needs to be able to tell if the symbol
  53 ;;; names a lexical macro or function, and it needs to be able to
  54 ;;; build environments which contain lexical macro or function
  55 ;;; bindings. It must be able, when walking a MACROLET, FLET or LABELS
  56 ;;; form to construct an environment which reflects the bindings
  57 ;;; created by that form. Note that the environment created does NOT
  58 ;;; have to be sufficient to evaluate the body, merely to walk its
  59 ;;; body. This means that definitions do not have to be supplied for
  60 ;;; lexical functions, only the fact that that function is bound is
  61 ;;; important. For macros, the macroexpansion function must be
  62 ;;; supplied.
  63 ;;;
  64 ;;; This code is organized in a way that lets it work in
  65 ;;; implementations that stack cons their environments. That is
  66 ;;; reflected in the fact that the only operation that lets a user
  67 ;;; build a new environment is a WITH-BODY macro which executes its
  68 ;;; body with the specified symbol bound to the new environment. No
  69 ;;; code in this walker or in PCL will hold a pointer to these
  70 ;;; environments after the body returns. Other user code is free to do
  71 ;;; so in implementations where it works, but that code is not
  72 ;;; considered portable.
  73 ;;;
  74 ;;; There are 3 environment hacking tools. One macro,
  75 ;;; WITH-AUGMENTED-ENVIRONMENT, which is used to create new
  76 ;;; environments, and two functions, ENVIRONMENT-FUNCTION and
  77 ;;; ENVIRONMENT-MACRO, which are used to access the bindings of
  78 ;;; existing environments
  79
  80 ;;; In SBCL, as in CMU CL before it, the environment is represented
  81 ;;; with a structure that holds alists for the functional things,
  82 ;;; variables, blocks, etc. Except for SYMBOL-MACROLET, only the
  83 ;;; SB!C::LEXENV-FUNS slot is relevant. It holds: Alist (Name . What),
  84 ;;; where What is either a functional (a local function) or a list
  85 ;;; (MACRO . <function>) (a local macro, with the specifier expander.)
  86 ;;; Note that Name may be a (SETF <name>) function. Accessors are
  87 ;;; defined below, eg (ENV-WALK-FUNCTION ENV).
  88 ;;;
  89 ;;; If WITH-AUGMENTED-ENVIRONMENT is called from WALKER-ENVIRONMENT-BIND
  90 ;;; this code hides the WALKER version of an environment
  91 ;;; inside the SB!C::LEXENV structure.
  92 ;;;
  93 ;;; In CMUCL (and former SBCL), This used to be a list of lists of form
  94 ;;; (<gensym-name> MACRO . #<interpreted-function>) in the :functions slot
  95 ;;; in a C::LEXENV.
  96 ;;; This form was accepted by the compiler, but this was a crude hack,
  97 ;;; because the <interpreted-function> was used as a structure to hold the
  98 ;;; bits of interest, {function, form, declarations, lexical-variables},
  99 ;;; a list, which was not really an interpreted function.
 100 ;;; Instead this list was COERCEd to a #<FUNCTION ...>!
 101 ;;;
 102 ;;; Instead, we now use a special sort of "function"-type for that
 103 ;;; information, because the functions slot in SB!C::LEXENV is
 104 ;;; supposed to have a list of <Name MACRO . #<function> elements.
 105 ;;; So, now we hide our bits of interest in the walker-info slot in
 106 ;;; our new BOGO-FUN.
 107 ;;;
 108 ;;; MACROEXPAND-1 and SB!INT:EVAL-IN-LEXENV are the only SBCL
 109 ;;; functions that get called with the constructed environment
 110 ;;; argument.
 111
 112 (/show "walk.lisp 108")
 113
 114 (defmacro with-augmented-environment
 115     ((new-env old-env &key functions macros) &body body)
 116   `(let ((,new-env (with-augmented-environment-internal ,old-env
 117                                                         ,functions
 118                                                         ,macros)))
 119      ,@body))
 120
 121 ;;; a unique tag to show that we're the intended caller of BOGO-FUN
 122 (defvar *bogo-fun-magic-tag*
 123   '(:bogo-fun-magic-tag))
 124
 125 ;;; The interface of BOGO-FUNs (previously implemented as
 126 ;;; FUNCALLABLE-INSTANCEs) is just these two operations, so we can do
 127 ;;; them with ordinary closures.
 128 ;;;
 129 ;;; KLUDGE: BOGO-FUNs are sorta weird, and MNA and I have both hacked
 130 ;;; on this code without quite figuring out what they're for. (He
 131 ;;; changed them to work after some changes in the IR1 interpreter
 132 ;;; made functions not be built lazily, and I changed them so that
 133 ;;; they don't need FUNCALLABLE-INSTANCE stuff, so that the F-I stuff
 134 ;;; can become less general.) There may be further simplifications or
 135 ;;; clarifications which could be done. -- WHN 2001-10-19
 136 (defun walker-info-to-bogo-fun (walker-info)
 137   (lambda (magic-tag &rest rest)
 138     (aver (not rest)) ; else someone is using me in an unexpected way
 139     (aver (eql magic-tag *bogo-fun-magic-tag*)) ; else ditto
 140     walker-info))
 141 (defun bogo-fun-to-walker-info (bogo-fun)
 142   (declare (type function bogo-fun))
 143   (funcall bogo-fun *bogo-fun-magic-tag*))
 144
 145 (defun with-augmented-environment-internal (env funs macros)
 146   ;; Note: In order to record the correct function definition, we
 147   ;; would have to create an interpreted closure, but the
 148   ;; WITH-NEW-DEFINITION macro down below makes no distinction between
 149   ;; FLET and LABELS, so we have no idea what to use for the
 150   ;; environment. So we just blow it off, 'cause anything real we do
 151   ;; would be wrong. But we still have to make an entry so we can tell
 152   ;; functions from macros.
 153   (let ((lexenv (sb!kernel::coerce-to-lexenv env)))
 154     (sb!c::make-lexenv
 155      :default lexenv
 156      :vars (when (eql (caar macros) *key-to-walker-environment*)
 157              (copy-tree (remove :lexical-var (fourth (cadar macros))
 158                                 :key #'cadr)))
 159      :funs (append (mapcar (lambda (f)
 160                              (cons (car f)
 161                                    (sb!c::make-functional :lexenv lexenv)))
 162                            funs)
 163                    (mapcar (lambda (m)
 164                              (list* (car m)
 165                                     'sb!c::macro
 166                                     (if (eq (car m)
 167                                             *key-to-walker-environment*)
 168                                         (walker-info-to-bogo-fun (cadr m))
 169                                         (coerce (cadr m) 'function))))
 170                            macros)))))
 171
 172 (defun environment-function (env fn)
 173   (when env
 174     (let ((entry (assoc fn (sb!c::lexenv-funs env) :test #'equal)))
 175       (and entry
 176            (sb!c::functional-p (cdr entry))
 177            (cdr entry)))))
 178
 179 (defun environment-macro (env macro)
 180   (when env
 181     (let ((entry (assoc macro (sb!c::lexenv-funs env) :test #'eq)))
 182       (and entry
 183            (eq (cadr entry) 'sb!c::macro)
 184            (if (eq macro *key-to-walker-environment*)
 185                (values (bogo-fun-to-walker-info (cddr entry)))
 186                (values (function-lambda-expression (cddr entry))))))))
 187 \f
 188 ;;;; other environment hacking, not so SBCL-specific as the
 189 ;;;; environment hacking in the previous section
 190
 191 (defmacro with-new-definition-in-environment
 192           ((new-env old-env macrolet/flet/labels-form) &body body)
 193   (let ((functions (make-symbol "Functions"))
 194         (macros (make-symbol "Macros")))
 195     `(let ((,functions ())
 196            (,macros ()))
 197        (ecase (car ,macrolet/flet/labels-form)
 198          ((flet labels)
 199           (dolist (fn (cadr ,macrolet/flet/labels-form))
 200             (push fn ,functions)))
 201          ((macrolet)
 202           (dolist (mac (cadr ,macrolet/flet/labels-form))
 203             (push (list (car mac)
 204                         (convert-macro-to-lambda (cadr mac)
 205                                                  (cddr mac)
 206                                                  ,old-env
 207                                                  (string (car mac))))
 208                   ,macros))))
 209        (with-augmented-environment
 210               (,new-env ,old-env :functions ,functions :macros ,macros)
 211          ,@body))))
 212
 213 (defun convert-macro-to-lambda (llist body env &optional (name "dummy macro"))
 214   (let ((gensym (make-symbol name)))
 215     (eval-in-lexenv `(defmacro ,gensym ,llist ,@body)
 216                     (sb!c::make-restricted-lexenv env))
 217     (macro-function gensym)))
 218 \f
 219 ;;;; the actual walker
 220
 221 ;;; As the walker walks over the code, it communicates information to
 222 ;;; itself about the walk. This information includes the walk
 223 ;;; function, variable bindings, declarations in effect etc. This
 224 ;;; information is inherently lexical, so the walker passes it around
 225 ;;; in the actual environment the walker passes to macroexpansion
 226 ;;; functions. This is what makes the NESTED-WALK-FORM facility work
 227 ;;; properly.
 228 (defmacro walker-environment-bind ((var env &rest key-args)
 229                                       &body body)
 230   `(with-augmented-environment
 231      (,var ,env :macros (walker-environment-bind-1 ,env ,.key-args))
 232      .,body))
 233
 234 (defvar *key-to-walker-environment* (gensym))
 235
 236 (defun env-lock (env)
 237   (environment-macro env *key-to-walker-environment*))
 238
 239 (defun walker-environment-bind-1 (env &key (walk-function nil wfnp)
 240                                            (walk-form nil wfop)
 241                                            (declarations nil decp)
 242                                            (lexical-vars nil lexp))
 243   (let ((lock (env-lock env)))
 244     (list
 245       (list *key-to-walker-environment*
 246             (list (if wfnp walk-function (car lock))
 247                   (if wfop walk-form     (cadr lock))
 248                   (if decp declarations  (caddr lock))
 249                   (if lexp lexical-vars  (cadddr lock)))))))
 250
 251 (defun env-walk-function (env)
 252   (car (env-lock env)))
 253
 254 (defun env-walk-form (env)
 255   (cadr (env-lock env)))
 256
 257 (defun env-declarations (env)
 258   (caddr (env-lock env)))
 259
 260 (defun env-lexical-variables (env)
 261   (cadddr (env-lock env)))
 262
 263 (defun note-declaration (declaration env)
 264   (push declaration (caddr (env-lock env))))
 265
 266 (defun note-lexical-binding (thing env)
 267   (push (list thing :lexical-var) (cadddr (env-lock env))))
 268
 269 (defun var-lexical-p (var env)
 270   (let ((entry (member var (env-lexical-variables env) :key #'car :test #'eq)))
 271     (when (eq (cadar entry) :lexical-var)
 272       entry)))
 273
 274 (defun variable-symbol-macro-p (var env)
 275   (let ((entry (member var (env-lexical-variables env) :key #'car :test #'eq)))
 276     (when (eq (cadar entry) 'sb!sys:macro)
 277       entry)))
 278
 279 (defun walked-var-declaration-p (declaration)
 280   (member declaration '(sb!pcl::%class sb!pcl::%variable-rebinding special)))
 281
 282 (defun %var-declaration (declaration var env)
 283   (let ((id (or (var-lexical-p var env) var)))
 284     (dolist (decl (env-declarations env))
 285       (when (and (eq (car decl) declaration)
 286                  (eq (cadr decl) id))
 287         (return decl)))))
 288
 289 (defun var-declaration (declaration var env)
 290   (if (walked-var-declaration-p declaration)
 291       (%var-declaration declaration var env)
 292       (error "Not a variable declaration the walker cares about: ~S" declaration)))
 293
 294 #-sb-xc-host
 295 (define-compiler-macro var-declaration (&whole form declaration var env
 296                                         &environment lexenv)
 297   (if (sb!xc:constantp declaration lexenv)
 298       (let ((decl (constant-form-value declaration lexenv)))
 299         (if (walked-var-declaration-p decl)
 300             `(%var-declaration ,declaration ,var ,env)
 301             form))
 302       form))
 303
 304 (defun var-special-p (var env)
 305   (and (or (var-declaration 'special var env)
 306            (var-globally-special-p var))
 307        t))
 308
 309 (defun var-globally-special-p (symbol)
 310   (eq (info :variable :kind symbol) :special))
 311
 312 \f
 313 ;;;; handling of special forms
 314
 315 ;;; Here are some comments from the original PCL on the difficulty of
 316 ;;; doing this portably across different CLTL1 implementations. This
 317 ;;; is no longer directly relevant because this code now only runs on
 318 ;;; SBCL, but the comments are retained for culture: they might help
 319 ;;; explain some of the design decisions which were made in the code.
 320 ;;;
 321 ;;; and I quote...
 322 ;;;
 323 ;;;     The set of special forms is purposely kept very small because
 324 ;;;     any program analyzing program (read code walker) must have
 325 ;;;     special knowledge about every type of special form. Such a
 326 ;;;     program needs no special knowledge about macros...
 327 ;;;
 328 ;;; So all we have to do here is a define a way to store and retrieve
 329 ;;; templates which describe how to walk the 24 special forms and we
 330 ;;; are all set...
 331 ;;;
 332 ;;; Well, its a nice concept, and I have to admit to being naive
 333 ;;; enough that I believed it for a while, but not everyone takes
 334 ;;; having only 24 special forms as seriously as might be nice. There
 335 ;;; are (at least) 3 ways to lose:
 336 ;;
 337 ;;;   1 - Implementation x implements a Common Lisp special form as
 338 ;;;       a macro which expands into a special form which:
 339 ;;;      - Is a common lisp special form (not likely)
 340 ;;;      - Is not a common lisp special form (on the 3600 IF --> COND).
 341 ;;;
 342 ;;;     * We can save ourselves from this case (second subcase really)
 343 ;;;       by checking to see whether there is a template defined for
 344 ;;;       something before we check to see whether we can macroexpand it.
 345 ;;;
 346 ;;;   2 - Implementation x implements a Common Lisp macro as a special form.
 347 ;;;
 348 ;;;     * This is a screw, but not so bad, we save ourselves from it by
 349 ;;;       defining extra templates for the macros which are *likely* to
 350 ;;;       be implemented as special forms. [Note: As of sbcl-0.6.9, these
 351 ;;;       extra templates have been deleted, since this is not a problem
 352 ;;;       in SBCL and we no longer try to make this walker portable
 353 ;;;       across other possibly-broken CL implementations.]
 354 ;;;
 355 ;;;   3 - Implementation x has a special form which is not on the list of
 356 ;;;       Common Lisp special forms.
 357 ;;;
 358 ;;;     * This is a bad sort of a screw and happens more than I would
 359 ;;;       like to think, especially in the implementations which provide
 360 ;;;       more than just Common Lisp (3600, Xerox etc.).
 361 ;;;       The fix is not terribly satisfactory, but will have to do for
 362 ;;;       now. There is a hook in get walker-template which can get a
 363 ;;;       template from the implementation's own walker. That template
 364 ;;;       has to be converted, and so it may be that the right way to do
 365 ;;;       this would actually be for that implementation to provide an
 366 ;;;       interface to its walker which looks like the interface to this
 367 ;;;       walker.
 368
 369 (defmacro get-walker-template-internal (x)
 370   `(get ,x 'walker-template))
 371
 372 (defmacro define-walker-template (name
 373                                   &optional (template '(nil repeat (eval))))
 374   `(eval-when (:load-toplevel :execute)
 375      (setf (get-walker-template-internal ',name) ',template)))
 376
 377 (defun get-walker-template (x context)
 378   (cond ((symbolp x)
 379          (get-walker-template-internal x))
 380         ((and (listp x) (eq (car x) 'lambda))
 381          '(lambda repeat (eval)))
 382         (t
 383          ;; FIXME: In an ideal world we would do something similar to
 384          ;; COMPILER-ERROR here, replacing the form within the walker
 385          ;; with an error-signalling form. This is slightly less
 386          ;; pretty, but informative non the less. Best is the enemy of
 387          ;; good, etc.
 388          (error "Illegal function call in method body:~%  ~S"
 389                 context))))
 390 \f
 391 ;;;; the actual templates
 392
 393 ;;; ANSI special forms
 394 (define-walker-template block                (nil nil repeat (eval)))
 395 (define-walker-template catch                (nil eval repeat (eval)))
 396 (define-walker-template declare              walk-unexpected-declare)
 397 (define-walker-template eval-when            (nil quote repeat (eval)))
 398 (define-walker-template flet                 walk-flet)
 399 (define-walker-template function             (nil call))
 400 (define-walker-template go                   (nil quote))
 401 (define-walker-template if                   walk-if)
 402 (define-walker-template labels               walk-labels)
 403 (define-walker-template lambda               walk-lambda)
 404 (define-walker-template let                  walk-let)
 405 (define-walker-template let*                 walk-let*)
 406 (define-walker-template locally              walk-locally)
 407 (define-walker-template macrolet             walk-macrolet)
 408 (define-walker-template multiple-value-call  (nil eval repeat (eval)))
 409 (define-walker-template multiple-value-prog1 (nil return repeat (eval)))
 410 (define-walker-template multiple-value-setq  walk-multiple-value-setq)
 411 (define-walker-template multiple-value-bind  walk-multiple-value-bind)
 412 (define-walker-template progn                (nil repeat (eval)))
 413 (define-walker-template progv                (nil eval eval repeat (eval)))
 414 (define-walker-template quote                (nil quote))
 415 (define-walker-template return-from          (nil quote repeat (return)))
 416 (define-walker-template setq                 walk-setq)
 417 (define-walker-template symbol-macrolet      walk-symbol-macrolet)
 418 (define-walker-template tagbody              walk-tagbody)
 419 (define-walker-template the                  (nil quote eval))
 420 (define-walker-template throw                (nil eval eval))
 421 (define-walker-template unwind-protect       (nil return repeat (eval)))
 422
 423 ;;; SBCL-only special forms
 424 (define-walker-template sb!ext:truly-the     (nil quote eval))
 425 ;;; FIXME: maybe we don't need this one any more, given that
 426 ;;; NAMED-LAMBDA now expands into (FUNCTION (NAMED-LAMBDA ...))?
 427 (define-walker-template named-lambda         walk-named-lambda)
 428 \f
 429 (defvar *walk-form-expand-macros-p* nil)
 430
 431 (defun walk-form (form
 432                   &optional environment
 433                             (walk-function
 434                              (lambda (subform context env)
 435                                (declare (ignore context env))
 436                                subform)))
 437   (walker-environment-bind (new-env environment :walk-function walk-function)
 438     (walk-form-internal form :eval new-env)))
 439
 440 ;;; WALK-FORM-INTERNAL is the main driving function for the code
 441 ;;; walker. It takes a form and the current context and walks the form
 442 ;;; calling itself or the appropriate template recursively.
 443 ;;;
 444 ;;;   "It is recommended that a program-analyzing-program process a form
 445 ;;;    that is a list whose car is a symbol as follows:
 446 ;;;
 447 ;;;     1. If the program has particular knowledge about the symbol,
 448 ;;;        process the form using special-purpose code. All of the
 449 ;;;        standard special forms should fall into this category.
 450 ;;;     2. Otherwise, if MACRO-FUNCTION is true of the symbol apply
 451 ;;;        either MACROEXPAND or MACROEXPAND-1 and start over.
 452 ;;;     3. Otherwise, assume it is a function call. "
 453 (defun walk-form-internal (form context env)
 454   ;; First apply the walk-function to perform whatever translation
 455   ;; the user wants to this form. If the second value returned
 456   ;; by walk-function is T then we don't recurse...
 457   (catch form
 458     (multiple-value-bind (newform walk-no-more-p)
 459         (funcall (env-walk-function env) form context env)
 460       (catch newform
 461         (cond
 462          (walk-no-more-p newform)
 463          ((not (eq form newform))
 464           (walk-form-internal newform context env))
 465          ((not (consp newform))
 466           (let ((symmac (car (variable-symbol-macro-p newform env))))
 467             (if symmac
 468                 (let ((newnewform (walk-form-internal (cddr symmac)
 469                                                       context
 470                                                       env)))
 471                   (if (eq newnewform (cddr symmac))
 472                       (if *walk-form-expand-macros-p* newnewform newform)
 473                       newnewform))
 474                 newform)))
 475          (t
 476           (let* ((fn (car newform))
 477                  (template (get-walker-template fn newform)))
 478             (if template
 479                 (if (symbolp template)
 480                     (funcall template newform context env)
 481                     (walk-template newform template context env))
 482                 (multiple-value-bind (newnewform macrop)
 483                     (walker-environment-bind
 484                         (new-env env :walk-form newform)
 485                       (sb-xc:macroexpand-1 newform new-env))
 486                   (cond
 487                    (macrop
 488                     (let ((newnewnewform (walk-form-internal newnewform
 489                                                              context
 490                                                              env)))
 491                       (if (eq newnewnewform newnewform)
 492                           (if *walk-form-expand-macros-p* newnewform newform)
 493                           newnewnewform)))
 494                    ((and (symbolp fn)
 495                          (not (fboundp fn))
 496                          (special-operator-p fn))
 497                     ;; This shouldn't happen, since this walker is now
 498                     ;; maintained as part of SBCL, so it should know
 499                     ;; about all the special forms that SBCL knows
 500                     ;; about.
 501                     (bug "unexpected special form ~S" fn))
 502                    (t
 503                     ;; Otherwise, walk the form as if it's just a
 504                     ;; standard function call using a template for
 505                     ;; standard function call.
 506                     (walk-template
 507                      newnewform '(call repeat (eval)) context env))))))))))))
 508
 509 (defun walk-template (form template context env)
 510   (if (atom template)
 511       (ecase template
 512         ((eval function test effect return)
 513          (walk-form-internal form :eval env))
 514         ((quote nil) form)
 515         (set
 516           (walk-form-internal form :set env))
 517         ((lambda call)
 518          (cond ((legal-fun-name-p form)
 519                 form)
 520                (t (walk-form-internal form context env)))))
 521       (case (car template)
 522         (repeat
 523           (walk-template-handle-repeat form
 524                                        (cdr template)
 525                                        ;; For the case where nothing
 526                                        ;; happens after the repeat
 527                                        ;; optimize away the call to
 528                                        ;; LENGTH.
 529                                        (if (null (cddr template))
 530                                            ()
 531                                            (nthcdr (- (length form)
 532                                                       (length
 533                                                         (cddr template)))
 534                                                    form))
 535                                        context
 536                                        env))
 537         (if
 538           (walk-template form
 539                          (if (if (listp (cadr template))
 540                                  (eval (cadr template))
 541                                  (funcall (cadr template) form))
 542                              (caddr template)
 543                              (cadddr template))
 544                          context
 545                          env))
 546         (remote
 547           (walk-template form (cadr template) context env))
 548         (otherwise
 549           (cond ((atom form) form)
 550                 (t (recons form
 551                            (walk-template
 552                              (car form) (car template) context env)
 553                            (walk-template
 554                              (cdr form) (cdr template) context env))))))))
 555
 556 (defun walk-template-handle-repeat (form template stop-form context env)
 557   (if (eq form stop-form)
 558       (walk-template form (cdr template) context env)
 559       (walk-template-handle-repeat-1
 560        form template (car template) stop-form context env)))
 561
 562 (defun walk-template-handle-repeat-1 (form template repeat-template
 563                                            stop-form context env)
 564   (cond ((null form) ())
 565         ((eq form stop-form)
 566          (if (null repeat-template)
 567              (walk-template stop-form (cdr template) context env)
 568              (error "while handling code walker REPEAT:
 569                      ~%ran into STOP while still in REPEAT template")))
 570         ((null repeat-template)
 571          (walk-template-handle-repeat-1
 572            form template (car template) stop-form context env))
 573         (t
 574          (recons form
 575                  (walk-template (car form) (car repeat-template) context env)
 576                  (walk-template-handle-repeat-1 (cdr form)
 577                                                 template
 578                                                 (cdr repeat-template)
 579                                                 stop-form
 580                                                 context
 581                                                 env)))))
 582
 583 (defun walk-repeat-eval (form env)
 584   (and form
 585        (recons form
 586                (walk-form-internal (car form) :eval env)
 587                (walk-repeat-eval (cdr form) env))))
 588
 589 (defun recons (x car cdr)
 590   (if (or (not (eq (car x) car))
 591           (not (eq (cdr x) cdr)))
 592       (cons car cdr)
 593       x))
 594
 595 (defun relist (x &rest args)
 596   (if (null args)
 597       nil
 598       (relist-internal x args nil)))
 599
 600 (defun relist* (x &rest args)
 601   (relist-internal x args t))
 602
 603 (defun relist-internal (x args *p)
 604   (if (null (cdr args))
 605       (if *p
 606           (car args)
 607           (recons x (car args) nil))
 608       (recons x
 609               (car args)
 610               (relist-internal (cdr x) (cdr args) *p))))
 611 \f
 612 ;;;; special walkers
 613
 614 (defun walk-declarations (body fn env
 615                                &optional doc-string-p declarations old-body
 616                                &aux (form (car body)) macrop new-form)
 617   (cond ((and (stringp form)                    ;might be a doc string
 618               (cdr body)                        ;isn't the returned value
 619               (null doc-string-p)               ;no doc string yet
 620               (null declarations))              ;no declarations yet
 621          (recons body
 622                  form
 623                  (walk-declarations (cdr body) fn env t)))
 624         ((and (listp form) (eq (car form) 'declare))
 625          ;; We got ourselves a real live declaration. Record it, look
 626          ;; for more.
 627          (dolist (declaration (cdr form))
 628            (let ((type (car declaration))
 629                  (name (cadr declaration))
 630                  (args (cddr declaration)))
 631              (if (walked-var-declaration-p type)
 632                  (note-declaration `(,type
 633                                      ,(or (var-lexical-p name env) name)
 634                                      ,.args)
 635                                    env)
 636                  (note-declaration declaration env))
 637              (push declaration declarations)))
 638          (recons body
 639                  form
 640                  (walk-declarations
 641                    (cdr body) fn env doc-string-p declarations)))
 642         ((and form
 643               (listp form)
 644               (null (get-walker-template (car form) form))
 645               (progn
 646                 (multiple-value-setq (new-form macrop)
 647                                      (sb-xc:macroexpand-1 form env))
 648                 macrop))
 649          ;; This form was a call to a macro. Maybe it expanded
 650          ;; into a declare?  Recurse to find out.
 651          (walk-declarations (recons body new-form (cdr body))
 652                             fn env doc-string-p declarations
 653                             (or old-body body)))
 654         (t
 655          ;; Now that we have walked and recorded the declarations,
 656          ;; call the function our caller provided to expand the body.
 657          ;; We call that function rather than passing the real-body
 658          ;; back, because we are RECONSING up the new body.
 659          (funcall fn (or old-body body) env))))
 660
 661 (defun walk-unexpected-declare (form context env)
 662   (declare (ignore context env))
 663   (warn "encountered ~S ~_in a place where a DECLARE was not expected"
 664         form)
 665   form)
 666
 667 (defun walk-arglist (arglist context env &optional (destructuringp nil)
 668                                          &aux arg)
 669   (cond ((null arglist) ())
 670         ((symbolp (setq arg (car arglist)))
 671          (or (member arg sb!xc:lambda-list-keywords :test #'eq)
 672              (note-lexical-binding arg env))
 673          (recons arglist
 674                  arg
 675                  (walk-arglist (cdr arglist)
 676                                context
 677                                env
 678                                (and destructuringp
 679                                     (not (member arg sb!xc:lambda-list-keywords))))))
 680         ((consp arg)
 681          (prog1 (recons arglist
 682                         (if destructuringp
 683                             (walk-arglist arg context env destructuringp)
 684                             (relist* arg
 685                                      (car arg)
 686                                      (walk-form-internal (cadr arg) :eval env)
 687                                      (cddr arg)))
 688                         (walk-arglist (cdr arglist) context env nil))
 689                 (if (symbolp (car arg))
 690                     (note-lexical-binding (car arg) env)
 691                     (note-lexical-binding (cadar arg) env))
 692                 (or (null (cddr arg))
 693                     (not (symbolp (caddr arg)))
 694                     (note-lexical-binding (caddr arg) env))))
 695           (t
 696            (error "can't understand something in the arglist ~S" arglist))))
 697
 698 (defun walk-let (form context env)
 699   (walk-let/let* form context env nil))
 700
 701 (defun walk-let* (form context env)
 702   (walk-let/let* form context env t))
 703
 704 (defun walk-let/let* (form context old-env sequentialp)
 705   (walker-environment-bind (new-env old-env)
 706     (let* ((let/let* (car form))
 707            (bindings (cadr form))
 708            (body (cddr form))
 709            (walked-bindings
 710              (walk-bindings-1 bindings
 711                               old-env
 712                               new-env
 713                               context
 714                               sequentialp))
 715            (walked-body
 716              (walk-declarations body #'walk-repeat-eval new-env)))
 717       (relist*
 718         form let/let* walked-bindings walked-body))))
 719
 720 (defun walk-locally (form context old-env)
 721   (declare (ignore context))
 722   (walker-environment-bind (new-env old-env)
 723     (let* ((locally (car form))
 724            (body (cdr form))
 725            (walked-body
 726             (walk-declarations body #'walk-repeat-eval new-env)))
 727       (relist*
 728        form locally walked-body))))
 729
 730 (defun walk-multiple-value-setq (form context env)
 731   (let ((vars (cadr form)))
 732     (if (some (lambda (var)
 733                 (variable-symbol-macro-p var env))
 734               vars)
 735         (let* ((temps (mapcar (lambda (var)
 736                                 (declare (ignore var))
 737                                 (gensym))
 738                               vars))
 739                (sets (mapcar (lambda (var temp) `(setq ,var ,temp))
 740                              vars
 741                              temps))
 742                (expanded `(multiple-value-bind ,temps ,(caddr form)
 743                              ,@sets))
 744                (walked (walk-form-internal expanded context env)))
 745           (if (eq walked expanded)
 746               form
 747               walked))
 748         (walk-template form '(nil (repeat (set)) eval) context env))))
 749
 750 (defun walk-multiple-value-bind (form context old-env)
 751   (walker-environment-bind (new-env old-env)
 752     (let* ((mvb (car form))
 753            (bindings (cadr form))
 754            (mv-form (walk-template (caddr form) 'eval context old-env))
 755            (body (cdddr form))
 756            walked-bindings
 757            (walked-body
 758              (walk-declarations
 759                body
 760                (lambda (real-body real-env)
 761                  (setq walked-bindings
 762                        (walk-bindings-1 bindings
 763                                         old-env
 764                                         new-env
 765                                         context
 766                                         nil))
 767                  (walk-repeat-eval real-body real-env))
 768                new-env)))
 769       (relist* form mvb walked-bindings mv-form walked-body))))
 770
 771 (defun walk-bindings-1 (bindings old-env new-env context sequentialp)
 772   (and bindings
 773        (let ((binding (car bindings)))
 774          (recons bindings
 775                  (if (symbolp binding)
 776                      (prog1 binding
 777                             (note-lexical-binding binding new-env))
 778                      (prog1 (relist* binding
 779                                      (car binding)
 780                                      (walk-form-internal (cadr binding)
 781                                                          context
 782                                                          (if sequentialp
 783                                                              new-env
 784                                                              old-env))
 785                                      ;; Save cddr for DO/DO*; it is
 786                                      ;; the next value form. Don't
 787                                      ;; walk it now, though.
 788                                      (cddr binding))
 789                             (note-lexical-binding (car binding) new-env)))
 790                  (walk-bindings-1 (cdr bindings)
 791                                   old-env
 792                                   new-env
 793                                   context
 794                                   sequentialp)))))
 795
 796 (defun walk-bindings-2 (bindings walked-bindings context env)
 797   (and bindings
 798        (let ((binding (car bindings))
 799              (walked-binding (car walked-bindings)))
 800          (recons bindings
 801                  (if (symbolp binding)
 802                      binding
 803                      (relist* binding
 804                               (car walked-binding)
 805                               (cadr walked-binding)
 806                               (walk-template (cddr binding)
 807                                              '(eval)
 808                                              context
 809                                              env)))
 810                  (walk-bindings-2 (cdr bindings)
 811                                   (cdr walked-bindings)
 812                                   context
 813                                   env)))))
 814
 815 (defun walk-lambda (form context old-env)
 816   (walker-environment-bind (new-env old-env)
 817     (let* ((arglist (cadr form))
 818            (body (cddr form))
 819            (walked-arglist (walk-arglist arglist context new-env))
 820            (walked-body
 821              (walk-declarations body #'walk-repeat-eval new-env)))
 822       (relist* form
 823                (car form)
 824                walked-arglist
 825                walked-body))))
 826
 827 (defun walk-named-lambda (form context old-env)
 828   (walker-environment-bind (new-env old-env)
 829     (let* ((name (second form))
 830            (arglist (third form))
 831            (body (cdddr form))
 832            (walked-arglist (walk-arglist arglist context new-env))
 833            (walked-body
 834              (walk-declarations body #'walk-repeat-eval new-env)))
 835       (relist* form
 836                (car form)
 837                name
 838                walked-arglist
 839                walked-body))))
 840
 841 (defun walk-setq (form context env)
 842   (if (cdddr form)
 843       (let* ((expanded (let ((rforms nil)
 844                              (tail (cdr form)))
 845                          (loop (when (null tail) (return (nreverse rforms)))
 846                                (let ((var (pop tail)) (val (pop tail)))
 847                                  (push `(setq ,var ,val) rforms)))))
 848              (walked (walk-repeat-eval expanded env)))
 849         (if (eq expanded walked)
 850             form
 851             `(progn ,@walked)))
 852       (let* ((var (cadr form))
 853              (val (caddr form))
 854              (symmac (car (variable-symbol-macro-p var env))))
 855         (if symmac
 856             (let* ((expanded `(setf ,(cddr symmac) ,val))
 857                    (walked (walk-form-internal expanded context env)))
 858               (if (eq expanded walked)
 859                   form
 860                   walked))
 861             (relist form 'setq
 862                     (walk-form-internal var :set env)
 863                     (walk-form-internal val :eval env))))))
 864
 865 (defun walk-symbol-macrolet (form context old-env)
 866   (declare (ignore context))
 867   (let* ((bindings (cadr form))
 868          (body (cddr form)))
 869     (walker-environment-bind
 870         (new-env old-env
 871                  :lexical-vars
 872                  (append (mapcar (lambda (binding)
 873                                    `(,(car binding)
 874                                      sb!sys:macro . ,(cadr binding)))
 875                                  bindings)
 876                          (env-lexical-variables old-env)))
 877       (relist* form 'symbol-macrolet bindings
 878                (walk-declarations body #'walk-repeat-eval new-env)))))
 879
 880 (defun walk-tagbody (form context env)
 881   (recons form (car form) (walk-tagbody-1 (cdr form) context env)))
 882
 883 (defun walk-tagbody-1 (form context env)
 884   (and form
 885        (recons form
 886                (walk-form-internal (car form)
 887                                    (if (symbolp (car form)) 'quote context)
 888                                    env)
 889                (walk-tagbody-1 (cdr form) context env))))
 890
 891 (defun walk-macrolet (form context old-env)
 892   (walker-environment-bind (old-env old-env)
 893     (walker-environment-bind (macro-env
 894                               nil
 895                               :walk-function (env-walk-function old-env))
 896       (labels ((walk-definitions (definitions)
 897                  (and definitions
 898                       (let ((definition (car definitions)))
 899                         (recons definitions
 900                                 (relist* definition
 901                                          (car definition)
 902                                          (walk-arglist (cadr definition)
 903                                                        context
 904                                                        macro-env
 905                                                        t)
 906                                          (walk-declarations (cddr definition)
 907                                                             #'walk-repeat-eval
 908                                                             macro-env))
 909                                 (walk-definitions (cdr definitions)))))))
 910         (with-new-definition-in-environment (new-env old-env form)
 911           (relist* form
 912                    (car form)
 913                    (walk-definitions (cadr form))
 914                    (walk-declarations (cddr form)
 915                                       #'walk-repeat-eval
 916                                       new-env)))))))
 917
 918 (defun walk-flet (form context old-env)
 919   (walker-environment-bind (old-env old-env)
 920     (labels ((walk-definitions (definitions)
 921                (if (null definitions)
 922                    ()
 923                    (recons definitions
 924                            (walk-lambda (car definitions) context old-env)
 925                            (walk-definitions (cdr definitions))))))
 926       (recons form
 927               (car form)
 928               (recons (cdr form)
 929                       (walk-definitions (cadr form))
 930                       (with-new-definition-in-environment (new-env old-env form)
 931                         (walk-declarations (cddr form)
 932                                            #'walk-repeat-eval
 933                                            new-env)))))))
 934
 935 (defun walk-labels (form context old-env)
 936   (walker-environment-bind (old-env old-env)
 937     (with-new-definition-in-environment (new-env old-env form)
 938       (labels ((walk-definitions (definitions)
 939                  (if (null definitions)
 940                      ()
 941                      (recons definitions
 942                              (walk-lambda (car definitions) context new-env)
 943                              (walk-definitions (cdr definitions))))))
 944         (recons form
 945                 (car form)
 946                 (recons (cdr form)
 947                         (walk-definitions (cadr form))
 948                         (walk-declarations (cddr form)
 949                                            #'walk-repeat-eval
 950                                            new-env)))))))
 951
 952 (defun walk-if (form context env)
 953   (destructuring-bind (if predicate arm1 &optional arm2) form
 954     (declare (ignore if)) ; should be 'IF
 955     (relist form
 956             'if
 957             (walk-form-internal predicate context env)
 958             (walk-form-internal arm1 context env)
 959             (walk-form-internal arm2 context env))))
 960 \f
 961 ;;;; examples
 962
 963 #|
 964 ;;; Here are some examples of the kinds of things you should be able
 965 ;;; to do with your implementation of the macroexpansion environment
 966 ;;; hacking mechanism.
 967 ;;;
 968 ;;; WITH-LEXICAL-MACROS is kind of like MACROLET, but it only takes
 969 ;;; names of the macros and actual macroexpansion functions to use to
 970 ;;; macroexpand them. The win about that is that for macros which want
 971 ;;; to wrap several MACROLETs around their body, they can do this but
 972 ;;; have the macroexpansion functions be compiled. See the WITH-RPUSH
 973 ;;; example.
 974 ;;;
 975 ;;; If the implementation had a special way of communicating the
 976 ;;; augmented environment back to the evaluator that would be totally
 977 ;;; great. It would mean that we could just augment the environment
 978 ;;; then pass control back to the implementations own compiler or
 979 ;;; interpreter. We wouldn't have to call the actual walker. That
 980 ;;; would make this much faster. Since the principal client of this is
 981 ;;; defmethod it would make compiling defmethods faster and that would
 982 ;;; certainly be a win.
 983
 984 (defmacro with-lexical-macros (macros &body body &environment old-env)
 985   (with-augmented-environment (new-env old-env :macros macros)
 986     (walk-form (cons 'progn body) :environment new-env)))
 987
 988 (defun expand-rpush (form env)
 989   (declare (ignore env))
 990   `(push ,(caddr form) ,(cadr form)))
 991
 992 (defmacro with-rpush (&body body)
 993   `(with-lexical-macros ,(list (list 'rpush #'expand-rpush)) ,@body))
 994 |#