tests/debug.impure.lisp

   1 ;;;; This file is for testing debugging functionality, using
   2 ;;;; test machinery which might have side effects (e.g.
   3 ;;;; executing DEFUN).
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; While most of SBCL is derived from the CMU CL system, the test
   9 ;;;; files (like this one) were written from scratch after the fork
  10 ;;;; from CMU CL.
  11 ;;;;
  12 ;;;; This software is in the public domain and is provided with
  13 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  14 ;;;; more information.
  15
  16 (cl:in-package :cl-user)
  17
  18 ;;; The debugger doesn't have any native knowledge of the interpreter
  19 (when (eq sb-ext:*evaluator-mode* :interpret)
  20   (sb-ext:quit :unix-status 104))
  21
  22 \f
  23 ;;;; Check that we get debug arglists right.
  24
  25 ;;; FIXME: This should use some get-argslist like functionality that
  26 ;;; we actually export.
  27 ;;;
  28 ;;; Return the debug arglist of the function object FUN as a list, or
  29 ;;; punt with :UNKNOWN.
  30 (defun get-arglist (fun)
  31   (declare (type function fun))
  32   ;; The Lisp-level type FUNCTION can conceal a multitude of sins..
  33   (case (sb-kernel:widetag-of fun)
  34     (#.sb-vm:simple-fun-header-widetag
  35       (sb-kernel:%simple-fun-arglist fun))
  36     (#.sb-vm:closure-header-widetag (get-arglist
  37                                      (sb-kernel:%closure-fun fun)))
  38     ;; In code/describe.lisp, ll. 227 (%describe-fun), we use a scheme
  39     ;; like above, and it seems to work. -- MNA 2001-06-12
  40     ;;
  41     ;; (There might be other cases with arglist info also.
  42     ;; SIMPLE-FUN-HEADER-WIDETAG and CLOSURE-HEADER-WIDETAG just
  43     ;; happen to be the two case that I had my nose rubbed in when
  44     ;; debugging a GC problem caused by applying %SIMPLE-FUN-ARGLIST to
  45     ;; a closure. -- WHN 2001-06-05)
  46     (t
  47      #+sb-eval
  48      (if (typep fun 'sb-eval::interpreted-function)
  49          (sb-eval::interpreted-function-lambda-list fun)
  50          :unknown)
  51      #-sb-eval
  52      :unknown)))
  53
  54 (defun zoop (zeep &key beep)
  55   blurp)
  56 (assert (equal (get-arglist #'zoop) '(zeep &key beep)))
  57
  58 ;;; Check some predefined functions too.
  59 ;;;
  60 ;;; (We don't know exactly what the arguments are, e.g. the first
  61 ;;; argument of PRINT might be SB-IMPL::OBJECT or SB-KERNEL::OBJ or
  62 ;;; whatever. But we do know the general structure that a correct
  63 ;;; answer should have, so we can safely do a lot of checks.)
  64 (destructuring-bind (object-sym &optional-sym stream-sym) (get-arglist #'print)
  65   (assert (symbolp object-sym))
  66   (assert (eql &optional-sym '&optional))
  67   (assert (symbolp stream-sym)))
  68 (destructuring-bind (dest-sym control-sym &rest-sym format-args-sym)
  69     (get-arglist #'format)
  70   (assert (symbolp dest-sym))
  71   (assert (symbolp control-sym))
  72   (assert (eql &rest-sym '&rest))
  73   (assert (symbolp format-args-sym)))
  74
  75 ;;; Check for backtraces generally being correct.  Ensure that the
  76 ;;; actual backtrace finishes (doesn't signal any errors on its own),
  77 ;;; and that it contains the frames we expect, doesn't contain any
  78 ;;; "bogus stack frame"s, and contains the appropriate toplevel call
  79 ;;; and hasn't been cut off anywhere.
  80 (defun verify-backtrace (test-function frame-specs &key (allow-stunted nil))
  81   (labels ((args-equal (want real)
  82              (cond ((eq '&rest (car want))
  83                     t)
  84                    ((endp want)
  85                     (endp real))
  86                    ((or (eq '? (car want)) (equal (car want) (car real)))
  87                     (args-equal (cdr want) (cdr real)))
  88                    (t
  89                     nil))))
  90     (let ((result nil))
  91       (block outer-handler
  92         (handler-bind
  93             ((error (lambda (condition)
  94                       ;; find the part of the backtrace we're interested in
  95                       (let* ((full-backtrace (sb-debug:backtrace-as-list))
  96                              (backtrace (member (caar frame-specs) full-backtrace
  97                                                 :key #'car
  98                                                 :test #'equal)))
  99
 100                         (setf result condition)
 101
 102                         (unless backtrace
 103                           (format t "~&//~S not in backtrace:~%   ~S~%"
 104                                   (caar frame-specs)
 105                                   full-backtrace)
 106                           (setf result nil))
 107
 108                         ;; check that we have all the frames we wanted
 109                         (mapcar
 110                          (lambda (spec frame)
 111                            (unless (or (not spec)
 112                                        (and (equal (car spec) (car frame))
 113                                             (args-equal (cdr spec)
 114                                                         (cdr frame))))
 115                              (print (list :mismatch spec frame))
 116                              (setf result nil)))
 117                          frame-specs
 118                          backtrace)
 119
 120                         ;; Make sure the backtrace isn't stunted in
 121                         ;; any way.  (Depends on running in the main
 122                         ;; thread.) FIXME: On Windows we get two
 123                         ;; extra foreign frames below regular frames.
 124                         (let ((end (last backtrace #-win32 2 #+win32 4)))
 125                           (unless (equal (caar end)
 126                                          'sb-impl::toplevel-init)
 127                             (print (list :backtrace-stunted (caar end)))
 128                             (setf result nil)))
 129                         (return-from outer-handler)))))
 130           (funcall test-function)))
 131       result)))
 132
 133 (defvar *undefined-function-frame*
 134   ;; bug 353
 135   '(#+(or x86 x86-64) "bogus stack frame"
 136     #-(or x86 x86-64) "undefined function"))
 137
 138 ;;; Test for "undefined function" (undefined_tramp) working properly.
 139 ;;; Try it with and without tail call elimination, since they can have
 140 ;;; different effects.  (Specifically, if undefined_tramp is incorrect
 141 ;;; a stunted stack can result from the tail call variant.)
 142 (flet ((optimized ()
 143          (declare (optimize (speed 2) (debug 1))) ; tail call elimination
 144          (#:undefined-function 42))
 145        (not-optimized ()
 146          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 147          (#:undefined-function 42))
 148        (test (fun)
 149          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 150          (funcall fun)))
 151
 152   (with-test (:name (:undefined-function :bug-346)
 153               :fails-on '(or :alpha :ppc :sparc :mips
 154                           (and :x86-64 (or :freebsd :darwin))))
 155     (assert (verify-backtrace
 156              (lambda () (test #'optimized))
 157              (list *undefined-function-frame*
 158                    (list '(flet test) #'optimized)))))
 159
 160   ;; bug 353: This test fails at least most of the time for x86/linux
 161   ;; ca. 0.8.20.16. -- WHN
 162   (with-test (:name (:undefined-function :bug-353)
 163               ;; This used to have fewer :fails-on features pre-0.9.16.38,
 164               ;; but it turns out that the bug was just being masked by
 165               ;; the presence of the IR1 stepper instrumentation (and
 166               ;; is thus again failing now that the instrumentation is
 167               ;; no more).
 168               :fails-on '(or :x86 :x86-64 :alpha :mips))
 169     (assert (verify-backtrace
 170              (lambda () (test #'not-optimized))
 171              (list *undefined-function-frame*
 172                    (list '(flet not-optimized))
 173                    (list '(flet test) #'not-optimized))))))
 174
 175 ;;; Division by zero was a common error on PPC. It depended on the
 176 ;;; return function either being before INTEGER-/-INTEGER in memory,
 177 ;;; or more than MOST-POSITIVE-FIXNUM bytes ahead. It also depends on
 178 ;;; INTEGER-/-INTEGER calling SIGNED-TRUNCATE. I believe Raymond Toy
 179 ;;; says that the Sparc backend (at least for CMUCL) inlines this, so
 180 ;;; if SBCL does the same this test is probably not good for the
 181 ;;; Sparc.
 182 ;;;
 183 ;;; Disabling tail call elimination on this will probably ensure that
 184 ;;; the return value (to the flet or the enclosing top level form) is
 185 ;;; more than MOST-POSITIVE-FIXNUM with the current spaces on OS X.
 186 ;;; Enabling it might catch other problems, so do it anyway.
 187 (flet ((optimized ()
 188          (declare (optimize (speed 2) (debug 1))) ; tail call elimination
 189          (/ 42 0))
 190        (not-optimized ()
 191          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 192          (/ 42 0))
 193        (test (fun)
 194          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 195          (funcall fun)))
 196   (with-test (:name (:divide-by-zero :bug-346)
 197               :fails-on '(or :alpha (and :x86-64 :darwin)))   ; bug 346
 198     (assert (verify-backtrace (lambda () (test #'optimized))
 199                               (list '(/ 42 &rest)
 200                                     (list '(flet test) #'optimized)))))
 201   (with-test (:name (:divide-by-zero :bug-356)
 202               :fails-on '(or :alpha (and :x86-64 :darwin)))   ; bug 356
 203     (assert (verify-backtrace (lambda () (test #'not-optimized))
 204                               (list '(/ 42 &rest)
 205                                     '((flet not-optimized))
 206                                     (list '(flet test) #'not-optimized))))))
 207
 208 (with-test (:name (:throw :no-such-tag)
 209             :fails-on '(or
 210                         (and :x86 :sunos)
 211                         (and :x86-64 :darwin)
 212                         (and :sparc :linux)
 213                         :alpha
 214                         :mips))
 215   (progn
 216     (defun throw-test ()
 217       (throw 'no-such-tag t))
 218     (assert (verify-backtrace #'throw-test '((throw-test))))))
 219
 220 ;;; test entry point handling in backtraces
 221
 222 (defun oops ()
 223   (error "oops"))
 224
 225 (defmacro defbt (n ll &body body)
 226   `(progn
 227      ;; normal debug info
 228      (defun ,(intern (format nil "BT.~A.1" n)) ,ll
 229        ,@body)
 230      ;; no arguments saved
 231      (defun ,(intern (format nil "BT.~A.2" n)) ,ll
 232        (declare (optimize (debug 1) (speed 3)))
 233        ,@body)
 234      ;; no lambda-list saved
 235      (defun ,(intern (format nil "BT.~A.3" n)) ,ll
 236        (declare (optimize (debug 0)))
 237        ,@body)))
 238
 239 (defbt 1 (&key key)
 240   (list key))
 241
 242 (defbt 2 (x)
 243   (list x))
 244
 245 (defbt 3 (&key (key (oops)))
 246   (list key))
 247
 248 ;;; ERROR instead of OOPS so that tail call elimination doesn't happen
 249 (defbt 4 (&optional opt)
 250   (list (error "error")))
 251
 252 (defbt 5 (&optional (opt (oops)))
 253   (list opt))
 254
 255 (defmacro with-details (bool &body body)
 256   `(let ((sb-debug:*show-entry-point-details* ,bool))
 257      ,@body))
 258
 259 ;;; FIXME: This test really should be broken into smaller pieces
 260 (with-test (:name (:backtrace :misc)
 261             :fails-on '(or (and :x86 (or :sunos)) (and :x86-64 :darwin)))
 262   (write-line "//tl-xep")
 263   (with-details t
 264     (assert (verify-backtrace #'namestring
 265                               '(((sb-c::tl-xep namestring) 0 ?)))))
 266   (with-details nil
 267     (assert (verify-backtrace #'namestring
 268                               '((namestring)))))
 269
 270   ;; &MORE-PROCESSOR
 271   (with-details t
 272     (assert (verify-backtrace (lambda () (bt.1.1 :key))
 273                               '(((sb-c::&more-processor bt.1.1) &rest))))
 274     (assert (verify-backtrace (lambda () (bt.1.2 :key))
 275                               '(((sb-c::&more-processor bt.1.2) &rest))))
 276     (assert (verify-backtrace (lambda () (bt.1.3 :key))
 277                               '(((sb-c::&more-processor bt.1.3) &rest)))))
 278   (with-details nil
 279     (assert (verify-backtrace (lambda () (bt.1.1 :key))
 280                               '((bt.1.1 :key))))
 281     (assert (verify-backtrace (lambda () (bt.1.2 :key))
 282                               '((bt.1.2 &rest))))
 283     (assert (verify-backtrace (lambda () (bt.1.3 :key))
 284                               '((bt.1.3 &rest)))))
 285
 286   ;; XEP
 287   (write-line "//xep")
 288   (with-details t
 289     (assert (verify-backtrace #'bt.2.1
 290                               '(((sb-c::xep bt.2.1) 0 ?))))
 291     (assert (verify-backtrace #'bt.2.2
 292                               '(((sb-c::xep bt.2.2) &rest))))
 293     (assert (verify-backtrace #'bt.2.3
 294                               '(((sb-c::xep bt.2.3) &rest)))))
 295   (with-details nil
 296     (assert (verify-backtrace #'bt.2.1
 297                               '((bt.2.1))))
 298     (assert (verify-backtrace #'bt.2.2
 299                               '((bt.2.2 &rest))))
 300     (assert (verify-backtrace #'bt.2.3
 301                               '((bt.2.3 &rest)))))
 302
 303   ;; VARARGS-ENTRY
 304   (write-line "//varargs-entry")
 305   (with-details t
 306     (assert (verify-backtrace #'bt.3.1
 307                               '(((sb-c::varargs-entry bt.3.1) :key nil))))
 308     (assert (verify-backtrace #'bt.3.2
 309                               '(((sb-c::varargs-entry bt.3.2) :key ?))))
 310     (assert (verify-backtrace #'bt.3.3
 311                               '(((sb-c::varargs-entry bt.3.3) &rest)))))
 312   (with-details nil
 313     (assert (verify-backtrace #'bt.3.1
 314                               '((bt.3.1 :key nil))))
 315     (assert (verify-backtrace #'bt.3.2
 316                               '((bt.3.2 :key ?))))
 317     (assert (verify-backtrace #'bt.3.3
 318                               '((bt.3.3 &rest)))))
 319
 320   ;; HAIRY-ARG-PROCESSOR
 321   (write-line "//hairy-args-processor")
 322   (with-details t
 323     (assert (verify-backtrace #'bt.4.1
 324                               '(((sb-c::hairy-arg-processor bt.4.1) ?))))
 325     (assert (verify-backtrace #'bt.4.2
 326                               '(((sb-c::hairy-arg-processor bt.4.2) ?))))
 327     (assert (verify-backtrace #'bt.4.3
 328                               '(((sb-c::hairy-arg-processor bt.4.3) &rest)))))
 329   (with-details nil
 330     (assert (verify-backtrace #'bt.4.1
 331                               '((bt.4.1 ?))))
 332     (assert (verify-backtrace #'bt.4.2
 333                               '((bt.4.2 ?))))
 334     (assert (verify-backtrace #'bt.4.3
 335                               '((bt.4.3 &rest)))))
 336
 337   ;; &OPTIONAL-PROCESSOR
 338   (write-line "//optional-processor")
 339   (with-details t
 340     (assert (verify-backtrace #'bt.5.1
 341                               '(((sb-c::&optional-processor bt.5.1)))))
 342     (assert (verify-backtrace #'bt.5.2
 343                               '(((sb-c::&optional-processor bt.5.2) &rest))))
 344     (assert (verify-backtrace #'bt.5.3
 345                               '(((sb-c::&optional-processor bt.5.3) &rest)))))
 346   (with-details nil
 347     (assert (verify-backtrace #'bt.5.1
 348                               '((bt.5.1))))
 349     (assert (verify-backtrace #'bt.5.2
 350                               '((bt.5.2 &rest))))
 351     (assert (verify-backtrace #'bt.5.3
 352                               '((bt.5.3 &rest))))))
 353
 354 (write-line "//compile nil")
 355 (defvar *compile-nil-error* (compile nil '(lambda (x) (cons (when x (error "oops")) nil))))
 356 (defvar *compile-nil-non-tc* (compile nil '(lambda (y) (cons (funcall *compile-nil-error* y) nil))))
 357 (assert (verify-backtrace (lambda () (funcall *compile-nil-non-tc* 13))
 358                           '(((lambda (x)) 13)
 359                             ((lambda (y)) 13))))
 360
 361 ;;;; test TRACE
 362
 363 (defun trace-this ()
 364   'ok)
 365
 366 (defun trace-fact (n)
 367   (if (zerop n)
 368       1
 369       (* n (trace-fact (1- n)))))
 370
 371 (let ((out (with-output-to-string (*trace-output*)
 372              (trace trace-this)
 373              (assert (eq 'ok (trace-this)))
 374              (untrace))))
 375   (assert (search "TRACE-THIS" out))
 376   (assert (search "returned OK" out)))
 377
 378 ;;; bug 379
 379 ;;; This is not a WITH-TEST :FAILS-ON PPC DARWIN since there are
 380 ;;; suspicions that the breakpoint trace might corrupt the whole image
 381 ;;; on that platform.
 382 #-(and (or ppc x86 x86-64) darwin)
 383 (with-test (:name (trace :encapsulate nil)
 384             :fails-on '(or :ppc :sparc :mips))
 385   (let ((out (with-output-to-string (*trace-output*)
 386                (trace trace-this :encapsulate nil)
 387                (assert (eq 'ok (trace-this)))
 388                (untrace))))
 389     (assert (search "TRACE-THIS" out))
 390     (assert (search "returned OK" out))))
 391
 392 #-(and (or ppc x86 x86-64) darwin)
 393 (with-test (:name (trace-recursive :encapsulate nil)
 394             :fails-on '(or :ppc :sparc :mips))
 395   (let ((out (with-output-to-string (*trace-output*)
 396                (trace trace-fact :encapsulate nil)
 397                (assert (= 120 (trace-fact 5)))
 398                (untrace))))
 399     (assert (search "TRACE-FACT" out))
 400     (assert (search "returned 1" out))
 401     (assert (search "returned 120" out))))
 402
 403 (with-test (:name :bug-414)
 404   (handler-bind ((warning #'error))
 405     (load (compile-file "bug-414.lisp"))
 406     (disassemble 'bug-414)))
 407
 408 ;;;; test infinite error protection
 409
 410 (defmacro nest-errors (n-levels error-form)
 411   (if (< 0 n-levels)
 412       `(handler-bind ((error (lambda (condition)
 413                                (declare (ignore condition))
 414                                ,error-form)))
 415         (nest-errors ,(1- n-levels) ,error-form))
 416       error-form))
 417
 418 (defun erroring-debugger-hook (condition old-debugger-hook)
 419   (let ((*debugger-hook* old-debugger-hook))
 420     (format t "recursive condition: ~A~%" condition) (force-output)
 421     (error "recursive condition: ~A" condition)))
 422
 423 (defun test-inifinite-error-protection ()
 424   ;; after 50 successful throws to SB-IMPL::TOPLEVEL-CATCHER sbcl used
 425   ;; to halt, it produces so much garbage that's hard to suppress that
 426   ;; it is tested only once
 427   (write-line "--HARMLESS BUT ALARMING BACKTRACE COMING UP--")
 428   (let ((*debugger-hook* #'erroring-debugger-hook))
 429     (loop repeat 1 do
 430           (let ((error-counter 0)
 431                 (*terminal-io* (make-broadcast-stream)))
 432             (assert
 433              (not (eq
 434                    :normal-exit
 435                    (catch 'sb-impl::toplevel-catcher
 436                      (nest-errors 20 (error "infinite error ~s"
 437                                             (incf error-counter)))
 438                      :normal-exit)))))))
 439   (write-line "--END OF H-B-A-B--"))
 440
 441 (enable-debugger)
 442
 443 (test-inifinite-error-protection)
 444
 445 #+sb-thread
 446 (let ((thread (sb-thread:make-thread #'test-inifinite-error-protection)))
 447   (loop while (sb-thread:thread-alive-p thread)))
 448
 449 (disable-debugger)
 450
 451 (write-line "/debug.impure.lisp done")