src/run.lisp

   1 ;; -*- lisp -*-
   2
   3 (in-package :it.bese.FiveAM)
   4
   5 ;;;; * Running Tests
   6
   7 ;;;; Once the programmer has defined what the tests are these need to
   8 ;;;; be run and the expected effects should be compared with the
   9 ;;;; actual effects. FiveAM provides the function RUN for this
  10 ;;;; purpose, RUN executes a number of tests and collects the results
  11 ;;;; of each individual check into a list which is then
  12 ;;;; returned. There are three types of test results: passed, failed
  13 ;;;; and skipped, these are represented by TEST-RESULT objects.
  14
  15 ;;;; Generally running a test will return normally, but there are two
  16 ;;;; exceptional situations which can occur:
  17
  18 ;;;; - An exception is signaled while running the test. If the
  19 ;;;;   variable *debug-on-error* is T than FiveAM will enter the
  20 ;;;;   debugger, otherwise a test failure (of type
  21 ;;;;   unexpected-test-failure) is returned. When entering the
  22 ;;;;   debugger two restarts are made available, one simply reruns the
  23 ;;;;   current test and another signals a test-failure and continues
  24 ;;;;   with the remaining tests.
  25
  26 ;;;; - A circular dependency is detected. An error is signaled and a
  27 ;;;;   restart is made available which signals a test-skipped and
  28 ;;;;   continues with the remaining tests. This restart also sets the
  29 ;;;;   dependency status of the test to nil, so any tests which depend
  30 ;;;;   on this one (even if the dependency is not circular) will be
  31 ;;;;   skipped.
  32
  33 ;;;; The functions RUN!, !, !! and !!! are convenient wrappers around
  34 ;;;; RUN and EXPLAIN.
  35
  36 (defparameter *debug-on-error* nil
  37   "T if we should drop into a debugger on error, NIL otherwise.")
  38
  39 (defun import-testing-symbols (package-designator)
  40   (import '(5am::is 5am::is-true 5am::is-false 5am::signals 5am::finishes)
  41           package-designator))
  42
  43 (defparameter *run-queue* '()
  44   "List of test waiting to be run.")
  45
  46 (define-condition circular-dependency (error)
  47   ((test-case :initarg :test-case))
  48   (:report (lambda (cd stream)
  49              (format stream "A circular dependency wes detected in ~S." (slot-value cd 'test-case))))
  50   (:documentation "Condition signaled when a circular dependency
  51 between test-cases has been detected."))
  52
  53 (defgeneric run-resolving-dependencies (test)
  54   (:documentation "Given a dependency spec determine if the spec
  55 is satisfied or not, this will generally involve running other
  56 tests. If the dependency spec can be satisfied the test is alos
  57 run."))
  58
  59 (defmethod run-resolving-dependencies ((test test-case))
  60   "Return true if this test, and its dependencies, are satisfied,
  61   NIL otherwise."
  62   (case (status test)
  63     (:unknown
  64      (setf (status test) :resolving)
  65      (if (or (not (depends-on test))
  66              (resolve-dependencies (depends-on test)))
  67          (progn
  68            (run-test-lambda test)
  69            (status test))
  70          (with-run-state (result-list)
  71            (unless (eql :circular (status test))
  72              (push (make-instance 'test-skipped
  73                                   :test-case test
  74                                   :reason "Dependencies not satisfied")
  75                    result-list)
  76              (setf (status test) :depends-not-satisfied)))))
  77     (:resolving
  78      (restart-case
  79          (error 'circular-dependency :test-case test)
  80        (skip ()
  81          :report (lambda (s)
  82                    (format s "Skip the test ~S and all its dependencies." (name test)))
  83          (with-run-state (result-list)
  84            (push (make-instance 'test-skipped :reason "Circular dependencies" :test-case test)
  85                  result-list))
  86          (setf (status test) :circular))))
  87     (t (status test))))
  88
  89 (defmethod resolve-dependencies ((depends-on symbol))
  90   "A test which depends on a symbol is interpreted as `(AND
  91   ,DEPENDS-ON)."
  92   (run-resolving-dependencies (get-test depends-on)))
  93
  94 (defmethod resolve-dependencies ((depends-on list))
  95   "Return true if the dependency spec DEPENDS-ON is satisfied,
  96   nil otherwise."
  97   (if (null depends-on)
  98       t
  99       (flet ((satisfies-depends-p (test)
 100                (funcall test (lambda (dep)
 101                                (eql t (resolve-dependencies dep)))
 102                              (cdr depends-on))))
 103         (ecase (car depends-on)
 104           (and (satisfies-depends-p #'every))
 105           (or  (satisfies-depends-p #'some))
 106           (not (satisfies-depends-p #'notany))))))
 107
 108 (defun results-status (result-list)
 109   "Given a list of test results (generated while running a test)
 110   return true if all of the results are of type TEST-PASSED,
 111   faile otherwise."
 112   (every (lambda (res)
 113            (typep res 'test-passed))
 114          result-list))
 115
 116 (defun return-result-list (test-lambda)
 117   "Run the test function TEST-LAMBDA and return a list of all
 118   test results generated, does not modify the special environment
 119   variable RESULT-LIST."
 120   (bind-run-state ((result-list '()))
 121     (funcall test-lambda)
 122     result-list))
 123
 124 (defmethod run-test-lambda ((test test-case))
 125   (with-run-state (result-list)
 126     (bind-run-state ((current-test test))
 127       (labels ((abort-test (e)
 128                  (add-result  'unexpected-test-failure
 129                               :test-case test
 130                               :reason (format nil "Unexpected Error: ~S." e)
 131                               :condition e))
 132                (run-it ()
 133                  (let ((result-list '()))
 134                    (declare (special result-list))
 135                    (handler-bind ((error (lambda (e)
 136                                            (unless *debug-on-error*
 137                                              (abort-test e)
 138                                              (return-from run-it result-list)))))
 139                      (restart-case
 140                          (funcall (test-lambda test))
 141                        (retest ()
 142                          :report (lambda (stream)
 143                                    (format stream "~@<Rerun the test ~S~@:>" test))
 144                          (return-from run-it (run-it)))
 145                        (ignore ()
 146                          :report (lambda (stream)
 147                                    (format stream "~@<Signal a test failure and abort the test ~S.~@:>" test))
 148                          (abort-test (make-instance 'test-failure :test-case test
 149                                                     :reason "Failure restart."))))
 150                      result-list))))
 151         (let ((results (run-it)))
 152           (setf (status test) (results-status results)
 153                 result-list (nconc result-list results)))))))
 154
 155 (defgeneric %run (test-spec)
 156   (:documentation "Internal method for running a test. Does not
 157   update the status of the tests nor the special vairables !,
 158   !!, !!!"))
 159
 160 (defmethod %run ((test test-case))
 161   (run-resolving-dependencies test))
 162
 163 (defmethod %run ((suite test-suite))
 164   (let ((suite-results '()))
 165     (bind-run-state ((result-list '()))
 166       (loop for test being the hash-values of (tests suite)
 167             do (%run test)
 168             finally (setf suite-results result-list)))
 169     (setf (status suite) (every (lambda (res)
 170                                   (typep res 'test-passed))
 171                                   suite-results))
 172     (with-run-state (result-list)
 173       (setf result-list (nconc result-list suite-results)))))
 174
 175 (defmethod %run ((test-name symbol))
 176   (when-bind test (get-test test-name)
 177     (%run test)))
 178
 179 (defvar *initial-!* (lambda () (format t "Haven't run that many tests yet.~%")))
 180
 181 (defvar *!* *initial-!*)
 182 (defvar *!!* *initial-!*)
 183 (defvar *!!!* *initial-!*)
 184
 185 ;;;; ** Public entry points
 186
 187 (defun run! (test-spec)
 188   "Equivalent to (explain (run TEST-SPEC))."
 189   (explain! (run test-spec)))
 190
 191 (defun explain! (result-list)
 192   "Explain the results of RESULT-LIST using a
 193 detailed-text-explainer with output going to *test-dribble*"
 194   (explain (make-instance 'detailed-text-explainer) result-list *test-dribble*))
 195
 196 (defun run (test-spec)
 197     "Run the test specified by TEST-SPEC.
 198
 199 TEST-SPEC can be either a symbol naming a test or test suite, or
 200 a testable-object object. This function changes the operations
 201 performed by the !, !! and !!! functions."
 202     (psetf *!* (lambda ()
 203                  (loop for test being the hash-keys of *test*
 204                     do (setf (status (get-test test)) :unknown))
 205                  (bind-run-state ((result-list '()))
 206                    (%run test-spec)
 207                    result-list))
 208            *!!* *!*
 209            *!!!* *!!*)
 210     (funcall *!*))
 211
 212 (defun ! ()
 213   "Rerun the most recently run test and explain the results."
 214   (explain! (funcall *!*)))
 215
 216 (defun !! ()
 217   "Rerun the second most recently run test and explain the results."
 218   (explain! (funcall *!!*)))
 219
 220 (defun !!! ()
 221   "Rerun the third most recently run test and explain the results."
 222   (explain! (funcall *!!!*)))
 223
 224 ;; Copyright (c) 2002-2003, Edward Marco Baringer
 225 ;; All rights reserved.
 226 ;;
 227 ;; Redistribution and use in source and binary forms, with or without
 228 ;; modification, are permitted provided that the following conditions are
 229 ;; met:
 230 ;;
 231 ;;  - Redistributions of source code must retain the above copyright
 232 ;;    notice, this list of conditions and the following disclaimer.
 233 ;;
 234 ;;  - Redistributions in binary form must reproduce the above copyright
 235 ;;    notice, this list of conditions and the following disclaimer in the
 236 ;;    documentation and/or other materials provided with the distribution.
 237 ;;
 238 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 239 ;;    of its contributors may be used to endorse or promote products
 240 ;;    derived from this software without specific prior written permission.
 241 ;;
 242 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 243 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 244 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 245 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 246 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 247 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 248 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 249 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 250 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 251 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 252 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.