src/suite.lisp

   1 ;;;; -*- Mode: Lisp; indent-tabs-mode: nil -*-
   2
   3 (in-package :it.bese.fiveam)
   4
   5 ;;;; * Test Suites
   6
   7 ;;;; Test suites allow us to collect multiple tests into a single
   8 ;;;; object and run them all using asingle name. Test suites do not
   9 ;;;; affect the way test are run nor the way the results are handled,
  10 ;;;; they are simply a test organizing group.
  11
  12 ;;;; Test suites can contain both tests and other test suites. Running
  13 ;;;; a test suite causes all of its tests and test suites to be
  14 ;;;; run. Suites do not affect test dependencies, running a test suite
  15 ;;;; can cause tests which are not in the suite to be run.
  16
  17 ;;;; ** Creating Suits
  18
  19 (defvar *suites* (make-hash-table :test 'eql))
  20
  21 (defmacro def-suite (name &key description (in nil in-p) (fixture nil fixture-p))
  22   "Define a new test-suite named NAME.
  23
  24 NAME::
  25   The symbol naming the test.
  26
  27 DESCRIPTION::
  28   A string describing the contents/purpose of this suite.
  29
  30 IN (a symbol)::
  31   If provided, causes this suite te be nested in the suite named by
  32   `IN`. If `IN` is `NIL`, as opposed to not being passed at all, the
  33   new suite will not be a part of any existing suite.
  34
  35 FIXTURE::
  36   Whatever value is passed here will be passed, unevaluated, to all
  37   tests defined in this suite.
  38
  39 [NOTE]
  40 This macro is built on top of `make-suite` and  it, just like `make-suite`,
  41 will overrwrite any existing suite named `NAME`."
  42   `(eval-when (:compile-toplevel :load-toplevel :execute)
  43      (make-suite ',name
  44                  ,@(when description `(:description ,description))
  45                  ,@(when in-p      `(:in ',in))
  46                  ,@(when fixture-p `(:fixture ',fixture)))
  47      ',name))
  48
  49 (defun remove-from-suites (test-name)
  50   (when (get-test test-name)
  51     ;; if this suite already exists, and it's :IN some other suite, remove it.
  52     (dolist (s (list-all-suites))
  53       (when (gethash test-name (tests s))
  54         (remhash test-name (tests s))))))
  55
  56 (defun make-suite (name &key description ((:in parent-suite) *suite*) fixture)
  57   "Create a new test suite object.
  58
  59 Overrides any existing suite named NAME."
  60   (remove-from-suites name)
  61   (let ((suite (make-instance 'test-suite :name name :fixture fixture)))
  62     (when description
  63       (setf (description suite) description))
  64     (setf (gethash name *suites*) suite)
  65     (loop for i in (ensure-list parent-suite)
  66           for in-suite = (get-test i)
  67           do (progn
  68                (when (null in-suite)
  69                  (cerror "Create a new suite named ~A." "Unknown suite ~A." i)
  70                  (setf (get-test in-suite) (make-suite i)
  71                        in-suite (get-test in-suite)))
  72                (setf (gethash name (tests in-suite)) suite)))
  73     (setf (get-test name) suite)
  74     suite))
  75
  76 (defun list-all-suites ()
  77   (loop for suite being the hash-value in *suites*
  78         collect suite))
  79
  80 ;;;; ** Managing the Current Suite
  81
  82 (defvar *suite* (setf (get-test 'T) (make-suite 'T :description "Default global suite" :in nil))
  83   "The current test suite object")
  84
  85 (defmacro in-suite (suite-name)
  86   "Set the `*suite*` special variable so that all tests defined
  87 after the execution of this form are, unless specified otherwise,
  88 in the test-suite named `SUITE-NAME`.
  89
  90 See also: `DEF-SUITE` and `*SUITE*`. "
  91   `(eval-when (:compile-toplevel :load-toplevel :execute)
  92      (%in-suite ,suite-name)))
  93
  94 (defmacro %in-suite (suite-name &rest def-suite-args)
  95   (with-gensyms (suite)
  96     `(progn
  97        (if-let (,suite (get-test ',suite-name))
  98          (setf *suite* ,suite)
  99          (progn
 100            (cerror "Create a new suite named ~A." "Unknown suite ~A." ',suite-name)
 101            (setf (get-test ',suite-name) (make-suite ',suite-name ,@def-suite-args)
 102                  *suite* (get-test ',suite-name))))
 103        ',suite-name)))
 104
 105 ;; Copyright (c) 2002-2003, Edward Marco Baringer
 106 ;; All rights reserved.
 107 ;;
 108 ;; Redistribution and use in source and binary forms, with or without
 109 ;; modification, are permitted provided that the following conditions are
 110 ;; met:
 111 ;;
 112 ;;  - Redistributions of source code must retain the above copyright
 113 ;;    notice, this list of conditions and the following disclaimer.
 114 ;;
 115 ;;  - Redistributions in binary form must reproduce the above copyright
 116 ;;    notice, this list of conditions and the following disclaimer in the
 117 ;;    documentation and/or other materials provided with the distribution.
 118 ;;
 119 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 120 ;;    of its contributors may be used to endorse or promote products
 121 ;;    derived from this software without specific prior written permission.
 122 ;;
 123 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 124 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 125 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 126 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 127 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 128 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 129 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 130 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 131 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 132 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 133 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE