tests/debug.impure.lisp

   1 ;;;; This file is for testing debugging functionality, using
   2 ;;;; test machinery which might have side effects (e.g.
   3 ;;;; executing DEFUN).
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; While most of SBCL is derived from the CMU CL system, the test
   9 ;;;; files (like this one) were written from scratch after the fork
  10 ;;;; from CMU CL.
  11 ;;;;
  12 ;;;; This software is in the public domain and is provided with
  13 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  14 ;;;; more information.
  15
  16 (cl:in-package :cl-user)
  17 \f
  18 ;;;; Check that we get debug arglists right.
  19
  20 ;;; FIXME: This should use some get-argslist like functionality that
  21 ;;; we actually export.
  22 ;;;
  23 ;;; Return the debug arglist of the function object FUN as a list, or
  24 ;;; punt with :UNKNOWN.
  25 (defun get-arglist (fun)
  26   (declare (type function fun))
  27   ;; The Lisp-level type FUNCTION can conceal a multitude of sins..
  28   (case (sb-kernel:widetag-of fun)
  29     (#.sb-vm:simple-fun-header-widetag
  30       (sb-kernel:%simple-fun-arglist fun))
  31     (#.sb-vm:closure-header-widetag (get-arglist
  32                                      (sb-kernel:%closure-fun fun)))
  33     ;; In code/describe.lisp, ll. 227 (%describe-fun), we use a scheme
  34     ;; like above, and it seems to work. -- MNA 2001-06-12
  35     ;;
  36     ;; (There might be other cases with arglist info also.
  37     ;; SIMPLE-FUN-HEADER-WIDETAG and CLOSURE-HEADER-WIDETAG just
  38     ;; happen to be the two case that I had my nose rubbed in when
  39     ;; debugging a GC problem caused by applying %SIMPLE-FUN-ARGLIST to
  40     ;; a closure. -- WHN 2001-06-05)
  41     (t :unknown)))
  42
  43 (defun zoop (zeep &key beep)
  44   blurp)
  45 (assert (equal (get-arglist #'zoop) '(zeep &key beep)))
  46
  47 ;;; Check some predefined functions too.
  48 ;;;
  49 ;;; (We don't know exactly what the arguments are, e.g. the first
  50 ;;; argument of PRINT might be SB-IMPL::OBJECT or SB-KERNEL::OBJ or
  51 ;;; whatever. But we do know the general structure that a correct
  52 ;;; answer should have, so we can safely do a lot of checks.)
  53 (destructuring-bind (object-sym &optional-sym stream-sym) (get-arglist #'print)
  54   (assert (symbolp object-sym))
  55   (assert (eql &optional-sym '&optional))
  56   (assert (symbolp stream-sym)))
  57 (destructuring-bind (dest-sym control-sym &rest-sym format-args-sym)
  58     (get-arglist #'format)
  59   (assert (symbolp dest-sym))
  60   (assert (symbolp control-sym))
  61   (assert (eql &rest-sym '&rest))
  62   (assert (symbolp format-args-sym)))
  63
  64 ;;; Check for backtraces generally being correct.  Ensure that the
  65 ;;; actual backtrace finishes (doesn't signal any errors on its own),
  66 ;;; and that it contains the frames we expect, doesn't contain any
  67 ;;; "bogus stack frame"s, and contains the appropriate toplevel call
  68 ;;; and hasn't been cut off anywhere.
  69 (defun verify-backtrace (test-function frame-specs &key (allow-stunted nil))
  70   (labels ((args-equal (want real)
  71              (cond ((eq '&rest (car want))
  72                     t)
  73                    ((endp want)
  74                     (endp real))
  75                    ((or (eq '? (car want)) (equal (car want) (car real)))
  76                     (args-equal (cdr want) (cdr real)))
  77                    (t
  78                     nil))))
  79     (let ((result nil))
  80       (block outer-handler
  81         (handler-bind
  82             ((error (lambda (condition)
  83                       ;; find the part of the backtrace we're interested in
  84                       (let ((backtrace (progn
  85                                          ;; (backtrace 13)
  86                                          (member (caar frame-specs)
  87                                                  (sb-debug:backtrace-as-list)
  88                                                  :key #'car
  89                                                  :test #'equal))))
  90
  91                         (setf result condition)
  92
  93                         (unless backtrace
  94                           (print :missing-backtrace)
  95                           (setf result nil))
  96
  97                         ;; check that we have all the frames we wanted
  98                         (mapcar
  99                          (lambda (spec frame)
 100                            (unless (or (not spec)
 101                                        (and (equal (car spec) (car frame))
 102                                             (args-equal (cdr spec)
 103                                                         (cdr frame))))
 104                              (print (list :mismatch spec frame))
 105                              (setf result nil)))
 106                          frame-specs
 107                          backtrace)
 108
 109                         ;; Make sure the backtrace isn't stunted in
 110                         ;; any way.  (Depends on running in the main
 111                         ;; thread.)
 112                         (let ((end (last backtrace 2)))
 113                           (unless (equal (caar end)
 114                                          (if *show-entry-point-details*
 115                                              '(sb-c::tl-xep sb-impl::toplevel-init)
 116                                              'sb-impl::toplevel-init))
 117                             (print (list :backtrace-stunted (caar end)))
 118                             (setf result nil)))
 119                         (return-from outer-handler)))))
 120           (funcall test-function)))
 121       result)))
 122
 123 (defvar *undefined-function-frame*
 124   ;; bug 353
 125   '(#+(or x86 x86-64) "bogus stack frame"
 126     #-(or x86 x86-64) "undefined function"))
 127
 128 ;;; Test for "undefined function" (undefined_tramp) working properly.
 129 ;;; Try it with and without tail call elimination, since they can have
 130 ;;; different effects.  (Specifically, if undefined_tramp is incorrect
 131 ;;; a stunted stack can result from the tail call variant.)
 132 (flet ((optimized ()
 133          (declare (optimize (speed 2) (debug 1))) ; tail call elimination
 134          (#:undefined-function 42))
 135        (not-optimized ()
 136          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 137          (#:undefined-function 42))
 138        (test (fun)
 139          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 140          (funcall fun)))
 141
 142   (with-test (:name (:undefined-function :bug-346)
 143               :fails-on '(or :alpha))   ; bug 346
 144     (assert (verify-backtrace
 145              (lambda () (test #'optimized))
 146              (list *undefined-function-frame*
 147                    (list '(flet test) #'optimized)))))
 148
 149   ;; bug 353: This test fails at least most of the time for x86/linux
 150   ;; ca. 0.8.20.16. -- WHN
 151   (with-test (:name (:undefined-function :bug-356)
 152               :fails-on '(or (and :x86 :linux) :alpha))
 153     (assert (verify-backtrace
 154              (lambda () (test #'not-optimized))
 155              (list *undefined-function-frame*
 156                    (list '(flet not-optimized))
 157                    (list '(flet test) #'not-optimized))))))
 158
 159 ;;; Division by zero was a common error on PPC.  It depended on the
 160 ;;; return function either being before INTEGER-/-INTEGER in memory,
 161 ;;; or more than MOST-POSITIVE-FIXNUM bytes ahead.  It also depends on
 162 ;;; INTEGER-/-INTEGER calling SIGNED-TRUNCATE.  I believe Raymond Toy
 163 ;;; says that the Sparc backend (at least for CMUCL) inlines this, so
 164 ;;; if SBCL does the same this test is probably not good for the
 165 ;;; Sparc.
 166 ;;;
 167 ;;; Disabling tail call elimination on this will probably ensure that
 168 ;;; the return value (to the flet or the enclosing top level form) is
 169 ;;; more than MOST-POSITIVE-FIXNUM with the current spaces on OS X.
 170 ;;; Enabling it might catch other problems, so do it anyway.
 171 (flet ((optimized ()
 172          (declare (optimize (speed 2) (debug 1))) ; tail call elimination
 173          (/ 42 0))
 174        (not-optimized ()
 175          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 176          (/ 42 0))
 177        (test (fun)
 178          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 179          (funcall fun)))
 180   (with-test (:name (:divide-by-zero :bug-346)
 181               :fails-on '(or :alpha))   ; bug 346
 182     (assert (verify-backtrace (lambda () (test #'optimized))
 183                               (list '(/ 42 &rest)
 184                                     (list '(flet test) #'optimized)))))
 185   (with-test (:name (:divide-by-zero :bug-356)
 186               :fails-on '(or :alpha))   ; bug 356
 187     (assert (verify-backtrace (lambda () (test #'not-optimized))
 188                               (list '(/ 42 &rest)
 189                                     '((flet not-optimized))
 190                                     (list '(flet test) #'not-optimized))))))
 191
 192 (with-test (:name (:throw :no-such-tag)
 193             :fails-on '(or (and :x86 :linux) (and :x86 :freebsd) :alpha :mips))
 194   (progn
 195     (defun throw-test ()
 196       (throw 'no-such-tag t))
 197     (assert (verify-backtrace #'throw-test '((throw-test))))))
 198
 199 ;;; test entry point handling in backtraces
 200
 201 (defun oops ()
 202   (error "oops"))
 203
 204 (defmacro defbt (n ll &body body)
 205   `(progn
 206      ;; normal debug info
 207      (defun ,(intern (format nil "BT.~A.1" n)) ,ll
 208        ,@body)
 209      ;; no arguments saved
 210      (defun ,(intern (format nil "BT.~A.2" n)) ,ll
 211        (declare (optimize (debug 1) (speed 3)))
 212        ,@body)
 213      ;; no lambda-list saved
 214      (defun ,(intern (format nil "BT.~A.3" n)) ,ll
 215        (declare (optimize (debug 0)))
 216        ,@body)))
 217
 218 (defbt 1 (&key key)
 219   (list key))
 220
 221 (defbt 2 (x)
 222   (list x))
 223
 224 (defbt 3 (&key (key (oops)))
 225   (list key))
 226
 227 ;;; ERROR instead of OOPS so that tail call elimination doesn't happen
 228 (defbt 4 (&optional opt)
 229   (list (error "error")))
 230
 231 (defbt 5 (&optional (opt (oops)))
 232   (list opt))
 233
 234 ;;; FIXME: This test really should be broken into smaller pieces
 235 (with-test (:name (:backtrace :misc)
 236             :fails-on '(and :x86 :linux))
 237   (macrolet ((with-details (bool &body body)
 238                `(let ((sb-debug:*show-entry-point-details* ,bool))
 239                  ,@body)))
 240
 241     ;; TL-XEP
 242     (print :tl-xep)
 243     (with-details t
 244       (assert (verify-backtrace #'namestring
 245                                 '(((sb-c::tl-xep namestring) 0 ?)))))
 246     (with-details nil
 247       (assert (verify-backtrace #'namestring
 248                                 '((namestring)))))
 249
 250
 251     ;; &MORE-PROCESSOR
 252     (with-details t
 253       (assert (verify-backtrace (lambda () (bt.1.1 :key))
 254                                 '(((sb-c::&more-processor bt.1.1) &rest))))
 255       (assert (verify-backtrace (lambda () (bt.1.2 :key))
 256                                 '(((sb-c::&more-processor bt.1.2) &rest))))
 257       (assert (verify-backtrace (lambda () (bt.1.3 :key))
 258                                 '(((sb-c::&more-processor bt.1.3) &rest)))))
 259     (with-details nil
 260       (assert (verify-backtrace (lambda () (bt.1.1 :key))
 261                                 '((bt.1.1 :key))))
 262       (assert (verify-backtrace (lambda () (bt.1.2 :key))
 263                                 '((bt.1.2 &rest))))
 264       (assert (verify-backtrace (lambda () (bt.1.3 :key))
 265                                 '((bt.1.3 &rest)))))
 266
 267     ;; XEP
 268     (print :xep)
 269     (with-details t
 270       (assert (verify-backtrace #'bt.2.1
 271                                 '(((sb-c::xep bt.2.1) 0 ?))))
 272       (assert (verify-backtrace #'bt.2.2
 273                                 '(((sb-c::xep bt.2.2) &rest))))
 274       (assert (verify-backtrace #'bt.2.3
 275                                 '(((sb-c::xep bt.2.3) &rest)))))
 276     (with-details nil
 277       (assert (verify-backtrace #'bt.2.1
 278                                 '((bt.2.1))))
 279       (assert (verify-backtrace #'bt.2.2
 280                                 '((bt.2.2 &rest))))
 281       (assert (verify-backtrace #'bt.2.3
 282                                 '((bt.2.3 &rest)))))
 283
 284     ;; VARARGS-ENTRY
 285     (print :varargs-entry)
 286     (with-details t
 287       (assert (verify-backtrace #'bt.3.1
 288                                 '(((sb-c::varargs-entry bt.3.1) :key nil))))
 289       (assert (verify-backtrace #'bt.3.2
 290                                 '(((sb-c::varargs-entry bt.3.2) :key ?))))
 291       (assert (verify-backtrace #'bt.3.3
 292                                 '(((sb-c::varargs-entry bt.3.3) &rest)))))
 293     (with-details nil
 294       (assert (verify-backtrace #'bt.3.1
 295                                 '((bt.3.1 :key nil))))
 296       (assert (verify-backtrace #'bt.3.2
 297                                 '((bt.3.2 :key ?))))
 298       (assert (verify-backtrace #'bt.3.3
 299                                 '((bt.3.3 &rest)))))
 300
 301     ;; HAIRY-ARG-PROCESSOR
 302     (print :hairy-args-processor)
 303     (with-details t
 304       (assert (verify-backtrace #'bt.4.1
 305                                 '(((sb-c::hairy-arg-processor bt.4.1) ?))))
 306       (assert (verify-backtrace #'bt.4.2
 307                                 '(((sb-c::hairy-arg-processor bt.4.2) ?))))
 308       (assert (verify-backtrace #'bt.4.3
 309                                 '(((sb-c::hairy-arg-processor bt.4.3) &rest)))))
 310     (with-details nil
 311       (assert (verify-backtrace #'bt.4.1
 312                                 '((bt.4.1 ?))))
 313       (assert (verify-backtrace #'bt.4.2
 314                                 '((bt.4.2 ?))))
 315       (assert (verify-backtrace #'bt.4.3
 316                                 '((bt.4.3 &rest)))))
 317
 318     ;; &OPTIONAL-PROCESSOR
 319     (print :optional-processor)
 320     (with-details t
 321       (assert (verify-backtrace #'bt.5.1
 322                                 '(((sb-c::&optional-processor bt.5.1)))))
 323       (assert (verify-backtrace #'bt.5.2
 324                                 '(((sb-c::&optional-processor bt.5.2) &rest))))
 325       (assert (verify-backtrace #'bt.5.3
 326                                 '(((sb-c::&optional-processor bt.5.3) &rest)))))
 327     (with-details nil
 328       (assert (verify-backtrace #'bt.5.1
 329                                 '((bt.5.1))))
 330       (assert (verify-backtrace #'bt.5.2
 331                                 '((bt.5.2 &rest))))
 332       (assert (verify-backtrace #'bt.5.3
 333                                 '((bt.5.3 &rest)))))))
 334
 335 ;;;; test TRACE
 336
 337 (defun trace-this ()
 338   'ok)
 339
 340 (let ((out (with-output-to-string (*trace-output*)
 341              (trace trace-this)
 342              (assert (eq 'ok (trace-this)))
 343              (untrace))))
 344   (assert (search "TRACE-THIS" out))
 345   (assert (search "returned OK" out)))
 346
 347 ;;; bug 379
 348 ;;; This is not a WITH-TEST :FAILS-ON PPC DARWIN since there are
 349 ;;; suspicions that the breakpoint trace might corrupt the whole image
 350 ;;; on that platform.
 351 #-(and ppc darwin)
 352 (with-test (:name (trace :encapsulate nil)
 353             :fails-on '(or ppc sparc))
 354   (let ((out (with-output-to-string (*trace-output*)
 355                (trace trace-this :encapsulate nil)
 356                (assert (eq 'ok (trace-this)))
 357                (untrace))))
 358     (assert (search "TRACE-THIS" out))
 359     (assert (search "returned OK" out))))
 360
 361 ;;;; test infinite error protection
 362
 363 (defmacro nest-errors (n-levels error-form)
 364   (if (< 0 n-levels)
 365       `(handler-bind ((error (lambda (condition)
 366                                (declare (ignore condition))
 367                                ,error-form)))
 368         (nest-errors ,(1- n-levels) ,error-form))
 369       error-form))
 370
 371 (defun erroring-debugger-hook (condition old-debugger-hook)
 372   (let ((*debugger-hook* old-debugger-hook))
 373     (format t "recursive condition: ~A~%" condition) (force-output)
 374     (error "recursive condition: ~A" condition)))
 375
 376 (defun test-inifinite-error-protection ()
 377   ;; after 50 successful throws to SB-IMPL::TOPLEVEL-CATCHER sbcl used
 378   ;; to halt, it produces so much garbage that's hard to suppress that
 379   ;; it is tested only once
 380   (let ((*debugger-hook* #'erroring-debugger-hook))
 381     (loop repeat 1 do
 382           (let ((error-counter 0)
 383                 (*terminal-io* (make-broadcast-stream)))
 384             (assert
 385              (not (eq
 386                    :normal-exit
 387                    (catch 'sb-impl::toplevel-catcher
 388                      (nest-errors 20 (error "infinite error ~s"
 389                                             (incf error-counter)))
 390                      :normal-exit))))))))
 391
 392 (enable-debugger)
 393
 394 (test-inifinite-error-protection)
 395
 396 #+sb-thread
 397 (let ((thread (sb-thread:make-thread #'test-inifinite-error-protection)))
 398   (loop while (sb-thread:thread-alive-p thread)))
 399
 400 (disable-debugger)