tests/debug.impure.lisp

   1 ;;;; This file is for testing debugging functionality, using
   2 ;;;; test machinery which might have side effects (e.g.
   3 ;;;; executing DEFUN).
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; While most of SBCL is derived from the CMU CL system, the test
   9 ;;;; files (like this one) were written from scratch after the fork
  10 ;;;; from CMU CL.
  11 ;;;;
  12 ;;;; This software is in the public domain and is provided with
  13 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  14 ;;;; more information.
  15
  16 (cl:in-package :cl-user)
  17
  18 ;;; The debugger doesn't have any native knowledge of the interpreter
  19 (when (eq sb-ext:*evaluator-mode* :interpret)
  20   (sb-ext:quit :unix-status 104))
  21
  22 \f
  23 ;;;; Check that we get debug arglists right.
  24
  25 ;;; FIXME: This should use some get-argslist like functionality that
  26 ;;; we actually export.
  27 ;;;
  28 ;;; Return the debug arglist of the function object FUN as a list, or
  29 ;;; punt with :UNKNOWN.
  30 (defun get-arglist (fun)
  31   (declare (type function fun))
  32   ;; The Lisp-level type FUNCTION can conceal a multitude of sins..
  33   (case (sb-kernel:widetag-of fun)
  34     (#.sb-vm:simple-fun-header-widetag
  35       (sb-kernel:%simple-fun-arglist fun))
  36     (#.sb-vm:closure-header-widetag (get-arglist
  37                                      (sb-kernel:%closure-fun fun)))
  38     ;; In code/describe.lisp, ll. 227 (%describe-fun), we use a scheme
  39     ;; like above, and it seems to work. -- MNA 2001-06-12
  40     ;;
  41     ;; (There might be other cases with arglist info also.
  42     ;; SIMPLE-FUN-HEADER-WIDETAG and CLOSURE-HEADER-WIDETAG just
  43     ;; happen to be the two case that I had my nose rubbed in when
  44     ;; debugging a GC problem caused by applying %SIMPLE-FUN-ARGLIST to
  45     ;; a closure. -- WHN 2001-06-05)
  46     (t
  47      #+sb-eval
  48      (if (typep fun 'sb-eval::interpreted-function)
  49          (sb-eval::interpreted-function-lambda-list fun)
  50          :unknown)
  51      #-sb-eval
  52      :unknown)))
  53
  54 (defun zoop (zeep &key beep)
  55   blurp)
  56 (assert (equal (get-arglist #'zoop) '(zeep &key beep)))
  57
  58 ;;; Check some predefined functions too.
  59 ;;;
  60 ;;; (We don't know exactly what the arguments are, e.g. the first
  61 ;;; argument of PRINT might be SB-IMPL::OBJECT or SB-KERNEL::OBJ or
  62 ;;; whatever. But we do know the general structure that a correct
  63 ;;; answer should have, so we can safely do a lot of checks.)
  64 (destructuring-bind (object-sym &optional-sym stream-sym) (get-arglist #'print)
  65   (assert (symbolp object-sym))
  66   (assert (eql &optional-sym '&optional))
  67   (assert (symbolp stream-sym)))
  68 (destructuring-bind (dest-sym control-sym &rest-sym format-args-sym)
  69     (get-arglist #'format)
  70   (assert (symbolp dest-sym))
  71   (assert (symbolp control-sym))
  72   (assert (eql &rest-sym '&rest))
  73   (assert (symbolp format-args-sym)))
  74
  75 ;;; Check for backtraces generally being correct.  Ensure that the
  76 ;;; actual backtrace finishes (doesn't signal any errors on its own),
  77 ;;; and that it contains the frames we expect, doesn't contain any
  78 ;;; "bogus stack frame"s, and contains the appropriate toplevel call
  79 ;;; and hasn't been cut off anywhere.
  80 (defun verify-backtrace (test-function frame-specs &key (allow-stunted nil))
  81   (labels ((args-equal (want real)
  82              (cond ((eq '&rest (car want))
  83                     t)
  84                    ((endp want)
  85                     (endp real))
  86                    ((or (eq '? (car want)) (equal (car want) (car real)))
  87                     (args-equal (cdr want) (cdr real)))
  88                    (t
  89                     nil))))
  90     (let ((result nil))
  91       (block outer-handler
  92         (handler-bind
  93             ((error (lambda (condition)
  94                       ;; find the part of the backtrace we're interested in
  95                       (let ((backtrace (progn
  96                                          ;; (backtrace 13)
  97                                          (member (caar frame-specs)
  98                                                  (sb-debug:backtrace-as-list)
  99                                                  :key #'car
 100                                                  :test #'equal))))
 101
 102                         (setf result condition)
 103
 104                         (unless backtrace
 105                           (print :missing-backtrace)
 106                           (setf result nil))
 107
 108                         ;; check that we have all the frames we wanted
 109                         (mapcar
 110                          (lambda (spec frame)
 111                            (unless (or (not spec)
 112                                        (and (equal (car spec) (car frame))
 113                                             (args-equal (cdr spec)
 114                                                         (cdr frame))))
 115                              (print (list :mismatch spec frame))
 116                              (setf result nil)))
 117                          frame-specs
 118                          backtrace)
 119
 120                         ;; Make sure the backtrace isn't stunted in
 121                         ;; any way.  (Depends on running in the main
 122                         ;; thread.)
 123                         (let ((end (last backtrace 2)))
 124                           (unless (equal (caar end)
 125                                          (if *show-entry-point-details*
 126                                              '(sb-c::tl-xep sb-impl::toplevel-init)
 127                                              'sb-impl::toplevel-init))
 128                             (print (list :backtrace-stunted (caar end)))
 129                             (setf result nil)))
 130                         (return-from outer-handler)))))
 131           (funcall test-function)))
 132       result)))
 133
 134 (defvar *undefined-function-frame*
 135   ;; bug 353
 136   '(#+(or x86 x86-64) "bogus stack frame"
 137     #-(or x86 x86-64) "undefined function"))
 138
 139 ;;; Test for "undefined function" (undefined_tramp) working properly.
 140 ;;; Try it with and without tail call elimination, since they can have
 141 ;;; different effects.  (Specifically, if undefined_tramp is incorrect
 142 ;;; a stunted stack can result from the tail call variant.)
 143 (flet ((optimized ()
 144          (declare (optimize (speed 2) (debug 1))) ; tail call elimination
 145          (#:undefined-function 42))
 146        (not-optimized ()
 147          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 148          (#:undefined-function 42))
 149        (test (fun)
 150          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 151          (funcall fun)))
 152
 153   (with-test (:name (:undefined-function :bug-346)
 154               :fails-on '(or :alpha))   ; bug 346
 155     (assert (verify-backtrace
 156              (lambda () (test #'optimized))
 157              (list *undefined-function-frame*
 158                    (list '(flet test) #'optimized)))))
 159
 160   ;; bug 353: This test fails at least most of the time for x86/linux
 161   ;; ca. 0.8.20.16. -- WHN
 162   (with-test (:name (:undefined-function :bug-353)
 163               ;; This used to have fewer :fails-on features pre-0.9.16.38,
 164               ;; but it turns out that the bug was just being masked by
 165               ;; the presence of the IR1 stepper instrumentation (and
 166               ;; is thus again failing now that the instrumentation is
 167               ;; no more).
 168               :fails-on '(or :x86 :x86-64 :alpha))
 169     (assert (verify-backtrace
 170              (lambda () (test #'not-optimized))
 171              (list *undefined-function-frame*
 172                    (list '(flet not-optimized))
 173                    (list '(flet test) #'not-optimized))))))
 174
 175 ;;; Division by zero was a common error on PPC. It depended on the
 176 ;;; return function either being before INTEGER-/-INTEGER in memory,
 177 ;;; or more than MOST-POSITIVE-FIXNUM bytes ahead. It also depends on
 178 ;;; INTEGER-/-INTEGER calling SIGNED-TRUNCATE. I believe Raymond Toy
 179 ;;; says that the Sparc backend (at least for CMUCL) inlines this, so
 180 ;;; if SBCL does the same this test is probably not good for the
 181 ;;; Sparc.
 182 ;;;
 183 ;;; Disabling tail call elimination on this will probably ensure that
 184 ;;; the return value (to the flet or the enclosing top level form) is
 185 ;;; more than MOST-POSITIVE-FIXNUM with the current spaces on OS X.
 186 ;;; Enabling it might catch other problems, so do it anyway.
 187 (flet ((optimized ()
 188          (declare (optimize (speed 2) (debug 1))) ; tail call elimination
 189          (/ 42 0))
 190        (not-optimized ()
 191          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 192          (/ 42 0))
 193        (test (fun)
 194          (declare (optimize (speed 1) (debug 2))) ; no tail call elimination
 195          (funcall fun)))
 196   (with-test (:name (:divide-by-zero :bug-346)
 197               :fails-on '(or :alpha))   ; bug 346
 198     (assert (verify-backtrace (lambda () (test #'optimized))
 199                               (list '(/ 42 &rest)
 200                                     (list '(flet test) #'optimized)))))
 201   (with-test (:name (:divide-by-zero :bug-356)
 202               :fails-on '(or :alpha))   ; bug 356
 203     (assert (verify-backtrace (lambda () (test #'not-optimized))
 204                               (list '(/ 42 &rest)
 205                                     '((flet not-optimized))
 206                                     (list '(flet test) #'not-optimized))))))
 207
 208 (with-test (:name (:throw :no-such-tag)
 209             :fails-on '(or
 210                         (and :x86 (or :linux :freebsd sunos))
 211                         :alpha
 212                         :mips))
 213   (progn
 214     (defun throw-test ()
 215       (throw 'no-such-tag t))
 216     (assert (verify-backtrace #'throw-test '((throw-test))))))
 217
 218 ;;; test entry point handling in backtraces
 219
 220 (defun oops ()
 221   (error "oops"))
 222
 223 (defmacro defbt (n ll &body body)
 224   `(progn
 225      ;; normal debug info
 226      (defun ,(intern (format nil "BT.~A.1" n)) ,ll
 227        ,@body)
 228      ;; no arguments saved
 229      (defun ,(intern (format nil "BT.~A.2" n)) ,ll
 230        (declare (optimize (debug 1) (speed 3)))
 231        ,@body)
 232      ;; no lambda-list saved
 233      (defun ,(intern (format nil "BT.~A.3" n)) ,ll
 234        (declare (optimize (debug 0)))
 235        ,@body)))
 236
 237 (defbt 1 (&key key)
 238   (list key))
 239
 240 (defbt 2 (x)
 241   (list x))
 242
 243 (defbt 3 (&key (key (oops)))
 244   (list key))
 245
 246 ;;; ERROR instead of OOPS so that tail call elimination doesn't happen
 247 (defbt 4 (&optional opt)
 248   (list (error "error")))
 249
 250 (defbt 5 (&optional (opt (oops)))
 251   (list opt))
 252
 253 ;;; FIXME: This test really should be broken into smaller pieces
 254 (with-test (:name (:backtrace :misc)
 255             :fails-on '(and :x86 (or :linux :sunos)))
 256   (macrolet ((with-details (bool &body body)
 257                `(let ((sb-debug:*show-entry-point-details* ,bool))
 258                  ,@body)))
 259
 260     ;; TL-XEP
 261     (print :tl-xep)
 262     (with-details t
 263       (assert (verify-backtrace #'namestring
 264                                 '(((sb-c::tl-xep namestring) 0 ?)))))
 265     (with-details nil
 266       (assert (verify-backtrace #'namestring
 267                                 '((namestring)))))
 268
 269
 270     ;; &MORE-PROCESSOR
 271     (with-details t
 272       (assert (verify-backtrace (lambda () (bt.1.1 :key))
 273                                 '(((sb-c::&more-processor bt.1.1) &rest))))
 274       (assert (verify-backtrace (lambda () (bt.1.2 :key))
 275                                 '(((sb-c::&more-processor bt.1.2) &rest))))
 276       (assert (verify-backtrace (lambda () (bt.1.3 :key))
 277                                 '(((sb-c::&more-processor bt.1.3) &rest)))))
 278     (with-details nil
 279       (assert (verify-backtrace (lambda () (bt.1.1 :key))
 280                                 '((bt.1.1 :key))))
 281       (assert (verify-backtrace (lambda () (bt.1.2 :key))
 282                                 '((bt.1.2 &rest))))
 283       (assert (verify-backtrace (lambda () (bt.1.3 :key))
 284                                 '((bt.1.3 &rest)))))
 285
 286     ;; XEP
 287     (print :xep)
 288     (with-details t
 289       (assert (verify-backtrace #'bt.2.1
 290                                 '(((sb-c::xep bt.2.1) 0 ?))))
 291       (assert (verify-backtrace #'bt.2.2
 292                                 '(((sb-c::xep bt.2.2) &rest))))
 293       (assert (verify-backtrace #'bt.2.3
 294                                 '(((sb-c::xep bt.2.3) &rest)))))
 295     (with-details nil
 296       (assert (verify-backtrace #'bt.2.1
 297                                 '((bt.2.1))))
 298       (assert (verify-backtrace #'bt.2.2
 299                                 '((bt.2.2 &rest))))
 300       (assert (verify-backtrace #'bt.2.3
 301                                 '((bt.2.3 &rest)))))
 302
 303     ;; VARARGS-ENTRY
 304     (print :varargs-entry)
 305     (with-details t
 306       (assert (verify-backtrace #'bt.3.1
 307                                 '(((sb-c::varargs-entry bt.3.1) :key nil))))
 308       (assert (verify-backtrace #'bt.3.2
 309                                 '(((sb-c::varargs-entry bt.3.2) :key ?))))
 310       (assert (verify-backtrace #'bt.3.3
 311                                 '(((sb-c::varargs-entry bt.3.3) &rest)))))
 312     (with-details nil
 313       (assert (verify-backtrace #'bt.3.1
 314                                 '((bt.3.1 :key nil))))
 315       (assert (verify-backtrace #'bt.3.2
 316                                 '((bt.3.2 :key ?))))
 317       (assert (verify-backtrace #'bt.3.3
 318                                 '((bt.3.3 &rest)))))
 319
 320     ;; HAIRY-ARG-PROCESSOR
 321     (print :hairy-args-processor)
 322     (with-details t
 323       (assert (verify-backtrace #'bt.4.1
 324                                 '(((sb-c::hairy-arg-processor bt.4.1) ?))))
 325       (assert (verify-backtrace #'bt.4.2
 326                                 '(((sb-c::hairy-arg-processor bt.4.2) ?))))
 327       (assert (verify-backtrace #'bt.4.3
 328                                 '(((sb-c::hairy-arg-processor bt.4.3) &rest)))))
 329     (with-details nil
 330       (assert (verify-backtrace #'bt.4.1
 331                                 '((bt.4.1 ?))))
 332       (assert (verify-backtrace #'bt.4.2
 333                                 '((bt.4.2 ?))))
 334       (assert (verify-backtrace #'bt.4.3
 335                                 '((bt.4.3 &rest)))))
 336
 337     ;; &OPTIONAL-PROCESSOR
 338     (print :optional-processor)
 339     (with-details t
 340       (assert (verify-backtrace #'bt.5.1
 341                                 '(((sb-c::&optional-processor bt.5.1)))))
 342       (assert (verify-backtrace #'bt.5.2
 343                                 '(((sb-c::&optional-processor bt.5.2) &rest))))
 344       (assert (verify-backtrace #'bt.5.3
 345                                 '(((sb-c::&optional-processor bt.5.3) &rest)))))
 346     (with-details nil
 347       (assert (verify-backtrace #'bt.5.1
 348                                 '((bt.5.1))))
 349       (assert (verify-backtrace #'bt.5.2
 350                                 '((bt.5.2 &rest))))
 351       (assert (verify-backtrace #'bt.5.3
 352                                 '((bt.5.3 &rest)))))))
 353
 354 ;;;; test TRACE
 355
 356 (defun trace-this ()
 357   'ok)
 358
 359 (defun trace-fact (n)
 360   (if (zerop n)
 361       1
 362       (* n (trace-fact (1- n)))))
 363
 364 (let ((out (with-output-to-string (*trace-output*)
 365              (trace trace-this)
 366              (assert (eq 'ok (trace-this)))
 367              (untrace))))
 368   (assert (search "TRACE-THIS" out))
 369   (assert (search "returned OK" out)))
 370
 371 ;;; bug 379
 372 ;;; This is not a WITH-TEST :FAILS-ON PPC DARWIN since there are
 373 ;;; suspicions that the breakpoint trace might corrupt the whole image
 374 ;;; on that platform.
 375 #-(and (or ppc x86) darwin)
 376 (with-test (:name (trace :encapsulate nil)
 377             :fails-on '(or :ppc :sparc :mips))
 378   (let ((out (with-output-to-string (*trace-output*)
 379                (trace trace-this :encapsulate nil)
 380                (assert (eq 'ok (trace-this)))
 381                (untrace))))
 382     (assert (search "TRACE-THIS" out))
 383     (assert (search "returned OK" out))))
 384
 385 #-(and (or ppc x86) darwin)
 386 (with-test (:name (trace-recursive :encapsulate nil)
 387             :fails-on '(or :ppc :sparc :mips))
 388   (let ((out (with-output-to-string (*trace-output*)
 389                (trace trace-fact :encapsulate nil)
 390                (assert (= 120 (trace-fact 5)))
 391                (untrace))))
 392     (assert (search "TRACE-FACT" out))
 393     (assert (search "returned 1" out))
 394     (assert (search "returned 120" out))))
 395
 396 ;;;; test infinite error protection
 397
 398 (defmacro nest-errors (n-levels error-form)
 399   (if (< 0 n-levels)
 400       `(handler-bind ((error (lambda (condition)
 401                                (declare (ignore condition))
 402                                ,error-form)))
 403         (nest-errors ,(1- n-levels) ,error-form))
 404       error-form))
 405
 406 (defun erroring-debugger-hook (condition old-debugger-hook)
 407   (let ((*debugger-hook* old-debugger-hook))
 408     (format t "recursive condition: ~A~%" condition) (force-output)
 409     (error "recursive condition: ~A" condition)))
 410
 411 (defun test-inifinite-error-protection ()
 412   ;; after 50 successful throws to SB-IMPL::TOPLEVEL-CATCHER sbcl used
 413   ;; to halt, it produces so much garbage that's hard to suppress that
 414   ;; it is tested only once
 415   (let ((*debugger-hook* #'erroring-debugger-hook))
 416     (loop repeat 1 do
 417           (let ((error-counter 0)
 418                 (*terminal-io* (make-broadcast-stream)))
 419             (assert
 420              (not (eq
 421                    :normal-exit
 422                    (catch 'sb-impl::toplevel-catcher
 423                      (nest-errors 20 (error "infinite error ~s"
 424                                             (incf error-counter)))
 425                      :normal-exit))))))))
 426
 427 (enable-debugger)
 428
 429 (test-inifinite-error-protection)
 430
 431 #+sb-thread
 432 (let ((thread (sb-thread:make-thread #'test-inifinite-error-protection)))
 433   (loop while (sb-thread:thread-alive-p thread)))
 434
 435 (disable-debugger)