src/run.lisp

   1 ;; -*- lisp -*-
   2
   3 (in-package :it.bese.FiveAM)
   4
   5 ;;;; * Running Tests
   6
   7 ;;;; Once the programmer has defined what the tests are these need to
   8 ;;;; be run and the expected effects should be compared with the
   9 ;;;; actual effects. FiveAM provides the function RUN for this
  10 ;;;; purpose, RUN executes a number of tests and collects the results
  11 ;;;; of each individual check into a list which is then
  12 ;;;; returned. There are three types of test results: passed, failed
  13 ;;;; and skipped, these are represented by TEST-RESULT objects.
  14
  15 ;;;; Generally running a test will return normally, but there are two
  16 ;;;; exceptional situations which can occur:
  17
  18 ;;;; - An exception is signaled while running the test. If the
  19 ;;;;   variable *debug-on-error* is T than FiveAM will enter the
  20 ;;;;   debugger, otherwise a test failure (of type
  21 ;;;;   unexpected-test-failure) is returned. When entering the
  22 ;;;;   debugger two restarts are made available, one simply reruns the
  23 ;;;;   current test and another signals a test-failure and continues
  24 ;;;;   with the remaining tests.
  25
  26 ;;;; - A circular dependency is detected. An error is signaled and a
  27 ;;;;   restart is made available which signals a test-skipped and
  28 ;;;;   continues with the remaining tests. This restart also sets the
  29 ;;;;   dependency status of the test to nil, so any tests which depend
  30 ;;;;   on this one (even if the dependency is not circular) will be
  31 ;;;;   skipped.
  32
  33 ;;;; The functions RUN!, !, !! and !!! are convenient wrappers around
  34 ;;;; RUN and EXPLAIN.
  35
  36 (defparameter *debug-on-error* nil
  37   "T if we should drop into a debugger on error, NIL otherwise.")
  38
  39 (defun import-testing-symbols (package-designator)
  40   (import '(5am::is 5am::is-true 5am::is-false 5am::signals 5am::finishes)
  41           package-designator))
  42
  43 (defparameter *run-queue* '()
  44   "List of test waiting to be run.")
  45
  46 (define-condition circular-dependency (error)
  47   ((test-case :initarg :test-case))
  48   (:report (lambda (cd stream)
  49              (format stream "A circular dependency wes detected in ~S." (slot-value cd 'test-case))))
  50   (:documentation "Condition signaled when a circular dependency
  51 between test-cases has been detected."))
  52
  53 (defgeneric run-resolving-dependencies (test)
  54   (:documentation "Given a dependency spec determine if the spec
  55 is satisfied or not, this will generally involve running other
  56 tests. If the dependency spec can be satisfied the test is alos
  57 run."))
  58
  59 (defmethod run-resolving-dependencies ((test test-case))
  60   "Return true if this test, and its dependencies, are satisfied,
  61   NIL otherwise."
  62   (case (status test)
  63     (:unknown
  64      (setf (status test) :resolving)
  65      (if (or (not (depends-on test))
  66              (resolve-dependencies (depends-on test)))
  67          (progn
  68            (run-test-lambda test)
  69            (status test))
  70          (with-run-state (result-list)
  71            (unless (eql :circular (status test))
  72              (push (make-instance 'test-skipped
  73                                   :test-case test
  74                                   :reason "Dependencies not satisfied")
  75                    result-list)
  76              (setf (status test) :depends-not-satisfied)))))
  77     (:resolving
  78      (restart-case
  79          (error 'circular-dependency :test-case test)
  80        (skip ()
  81          :report (lambda (s)
  82                    (format s "Skip the test ~S and all its dependencies." (name test)))
  83          (with-run-state (result-list)
  84            (push (make-instance 'test-skipped :reason "Circular dependencies" :test-case test)
  85                  result-list))
  86          (setf (status test) :circular))))
  87     (t (status test))))
  88
  89 (defmethod resolve-dependencies ((depends-on symbol))
  90   "A test which depends on a symbol is interpreted as `(AND
  91   ,DEPENDS-ON)."
  92   (run-resolving-dependencies (get-test depends-on)))
  93
  94 (defmethod resolve-dependencies ((depends-on list))
  95   "Return true if the dependency spec DEPENDS-ON is satisfied,
  96   nil otherwise."
  97   (if (null depends-on)
  98       t
  99       (flet ((satisfies-depends-p (test)
 100                (funcall test (lambda (dep)
 101                                (eql t (resolve-dependencies dep)))
 102                              (cdr depends-on))))
 103         (ecase (car depends-on)
 104           (and (satisfies-depends-p #'every))
 105           (or  (satisfies-depends-p #'some))
 106           (not (satisfies-depends-p #'notany))))))
 107
 108 (defun results-status (result-list)
 109   "Given a list of test results (generated while running a test)
 110   return true if all of the results are of type TEST-PASSED,
 111   faile otherwise."
 112   (every (lambda (res)
 113            (typep res 'test-passed))
 114          result-list))
 115
 116 (defun return-result-list (test-lambda)
 117   "Run the test function TEST-LAMBDA and return a list of all
 118   test results generated, does not modify the special environment
 119   variable RESULT-LIST."
 120   (bind-run-state ((result-list '()))
 121     (funcall test-lambda)
 122     result-list))
 123
 124 (defmethod run-test-lambda ((test test-case))
 125   (with-run-state (result-list)
 126     (bind-run-state ((current-test test))
 127       (labels ((abort-test (e)
 128                  (add-result 'unexpected-test-failure
 129                              :test-expr nil
 130                              :test-case test
 131                              :reason (format nil "Unexpected Error: ~S." e)
 132                              :condition e))
 133                (run-it ()
 134                  (let ((result-list '()))
 135                    (declare (special result-list))
 136                    (handler-bind ((error (lambda (e)
 137                                            (unless *debug-on-error*
 138                                              (abort-test e)
 139                                              (return-from run-it result-list)))))
 140                      (restart-case
 141                          (funcall (test-lambda test))
 142                        (retest ()
 143                          :report (lambda (stream)
 144                                    (format stream "~@<Rerun the test ~S~@:>" test))
 145                          (return-from run-it (run-it)))
 146                        (ignore ()
 147                          :report (lambda (stream)
 148                                    (format stream "~@<Signal a test failure and abort the test ~S.~@:>" test))
 149                          (abort-test (make-instance 'test-failure :test-case test
 150                                                     :reason "Failure restart."))))
 151                      result-list))))
 152         (let ((results (run-it)))
 153           (setf (status test) (results-status results)
 154                 result-list (nconc result-list results)))))))
 155
 156 (defgeneric %run (test-spec)
 157   (:documentation "Internal method for running a test. Does not
 158   update the status of the tests nor the special vairables !,
 159   !!, !!!"))
 160
 161 (defmethod %run ((test test-case))
 162   (run-resolving-dependencies test))
 163
 164 (defmethod %run ((suite test-suite))
 165   (let ((suite-results '()))
 166     (bind-run-state ((result-list '()))
 167       (loop for test being the hash-values of (tests suite)
 168             do (%run test)
 169             finally (setf suite-results result-list)))
 170     (setf (status suite) (every (lambda (res)
 171                                   (typep res 'test-passed))
 172                                   suite-results))
 173     (with-run-state (result-list)
 174       (setf result-list (nconc result-list suite-results)))))
 175
 176 (defmethod %run ((test-name symbol))
 177   (when-bind test (get-test test-name)
 178     (%run test)))
 179
 180 (defvar *initial-!* (lambda () (format t "Haven't run that many tests yet.~%")))
 181
 182 (defvar *!* *initial-!*)
 183 (defvar *!!* *initial-!*)
 184 (defvar *!!!* *initial-!*)
 185
 186 ;;;; ** Public entry points
 187
 188 (defun run! (test-spec)
 189   "Equivalent to (explain (run TEST-SPEC))."
 190   (explain! (run test-spec)))
 191
 192 (defun explain! (result-list)
 193   "Explain the results of RESULT-LIST using a
 194 detailed-text-explainer with output going to *test-dribble*"
 195   (explain (make-instance 'detailed-text-explainer) result-list *test-dribble*))
 196
 197 (defun run (test-spec)
 198     "Run the test specified by TEST-SPEC.
 199
 200 TEST-SPEC can be either a symbol naming a test or test suite, or
 201 a testable-object object. This function changes the operations
 202 performed by the !, !! and !!! functions."
 203     (psetf *!* (lambda ()
 204                  (loop for test being the hash-keys of *test*
 205                     do (setf (status (get-test test)) :unknown))
 206                  (bind-run-state ((result-list '()))
 207                    (%run test-spec)
 208                    result-list))
 209            *!!* *!*
 210            *!!!* *!!*)
 211     (funcall *!*))
 212
 213 (defun ! ()
 214   "Rerun the most recently run test and explain the results."
 215   (explain! (funcall *!*)))
 216
 217 (defun !! ()
 218   "Rerun the second most recently run test and explain the results."
 219   (explain! (funcall *!!*)))
 220
 221 (defun !!! ()
 222   "Rerun the third most recently run test and explain the results."
 223   (explain! (funcall *!!!*)))
 224
 225 ;; Copyright (c) 2002-2003, Edward Marco Baringer
 226 ;; All rights reserved.
 227 ;;
 228 ;; Redistribution and use in source and binary forms, with or without
 229 ;; modification, are permitted provided that the following conditions are
 230 ;; met:
 231 ;;
 232 ;;  - Redistributions of source code must retain the above copyright
 233 ;;    notice, this list of conditions and the following disclaimer.
 234 ;;
 235 ;;  - Redistributions in binary form must reproduce the above copyright
 236 ;;    notice, this list of conditions and the following disclaimer in the
 237 ;;    documentation and/or other materials provided with the distribution.
 238 ;;
 239 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 240 ;;    of its contributors may be used to endorse or promote products
 241 ;;    derived from this software without specific prior written permission.
 242 ;;
 243 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 244 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 245 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 246 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 247 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 248 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 249 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 250 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 251 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 252 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 253 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.