tests/interface.pure.lisp

   1 ;;;; tests for problems in the interface presented to the user/programmer
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; While most of SBCL is derived from the CMU CL system, the test
   7 ;;;; files (like this one) were written from scratch after the fork
   8 ;;;; from CMU CL.
   9 ;;;;
  10 ;;;; This software is in the public domain and is provided with
  11 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  12 ;;;; more information.
  13
  14 (in-package :cl-user)
  15 \f
  16 ;;;; properties of symbols, e.g. presence of doc strings for public symbols
  17
  18 ;;; FIXME: It would probably be good to require here that every
  19 ;;; external symbol either has a doc string or has some good excuse
  20 ;;; (like being an accessor for a structure which has a doc string).
  21 \f
  22 ;;;; tests of interface machinery
  23
  24 ;;; APROPOS should accept a package designator, not just a package, and
  25 ;;; furthermore do the right thing when it gets a package designator.
  26 ;;; (bug reported and fixed by Alexey Dejneka sbcl-devel 2001-10-17)
  27 (assert (< 0
  28            (length (apropos-list "PRINT" :cl))
  29            (length (apropos-list "PRINT"))))
  30 ;;; Further, it should correctly deal with the external-only flag (bug
  31 ;;; reported by cliini on #lisp IRC 2003-05-30, fixed in sbcl-0.8.0.1x
  32 ;;; by CSR)
  33 (assert (= (length (apropos-list "" "CL"))
  34            (length (apropos-list "" "CL" t))))
  35 (assert (< 0
  36            (length (apropos-list "" "SB-VM" t))
  37            (length (apropos-list "" "SB-VM"))))
  38 \f
  39 ;;; DESCRIBE shouldn't fail on rank-0 arrays (bug reported and fixed
  40 ;;; by Lutz Euler sbcl-devel 2002-12-03)
  41 (describe #0a0)
  42 (describe #(1 2 3))
  43 (describe #2a((1 2) (3 4)))
  44
  45 ;;; TYPEP, SUBTYPEP, UPGRADED-ARRAY-ELEMENT-TYPE and
  46 ;;; UPGRADED-COMPLEX-PART-TYPE should be able to deal with NIL as an
  47 ;;; environment argument
  48 (typep 1 'fixnum nil)
  49 (subtypep 'fixnum 'integer nil)
  50 (upgraded-array-element-type '(mod 5) nil)
  51 (upgraded-complex-part-type '(single-float 0.0 1.0) nil)
  52
  53 ;;; We should have documentation for our extension package:
  54 (assert (documentation (find-package "SB-EXT") t))
  55
  56 ;;; DECLARE should not be a special operator
  57 (assert (not (special-operator-p 'declare)))
  58
  59 ;;; WITH-TIMEOUT should accept more than one form in its body.
  60 (with-test (:name :with-timeout-forms)
  61   (handler-bind ((sb-ext:timeout #'continue))
  62     (sb-ext:with-timeout 3
  63       (sleep 2)
  64       (sleep 2))))
  65
  66 ;;; SLEEP should work with large integers as well -- no timers
  67 ;;; on win32, so don't test there.
  68 (with-test (:name (sleep pretty-much-forever) :skipped-on :win32)
  69   (assert (eq :timeout
  70               (handler-case
  71                   (sb-ext:with-timeout 1
  72                     (sleep (ash 1 (* 2 sb-vm:n-word-bits))))
  73                 (sb-ext:timeout ()
  74                   :timeout)))))
  75
  76 ;;; DOCUMENTATION should return nil, not signal slot-unbound
  77 (documentation 'fixnum 'type)
  78 (documentation 'class 'type)
  79 (documentation (find-class 'class) 'type)
  80 (documentation 'foo 'structure)
  81
  82 ;;; DECODE-UNIVERSAL-TIME should accept second-resolution time-zones.
  83 (macrolet ((test (ut time-zone list)
  84              (destructuring-bind (sec min hr date mon yr day tz)
  85                  list
  86                `(multiple-value-bind (sec min hr date mon yr day dst tz)
  87                     (decode-universal-time ,ut ,time-zone)
  88                   (declare (ignore dst))
  89                   (assert (= sec ,sec))
  90                   (assert (= min ,min))
  91                   (assert (= hr ,hr))
  92                   (assert (= date ,date))
  93                   (assert (= mon ,mon))
  94                   (assert (= yr ,yr))
  95                   (assert (= day ,day))
  96                   (assert (= tz ,tz))))))
  97   (test (* 86400 365) -1/3600 (1 0 0 1 1 1901 1 -1/3600))
  98   (test (* 86400 365) 0 (0 0 0 1 1 1901 1 0))
  99   (test (* 86400 365) 1/3600 (59 59 23 31 12 1900 0 1/3600)))
 100
 101 ;;; DECODE-UNIVERSAL-TIME shouldn't fail when the time is outside UNIX
 102 ;;; 32-bit time_t and a timezone wasn't passed
 103 (decode-universal-time 0 nil)
 104
 105 ;;; ENCODE-UNIVERSAL-TIME should be able to encode the universal time
 106 ;;; 0 when passed a representation in a timezone where the
 107 ;;; representation of 0 as a decoded time is in 1899.
 108 (encode-universal-time 0 0 23 31 12 1899 1)
 109
 110 ;;; DISASSEMBLE shouldn't fail on purified functions
 111 (disassemble 'cl:+)
 112 (disassemble 'sb-ext:run-program)
 113
 114 ;;; minimal test of GC: see stress-gc.{sh,lisp} for a more
 115 ;;; comprehensive test.
 116 (loop repeat 2
 117       do (compile nil '(lambda (x) x))
 118       do (sb-ext:gc :full t))
 119
 120 ;;; On x86-64, the instruction definitions for CMP*[PS][SD] were broken
 121 ;;; so that the disassembler threw an error when they were used with
 122 ;;; one operand in memory.
 123 (with-test (:name :bug-814702)
 124   (disassemble (lambda (x)
 125                  (= #C(2.0f0 3.0f0)
 126                     (the (complex single-float) x))))
 127   (disassemble (lambda (x y)
 128                  (= (the (complex single-float) x)
 129                     (the (complex single-float) y)))))