tests/run-tests.lisp

   1 #+#.(cl:if (cl:find-package "ASDF") '(or) '(and))
   2 (load (merge-pathnames "../contrib/asdf/asdf.fasl"))
   3
   4 #+#.(cl:if (cl:find-package "SB-POSIX") '(or) '(and))
   5 (let ((asdf:*central-registry*
   6        (cons "../contrib/systems/" asdf:*central-registry*)))
   7   (asdf:oos 'asdf:load-op 'sb-posix))
   8
   9 (load "test-util.lisp")
  10
  11 (defpackage :run-tests
  12     (:use :cl :test-util :sb-ext))
  13
  14 (load "assertoid.lisp")
  15
  16 (in-package run-tests)
  17
  18 (defvar *all-failures* nil)
  19 (defvar *break-on-error* nil)
  20 (defvar *report-skipped-tests* nil)
  21 (defvar *accept-files* nil)
  22
  23 (defun run-all ()
  24   (dolist (arg (cdr *posix-argv*))
  25     (cond ((string= arg "--break-on-failure")
  26            (setf *break-on-error* t)
  27            (setf test-util:*break-on-failure* t))
  28           ((string= arg "--break-on-expected-failure")
  29            (setf test-util:*break-on-expected-failure* t))
  30           ((string= arg "--report-skipped-tests")
  31            (setf *report-skipped-tests* t))
  32           (t
  33            (push (truename (parse-namestring arg)) *accept-files*))))
  34   (pure-runner (pure-load-files) #'load-test)
  35   (pure-runner (pure-cload-files) #'cload-test)
  36   (impure-runner (impure-load-files) #'load-test)
  37   (impure-runner (impure-cload-files) #'cload-test)
  38   #-win32 (impure-runner (sh-files) #'sh-test)
  39   (report)
  40   (sb-ext:exit :code (if (unexpected-failures)
  41                          1
  42                          104)))
  43
  44 (defun report ()
  45   (terpri)
  46   (format t "Finished running tests.~%")
  47   (let ((skipcount 0))
  48     (cond (*all-failures*
  49            (format t "Status:~%")
  50            (dolist (fail (reverse *all-failures*))
  51              (cond ((eq (car fail) :unhandled-error)
  52                     (format t " ~20a ~a~%"
  53                             "Unhandled error"
  54                             (enough-namestring (second fail))))
  55                    ((eq (car fail) :invalid-exit-status)
  56                     (format t " ~20a ~a~%"
  57                             "Invalid exit status:"
  58                             (enough-namestring (second fail))))
  59                    ((eq (car fail) :skipped-disabled)
  60                     (when *report-skipped-tests*
  61                       (format t " ~20a ~a / ~a~%"
  62                               "Skipped (irrelevant):"
  63                               (enough-namestring (second fail))
  64                               (third fail)))
  65                     (incf skipcount))
  66                    (t
  67                     (format t " ~20a ~a / ~a~%"
  68                             (ecase (first fail)
  69                               (:expected-failure "Expected failure:")
  70                               (:unexpected-failure "Failure:")
  71                               (:unexpected-success "Unexpected success:")
  72                               (:skipped-broken "Skipped (broken):")
  73                               (:skipped-disabled "Skipped (irrelevant):"))
  74                             (enough-namestring (second fail))
  75                             (third fail)))))
  76            (when (> skipcount 0)
  77              (format t " (~a tests skipped for this combination of platform and features)~%"
  78                      skipcount)))
  79           (t
  80            (format t "All tests succeeded~%")))))
  81
  82 (defun pure-runner (files test-fun)
  83   (format t "// Running pure tests (~a)~%" test-fun)
  84   (let ((*package* (find-package :cl-user))
  85         (*failures* nil))
  86     (setup-cl-user)
  87     (dolist (file files)
  88       (when (accept-test-file file)
  89         (format t "// Running ~a~%" file)
  90         (restart-case
  91             (handler-bind ((error (make-error-handler file)))
  92               (eval (funcall test-fun file)))
  93           (skip-file ()))))
  94     (append-failures)))
  95
  96 (defun run-in-child-sbcl (load-forms forms)
  97   ;; We used to fork() for POSIX platforms, and use this for Windows.
  98   ;; However, it seems better to use the same solution everywhere.
  99   (process-exit-code
 100    (#-win32 with-open-file #-win32 (devnull "/dev/null") #+win32 progn
 101      (sb-ext:run-program
 102       (first *POSIX-ARGV*)
 103       (append
 104        (list "--core" SB-INT:*CORE-STRING*
 105              "--noinform"
 106              "--no-sysinit"
 107              "--no-userinit"
 108              "--noprint"
 109              "--disable-debugger")
 110        (loop for form in (append load-forms forms)
 111              collect "--eval"
 112              collect (write-to-string form)))
 113       :output sb-sys:*stdout*
 114       :input #-win32 devnull #+win32 sb-sys:*stdin*))))
 115
 116 (defun run-impure-in-child-sbcl (test-file test-code)
 117   (run-in-child-sbcl
 118     `((load "test-util")
 119       (load "assertoid")
 120       (defpackage :run-tests
 121         (:use :cl :test-util :sb-ext)))
 122
 123     `((in-package :cl-user)
 124       (use-package :test-util)
 125       (use-package :assertoid)
 126       (setf test-util:*break-on-failure* ,test-util:*break-on-failure*)
 127       (setf test-util:*break-on-expected-failure*
 128             ,test-util:*break-on-expected-failure*)
 129       (let ((file ,test-file)
 130             (*break-on-error* ,run-tests::*break-on-error*))
 131         (declare (special *break-on-error*))
 132         (format t "// Running ~a~%" file)
 133         (restart-case
 134             (handler-bind
 135                 ((error (lambda (condition)
 136                           (push (list :unhandled-error file)
 137                                 test-util::*failures*)
 138                           (cond (*break-on-error*
 139                                  (test-util:really-invoke-debugger condition))
 140                                 (t
 141                                  (format *error-output* "~&Unhandled ~a: ~a~%"
 142                                          (type-of condition) condition)
 143                                  (sb-debug:backtrace)))
 144                           (invoke-restart 'skip-file))))
 145               ,test-code)
 146           (skip-file ()
 147             (format t ">>>~a<<<~%" test-util::*failures*)))
 148         (test-util:report-test-status)
 149         (sb-ext:exit :code 104)))))
 150
 151 (defun impure-runner (files test-fun)
 152   (format t "// Running impure tests (~a)~%" test-fun)
 153   (let ((*package* (find-package :cl-user)))
 154     (setup-cl-user)
 155     (dolist (file files)
 156       (when (accept-test-file file)
 157         (force-output)
 158         (let ((exit-code (run-impure-in-child-sbcl file
 159                                                    (funcall test-fun file))))
 160           (if (= exit-code 104)
 161               (with-open-file (stream "test-status.lisp-expr"
 162                                       :direction :input
 163                                       :if-does-not-exist :error)
 164                 (append-failures (read stream)))
 165               (push (list :invalid-exit-status file)
 166                     *all-failures*)))))))
 167
 168 (defun make-error-handler (file)
 169   (lambda (condition)
 170     (push (list :unhandled-error file) *failures*)
 171     (cond (*break-on-error*
 172            (test-util:really-invoke-debugger condition))
 173           (t
 174            (format *error-output* "~&Unhandled ~a: ~a~%"
 175                    (type-of condition) condition)
 176            (sb-debug:backtrace)))
 177     (invoke-restart 'skip-file)))
 178
 179 (defun append-failures (&optional (failures *failures*))
 180   (setf *all-failures* (append failures *all-failures*)))
 181
 182 (defun unexpected-failures ()
 183   (remove-if (lambda (x)
 184                (or (eq (car x) :expected-failure)
 185                    (eq (car x) :unexpected-success)
 186                    (eq (car x) :skipped-broken)
 187                    (eq (car x) :skipped-disabled)))
 188              *all-failures*))
 189
 190 (defun setup-cl-user ()
 191   (use-package :test-util)
 192   (use-package :assertoid))
 193
 194 (defun load-test (file)
 195   `(load ,file))
 196
 197 (defun cload-test (file)
 198   `(let ((compile-name (compile-file-pathname ,file)))
 199      (unwind-protect
 200           (progn
 201             (compile-file ,file)
 202             (load compile-name))
 203        (ignore-errors
 204          (delete-file compile-name)))))
 205
 206 (defun sh-test (file)
 207   ;; What? No SB-POSIX:EXECV?
 208   `(let ((process (sb-ext:run-program "/bin/sh"
 209                                       (list (native-namestring ,file))
 210                                       :environment (test-util::test-env)
 211                                       :output *error-output*)))
 212      (let ((*failures* nil))
 213        (test-util:report-test-status))
 214      (sb-ext:exit :code (process-exit-code process))))
 215
 216 (defun accept-test-file (file)
 217   (if *accept-files*
 218       (find (truename file) *accept-files* :test #'equalp)
 219       t))
 220
 221 (defun pure-load-files ()
 222   (directory "*.pure.lisp"))
 223
 224 (defun pure-cload-files ()
 225   (directory "*.pure-cload.lisp"))
 226
 227 (defun impure-load-files ()
 228   (directory "*.impure.lisp"))
 229
 230 (defun impure-cload-files ()
 231   (directory "*.impure-cload.lisp"))
 232
 233 (defun sh-files ()
 234   (directory "*.test.sh"))