+ (Internal)
+ :OPTIMIZER
+ :SOURCE-TRANSFORM
+ :TRANSFORM
+ :VOP
+
+If an unsupported TYPE is requested, the function will return NIL.
+"
+ (flet ((listify (x)
+ (if (listp x)
+ x
+ (list x))))
+ (listify
+ (case type
+ ((:variable)
+ (when (eq (sb-int:info :variable :kind name) :special)
+ (translate-source-location (sb-int:info :source-location type name))))
+ ((:constant)
+ (when (eq (sb-int:info :variable :kind name) :constant)
+ (translate-source-location (sb-int:info :source-location type name))))
+ ((:symbol-macro)
+ (when (eq (sb-int:info :variable :kind name) :macro)
+ (translate-source-location (sb-int:info :source-location type name))))
+ ((:macro)
+ (when (and (symbolp name)
+ (macro-function name))
+ (find-definition-source (macro-function name))))
+ ((:compiler-macro)
+ (when (compiler-macro-function name)
+ (find-definition-source (compiler-macro-function name))))
+ ((:function :generic-function)
+ (when (and (fboundp name)
+ (or (not (symbolp name))
+ (not (macro-function name))))
+ (let ((fun (fdefinition name)))
+ (when (eq (not (typep fun 'generic-function))
+ (not (eq type :generic-function)))
+ (find-definition-source fun)))))
+ ((:type)
+ (let ((expander-fun (sb-int:info :type :expander name)))
+ (when expander-fun
+ (find-definition-source expander-fun))))
+ ((:method)
+ (when (and (fboundp name)
+ (typep (fdefinition name) 'generic-function))
+ (loop for method in (sb-mop::generic-function-methods
+ (fdefinition name))
+ for source = (find-definition-source method)
+ when source collect source)))
+ ((:setf-expander)
+ (when (and (consp name)
+ (eq (car name) 'setf))
+ (setf name (cadr name)))
+ (let ((expander-fun (or (sb-int:info :setf :inverse name)
+ (sb-int:info :setf :expander name))))
+ (when expander-fun
+ (sb-introspect:find-definition-source expander-fun))))
+ ((:structure)
+ (let ((class (ignore-errors (find-class name))))
+ (if class
+ (when (typep class 'sb-pcl::structure-class)
+ (find-definition-source class))
+ (when (sb-int:info :typed-structure :info name)
+ (translate-source-location
+ (sb-int:info :source-location :typed-structure name))))))
+ ((:condition :class)
+ (let ((class (ignore-errors (find-class name))))
+ (when class
+ (when (eq (not (typep class 'sb-pcl::condition-class))
+ (not (eq type :condition)))
+ (find-definition-source class)))))
+ ((:method-combination)
+ (let ((combination-fun
+ (ignore-errors (find-method #'sb-mop:find-method-combination
+ nil
+ (list (find-class 'generic-function)
+ (list 'eql name)
+ t)))))
+ (when combination-fun
+ (find-definition-source combination-fun))))
+ ((:package)
+ (when (symbolp name)
+ (let ((package (find-package name)))
+ (when package
+ (find-definition-source package)))))
+ ;;; TRANSFORM and OPTIMIZER handling from swank-sbcl
+ ((:transform)
+ (let ((fun-info (sb-int:info :function :info name)))
+ (when fun-info
+ (loop for xform in (sb-c::fun-info-transforms fun-info)
+ for source = (find-definition-source
+ (sb-c::transform-function xform))
+ for typespec = (sb-kernel:type-specifier
+ (sb-c::transform-type xform))
+ for note = (sb-c::transform-note xform)
+ do (setf (definition-source-description source)
+ (if (consp typespec)
+ (list (second typespec) note)
+ (list note)))
+ collect source))))
+ ((:optimizer)
+ (let ((fun-info (sb-int:info :function :info name)))
+ (when fun-info
+ (let ((otypes '((sb-c::fun-info-derive-type . sb-c:derive-type)
+ (sb-c::fun-info-ltn-annotate . sb-c:ltn-annotate)
+ (sb-c::fun-info-ltn-annotate . sb-c:ltn-annotate)
+ (sb-c::fun-info-optimizer . sb-c:optimizer))))
+ (loop for (reader . name) in otypes
+ for fn = (funcall reader fun-info)
+ when fn collect
+ (let ((source (find-definition-source fn)))
+ (setf (definition-source-description source)
+ (list name))
+ source))))))
+ ((:vop)
+ (let ((fun-info (sb-int:info :function :info name)))
+ (when fun-info
+ (loop for vop in (sb-c::fun-info-templates fun-info)
+ for source = (find-definition-source
+ (sb-c::vop-info-generator-function vop))
+ do (setf (definition-source-description source)
+ (list (sb-c::template-name vop)
+ (sb-c::template-note vop)))
+ collect source))))
+ ((:source-transform)
+ (let ((transform-fun (sb-int:info :function :source-transform name)))
+ (when transform-fun
+ (sb-introspect:find-definition-source transform-fun))))
+ (t
+ nil)))))
+
+(defun find-definition-source (object)
+ (typecase object
+ ((or sb-pcl::condition-class sb-pcl::structure-class)
+ (let ((classoid (sb-impl::find-classoid (class-name object))))
+ (when classoid
+ (let ((layout (sb-impl::classoid-layout classoid)))
+ (when layout
+ (translate-source-location
+ (sb-kernel::layout-source-location layout)))))))
+ (method-combination
+ (car
+ (find-definition-sources-by-name (sb-pcl::method-combination-type object)
+ :method-combination)))
+ (package
+ (translate-source-location (sb-impl::package-source-location object)))
+ (class
+ (translate-source-location (sb-pcl::definition-source object)))
+ ;; Use the PCL definition location information instead of the function
+ ;; debug-info for methods and generic functions. Sometimes the
+ ;; debug-info would point into PCL internals instead of the proper
+ ;; location.
+ (generic-function
+ (let ((source (translate-source-location
+ (sb-pcl::definition-source object))))
+ (when source
+ (setf (definition-source-description source)
+ (list (sb-mop:generic-function-lambda-list object))))
+ source))
+ (method
+ (let ((source (translate-source-location
+ (sb-pcl::definition-source object))))
+ (when source
+ (setf (definition-source-description source)
+ (append (method-qualifiers object)
+ (sb-pcl::unparse-specializers
+ (sb-mop:method-specializers object)))))
+ source))
+ (function
+ (cond ((struct-accessor-p object)
+ (find-definition-source
+ (struct-accessor-structure-class object)))
+ ((struct-predicate-p object)
+ (find-definition-source
+ (struct-predicate-structure-class object)))
+ (t
+ (find-function-definition-source object))))
+ (t
+ (error "Don't know how to retrive source location for a ~S~%"
+ (type-of object)))))
+
+(defun find-function-definition-source (function)
+ (let* ((debug-info (function-debug-info function))
+ (debug-source (debug-info-source debug-info))
+ (debug-fun (debug-info-debug-function debug-info))
+ (tlf (if debug-fun (sb-c::compiled-debug-fun-tlf-number debug-fun))))
+ (make-definition-source
+ :pathname
+ (if (eql (sb-c::debug-source-from debug-source) :file)
+ (parse-namestring (sb-c::debug-source-name debug-source)))
+ :character-offset
+ (if tlf
+ (elt (sb-c::debug-source-start-positions debug-source) tlf))
+ ;; Unfortunately there is no proper source path available in the
+ ;; debug-source. FIXME: We could use sb-di:code-locations to get
+ ;; a full source path. -luke (12/Mar/2005)
+ :form-path (if tlf (list tlf))
+ :file-write-date (sb-c::debug-source-created debug-source)
+ :plist (sb-c::debug-source-plist debug-source))))
+
+(defun translate-source-location (location)
+ (if location
+ (make-definition-source
+ :pathname (let ((n (sb-c:definition-source-location-namestring location)))
+ (when n
+ (parse-namestring n)))
+ :form-path
+ (let ((number (sb-c:definition-source-location-toplevel-form-number
+ location)))
+ (when number
+ (list number)))
+ :plist (sb-c:definition-source-location-plist location))
+ (make-definition-source)))