tests/timer.impure.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; While most of SBCL is derived from the CMU CL system, the test
   5 ;;;; files (like this one) were written from scratch after the fork
   6 ;;;; from CMU CL.
   7 ;;;;
   8 ;;;; This software is in the public domain and is provided with
   9 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  10 ;;;; more information.
  11
  12 (in-package "CL-USER")
  13
  14 (use-package :test-util)
  15
  16 (with-test (:name :heap)
  17   (let* ((size 1000)
  18          (heap (make-array size :adjustable t :fill-pointer 0))
  19          (unsorted (loop for i below size collect (random size)))
  20          (sorted (sort (copy-list unsorted) #'>=))
  21          heap-sorted)
  22     (map nil #'(lambda (val) (sb-impl::heap-insert heap val)) unsorted)
  23     (setf heap-sorted (loop for i below size
  24                             collect (sb-impl::heap-extract-maximum heap)))
  25     (unless (equal sorted heap-sorted)
  26       (error "Heap sort failure ~S" heap-sorted))))
  27
  28 (sb-alien:define-alien-routine "check_deferrables_blocked_or_lose"
  29     void
  30   (where sb-alien:unsigned-long))
  31 (sb-alien:define-alien-routine "check_deferrables_unblocked_or_lose"
  32     void
  33   (where sb-alien:unsigned-long))
  34
  35 (defun make-limited-timer (fn n &rest args)
  36   (let (timer)
  37     (setq timer
  38           (apply #'sb-ext:make-timer
  39                  (lambda ()
  40                    (sb-sys:without-interrupts
  41                      (decf n)
  42                      (cond ((minusp n)
  43                             (warn "Unscheduling timer ~A ~
  44                                    upon reaching run limit. System too slow?"
  45                                   timer)
  46                             (sb-ext:unschedule-timer timer))
  47                            (t
  48                             (sb-sys:allow-with-interrupts
  49                               (funcall fn))))))
  50                  args))))
  51
  52 (defun make-and-schedule-and-wait (fn time)
  53   (let ((finishedp nil))
  54     (sb-ext:schedule-timer (sb-ext:make-timer
  55                             (lambda ()
  56                               (sb-sys:without-interrupts
  57                                 (unwind-protect
  58                                      (sb-sys:allow-with-interrupts
  59                                        (funcall fn))
  60                                   (setq finishedp t)))))
  61                            time)
  62     (loop until finishedp)))
  63
  64 (with-test (:name (:timer :deferrables-blocked))
  65   (make-and-schedule-and-wait (lambda ()
  66                                 (check-deferrables-blocked-or-lose 0))
  67                               (random 0.1))
  68   (check-deferrables-unblocked-or-lose 0))
  69
  70 (with-test (:name (:timer :deferrables-unblocked))
  71   (make-and-schedule-and-wait (lambda ()
  72                                 (sb-sys:with-interrupts
  73                                   (check-deferrables-unblocked-or-lose 0)))
  74                               (random 0.1))
  75   (check-deferrables-unblocked-or-lose 0))
  76
  77 #-win32
  78 (with-test (:name (:timer :deferrables-unblocked :unwind))
  79   (catch 'xxx
  80     (make-and-schedule-and-wait (lambda ()
  81                                   (check-deferrables-blocked-or-lose 0)
  82                                   (throw 'xxx nil))
  83                                 (random 0.1))
  84     (sleep 1))
  85   (check-deferrables-unblocked-or-lose 0))
  86
  87 (defmacro raises-timeout-p (&body body)
  88   `(handler-case (progn (progn ,@body) nil)
  89     (sb-ext:timeout () t)))
  90
  91 (with-test (:name (:timer :relative)
  92             :fails-on '(and :sparc :linux))
  93   (let* ((has-run-p nil)
  94          (timer (make-timer (lambda () (setq has-run-p t))
  95                             :name "simple timer")))
  96     (schedule-timer timer 0.5)
  97     (sleep 0.2)
  98     (assert (not has-run-p))
  99     (sleep 0.5)
 100     (assert has-run-p)
 101     (assert (zerop (length (sb-impl::%pqueue-contents sb-impl::*schedule*))))))
 102
 103 (with-test (:name (:timer :absolute)
 104             :fails-on '(and :sparc :linux))
 105   (let* ((has-run-p nil)
 106          (timer (make-timer (lambda () (setq has-run-p t))
 107                             :name "simple timer")))
 108     (schedule-timer timer (+ 1/2 (get-universal-time)) :absolute-p t)
 109     (sleep 0.2)
 110     (assert (not has-run-p))
 111     (sleep 0.5)
 112     (assert has-run-p)
 113     (assert (zerop (length (sb-impl::%pqueue-contents sb-impl::*schedule*))))))
 114
 115 #+sb-thread
 116 (with-test (:name (:timer :other-thread))
 117   (let* ((thread (sb-thread:make-thread (lambda () (sleep 2))))
 118          (timer (make-timer (lambda ()
 119                               (assert (eq thread sb-thread:*current-thread*)))
 120                             :thread thread)))
 121     (schedule-timer timer 0.1)))
 122
 123 #+sb-thread
 124 (with-test (:name (:timer :new-thread))
 125   (let* ((original-thread sb-thread:*current-thread*)
 126          (timer (make-timer
 127                  (lambda ()
 128                    (assert (not (eq original-thread
 129                                     sb-thread:*current-thread*))))
 130                  :thread t)))
 131     (schedule-timer timer 0.1)))
 132
 133 (with-test (:name (:timer :repeat-and-unschedule)
 134             :fails-on '(and :sparc :linux))
 135   (let* ((run-count 0)
 136          timer)
 137     (setq timer
 138           (make-timer (lambda ()
 139                         (when (= 5 (incf run-count))
 140                           (unschedule-timer timer)))))
 141     (schedule-timer timer 0 :repeat-interval 0.2)
 142     (assert (timer-scheduled-p timer :delta 0.3))
 143     (sleep 1.3)
 144     (assert (= 5 run-count))
 145     (assert (not (timer-scheduled-p timer)))
 146     (assert (zerop (length (sb-impl::%pqueue-contents sb-impl::*schedule*))))))
 147
 148 (with-test (:name (:timer :reschedule))
 149   (let* ((has-run-p nil)
 150          (timer (make-timer (lambda ()
 151                               (setq has-run-p t)))))
 152     (schedule-timer timer 0.2)
 153     (schedule-timer timer 0.3)
 154     (sleep 0.5)
 155     (assert has-run-p)
 156     (assert (zerop (length (sb-impl::%pqueue-contents sb-impl::*schedule*))))))
 157
 158 (with-test (:name (:timer :stress))
 159   (let ((time (1+ (get-universal-time))))
 160     (loop repeat 200 do
 161              (schedule-timer (make-timer (lambda ())) time :absolute-p t))
 162     (sleep 2)
 163     (assert (zerop (length (sb-impl::%pqueue-contents sb-impl::*schedule*))))))
 164
 165 (with-test (:name (:timer :stress2))
 166   (let ((time (1+ (get-universal-time)))
 167         (n 0))
 168     (loop for time-n from time upto (+ 1/10 time) by (/ 1/10 200)
 169           do (schedule-timer (make-timer (lambda ())) time-n :absolute-p t)
 170              (incf n))
 171     (sleep 2)
 172     (assert (zerop (length (sb-impl::%pqueue-contents sb-impl::*schedule*))))))
 173
 174 (with-test (:name (:with-timeout :timeout))
 175   (assert (raises-timeout-p
 176            (sb-ext:with-timeout 0.2
 177              (sleep 1)))))
 178
 179 (with-test (:name (:with-timeout :fall-through))
 180   (assert (not (raises-timeout-p
 181                 (sb-ext:with-timeout 0.3
 182                   (sleep 0.1))))))
 183
 184 (with-test (:name (:with-timeout :nested-timeout-smaller))
 185   (assert(raises-timeout-p
 186           (sb-ext:with-timeout 10
 187             (sb-ext:with-timeout 0.5
 188               (sleep 2))))))
 189
 190 (with-test (:name (:with-timeout :nested-timeout-bigger))
 191   (assert(raises-timeout-p
 192           (sb-ext:with-timeout 0.5
 193             (sb-ext:with-timeout 2
 194               (sleep 2))))))
 195
 196 (defun wait-for-threads (threads)
 197   (loop while (some #'sb-thread:thread-alive-p threads) do (sleep 0.01)))
 198
 199 #+sb-thread
 200 (with-test (:name (:with-timeout :many-at-the-same-time))
 201   (let ((ok t))
 202     (let ((threads (loop repeat 10 collect
 203                          (sb-thread:make-thread
 204                           (lambda ()
 205                             (handler-case
 206                                 (sb-ext:with-timeout 0.5
 207                                   (sleep 5)
 208                                   (setf ok nil)
 209                                   (format t "~%not ok~%"))
 210                               (timeout ()
 211                                 )))))))
 212       (assert (not (raises-timeout-p
 213                     (sb-ext:with-timeout 20
 214                       (wait-for-threads threads)))))
 215       (assert ok))))
 216
 217 #+sb-thread
 218 (with-test (:name (:with-timeout :dead-thread))
 219   (sb-thread:make-thread
 220    (lambda ()
 221      (let ((timer (make-timer (lambda ()))))
 222        (schedule-timer timer 3)
 223        (assert t))))
 224   (sleep 6)
 225   (assert t))
 226
 227
 228 (defun random-type (n)
 229   `(integer ,(random n) ,(+ n (random n))))
 230
 231 ;;; FIXME: Since timeouts do not work on Windows this would loop
 232 ;;; forever.
 233 #-win32
 234 (with-test (:name (:hash-cache :interrupt))
 235   (let* ((type1 (random-type 500))
 236          (type2 (random-type 500))
 237          (wanted (subtypep type1 type2)))
 238     (dotimes (i 100)
 239       (block foo
 240         (sb-ext:schedule-timer (sb-ext:make-timer
 241                                 (lambda ()
 242                                   (assert (eq wanted (subtypep type1 type2)))
 243                                     (return-from foo)))
 244                                0.05)
 245         (loop
 246            (assert (eq wanted (subtypep type1 type2))))))))
 247
 248 ;;; Used to hang occasionally at least on x86. Two bugs caused it:
 249 ;;; running out of stack (due to repeating timers being rescheduled
 250 ;;; before they ran) and dying threads were open interrupts.
 251 #+sb-thread
 252 (with-test (:name (:timer :parallel-unschedule) :fails-on :ppc)
 253   #+darwin
 254   (error "Prone to hang on Darwin due to interrupt issues.")
 255   #+ppc
 256   (error "Prone to hang the host on linux/ppc for unknown reasons.")
 257   (let ((timer (sb-ext:make-timer (lambda () 42) :name "parallel schedulers"))
 258         (other nil))
 259     (flet ((flop ()
 260              (sleep (random 0.01))
 261              (loop repeat 10000
 262                    do (sb-ext:unschedule-timer timer))))
 263       (loop repeat 5
 264             do (mapcar #'sb-thread:join-thread
 265                        (loop for i from 1 upto 10
 266                              collect (let* ((thread (sb-thread:make-thread #'flop
 267                                                                            :name (format nil "scheduler ~A" i)))
 268                                             (ticker (make-limited-timer (lambda () 13)
 269                                                                                1000
 270                                                                                :thread (or other thread)
 271                                                                                :name (format nil "ticker ~A" i))))
 272                                        (setf other thread)
 273                                        (sb-ext:schedule-timer ticker 0 :repeat-interval 0.00001)
 274                                        thread)))))))
 275
 276 ;;;; FIXME: OS X 10.4 doesn't like these being at all, and gives us a SIGSEGV
 277 ;;;; instead of using the Mach expection system! 10.5 on the other tends to
 278 ;;;; lose() here with interrupt already pending. :/
 279 ;;;;
 280 ;;;; Used to have problems in genereal, see comment on (:TIMER
 281 ;;;; :PARALLEL-UNSCHEDULE).
 282 (with-test (:name (:timer :schedule-stress))
 283   (flet ((test ()
 284          (let* ((slow-timers
 285                  (loop for i from 1 upto 1
 286                        collect (make-limited-timer
 287                                 (lambda () 13)
 288                                 1000
 289                                 :name (format nil "slow ~A" i))))
 290                 (fast-timer (make-limited-timer (lambda () 42) 1000
 291                                                 :name "fast")))
 292            (sb-ext:schedule-timer fast-timer 0.0001 :repeat-interval 0.0001)
 293            (dolist (timer slow-timers)
 294              (sb-ext:schedule-timer timer (random 0.1)
 295                                     :repeat-interval (random 0.1)))
 296            (dolist (timer slow-timers)
 297              (sb-ext:unschedule-timer timer))
 298            (sb-ext:unschedule-timer fast-timer))))
 299   #+sb-thread
 300   (mapcar #'sb-thread:join-thread
 301           (loop repeat 10 collect (sb-thread:make-thread #'test)))
 302   #-sb-thread
 303   (loop repeat 10 do (test))))
 304
 305 #+sb-thread
 306 (with-test (:name (:timer :threaded-stress))
 307   (let ((barrier (sb-thread:make-semaphore))
 308         (goal 100))
 309     (flet ((wait-for-goal ()
 310              (let ((*n* 0))
 311                (declare (special *n*))
 312                (sb-thread:signal-semaphore barrier)
 313                (loop until (eql *n* goal))))
 314            (one ()
 315              (declare (special *n*))
 316              (incf *n*)))
 317       (let ((threads (list (sb-thread:make-thread #'wait-for-goal)
 318                            (sb-thread:make-thread #'wait-for-goal)
 319                            (sb-thread:make-thread #'wait-for-goal))))
 320         (sb-thread:wait-on-semaphore barrier)
 321         (sb-thread:wait-on-semaphore barrier)
 322         (sb-thread:wait-on-semaphore barrier)
 323         (flet ((sched (thread)
 324                  (sb-thread:make-thread (lambda ()
 325                                           (loop repeat goal
 326                                                 do (sb-ext:schedule-timer (make-timer #'one :thread thread) 0.001))))))
 327           (dolist (thread threads)
 328             (sched thread)))
 329         (mapcar #'sb-thread:join-thread threads)))))