tests/run-tests.lisp

   1 #+#.(cl:if (cl:find-package "ASDF") '(or) '(and))
   2 (load (merge-pathnames "../contrib/asdf/asdf.fasl"))
   3
   4 #+#.(cl:if (cl:find-package "SB-POSIX") '(or) '(and))
   5 (let ((asdf:*central-registry*
   6        (cons "../contrib/systems/" asdf:*central-registry*)))
   7   (asdf:oos 'asdf:load-op 'sb-posix))
   8
   9 (load "test-util.lisp")
  10
  11 (defpackage :run-tests
  12     (:use :cl :test-util :sb-ext))
  13
  14 (load "assertoid.lisp")
  15
  16 (in-package run-tests)
  17
  18 (defvar *all-failures* nil)
  19 (defvar *break-on-error* nil)
  20 (defvar *accept-files* nil)
  21
  22 (defun run-all ()
  23   (dolist (arg (cdr *posix-argv*))
  24     (cond ((string= arg "--break-on-failure")
  25            (setf *break-on-error* t)
  26            (setf test-util:*break-on-failure* t))
  27           ((string= arg "--break-on-expected-failure")
  28            (setf test-util:*break-on-expected-failure* t))
  29           (t
  30            (push (truename (parse-namestring arg)) *accept-files*))))
  31   (pure-runner (pure-load-files) #'load-test)
  32   (pure-runner (pure-cload-files) #'cload-test)
  33   (impure-runner (impure-load-files) #'load-test)
  34   (impure-runner (impure-cload-files) #'cload-test)
  35   (impure-runner (sh-files) #'sh-test)
  36   (report)
  37   (sb-ext:quit :unix-status (if (unexpected-failures)
  38                                 1
  39                                 104)))
  40
  41 (defun report ()
  42   (terpri)
  43   (format t "Finished running tests.~%")
  44   (cond (*all-failures*
  45          (format t "Status:~%")
  46          (dolist (fail (reverse *all-failures*))
  47            (cond ((eq (car fail) :unhandled-error)
  48                   (format t " ~20a ~a~%"
  49                           "Unhandled error"
  50                           (enough-namestring (second fail))))
  51                  ((eq (car fail) :invalid-exit-status)
  52                   (format t " ~20a ~a~%"
  53                           "Invalid exit status:"
  54                           (enough-namestring (second fail))))
  55                  (t
  56                   (format t " ~20a ~a / ~a~%"
  57                           (ecase (first fail)
  58                             (:expected-failure "Expected failure:")
  59                             (:unexpected-failure "Failure:")
  60                             (:unexpected-success "Unexpected success:"))
  61                           (enough-namestring (second fail))
  62                           (third fail))))))
  63         (t
  64          (format t "All tests succeeded~%"))))
  65
  66 (defun pure-runner (files test-fun)
  67   (format t "// Running pure tests (~a)~%" test-fun)
  68   (let ((*package* (find-package :cl-user))
  69         (*failures* nil))
  70     (setup-cl-user)
  71     (dolist (file files)
  72       (when (accept-test-file file)
  73         (format t "// Running ~a~%" file)
  74         (restart-case
  75             (handler-bind ((error (make-error-handler file)))
  76               (funcall test-fun file))
  77           (skip-file ()))))
  78     (append-failures)))
  79
  80 (defun impure-runner (files test-fun)
  81   (format t "// Running impure tests (~a)~%" test-fun)
  82   (let ((*package* (find-package :cl-user)))
  83     (setup-cl-user)
  84     (dolist (file files)
  85       (when (accept-test-file file)
  86         (force-output)
  87         (let ((pid (sb-posix:fork)))
  88           (cond ((= pid 0)
  89                  (format t "// Running ~a~%" file)
  90                  (restart-case
  91                      (handler-bind ((error (make-error-handler file)))
  92                        (funcall test-fun file))
  93                    (skip-file ()
  94                      (format t ">>>~a<<<~%" *failures*)))
  95                  (report-test-status)
  96                  (sb-ext:quit :unix-status 104))
  97                 (t
  98                  (let ((status (make-array 1 :element-type '(signed-byte 32))))
  99                    (sb-posix:waitpid pid 0 status)
 100                    (if (and (sb-posix:wifexited (aref status 0))
 101                             (= (sb-posix:wexitstatus (aref status 0))
 102                                104))
 103                        (with-open-file (stream "test-status.lisp-expr"
 104                                                :direction :input
 105                                                :if-does-not-exist :error)
 106                          (append-failures (read stream)))
 107                        (push (list :invalid-exit-status file)
 108                              *all-failures*))))))))))
 109
 110 (defun make-error-handler (file)
 111   (lambda (condition)
 112     (push (list :unhandled-error file) *failures*)
 113     (cond (*break-on-error*
 114            (test-util:really-invoke-debugger condition))
 115           (t
 116            (format *error-output* "~&Unhandled ~a: ~a~%"
 117                    (type-of condition) condition)
 118            (sb-debug:backtrace)))
 119     (invoke-restart 'skip-file)))
 120
 121 (defun append-failures (&optional (failures *failures*))
 122   (setf *all-failures* (append failures *all-failures*)))
 123
 124 (defun unexpected-failures ()
 125   (remove-if (lambda (x)
 126                (or (eq (car x) :expected-failure)
 127                    (eq (car x) :unexpected-success)))
 128              *all-failures*))
 129
 130 (defun setup-cl-user ()
 131   (use-package :test-util)
 132   (use-package :assertoid))
 133
 134 (defun load-test (file)
 135   (load file))
 136
 137 (defun cload-test (file)
 138   (let ((compile-name (compile-file-pathname file)))
 139     (unwind-protect
 140          (progn
 141            (compile-file file)
 142            (load compile-name))
 143       (ignore-errors
 144         (delete-file compile-name)))))
 145
 146 (defun sh-test (file)
 147   ;; What? No SB-POSIX:EXECV?
 148   (let ((process (sb-ext:run-program "/bin/sh"
 149                                      (list (namestring file))
 150                                      :output *error-output*)))
 151     (sb-ext:quit :unix-status (process-exit-code process))))
 152
 153 (defun accept-test-file (file)
 154   (if *accept-files*
 155       (find (truename file) *accept-files* :test #'equalp)
 156       t))
 157
 158 (defun pure-load-files ()
 159   (directory "*.pure.lisp"))
 160
 161 (defun pure-cload-files ()
 162   (directory "*.pure-cload.lisp"))
 163
 164 (defun impure-load-files ()
 165   (directory "*.impure.lisp"))
 166
 167 (defun impure-cload-files ()
 168   (directory "*.impure-cload.lisp"))
 169
 170 (defun sh-files ()
 171   (directory "*.test.sh"))