+(deftest deftype-lambda-list.1
+ (deftype-lambda-list 'foobar-type)
+ (&whole w &environment e r1 r2 &optional o &rest rest &key k1 k2 k3)
+ t)
+
+(deftest deftype-lambda-list.2
+ (deftype-lambda-list (gensym))
+ nil
+ nil)
+
+;; ARRAY is a primitive type with associated translator function.
+(deftest deftype-lambda-list.3
+ (deftype-lambda-list 'array)
+ (&optional (sb-kernel::element-type '*) (sb-kernel::dimensions '*))
+ t)
+
+;; VECTOR is a primitive type that is defined by means of DEFTYPE.
+(deftest deftype-lambda-list.4
+ (deftype-lambda-list 'vector)
+ (&optional sb-kernel::element-type sb-kernel::size)
+ t)
+
+;;; Test allocation-information
+
+(defun tai (x kind info &key ignore)
+ (multiple-value-bind (kind2 info2) (sb-introspect:allocation-information x)
+ (unless (eq kind kind2)
+ (error "wanted ~S, got ~S" kind kind2))
+ (when (not (null ignore))
+ (setf info2 (copy-list info2))
+ (dolist (key ignore)
+ (remf info2 key))
+ (setf info (copy-list info))
+ (dolist (key ignore)
+ (remf info key)))
+ (equal info info2)))
+
+(deftest allocation-infromation.1
+ (tai nil :heap '(:space :static))
+ t)
+
+(deftest allocation-information.2
+ (tai t :heap '(:space :static))
+ t)
+
+(deftest allocation-information.3
+ (tai 42 :immediate nil)
+ t)
+
+;;; Skip the whole damn test on GENCGC PPC -- the combination is just
+;;; to flaky for this to make too much sense.
+#-(and ppc gencgc)
+(deftest allocation-information.4
+ #+gencgc
+ (tai #'cons :heap
+ ;; FIXME: This is the canonical GENCGC result. On PPC we sometimes get
+ ;; :LARGE T, which doesn't seem right -- but ignore that for now.
+ '(:space :dynamic :generation 6 :write-protected t :boxed t :pinned nil :large nil)
+ :ignore (list :page #+ppc :large))
+ #-gencgc
+ (tai :cons :heap
+ ;; FIXME: Figure out what's the right cheney-result. SPARC at least
+ ;; has exhibited both :READ-ONLY and :DYNAMIC, which seems wrong.
+ '()
+ :ignore '(:space))
+ t)
+
+#+sb-thread
+(deftest allocation-information.thread.1
+ (let ((x (list 1 2 3)))
+ (declare (dynamic-extent x))
+ (tai x :stack sb-thread:*current-thread*))
+ t)
+
+#+sb-thread
+(progn
+ (defun thread-tai ()
+ (let ((x (list 1 2 3)))
+ (declare (dynamic-extent x))
+ (let ((child (sb-thread:make-thread
+ (lambda ()
+ (sb-introspect:allocation-information x)))))
+ (equal (list :stack sb-thread:*current-thread*)
+ (multiple-value-list (sb-thread:join-thread child))))))
+
+ (deftest allocation-information.thread.2
+ (thread-tai)
+ t)
+
+ (defun thread-tai2 ()
+ (let* ((sem (sb-thread:make-semaphore))
+ (obj nil)
+ (child (sb-thread:make-thread
+ (lambda ()
+ (let ((x (list 1 2 3)))
+ (declare (dynamic-extent x))
+ (setf obj x)
+ (sb-thread:wait-on-semaphore sem)))
+ :name "child")))
+ (loop until obj)
+ (unwind-protect
+ (equal (list :stack child)
+ (multiple-value-list
+ (sb-introspect:allocation-information obj)))
+ (sb-thread:signal-semaphore sem)
+ (sb-thread:join-thread child))))
+
+ (deftest allocation-information.thread.3
+ (thread-tai2)
+ t))
+
+;;;; Test FUNCTION-TYPE
+
+(defun type-equal (typespec1 typespec2)
+ (or (equal typespec1 typespec2) ; TYPE= punts on &keywords in FTYPEs.
+ (sb-kernel:type= (sb-kernel:values-specifier-type typespec1)
+ (sb-kernel:values-specifier-type typespec2))))
+
+(defmacro interpret (form)
+ `(let ((sb-ext:*evaluator-mode* :interpret))
+ (eval ',form)))
+
+;; Functions
+
+(declaim (ftype (function (integer &optional string) string) moon))
+(defun moon (int &optional suffix)
+ (concatenate 'string (princ-to-string int) suffix))
+
+(deftest function-type.1
+ (values (type-equal (function-type 'moon) (function-type #'moon))
+ (type-equal (function-type #'moon)
+ '(function (integer &optional string)
+ (values string &rest t))))
+ t t)
+
+(defun sun (x y &key k1)
+ (declare (fixnum x y))
+ (declare (boolean k1))
+ (declare (ignore x y k1))
+ t)
+
+(deftest function-type.2
+ (values (type-equal (function-type 'sun) (function-type #'sun))
+ (type-equal (function-type #'sun)
+ '(function (fixnum fixnum &key (:k1 (member nil t)))
+ (values (member t) &optional))))
+ t t)
+
+;; Local functions
+
+(deftest function-type.5
+ (flet ((f (s)
+ (declare (symbol s))
+ (values (symbol-name s))))
+ (type-equal (function-type #'f)
+ '(function (symbol) (values simple-string &optional))))
+ t)
+
+;; Closures
+
+(deftest function-type.6
+ (let ((x 10))
+ (declare (fixnum x))
+ (flet ((closure (y)
+ (declare (fixnum y))
+ (setq x (+ x y))))
+ (type-equal (function-type #'closure)
+ '(function (fixnum) (values fixnum &optional)))))
+ t)
+
+;; Anonymous functions
+
+(deftest function-type.7
+ (type-equal (function-type #'(lambda (x) (declare (fixnum x)) x))
+ '(function (fixnum) (values fixnum &optional)))
+ t)
+
+;; Interpreted functions
+
+#+sb-eval
+(deftest function-type.8
+ (type-equal (function-type (interpret (lambda (x) (declare (fixnum x)) x)))
+ '(function (&rest t) *))
+ t)
+
+;; Generic functions
+
+(defgeneric earth (x y))
+
+(deftest function-type+gfs.1
+ (values (type-equal (function-type 'earth) (function-type #'earth))
+ (type-equal (function-type 'earth) '(function (t t) *)))
+ t t)
+
+;; Implicitly created generic functions.
+
+;; (FUNCTION-TYPE 'MARS) => FUNCTION at the moment. (1.0.31.26)
+
+;; See LP #520695.
+
+(defmethod mars (x y) (+ x y))
+
+#+ nil
+(deftest function-type+gfs.2
+ (values (type-equal (function-type 'mars) (function-type #'mars))
+ (type-equal (function-type 'mars) '(function (t t) *)))
+ t t)
+
+;; DEFSTRUCT created functions
+
+;; These do not yet work because SB-KERNEL:%FUN-NAME does not work on
+;; functions defined by DEFSTRUCT. (1.0.35.x)
+
+;; See LP #520692.
+
+#+nil
+(progn
+
+ (defstruct (struct (:predicate our-struct-p)
+ (:copier copy-our-struct))
+ (a 42 :type fixnum))
+
+ (deftest function-type+defstruct.1
+ (values (type-equal (function-type 'struct-a)
+ (function-type #'struct-a))
+ (type-equal (function-type 'struct-a)
+ '(function (struct) (values fixnum &optional))))
+ t t)
+
+ (deftest function-type+defstruct.2
+ (values (type-equal (function-type 'our-struct-p)
+ (function-type #'our-struct-p))
+ (type-equal (function-type 'our-struct-p)
+ '(function (t) (values (member t nil) &optional))))
+ t t)
+
+ (deftest function-type+defstruct.3
+ (values (type-equal (function-type 'copy-our-struct)
+ (function-type #'copy-our-struct))
+ (type-equal (function-type 'copy-our-struct)
+ '(function (struct) (values struct &optional))))
+ t t)
+
+ (defstruct (typed-struct :named (:type list)
+ (:predicate typed-struct-p))
+ (a 42 :type fixnum))
+
+ (deftest function-type+defstruct.4
+ (values (type-equal (function-type 'typed-struct-a)
+ (function-type #'typed-struct-a))
+ (type-equal (function-type 'typed-struct-a)
+ '(function (list) (values fixnum &optional))))
+ t t)
+
+ (deftest function-type+defstruct.5
+ (values (type-equal (function-type 'typed-struct-p)
+ (function-type #'typed-struct-p))
+ (type-equal (function-type 'typed-struct-p)
+ '(function (t) (values (member t nil) &optional))))
+ t t)
+
+ ) ; #+nil (progn ...
+
+;; SETF functions
+
+(defun (setf sun) (value x y &key k1)
+ (declare (boolean value))
+ (declare (fixnum x y))
+ (declare (boolean k1))
+ (declare (ignore x y k1))
+ value)
+
+(deftest function-type+setf.1
+ (values (type-equal (function-type '(setf sun))
+ (function-type #'(setf sun)))
+ (type-equal (function-type '(setf sun))
+ '(function ((member nil t)
+ fixnum fixnum
+ &key (:k1 (member nil t)))
+ (values (member nil t) &optional))))
+ t t)