tests/threads.impure.lisp

   1 ;;;; miscellaneous tests of thread stuff
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; While most of SBCL is derived from the CMU CL system, the test
   7 ;;;; files (like this one) were written from scratch after the fork
   8 ;;;; from CMU CL.
   9 ;;;
  10 ;;;; This software is in the public domain and is provided with
  11 ;;;; absoluely no warranty. See the COPYING and CREDITS files for
  12 ;;;; more information.
  13
  14 #-sb-thread (quit :unix-status 104)
  15
  16 (in-package "SB-THREAD") ; this is white-box testing, really
  17
  18 ;;; We had appalling scaling properties for a while.  Make sure they
  19 ;;; don't reappear.
  20 (defun scaling-test (function &optional (nthreads 5))
  21   "Execute FUNCTION with NTHREADS lurking to slow it down."
  22   (let ((queue (sb-thread:make-waitqueue))
  23         (mutex (sb-thread:make-mutex)))
  24     ;; Start NTHREADS idle threads.
  25     (dotimes (i nthreads)
  26       (sb-thread:make-thread (lambda ()
  27                                (sb-thread:condition-wait queue mutex)
  28                                (sb-ext:quit))))
  29     (let ((start-time (get-internal-run-time)))
  30       (funcall function)
  31       (prog1 (- (get-internal-run-time) start-time)
  32         (sb-thread:condition-broadcast queue)))))
  33 (defun fact (n)
  34   "A function that does work with the CPU."
  35   (if (zerop n) 1 (* n (fact (1- n)))))
  36 (let ((work (lambda () (fact 15000))))
  37   (let ((zero (scaling-test work 0))
  38         (four (scaling-test work 4)))
  39     ;; a slightly weak assertion, but good enough for starters.
  40     (assert (< four (* 1.5 zero)))))
  41
  42 ;;; For one of the interupt-thread tests, we want a foreign function
  43 ;;; that does not make syscalls
  44
  45 (with-open-file (o "threads-foreign.c" :direction :output :if-exists :supersede)
  46   (format o "void loop_forever() { while(1) ; }~%"))
  47 (sb-ext:run-program
  48  "cc"
  49  (or #+linux '("-shared" "-o" "threads-foreign.so" "threads-foreign.c")
  50      (error "Missing shared library compilation options for this platform"))
  51  :search t)
  52 (sb-alien:load-shared-object "threads-foreign.so")
  53 (sb-alien:define-alien-routine loop-forever sb-alien:void)
  54
  55
  56 ;;; elementary "can we get a lock and release it again"
  57 (let ((l (make-mutex :name "foo"))
  58       (p (current-thread-id)))
  59   (assert (eql (mutex-value l) nil) nil "1")
  60   (assert (eql (mutex-lock l) 0) nil "2")
  61   (sb-thread:get-mutex l)
  62   (assert (eql (mutex-value l) p) nil "3")
  63   (assert (eql (mutex-lock l) 0) nil "4")
  64   (sb-thread:release-mutex l)
  65   (assert (eql (mutex-value l) nil) nil "5")
  66   (assert (eql (mutex-lock l) 0)  nil "6")
  67   (describe l))
  68
  69 ;; test that SLEEP actually sleeps for at least the given time, even
  70 ;; if interrupted by another thread exiting/a gc/anything
  71 (let ((start-time (get-universal-time)))
  72   (make-thread (lambda () (sleep 1))) ; kid waits 1 then dies ->SIG_THREAD_EXIT
  73   (sleep 5)
  74   (assert (>= (get-universal-time) (+ 5 start-time))))
  75
  76
  77 (let ((queue (make-waitqueue :name "queue"))
  78       (lock (make-mutex :name "lock")))
  79   (labels ((in-new-thread ()
  80              (with-mutex (lock)
  81                (assert (eql (mutex-value lock) (current-thread-id)))
  82                (format t "~A got mutex~%" (current-thread-id))
  83                ;; now drop it and sleep
  84                (condition-wait queue lock)
  85                ;; after waking we should have the lock again
  86                (assert (eql (mutex-value lock) (current-thread-id))))))
  87     (make-thread #'in-new-thread)
  88     (sleep 2)                           ; give it  a chance to start
  89     ;; check the lock is free while it's asleep
  90     (format t "parent thread ~A~%" (current-thread-id))
  91     (assert (eql (mutex-value lock) nil))
  92     (assert (eql (mutex-lock lock) 0))
  93     (with-mutex (lock)
  94       (condition-notify queue))
  95     (sleep 1)))
  96
  97 (let ((queue (make-waitqueue :name "queue"))
  98       (lock (make-mutex :name "lock")))
  99   (labels ((ours-p (value)
 100              (sb-vm:control-stack-pointer-valid-p
 101               (sb-sys:int-sap (sb-kernel:get-lisp-obj-address value))))
 102            (in-new-thread ()
 103              (with-recursive-lock (lock)
 104                (assert (ours-p (mutex-value lock)))
 105                (format t "~A got mutex~%" (mutex-value lock))
 106                ;; now drop it and sleep
 107                (condition-wait queue lock)
 108                ;; after waking we should have the lock again
 109                (format t "woken, ~A got mutex~%" (mutex-value lock))
 110                (assert (ours-p (mutex-value lock))))))
 111     (make-thread #'in-new-thread)
 112     (sleep 2)                           ; give it  a chance to start
 113     ;; check the lock is free while it's asleep
 114     (format t "parent thread ~A~%" (current-thread-id))
 115     (assert (eql (mutex-value lock) nil))
 116     (assert (eql (mutex-lock lock) 0))
 117     (with-recursive-lock (lock)
 118       (condition-notify queue))
 119     (sleep 1)))
 120
 121 (let ((mutex (make-mutex :name "contended")))
 122   (labels ((run ()
 123              (let ((me (current-thread-id)))
 124                (dotimes (i 100)
 125                  (with-mutex (mutex)
 126                    (sleep .1)
 127                    (assert (eql (mutex-value mutex) me)))
 128                  (assert (not (eql (mutex-value mutex) me))))
 129                (format t "done ~A~%" (current-thread-id)))))
 130     (let ((kid1 (make-thread #'run))
 131           (kid2 (make-thread #'run)))
 132       (format t "contention ~A ~A~%" kid1 kid2))))
 133
 134 (defun test-interrupt (function-to-interrupt &optional quit-p)
 135   (let ((child  (make-thread function-to-interrupt)))
 136     ;;(format t "gdb ./src/runtime/sbcl ~A~%attach ~A~%" child child)
 137     (sleep 2)
 138     (format t "interrupting child ~A~%" child)
 139     (interrupt-thread child
 140                       (lambda ()
 141                         (format t "child pid ~A~%" (current-thread-id))
 142                         (when quit-p (sb-ext:quit))))
 143     (sleep 1)
 144     child))
 145
 146 ;;; separate tests for (a) interrupting Lisp code, (b) C code, (c) a syscall,
 147 ;;; (d) waiting on a lock, (e) some code which we hope is likely to be
 148 ;;; in pseudo-atomic
 149
 150 (let ((child (test-interrupt (lambda () (loop)))))  (terminate-thread child))
 151
 152 (test-interrupt #'loop-forever :quit)
 153
 154 (let ((child (test-interrupt (lambda () (loop (sleep 2000))))))
 155   ;; Interrupting a sleep form causes it to return early.  Welcome to Unix.
 156   ;; Just to be sure our LOOP form works, let's check the child is still
 157   ;; there
 158   (assert (zerop (sb-unix:unix-kill child 0)))
 159   (terminate-thread child))
 160
 161 (let ((lock (make-mutex :name "loctite"))
 162       child)
 163   (with-mutex (lock)
 164     (setf child (test-interrupt
 165                  (lambda ()
 166                    (with-mutex (lock)
 167                      (assert (eql (mutex-value lock) (current-thread-id))))
 168                    (assert (not (eql (mutex-value lock) (current-thread-id))))
 169                    (sleep 60))))
 170     ;;hold onto lock for long enough that child can't get it immediately
 171     (sleep 20)
 172     (interrupt-thread child (lambda () (format t "l ~A~%" (mutex-value lock))))
 173     (format t "parent releasing lock~%"))
 174   (terminate-thread child))
 175
 176 (defun alloc-stuff () (copy-list '(1 2 3 4 5)))
 177
 178 (let ((c (test-interrupt (lambda () (loop (alloc-stuff))))))
 179   ;; NB this only works on x86: other ports don't have a symbol for
 180   ;; pseudo-atomic atomicity
 181   (format t "new thread ~A~%" c)
 182   (dotimes (i 100)
 183     (sleep (random 1d0))
 184     (interrupt-thread c
 185                       (lambda ()
 186                         (princ ".") (force-output)
 187                         (assert (zerop SB-KERNEL:*PSEUDO-ATOMIC-ATOMIC*)))))
 188   (terminate-thread c))
 189
 190 (format t "~&interrupt test done~%")
 191
 192 (let (a-done b-done)
 193   (make-thread (lambda ()
 194                  (dotimes (i 100)
 195                    (sb-ext:gc) (princ "\\") (force-output) )
 196                  (setf a-done t)))
 197   (make-thread (lambda ()
 198                  (dotimes (i 25)
 199                    (sb-ext:gc :full t)
 200                    (princ "/") (force-output))
 201                  (setf b-done t)))
 202   (loop
 203    (when (and a-done b-done) (return))
 204    (sleep 1)))
 205
 206 (defun waste (&optional (n 100000))
 207   (loop repeat n do (make-string 16384)))
 208
 209 (loop for i below 100 do
 210       (format t "LOOP:~A~%" i)
 211       (force-output)
 212       (sb-thread:make-thread
 213        #'(lambda ()
 214            (waste)))
 215       (waste)
 216       (sb-ext:gc))
 217
 218 (defparameter *aaa* nil)
 219 (loop for i below 100 do
 220       (format t "LOOP:~A~%" i)
 221       (force-output)
 222       (sb-thread:make-thread
 223        #'(lambda ()
 224            (let ((*aaa* (waste)))
 225              (waste))))
 226       (let ((*aaa* (waste)))
 227         (waste))
 228       (sb-ext:gc))
 229
 230 (format t "~&gc test done~%")
 231
 232 #|  ;; a cll post from eric marsden
 233 | (defun crash ()
 234 |   (setq *debugger-hook*
 235 |         (lambda (condition old-debugger-hook)
 236 |           (debug:backtrace 10)
 237 |           (unix:unix-exit 2)))
 238 |   #+live-dangerously
 239 |   (mp::start-sigalrm-yield)
 240 |   (flet ((roomy () (loop (with-output-to-string (*standard-output*) (room)))))
 241 |     (mp:make-process #'roomy)
 242 |     (mp:make-process #'roomy)))
 243 |#
 244
 245 ;; give the other thread time to die before we leave, otherwise the
 246 ;; overall exit status is 0, not 104
 247 (sleep 2)
 248
 249 (sb-ext:quit :unix-status 104)